libada/configure.ac

   1 # Configure script for libada.
   2 #   Copyright 2003, 2004, 2009 Free Software Foundation, Inc.
   3 #
   4 # This file is free software; you can redistribute it and/or modify it
   5 # under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; see the file COPYING3.  If not see
  16 # <http://www.gnu.org/licenses/>.
  17
  18 sinclude(../config/acx.m4)
  19 sinclude(../config/multi.m4)
  20 sinclude(../config/override.m4)
  21
  22 AC_INIT
  23 AC_PREREQ([2.64])
  24
  25 AC_CONFIG_SRCDIR([Makefile.in])
  26
  27 # Determine the host, build, and target systems
  28 AC_CANONICAL_BUILD
  29 AC_CANONICAL_HOST
  30 AC_CANONICAL_TARGET
  31 target_alias=${target_alias-$host_alias}
  32
  33 # Determine the noncanonical target name, for directory use.
  34 ACX_NONCANONICAL_TARGET
  35
  36 # Determine the target- and build-specific subdirectories
  37 GCC_TOPLEV_SUBDIRS
  38
  39 # Command-line options.
  40 # Very limited version of AC_MAINTAINER_MODE.
  41 AC_ARG_ENABLE([maintainer-mode],
  42   [AC_HELP_STRING([--enable-maintainer-mode],
  43                  [enable make rules and dependencies not useful (and
  44                   sometimes confusing) to the casual installer])],
  45   [case ${enable_maintainer_mode} in
  46      yes) MAINT='' ;;
  47      no) MAINT='#' ;;
  48      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
  49    esac
  50    maintainer_mode=${enableval}],
  51   [MAINT='#'])
  52 AC_SUBST([MAINT])dnl
  53
  54 AM_ENABLE_MULTILIB(, ..)
  55 # Calculate toolexeclibdir
  56 # Also toolexecdir, though it's only used in toolexeclibdir
  57 case ${enable_version_specific_runtime_libs} in
  58   yes)
  59     # Need the gcc compiler version to know where to install libraries
  60     # and header files if --enable-version-specific-runtime-libs option
  61     # is selected.
  62     toolexecdir='$(libdir)/gcc/$(target_alias)'
  63     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  64     ;;
  65   no)
  66     if test -n "$with_cross_host" &&
  67        test x"$with_cross_host" != x"no"; then
  68       # Install a library built with a cross compiler in tooldir, not libdir.
  69       toolexecdir='$(exec_prefix)/$(target_alias)'
  70       toolexeclibdir='$(toolexecdir)/lib'
  71     else
  72       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  73       toolexeclibdir='$(libdir)'
  74     fi
  75     multi_os_directory=`$CC -print-multi-os-directory`
  76     case $multi_os_directory in
  77       .) ;; # Avoid trailing /.
  78       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  79     esac
  80     ;;
  81 esac
  82 AC_SUBST(toolexecdir)
  83 AC_SUBST(toolexeclibdir)
  84 #TODO: toolexeclibdir is currently disregarded
  85
  86 # Check the compiler.
  87 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  88 # We must force CC to /not/ be precious variables; otherwise
  89 # the wrong, non-multilib-adjusted value will be used in multilibs.
  90 # As a side effect, we have to subst CFLAGS ourselves.
  91
  92 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  93 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  94 AC_PROG_CC
  95 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  96
  97 AC_SUBST(CFLAGS)
  98
  99 AC_ARG_ENABLE([shared],
 100 [AC_HELP_STRING([--disable-shared],
 101                 [don't provide a shared libgnat])],
 102 [
 103 case $enable_shared in
 104   yes | no) ;;
 105   *)
 106     enable_shared=no
 107     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 108     for pkg in $enableval; do
 109       case $pkg in
 110         ada | libada)
 111           enable_shared=yes ;;
 112       esac
 113     done
 114     IFS="$ac_save_ifs"
 115     ;;
 116 esac
 117 ], [enable_shared=yes])
 118 AC_SUBST([enable_shared])
 119
 120 # These must be passed down, or are needed by gcc/libgcc.mvars
 121 AC_PROG_AWK
 122 AC_PROG_LN_S
 123
 124 # Determine what to build for 'gnatlib'
 125 if test $build = $target \
 126    && test ${enable_shared} = yes ; then
 127   # Note that build=target is almost certainly the wrong test; FIXME
 128   default_gnatlib_target="gnatlib-shared"
 129 else
 130   default_gnatlib_target="gnatlib-plain"
 131 fi
 132 AC_SUBST([default_gnatlib_target])
 133
 134 warn_cflags=
 135 if test "x$GCC" = "xyes"; then
 136   warn_cflags='$(GCC_WARN_CFLAGS)'
 137 fi
 138 AC_SUBST(warn_cflags)
 139
 140 # Output: create a Makefile.
 141 AC_CONFIG_FILES([Makefile])
 142
 143 AC_OUTPUT