gcc/ada/a-wtgeau.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --         A D A . W I D E _ T E X T _ I O . G E N E R I C _ A U X          --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --          Copyright (C) 1992-2001 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This package contains a set of auxiliary routines used by Wide_Text_IO
  36 --  generic children, including for reading and writing numeric strings.
  37
  38 --  Note: although this is the Wide version of the package, the interface
  39 --  here is still in terms of Character and String rather than Wide_Character
  40 --  and Wide_String, since all numeric strings are composed entirely of
  41 --  characters in the range of type Standard.Character, and the basic
  42 --  conversion routines work with Character rather than Wide_Character.
  43
  44 package Ada.Wide_Text_IO.Generic_Aux is
  45
  46    --  Note: for all the Load routines, File indicates the file to be read,
  47    --  Buf is the string into which data is stored, Ptr is the index of the
  48    --  last character stored so far, and is updated if additional characters
  49    --  are stored. Data_Error is raised if the input overflows Buf. The only
  50    --  Load routines that do a file status check are Load_Skip and Load_Width
  51    --  so one of these two routines must be called first.
  52
  53    procedure Check_End_Of_Field
  54      (Buf   : String;
  55       Stop  : Integer;
  56       Ptr   : Integer;
  57       Width : Field);
  58    --  This routine is used after doing a get operations on a numeric value.
  59    --  Buf is the string being scanned, and Stop is the last character of
  60    --  the field being scanned. Ptr is as set by the call to the scan routine
  61    --  that scanned out the numeric value, i.e. it points one past the last
  62    --  character scanned, and Width is the width parameter from the Get call.
  63    --
  64    --  There are two cases, if Width is non-zero, then a check is made that
  65    --  the remainder of the field is all blanks. If Width is zero, then it
  66    --  means that the scan routine scanned out only part of the field. We
  67    --  have already scanned out the field that the ACVC tests seem to expect
  68    --  us to read (even if it does not follow the syntax of the type being
  69    --  scanned, e.g. allowing negative exponents in integers, and underscores
  70    --  at the end of the string), so we just raise Data_Error.
  71
  72    procedure Check_On_One_Line (File : File_Type; Length : Integer);
  73    --  Check to see if item of length Integer characters can fit on
  74    --  current line. Call New_Line if not, first checking that the
  75    --  line length can accommodate Length characters, raise Layout_Error
  76    --  if item is too large for a single line.
  77
  78    function Is_Blank (C : Character) return Boolean;
  79    --  Determines if C is a blank (space or tab)
  80
  81    procedure Load_Width
  82      (File  : File_Type;
  83       Width : in Field;
  84       Buf   : out String;
  85       Ptr   : in out Integer);
  86    --  Loads exactly Width characters, unless a line mark is encountered first
  87
  88    procedure Load_Skip (File  : File_Type);
  89    --  Skips leading blanks and line and page marks, if the end of file is
  90    --  read without finding a non-blank character, then End_Error is raised.
  91    --  Note: a blank is defined as a space or horizontal tab (RM A.10.6(5)).
  92
  93    procedure Load
  94      (File   : File_Type;
  95       Buf    : out String;
  96       Ptr    : in out Integer;
  97       Char   : Character;
  98       Loaded : out Boolean);
  99    --  If next character is Char, loads it, otherwise no characters are loaded
 100    --  Loaded is set to indicate whether or not the character was found.
 101
 102    procedure Load
 103      (File   : File_Type;
 104       Buf    : out String;
 105       Ptr    : in out Integer;
 106       Char   : Character);
 107    --  Same as above, but no indication if character is loaded
 108
 109    procedure Load
 110      (File   : File_Type;
 111       Buf    : out String;
 112       Ptr    : in out Integer;
 113       Char1  : Character;
 114       Char2  : Character;
 115       Loaded : out Boolean);
 116    --  If next character is Char1 or Char2, loads it, otherwise no characters
 117    --  are loaded. Loaded is set to indicate whether or not one of the two
 118    --  characters was found.
 119
 120    procedure Load
 121      (File   : File_Type;
 122       Buf    : out String;
 123       Ptr    : in out Integer;
 124       Char1  : Character;
 125       Char2  : Character);
 126    --  Same as above, but no indication if character is loaded
 127
 128    procedure Load_Digits
 129      (File   : File_Type;
 130       Buf    : out String;
 131       Ptr    : in out Integer;
 132       Loaded : out Boolean);
 133    --  Loads a sequence of zero or more decimal digits. Loaded is set if
 134    --  at least one digit is loaded.
 135
 136    procedure Load_Digits
 137      (File   : File_Type;
 138       Buf    : out String;
 139       Ptr    : in out Integer);
 140    --  Same as above, but no indication if character is loaded
 141
 142    procedure Load_Extended_Digits
 143      (File   : File_Type;
 144       Buf    : out String;
 145       Ptr    : in out Integer;
 146       Loaded : out Boolean);
 147    --  Like Load_Digits, but also allows extended digits a-f and A-F
 148
 149    procedure Load_Extended_Digits
 150      (File   : File_Type;
 151       Buf    : out String;
 152       Ptr    : in out Integer);
 153    --  Same as above, but no indication if character is loaded
 154
 155    procedure Put_Item (File : File_Type; Str : String);
 156    --  This routine is like Wide_Text_IO.Put, except that it checks for
 157    --  overflow of bounded lines, as described in (RM A.10.6(8)). It is used
 158    --  for all output of numeric values and of enumeration values. Note that
 159    --  the buffer is of type String. Put_Item deals with converting this to
 160    --  Wide_Characters as required.
 161
 162    procedure Store_Char
 163      (File : File_Type;
 164       ch   : Integer;
 165       Buf  : out String;
 166       Ptr  : in out Integer);
 167    --  Store a single character in buffer, checking for overflow and
 168    --  adjusting the column number in the file to reflect the fact
 169    --  that a character has been acquired from the input stream.
 170    --  The pos value of the character to store is in ch on entry.
 171
 172    procedure String_Skip (Str : String; Ptr : out Integer);
 173    --  Used in the Get from string procedures to skip leading blanks in the
 174    --  string. Ptr is set to the index of the first non-blank. If the string
 175    --  is all blanks, then the excption End_Error is raised, Note that blank
 176    --  is defined as a space or horizontal tab (RM A.10.6(5)).
 177
 178    procedure Ungetc (ch : Integer; File : File_Type);
 179    --  Pushes back character into stream, using ungetc. The caller has
 180    --  checked that the file is in read status. Device_Error is raised
 181    --  if the character cannot be pushed back. An attempt to push back
 182    --  an end of file (EOF) is ignored.
 183
 184 private
 185    pragma Inline (Is_Blank);
 186
 187 end Ada.Wide_Text_IO.Generic_Aux;