gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008, 2009 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 ACX_PROG_GNAT([-I"$srcdir"/ada])
 280
 281 # autoconf is lame and doesn't give us any substitution variable for this.
 282 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 283   NO_MINUS_C_MINUS_O=yes
 284 else
 285   OUTPUT_OPTION='-o $@'
 286 fi
 287 AC_SUBST(NO_MINUS_C_MINUS_O)
 288 AC_SUBST(OUTPUT_OPTION)
 289
 290 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 291 # optimizations to be activated explicitly by the toplevel.
 292 case "$CC" in
 293   */prev-gcc/xgcc*) ;;
 294   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 295 esac
 296 AC_SUBST(CFLAGS)
 297
 298 # -------------------------
 299 # Check C compiler features
 300 # -------------------------
 301
 302 AC_USE_SYSTEM_EXTENSIONS
 303 AC_PROG_CPP
 304 AC_C_INLINE
 305
 306 # sizeof(char) is 1 by definition.
 307 AC_CHECK_SIZEOF(void *)
 308 AC_CHECK_SIZEOF(short)
 309 AC_CHECK_SIZEOF(int)
 310 AC_CHECK_SIZEOF(long)
 311 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 312 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 313
 314 # ---------------------
 315 # Warnings and checking
 316 # ---------------------
 317
 318 # Check $CC warning features (if it's GCC).
 319 # We want to use -pedantic, but we don't want warnings about
 320 # * 'long long'
 321 # * variadic macros
 322 # * overlong strings
 323 # So, we only use -pedantic if we can disable those warnings.
 324
 325 ACX_PROG_CC_WARNING_OPTS(
 326         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wstrict-prototypes ],
 327                        [-Wmissing-prototypes -Wcast-qual])), [loose_warn])
 328 ACX_PROG_CC_WARNING_OPTS(
 329         m4_quote(m4_do([-Wold-style-definition -Wc++-compat ],
 330                        [-Wmissing-format-attribute])), [strict_warn])
 331 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 332         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 333                        [-Wno-overlength-strings])), [strict_warn])
 334 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 335
 336 # The above macros do nothing if the compiler is not GCC.  However, the
 337 # Makefile has more goo to add other flags, so this variabl is used to
 338 # enables warnings only for GCC.
 339 warn_cflags=
 340 if test "x$GCC" = "xyes"; then
 341   warn_cflags='$(GCC_WARN_CFLAGS)'
 342 fi
 343 AC_SUBST(warn_cflags)
 344
 345 # Enable expensive internal checks
 346 is_release=
 347 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 348   is_release=yes
 349 fi
 350
 351 AC_ARG_ENABLE(checking,
 352 [  --enable-checking[=LIST]
 353                           enable expensive run-time checks.  With LIST,
 354                           enable only specific categories of checks.
 355                           Categories are: yes,no,all,none,release.
 356                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
 357                           rtlflag,rtl,runtime,tree,valgrind,types.],
 358 [ac_checking_flags="${enableval}"],[
 359 # Determine the default checks.
 360 if test x$is_release = x ; then
 361   ac_checking_flags=yes
 362 else
 363   ac_checking_flags=release
 364 fi])
 365 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 366 for check in release $ac_checking_flags
 367 do
 368         case $check in
 369         # these set all the flags to specific states
 370         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 371                         ac_fold_checking= ; ac_gc_checking=1 ;
 372                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 373                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 374                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 375                         ac_types_checking=1 ;;
 376         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 377                         ac_fold_checking= ; ac_gc_checking= ;
 378                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 379                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 380                         ac_tree_checking= ; ac_valgrind_checking= ;
 381                         ac_types_checking= ;;
 382         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 383                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 384                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 385                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 386                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 387                         ac_types_checking=1 ;;
 388         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 389                         ac_fold_checking= ; ac_gc_checking= ;
 390                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 391                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 392                         ac_tree_checking= ; ac_valgrind_checking= ;
 393                         ac_types_checking= ;;
 394         # these enable particular checks
 395         assert)         ac_assert_checking=1 ;;
 396         df)             ac_df_checking=1 ;;
 397         fold)           ac_fold_checking=1 ;;
 398         gc)             ac_gc_checking=1 ;;
 399         gcac)           ac_gc_always_collect=1 ;;
 400         gimple)         ac_gimple_checking=1 ;;
 401         misc)           ac_checking=1 ;;
 402         rtl)            ac_rtl_checking=1 ;;
 403         rtlflag)        ac_rtlflag_checking=1 ;;
 404         runtime)        ac_runtime_checking=1 ;;
 405         tree)           ac_tree_checking=1 ;;
 406         types)          ac_types_checking=1 ;;
 407         valgrind)       ac_valgrind_checking=1 ;;
 408         *)      AC_MSG_ERROR(unknown check category $check) ;;
 409         esac
 410 done
 411 IFS="$ac_save_IFS"
 412
 413 nocommon_flag=""
 414 if test x$ac_checking != x ; then
 415   AC_DEFINE(ENABLE_CHECKING, 1,
 416 [Define if you want more run-time sanity checks.  This one gets a grab
 417    bag of miscellaneous but relatively cheap checks.])
 418   nocommon_flag=-fno-common
 419 fi
 420 AC_SUBST(nocommon_flag)
 421 if test x$ac_df_checking != x ; then
 422   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 423 [Define if you want more run-time sanity checks for dataflow.])
 424 fi
 425 if test x$ac_assert_checking != x ; then
 426   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 427 [Define if you want assertions enabled.  This is a cheap check.])
 428 fi
 429 if test x$ac_gimple_checking != x ; then
 430   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 431 [Define if you want operations on GIMPLE (the basic data structure of
 432 the high-level optimizers) to be checked for dynamic type safety at
 433 runtime.  This is moderately expensive.])
 434 fi
 435 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 436 if test x$ac_runtime_checking != x ; then
 437   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 438 [Define if you want runtime assertions enabled.  This is a cheap check.])
 439 fi
 440 if test x$ac_tree_checking != x ; then
 441   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 442 [Define if you want all operations on trees (the basic data
 443    structure of the front ends) to be checked for dynamic type safety
 444    at runtime.  This is moderately expensive.  The tree browser debugging
 445    routines will also be enabled by this option.
 446    ])
 447   TREEBROWSER=tree-browser.o
 448 fi
 449 if test x$ac_types_checking != x ; then
 450   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 451 [Define if you want all gimple types to be verified after gimplifiation.
 452    This is cheap.
 453    ])
 454 fi
 455 AC_SUBST(TREEBROWSER)
 456 if test x$ac_rtl_checking != x ; then
 457   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 458 [Define if you want all operations on RTL (the basic data structure
 459    of the optimizer and back end) to be checked for dynamic type safety
 460    at runtime.  This is quite expensive.])
 461 fi
 462 if test x$ac_rtlflag_checking != x ; then
 463   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 464 [Define if you want RTL flag accesses to be checked against the RTL
 465    codes that are supported for each access macro.  This is relatively
 466    cheap.])
 467 fi
 468 if test x$ac_gc_checking != x ; then
 469   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 470 [Define if you want the garbage collector to do object poisoning and
 471    other memory allocation checks.  This is quite expensive.])
 472 fi
 473 if test x$ac_gc_always_collect != x ; then
 474   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 475 [Define if you want the garbage collector to operate in maximally
 476    paranoid mode, validating the entire heap and collecting garbage at
 477    every opportunity.  This is extremely expensive.])
 478 fi
 479 if test x$ac_fold_checking != x ; then
 480   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 481 [Define if you want fold checked that it never destructs its argument.
 482    This is quite expensive.])
 483 fi
 484 valgrind_path_defines=
 485 valgrind_command=
 486
 487 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 488 dnl # an if statement.  This was the source of very frustrating bugs
 489 dnl # in converting to autoconf 2.5x!
 490 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 491
 492 if test x$ac_valgrind_checking != x ; then
 493   # It is certainly possible that there's valgrind but no valgrind.h.
 494   # GCC relies on making annotations so we must have both.
 495   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 496   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 497     [[#include <valgrind/memcheck.h>
 498 #ifndef VALGRIND_DISCARD
 499 #error VALGRIND_DISCARD not defined
 500 #endif]])],
 501   [gcc_cv_header_valgrind_memcheck_h=yes],
 502   [gcc_cv_header_valgrind_memcheck_h=no])
 503   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 504   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 505   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 506     [[#include <memcheck.h>
 507 #ifndef VALGRIND_DISCARD
 508 #error VALGRIND_DISCARD not defined
 509 #endif]])],
 510   [gcc_cv_header_memcheck_h=yes],
 511   [gcc_cv_header_memcheck_h=no])
 512   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 513   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 514         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 515   if test "x$valgrind_path" = "x" \
 516     || (test $have_valgrind_h = no \
 517         && test $gcc_cv_header_memcheck_h = no \
 518         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 519         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 520   fi
 521   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 522   valgrind_command="$valgrind_path -q"
 523   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 524 [Define if you want to run subprograms and generated programs
 525    through valgrind (a memory checker).  This is extremely expensive.])
 526   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 527     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 528         [Define if valgrind's valgrind/memcheck.h header is installed.])
 529   fi
 530   if test $gcc_cv_header_memcheck_h = yes; then
 531     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 532         [Define if valgrind's memcheck.h header is installed.])
 533   fi
 534 fi
 535 AC_SUBST(valgrind_path_defines)
 536 AC_SUBST(valgrind_command)
 537
 538 # Enable code coverage collection
 539 AC_ARG_ENABLE(coverage,
 540 [  --enable-coverage[=LEVEL]
 541                           enable compiler's code coverage collection.
 542                           Use to measure compiler performance and locate
 543                           unused parts of the compiler. With LEVEL, specify
 544                           optimization. Values are opt, noopt,
 545                           default is noopt],
 546 [case "${enableval}" in
 547   yes|noopt)
 548     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 549     ;;
 550   opt)
 551     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 552     ;;
 553   no)
 554     # a.k.a. --disable-coverage
 555     coverage_flags=""
 556     ;;
 557   *)
 558     AC_MSG_ERROR(unknown coverage setting $enableval)
 559     ;;
 560 esac],
 561 [coverage_flags=""])
 562 AC_SUBST(coverage_flags)
 563
 564 AC_ARG_ENABLE(gather-detailed-mem-stats,
 565 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 566 [enable_gather_detailed_mem_stats=no])
 567 if test x$enable_gather_detailed_mem_stats = xyes ; then
 568   AC_DEFINE(GATHER_STATISTICS, 1,
 569         [Define to enable detailed memory allocation stats gathering.])
 570 fi
 571
 572 # -------------------------------
 573 # Miscenalleous configure options
 574 # -------------------------------
 575
 576 # With stabs
 577 AC_ARG_WITH(stabs,
 578 [  --with-stabs            arrange to use stabs instead of host debug format],
 579 stabs="$with_stabs",
 580 stabs=no)
 581
 582 # Determine whether or not multilibs are enabled.
 583 AC_ARG_ENABLE(multilib,
 584 [  --enable-multilib       enable library support for multiple ABIs],
 585 [], [enable_multilib=yes])
 586 AC_SUBST(enable_multilib)
 587
 588 # Enable __cxa_atexit for C++.
 589 AC_ARG_ENABLE(__cxa_atexit,
 590 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 591 [], [])
 592
 593 # Enable C extension for decimal float if target supports it.
 594 AC_ARG_ENABLE(decimal-float,
 595 [  --enable-decimal-float={no,yes,bid,dpd}
 596                         enable decimal float extension to C.  Selecting 'bid'
 597                         or 'dpd' choses which decimal floating point format
 598                         to use],
 599 [
 600   case $enable_decimal_float in
 601     yes | no | bid | dpd) ;;
 602     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 603 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 604   esac
 605 ],
 606 [
 607   case $target in
 608     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 609       enable_decimal_float=yes
 610       ;;
 611     *)
 612       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 613       enable_decimal_float=no
 614       ;;
 615   esac
 616 ])
 617
 618 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 619 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 620 [Define to 1 to enable decimal float extension to C.])
 621
 622 # x86's use BID format instead of DPD
 623 case x$enable_decimal_float in
 624   xyes)
 625     case $target in
 626       i?86*-*-linux* | x86_64*-*-linux*)
 627         enable_decimal_float=bid
 628         ;;
 629       *)
 630         enable_decimal_float=dpd
 631         ;;
 632     esac
 633     ;;
 634   xno)
 635     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 636     # dependency on libdecnumber.
 637     enable_decimal_float=dpd
 638     ;;
 639 esac
 640 AC_SUBST(enable_decimal_float)
 641
 642 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 643 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 644 [Define to 1 to specify that we are using the BID decimal floating
 645 point format instead of DPD])
 646
 647 # Enable C extension for fixed-point arithmetic.
 648 AC_ARG_ENABLE(fixed-point,
 649 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 650 [
 651 ],
 652 [
 653   case $target in
 654     mips*-*-*)
 655       case $host in
 656         mips*-sgi-irix*)
 657           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 658           enable_fixed_point=no
 659           ;;
 660         *)
 661           enable_fixed_point=yes
 662           ;;
 663       esac
 664       ;;
 665     *)
 666       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 667       enable_fixed_point=no
 668       ;;
 669   esac
 670 ])
 671 AC_SUBST(enable_fixed_point)
 672
 673 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 674 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 675 [Define to 1 to enable fixed-point arithmetic extension to C.])
 676
 677 # Enable threads
 678 # Pass with no value to take the default
 679 # Pass with a value to specify a thread package
 680 AC_ARG_ENABLE(threads,
 681 [  --enable-threads        enable thread usage for target GCC
 682   --enable-threads=LIB    use LIB thread package for target GCC],,
 683 [enable_threads=''])
 684
 685 AC_ARG_ENABLE(tls,
 686 [  --enable-tls            enable or disable generation of tls code
 687                           overriding the assembler check for tls support],
 688 [
 689   case $enable_tls in
 690     yes | no) ;;
 691     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 692 Valid choices are 'yes' and 'no'.]) ;;
 693   esac
 694 ], [enable_tls=''])
 695
 696 AC_ARG_ENABLE(objc-gc,
 697 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 698                           the GNU Objective-C runtime],
 699 if test x$enable_objc_gc = xno; then
 700         objc_boehm_gc=''
 701 else
 702         objc_boehm_gc=1
 703 fi,
 704 objc_boehm_gc='')
 705
 706 AC_ARG_WITH(dwarf2,
 707 [  --with-dwarf2           force the default debug format to be DWARF 2],
 708 dwarf2="$with_dwarf2",
 709 dwarf2=no)
 710
 711 AC_ARG_ENABLE(shared,
 712 [  --disable-shared        don't provide a shared libgcc],
 713 [
 714   case $enable_shared in
 715   yes | no) ;;
 716   *)
 717     enable_shared=no
 718     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 719     for pkg in $enableval; do
 720       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 721         enable_shared=yes
 722       fi
 723     done
 724     IFS="$ac_save_ifs"
 725     ;;
 726   esac
 727 ], [enable_shared=yes])
 728 AC_SUBST(enable_shared)
 729
 730 AC_ARG_WITH(build-sysroot,
 731   [  --with-build-sysroot=sysroot
 732                           use sysroot as the system root during the build])
 733
 734 AC_ARG_WITH(sysroot,
 735 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 736 [
 737  case ${with_sysroot} in
 738  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 739  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 740  esac
 741
 742  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 743  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 744
 745  if test "x$prefix" = xNONE; then
 746   test_prefix=/usr/local
 747  else
 748   test_prefix=$prefix
 749  fi
 750  if test "x$exec_prefix" = xNONE; then
 751   test_exec_prefix=$test_prefix
 752  else
 753   test_exec_prefix=$exec_prefix
 754  fi
 755  case ${TARGET_SYSTEM_ROOT} in
 756  "${test_prefix}"|"${test_prefix}/"*|\
 757  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 758  '${prefix}'|'${prefix}/'*|\
 759  '${exec_prefix}'|'${exec_prefix}/'*)
 760    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 761    TARGET_SYSTEM_ROOT_DEFINE="$t"
 762    ;;
 763  esac
 764 ], [
 765  TARGET_SYSTEM_ROOT=
 766  TARGET_SYSTEM_ROOT_DEFINE=
 767  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 768 ])
 769 AC_SUBST(TARGET_SYSTEM_ROOT)
 770 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 771 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 772
 773 # Build with intermodule optimisations
 774 AC_ARG_ENABLE(intermodule,
 775 [  --enable-intermodule    build the compiler in one step],
 776 [case ${enable_intermodule} in
 777   yes) onestep="-onestep";;
 778   *) onestep="";;
 779 esac],
 780 [onestep=""])
 781 AC_SUBST(onestep)
 782
 783 ACX_PKGVERSION([GCC])
 784 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 785
 786 # Sanity check enable_languages in case someone does not run the toplevel
 787 # configure # script.
 788 AC_ARG_ENABLE(languages,
 789 [  --enable-languages=LIST specify which front-ends to build],
 790 [case ,${enable_languages}, in
 791        ,,|,yes,)
 792                 # go safe -- we cannot be much sure without the toplevel
 793                 # configure's
 794                 # analysis of which target libs are present and usable
 795                 enable_languages=c
 796                 ;;
 797          *,all,*)
 798                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 799                 ;;
 800         *,c,*)
 801                 ;;
 802         *)
 803                 enable_languages=c,${enable_languages}
 804                 ;;
 805 esac],
 806 [enable_languages=c])
 807
 808 # Used by documentation targets
 809 AC_SUBST(datarootdir)
 810 AC_SUBST(docdir)
 811 AC_SUBST(htmldir)
 812
 813 AC_ARG_WITH(multilib-list,
 814 [  --with-multilib-list    Select multilibs (SH only)],
 815 :,
 816 with_multilib_list=default)
 817
 818 # -------------------------
 819 # Checks for other programs
 820 # -------------------------
 821
 822 AC_PROG_MAKE_SET
 823
 824 # Find some useful tools
 825 AC_PROG_AWK
 826 # We need awk to create options.c and options.h.
 827 # Bail out if it's missing.
 828 case ${AWK} in
 829   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 830 esac
 831
 832 gcc_AC_PROG_LN_S
 833 ACX_PROG_LN($LN_S)
 834 AC_PROG_RANLIB
 835 case "${host}" in
 836 *-*-darwin*)
 837   # By default, the Darwin ranlib will not treat common symbols as
 838   # definitions when  building the archive table of contents.  Other
 839   # ranlibs do that; pass an option to the Darwin ranlib that makes
 840   # it behave similarly.
 841   ranlib_flags="-c"
 842   ;;
 843 *)
 844   ranlib_flags=""
 845 esac
 846 AC_SUBST(ranlib_flags)
 847
 848 gcc_AC_PROG_INSTALL
 849
 850 # See if cmp has --ignore-initial.
 851 gcc_AC_PROG_CMP_IGNORE_INITIAL
 852
 853 # See if we have the mktemp command.
 854 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 855
 856 # See if makeinfo has been installed and is modern enough
 857 # that we can use it.
 858 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 859   [GNU texinfo.* \([0-9][0-9.]*\)],
 860   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 861 if test $gcc_cv_prog_makeinfo_modern = no; then
 862   AC_MSG_WARN([
 863 *** Makeinfo is missing or too old.
 864 *** Info documentation will not be built.])
 865   BUILD_INFO=
 866 else
 867   BUILD_INFO=info
 868 fi
 869 AC_SUBST(BUILD_INFO)
 870
 871 # Is pod2man recent enough to regenerate manpages?
 872 AC_MSG_CHECKING([for recent Pod::Man])
 873 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 874   AC_MSG_RESULT(yes)
 875   GENERATED_MANPAGES=generated-manpages
 876 else
 877   AC_MSG_RESULT(no)
 878   GENERATED_MANPAGES=
 879 fi
 880 AC_SUBST(GENERATED_MANPAGES)
 881
 882 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 883
 884 # How about lex?
 885 dnl Don't use AC_PROG_LEX; we insist on flex.
 886 dnl LEXLIB is not useful in gcc.
 887 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 888
 889 # Bison?
 890 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 891
 892 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 893 # check for build == host before using them.
 894
 895 # NM
 896 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 897   && test -d ../binutils ; then
 898   NM='$(objdir)/../binutils/nm-new'
 899 else
 900   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 901 fi
 902
 903 # AR
 904 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 905   && test -d ../binutils ; then
 906   AR='$(objdir)/../binutils/ar'
 907 else
 908   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 909 fi
 910
 911
 912 # --------------------
 913 # Checks for C headers
 914 # --------------------
 915
 916 # Need to reject headers which give warnings, so that the -Werror bootstrap
 917 # works later. *sigh*  This needs to come before all header checks.
 918 AC_PROG_CPP_WERROR
 919
 920 AC_HEADER_STDC
 921 AC_HEADER_TIME
 922 ACX_HEADER_STRING
 923 AC_HEADER_SYS_WAIT
 924 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 925                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 926                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 927                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 928
 929 # Check for thread headers.
 930 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 931 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 932
 933 # These tests can't be done till we know if we have limits.h.
 934 gcc_AC_C_CHAR_BIT
 935 AC_C_BIGENDIAN
 936
 937 # --------
 938 # UNSORTED
 939 # --------
 940
 941
 942 # These libraries may be used by collect2.
 943 # We may need a special search path to get them linked.
 944 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 945 [save_LIBS="$LIBS"
 946 for libs in '' -lld -lmld \
 947                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 948                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 949 do
 950         LIBS="$libs"
 951         AC_TRY_LINK_FUNC(ldopen,
 952                 [gcc_cv_collect2_libs="$libs"; break])
 953 done
 954 LIBS="$save_LIBS"
 955 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 956 case $gcc_cv_collect2_libs in
 957         "none required")        ;;
 958         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 959 esac
 960 AC_SUBST(COLLECT2_LIBS)
 961
 962 # When building Ada code on Alpha, we need exc_resume which is usually in
 963 # -lexc.  So test for it.
 964 save_LIBS="$LIBS"
 965 LIBS=
 966 AC_SEARCH_LIBS(exc_resume, exc)
 967 GNAT_LIBEXC="$LIBS"
 968 LIBS="$save_LIBS"
 969 AC_SUBST(GNAT_LIBEXC)
 970
 971 # Some systems put ldexp and frexp in libm instead of libc; assume
 972 # they're both in the same place.  jcf-dump needs them.
 973 save_LIBS="$LIBS"
 974 LIBS=
 975 AC_SEARCH_LIBS(ldexp, m)
 976 LDEXP_LIB="$LIBS"
 977 LIBS="$save_LIBS"
 978 AC_SUBST(LDEXP_LIB)
 979
 980 # Use <inttypes.h> only if it exists,
 981 # doesn't clash with <sys/types.h>, and declares intmax_t.
 982 AC_MSG_CHECKING(for inttypes.h)
 983 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 984 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 985 [[#include <sys/types.h>
 986 #include <inttypes.h>]],
 987   [[intmax_t i = -1;]])],
 988   [gcc_cv_header_inttypes_h=yes],
 989   [gcc_cv_header_inttypes_h=no])])
 990 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 991 if test $gcc_cv_header_inttypes_h = yes; then
 992   AC_DEFINE(HAVE_INTTYPES_H, 1,
 993         [Define if you have a working <inttypes.h> header file.])
 994 fi
 995
 996 dnl Disabled until we have a complete test for buggy enum bitfields.
 997 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 998
 999 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1000   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1001   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1002   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1003   putchar_unlocked putc_unlocked)
