libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # (1) We use an abnormal CXX (without library references), so we
 146 # must cache it under a different name.
 147 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
 148 # the non-multilib-adjusted value will be used in multilibs.
 149 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
 150 # (4) As another side effect, automake doesn't automatically include them
 151 # in Makefile.in.
 152 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 153 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 154 # used in later tests.  This may not be necessary in libjava; I don't know.
 155 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 156 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 157 save_CXXFLAGS="$CXXFLAGS"
 158 CXXFLAGS="$CXXFLAGS -fno-builtin"
 159 AC_PROG_CC
 160 AC_PROG_CXX
 161 CXXFLAGS="$save_CXXFLAGS"
 162 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 163 AC_SUBST(CFLAGS)
 164 AC_SUBST(CXXFLAGS)
 165 AC_SUBST(LDFLAGS)
 166
 167 AM_INIT_AUTOMAKE([1.9.0])
 168
 169 AC_CHECK_TOOL(AS, as)
 170 AC_CHECK_TOOL(LD, ld)
 171 AC_CHECK_TOOL(AR, ar)
 172 AC_CHECK_TOOL(RANLIB, ranlib, :)
 173 AC_PROG_AWK
 174 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 175 AC_PATH_PROG([ZIP], [zip], no)
 176 AC_PATH_PROG([UNZIP], [unzip], unzip)
 177
 178 # We need a jar that supports -@.  This is a GNU extension.
 179 if test "$JAR" != no; then
 180    rm -f config-test.jar
 181    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 182    if test -f config-test.jar; then
 183      rm -f config-test.jar
 184    else
 185      JAR=no
 186    fi
 187 fi
 188
 189 # Prefer the jar we found, but fall back to our jar script.
 190 if test "$JAR" = no; then
 191   if test "$ZIP" = no; then
 192     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 193   else
 194     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 195     JAR=`pwd`/scripts/jar
 196   fi
 197 fi
 198
 199 AC_PROG_INSTALL
 200
 201 AM_MAINTAINER_MODE
 202
 203 AC_EXEEXT
 204
 205 # configure.host sets the following important variables
 206 #       libgcj_cflags    - host specific C compiler flags
 207 #       libgcj_cxxflags  - host specific C++ compiler flags
 208 #       libgcj_javaflags - host specific Java compiler flags
 209
 210 libgcj_cflags=
 211 libgcj_cxxflags=
 212 libgcj_javaflags=
 213
 214 . ${srcdir}/configure.host
 215
 216 ACX_PROG_LD_GNU_SYMBOLIC
 217 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 218 if test -z "$libgcj_ld_symbolic"; then
 219   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 220 fi
 221
 222 LIBGCJ_CFLAGS="${libgcj_cflags}"
 223 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 224 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 225 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 226 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 227 AC_SUBST(LIBGCJ_CFLAGS)
 228 AC_SUBST(LIBGCJ_CXXFLAGS)
 229 AC_SUBST(LIBGCJ_JAVAFLAGS)
 230 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 231 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 232
 233 # Only use libltdl for non-newlib builds.
 234 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 235    AC_LTDL_SHLIBPATH
 236 fi
 237
 238 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 239
 240 # See if the user has requested runtime debugging.
 241 LIBGCJDEBUG="disable"
 242 AC_SUBST(LIBGCJDEBUG)
 243 AC_ARG_ENABLE(libgcj-debug,
 244   AS_HELP_STRING([--enable-libgcj-debug],
 245                  [enable runtime debugging code]),
 246   [if test "$enable_libgcj_debug" = yes; then
 247     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 248     LIBGCJDEBUG="enable"
 249   fi])
 250
 251 AC_ARG_WITH([escher],
 252          AS_HELP_STRING([--with-escher=ABS.PATH],
 253                         [specify path to escher dir or JAR for X peers]))
 254 case "$with_escher" in
 255 "")
 256         use_escher=false
 257         ;;
 258 "no")
 259         use_escher=false
 260         ;;
 261 "yes")
 262         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 263         ;;
 264 *)
 265         use_escher=true
 266         ;;
 267 esac
 268
 269 # Determine which AWT peer libraries to build
 270 AC_ARG_ENABLE(java-awt,
 271   AS_HELP_STRING([--enable-java-awt],
 272                  [list of AWT peer implementations to be built]))
 273
 274 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 275 use_xlib_awt=""
 276 use_gtk_awt=""
 277 use_qt_awt=""
 278 use_x_awt=""
 279 # The default toolkit to use is the first one specified.
 280 TOOLKIT=
 281 AC_SUBST(TOOLKIT)
 282
 283 for peer in $peerlibs ; do
 284   case $peer in
 285     xlib)
 286       if test "$no_x" = yes; then
 287         echo "*** xlib peers requested but no X library available" 1>&2
 288         exit 1
 289       else
 290         use_xlib_awt="yes"
 291         if test -z "$TOOLKIT"; then
 292            TOOLKIT=gnu.awt.xlib.XToolkit
 293         fi
 294       fi
 295       ;;
 296     gtk)
 297       if test "$no_x" = yes; then
 298          echo "*** gtk peers requested but no X library available" 1>&2
 299          exit 1
 300       else
 301          use_gtk_awt=yes
 302          if test -z "$TOOLKIT"; then
 303             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 304          fi
 305       fi
 306       ;;
 307     qt)
 308       if test "$no_x" = yes; then
 309          # Perhaps we should admit the possibility of embedded Qt.
 310          echo "*** Qt peers requested but no X library available" 1>&2
 311          exit 1
 312       else
 313          use_qt_awt=yes
 314          if test -z "$TOOLKIT"; then
 315             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 316          fi
 317       fi
 318       ;;
 319     x)
 320       use_x_awt=yes
 321       if test -z "$TOOLKIT"; then
 322          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 323       fi
 324       ;;
 325     no)
 326       use_xlib_awt=
 327       use_gtk_awt=
 328       use_qt_awt=
 329       use_x_awt=
 330       break
 331       ;;
 332     *)
 333       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 334       exit 1
 335   esac
 336 done
 337
 338 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 339 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 340
 341 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 342
 343 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 344
 345 # Create standard.omit based on decisions we just made.
 346 cp $srcdir/standard.omit.in standard.omit
 347 if test "$use_xlib_awt" != yes; then
 348    echo gnu/awt/xlib >> standard.omit
 349    echo gnu/gcj/xlib >> standard.omit
 350 fi
 351 if test "$use_x_awt" != yes; then
 352    echo gnu/java/awt/peer/x >> standard.omit
 353 fi
 354
 355 # Tools that need to be compiled against classpath's tools classes
 356 : > vm-tools-packages
 357 for package in gnu/gcj/tools/gc_analyze ; do
 358     echo $package >> standard.omit
 359     echo $package >> vm-tools-packages
 360 done
 361
 362 if test -z "${with_multisubdir}"; then
 363    builddotdot=.
 364 else
 365    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 366 fi
 367
 368 NATIVE=yes
 369
 370 # Which gcj and host gcj (for ecjx) do we use?
 371 which_gcj=default
 372 host_exeext=${ac_exeext}
 373 GCJ_FOR_ECJX=
 374 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 375 if test -n "${with_cross_host}"; then
 376   # We are being configured with a cross compiler. We can't
 377   # use ac_exeext, because that is for the target platform.
 378   NATIVE=no
 379   cross_host_exeext=
 380   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 381   case "${with_cross_host}" in
 382      *mingw* | *cygwin*)
 383          cross_host_exeext=.exe
 384      ;;
 385   esac
 386   host_exeext=${cross_host_exeext}
 387   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 388      if test x"$build_noncanonical" = x"$with_cross_host"; then
 389         # Ordinary cross (host!=target and host=build)
 390         which_gcj=built
 391      else
 392         # Canadian cross (host!=target and host!=build)
 393         which_gcj=cross
 394      fi
 395   else
 396      which_gcj=cross
 397   fi
 398 else
 399   # We are being configured with a native or crossed-native compiler
 400   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 401      if test x"$build" = x"$host"; then
 402         # True native build (host=target and host=build)
 403         which_gcj=built
 404      else
 405         # Crossed-native build (host=target and host!=build)
 406         which_gcj=cross
 407      fi
 408   else
 409      which_gcj=path
 410   fi
 411 fi
 412 case "${which_gcj}" in
 413    built)
 414       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 415       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 416    ;;
 417    cross)
 418       if test "x${with_newlib}" = "xyes"; then
 419          # FIXME (comment): Why is this needed?
 420          GCC_UNWIND_INCLUDE=
 421          GCJ="${target_noncanonical}-gcj"
 422       else
 423          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 424       fi
 425       GCJH='$(target_noncanonical)-gcjh'
 426    ;;
 427    path)
 428       GCJ="gcj -B`${PWDCMD-pwd}`/"
 429       GCJH=gcjh
 430    ;;
 431 esac
 432 JAVAC="$GCJ -C"
 433 export JAVAC
 434
 435 AC_SUBST(GCJ_FOR_ECJX)
 436 AC_SUBST(GCJH)
 437 AC_SUBST(host_exeext)
 438
 439 # Create it, so that compile/link tests don't fail
 440 test -f libgcj.spec || touch libgcj.spec
 441
 442
 443
 444 # Set up to configure Classpath.
 445 # FIXME: no supported way to pass args in autoconf.
 446 # Disable tool wrappers to avoid ltdl.h configure check.
 447 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 448 ac_configure_args="$ac_configure_args --disable-load-library"
 449 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 450 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 451 dir1=`cd $srcdir && pwd`
 452 dir2=`pwd`
 453 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 454 ac_configure_args="$ac_configure_args --disable-core-jni"
 455 dnl FIXME?
 456 ac_configure_args="$ac_configure_args --disable-examples"
 457 ac_configure_args="$ac_configure_args --with-glibj=build"
 458 if test "$plugin_enabled" != yes; then
 459   ac_configure_args="$ac_configure_args --disable-plugin"
 460 fi
 461 if test "$gconf_enabled" != yes; then
 462   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 463   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 464 fi
 465 if test "$use_gtk_awt" != yes; then
 466   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 467 fi
 468 if test "$use_qt_awt" != yes; then
 469   ac_configure_args="$ac_configure_args --disable-qt-peer"
 470 else
 471   # We need this as qt is disabled by default in classpath.
 472   ac_configure_args="$ac_configure_args --enable-qt-peer"
 473 fi
 474 if test "$use_x_awt" != yes; then
 475   ac_configure_args="$ac_configure_args --without-escher"
 476 else
 477   # We need this as escher is disabled by default in classpath.
 478   if test "$use_escher" != true; then
 479     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 480   else
 481     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 482   fi
 483 fi
 484 if test "x$BUILD_GJDOC" = xno; then
 485   ac_configure_args="$ac_configure_args --disable-gjdoc"
 486 fi
 487 # -Werror causes unavoidable problems in code using alsa.
 488 ac_configure_args="$ac_configure_args --disable-regen-headers"
 489 ac_configure_args="$ac_configure_args --disable-Werror"
 490 dnl --with-gcj=$GCJ
 491 dnl --with-javah=$GCJH
 492 dnl gtk-cairo -- just export here...
 493 dnl --enable-regen-headers?
 494
 495 # Only use libltdl for non-newlib builds.
 496 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 497    AC_LIBLTDL_CONVENIENCE
 498    AC_LIBTOOL_DLOPEN
 499    DIRLTDL=libltdl
 500    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 501    # Sigh.  Libtool's macro doesn't do the right thing.
 502    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 503    # FIXME: this is a hack.
 504    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 505    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 506 fi
 507 AC_SUBST(INCLTDL)
 508 AC_SUBST(LIBLTDL)
 509 AC_SUBST(DIRLTDL)
 510 AC_PROG_LIBTOOL
 511 AM_PROG_GCJ
 512 AM_PROG_CC_C_O
 513
 514 AC_CONFIG_SUBDIRS(classpath libltdl)
 515
 516 # The -no-testsuite modules omit the test subdir.
 517 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 518
 519 # Should the runtime set system properties by examining the
 520 # environment variable GCJ_PROPERTIES?
 521 AC_ARG_ENABLE(getenv-properties,
 522   AS_HELP_STRING([--disable-getenv-properties],
 523                  [don't set system properties from GCJ_PROPERTIES]))
 524
 525 # Whether GCJ_PROPERTIES is used depends on the target.
 526 if test -z "$enable_getenv_properties"; then
 527    enable_getenv_properties=${enable_getenv_properties_default-yes}
 528 fi
 529 if test "$enable_getenv_properties" = no; then
 530    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 531      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 532 fi
 533
 534 # Whether we should use arguments to main()
 535 if test -z "$enable_main_args"; then
 536    enable_main_args=${enable_main_args_default-yes}
 537 fi
 538 if test "$enable_main_args" = no; then
 539    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 540 fi
 541
 542
 543 # Should we use hashtable-based synchronization?
 544 # Currently works only for Linux X86/ia64
 545 # Typically faster and more space-efficient
 546 AC_ARG_ENABLE(hash-synchronization,
 547   AS_HELP_STRING([--enable-hash-synchronization],
 548                  [use global hash table for monitor locks]))
 549
 550 if test -z "$enable_hash_synchronization"; then
 551    enable_hash_synchronization=$enable_hash_synchronization_default
 552 fi
 553
 554
 555 install_ecj_jar=no
 556 ECJ_BUILD_JAR=
 557 ECJ_JAR=
 558 AC_ARG_WITH(ecj-jar,
 559         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 560         [ECJ_JAR=$withval],
 561         [if test -f $multi_basedir/ecj.jar; then
 562            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 563            ECJ_JAR='$(jardir)/ecj.jar'
 564            install_ecj_jar=yes
 565          fi])
 566 AC_SUBST(ECJ_BUILD_JAR)
 567 AC_SUBST(ECJ_JAR)
 568 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 569 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 570
 571 AC_ARG_WITH(java-home,
 572   AS_HELP_STRING([--with-java-home=DIRECTORY],
 573                  [value of java.home system property]),
 574                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 575 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 576 AC_SUBST(JAVA_HOME)
 577
 578 suppress_libgcj_bc=no
 579 AC_ARG_ENABLE(libgcj-bc,
 580   AS_HELP_STRING([--enable-libgcj-bc],
 581                  [enable(default) or disable BC ABI for portions of libgcj]),
 582   [if test "$enable_libgcj_bc" = "no"; then
 583      suppress_libgcj_bc=yes
 584    fi])
 585 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 586
 587 build_libgcj_reduced_reflection=no
 588 AC_ARG_ENABLE(reduced-reflection,
 589   AS_HELP_STRING([--enable-reduced-reflection],
 590                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 591   [if test "$enable_reduced_reflection" = "yes"; then
 592      build_libgcj_reduced_reflection=yes
 593    fi])
 594 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 595
 596 # What is the native OS API for MinGW?
 597 AC_ARG_WITH(win32-nlsapi,
 598   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 599                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 600 [case "${withval}" in
 601   ansi) with_win32_nlsapi=ansi ;;
 602   unicows) with_win32_nlsapi=unicows ;;
 603   unicode) with_win32_nlsapi=unicode ;;
 604   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 605 esac],[with_win32_nlsapi=ansi])
 606
 607 case "${with_win32_nlsapi}" in
 608   unicows | unicode)
 609     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 610       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 611     ;;
 612 esac
 613
 614 # configure.host sets slow_pthread_self if the synchronization code should
 615 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 616 if test "${slow_pthread_self}" = "yes"; then
 617   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 618     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 619 fi
 620
 621 # Check for gc debugging.  This option is handled both here and in the GC.
 622 AC_ARG_ENABLE(gc-debug,
 623    AS_HELP_STRING([--enable-gc-debug],
 624                   [include full support for pointer backtracing etc.]),
 625 [ if test "$enable_gc_debug" = "yes"; then
 626     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 627               [Define if we want to use debug calls into the garbage collector.])
 628   fi])
 629
 630 # See if the user has the interpreter included.
 631 AC_ARG_ENABLE(interpreter,
 632   AS_HELP_STRING([--enable-interpreter],
 633                  [enable interpreter]),
 634   [if test "$enable_interpreter" = yes; then
 635     # This can also be set in configure.host.
 636     libgcj_interpreter=yes
 637   elif test "$enable_interpreter" = no; then
 638     libgcj_interpreter=no
 639   fi])
 640
 641 if test "$libgcj_interpreter" = yes; then
 642    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 643 fi
 644 INTERPRETER="$libgcj_interpreter"
 645 AC_SUBST(INTERPRETER)
 646 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 647
 648 AC_MSG_CHECKING([for exception model to use])
 649 AC_LANG_PUSH(C++)
 650 AC_ARG_ENABLE(sjlj-exceptions,
 651   AS_HELP_STRING([--enable-sjlj-exceptions],
 652                  [force use of builtin_setjmp for exceptions]),
 653 [:],
 654 [dnl Botheration.  Now we've got to detect the exception model.
 655 dnl Link tests against libgcc.a are problematic since -- at least
 656 dnl as of this writing -- we've not been given proper -L bits for
 657 dnl single-tree newlib and libgloss.
 658 dnl
 659 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 660 dnl conftest files before we got a change to grep them first.
 661 cat > conftest.$ac_ext << EOF
 662 [#]line __oline__ "configure"
 663 struct S { ~S(); };
 664 void bar();
 665 void foo()
 666 {
 667   S s;
 668   bar();
 669 }
 670 EOF
 671 old_CXXFLAGS="$CXXFLAGS"
 672 CXXFLAGS=-S
 673 if AC_TRY_EVAL(ac_compile); then
 674   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 675     enable_sjlj_exceptions=yes
 676   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 677     enable_sjlj_exceptions=no
 678   fi
 679 fi
 680 CXXFLAGS="$old_CXXFLAGS"
 681 rm -f conftest*])
 682 if test x$enable_sjlj_exceptions = xyes; then
 683   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 684         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 685   ac_exception_model_name=sjlj
 686 elif test x$enable_sjlj_exceptions = xno; then
 687   ac_exception_model_name="call frame"
 688 else
 689   AC_MSG_ERROR([unable to detect exception model])
 690 fi
 691 AC_LANG_POP(C++)
 692 AC_MSG_RESULT($ac_exception_model_name)
 693
 694 # If we are non using SJLJ exceptions, and this host does not have support
 695 # for unwinding from a signal handler, enable checked dereferences and divides.
 696 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 697   CHECKREFSPEC=-fcheck-references
 698   DIVIDESPEC=-fuse-divide-subroutine
 699   EXCEPTIONSPEC=
 700 fi
 701
 702 # See if the user wants to disable java.net.  This is the mildly
 703 # ugly way that we admit that target-side configuration sucks.
 704 AC_ARG_ENABLE(java-net,
 705   AS_HELP_STRING([--disable-java-net],
 706                  [disable java.net]))
 707
 708 # Whether java.net is built by default can depend on the target.
 709 if test -z "$enable_java_net"; then
 710    enable_java_net=${enable_java_net_default-yes}
 711 fi
 712 if test "$enable_java_net" = no; then
 713    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 714 fi
 715
 716 # See if the user wants to configure without libffi.  Some
 717 # architectures don't support it, and default values are set in
 718 # configure.host.
 719 AC_ARG_WITH(libffi,
 720   AS_HELP_STRING([--without-libffi],
 721                  [don't use libffi]),
 722   [:],
 723   [with_libffi=${with_libffi_default-yes}])
 724
 725 LIBFFI=
 726 LIBFFIINCS=
 727 if test "$with_libffi" != no; then
 728    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 729    LIBFFI=../libffi/libffi_convenience.la
 730    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 731 fi
 732 AC_SUBST(LIBFFI)
 733 AC_SUBST(LIBFFIINCS)
 734
 735 # See if the user wants to disable JVMPI support.
 736 AC_ARG_ENABLE(jvmpi,
 737   AS_HELP_STRING([--disable-jvmpi],
 738                  [disable JVMPI support]))
 739
 740 if test "$enable_jvmpi" != no; then
 741     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 742 fi
 743
 744 # If the target is an eCos system, use the appropriate eCos
 745 # I/O routines.
 746 # FIXME: this should not be a local option but a global target
 747 # system; at present there is no eCos target.
 748 TARGET_ECOS=${PROCESS-"no"}
 749 AC_ARG_WITH(ecos,
 750 [  --with-ecos             enable runtime eCos target support],
 751 TARGET_ECOS="$with_ecos"
 752 )
 753
 754 case "$TARGET_ECOS" in
 755    no) case "$host" in
 756       *mingw*)
 757             PLATFORM=Win32
 758             PLATFORMNET=Win32
 759             PLATFORMH=win32.h
 760         CHECK_FOR_BROKEN_MINGW_LD
 761       ;;
 762       *)
 763             PLATFORM=Posix
 764             PLATFORMNET=Posix
 765             PLATFORMH=posix.h
 766       ;;
 767       esac
 768       ;;
 769    *)
 770       PLATFORM=Ecos
 771       PLATFORMNET=NoNet
 772       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 773       PLATFORMH=posix.h
 774       ;;
 775 esac
 776 AC_SUBST(PLATFORM)
 777 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 778
 779 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 780                                       [Define if you have int32_t and uint32_t.]))
 781 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 782                                         [Define if you have int32_t and uint32_t.]))
 783 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 784                                           [Define if you have u_int32_t]))
 785 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 786                                            [Define if you have u_int32_t]))
 787
 788 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 789 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 790
 791 case "$host" in
 792   *-darwin*) DARWIN_CRT=true ;;
 793   *) DARWIN_CRT=false ;;
 794 esac
 795 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 796
 797 # This may not be defined in a non-ANS conformant embedded system.
 798 # FIXME: Should these case a runtime exception in that case?
 799 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 800                                   [Define is you have 'localtime' in <time.h>]))
 801
 802 # Create the subdirectory for natFile.cc, or the attempt
 803 # to create the link will fail.
 804 test -d java || mkdir java
 805 test -d java/io || mkdir java/io
 806 test -d gnu || mkdir gnu
 807 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 808
 809 # Likewise for natConcreteProcess.cc.
 810 test -d java/lang || mkdir java/lang
 811 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 812
 813 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 814 test -d java/net || mkdir java/net
 815 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 816 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 817
 818 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 819 test -d gnu/java || mkdir gnu/java
 820 test -d gnu/java/net || mkdir gnu/java/net
 821 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 822 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 823
 824 # Likewise for natVMPipe.cc and natVMSelector.cc.
 825 test -d gnu/java/nio || mkdir gnu/java/nio
 826 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 827 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 828
 829 # Likewise for natFileChannelImpl.cc
 830 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 831 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 832
 833 case "${host}" in
 834     *mingw*)
 835       SYSTEMSPEC="-lgdi32 -lws2_32"
 836       if test "${with_win32_nlsapi}" = "unicows"; then
 837         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 838       fi
 839     ;;
 840     *)
 841       SYSTEMSPEC=
 842     ;;
 843 esac
 844 AC_SUBST(SYSTEMSPEC)
 845
 846 AC_ARG_WITH(system-zlib,
 847   AS_HELP_STRING([--with-system-zlib],
 848                  [use installed libz]))
 849 ZLIBSPEC=
 850 AC_SUBST(ZLIBSPEC)
 851 ZLIBTESTSPEC=
 852 AC_SUBST(ZLIBTESTSPEC)
 853
 854 AC_PATH_XTRA
 855
 856 # FIXME: this should be _libs on some hosts.
 857 libsubdir=.libs
 858
 859 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 860
 861 LIBSTDCXXSPEC=
 862 # extra LD Flags which are required for targets
 863 case "${host}" in
 864 *-*-darwin[[0-7]].*)
 865     # For now we have to disable it on darwin[8-9] because it slows down
 866     # the linking phase. A possible bug in ld?
 867     # on Darwin -single_module speeds up loading of the dynamic libraries.
 868     extra_ldflags_libjava=-Wl,-single_module
 869     ;;
 870 *-*-darwin[[912]]*)
 871     extra_gij_ldflags=-Wl,-allow_stack_execute
 872     ;;
 873 arm*linux*eabi)
 874     # Some of the ARM unwinder code is actually in libstdc++.  We
 875     # could in principle replicate it in libgcj, but it's better to
 876     # have a dependency on libstdc++.
 877     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 878     LIBSTDCXXSPEC=-lstdc++
 879     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 880     ;;
 881 esac
 882 AC_SUBST(extra_ldflags_libjava)
 883 AC_SUBST(extra_gij_ldflags)
 884 AC_SUBST(extra_ldflags)
 885 AC_SUBST(LIBSTDCXXSPEC)
 886
 887 AC_SUBST(LIBGCJTESTSPEC)
 888
 889 # Allow the GC to be disabled.  Can be useful when debugging.
 890 AC_MSG_CHECKING([for garbage collector to use])
 891 AC_ARG_ENABLE(java-gc,
 892   AS_HELP_STRING([--enable-java-gc=TYPE],
 893                  [choose garbage collector (default is boehm)]),
 894   [GC=$enableval],
 895   [GC=boehm])
 896 GCLIBS=
 897 GCINCS=
 898 GCDEPS=
 899 GCSPEC=
 900 JC1GCSPEC=
 901 GCTESTSPEC=
 902 case "$GC" in
 903  boehm)
 904     AC_MSG_RESULT(boehm)
 905     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 906     JC1GCSPEC='-fuse-boehm-gc'
 907     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 908     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 909     GCOBJS=boehm.lo
 910     GCHDR=boehm-gc.h
 911     # The POSIX thread support needs to know this.
 912     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 913     ;;
 914  no)
 915     AC_MSG_RESULT(none)
 916     GCHDR=no-gc.h
 917     ;;
 918  *)
 919     AC_MSG_ERROR([unrecognized collector "$GC"])
 920     ;;
 921 esac
 922 AC_SUBST(GCLIBS)
 923 AC_SUBST(GCINCS)
 924 AC_SUBST(GCDEPS)
 925 AC_SUBST(GCSPEC)
 926 AC_SUBST(JC1GCSPEC)
 927 AC_SUBST(GCTESTSPEC)
 928 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 929 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 930 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 931
 932
 933 AC_MSG_CHECKING([for thread model used by GCC])
 934 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 935 AC_MSG_RESULT([$THREADS])
 936
 937 case "$THREADS" in
 938  no | none | single)
 939     THREADS=none
 940     ;;
 941  aix | posix | posix95 | pthreads)
 942     THREADS=posix
 943     case "$host" in
 944      *-*-linux*)
 945         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 946         ;;
 947     esac
 948     ;;
 949  win32)
 950     ;;
 951  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 952     AC_MSG_ERROR(thread package $THREADS not yet supported)
 953     ;;
 954  *)
 955     AC_MSG_ERROR($THREADS is an unknown thread package)
 956     ;;
 957 esac
 958
 959 THREADCXXFLAGS=
 960 THREADLDFLAGS=
 961 THREADLIBS=
 962 THREADINCS=
 963 THREADDEPS=
 964 THREADH=
 965 THREADSPEC=
 966 THREADSTARTFILESPEC=
 967 case "$THREADS" in
 968  posix)
 969     case "$host" in
 970      *-*-cygwin*)
 971         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 972         ;;
 973      *-*-freebsd[[1234]]*)
 974         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 975         # merely adds pthread_* functions) but it does have a -pthread switch
 976         # which is required at link-time to select -lc_r *instead* of -lc.
 977         THREADLDFLAGS=-pthread
 978         # Don't set THREADSPEC here as might be expected since -pthread is
 979         # not processed when found within a spec file, it must come from
 980         # the command line.  For now, the user must provide the -pthread
 981         # switch to link code compiled with gcj.  In future, consider adding
 982         # support for weak references to pthread_* functions ala gthr.h API.
 983         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 984         ;;
 985      *-*-freebsd*)
 986         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 987         # systems which support threads and -lpthread.
 988         THREADLDFLAGS=-pthread
 989         THREADSPEC=-lpthread
 990         ;;
 991      alpha*-dec-osf* | hppa*-hp-hpux*)
 992         THREADCXXFLAGS=-pthread
 993         # boehm-gc needs some functions from librt, so link that too.
 994         THREADLIBS='-lpthread -lrt'
 995         THREADSPEC='-lpthread -lrt'
 996         ;;
 997      *)
 998         THREADLIBS=-lpthread
 999         THREADSPEC=-lpthread
