libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                            configuring in a subdirectory])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 LIBGCJ_CONFIGURE(.)
  17
  18 AM_CONFIG_HEADER(include/config.h)
  19
  20 AM_PROG_LIBTOOL
  21
  22 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  23    COMPPATH=.
  24 else
  25    COMPPATH=..
  26 fi
  27 AC_SUBST(COMPPATH)
  28
  29 dnl The -no-testsuite modules omit the test subdir.
  30 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  31
  32 dnl See whether the user prefers size or speed for Character.
  33 dnl The default is size.
  34 AC_ARG_ENABLE(fast-character,
  35 [  --enable-fast-character prefer speed over size for Character],
  36 # Nothing
  37 , AC_DEFINE(COMPACT_CHARACTER))
  38
  39 dnl Should the runtime set system properties by examining the
  40 dnl environment variable GCJ_PROPERTIES?
  41 AC_ARG_ENABLE(getenv-properties,
  42 [  --disable-getenv-properties
  43                           don't set system properties from GCJ_PROPERTIES])
  44
  45 dnl Whether GCJ_PROPERTIES is used depends on the target.
  46 if test -n "$enable_getenv_properties"; then
  47    enable_getenv_properties=${enable_getenv_properties_default-yes}
  48 fi
  49 if test "$enable_getenv_properties" = no; then
  50    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  51 fi
  52
  53 dnl See if the user has requested runtime debugging.
  54 AC_ARG_ENABLE(libgcj-debug,
  55 [  --enable-libgcj-debug   enable runtime debugging code],
  56   if test "$enable_libgcj_debug" = yes; then
  57      AC_DEFINE(DEBUG)
  58   fi)
  59
  60 dnl See if the user has the enterpreter included.
  61 AC_ARG_ENABLE(interpreter,
  62 [  --enable-interpreter    enable interpreter],
  63   if test "$enable_interpreter" = yes; then
  64      AC_DEFINE(INTERPRETER)
  65   fi)
  66
  67 dnl See if the user wants to disable java.net.  This is the mildly
  68 dnl ugly way that we admit that target-side configuration sucks.
  69 AC_ARG_ENABLE(java-net,
  70 [  --disable-java-net      disable java.net])
  71
  72 dnl Whether java.net is built by default can depend on the target.
  73 if test -n "$enable_java_net"; then
  74    enable_java_net=${enable_java_net_default-yes}
  75 fi
  76 if test "$enable_java_net" = no; then
  77    AC_DEFINE(DISABLE_JAVA_NET)
  78 fi
  79
  80 dnl If the target is an eCos system, use the appropriate eCos
  81 dnl I/O routines.
  82 dnl FIXME: this should not be a local option but a global target
  83 dnl system; at present there is no eCos target.
  84 TARGET_ECOS="no"
  85 AC_ARG_WITH(ecos,
  86 [  --with-ecos             enable runtime eCos target support],
  87 TARGET_ECOS="$with_ecos"
  88 )
  89
  90 case "$TARGET_ECOS" in
  91    no)
  92       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
  93       PROCESS=${PROCESS-Posix}
  94       ;;
  95    *)
  96       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
  97       PROCESS=Ecos
  98       AC_DEFINE(ECOS)
  99       ;;
 100 esac
 101
 102 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 103 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 104 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 105 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 106
 107
 108 dnl These may not be defined in a non-ANS conformant embedded system.
 109 dnl FIXME: Should these case a runtime exception in that case?
 110 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 111 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 112
 113 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 114 dnl to create the link will fail.
 115 test -d java || mkdir java
 116 test -d java/io || mkdir java/io
 117 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 118
 119 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 120 test -d java/lang || mkdir java/lang
 121 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 122 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 123
 124 SYSTEMSPEC=
 125 AC_SUBST(SYSTEMSPEC)
 126
 127 AC_ARG_WITH(system-zlib,
 128 [  --with-system-zlib      use installed libz])
 129 ZLIBSPEC=
 130 AC_SUBST(ZLIBSPEC)
 131
 132 dnl FIXME: this should be _libs on some hosts.
 133 libsubdir=.libs
 134
 135 dnl Allow the GC to be disabled.  Can be useful when debugging.
 136 AC_MSG_CHECKING([for garbage collector to use])
 137 AC_ARG_ENABLE(java-gc,
 138 changequote(<<,>>)dnl
 139 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 140 changequote([,])
 141   GC=$enableval,
 142   GC=boehm)
 143 GCLIBS=
 144 GCINCS=
 145 GCDEPS=
 146 GCOBJS=
 147 GCSPEC=
 148 case "$GC" in
 149  boehm)
 150     AC_MSG_RESULT(boehm)
 151     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 152     # We include the path to the boehm-gc build directory.
 153     # See Makefile.am to understand why.
 154     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 155     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 156     GCSPEC='-lgcjgc'
 157     dnl We also want to pick up some cpp flags required when including
 158     dnl boehm-config.h.  Yuck.
 159     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 160     GCOBJS=boehm.lo
 161     GCHDR=boehm-gc.h
 162     dnl The POSIX thread support needs to know this.
 163     AC_DEFINE(HAVE_BOEHM_GC)
 164     ;;
 165  no)
 166     AC_MSG_RESULT(none)
 167     GCOBJS=nogc.lo
 168     GCHDR=no-gc.h
 169     ;;
 170  *)
 171     AC_MSG_ERROR(unrecognized collector \"$GC\")
 172     ;;
 173 esac
 174 AC_SUBST(GCLIBS)
 175 AC_SUBST(GCINCS)
 176 AC_SUBST(GCDEPS)
 177 AC_SUBST(GCOBJS)
 178 AC_SUBST(GCSPEC)
 179 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 180
 181
 182 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 183 dnl In particular both packages must make the same decision about which
 184 dnl thread package to use.
 185 AC_MSG_CHECKING([for threads package to use])
 186 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 187   THREADS=$enableval,
 188   dnl FIXME: figure out native threads to use here.
 189   THREADS=no)
 190
 191 if test "$THREADS" = yes; then
 192    case "$host" in
 193     *-*-vxworks*)
 194        THREADS=vxworks
 195        ;;
 196     *-*-linux*)
 197        # FIXME: this isn't correct in all cases.
 198        THREADS=posix
 199        ;;
 200     *-*-win*)
 201        THREADS=win32
 202        ;;
 203     *-*-irix*)
 204        # FIXME: for now, choose POSIX, because we implement that.
 205        # Later, choose irix threads.
 206        THREADS=posix
 207        ;;
 208     *-*-solaris*)
 209        # FIXME: for now, choose POSIX, because we implement that.
 210        # Later, choose solaris threads.
 211        THREADS=posix
 212        ;;
 213     *)
 214        # For now.
 215        THREADS=none
 216        ;;
 217    esac
 218 fi
 219
 220 case "$THREADS" in
 221  no | none | single)
 222     THREADS=none
 223     ;;
 224  posix | pthreads)
 225     THREADS=posix
 226     case "$host" in
 227      *-*-linux*)
 228         AC_DEFINE(LINUX_THREADS)
 229         ;;
 230     esac
 231     ;;
 232  qt)
 233     ;;
 234  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 235     AC_MSG_ERROR(thread package $THREADS not yet supported)
 236     ;;
 237  *)
 238     AC_MSG_ERROR($THREADS is an unknown thread package)
 239     ;;
 240 esac
 241 AC_MSG_RESULT($THREADS)
 242
 243 THREADLIBS=
 244 THREADINCS=
 245 THREADDEPS=
 246 THREADOBJS=
 247 THREADH=
 248 THREADSPEC=
 249 case "$THREADS" in
 250  posix)
 251     THREADLIBS=-lpthread
 252     THREADSPEC=-lpthread
 253     THREADOBJS=posix-threads.lo
 254     THREADH=posix-threads.h
 255     # MIT pthreads doesn't seem to have the mutexattr functions.
 256     # But for now we don't check for it.  We just assume you aren't
 257     # using MIT pthreads.
 258     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 259     ;;
 260
 261  qt)
 262     THREADDEPS='$(top_builddir)/../qthreads/libgcjcoop.la'
 263     # We include the path to the qthreads build directory.
 264     # See Makefile.am to understand why.
 265     THREADLIBS="$THREADDEPS -L\$(here)/../qthreads/$libsubdir"
 266     THREADSPEC='-lgcjcoop'
 267     THREADOBJS=quick-threads.lo
 268     THREADINCS='-I$(top_srcdir)/../qthreads'
 269     THREADH=quick-threads.h
 270     ;;
 271
 272  none)
 273     THREADOBJS=no-threads.lo
 274     THREADH=no-threads.h
 275     ;;
 276 esac
 277 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 278 AC_SUBST(THREADLIBS)
 279 AC_SUBST(THREADINCS)
 280 AC_SUBST(THREADDEPS)
 281 AC_SUBST(THREADOBJS)
 282 AC_SUBST(THREADSPEC)
 283
 284 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 285
 286 CANADIAN=no
 287 NULL_TARGET=no
 288 NATIVE=yes
 289
 290 # Find eh-common.h and support headers.  If we're in the tree with
 291 # gcc, then look there.  Otherwise look in compat-include.  If all else
 292 # fails, just hope the user has set things up somehow.
 293 if test -r $srcdir/../gcc/eh-common.h; then
 294    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 295 else
 296    if test -d $srcdir/../compat-include; then
 297       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 298    else
 299       EH_COMMON_INCLUDE=
 300    fi
 301 fi
 302
 303 if test -n "${with_cross_host}"; then
 304    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 305    # may not work correctly, because the compiler may not be able to
 306    # link executables.
 307
 308    # We assume newlib.  This lets us hard-code the functions we know
 309    # we'll have.
 310    AC_DEFINE(HAVE_MEMMOVE)
 311    AC_DEFINE(HAVE_MEMCPY)
 312    AC_DEFINE(HAVE_STRERROR)
 313    AC_DEFINE(HAVE_GMTIME_R)
 314    AC_DEFINE(HAVE_LOCALTIME_R)
 315    dnl This is only for POSIX threads.
 316    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 317    dnl We also assume we are using gcc, which provides alloca.
 318    AC_DEFINE(HAVE_ALLOCA)
 319
 320    ZLIBSPEC=-lzgcj
 321
 322    # If Canadian cross, then don't pick up tools from the build
 323    # directory.
 324    if test "$build" != "$with_cross_host"; then
 325       CANADIAN=yes
 326       EH_COMMON_INCLUDE=
 327       GCJ="${target_alias}-gcj"
 328    else
 329       GCJ=
 330    fi
 331    NATIVE=no
 332 else
 333    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 334    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r)
 335    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath)
 336    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 337    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 338
 339    AC_CHECK_FUNCS(gethostbyname_r, [
 340      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 341      # There are two different kinds of gethostbyname_r.
 342      # We look for the one that returns `int'.
 343      # Hopefully this check is robust enough.
 344      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 345        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 346
 347      case " $GCINCS " in
 348      *" -D_REENTRANT "*) ;;
 349      *)
 350         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 351         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 352         [libjava_cv_gethostbyname_r_needs_reentrant],
 353         [ AC_LANG_SAVE
 354           AC_LANG_CPLUSPLUS
 355           AC_TRY_COMPILE([#include <netdb.h>],
 356             [gethostbyname_r("", 0, 0);],
 357             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 358                 CPPFLAGS_SAVE="$CPPFLAGS"
 359                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 360                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 361                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 362                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 363                 CPPFLAGS="$CPPFLAGS_SAVE"
 364           ])
 365           AC_LANG_RESTORE
 366         ])
 367         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 368           AC_DEFINE(GETHOSTBYNAME_R_NEEDS_REENTRANT, 1, [Define if gethostbyname_r is only declared if _REENTRANT is defined])
 369         fi
 370      ;;
 371      esac
 372
 373      AC_CACHE_CHECK([for struct hostent_data],
 374         [libjava_cv_struct_hostent_data], [dnl
 375         AC_TRY_COMPILE([
 376 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 377 # define _REENTRANT 1
 378 #endif
 379 #include <netdb.h>], [struct hostent_data data;],
 380           [libjava_cv_struct_hostent_data=yes],
 381           [libjava_cv_struct_hostent_data=no])])
 382      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 383        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 384          [Define if struct hostent_data is defined in netdb.h])
 385      fi
 386    ])
 387
 388    AC_CHECK_FUNCS(gethostbyaddr_r, [
 389      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 390      # There are two different kinds of gethostbyaddr_r.
 391      # We look for the one that returns `int'.
 392      # Hopefully this check is robust enough.
 393      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 394        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 395
 396    AC_CHECK_FUNCS(gethostname, [
 397      AC_DEFINE(HAVE_GETHOSTNAME)
 398      AC_EGREP_HEADER(gethostname, unistd.h, [
 399        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 400
 401    # Look for these functions in the thread library, but only bother
 402    # if using POSIX threads.
 403    if test "$THREADS" = posix; then
 404       save_LIBS="$LIBS"
 405       LIBS="$LIBS $THREADLIBS"
 406       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 407       # E.g., Solaris.
 408       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 409
 410       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 411       # Solaris 7 the name librt is preferred.
 412       AC_CHECK_FUNCS(sched_yield, , [
 413         AC_CHECK_LIB(rt, sched_yield, [
 414           AC_DEFINE(HAVE_SCHED_YIELD)
 415           THREADLIBS="$THREADLIBS -lrt"
 416           THREADSPEC="$THREADSPEC -lrt"], [
 417           AC_CHECK_LIB(posix4, sched_yield, [
 418             AC_DEFINE(HAVE_SCHED_YIELD)
 419             THREADLIBS="$THREADLIBS -lposix4"
 420             THREADSPEC="$THREADSPEC -lposix4"])])])
 421       LIBS="$save_LIBS"
 422
 423       # We can save a little space at runtime if the mutex has m_count
 424       # or __m_count.  This is a nice hack for Linux.
 425       AC_TRY_COMPILE([#include <pthread.h>], [
 426           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 427         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 428         AC_TRY_COMPILE([#include <pthread.h>], [
 429             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 430           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 431    fi
 432
 433    # We require a way to get the time.
 434    time_found=no
 435    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 436    if test "$time_found" = no; then
 437       AC_MSG_ERROR([no function found to get the time])
 438    fi
 439
 440    AC_CHECK_FUNCS(memmove)
 441
 442    # We require memcpy.
 443    memcpy_found=no
 444    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 445    if test "$memcpy_found" = no; then
 446       AC_MSG_ERROR([memcpy is required])
 447    fi
 448
 449    # Some library-finding code we stole from Tcl.
 450    #--------------------------------------------------------------------
 451    #    Check for the existence of the -lsocket and -lnsl libraries.
 452    #    The order here is important, so that they end up in the right
 453    #    order in the command line generated by make.  Here are some
 454    #    special considerations:
 455    #    1. Use "connect" and "accept" to check for -lsocket, and
 456    #       "gethostbyname" to check for -lnsl.
 457    #    2. Use each function name only once:  can't redo a check because
 458    #       autoconf caches the results of the last check and won't redo it.
 459    #    3. Use -lnsl and -lsocket only if they supply procedures that
 460    #       aren't already present in the normal libraries.  This is because
 461    #       IRIX 5.2 has libraries, but they aren't needed and they're
 462    #       bogus:  they goof up name resolution if used.
 463    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 464    #       To get around this problem, check for both libraries together
 465    #       if -lsocket doesn't work by itself.
 466    #--------------------------------------------------------------------
 467
 468    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 469     [gcj_cv_lib_sockets=
 470      gcj_checkBoth=0
 471      unset ac_cv_func_connect
 472      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 473      if test "$gcj_checkSocket" = 1; then
 474          unset ac_cv_func_connect
 475          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 476                       gcj_checkBoth=1)
 477      fi
 478      if test "$gcj_checkBoth" = 1; then
 479          gcj_oldLibs=$LIBS
 480          LIBS="$LIBS -lsocket -lnsl"
 481          unset ac_cv_func_accept
 482          AC_CHECK_FUNC(accept,
 483                        [gcj_checkNsl=0
 484                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 485          unset ac_cv_func_accept
 486          LIBS=$gcj_oldLibs
 487      fi
 488      unset ac_cv_func_gethostbyname
 489      gcj_oldLibs=$LIBS
 490      LIBS="$LIBS $gcj_cv_lib_sockets"
 491      AC_CHECK_FUNC(gethostbyname, ,
 492                    [AC_CHECK_LIB(nsl, main,
 493                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 494      unset ac_cv_func_gethostbyname
 495      LIBS=$gcj_oldLIBS
 496    ])
 497    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 498
 499    if test "$with_system_zlib" = yes; then
 500       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 501    else
 502       ZLIBSPEC=-lzgcj
 503    fi
 504
 505    # On Solaris, and maybe other architectures, the Boehm collector
 506    # requires -ldl.
 507    if test "$GC" = boehm; then
 508       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 509    fi
 510
 511    if test -d "$libgcj_basedir/../gcc/java"; then
 512       GCJ=
 513    else
 514       CANADIAN=yes
 515       NULL_TARGET=yes
 516       GCJ=gcj
 517    fi
 518 fi
 519
 520 ZLIBS=
 521 ZDEPS=
 522 ZINCS=
 523 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 524    # We include the path to the zlib build directory.
 525    # See Makefile.am to understand why.
 526    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 527    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 528    ZINCS='-I$(top_srcdir)/../zlib'
 529 else
 530    ZLIBS="$ZLIBSPEC"
 531 fi
 532 AC_SUBST(ZLIBS)
 533 AC_SUBST(ZDEPS)
 534 AC_SUBST(ZINCS)
 535 AC_SUBST(DIVIDESPEC)
 536
 537 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 538 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 539 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 540 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 541 AC_SUBST(EH_COMMON_INCLUDE)
 542
 543 # Determine gcj version number.
 544 if test "$GCJ" = ""; then
 545    if test -z "${with_multisubdir}"; then
 546       builddotdot=.
 547    else
 548 changequote(<<,>>)
 549       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 550 changequote([,])
 551    fi
 552    dir="`cd ${builddotdot}/../../gcc && pwd`"
 553    GCJ="$dir/gcj -B$dir/"
 554 fi
 555 changequote(<<,>>)
 556 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 557 changequote([,])
 558 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 559
 560 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 561 # we want to continue to support that version.
 562 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 563 cat > conftest.java << 'END'
 564 public class conftest { }
 565 END
 566 use_fuse=yes
 567 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 568    conftest.java > /dev/null 2>&1 \
 569    || use_fuse=no
 570 rm -f conftest.java
 571 if test "$use_fuse" = no; then
 572    DIVIDESPEC=
 573 fi
 574 AC_MSG_RESULT($use_fuse)
 575
 576 AC_SUBST(AM_RUNTESTFLAGS)
 577
 578 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 579 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 580 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 581 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h)
 582 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 583 dnl for now.  If you change this, you also must update natFile.cc.
 584 AC_CHECK_HEADERS(dirent.h)
 585
 586 AC_CHECK_TYPE([ssize_t], [int])
 587
 588 AC_MSG_CHECKING([for in_addr_t])
 589 AC_TRY_COMPILE([#include <sys/types.h>
 590 #if STDC_HEADERS
 591 #include <stdlib.h>
 592 #include <stddef.h>
 593 #endif
 594 #if HAVE_NETINET_IN_H
 595 #include <netinet/in.h>
 596 #endif], [in_addr_t foo;],
 597   [AC_DEFINE([HAVE_IN_ADDR_T])
 598    AC_MSG_RESULT(yes)],
 599   [AC_MSG_RESULT(no)])
 600
 601 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 602 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 603   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 604    AC_MSG_RESULT(yes)],
 605   [AC_MSG_RESULT(no)])
 606
 607 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 608 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 609   [AC_DEFINE(HAVE_INET6)
 610    AC_MSG_RESULT(yes)],
 611   [AC_MSG_RESULT(no)])
 612
 613 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 614 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 615   [AC_DEFINE(HAVE_SOCKLEN_T)
 616    AC_MSG_RESULT(yes)],
 617   [AC_MSG_RESULT(no)])
 618
 619 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 620 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 621   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 622    AC_MSG_RESULT(yes)],
 623   [AC_MSG_RESULT(no)
 624    AC_MSG_CHECKING([for global timezone variable])
 625    dnl FIXME: we don't want a link check here because that won't work
 626    dnl when cross-compiling.  So instead we make an assumption that
 627    dnl the header file will mention timezone if it exists.
 628    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 629      [AC_DEFINE(HAVE_TIMEZONE)
 630       AC_MSG_RESULT(yes)],
 631      [AC_MSG_RESULT(no)])])
 632
 633 AC_FUNC_ALLOCA
 634
 635 AC_CHECK_PROGS(PERL, perl, false)
 636
 637 case "${host}" in
 638   i?86-*-linux*)
 639     SIGNAL_HANDLER=include/i386-signal.h
 640         ;;
 641   sparc-sun-solaris*)
 642     SIGNAL_HANDLER=include/sparc-signal.h
 643         ;;
 644   *)
 645     SIGNAL_HANDLER=include/default-signal.h
 646         ;;
 647 esac
 648
 649 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 650
 651 if test "${multilib}" = "yes"; then
 652   multilib_arg="--enable-multilib"
 653 else
 654   multilib_arg=
 655 fi
 656
 657 here=`pwd`
 658 AC_SUBST(here)
 659
 660 AC_OUTPUT(Makefile libgcj.spec gcj/Makefile include/Makefile testsuite/Makefile,
 661 [if test -n "$CONFIG_FILES"; then
 662   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 663 fi],
 664 srcdir=${srcdir}
 665 host=${host}
 666 target=${target}
 667 with_multisubdir=${with_multisubdir}
 668 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 669 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 670 libgcj_basedir=${libgcj_basedir}
 671 CC="${CC}"
 672 CXX="${CXX}"
 673 )