1004 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1005         sysconf strsignal getrusage nl_langinfo \
1006         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1007         gcc_UNLOCKED_FUNCS)
1008
1009 if test x$ac_cv_func_mbstowcs = xyes; then
1010   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1011 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1012 int main()
1013 {
1014   mbstowcs(0, "", 0);
1015   return 0;
1016 }]])],
1017     [gcc_cv_func_mbstowcs_works=yes],
1018     [gcc_cv_func_mbstowcs_works=no],
1019     [gcc_cv_func_mbstowcs_works=yes])])
1020   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1021     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1022   [Define this macro if mbstowcs does not crash when its
1023    first argument is NULL.])
1024   fi
1025 fi
1026
1027 AC_CHECK_TYPE(ssize_t, int)
1028 AC_CHECK_TYPE(caddr_t, char *)
1029
1030 gcc_AC_FUNC_MMAP_BLACKLIST
1031
1032 case "${host}" in
1033 *-*-*vms*)
1034   # Under VMS, vfork works very differently than on Unix. The standard test
1035   # won't work, and it isn't easily adaptable. It makes more sense to
1036   # just force it.
1037   ac_cv_func_vfork_works=yes
1038   ;;
1039 esac
1040 AC_FUNC_FORK
1041
1042 AM_ICONV
1043 # Until we have in-tree GNU iconv:
1044 LIBICONV_DEP=
1045 AC_SUBST(LIBICONV_DEP)
1046
1047 AM_LC_MESSAGES
1048
1049 AM_LANGINFO_CODESET
1050
1051 # We will need to find libiberty.h and ansidecl.h
1052 saved_CFLAGS="$CFLAGS"
1053 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1054 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1055         strsignal strstr strverscmp \
1056         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1057         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1058 #include "ansidecl.h"
1059 #include "system.h"])
1060
1061 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1062 #include "ansidecl.h"
1063 #include "system.h"
1064 #ifdef HAVE_SYS_RESOURCE_H
1065 #include <sys/resource.h>
1066 #endif
1067 ])
1068
1069 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1070 #include "ansidecl.h"
1071 #include "system.h"
1072 #ifdef HAVE_SYS_RESOURCE_H
1073 #include <sys/resource.h>
1074 #endif
1075 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1076 [Define to `long' if <sys/resource.h> doesn't define.])])
1077
1078 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1079 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1080 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1081 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1082 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1083 #include "ansidecl.h"
1084 #include "system.h"
1085 #ifdef HAVE_LDFCN_H
1086 #undef FREAD
1087 #undef FWRITE
1088 #include <ldfcn.h>
1089 #endif
1090 ])
1091
1092 gcc_AC_CHECK_DECLS(times, , ,[
1093 #include "ansidecl.h"
1094 #include "system.h"
1095 #ifdef HAVE_SYS_TIMES_H
1096 #include <sys/times.h>
1097 #endif
1098 ])
1099
1100 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1101 #include "ansidecl.h"
1102 #include "system.h"
1103 #include <signal.h>
1104 ])
1105
1106 # More time-related stuff.
1107 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1108 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1109 #include "ansidecl.h"
1110 #include "system.h"
1111 #ifdef HAVE_SYS_TIMES_H
1112 #include <sys/times.h>
1113 #endif
1114 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1115 if test $ac_cv_struct_tms = yes; then
1116   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1117   [Define if <sys/times.h> defines struct tms.])
1118 fi
1119
1120 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1121 # revisit after autoconf 2.50.
1122 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1123 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1124 #include "ansidecl.h"
1125 #include "system.h"
1126 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1127 if test $gcc_cv_type_clock_t = yes; then
1128   AC_DEFINE(HAVE_CLOCK_T, 1,
1129   [Define if <time.h> defines clock_t.])
1130 fi
1131
1132 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1133 CFLAGS="$saved_CFLAGS"
1134
1135 gcc_AC_INITFINI_ARRAY
1136
1137 # mkdir takes a single argument on some systems.
1138 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1139
1140 # File extensions
1141 manext='.1'
1142 objext='.o'
1143 AC_SUBST(manext)
1144 AC_SUBST(objext)
1145
1146 # With Setjmp/Longjmp based exception handling.
1147 AC_ARG_ENABLE(sjlj-exceptions,
1148 [  --enable-sjlj-exceptions
1149                           arrange to use setjmp/longjmp exception handling],
1150 [case $target in
1151   *-*-hpux10*)
1152     if test $enableval != yes; then
1153       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1154       enableval=yes
1155     fi
1156     ;;
1157 esac
1158 force_sjlj_exceptions=yes],
1159 [case $target in
1160   *-*-hpux10*)
1161     force_sjlj_exceptions=yes
1162     enableval=yes
1163     ;;
1164   *)
1165     force_sjlj_exceptions=no
1166     ;;
1167 esac])
1168 if test $force_sjlj_exceptions = yes; then
1169   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1170   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1171     [Define 0/1 to force the choice for exception handling model.])
1172 fi
1173
1174 # For platforms with the unwind ABI which includes an unwind library,
1175 # libunwind, we can choose to use the system libunwind.
1176 # config.gcc also contains tests of with_system_libunwind.
1177 GCC_CHECK_UNWIND_GETIPINFO
1178
1179 # --------------------------------------------------------
1180 # Build, host, and target specific configuration fragments
1181 # --------------------------------------------------------
1182
1183 # Collect build-machine-specific information.
1184 . ${srcdir}/config.build
1185
1186 # Collect host-machine-specific information.
1187 . ${srcdir}/config.host
1188
1189 target_gtfiles=
1190
1191 # Collect target-machine-specific information.
1192 . ${srcdir}/config.gcc
1193
1194 extra_objs="${host_extra_objs} ${extra_objs}"
1195 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1196
1197 # Default the target-machine variables that were not explicitly set.
1198 if test x"$tm_file" = x
1199 then tm_file=$cpu_type/$cpu_type.h; fi
1200
1201 if test x"$extra_headers" = x
1202 then extra_headers=; fi
1203
1204 if test x$md_file = x
1205 then md_file=$cpu_type/$cpu_type.md; fi
1206
1207 if test x$out_file = x
1208 then out_file=$cpu_type/$cpu_type.c; fi
1209
1210 if test x"$tmake_file" = x
1211 then tmake_file=$cpu_type/t-$cpu_type
1212 fi
1213
1214 if test x"$dwarf2" = xyes
1215 then tm_file="$tm_file tm-dwarf2.h"
1216 fi
1217
1218 # Say what files are being used for the output code and MD file.
1219 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1220 echo "Using \`$srcdir/config/$md_file' as machine description file."
1221
1222 # If any of the xm_file variables contain nonexistent files, warn
1223 # about them and drop them.
1224
1225 bx=
1226 for x in $build_xm_file; do
1227   if    test -f $srcdir/config/$x
1228   then      bx="$bx $x"
1229   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1230   fi
1231 done
1232 build_xm_file="$bx"
1233
1234 hx=
1235 for x in $host_xm_file; do
1236   if    test -f $srcdir/config/$x
1237   then      hx="$hx $x"
1238   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1239   fi
1240 done
1241 host_xm_file="$hx"
1242
1243 tx=
1244 for x in $xm_file; do
1245   if    test -f $srcdir/config/$x
1246   then      tx="$tx $x"
1247   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1248   fi
1249 done
1250 xm_file="$tx"
1251
1252 count=a
1253 for f in $tm_file; do
1254         count=${count}x
1255 done
1256 if test $count = ax; then
1257         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1258 else
1259         echo "Using the following target machine macro files:"
1260         for f in $tm_file; do
1261                 echo "  $srcdir/config/$f"
1262         done
1263 fi
1264
1265 if test x$need_64bit_hwint = xyes; then
1266         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1267 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1268 fi
1269
1270 if test x$use_long_long_for_widest_fast_int = xyes; then
1271         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1272 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1273 efficiently supported by the host hardware.])
1274 fi
1275
1276 count=a
1277 for f in $host_xm_file; do
1278         count=${count}x
1279 done
1280 if test $count = a; then
1281         :
1282 elif test $count = ax; then
1283         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1284 else
1285         echo "Using the following host machine macro files:"
1286         for f in $host_xm_file; do
1287                 echo "  $srcdir/config/$f"
1288         done
1289 fi
1290 echo "Using ${out_host_hook_obj} for host machine hooks."
1291
1292 if test "$host_xm_file" != "$build_xm_file"; then
1293         count=a
1294         for f in $build_xm_file; do
1295                 count=${count}x
1296         done
1297         if test $count = a; then
1298                 :
1299         elif test $count = ax; then
1300                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1301         else
1302                 echo "Using the following build machine macro files:"
1303                 for f in $build_xm_file; do
1304                         echo "  $srcdir/config/$f"
1305                 done
1306         fi
1307 fi
1308
1309 case ${host} in
1310   powerpc*-*-darwin*)
1311     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1312       gcc_cv_mcontext_underscores,
1313       AC_COMPILE_IFELSE([
1314 #include <sys/cdefs.h>
1315 #include <sys/signal.h>
1316 #include <ucontext.h>
1317 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1318 ],
1319         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1320       if test $gcc_cv_mcontext_underscores = yes; then
1321         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1322           [mcontext_t fields start with __])
1323       fi
1324     ;;
1325 esac
1326
1327 # ---------
1328 # Threading
1329 # ---------
1330
1331 # Check if a valid thread package
1332 case ${enable_threads} in
1333   "" | no)
1334     # No threads
1335     target_thread_file='single'
1336     ;;
1337   yes)
1338     # default
1339     target_thread_file='single'
1340     ;;
1341   aix | dce | gnat | irix | posix | posix95 | rtems | \
1342   single | solaris | vxworks | win32 | mipssde)
1343     target_thread_file=${enable_threads}
1344     ;;
1345   *)
1346     echo "${enable_threads} is an unknown thread package" 1>&2
1347     exit 1
1348     ;;
1349 esac
1350
1351 if test x${thread_file} = x; then
1352   # No thread file set by target-specific clauses in config.gcc,
1353   # so use file chosen by default logic above
1354   thread_file=${target_thread_file}
1355 fi
1356
1357 # Make gthr-default.h if we have a thread file.
1358 gthread_flags=
1359 if test $thread_file != single; then
1360   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1361   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1362     rm -f gthr-default.h-t
1363   else
1364     mv -f gthr-default.h-t gthr-default.h
1365   fi
1366   gthread_flags=-DHAVE_GTHR_DEFAULT
1367 fi
1368 AC_SUBST(gthread_flags)
1369
1370 # --------
1371 # UNSORTED
1372 # --------
1373
1374 use_cxa_atexit=no
1375 if test x$enable___cxa_atexit = xyes || \
1376    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1377   if test x$host = x$target; then
1378     case $host in
1379       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1380       # keyed to flag_use_cxa_atexit
1381       *-*-mingw32*)
1382         use_cxa_atexit=yes
1383         ;;
1384       *)
1385         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1386           [echo "__cxa_atexit can't be enabled on this target"])
1387         ;;
1388     esac
1389   else
1390     # We can't check for __cxa_atexit when building a cross, so assume
1391     # it is available
1392     use_cxa_atexit=yes
1393   fi
1394   if test x$use_cxa_atexit = xyes; then
1395     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1396       [Define if you want to use __cxa_atexit, rather than atexit, to
1397       register C++ destructors for local statics and global objects.
1398       This is essential for fully standards-compliant handling of
1399       destructors, but requires __cxa_atexit in libc.])
1400   fi
1401 fi
1402
1403 # Look for a file containing extra machine modes.
1404 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1405   extra_modes_file='$(srcdir)'/config/${extra_modes}
1406   AC_SUBST(extra_modes_file)
1407   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1408   [Define to the name of a file containing a list of extra machine modes
1409    for this architecture.])
1410 fi
1411
1412 # Convert extra_options into a form suitable for Makefile use.
1413 extra_opt_files=
1414 for f in $extra_options; do
1415   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1416 done
1417 AC_SUBST(extra_opt_files)
1418
1419 # auto-host.h is the file containing items generated by autoconf and is
1420 # the first file included by config.h.
1421 # If host=build, it is correct to have bconfig include auto-host.h
1422 # as well.  If host!=build, we are in error and need to do more
1423 # work to find out the build config parameters.
1424 if test x$host = x$build
1425 then
1426         build_auto=auto-host.h
1427 else
1428         # We create a subdir, then run autoconf in the subdir.
1429         # To prevent recursion we set host and build for the new
1430         # invocation of configure to the build for this invocation
1431         # of configure.
1432         tempdir=build.$$
1433         rm -rf $tempdir
1434         mkdir $tempdir
1435         cd $tempdir
1436         case ${srcdir} in
1437         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1438         *) realsrcdir=../${srcdir};;
1439         esac
1440         saved_CFLAGS="${CFLAGS}"
1441         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1442         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1443         ${realsrcdir}/configure \
1444                 --enable-languages=${enable_languages-all} \
1445                 --target=$target_alias --host=$build_alias --build=$build_alias
1446         CFLAGS="${saved_CFLAGS}"
1447
1448         # We just finished tests for the build machine, so rename
1449         # the file auto-build.h in the gcc directory.
1450         mv auto-host.h ../auto-build.h
1451         cd ..
1452         rm -rf $tempdir
1453         build_auto=auto-build.h
1454 fi
1455 AC_SUBST(build_subdir)
1456
1457 tm_file="${tm_file} defaults.h"
1458 tm_p_file="${tm_p_file} tm-preds.h"
1459 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1460 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1461 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1462 # put this back in temporarily.
1463 xm_file="auto-host.h ansidecl.h ${xm_file}"
1464
1465 # --------
1466 # UNSORTED
1467 # --------
1468
1469 changequote(,)dnl
1470 # Compile in configure arguments.
1471 if test -f configargs.h ; then
1472         # Being re-configured.
1473         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1474         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1475 else
1476         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1477 fi
1478
1479 # Double all backslashes and backslash all quotes to turn
1480 # gcc_config_arguments into a C string.
1481 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1482 $gcc_config_arguments
1483 EOF
1484 gcc_config_arguments_str=`cat conftest.out`
1485 rm -f conftest.out
1486
1487 cat > configargs.h <<EOF
1488 /* Generated automatically. */
1489 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1490 static const char thread_model[] = "$thread_file";
1491
1492 static const struct {
1493   const char *name, *value;
1494 } configure_default_options[] = $configure_default_options;
1495 EOF
1496 changequote([,])dnl
1497
1498 changequote(,)dnl
1499 gcc_BASEVER=`cat $srcdir/BASE-VER`
1500 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1501 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1502 if test -f $srcdir/REVISION ; then
1503         gcc_REVISION=`cat $srcdir/REVISION`
1504 else
1505         gcc_REVISION=""
1506 fi
1507 cat > plugin-version.h <<EOF
1508 #include "configargs.h"
1509
1510 static char basever[] = "$gcc_BASEVER";
1511 static char datestamp[] = "$gcc_DATESTAMP";
1512 static char devphase[] = "$gcc_DEVPHASE";
1513 static char revision[] = "$gcc_REVISION";
1514
1515 /* FIXME plugins: We should make the version information more precise.
1516    One way to do is to add a checksum. */
1517
1518 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1519                                                 devphase, revision,
1520                                                 configuration_arguments};
1521 EOF
1522 changequote([,])dnl
1523
1524 # Internationalization
1525 ZW_GNU_GETTEXT_SISTER_DIR
1526
1527 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1528 # -liconv on the link line twice.
1529 case "$LIBINTL" in *$LIBICONV*)
1530         LIBICONV= ;;
1531 esac
1532
1533 AC_ARG_ENABLE(secureplt,
1534 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1535 [], [])
1536
1537 AC_ARG_ENABLE(cld,
1538 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1539 [enable_cld=no])
1540
1541 # Windows32 Registry support for specifying GCC installation paths.
1542 AC_ARG_ENABLE(win32-registry,
1543 [  --disable-win32-registry
1544                           disable lookup of installation paths in the
1545                           Registry on Windows hosts
1546   --enable-win32-registry enable registry lookup (default)
1547   --enable-win32-registry=KEY
1548                           use KEY instead of GCC version as the last portion
1549                           of the registry key],,)
1550
1551 case $host_os in
1552   win32 | pe | cygwin* | mingw32* | uwin*)
1553     if test "x$enable_win32_registry" != xno; then
1554       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1555     fi
1556
1557     if test "x$enable_win32_registry" != xno; then
1558       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1559   [Define to 1 if installation paths should be looked up in the Windows
1560    Registry. Ignored on non-Windows hosts.])
1561
1562       if test "x$enable_win32_registry" != xyes \
1563          && test "x$enable_win32_registry" != x; then
1564         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1565   [Define to be the last component of the Windows registry key under which
1566    to look for installation paths.  The full key used will be
1567    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1568    The default is the GCC version number.])
1569       fi
1570     fi
1571   ;;
1572 esac
1573
1574 # Get an absolute path to the GCC top-level source directory
1575 holddir=`${PWDCMD-pwd}`
1576 cd $srcdir
1577 topdir=`${PWDCMD-pwd}`
1578 cd $holddir
1579
1580 # Conditionalize the makefile for this host machine.
1581 xmake_file=
1582 for f in ${host_xmake_file}
1583 do
1584         if test -f ${srcdir}/config/$f
1585         then
1586                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1587         fi
1588 done
1589
1590 # Conditionalize the makefile for this target machine.
1591 tmake_file_=
1592 for f in ${tmake_file}
1593 do
1594         if test -f ${srcdir}/config/$f
1595         then
1596                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1597         fi
1598 done
1599 tmake_file="${tmake_file_}"
1600
1601 out_object_file=`basename $out_file .c`.o
1602
1603 tm_file_list="options.h"
1604 tm_include_list="options.h"
1605 for f in $tm_file; do
1606   case $f in
1607     ./* )
1608        f=`echo $f | sed 's/^..//'`
1609        tm_file_list="${tm_file_list} $f"
1610        tm_include_list="${tm_include_list} $f"
1611        ;;
1612     defaults.h )
1613        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1614        tm_include_list="${tm_include_list} $f"
1615        ;;
1616     * )
1617        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1618        tm_include_list="${tm_include_list} config/$f"
1619        ;;
1620   esac
1621 done
1622
1623 tm_p_file_list=
1624 tm_p_include_list=
1625 for f in $tm_p_file; do
1626   case $f in
1627     tm-preds.h )
1628        tm_p_file_list="${tm_p_file_list} $f"
1629        tm_p_include_list="${tm_p_include_list} $f"
1630        ;;
1631     * )
1632        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1633        tm_p_include_list="${tm_p_include_list} config/$f"
1634   esac
1635 done
1636
1637 xm_file_list=
1638 xm_include_list=
1639 for f in $xm_file; do
1640   case $f in
1641     ansidecl.h )
1642        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1643        xm_include_list="${xm_include_list} $f"
1644        ;;
1645     auto-host.h )
1646        xm_file_list="${xm_file_list} $f"
1647        xm_include_list="${xm_include_list} $f"
1648        ;;
1649     * )
1650        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1651        xm_include_list="${xm_include_list} config/$f"
1652        ;;
1653   esac
1654 done
1655
1656 host_xm_file_list=
1657 host_xm_include_list=
1658 for f in $host_xm_file; do
1659   case $f in
1660     ansidecl.h )
1661        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1662        host_xm_include_list="${host_xm_include_list} $f"
1663        ;;
1664     auto-host.h )
1665        host_xm_file_list="${host_xm_file_list} $f"
1666        host_xm_include_list="${host_xm_include_list} $f"
1667        ;;
1668     * )
1669        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1670        host_xm_include_list="${host_xm_include_list} config/$f"
1671        ;;
1672   esac
1673 done
1674
1675 build_xm_file_list=
1676 for f in $build_xm_file; do
1677   case $f in
1678     ansidecl.h )
1679        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1680        build_xm_include_list="${build_xm_include_list} $f"
1681        ;;
1682     auto-build.h | auto-host.h )
1683        build_xm_file_list="${build_xm_file_list} $f"
1684        build_xm_include_list="${build_xm_include_list} $f"
1685        ;;
1686     * )
1687        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1688        build_xm_include_list="${build_xm_include_list} config/$f"
1689        ;;
1690   esac
1691 done
1692
1693 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1694 # cross-compiler which does not use the native headers and libraries.
1695 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1696 CROSS=                                          AC_SUBST(CROSS)
1697 ALL=all.internal                                AC_SUBST(ALL)
1698 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1699
1700 if test "x$with_build_sysroot" != x; then
1701   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1702 else
1703   # This value is used, even on a native system, because
1704   # CROSS_SYSTEM_HEADER_DIR is just
1705   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1706   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1707 fi
1708
1709 if test x$host != x$target
1710 then
1711         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1712         ALL=all.cross
1713         SYSTEM_HEADER_DIR=$build_system_header_dir
1714         case "$host","$target" in
1715         # Darwin crosses can use the host system's libraries and headers,
1716         # because of the fat library support.  Of course, it must be the
1717         # same version of Darwin on both sides.  Allow the user to
1718         # just say --target=foo-darwin without a version number to mean
1719         # "the version on this system".
1720             *-*-darwin*,*-*-darwin*)
1721                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1722                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1723                 if test $hostos = $targetos -o $targetos = darwin ; then
1724                     CROSS=
1725                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1726                     with_headers=yes
1727                 fi
1728                 ;;
1729
1730             i?86-*-*,x86_64-*-* \
1731             | powerpc*-*-*,powerpc64*-*-*)
1732                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1733         esac
1734 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1735         SYSTEM_HEADER_DIR=$build_system_header_dir
1736 fi
1737
1738 # If this is a cross-compiler that does not
1739 # have its own set of headers then define
1740 # inhibit_libc
1741
1742 # If this is using newlib, without having the headers available now,
1743 # then define inhibit_libc in LIBGCC2_CFLAGS.
1744 # This prevents libgcc2 from containing any code which requires libc
1745 # support.
1746 : ${inhibit_libc=false}
1747 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1748        test x$with_newlib = xyes ; } &&
1749      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1750        inhibit_libc=true
1751 fi
1752 AC_SUBST(inhibit_libc)
1753
1754 # When building gcc with a cross-compiler, we need to adjust things so
1755 # that the generator programs are still built with the native compiler.
1756 # Also, we cannot run fixincludes.
1757
1758 # These are the normal (build=host) settings:
1759 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1760 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1761 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1762 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1763
1764 # And these apply if build != host, or we are generating coverage data
1765 if test x$build != x$host || test "x$coverage_flags" != x
1766 then
1767     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1768     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1769 fi
1770
1771 # Expand extra_headers to include complete path.
1772 # This substitutes for lots of t-* files.
1773 extra_headers_list=
1774 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1775 for file in ${extra_headers} ; do
1776   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1777 done
1778
1779 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1780 if test x"$use_gcc_tgmath" = xyes
1781 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1782 fi
1783
1784 # Define collect2 in Makefile.
1785 case $host_can_use_collect2 in
1786   no) collect2= ;;
1787   *) collect2='collect2$(exeext)' ;;
1788 esac
1789 AC_SUBST([collect2])
1790
1791 # Add a definition of USE_COLLECT2 if system wants one.
1792 case $use_collect2 in
1793   no) use_collect2= ;;
1794   "") ;;
1795   *)
1796     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1797     xm_defines="${xm_defines} USE_COLLECT2"
1798     case $host_can_use_collect2 in
1799       no)
1800         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1801         ;;
1802     esac
1803     ;;
1804 esac
1805
1806 # ---------------------------
1807 # Assembler & linker features
1808 # ---------------------------
1809
1810 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1811 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1812 # However when ld-new is first executed from the build tree, libtool will
1813 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1814 # to the build tree.  While doing this we need to use the previous-stage
1815 # linker, or we have an infinite loop.  The presence of a shell script as
1816 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1817 # the gcc/collect-ld script.  So we need to know how libtool works, or
1818 # exec-tool will fail.
1819
1820 m4_defun([_LT_CONFIG_COMMANDS], [])
1821 AC_PROG_LIBTOOL
1822 AC_SUBST(objdir)
1823 AC_SUBST(enable_fast_install)
1824
1825 # Identify the assembler which will work hand-in-glove with the newly
1826 # built GCC, so that we can examine its features.  This is the assembler
1827 # which will be driven by the driver program.
1828 #
1829 # If build != host, and we aren't building gas in-tree, we identify a
1830 # build->target assembler and hope that it will have the same features
1831 # as the host->target assembler we'll be using.
1832 gcc_cv_gas_major_version=
1833 gcc_cv_gas_minor_version=
1834 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1835
1836 m4_pattern_allow([AS_FOR_TARGET])dnl
1837 AS_VAR_SET_IF(gcc_cv_as,, [
1838 if test -x "$DEFAULT_ASSEMBLER"; then
1839         gcc_cv_as="$DEFAULT_ASSEMBLER"
1840 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1841      && test -f ../gas/Makefile \
1842      && test x$build = x$host; then
1843         gcc_cv_as=../gas/as-new$build_exeext
1844 elif test -x as$build_exeext; then
1845         # Build using assembler in the current directory.
1846         gcc_cv_as=./as$build_exeext
1847 elif test -x $AS_FOR_TARGET; then
1848         gcc_cv_as="$AS_FOR_TARGET"
1849 else
1850         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1851 fi])
1852
1853 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1854 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1855 case "$ORIGINAL_AS_FOR_TARGET" in
1856   ./as | ./as$build_exeext) ;;
1857   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1858 esac
1859
1860 AC_MSG_CHECKING(what assembler to use)
1861 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1862   # Single tree build which includes gas.  We want to prefer it
1863   # over whatever linker top-level may have detected, since
1864   # we'll use what we're building after installation anyway.
1865   AC_MSG_RESULT(newly built gas)
1866   in_tree_gas=yes
1867   _gcc_COMPUTE_GAS_VERSION
1868   in_tree_gas_is_elf=no
1869   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1870      || (grep 'obj_format = multi' ../gas/Makefile \
1871          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1872   then
1873     in_tree_gas_is_elf=yes
1874   fi
1875 else
1876   AC_MSG_RESULT($gcc_cv_as)
1877   in_tree_gas=no
1878 fi
1879
1880 # Identify the linker which will work hand-in-glove with the newly
1881 # built GCC, so that we can examine its features.  This is the linker
1882 # which will be driven by the driver program.
1883 #
1884 # If build != host, and we aren't building gas in-tree, we identify a
1885 # build->target linker and hope that it will have the same features
1886 # as the host->target linker we'll be using.
1887 gcc_cv_gld_major_version=
1888 gcc_cv_gld_minor_version=
1889 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1890 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1891
1892 AS_VAR_SET_IF(gcc_cv_ld,, [
1893 if test -x "$DEFAULT_LINKER"; then
1894         gcc_cv_ld="$DEFAULT_LINKER"
1895 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1896      && test -f ../ld/Makefile \
1897      && test x$build = x$host; then
1898         gcc_cv_ld=../ld/ld-new$build_exeext
1899 elif test -x collect-ld$build_exeext; then
1900         # Build using linker in the current directory.
1901         gcc_cv_ld=./collect-ld$build_exeext
1902 elif test -x $LD_FOR_TARGET; then
1903         gcc_cv_ld="$LD_FOR_TARGET"
1904 else
1905         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1906 fi])
1907
1908 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1909 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1910 case "$ORIGINAL_LD_FOR_TARGET" in
1911   ./collect-ld | ./collect-ld$build_exeext) ;;
1912   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1913 esac
1914
1915 AC_MSG_CHECKING(what linker to use)
1916 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1917         # Single tree build which includes ld.  We want to prefer it
1918         # over whatever linker top-level may have detected, since
1919         # we'll use what we're building after installation anyway.
1920         AC_MSG_RESULT(newly built ld)
1921         in_tree_ld=yes
1922         in_tree_ld_is_elf=no
1923         if (grep 'EMUL = .*elf' ../ld/Makefile \
1924             || grep 'EMUL = .*linux' ../ld/Makefile \
1925             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1926           in_tree_ld_is_elf=yes
1927         fi
1928         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1929         do
1930 changequote(,)dnl
1931                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1932                 if test x$gcc_cv_gld_version != x; then
1933                         break
1934                 fi
1935         done
1936         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1937         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1938 changequote([,])dnl
1939 else
1940         AC_MSG_RESULT($gcc_cv_ld)
1941         in_tree_ld=no
1942 fi
1943
1944 # Figure out what nm we will be using.
1945 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1946 AS_VAR_SET_IF(gcc_cv_nm,, [
1947 if test -f $gcc_cv_binutils_srcdir/configure.in \
1948      && test -f ../binutils/Makefile \
1949      && test x$build = x$host; then
1950         gcc_cv_nm=../binutils/nm-new$build_exeext
1951 elif test -x nm$build_exeext; then
1952         gcc_cv_nm=./nm$build_exeext
1953 elif test -x $NM_FOR_TARGET; then
1954         gcc_cv_nm="$NM_FOR_TARGET"
1955 else
1956         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1957 fi])
1958
1959 AC_MSG_CHECKING(what nm to use)
1960 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1961         # Single tree build which includes binutils.
1962         AC_MSG_RESULT(newly built nm)
1963         in_tree_nm=yes
1964 else
1965         AC_MSG_RESULT($gcc_cv_nm)
1966         in_tree_nm=no
1967 fi
1968
1969 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1970 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1971 case "$ORIGINAL_NM_FOR_TARGET" in
1972   ./nm | ./nm$build_exeext) ;;
1973   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1974 esac
1975
1976
1977 # Figure out what objdump we will be using.
1978 AS_VAR_SET_IF(gcc_cv_objdump,, [
1979 if test -f $gcc_cv_binutils_srcdir/configure.in \
1980      && test -f ../binutils/Makefile \
1981      && test x$build = x$host; then
1982         # Single tree build which includes binutils.
1983         gcc_cv_objdump=../binutils/objdump$build_exeext
1984 elif test -x objdump$build_exeext; then
1985         gcc_cv_objdump=./objdump$build_exeext
1986 elif test -x $OBJDUMP_FOR_TARGET; then
1987         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
1988 else
1989         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
1990 fi])
1991
1992 AC_MSG_CHECKING(what objdump to use)
1993 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
1994         # Single tree build which includes binutils.
1995         AC_MSG_RESULT(newly built objdump)
1996 elif test x$gcc_cv_objdump = x; then
1997         AC_MSG_RESULT(not found)
1998 else
1999         AC_MSG_RESULT($gcc_cv_objdump)
2000 fi
2001
2002 # Figure out what readelf we will be using.
2003 AS_VAR_SET_IF(gcc_cv_readelf,, [
2004 if test -f $gcc_cv_binutils_srcdir/configure.in \
2005      && test -f ../binutils/Makefile \
2006      && test x$build = x$host; then
2007         # Single tree build which includes binutils.
2008         gcc_cv_readelf=../binutils/readelf$build_exeext
2009 elif test -x readelf$build_exeext; then
2010         gcc_cv_readelf=./readelf$build_exeext
2011 else
2012         AC_PATH_PROG(gcc_cv_readelf, readelf)
2013 fi])
2014
2015 AC_MSG_CHECKING(what readelf to use)
2016 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2017         # Single tree build which includes binutils.
2018         AC_MSG_RESULT(newly built readelf)
2019 elif test x$gcc_cv_readelf = x; then
2020         AC_MSG_RESULT(not found)
2021 else
2022         AC_MSG_RESULT($gcc_cv_readelf)
2023 fi
2024
2025 # Figure out what assembler alignment features are present.
2026 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2027  [2,6,0],,
2028 [.balign 4
2029 .p2align 2],,
2030 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2031   [Define if your assembler supports .balign and .p2align.])])
2032
2033 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2034  [2,8,0],,
2035  [.p2align 4,,7],,
2036 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2037   [Define if your assembler supports specifying the maximum number
2038    of bytes to skip when using the GAS .p2align command.])])
2039
2040 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2041  [2,8,0],,
2042  [.literal16],,
2043 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2044   [Define if your assembler supports .literal16.])])
2045
2046 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2047  [elf,2,9,0],,
2048  [conftest_label1: .word 0
2049 .subsection -1
2050 conftest_label2: .word 0
2051 .previous],
2052  [if test x$gcc_cv_nm != x; then
2053     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2054     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2055     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2056     then :
2057     else gcc_cv_as_subsection_m1=yes
2058     fi
2059     rm -f conftest.nm1 conftest.nm2
2060   fi],
2061  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2062   [Define if your assembler supports .subsection and .subsection -1 starts
2063    emitting at the beginning of your section.])])
2064
2065 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2066  [2,2,0],,
2067  [      .weak foobar],,
2068 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2069
2070 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2071  [2,17,0],,
2072  [      .weakref foobar, barfnot],,
2073 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2074
2075 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2076  [2,15,91],,
2077  [      .SPACE $TEXT$
2078         .NSUBSPA $CODE$,COMDAT],,
2079 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2080
2081 # .hidden needs to be supported in both the assembler and the linker,
2082 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2083 # This is irritatingly difficult to feature test for; we have to check the
2084 # date string after the version number.  If we've got an in-tree
2085 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2086 # to be safe.
2087 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2088 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2089  [elf,2,13,0],,
2090 [       .hidden foobar
2091 foobar:])
2092
2093 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2094 [if test $in_tree_ld = yes ; then
2095   gcc_cv_ld_hidden=no
2096   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2097      && test $in_tree_ld_is_elf = yes; then
2098      gcc_cv_ld_hidden=yes
2099   fi
2100 else
2101 changequote(,)dnl
2102   gcc_cv_ld_hidden=yes
2103   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2104   if echo "$ld_ver" | grep GNU > /dev/null; then
2105     ld_vers=`echo $ld_ver | sed -n \
2106         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2107     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2108     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2109     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2110     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2111     if test 0"$ld_date" -lt 20020404; then
2112       if test -n "$ld_date"; then
2113         # If there was date string, but was earlier than 2002-04-04, fail
2114         gcc_cv_ld_hidden=no
2115       elif test -z "$ld_vers"; then
2116         # If there was no date string nor ld version number, something is wrong
2117         gcc_cv_ld_hidden=no
2118       else
2119         test -z "$ld_vers_patch" && ld_vers_patch=0
2120         if test "$ld_vers_major" -lt 2; then
2121           gcc_cv_ld_hidden=no
2122         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2123           gcc_cv_ld_hidden="no"
2124         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2125           gcc_cv_ld_hidden=no
2126         fi
2127       fi
2128     fi
2129   else
2130     case "${target}" in
2131       hppa64*-*-hpux* | ia64*-*-hpux*)
2132         gcc_cv_ld_hidden=yes
2133         ;;
2134       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2135         gcc_cv_ld_hidden=yes
2136         ;;
2137       *)
2138         gcc_cv_ld_hidden=no
2139         ;;
2140     esac
2141   fi
2142 changequote([,])dnl
2143 fi])
2144 libgcc_visibility=no
2145 AC_SUBST(libgcc_visibility)
2146 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2147 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2148   libgcc_visibility=yes
2149   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2150   [Define if your assembler and linker support .hidden.])
2151 fi
2152
2153 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2154 gcc_cv_ld_ro_rw_mix=unknown
2155 if test $in_tree_ld = yes ; then
2156   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2157      && test $in_tree_ld_is_elf = yes; then
2158     gcc_cv_ld_ro_rw_mix=read-write
2159   fi
2160 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2161   echo '.section myfoosect, "a"' > conftest1.s
2162   echo '.section myfoosect, "aw"' > conftest2.s
2163   echo '.byte 1' >> conftest2.s
2164   echo '.section myfoosect, "a"' > conftest3.s
2165   echo '.byte 0' >> conftest3.s
2166   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2167      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2168      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2169      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2170         conftest2.o conftest3.o > /dev/null 2>&1; then
2171     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2172                          | sed -e '/myfoosect/!d' -e N`
2173     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2174       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2175         gcc_cv_ld_ro_rw_mix=read-only
2176       else
2177         gcc_cv_ld_ro_rw_mix=read-write
2178       fi
2179     fi
2180   fi
2181 changequote(,)dnl
2182   rm -f conftest.* conftest[123].*
2183 changequote([,])dnl
2184 fi
2185 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2186         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2187   [Define if your linker links a mix of read-only
2188    and read-write sections into a read-write section.])
2189 fi
2190 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2191
2192 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2193 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2194   [elf,2,11,0],,
2195 [       .data
2196         .uleb128 L2 - L1
2197 L1:
2198         .uleb128 1280
2199         .sleb128 -1010
2200 L2:],
2201  [# GAS versions before 2.11 do not support uleb128,
2202   # despite appearing to.
2203   # ??? There exists an elf-specific test that will crash
2204   # the assembler.  Perhaps it's better to figure out whether
2205   # arbitrary sections are supported and try the test.
2206   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2207   if echo "$as_ver" | grep GNU > /dev/null; then
2208 changequote(,)dnl
2209     as_vers=`echo $as_ver | sed -n \
2210         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2211     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2212     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2213 changequote([,])dnl
2214     if test $as_major -eq 2 && test $as_minor -lt 11
2215     then :
2216     else gcc_cv_as_leb128=yes
2217     fi
2218   fi],
2219   [AC_DEFINE(HAVE_AS_LEB128, 1,
2220     [Define if your assembler supports .sleb128 and .uleb128.])])
2221
2222 # Check if we have assembler support for unwind directives.
2223 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2224   ,,
2225 [       .text
2226         .cfi_startproc
2227         .cfi_offset 0, 0
2228         .cfi_same_value 1
2229         .cfi_def_cfa 1, 2
2230         .cfi_escape 1, 2, 3, 4, 5
2231         .cfi_endproc],
2232 [case "$target" in
2233   *-*-solaris*)
2234     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2235     # read-only and read-write sections, we need to make sure that the
2236     # assembler used emits read-write .eh_frame sections.
2237     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2238       if test "x$gcc_cv_objdump" != x; then
2239         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2240                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2241           gcc_cv_as_cfi_directive=no
2242         else
2243           gcc_cv_as_cfi_directive=yes
2244         fi
2245       else
2246         # no objdump, err on the side of caution
2247         gcc_cv_as_cfi_directive=no
2248       fi
2249     else
2250       gcc_cv_as_cfi_directive=yes
2251     fi
2252     ;;
2253   *-*-*)
2254     gcc_cv_as_cfi_directive=yes
2255     ;;
2256 esac])
2257 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_readelf != x; then
2258 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2259   ,,
2260 [       .text
2261         .cfi_startproc
2262         .cfi_adjust_cfa_offset 64
2263         .skip 512, 0
2264         .cfi_adjust_cfa_offset 128
2265         .cfi_endproc],
2266 [
2267 changequote(,)dnl
2268 if $gcc_cv_readelf -wf conftest.o 2>/dev/null \
2269     | grep 'DW_CFA_advance_loc[12]:[    ][      ]*512[  ]' >/dev/null; then
2270    gcc_cv_as_cfi_advance_working=yes
2271 fi
2272 changequote([,])dnl
2273 ])
2274 else
2275   # no readelf, err on the side of caution
2276   gcc_cv_as_cfi_advance_working=no
2277 fi
2278 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2279   [`if test $gcc_cv_as_cfi_directive = yes \
2280        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2281   [Define 0/1 if your assembler supports CFI directives.])
2282
2283 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2284   gcc_cv_as_cfi_personality_directive, ,,
2285 [       .text
2286         .cfi_startproc
2287         .cfi_personality 0, symbol
2288         .cfi_endproc])
2289 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2290   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2291     then echo 1; else echo 0; fi`],
2292   [Define 0/1 if your assembler supports .cfi_personality.])
2293
2294 # GAS versions up to and including 2.11.0 may mis-optimize
2295 # .eh_frame data.
2296 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2297   [elf,2,12,0],,
2298 [       .text
2299 .LFB1:
2300         .4byte  0
2301 .L1:
2302         .4byte  0
2303 .LFE1:
2304         .section        .eh_frame,"aw",@progbits
2305 __FRAME_BEGIN__:
2306         .4byte  .LECIE1-.LSCIE1
2307 .LSCIE1:
2308         .4byte  0x0
2309         .byte   0x1
2310         .ascii "z\0"
2311         .byte   0x1
2312         .byte   0x78
2313         .byte   0x1a
2314         .byte   0x0
2315         .byte   0x4
2316         .4byte  1
2317         .p2align 1
2318 .LECIE1:
2319 .LSFDE1:
2320         .4byte  .LEFDE1-.LASFDE1
2321 .LASFDE1:
2322         .4byte  .LASFDE1-__FRAME_BEGIN__
2323         .4byte  .LFB1
2324         .4byte  .LFE1-.LFB1
2325         .byte   0x4
2326         .4byte  .LFE1-.LFB1
2327         .byte   0x4
2328         .4byte  .L1-.LFB1
2329 .LEFDE1:],
2330 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2331 cat > conftest.lit <<EOF
2332  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2333  0010 01000000 12000000 18000000 00000000  ................
2334  0020 08000000 04080000 0044               .........D      @&t@
2335 EOF
2336 cat > conftest.big <<EOF
2337  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2338  0010 00000001 00000012 00000018 00000000  ................
2339  0020 00000008 04000000 0844               .........D      @&t@
2340 EOF
2341   # If the assembler didn't choke, and we can objdump,
2342   # and we got the correct data, then succeed.
2343   # The text in the here-document typically retains its unix-style line
2344   # endings, while the output of objdump will use host line endings.
2345   # Therefore, use diff -b for the comparisons.
2346   if test x$gcc_cv_objdump != x \
2347   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2348      | tail -3 > conftest.got \
2349   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2350     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2351   then
2352     gcc_cv_as_eh_frame=yes
2353   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2354     gcc_cv_as_eh_frame=buggy
2355   else
2356     # Uh oh, what do we do now?
2357     gcc_cv_as_eh_frame=no
2358   fi])
2359
2360 if test $gcc_cv_as_eh_frame = buggy; then
2361   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2362   [Define if your assembler mis-optimizes .eh_frame data.])
2363 fi
2364
2365 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2366  [elf,2,12,0], [--fatal-warnings],
2367  [.section .rodata.str, "aMS", @progbits, 1])
2368 if test $gcc_cv_as_shf_merge = no; then
2369   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2370     [elf,2,12,0], [--fatal-warnings],
2371     [.section .rodata.str, "aMS", %progbits, 1])
2372 fi
2373 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2374   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2375 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2376
2377 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2378  [elf,2,16,0], [--fatal-warnings],
2379  [.section .text,"axG",@progbits,.foo,comdat])
2380 if test $gcc_cv_as_comdat_group = yes; then
2381   gcc_cv_as_comdat_group_percent=no
2382 else
2383  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2384    [elf,2,16,0], [--fatal-warnings],
2385    [.section .text,"axG",%progbits,.foo,comdat])
2386 fi
2387 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2388   comdat_group=yes
2389   if test 0"$ld_date" -lt 20050308; then
2390     if test -n "$ld_date"; then
2391       # If there was date string, but was earlier than 2005-03-08, fail
2392       comdat_group=no
2393     elif test "$ld_vers_major" -lt 2; then
2394       comdat_group=no
2395     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2396       comdat_group=no
2397     fi
2398   fi
2399 else
2400   # assume linkers other than GNU ld don't support COMDAT group
2401   comdat_group=no
2402 fi
2403 if test $comdat_group = no; then
2404   gcc_cv_as_comdat_group=no
2405   gcc_cv_as_comdat_group_percent=no
2406 fi
2407 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2408   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2409 [Define 0/1 if your assembler and linker support COMDAT groups.])
2410
2411 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2412  gcc_cv_as_discriminator,
2413  [2,19,51],,
2414 [       .text
2415         .file 1 "conf.c"
2416         .loc 1 1 0 discriminator 1],,
2417 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2418   [Define if your assembler supports the .loc discriminator sub-directive.])])
2419
2420 # Thread-local storage - the check is heavily parameterized.
2421 conftest_s=
2422 tls_first_major=
2423 tls_first_minor=
2424 tls_as_opt=
2425 case "$target" in
2426 changequote(,)dnl
2427   alpha*-*-*)
2428     conftest_s='
2429         .section ".tdata","awT",@progbits
2430 foo:    .long   25
2431         .text
2432         ldq     $27,__tls_get_addr($29)         !literal!1
2433         lda     $16,foo($29)                    !tlsgd!1
2434         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2435         ldq     $27,__tls_get_addr($29)         !literal!2
2436         lda     $16,foo($29)                    !tlsldm!2
2437         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2438         ldq     $1,foo($29)                     !gotdtprel
2439         ldah    $2,foo($29)                     !dtprelhi
2440         lda     $3,foo($2)                      !dtprello
2441         lda     $4,foo($29)                     !dtprel
2442         ldq     $1,foo($29)                     !gottprel
2443         ldah    $2,foo($29)                     !tprelhi
2444         lda     $3,foo($2)                      !tprello
2445         lda     $4,foo($29)                     !tprel'
2446         tls_first_major=2
2447         tls_first_minor=13
2448         tls_as_opt=--fatal-warnings
2449         ;;
2450   cris-*-*|crisv32-*-*)
2451     conftest_s='
2452         .section ".tdata","awT",@progbits
2453 x:      .long   25
2454         .text
2455         move.d x:IE,$r10
2456         nop'
2457         tls_first_major=2
2458         tls_first_minor=20
2459         tls_as_opt=--fatal-warnings
2460         ;;
2461   frv*-*-*)
2462     conftest_s='
2463         .section ".tdata","awT",@progbits
2464 x:      .long   25
2465         .text
2466         call    #gettlsoff(x)'
2467         tls_first_major=2
2468         tls_first_minor=14
2469         ;;
2470   hppa*-*-linux*)
2471     conftest_s='
2472 t1:     .reg    %r20
2473 t2:     .reg    %r21
2474 gp:     .reg    %r19
2475         .section ".tdata","awT",@progbits
2476 foo:    .long   25
2477         .text
2478         .align  4
2479         addil LT%foo-$tls_gdidx$,gp
2480         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2481         b __tls_get_addr
2482         nop
2483         addil LT%foo-$tls_ldidx$,gp
2484         b __tls_get_addr
2485         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2486         addil LR%foo-$tls_dtpoff$,%ret0
2487         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2488         mfctl %cr27,%t1
2489         addil LT%foo-$tls_ieoff$,gp
2490         ldw RT%foo-$tls_ieoff$(%r1),%t2
2491         add %t1,%t2,%t3
2492         mfctl %cr27,%t1
2493         addil LR%foo-$tls_leoff$,%t1
2494         ldo RR%foo-$tls_leoff$(%r1),%t2'
2495         tls_first_major=2
2496         tls_first_minor=15
2497         tls_as_opt=--fatal-warnings
2498         ;;
2499   arm*-*-*)
2500     conftest_s='
2501         .section ".tdata","awT",%progbits
2502 foo:    .long   25
2503         .text
2504 .word foo(gottpoff)
2505 .word foo(tpoff)
2506 .word foo(tlsgd)
2507 .word foo(tlsldm)
2508 .word foo(tlsldo)'
2509         tls_first_major=2
2510         tls_first_minor=17
2511         ;;
2512   i[34567]86-*-*)
2513     conftest_s='
2514         .section ".tdata","awT",@progbits
2515 foo:    .long   25
2516         .text
2517         movl    %gs:0, %eax
2518         leal    foo@TLSGD(,%ebx,1), %eax
2519         leal    foo@TLSLDM(%ebx), %eax
2520         leal    foo@DTPOFF(%eax), %edx
2521         movl    foo@GOTTPOFF(%ebx), %eax
2522         subl    foo@GOTTPOFF(%ebx), %eax
2523         addl    foo@GOTNTPOFF(%ebx), %eax
2524         movl    foo@INDNTPOFF, %eax
2525         movl    $foo@TPOFF, %eax
2526         subl    $foo@TPOFF, %eax
2527         leal    foo@NTPOFF(%ecx), %eax'
2528         tls_first_major=2
2529         tls_first_minor=14
2530         tls_as_opt=--fatal-warnings
2531         ;;
2532   x86_64-*-*)
2533     conftest_s='
2534         .section ".tdata","awT",@progbits
2535 foo:    .long   25
2536         .text
2537         movq    %fs:0, %rax
2538         leaq    foo@TLSGD(%rip), %rdi
2539         leaq    foo@TLSLD(%rip), %rdi
2540         leaq    foo@DTPOFF(%rax), %rdx
2541         movq    foo@GOTTPOFF(%rip), %rax
2542         movq    $foo@TPOFF, %rax'
2543         tls_first_major=2
2544         tls_first_minor=14
2545         tls_as_opt=--fatal-warnings
2546         ;;
2547   ia64-*-*)
2548     conftest_s='
2549         .section ".tdata","awT",@progbits
2550 foo:    data8   25
2551         .text
2552         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2553         addl    r17 = @ltoff(@dtprel(foo#)), gp
2554         addl    r18 = @ltoff(@tprel(foo#)), gp
2555         addl    r19 = @dtprel(foo#), gp
2556         adds    r21 = @dtprel(foo#), r13
2557         movl    r23 = @dtprel(foo#)
2558         addl    r20 = @tprel(foo#), gp
2559         adds    r22 = @tprel(foo#), r13
2560         movl    r24 = @tprel(foo#)'
2561         tls_first_major=2
2562         tls_first_minor=13
2563         tls_as_opt=--fatal-warnings
2564         ;;
2565   mips*-*-*)
2566     conftest_s='
2567         .section .tdata,"awT",@progbits
2568 x:
2569         .word 2
2570         .text
2571         addiu $4, $28, %tlsgd(x)
2572         addiu $4, $28, %tlsldm(x)
2573         lui $4, %dtprel_hi(x)
2574         addiu $4, $4, %dtprel_lo(x)
2575         lw $4, %gottprel(x)($28)
2576         lui $4, %tprel_hi(x)
2577         addiu $4, $4, %tprel_lo(x)'
2578         tls_first_major=2
2579         tls_first_minor=16
2580         tls_as_opt='-32 --fatal-warnings'
2581         ;;
2582   m68k-*-*)
2583     conftest_s='
2584         .section .tdata,"awT",@progbits
2585 x:
2586         .word 2
2587         .text
2588 foo:
2589         move.l x@TLSGD(%a5),%a0
2590         move.l x@TLSLDM(%a5),%a0
2591         move.l x@TLSLDO(%a5),%a0
2592         move.l x@TLSIE(%a5),%a0
2593         move.l x@TLSLE(%a5),%a0'
2594         tls_first_major=2
2595         tls_first_minor=19
2596         tls_as_opt='--fatal-warnings'
2597         ;;
2598   powerpc-*-*)
2599     conftest_s='
2600         .section ".tdata","awT",@progbits
2601         .align 2
2602 ld0:    .space 4
2603 ld1:    .space 4
2604 x1:     .space 4
2605 x2:     .space 4
2606 x3:     .space 4
2607         .text
2608         addi 3,31,ld0@got@tlsgd
2609         bl __tls_get_addr
2610         addi 3,31,x1@got@tlsld
2611         bl __tls_get_addr
2612         addi 9,3,x1@dtprel
2613         addis 9,3,x2@dtprel@ha
2614         addi 9,9,x2@dtprel@l
2615         lwz 9,x3@got@tprel(31)
2616         add 9,9,x@tls
2617         addi 9,2,x1@tprel
2618         addis 9,2,x2@tprel@ha
2619         addi 9,9,x2@tprel@l'
2620         tls_first_major=2
2621         tls_first_minor=14
2622         tls_as_opt="-a32 --fatal-warnings"
2623         ;;
2624   powerpc64-*-*)
2625     conftest_s='
2626         .section ".tdata","awT",@progbits
2627         .align 3
2628 ld0:    .space 8
2629 ld1:    .space 8
2630 x1:     .space 8
2631 x2:     .space 8
2632 x3:     .space 8
2633         .text
2634         addi 3,2,ld0@got@tlsgd
2635         bl .__tls_get_addr
2636         nop
2637         addi 3,2,ld1@toc
2638         bl .__tls_get_addr
2639         nop
2640         addi 3,2,x1@got@tlsld
2641         bl .__tls_get_addr
2642         nop
2643         addi 9,3,x1@dtprel
2644         bl .__tls_get_addr
2645         nop
2646         addis 9,3,x2@dtprel@ha
2647         addi 9,9,x2@dtprel@l
2648         bl .__tls_get_addr
2649         nop
2650         ld 9,x3@got@dtprel(2)
2651         add 9,9,3
2652         bl .__tls_get_addr
2653         nop'
2654         tls_first_major=2
2655         tls_first_minor=14
2656         tls_as_opt="-a64 --fatal-warnings"
2657         ;;
2658   s390-*-*)
2659     conftest_s='
2660         .section ".tdata","awT",@progbits
2661 foo:    .long   25
2662         .text
2663         .long   foo@TLSGD
2664         .long   foo@TLSLDM
2665         .long   foo@DTPOFF
2666         .long   foo@NTPOFF
2667         .long   foo@GOTNTPOFF
2668         .long   foo@INDNTPOFF
2669         l       %r1,foo@GOTNTPOFF(%r12)
2670         l       %r1,0(%r1):tls_load:foo
2671         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2672         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2673         tls_first_major=2
2674         tls_first_minor=14
2675         tls_as_opt="-m31 --fatal-warnings"
2676         ;;
2677   s390x-*-*)
2678     conftest_s='
2679         .section ".tdata","awT",@progbits
2680 foo:    .long   25
2681         .text
2682         .quad   foo@TLSGD
2683         .quad   foo@TLSLDM
2684         .quad   foo@DTPOFF
2685         .quad   foo@NTPOFF
2686         .quad   foo@GOTNTPOFF
2687         lg      %r1,foo@GOTNTPOFF(%r12)
2688         larl    %r1,foo@INDNTPOFF
2689         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2690         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2691         tls_first_major=2
2692         tls_first_minor=14
2693         tls_as_opt="-m64 -Aesame --fatal-warnings"
2694         ;;
2695   sh-*-* | sh[34]-*-*)
2696     conftest_s='
2697         .section ".tdata","awT",@progbits
2698 foo:    .long   25
2699         .text
2700         .long   foo@TLSGD
2701         .long   foo@TLSLDM
2702         .long   foo@DTPOFF
2703         .long   foo@GOTTPOFF
2704         .long   foo@TPOFF'
2705         tls_first_major=2
2706         tls_first_minor=13
2707         tls_as_opt=--fatal-warnings
2708         ;;
2709   sparc*-*-*)
2710     case "$target" in
2711       sparc*-sun-solaris2.[56789]*)
2712         # TLS was introduced in the Solaris 9 4/04 release but
2713         # we do not enable it by default on Solaris 9 either.
2714         if test "x$enable_tls" = xyes ; then
2715           on_solaris=yes
2716         else
2717           enable_tls=no;
2718         fi
2719         ;;
2720       sparc*-sun-solaris2.*)
2721         on_solaris=yes
2722         ;;
2723       *)
2724         on_solaris=no
2725         ;;
2726     esac
2727     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2728       conftest_s='
2729         .section ".tdata",#alloc,#write,#tls
2730 foo:    .long   25
2731         .text
2732         sethi   %tgd_hi22(foo), %o0
2733         add     %o0, %tgd_lo10(foo), %o1
2734         add     %l7, %o1, %o0, %tgd_add(foo)
2735         call    __tls_get_addr, %tgd_call(foo)
2736         sethi   %tldm_hi22(foo), %l1
2737         add     %l1, %tldm_lo10(foo), %l2
2738         add     %l7, %l2, %o0, %tldm_add(foo)
2739         call    __tls_get_addr, %tldm_call(foo)
2740         sethi   %tldo_hix22(foo), %l3
2741         xor     %l3, %tldo_lox10(foo), %l4
2742         add     %o0, %l4, %l5, %tldo_add(foo)
2743         sethi   %tie_hi22(foo), %o3
2744         add     %o3, %tie_lo10(foo), %o3
2745         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2746         add     %g7, %o2, %o4, %tie_add(foo)
2747         sethi   %tle_hix22(foo), %l1
2748         xor     %l1, %tle_lox10(foo), %o5
2749         ld      [%g7 + %o5], %o1'
2750         tls_first_major=0
2751         tls_first_minor=0
2752     else
2753       conftest_s='
2754         .section ".tdata","awT",@progbits
2755 foo:    .long   25
2756         .text
2757         sethi   %tgd_hi22(foo), %o0
2758         add     %o0, %tgd_lo10(foo), %o1
2759         add     %l7, %o1, %o0, %tgd_add(foo)
2760         call    __tls_get_addr, %tgd_call(foo)
2761         sethi   %tldm_hi22(foo), %l1
2762         add     %l1, %tldm_lo10(foo), %l2
2763         add     %l7, %l2, %o0, %tldm_add(foo)
2764         call    __tls_get_addr, %tldm_call(foo)
2765         sethi   %tldo_hix22(foo), %l3
2766         xor     %l3, %tldo_lox10(foo), %l4
2767         add     %o0, %l4, %l5, %tldo_add(foo)
2768         sethi   %tie_hi22(foo), %o3
2769         add     %o3, %tie_lo10(foo), %o3
2770         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2771         add     %g7, %o2, %o4, %tie_add(foo)
2772         sethi   %tle_hix22(foo), %l1
2773         xor     %l1, %tle_lox10(foo), %o5
2774         ld      [%g7 + %o5], %o1'
2775         tls_first_major=2
2776         tls_first_minor=14
2777         tls_as_opt="-32 --fatal-warnings"
2778       fi
2779         ;;
2780   xtensa*-*-*)
2781     conftest_s='
2782         .section ".tdata","awT",@progbits
2783 foo:    .long   25
2784         .text
2785         movi    a8, foo@TLSFUNC
2786         movi    a10, foo@TLSARG
2787         callx8.tls a8, foo@TLSCALL'
2788         tls_first_major=2
2789         tls_first_minor=19
2790         ;;
2791 changequote([,])dnl
2792 esac
2793 set_have_as_tls=no
2794 if test "x$enable_tls" = xno ; then
2795   : # TLS explicitly disabled.
2796 elif test "x$enable_tls" = xyes ; then
2797   set_have_as_tls=yes # TLS explicitly enabled.
2798 elif test -z "$tls_first_major"; then
2799   : # If we don't have a check, assume no support.
2800 else
2801   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2802   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2803   [set_have_as_tls=yes])
2804 fi
2805 if test $set_have_as_tls = yes ; then
2806   AC_DEFINE(HAVE_AS_TLS, 1,
2807             [Define if your assembler supports thread-local storage.])
2808 fi
2809
2810 # Target-specific assembler checks.
2811
2812 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2813 gcc_cv_ld_static_dynamic=no
2814 if test $in_tree_ld = yes ; then
2815   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
2816     gcc_cv_ld_static_dynamic=yes
2817   fi
2818 elif test x$gcc_cv_ld != x; then
2819         # Check if linker supports -Bstatic/-Bdynamic option
2820         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2821           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2822                 gcc_cv_ld_static_dynamic=yes
2823         fi
2824 fi
2825 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2826         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2827 [Define if your linker supports -Bstatic/-Bdynamic option.])
2828 fi
2829 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2830
2831 if test x"$demangler_in_ld" = xyes; then
2832   AC_MSG_CHECKING(linker --demangle support)
2833   gcc_cv_ld_demangle=no
2834   if test $in_tree_ld = yes; then
2835     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2836       gcc_cv_ld_demangle=yes
2837     fi
2838   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2839     # Check if the GNU linker supports --demangle option
2840     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2841       gcc_cv_ld_demangle=yes
2842     fi
2843   fi
2844   if test x"$gcc_cv_ld_demangle" = xyes; then
2845     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2846 [Define if your linker supports --demangle option.])
2847   fi
2848   AC_MSG_RESULT($gcc_cv_ld_demangle)
2849 fi
2850
2851 case "$target" in
2852   # All TARGET_ABI_OSF targets.
2853   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2854     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2855         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2856 [       .set nomacro
2857         .text
2858         extbl   $3, $2, $3      !lituse_bytoff!1
2859         ldq     $2, a($29)      !literal!1
2860         ldq     $4, b($29)      !literal!2
2861         ldq_u   $3, 0($2)       !lituse_base!1
2862         ldq     $27, f($29)     !literal!5
2863         jsr     $26, ($27), f   !lituse_jsr!5
2864         ldah    $29, 0($26)     !gpdisp!3
2865         lda     $0, c($29)      !gprel
2866         ldah    $1, d($29)      !gprelhigh
2867         lda     $1, d($1)       !gprellow
2868         lda     $29, 0($29)     !gpdisp!3],,
2869     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2870   [Define if your assembler supports explicit relocations.])])
2871     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2872         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2873 [       .set nomacro
2874         .text
2875         ldq     $27, a($29)     !literal!1
2876         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2877     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2878   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2879     ;;
2880
2881   cris-*-*)
2882     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2883       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2884       [-no-mul-bug-abort], [.text],,
2885       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2886                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2887     ;;
2888
2889   sparc*-*-*)
2890     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2891       [.register %g2, #scratch],,
2892       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2893                 [Define if your assembler supports .register.])])
2894
2895     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2896       [-relax], [.text],,
2897       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2898                 [Define if your assembler supports -relax option.])])
2899
2900     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2901       gcc_cv_as_sparc_ua_pcrel,,
2902       [-K PIC],
2903 [.text
2904 foo:
2905         nop
2906 .data
2907 .align 4
2908 .byte 0
2909 .uaword %r_disp32(foo)],
2910       [if test x$gcc_cv_ld != x \
2911        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2912          gcc_cv_as_sparc_ua_pcrel=yes
2913        fi
2914        rm -f conftest],
2915       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2916                 [Define if your assembler and linker support unaligned PC relative relocs.])
2917
2918       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2919         gcc_cv_as_sparc_ua_pcrel_hidden,,
2920         [-K PIC],
2921 [.data
2922 .align 4
2923 .byte 0x31
2924 .uaword %r_disp32(foo)
2925 .byte 0x32, 0x33, 0x34
2926 .global foo
2927 .hidden foo
2928 foo:
2929 .skip 4],
2930         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2931          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2932          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2933             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2934             if $gcc_cv_objdump -R conftest 2> /dev/null \
2935                | grep 'DISP32' > /dev/null 2>&1; then
2936                 :
2937             else
2938                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2939             fi
2940          fi
2941          rm -f conftest],
2942          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2943                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2944     ]) # unaligned pcrel relocs
2945
2946     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2947       gcc_cv_as_sparc_offsetable_lo10,,
2948       [-xarch=v9],
2949 [.text
2950         or %g1, %lo(ab) + 12, %g1
2951         or %g1, %lo(ab + 12), %g1],
2952       [if test x$gcc_cv_objdump != x \
2953        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2954           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2955          gcc_cv_as_sparc_offsetable_lo10=yes
2956        fi],
2957        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2958                  [Define if your assembler supports offsetable %lo().])])
2959     ;;
2960
2961 changequote(,)dnl
2962   i[34567]86-*-* | x86_64-*-*)
2963 changequote([,])dnl
2964     case $target_os in
2965       cygwin* | pe | mingw32*)
2966         # Recent binutils allows the three-operand form of ".comm" on PE.  This
2967         # definition is used unconditionally to initialise the default state of
2968         # the target option variable that governs usage of the feature.
2969         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
2970          [2,19,52],,[.comm foo,1,32])
2971         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
2972           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
2973           [Define if your assembler supports specifying the alignment
2974            of objects allocated using the GAS .comm command.])
2975         # Used for DWARF 2 in PE
2976         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2977           gcc_cv_as_ix86_pe_secrel32,
2978           [2,15,91],,
2979 [.text
2980 foo:    nop
2981 .data
2982         .secrel32 foo],
2983           [if test x$gcc_cv_ld != x \
2984            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2985              gcc_cv_as_ix86_pe_secrel32=yes
2986            fi
2987            rm -f conftest],
2988           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2989             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2990         ;;
2991     esac
2992
2993     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2994        gcc_cv_as_ix86_filds,,,
2995        [filds mem; fists mem],,
2996        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
2997          [Define if your assembler uses filds and fists mnemonics.])])
2998
2999     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3000        gcc_cv_as_ix86_fildq,,,
3001        [fildq mem; fistpq mem],,
3002        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3003          [Define if your assembler uses fildq and fistq mnemonics.])])
3004
3005     gcc_GAS_CHECK_FEATURE([cmov syntax],
3006       gcc_cv_as_ix86_cmov_sun_syntax,,,
3007       [cmovl.l %edx, %eax],,
3008       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3009         [Define if your assembler supports the Sun syntax for cmov.])])
3010
3011     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3012       gcc_cv_as_ix86_ffreep,,,
3013       [ffreep %st(1)],,
3014       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3015         [Define if your assembler supports the ffreep mnemonic.])])
3016
3017     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3018       gcc_cv_as_ix86_sahf,,,
3019       [sahf],,
3020       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3021         [Define if your assembler supports the sahf mnemonic.])])
3022
3023     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3024       gcc_cv_as_ix86_diff_sect_delta,,,
3025       [.section .rodata
3026 .L1:
3027         .long .L2-.L1
3028         .long .L3-.L1
3029         .text
3030 .L3:    nop
3031 .L2:    nop],,
3032       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3033         [Define if your assembler supports the subtraction of symbols in different sections.])])
3034
3035     # This one is used unconditionally by i386.[ch]; it is to be defined
3036     # to 1 if the feature is present, 0 otherwise.
3037     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3038         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3039 [       .text
3040 .L0:
3041         nop
3042         .data
3043         .long .L0@GOTOFF])
3044     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3045       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3046       [Define true if the assembler supports '.long foo@GOTOFF'.])
3047     ;;
3048
3049   ia64*-*-*)
3050     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3051         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3052 [       .text
3053         addl r15 = @ltoffx(x#), gp
3054         ;;
3055         ld8.mov r16 = [[r15]], x#],,
3056     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3057           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3058
3059     ;;
3060
3061   powerpc*-*-*)
3062     case $target in
3063       *-*-aix*) conftest_s='    .machine "pwr5"
3064         .csect .text[[PR]]
3065         mfcr 3,128';;
3066       *-*-darwin*)
3067         gcc_GAS_CHECK_FEATURE([.machine directive support],
3068           gcc_cv_as_machine_directive,,,
3069           [     .machine ppc7400])
3070         if test x$gcc_cv_as_machine_directive != xyes; then
3071           echo "*** This target requires an assembler supporting \".machine\"" >&2
3072           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3073           test x$build = x$target && exit 1
3074         fi
3075         conftest_s='    .text
3076         mfcr r3,128';;
3077       *) conftest_s='   .machine power4
3078         .text
3079         mfcr 3,128';;
3080     esac
3081
3082     gcc_GAS_CHECK_FEATURE([mfcr field support],
3083       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3084       [$conftest_s],,
3085       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3086           [Define if your assembler supports mfcr field.])])
3087
3088     case $target in
3089       *-*-aix*) conftest_s='    .machine "pwr5"
3090         .csect .text[[PR]]
3091         popcntb 3,3';;
3092       *) conftest_s='   .machine power5
3093         .text
3094         popcntb 3,3';;
3095     esac
3096
3097     gcc_GAS_CHECK_FEATURE([popcntb support],
3098       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3099       [$conftest_s],,
3100       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3101           [Define if your assembler supports popcntb field.])])
3102
3103     case $target in
3104       *-*-aix*) conftest_s='    .machine "pwr5x"
3105         .csect .text[[PR]]
3106         frin 1,1';;
3107       *) conftest_s='   .machine power5
3108         .text
3109         frin 1,1';;
3110     esac
3111
3112     gcc_GAS_CHECK_FEATURE([fp round support],
3113       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3114       [$conftest_s],,
3115       [AC_DEFINE(HAVE_AS_FPRND, 1,
3116           [Define if your assembler supports fprnd.])])
3117
3118     case $target in
3119       *-*-aix*) conftest_s='    .machine "pwr6"
3120         .csect .text[[PR]]
3121         mffgpr 1,3';;
3122       *) conftest_s='   .machine power6
3123         .text
3124         mffgpr 1,3';;
3125     esac
3126
3127     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3128       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
3129       [$conftest_s],,
3130       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3131           [Define if your assembler supports mffgpr and mftgpr.])])
3132
3133     case $target in
3134       *-*-aix*) conftest_s='    .csect .text[[PR]]
3135 LCF..0:
3136         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3137       *-*-darwin*)
3138         conftest_s='    .text
3139 LCF0:
3140         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3141       *) conftest_s='   .text
3142 .LCF0:
3143         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3144     esac
3145
3146     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3147       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3148       [$conftest_s],,
3149       [AC_DEFINE(HAVE_AS_REL16, 1,
3150           [Define if your assembler supports R_PPC_REL16 relocs.])])
3151
3152     case $target in
3153       *-*-aix*) conftest_s='    .machine "pwr6"
3154         .csect .text[[PR]]
3155         cmpb 3,4,5';;
3156       *) conftest_s='   .machine power6
3157         .text
3158         cmpb 3,4,5';;
3159     esac
3160
3161     gcc_GAS_CHECK_FEATURE([compare bytes support],
3162       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
3163       [$conftest_s],,
3164       [AC_DEFINE(HAVE_AS_CMPB, 1,
3165           [Define if your assembler supports cmpb.])])
3166
3167     case $target in
3168       *-*-aix*) conftest_s='    .machine "pwr6"
3169         .csect .text[[PR]]
3170         dadd 1,2,3';;
3171       *) conftest_s='   .machine power6
3172         .text
3173         dadd 1,2,3';;
3174     esac
3175
3176     gcc_GAS_CHECK_FEATURE([decimal float support],
3177       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
3178       [$conftest_s],,
3179       [AC_DEFINE(HAVE_AS_DFP, 1,
3180           [Define if your assembler supports DFP instructions.])])
3181
3182     case $target in
3183       *-*-aix*) conftest_s='    .machine "pwr7"
3184         .csect .text[[PR]]
3185         lxvd2x 1,2,3';;
3186       *) conftest_s='   .machine power7
3187         .text
3188         lxvd2x 1,2,3';;
3189     esac
3190
3191     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3192       gcc_cv_as_powerpc_vsx, [9,99,0], -a32,
3193       [$conftest_s],,
3194       [AC_DEFINE(HAVE_AS_VSX, 1,
3195           [Define if your assembler supports VSX instructions.])])
3196
3197     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3198       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3199       [.gnu_attribute 4,1],,
3200       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3201           [Define if your assembler supports .gnu_attribute.])])
3202
3203     gcc_GAS_CHECK_FEATURE([tls marker support],
3204       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3205       [ bl __tls_get_addr(x@tlsgd)],,
3206       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3207           [Define if your assembler supports arg info for __tls_get_addr.])])
3208     ;;
3209
3210   mips*-*-*)
3211     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3212       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3213 [       lw $4,%gp_rel(foo)($4)],,
3214       [if test x$target_cpu_default = x
3215        then target_cpu_default=MASK_EXPLICIT_RELOCS
3216        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3217        fi])
3218     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3219       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3220       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3221                  [Define if the assembler understands -mno-shared.])])
3222
3223     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3224       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3225       [.gnu_attribute 4,1],,
3226       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3227           [Define if your assembler supports .gnu_attribute.])])
3228
3229     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3230       gcc_cv_as_mips_dtprelword, [2,18,0],,
3231       [.section .tdata,"awT",@progbits
3232 x:
3233         .word 2
3234         .text
3235         .dtprelword x+0x8000],,
3236       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3237           [Define if your assembler supports .dtprelword.])])
3238     ;;
3239 esac
3240
3241 # Mips and HP-UX need the GNU assembler.
3242 # Linux on IA64 might be able to use the Intel assembler.
3243
3244 case "$target" in
3245   mips*-*-* | *-*-hpux* )
3246     if test x$gas_flag = xyes \
3247        || test x"$host" != x"$build" \
3248        || test ! -x "$gcc_cv_as" \
3249        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3250       :
3251     else
3252       echo "*** This configuration requires the GNU assembler" >&2
3253       exit 1
3254     fi
3255     ;;
3256 esac
3257
3258 # ??? Not all targets support dwarf2 debug_line, even within a version
3259 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3260 # info to the output file.  So, as supported targets are added to gas 2.11,
3261 # add some instruction here to (also) show we expect this might work.
3262 # ??? Once 2.11 is released, probably need to add first known working
3263 # version to the per-target configury.
3264 case "$target" in
3265   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3266   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3267   | xstormy16*-*-* | cris-*-* | crisv32-*-* | xtensa*-*-* | bfin-*-* | score*-*-* \
3268   | spu-*-* | fido*-*-* | m32c-*-*)
3269     insn="nop"
3270     ;;
3271   ia64*-*-* | s390*-*-*)
3272     insn="nop 0"
3273     ;;
3274   mmix-*-*)
3275     insn="swym 0"
3276     ;;
3277 esac
3278 if test x"$insn" != x; then
3279  conftest_s="\
3280         .file 1 \"conftest.s\"
3281         .loc 1 3 0
3282         $insn"
3283  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3284   gcc_cv_as_dwarf2_debug_line,
3285   [elf,2,11,0],, [$conftest_s],
3286   [if test x$gcc_cv_objdump != x \
3287    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3288       | grep debug_line > /dev/null 2>&1; then
3289      gcc_cv_as_dwarf2_debug_line=yes
3290    fi])
3291
3292 # The .debug_line file table must be in the exact order that
3293 # we specified the files, since these indices are also used
3294 # by DW_AT_decl_file.  Approximate this test by testing if
3295 # the assembler bitches if the same index is assigned twice.
3296  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3297   gcc_cv_as_dwarf2_file_buggy,,,
3298 [       .file 1 "foo.s"
3299         .file 1 "bar.s"])
3300
3301  if test $gcc_cv_as_dwarf2_debug_line = yes \
3302  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3303         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3304   [Define if your assembler supports dwarf2 .file/.loc directives,
3305    and preserves file table indices exactly as given.])
3306  fi
3307
3308  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3309   gcc_cv_as_gdwarf2_flag,
3310   [elf,2,11,0], [--gdwarf2], [$insn],,
3311   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3312 [Define if your assembler supports the --gdwarf2 option.])])
3313
3314  gcc_GAS_CHECK_FEATURE([--gstabs option],
3315   gcc_cv_as_gstabs_flag,
3316   [elf,2,11,0], [--gstabs], [$insn],
3317   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3318    # and warns about it, but still exits successfully.  So check for
3319    # this.
3320    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3321    then :
3322    else gcc_cv_as_gstabs_flag=yes
3323    fi],
3324   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3325 [Define if your assembler supports the --gstabs option.])])
3326
3327  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3328   gcc_cv_as_debug_prefix_map_flag,
3329   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3330   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3331 [Define if your assembler supports the --debug-prefix-map option.])])
3332 fi
3333
3334 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
3335  ,,
3336 [.lcomm bar,4,16],,
3337 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
3338   [Define if your assembler supports .lcomm with an alignment field.])])
3339
3340 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3341  [gcc_cv_as_line_zero],
3342  [gcc_cv_as_line_zero=no
3343   if test $in_tree_gas = yes; then
3344     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3345   elif test "x$gcc_cv_as" != x; then
3346     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3347     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3348        test "x`cat conftest.out`" = x
3349     then
3350       gcc_cv_as_line_zero=yes
3351     else
3352       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3353       cat conftest.s >&AS_MESSAGE_LOG_FD
3354       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3355       cat conftest.out >&AS_MESSAGE_LOG_FD
3356     fi
3357     rm -f conftest.o conftest.s conftest.out
3358   fi])
3359 if test "x$gcc_cv_as_line_zero" = xyes; then
3360   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3361 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3362 fi
3363
3364 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3365 gcc_cv_ld_eh_frame_hdr=no
3366 if test $in_tree_ld = yes ; then
3367   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3368      && test $in_tree_ld_is_elf = yes; then
3369     gcc_cv_ld_eh_frame_hdr=yes
3370   fi
3371 elif test x$gcc_cv_ld != x; then
3372         # Check if linker supports --eh-frame-hdr option
3373         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3374                 gcc_cv_ld_eh_frame_hdr=yes
3375         fi
3376 fi
3377 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3378 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3379         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3380 [Define if your linker supports --eh-frame-hdr option.])
3381 fi
3382 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3383
3384 AC_MSG_CHECKING(linker position independent executable support)
3385 gcc_cv_ld_pie=no
3386 if test $in_tree_ld = yes ; then
3387   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3388      && test $in_tree_ld_is_elf = yes; then
3389     gcc_cv_ld_pie=yes
3390   fi
3391 elif test x$gcc_cv_ld != x; then
3392         # Check if linker supports -pie option
3393         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3394                 gcc_cv_ld_pie=yes
3395         fi
3396 fi
3397 if test x"$gcc_cv_ld_pie" = xyes; then
3398         AC_DEFINE(HAVE_LD_PIE, 1,
3399 [Define if your linker supports -pie option.])
3400 fi
3401 AC_MSG_RESULT($gcc_cv_ld_pie)
3402
3403 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3404 gcc_cv_ld_eh_gc_sections=no
3405 if test $in_tree_ld = yes ; then
3406   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3407      && test $in_tree_ld_is_elf = yes; then
3408     gcc_cv_ld_eh_gc_sections=yes
3409   fi
3410 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3411   cat > conftest.s <<EOF
3412         .section        .text
3413 .globl _start
3414         .type _start, @function
3415 _start:
3416         .long foo
3417         .size _start, .-_start
3418         .section        .text.foo,"ax",@progbits
3419         .type foo, @function
3420 foo:
3421         .long 0
3422         .size foo, .-foo
3423         .section        .gcc_except_table.foo,"a",@progbits
3424 .L0:
3425         .long 0
3426         .section        .eh_frame,"a",@progbits
3427         .long .L0
3428 EOF
3429   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3430     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3431          | grep "gc-sections option ignored" > /dev/null; then
3432       gcc_cv_ld_eh_gc_sections=no
3433     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3434       gcc_cv_ld_eh_gc_sections=yes
3435       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3436       if test x$gcc_cv_as_comdat_group != xyes; then
3437         gcc_cv_ld_eh_gc_sections=no
3438         cat > conftest.s <<EOF
3439         .section        .text
3440 .globl _start
3441         .type _start, @function
3442 _start:
3443         .long foo
3444         .size _start, .-_start
3445         .section        .gnu.linkonce.t.foo,"ax",@progbits
3446         .type foo, @function
3447 foo:
3448         .long 0
3449         .size foo, .-foo
3450         .section        .gcc_except_table.foo,"a",@progbits
3451 .L0:
3452         .long 0
3453         .section        .eh_frame,"a",@progbits
3454         .long .L0
3455 EOF
3456         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3457           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3458                | grep "gc-sections option ignored" > /dev/null; then
3459             gcc_cv_ld_eh_gc_sections=no
3460           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3461             gcc_cv_ld_eh_gc_sections=yes
3462           fi
3463         fi
3464       fi
3465     fi
3466   fi
3467   rm -f conftest.s conftest.o conftest
3468 fi
3469 case "$target" in
3470   hppa*-*-linux*)
3471     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3472     gcc_cv_ld_eh_gc_sections=no
3473     ;;
3474 esac
3475 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3476         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3477   [Define if your linker supports garbage collection of
3478    sections in presence of EH frames.])
3479 fi
3480 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3481
3482 # --------
3483 # UNSORTED
3484 # --------
3485
3486 AC_CACHE_CHECK(linker --as-needed support,
3487 gcc_cv_ld_as_needed,
3488 [gcc_cv_ld_as_needed=no
3489 if test $in_tree_ld = yes ; then
3490   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3491      && test $in_tree_ld_is_elf = yes; then
3492     gcc_cv_ld_as_needed=yes
3493   fi
3494 elif test x$gcc_cv_ld != x; then
3495         # Check if linker supports --as-needed and --no-as-needed options
3496         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3497                 gcc_cv_ld_as_needed=yes
3498         fi
3499 fi
3500 ])
3501 if test x"$gcc_cv_ld_as_needed" = xyes; then
3502         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3503 [Define if your linker supports --as-needed and --no-as-needed options.])
3504 fi
3505
3506 case "$target:$tm_file" in
3507   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3508     AC_CACHE_CHECK(linker support for omitting dot symbols,
3509     gcc_cv_ld_no_dot_syms,
3510     [gcc_cv_ld_no_dot_syms=no
3511     if test $in_tree_ld = yes ; then
3512       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3513         gcc_cv_ld_no_dot_syms=yes
3514       fi
3515     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3516       cat > conftest1.s <<EOF
3517         .text
3518         bl .foo
3519 EOF
3520       cat > conftest2.s <<EOF
3521         .section ".opd","aw"
3522         .align 3
3523         .globl foo
3524         .type foo,@function
3525 foo:
3526         .quad .LEfoo,.TOC.@tocbase,0
3527         .text
3528 .LEfoo:
3529         blr
3530         .size foo,.-.LEfoo
3531 EOF
3532       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3533          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3534          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3535         gcc_cv_ld_no_dot_syms=yes
3536       fi
3537       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3538     fi
3539     ])
3540     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3541       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3542     [Define if your PowerPC64 linker only needs function descriptor syms.])
3543     fi
3544     ;;
3545 esac
3546
3547 AC_CACHE_CHECK(linker --build-id support,
3548   gcc_cv_ld_buildid,
3549   [gcc_cv_ld_buildid=no
3550   if test $in_tree_ld = yes ; then
3551     if test "$gcc_cv_gld_major_version" -eq 2 -a \
3552        "$gcc_cv_gld_minor_version" -ge 18 -o \
3553        "$gcc_cv_gld_major_version" -gt 2 \
3554        && test $in_tree_ld_is_elf = yes; then
3555       gcc_cv_ld_buildid=yes
3556     fi
3557   elif test x$gcc_cv_ld != x; then
3558     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
3559       gcc_cv_ld_buildid=yes
3560     fi
3561   fi])
3562 if test x"$gcc_cv_ld_buildid" = xyes; then
3563   AC_DEFINE(HAVE_LD_BUILDID, 1,
3564   [Define if your linker supports --build-id.])
3565 fi
3566
3567 AC_ARG_ENABLE(linker-build-id,
3568 [  --enable-linker-build-id
3569                           compiler will always pass --build-id to linker],
3570 [],
3571 enable_linker_build_id=no)
3572
3573 if test x"$enable_linker_build_id" = xyes; then
3574   if test x"$gcc_cv_ld_buildid" = xyes; then
3575     AC_DEFINE(ENABLE_LD_BUILDID, 1,
3576     [Define if gcc should always pass --build-id to linker.])
3577   else
3578     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
3579   fi
3580 fi
3581
3582 AC_CACHE_CHECK(linker --sysroot support,
3583   gcc_cv_ld_sysroot,
3584   [gcc_cv_ld_sysroot=no
3585   if test $in_tree_ld = yes ; then
3586       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3587         gcc_cv_ld_sysroot=yes
3588       fi
3589   elif test x$gcc_cv_ld != x; then
3590     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3591       gcc_cv_ld_sysroot=yes
3592     fi
3593   fi])
3594 if test x"$gcc_cv_ld_sysroot" = xyes; then
3595   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3596   [Define if your linker supports --sysroot.])
3597 fi
3598
3599 if test x$with_sysroot = x && test x$host = x$target \
3600    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3601    && test "$prefix" != "NONE"; then
3602   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3603 [Define to PREFIX/include if cpp should also search that directory.])
3604 fi
3605
3606 # Test for stack protector support in target C library.
3607 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3608       gcc_cv_libc_provides_ssp,
3609       [gcc_cv_libc_provides_ssp=no
3610     case "$target" in
3611        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
3612       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3613         if test "x$with_sysroot" = x; then
3614           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3615         elif test "x$with_build_sysroot" != "x"; then
3616           glibc_header_dir="${with_build_sysroot}/usr/include"
3617         elif test "x$with_sysroot" = xyes; then
3618           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3619         else
3620           glibc_header_dir="${with_sysroot}/usr/include"
3621         fi
3622       else
3623         glibc_header_dir=/usr/include
3624       fi
3625       # glibc 2.4 and later provides __stack_chk_fail and
3626       # either __stack_chk_guard, or TLS access to stack guard canary.
3627       if test -f $glibc_header_dir/features.h \
3628          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3629             $glibc_header_dir/features.h > /dev/null; then
3630         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3631            $glibc_header_dir/features.h > /dev/null; then
3632           gcc_cv_libc_provides_ssp=yes
3633         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3634              $glibc_header_dir/features.h > /dev/null \
3635              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3636              $glibc_header_dir/features.h > /dev/null; then
3637           gcc_cv_libc_provides_ssp=yes
3638         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3639              $glibc_header_dir/features.h > /dev/null && \
3640              test -f $glibc_header_dir/bits/uClibc_config.h && \
3641              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3642              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3643           gcc_cv_libc_provides_ssp=yes
3644         fi
3645       fi
3646         ;;
3647        *-*-gnu*)
3648          # Avoid complicated tests (see
3649          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
3650          # simply assert that glibc does provide this, which is true for all
3651          # realistically usable GNU/Hurd configurations.
3652          gcc_cv_libc_provides_ssp=yes;;
3653        *-*-darwin*)
3654          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3655            [echo "no __stack_chk_fail on this target"])
3656         ;;
3657   *) gcc_cv_libc_provides_ssp=no ;;
3658     esac])
3659
3660 if test x$gcc_cv_libc_provides_ssp = xyes; then
3661   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3662             [Define if your target C library provides stack protector support])
3663 fi
3664
3665 # Check if TFmode long double should be used by default or not.
3666 # Some glibc targets used DFmode long double, but with glibc 2.4
3667 # and later they can use TFmode.
3668 case "$target" in
3669   powerpc*-*-linux* | \
3670   powerpc*-*-gnu* | \
3671   sparc*-*-linux* | \
3672   s390*-*-linux* | \
3673   alpha*-*-linux*)
3674     AC_ARG_WITH(long-double-128,
3675 [  --with-long-double-128  Use 128-bit long double by default.],
3676       gcc_cv_target_ldbl128="$with_long_double_128",
3677       [gcc_cv_target_ldbl128=no
3678       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3679         if test "x$with_sysroot" = x; then
3680           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3681         elif test "x$with_build_sysroot" != "x"; then
3682           glibc_header_dir="${with_build_sysroot}/usr/include"
3683         elif test "x$with_sysroot" = xyes; then
3684           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3685         else
3686           glibc_header_dir="${with_sysroot}/usr/include"
3687         fi
3688       else
3689         glibc_header_dir=/usr/include
3690       fi
3691 changequote(,)dnl
3692       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3693         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3694       && gcc_cv_target_ldbl128=yes
3695 changequote([,])dnl
3696       ])
3697     ;;
3698 esac
3699 if test x$gcc_cv_target_ldbl128 = xyes; then
3700   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3701             [Define if TFmode long double should be the default])
3702 fi
3703
3704 # Find out what GC implementation we want, or may, use.
3705 AC_ARG_WITH(gc,
3706 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3707                           with the compiler],
3708 [case "$withval" in
3709   page)
3710     GGC=ggc-$withval
3711     ;;
3712   zone)
3713     GGC=ggc-$withval
3714     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3715     ;;
3716   *)
3717     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3718     ;;
3719 esac],
3720 [GGC=ggc-page])
3721 AC_SUBST(GGC)
3722 echo "Using $GGC for garbage collection."
3723
3724 # Use the system's zlib library.
3725 zlibdir=-L../zlib
3726 zlibinc="-I\$(srcdir)/../zlib"
3727 AC_ARG_WITH(system-zlib,
3728 [  --with-system-zlib      use installed libz],
3729 zlibdir=
3730 zlibinc=
3731 )
3732 AC_SUBST(zlibdir)
3733 AC_SUBST(zlibinc)
3734
3735 dnl Very limited version of automake's enable-maintainer-mode
3736
3737 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3738   dnl maintainer-mode is disabled by default
3739   AC_ARG_ENABLE(maintainer-mode,
3740 [  --enable-maintainer-mode
3741                           enable make rules and dependencies not useful
3742                           (and sometimes confusing) to the casual installer],
3743       maintainer_mode=$enableval,
3744       maintainer_mode=no)
3745
3746 AC_MSG_RESULT($maintainer_mode)
3747
3748 if test "$maintainer_mode" = "yes"; then
3749   MAINT=''
3750 else
3751   MAINT='#'
3752 fi
3753 AC_SUBST(MAINT)dnl
3754
3755 # --------------
3756 # Language hooks
3757 # --------------
3758
3759 # Make empty files to contain the specs and options for each language.
3760 # Then add #include lines to for a compiler that has specs and/or options.
3761
3762 subdirs=
3763 lang_opt_files=
3764 lang_specs_files=
3765 lang_tree_files=
3766 # These (without "all_") are set in each config-lang.in.
3767 # `language' must be a single word so is spelled singularly.
3768 all_languages=
3769 all_compilers=
3770 all_outputs='Makefile gccbug'
3771 # List of language makefile fragments.
3772 all_lang_makefrags=
3773 # List of language subdirectory makefiles.  Deprecated.
3774 all_lang_makefiles=
3775 # Additional files for gengtype
3776 all_gtfiles="$target_gtfiles"
3777
3778 # These are the languages that are set in --enable-languages,
3779 # and are available in the GCC tree.
3780 all_selected_languages=
3781
3782 # Add the language fragments.
3783 # Languages are added via two mechanisms.  Some information must be
3784 # recorded in makefile variables, these are defined in config-lang.in.
3785 # We accumulate them and plug them into the main Makefile.
3786 # The other mechanism is a set of hooks for each of the main targets
3787 # like `clean', `install', etc.
3788
3789 language_hooks="Make-hooks"
3790
3791 for lang in ${srcdir}/*/config-lang.in
3792 do
3793 changequote(,)dnl
3794         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3795
3796         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3797         if test "x$lang_alias" = x
3798         then
3799               echo "$lang doesn't set \$language." 1>&2
3800               exit 1
3801         fi
3802         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3803         subdirs="$subdirs $subdir"
3804
3805         # $gcc_subdir is where the gcc integration files are to be found
3806         # for a language, both for internal compiler purposes (compiler
3807         # sources implementing front-end to GCC tree converters), and for
3808         # build infrastructure purposes (Make-lang.in, etc.)
3809         #
3810         # This will be <subdir> (relative to $srcdir) if a line like
3811         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
3812         # is found in <langdir>/config-lang.in, and will remain <langdir>
3813         # otherwise.
3814         #
3815         # Except for the language alias (fetched above), the regular
3816         # "config-lang.in" contents are always retrieved from $gcc_subdir,
3817         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
3818         # only this and the language alias.
3819
3820         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
3821         if [ "$gcc_subdir" = "" ]; then
3822            gcc_subdir="$subdir"
3823         fi
3824
3825         case ",$enable_languages," in
3826         *,$lang_alias,*)
3827             all_selected_languages="$all_selected_languages $lang_alias"
3828             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
3829                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
3830             fi
3831             ;;
3832         esac
3833 changequote([,])dnl
3834
3835         language=
3836         boot_language=
3837         compilers=
3838         outputs=
3839         gtfiles=
3840         subdir_requires=
3841         . ${srcdir}/$gcc_subdir/config-lang.in
3842         if test "x$language" = x
3843         then
3844                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
3845                 exit 1
3846         fi
3847
3848         ok=:
3849         case ",$enable_languages," in
3850                 *,$lang_alias,*) ;;
3851                 *)
3852                         for i in $subdir_requires; do
3853                                 test -f "${srcdir}/$i/config-lang.in" && continue
3854                                 ok=false
3855                                 break
3856                         done
3857                 ;;
3858         esac
3859         $ok || continue
3860
3861         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
3862         if test -f $srcdir/$gcc_subdir/lang.opt; then
3863             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
3864         fi
3865         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
3866             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
3867         fi
3868         if test -f ${srcdir}/$gcc_subdir/Makefile.in
3869                 then all_lang_makefiles="$gcc_subdir/Makefile"
3870         fi
3871         all_languages="$all_languages $language"
3872         all_compilers="$all_compilers $compilers"
3873         all_outputs="$all_outputs $outputs"
3874         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3875 done
3876
3877 # Pick up gtfiles for c
3878 gtfiles=
3879 . ${srcdir}/c-config-lang.in
3880 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3881
3882 check_languages=
3883 for language in $all_selected_languages
3884 do
3885         check_languages="$check_languages check-$language"
3886 done
3887
3888 # We link each language in with a set of hooks, reached indirectly via
3889 # lang.${target}.  Only do so for selected languages.
3890
3891 rm -f Make-hooks
3892 touch Make-hooks
3893 target_list="all.cross start.encap rest.encap tags \
3894         install-common install-man install-info install-pdf dvi pdf \
3895         html uninstall info man srcextra srcman srcinfo \
3896         mostlyclean clean distclean maintainer-clean"
3897
3898 for t in $target_list
3899 do
3900         x=
3901         for lang in $all_selected_languages
3902         do
3903                 x="$x $lang.$t"
3904         done
3905         echo "lang.$t: $x" >> Make-hooks
3906 done
3907
3908 # --------
3909 # UNSORTED
3910 # --------
3911
3912 # Create .gdbinit.
3913
3914 echo "dir ." > .gdbinit
3915 echo "dir ${srcdir}" >> .gdbinit
3916 if test x$gdb_needs_out_file_path = xyes
3917 then
3918         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3919 fi
3920 if test "x$subdirs" != x; then
3921         for s in $subdirs
3922         do
3923                 echo "dir ${srcdir}/$s" >> .gdbinit
3924         done
3925 fi
3926 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3927
3928 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3929 AC_SUBST(gcc_tooldir)
3930 AC_SUBST(dollar)
3931
3932 # Find a directory in which to install a shared libgcc.
3933
3934 AC_ARG_ENABLE(version-specific-runtime-libs,
3935 [  --enable-version-specific-runtime-libs
3936                           specify that runtime libraries should be
3937                           installed in a compiler-specific directory])
3938
3939 AC_ARG_WITH(slibdir,
3940 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3941 slibdir="$with_slibdir",
3942 if test "${enable_version_specific_runtime_libs+set}" = set; then
3943   slibdir='$(libsubdir)'
3944 elif test "$host" != "$target"; then
3945   slibdir='$(build_tooldir)/lib'
3946 else
3947   slibdir='$(libdir)'
3948 fi)
3949 AC_SUBST(slibdir)
3950
3951 AC_ARG_WITH(datarootdir,
3952 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3953 datarootdir="\${prefix}/$with_datarootdir",
3954 datarootdir='$(prefix)/share')
3955 AC_SUBST(datarootdir)
3956
3957 AC_ARG_WITH(docdir,
3958 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3959 docdir="\${prefix}/$with_docdir",
3960 docdir='$(datarootdir)')
3961 AC_SUBST(docdir)
3962
3963 AC_ARG_WITH(htmldir,
3964 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3965 htmldir="\${prefix}/$with_htmldir",
3966 htmldir='$(docdir)')
3967 AC_SUBST(htmldir)
3968
3969 # Substitute configuration variables
3970 AC_SUBST(subdirs)
3971 AC_SUBST(srcdir)
3972 AC_SUBST(all_compilers)
3973 AC_SUBST(all_gtfiles)
3974 AC_SUBST(all_lang_makefrags)
3975 AC_SUBST(all_lang_makefiles)
3976 AC_SUBST(all_languages)
3977 AC_SUBST(all_selected_languages)
3978 AC_SUBST(build_exeext)
3979 AC_SUBST(build_install_headers_dir)
3980 AC_SUBST(build_xm_file_list)
3981 AC_SUBST(build_xm_include_list)
3982 AC_SUBST(build_xm_defines)
3983 AC_SUBST(build_file_translate)
3984 AC_SUBST(check_languages)
3985 AC_SUBST(cpp_install_dir)
3986 AC_SUBST(xmake_file)
3987 AC_SUBST(tmake_file)
3988 AC_SUBST(TM_ENDIAN_CONFIG)
3989 AC_SUBST(TM_MULTILIB_CONFIG)
3990 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
3991 AC_SUBST(extra_gcc_objs)
3992 AC_SUBST(extra_headers_list)
3993 AC_SUBST(extra_objs)
3994 AC_SUBST(extra_parts)
3995 AC_SUBST(extra_passes)
3996 AC_SUBST(extra_programs)
3997 AC_SUBST(float_h_file)
3998 AC_SUBST(gcc_config_arguments)
3999 AC_SUBST(gcc_gxx_include_dir)
4000 AC_SUBST(host_exeext)
4001 AC_SUBST(host_xm_file_list)
4002 AC_SUBST(host_xm_include_list)
4003 AC_SUBST(host_xm_defines)
4004 AC_SUBST(out_host_hook_obj)
4005 AC_SUBST(install)
4006 AC_SUBST(lang_opt_files)
4007 AC_SUBST(lang_specs_files)
4008 AC_SUBST(lang_tree_files)
4009 AC_SUBST(local_prefix)
4010 AC_SUBST(md_file)
4011 AC_SUBST(objc_boehm_gc)
4012 AC_SUBST(out_file)
4013 AC_SUBST(out_object_file)
4014 AC_SUBST(thread_file)
4015 AC_SUBST(tm_file_list)
4016 AC_SUBST(tm_include_list)
4017 AC_SUBST(tm_defines)
4018 AC_SUBST(tm_p_file_list)
4019 AC_SUBST(tm_p_include_list)
4020 AC_SUBST(xm_file_list)
4021 AC_SUBST(xm_include_list)
4022 AC_SUBST(xm_defines)
4023 AC_SUBST(use_gcc_stdint)
4024 AC_SUBST(c_target_objs)
4025 AC_SUBST(cxx_target_objs)
4026 AC_SUBST(fortran_target_objs)
4027 AC_SUBST(target_cpu_default)
4028
4029 AC_SUBST_FILE(language_hooks)
4030
4031 # Echo link setup.
4032 if test x${build} = x${host} ; then
4033   if test x${host} = x${target} ; then
4034     echo "Links are now set up to build a native compiler for ${target}." 1>&2
4035   else
4036     echo "Links are now set up to build a cross-compiler" 1>&2
4037     echo " from ${host} to ${target}." 1>&2
4038   fi
4039 else
4040   if test x${host} = x${target} ; then
4041     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
4042     echo " for ${target}." 1>&2
4043   else
4044     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
4045     echo " from ${host} to ${target}." 1>&2
4046   fi
4047 fi
4048
4049 AC_ARG_VAR(GMPLIBS,[How to link GMP])
4050 AC_ARG_VAR(GMPINC,[How to find GMP include files])
4051
4052 case "${GMPLIBS}" in
4053   *-lmpc*) AC_DEFINE(HAVE_mpc, 1, [Define if mpc is in use.]) ;;
4054 esac
4055
4056 AC_ARG_VAR(PPLLIBS,[How to link PPL])
4057 AC_ARG_VAR(PPLINC,[How to find PPL include files])
4058
4059 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
4060 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
4061 if test "x${CLOOGLIBS}" != "x" ; then
4062    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
4063 fi
4064
4065 # Check for plugin support
4066 AC_ARG_ENABLE(plugin,
4067 [  --enable-plugin         enable plugin support],
4068 enable_plugin=$enableval,
4069 enable_plugin=yes; default_plugin=yes)
4070
4071 pluginlibs=
4072 if test x"$enable_plugin" = x"yes"; then
4073   # Check that the host supports -rdynamic and -ldl
4074   have_rdynamic=no
4075   have_dl=no
4076   saved_LDFLAGS="$LDFLAGS"
4077   saved_LIBS="$LIBS"
4078   LIBS=
4079
4080   # Check -rdynamic
4081   LDFLAGS="$LDFLAGS -rdynamic"
4082   AC_MSG_CHECKING([for -rdynamic])
4083   AC_TRY_LINK([],[return 0;],
4084     [AC_MSG_RESULT([yes]); have_rdynamic=yes],
4085     [AC_MSG_RESULT([no])])
4086   if test x"$have_rdynamic" = x"yes" ; then
4087     pluginlibs="-rdynamic"
4088   fi
4089
4090   # Check -ldl
4091   LDFLAGS="$LDFLAGS -ldl"
4092   AC_MSG_CHECKING([for -ldl])
4093   AC_TRY_LINK(
4094     [#include <dlfcn.h>],
4095     [volatile int f = 0; if (f) dlopen ("dummy", 0);],
4096     [AC_MSG_RESULT([yes]); have_dl=yes],
4097     [AC_MSG_RESULT([no])])
4098   if test x"$have_dl" = x"yes"; then
4099     pluginlibs="$pluginlibs -ldl"
4100   fi
4101
4102   # Check that we can build shared objects with -fPIC -shared
4103   LDFLAGS="$LDFLAGS -fPIC -shared"
4104   AC_MSG_CHECKING([for -fPIC -shared])
4105   AC_TRY_LINK(
4106     [extern int X;],[return X == 0;],
4107     [AC_MSG_RESULT([yes]); have_pic_shared=yes],
4108     [AC_MSG_RESULT([no]); have_pic_shared=no])
4109   if test x"$have_pic_shared" != x"yes"; then
4110     pluginlibs=
4111     enable_plugin=no
4112   fi
4113
4114   # If plugin support had been requested but not available, fail.
4115   if test x"$enable_plugin" = x"no" ; then
4116     if test x"$default_plugin" != x"yes"; then
4117       AC_MSG_ERROR([
4118 Building GCC with plugin support requires a host that supports
4119 -fPIC, -shared, -ldl and -rdynamic.])
4120     fi
4121   fi
4122
4123   LDFLAGS="$saved_LDFLAGS"
4124   LIBS="$saved_LIBS"
4125 fi
4126
4127 AC_SUBST(pluginlibs)
4128 AC_SUBST(enable_plugin)
4129 if test x"$enable_plugin" = x"yes"; then
4130   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
4131 fi
4132
4133 # Configure the subdirectories
4134 # AC_CONFIG_SUBDIRS($subdirs)
4135
4136 # Create the Makefile
4137 # and configure language subdirectories
4138 AC_CONFIG_FILES($all_outputs)
4139
4140 AC_CONFIG_COMMANDS([default],
4141 [
4142 case ${CONFIG_HEADERS} in
4143   *auto-host.h:config.in*)
4144   echo > cstamp-h ;;
4145 esac
4146 # Make sure all the subdirs exist.
4147 for d in $subdirs doc build
4148 do
4149     test -d $d || mkdir $d
4150 done
4151 ],
4152 [subdirs='$subdirs'])
4153 AC_OUTPUT