1000         ;;
1001     esac
1002     THREADH=posix-threads.h
1003     # MIT pthreads doesn't seem to have the mutexattr functions.
1004     # But for now we don't check for it.  We just assume you aren't
1005     # using MIT pthreads.
1006     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1007
1008     # If we're using the Boehm GC, then we happen to know that it
1009     # defines _REENTRANT, so we don't bother.  Eww.
1010     if test "$GC" != boehm; then
1011        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1012     fi
1013     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1014     ;;
1015
1016  win32)
1017     THREADH=win32-threads.h
1018     THREADCXXFLAGS=-mthreads
1019     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1020     # But we do not want the executables created to be dependent on
1021     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1022     # exception handling contexts.  The following kludge achieves this effect
1023     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1024     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1025     # A workaround is to explicitly use -mthreads while linking Java programs.
1026     # See PR libgcj/28263.
1027     #
1028     # FIXME: In Java we are able to detect thread death at the end of
1029     # Thread.run() so we should be able to clean up the exception handling
1030     # contexts ourselves.
1031     THREADSTARTFILESPEC='crtmt%O%s'
1032     ;;
1033
1034  none)
1035     THREADH=no-threads.h
1036     ;;
1037 esac
1038 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1039 AC_SUBST(THREADLIBS)
1040 AC_SUBST(THREADINCS)
1041 AC_SUBST(THREADDEPS)
1042 AC_SUBST(THREADSPEC)
1043 AC_SUBST(THREADSTARTFILESPEC)
1044 AC_SUBST(THREADLDFLAGS)
1045 AC_SUBST(THREADCXXFLAGS)
1046 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1047 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1048 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1049 if test "$enable_shared" != yes; then
1050   use_libgcj_bc=no
1051 fi
1052 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1053
1054 if test -d sysdep; then true; else mkdir sysdep; fi
1055 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1056 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1057 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1058
1059 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
1060 if test "$use_libgcj_bc" = yes; then
1061   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:-lgcj;:-lgcj_bc}"
1062 fi
1063 AC_SUBST(LIBGCJ_SPEC)
1064
1065 HASH_SYNC_SPEC=
1066 # Hash synchronization is only useful with posix threads right now.
1067 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1068    HASH_SYNC_SPEC=-fhash-synchronization
1069    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1070 fi
1071 AC_SUBST(HASH_SYNC_SPEC)
1072
1073 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1074
1075 # We're in the tree with gcc, and need to include some of its headers.
1076 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1077
1078 if test "x${with_newlib}" = "xyes"; then
1079    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1080    # may not work correctly, because the compiler may not be able to
1081    # link executables.
1082
1083    # We assume newlib.  This lets us hard-code the functions we know
1084    # we'll have.
1085    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1086    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1087    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1088    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1089    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1090    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1091    # This is only for POSIX threads.
1092    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1093
1094    # Assume we do not have getuid and friends.
1095    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1096    PLATFORMNET=NoNet
1097 else
1098    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1099                    localtime_r getpwuid_r getcwd \
1100                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1101                    nl_langinfo setlocale \
1102                    inet_pton uname inet_ntoa \
1103                    getrlimit sigaction ftruncate mmap \
1104                    getifaddrs])
1105    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1106    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1107    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1108    AC_CHECK_LIB(dl, dladdr, [
1109        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1110        AC_CHECK_LIB(dld, dladdr, [
1111        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1112
1113    if test x"$cross_compiling" = x"no"; then
1114      AC_CHECK_FILES(/proc/self/exe, [
1115        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1116      AC_CHECK_FILES(/proc/self/maps, [
1117        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1118          [Define if you have /proc/self/maps])])
1119    else
1120      case $host in
1121      *-linux*)
1122        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1123        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1124        ;;
1125      esac
1126    fi
1127
1128    AM_ICONV
1129    AM_LC_MESSAGES
1130    AC_STRUCT_TIMEZONE
1131
1132    AC_CHECK_FUNCS(gethostbyname_r, [
1133      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1134        [Define if you have the 'gethostbyname_r' function.])
1135      # There are two different kinds of gethostbyname_r.
1136      # We look for the one that returns `int'.
1137      # Hopefully this check is robust enough.
1138      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1139        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1140
1141      case " $GCINCS " in
1142      *" -D_REENTRANT "*) ;;
1143      *)
1144         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1145         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1146         [libjava_cv_gethostbyname_r_needs_reentrant],
1147         [ AC_LANG_PUSH(C++)
1148           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1149             [[gethostbyname_r("", 0, 0);]])],
1150             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1151                 CPPFLAGS_SAVE="$CPPFLAGS"
1152                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1153                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1154                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1155                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1156                 CPPFLAGS="$CPPFLAGS_SAVE"
1157           ])
1158           AC_LANG_POP(C++)
1159         ])
1160         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1161           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1162         fi
1163      ;;
1164      esac
1165
1166      AC_CACHE_CHECK([for struct hostent_data],
1167         [libjava_cv_struct_hostent_data], [dnl
1168         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1169 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1170 # define _REENTRANT 1
1171 #endif
1172 #include <netdb.h>]], [[struct hostent_data data;]])],
1173           [libjava_cv_struct_hostent_data=yes],
1174           [libjava_cv_struct_hostent_data=no])])
1175      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1176        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1177          [Define if struct hostent_data is defined in netdb.h])
1178      fi
1179    ])
1180
1181    # FIXME: libjava source code expects to find a prototype for
1182    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1183    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1184    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1185    # linkage check is enough, yet C++ code requires proper prototypes.)
1186    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1187    AC_CHECK_FUNCS(gethostbyaddr_r, [
1188      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1189        [Define if you have the 'gethostbyaddr_r' function.])
1190      # There are two different kinds of gethostbyaddr_r.
1191      # We look for the one that returns `int'.
1192      # Hopefully this check is robust enough.
1193      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1194        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1195          [Define if gethostbyaddr_r returns 'int'.])])])])
1196
1197    AC_CHECK_FUNCS(gethostname, [
1198      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1199        [Define if you have the 'gethostname' function.])
1200      AC_EGREP_HEADER(gethostname, unistd.h, [
1201        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1202          [Define if gethostname is declared in <unistd.h>.])])])
1203
1204    AC_CHECK_FUNCS(usleep, [
1205      AC_EGREP_HEADER(usleep, unistd.h, [
1206        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1207           [Define if usleep is declared in <unistd.h>.])])])
1208
1209    # Look for these functions in the thread library, but only bother
1210    # if using POSIX threads.
1211    if test "$THREADS" = posix; then
1212       save_LIBS="$LIBS"
1213       LIBS="$LIBS $THREADLIBS"
1214
1215       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1216       # Solaris 7 the name librt is preferred.
1217       AC_CHECK_FUNCS(sched_yield, , [
1218         AC_CHECK_LIB(rt, sched_yield, [
1219           AC_DEFINE(HAVE_SCHED_YIELD)
1220           THREADLIBS="$THREADLIBS -lrt"
1221           THREADSPEC="$THREADSPEC -lrt"], [
1222           AC_CHECK_LIB(posix4, sched_yield, [
1223             AC_DEFINE(HAVE_SCHED_YIELD)
1224             THREADLIBS="$THREADLIBS -lposix4"
1225             THREADSPEC="$THREADSPEC -lposix4"])])])
1226
1227       AC_CHECK_LIB(rt, clock_gettime, [
1228          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1229          case "$THREADSPEC" in
1230            *-lrt*) ;;
1231            *)
1232              THREADSPEC="$THREADSPEC -lrt"
1233              THREADLIBS="$THREADLIBS -lrt"
1234              ;;
1235          esac])
1236
1237       LIBS="$save_LIBS"
1238
1239       # We can save a little space at runtime if the mutex has m_count
1240       # or __m_count.  This is a nice hack for Linux.
1241       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1242           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1243         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1244              [Define if pthread_mutex_t has m_count member.]), [
1245         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1246             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1247           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1248             [Define if pthread_mutex_t has __m_count member.]))])
1249    fi
1250
1251    # We require a way to get the time.
1252    time_found=no
1253    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1254    if test "$time_found" = no; then
1255       AC_MSG_ERROR([no function found to get the time])
1256    fi
1257
1258    AC_CHECK_FUNCS(memmove)
1259
1260    # We require memcpy.
1261    memcpy_found=no
1262    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1263    if test "$memcpy_found" = no; then
1264       AC_MSG_ERROR([memcpy is required])
1265    fi
1266    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1267    AC_CHECK_LIB(dl, dlopen, [
1268        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1269        AC_CHECK_LIB(dld, dlopen, [
1270        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1271
1272    # Some library-finding code we stole from Tcl.
1273    #--------------------------------------------------------------------
1274    #    Check for the existence of the -lsocket and -lnsl libraries.
1275    #    The order here is important, so that they end up in the right
1276    #    order in the command line generated by make.  Here are some
1277    #    special considerations:
1278    #    1. Use "connect" and "accept" to check for -lsocket, and
1279    #       "gethostbyname" to check for -lnsl.
1280    #    2. Use each function name only once:  can't redo a check because
1281    #       autoconf caches the results of the last check and won't redo it.
1282    #    3. Use -lnsl and -lsocket only if they supply procedures that
1283    #       aren't already present in the normal libraries.  This is because
1284    #       IRIX 5.2 has libraries, but they aren't needed and they're
1285    #       bogus:  they goof up name resolution if used.
1286    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1287    #       To get around this problem, check for both libraries together
1288    #       if -lsocket doesn't work by itself.
1289    #--------------------------------------------------------------------
1290
1291    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1292     [gcj_cv_lib_sockets=
1293      gcj_checkBoth=0
1294      unset ac_cv_func_connect
1295      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1296      if test "$gcj_checkSocket" = 1; then
1297          unset ac_cv_func_connect
1298          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1299                       gcj_checkBoth=1)
1300      fi
1301      if test "$gcj_checkBoth" = 1; then
1302          gcj_oldLibs=$LIBS
1303          LIBS="$LIBS -lsocket -lnsl"
1304          unset ac_cv_func_accept
1305          AC_CHECK_FUNC(accept,
1306                        [gcj_checkNsl=0
1307                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1308          unset ac_cv_func_accept
1309          LIBS=$gcj_oldLibs
1310      fi
1311      unset ac_cv_func_gethostbyname
1312      gcj_oldLibs=$LIBS
1313      LIBS="$LIBS $gcj_cv_lib_sockets"
1314      AC_CHECK_FUNC(gethostbyname, ,
1315                    [AC_CHECK_LIB(nsl, main,
1316                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1317      unset ac_cv_func_gethostbyname
1318      LIBS=$gcj_oldLIBS
1319    ])
1320    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1321
1322    if test "$with_system_zlib" = yes; then
1323       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1324    fi
1325
1326    # Test for Gtk stuff, if asked for.
1327    if test "$use_gtk_awt" = yes; then
1328       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1329       AC_SUBST(GTK_CFLAGS)
1330       AC_SUBST(GTK_LIBS)
1331
1332       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1333       AC_SUBST(GLIB_CFLAGS)
1334       AC_SUBST(GLIB_LIBS)
1335
1336       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1337       AC_SUBST(LIBART_CFLAGS)
1338       AC_SUBST(LIBART_LIBS)
1339
1340       # We require the XTest Extension to support java.awt.Robot.
1341       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1342                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1343                    [${X_LIBS}])
1344    fi
1345
1346    # On Solaris, and maybe other architectures, the Boehm collector
1347    # requires -ldl.
1348    if test "$GC" = boehm; then
1349       case "${host}" in
1350           mips-sgi-irix6*)
1351             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1352             # libgcj.spec is used, so override here
1353             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1354           ;;
1355           *)
1356             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1357           ;;
1358       esac
1359    fi
1360 fi
1361
1362 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1363 case $build in
1364     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1365     *)         CLASSPATH_SEPARATOR=':' ;;
1366 esac
1367 AC_SUBST(CLASSPATH_SEPARATOR)
1368
1369 # We must search the source tree for java.lang, since we still don't
1370 # have libgcj.jar nor java/lang/*.class
1371 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1372 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1373
1374 # Since some classes depend on this one, we need its source available
1375 # before we can do any GCJ compilation test :-(
1376 if test ! -f gnu/classpath/Configuration.java; then
1377   test -d gnu || mkdir gnu
1378   test -d gnu/classpath || mkdir gnu/classpath
1379   # Note that it is not crucial that all the values here be correct.
1380   sed -e "s,@prefix@,$prefix," \
1381       -e "s,@VERSION@,$VERSION," \
1382       -e "s,@LIBDEBUG@,false," \
1383       -e "s,@INIT_LOAD_LIBRARY@,false," \
1384       -e "s,@@,$LIBGCJDEBUG," \
1385       -e "s,@default_toolkit@,$TOOLKIT," \
1386       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1387       -e "s,@GTK_CAIRO_ENABLED@,false," \
1388       -e "s,@ECJ_JAR@,," \
1389       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1390         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1391         > gnu/classpath/Configuration.java
1392   # We do not want to redirect the output of the grep below to /dev/null,
1393   # but we add /dev/null to the input list so that grep will print the
1394   # filename of Configuration.java in case it finds any matches.
1395   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1396     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1397   fi
1398 fi
1399
1400 LT_AC_PROG_GCJ
1401
1402 # Now remove it.
1403 rm -f gnu/classpath/Configuration.java
1404
1405 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1406
1407 AC_CHECK_SIZEOF(void *)
1408
1409 AC_C_BIGENDIAN
1410
1411 ZLIBS=
1412 SYS_ZLIBS=
1413 ZINCS=
1414
1415 if test -z "$ZLIBSPEC"; then
1416    # Use zlib from the GCC tree.
1417    ZINCS='-I$(top_srcdir)/../zlib'
1418    ZLIBS=../zlib/libzgcj_convenience.la
1419 else
1420    # System's zlib.
1421    SYS_ZLIBS="$ZLIBSPEC"
1422 fi
1423 AC_SUBST(ZLIBS)
1424 AC_SUBST(SYS_ZLIBS)
1425 AC_SUBST(ZINCS)
1426 AC_SUBST(DIVIDESPEC)
1427 AC_SUBST(CHECKREFSPEC)
1428 AC_SUBST(EXCEPTIONSPEC)
1429 AC_SUBST(BACKTRACESPEC)
1430 AC_SUBST(IEEESPEC)
1431
1432 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1433 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1434 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1435 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1436 AC_SUBST(GCC_UNWIND_INCLUDE)
1437
1438 # Process the option "--enable-version-specific-runtime-libs"
1439 # Calculate toolexeclibdir
1440 case ${version_specific_libs} in
1441   yes)
1442     # Need the gcc compiler version to know where to install libraries
1443     # and header files if --enable-version-specific-runtime-libs option
1444     # is selected.
1445     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1446     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1447     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1448     toolexeclibdir=$toolexecmainlibdir
1449     ;;
1450   no)
1451     if test -n "$with_cross_host" &&
1452        test x"$with_cross_host" != x"no"; then
1453       # Install a library built with a cross compiler in tooldir, not libdir.
1454       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1455       toolexecmainlibdir='$(toolexecdir)/lib'
1456     else
1457       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1458       toolexecmainlibdir='$(libdir)'
1459     fi
1460     multi_os_directory=`$CC -print-multi-os-directory`
1461     case $multi_os_directory in
1462       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1463       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1464     esac
1465     ;;
1466 esac
1467 AC_SUBST(toolexecdir)
1468 AC_SUBST(toolexecmainlibdir)
1469 AC_SUBST(toolexeclibdir)
1470
1471 # Determine gcj and libgcj version number.
1472 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1473 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1474 GCJVERSION=$gcjversion
1475 AC_SUBST(GCJVERSION)
1476 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1477
1478 # Determine where the standard .db file and GNU Classpath JNI
1479 # libraries are found.
1480 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1481 multi_os_directory=`$CC -print-multi-os-directory`
1482 case $multi_os_directory in
1483   .)
1484    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1485    ;;
1486   *)
1487    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1488    ;;
1489 esac
1490 AC_SUBST(dbexecdir)
1491 AC_SUBST(gcjsubdir)
1492
1493 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1494 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1495
1496 TL_AC_GXX_INCLUDE_DIR
1497
1498 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1499 # On that system, sys/ioctl.h will not include sys/filio.h unless
1500 # BSD_COMP is defined; just including sys/filio.h is simpler.
1501 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1502 # for now.  If you change this, you also must update natFile.cc.
1503 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1504                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1505                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1506                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1507                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1508 AC_CHECK_HEADERS(inttypes.h, [
1509     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1510     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1511 ])
1512
1513 AC_CHECK_TYPE([ssize_t], [int])
1514 AC_CHECK_TYPE([magic_t], [
1515     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1516 #ifdef HAVE_MAGIC_H
1517 #include <magic.h>
1518 #endif])
1519
1520 AC_MSG_CHECKING([for in_addr_t])
1521 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1522 #if STDC_HEADERS
1523 #include <stdlib.h>
1524 #include <stddef.h>
1525 #endif
1526 #if HAVE_NETINET_IN_H
1527 #include <netinet/in.h>
1528 #endif]], [[in_addr_t foo;]])],
1529   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1530      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1531    AC_MSG_RESULT(yes)],
1532   [AC_MSG_RESULT(no)])
1533
1534 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1535 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1536   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1537      [Define if struct ip_mreq is defined in netinet/in.h.])
1538    AC_MSG_RESULT(yes)],
1539   [AC_MSG_RESULT(no)])
1540
1541 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1542 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1543   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1544      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1545    AC_MSG_RESULT(yes)],
1546   [AC_MSG_RESULT(no)])
1547
1548 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1549 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1550   [AC_DEFINE(HAVE_INET6, 1,
1551      [Define if inet6 structures are defined in netinet/in.h.])
1552    AC_MSG_RESULT(yes)],
1553   [AC_MSG_RESULT(no)])
1554
1555 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1556 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1557 #include <sys/types.h>
1558 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1559   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1560    AC_MSG_RESULT(yes)],
1561   [AC_MSG_RESULT(no)])
1562
1563 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1564 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1565   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1566    AC_MSG_RESULT(yes)],
1567   [AC_MSG_RESULT(no)
1568    AC_MSG_CHECKING([for global timezone variable])
1569    dnl FIXME: we don't want a link check here because that won't work
1570    dnl when cross-compiling.  So instead we make an assumption that
1571    dnl the header file will mention timezone if it exists.
1572    dnl Don't find the win32 function timezone
1573    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1574      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1575       AC_MSG_RESULT(yes)],
1576      [AC_MSG_RESULT(no)
1577        AC_MSG_CHECKING([for global _timezone variable])
1578        dnl FIXME: As above, don't want link check
1579        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1580          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1581             [Define if your platform has the global _timezone variable.])
1582           AC_MSG_RESULT(yes)],
1583           [AC_MSG_RESULT(no)])])])
1584
1585 AC_CHECK_PROGS(PERL, perl, false)
1586
1587 SYSDEP_SOURCES=
1588 SIGNAL_HANDLER_AUX=
1589
1590 case "${host}" in
1591  i?86-*-linux*)
1592     SIGNAL_HANDLER=include/i386-signal.h
1593     ;;
1594  sparc*-sun-solaris*)
1595     SIGNAL_HANDLER=include/sparc-signal.h
1596     ;;
1597 # ia64-*)
1598 #    SYSDEP_SOURCES=sysdep/ia64.c
1599 #    test -d sysdep || mkdir sysdep
1600 #    ;;
1601  hppa*-*-linux*)
1602     SIGNAL_HANDLER=include/pa-signal.h
1603     ;;
1604  hppa*-hp-hpux*)
1605     SIGNAL_HANDLER=include/hppa-signal.h
1606     ;;
1607  ia64-*-linux*)
1608     SIGNAL_HANDLER=include/dwarf2-signal.h
1609     ;;
1610  powerpc*-*-linux*)
1611     SIGNAL_HANDLER=include/powerpc-signal.h
1612     ;;
1613  alpha*-*-linux*)
1614     SIGNAL_HANDLER=include/dwarf2-signal.h
1615     ;;
1616  s390*-*-linux*)
1617     SIGNAL_HANDLER=include/s390-signal.h
1618     ;;
1619  x86_64*-*-linux*)
1620     SIGNAL_HANDLER=include/x86_64-signal.h
1621     SIGNAL_HANDLER_AUX=include/i386-signal.h
1622     ;;
1623  sparc*-*-linux*)
1624     SIGNAL_HANDLER=include/dwarf2-signal.h
1625     ;;
1626  sh*-*-linux*)
1627     SIGNAL_HANDLER=include/sh-signal.h
1628     ;;
1629  *mingw*)
1630     SIGNAL_HANDLER=include/win32-signal.h
1631     ;;
1632  mips*-*-linux*)
1633     SIGNAL_HANDLER=include/mips-signal.h
1634     ;;
1635  m68*-*-linux*)
1636     SIGNAL_HANDLER=include/dwarf2-signal.h
1637     ;;
1638  powerpc*-*-darwin* | i?86-*-darwin9* | x86_64-*-darwin9*)
1639     SIGNAL_HANDLER=include/darwin-signal.h
1640     ;;
1641  powerpc*-*-aix*)
1642     SIGNAL_HANDLER=include/aix-signal.h
1643     ;;
1644  *)
1645     SIGNAL_HANDLER=include/default-signal.h
1646     ;;
1647 esac
1648
1649 # If we're using sjlj exceptions, forget what we just learned.
1650 if test "$enable_sjlj_exceptions" = yes; then
1651    SIGNAL_HANDLER=include/default-signal.h
1652    SIGNAL_HANDLER_AUX=
1653 fi
1654
1655 AC_SUBST(SYSDEP_SOURCES)
1656
1657 if test -z "$SIGNAL_HANDLER_AUX"; then
1658   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1659 fi
1660
1661 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1662                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1663
1664 if test "${multilib}" = "yes"; then
1665   multilib_arg="--enable-multilib"
1666 else
1667   multilib_arg=
1668 fi
1669
1670 # See if we support thread-local storage.
1671 GCC_CHECK_TLS
1672
1673 # For _Unwind_GetIPInfo.
1674 GCC_CHECK_UNWIND_GETIPINFO
1675
1676 # See if linker supports anonymous version scripts.
1677 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1678   [libjava_cv_anon_version_script],
1679   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1680    libjava_cv_anon_version_script=no
1681    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1682    echo '{ global: globalsymb*; local: *; };' > conftest.map
1683    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1684                [libjava_cv_anon_version_script=yes], [])
1685    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1686   ])
1687 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1688
1689 # Check if linker supports static linking on a per library basis
1690 LD_START_STATIC_SPEC=
1691 LD_FINISH_STATIC_SPEC=
1692 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1693   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1694     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1695     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1696   fi
1697 fi
1698 AC_SUBST(LD_START_STATIC_SPEC)
1699 AC_SUBST(LD_FINISH_STATIC_SPEC)
1700
1701 here=`${PWDCMD-pwd}`
1702 AC_SUBST(here)
1703
1704 # We get this from the environment.
1705 AC_SUBST(GCJFLAGS)
1706
1707 AC_ARG_WITH([python-dir],
1708             AS_HELP_STRING([--with-python-dir],
1709                            [the location to install Python modules. This path should NOT include the prefix.]),
1710             [with_python_dir=$withval], [with_python_dir=""])
1711
1712 if test "x${with_python_dir}" = "x"
1713 then
1714   # Needed for installing Python modules during make install.
1715   python_mod_dir="\${prefix}/share/python"
1716   # Needed for substituting into aot-compile*
1717   python_mod_dir_expanded="${prefix}/share/python"
1718 else
1719   python_mod_dir="\${prefix}${with_python_dir}"
1720   python_mod_dir_expanded="${prefix}${with_python_dir}"
1721 fi
1722 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1723 AC_SUBST(python_mod_dir)
1724 AC_SUBST(python_mod_dir_expanded)
1725
1726 # needed for aot-compile-rpm
1727 MAKE=`which make`
1728 AC_SUBST(MAKE)
1729
1730 AC_ARG_ENABLE([aot-compile-rpm],
1731   [AS_HELP_STRING([--enable-aot-compile-rpm],
1732                  [enable installation of aot-compile-rpm [default=no]])],
1733   [case "${enableval}" in
1734     yes) AOT_RPM_ENABLED=yes ;;
1735     no)  AOT_RPM_ENABLED=no ;;
1736     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1737   esac],
1738   [AOT_RPM_ENABLED=no]
1739 )
1740 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1741
1742 AC_ARG_ENABLE([java-home],
1743   [AS_HELP_STRING([--enable-java-home],
1744                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1745   [case "${enableval}" in
1746     yes) JAVA_HOME_ENABLED=yes ;;
1747     no)  JAVA_HOME_ENABLED=no ;;
1748     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1749   esac],
1750   [JAVA_HOME_ENABLED=no]
1751 )
1752 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1753
1754 # Only do these checks if java-home above is enabled.
1755 if test "x${JAVA_HOME_ENABLED}" = xyes
1756 then
1757
1758   AC_ARG_WITH([gcc-suffix],
1759               AS_HELP_STRING([--with-gcc-suffix],
1760                              [the GCC tool suffix (defaults to empty string)]),
1761               [gcc_suffix=$withval], [gcc_suffix=""])
1762   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1763   AC_SUBST(gcc_suffix)
1764
1765   AC_ARG_WITH([arch-directory],
1766               AS_HELP_STRING([--with-arch-directory],
1767                              [the arch directory under jre/lib (defaults to auto-detect)]),
1768               [host_cpu=$withval], [host_cpu=""])
1769
1770   AC_ARG_WITH([os-directory],
1771               AS_HELP_STRING([--with-os-directory],
1772                              [the os directory under include (defaults to auto-detect)]),
1773               [host_os=$withval], [host_os=""])
1774
1775   AC_ARG_WITH([origin-name],
1776               AS_HELP_STRING([--with-origin-name],
1777                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1778               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1779   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1780
1781   AC_ARG_WITH([arch-suffix],
1782               AS_HELP_STRING([--with-arch-suffix],
1783                              [the arch directory suffix (default is the empty string]),
1784               [arch_suffix=$withval], [arch_suffix=""])
1785   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1786
1787   AC_ARG_WITH([jvm-root-dir],
1788               AS_HELP_STRING([--with-jvm-root-dir],
1789                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1790               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1791   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1792
1793   AC_ARG_WITH([jvm-jar-dir],
1794               AS_HELP_STRING([--with-jvm-jar-dir],
1795                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1796               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1797   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1798
1799   JAVA_VERSION=1.5.0
1800   BUILD_VERSION=0
1801   AC_SUBST(JAVA_VERSION)
1802   AC_SUBST(BUILD_VERSION)
1803   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1804
1805   jre_dir=java-${JAVA_VERSION}-${origin_name}-${JAVA_VERSION}.${BUILD_VERSION}${arch_suffix}/jre
1806   sdk_dir=java-${JAVA_VERSION}-${origin_name}-${JAVA_VERSION}.${BUILD_VERSION}${arch_suffix}
1807   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1808   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1809
1810   JVM_ROOT_DIR=${jvm_root_dir}
1811   AC_SUBST(JVM_ROOT_DIR)
1812   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1813
1814   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1815   AC_SUBST(JVM_JAR_ROOT_DIR)
1816   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1817
1818   JVM_JAR_DIR=${jvm_jar_dir}/${sdk_dir}
1819   AC_SUBST(JVM_JAR_DIR)
1820   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1821
1822   JRE_DIR=${jre_dir}
1823   AC_SUBST(JRE_DIR)
1824
1825   SDK_DIR=${sdk_dir}
1826   AC_SUBST(SDK_DIR)
1827
1828   JRE_LNK=${jre_lnk}
1829   AC_SUBST(JRE_LNK)
1830
1831   SDK_LNK=${sdk_lnk}
1832   AC_SUBST(SDK_LNK)
1833
1834   SDK_BIN_DIR=${jvm_root_dir}/${sdk_dir}/bin
1835   AC_SUBST(SDK_BIN_DIR)
1836   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1837
1838   SDK_LIB_DIR=${jvm_root_dir}/${sdk_dir}/lib
1839   AC_SUBST(SDK_LIB_DIR)
1840   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1841
1842   SDK_INCLUDE_DIR=${jvm_root_dir}/${sdk_dir}/include
1843   AC_SUBST(SDK_INCLUDE_DIR)
1844   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1845
1846   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1847   AC_SUBST(JRE_BIN_DIR)
1848   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1849
1850   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1851   AC_SUBST(JRE_LIB_DIR)
1852   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1853
1854   # Find gcj prefix using gcj found in PATH.
1855   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1856
1857   # Where do the gcj binaries live?
1858   # For jhbuild based builds, they all live in a sibling of bin called
1859   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1860   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1861   AC_SUBST(GCJ_BIN_DIR)
1862   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1863
1864   echo host is ${host}
1865   if test "x${host_cpu}" = "x"
1866   then
1867     case ${host} in
1868       *-mingw* | *-cygwin*)
1869         host_cpu=x86;;
1870       i486-* | i586-* | i686-*)
1871         host_cpu=i386;;
1872       *)
1873         host_cpu=${host_cpu};;
1874     esac
1875   fi
1876   AC_MSG_RESULT(arch directory: ${host_cpu})
1877   CPU=${host_cpu}
1878   AC_SUBST(CPU)
1879
1880   if test "x${host_os}" = "x"
1881   then
1882     case ${host} in
1883       *-mingw* | *-cygwin*)
1884         host_os=win32;;
1885       *-linux*)
1886         host_os=linux;;
1887       *)
1888         host_os=${host_os};;
1889     esac
1890   fi
1891   echo os directory: ${host_os}
1892   OS=${host_os}
1893   AC_SUBST(OS)
1894
1895   # make an expanded $libdir, for substituting into
1896   # scripts (and other non-Makefile things).
1897   LIBDIR=$libdir
1898   if test "x${exec_prefix}" = "xNONE"
1899   then
1900       lib_exec_prefix=$prefix
1901   else
1902       lib_exec_prefix=$exec_prefix
1903   fi
1904   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1905   AC_SUBST(LIBDIR)
1906 fi
1907
1908 AC_CONFIG_FILES([
1909 Makefile
1910 libgcj.pc
1911 libgcj.spec
1912 libgcj-test.spec
1913 gcj/Makefile
1914 include/Makefile
1915 testsuite/Makefile
1916 contrib/aotcompile.py
1917 contrib/aot-compile
1918 contrib/aot-compile-rpm
1919 contrib/rebuild-gcj-db
1920 ])
1921
1922 if test ${multilib} = yes; then
1923   multilib_arg="--enable-multilib"
1924 else
1925   multilib_arg=
1926 fi
1927
1928 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1929 AC_OUTPUT