gcc/ada/lib-xref.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . X R E F                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2017, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Csets;    use Csets;
  28 with Elists;   use Elists;
  29 with Errout;   use Errout;
  30 with Nlists;   use Nlists;
  31 with Opt;      use Opt;
  32 with Restrict; use Restrict;
  33 with Rident;   use Rident;
  34 with Sem;      use Sem;
  35 with Sem_Aux;  use Sem_Aux;
  36 with Sem_Prag; use Sem_Prag;
  37 with Sem_Util; use Sem_Util;
  38 with Sem_Warn; use Sem_Warn;
  39 with Sinfo;    use Sinfo;
  40 with Sinput;   use Sinput;
  41 with Snames;   use Snames;
  42 with Stringt;  use Stringt;
  43 with Stand;    use Stand;
  44 with Table;    use Table;
  45
  46 with GNAT.Heap_Sort_G;
  47 with GNAT.HTable;
  48
  49 package body Lib.Xref is
  50
  51    ------------------
  52    -- Declarations --
  53    ------------------
  54
  55    --  The Xref table is used to record references. The Loc field is set
  56    --  to No_Location for a definition entry.
  57
  58    subtype Xref_Entry_Number is Int;
  59
  60    type Xref_Key is record
  61       --  These are the components of Xref_Entry that participate in hash
  62       --  lookups.
  63
  64       Ent : Entity_Id;
  65       --  Entity referenced (E parameter to Generate_Reference)
  66
  67       Loc : Source_Ptr;
  68       --  Location of reference (Original_Location (Sloc field of N parameter
  69       --  to Generate_Reference)). Set to No_Location for the case of a
  70       --  defining occurrence.
  71
  72       Typ : Character;
  73       --  Reference type (Typ param to Generate_Reference)
  74
  75       Eun : Unit_Number_Type;
  76       --  Unit number corresponding to Ent
  77
  78       Lun : Unit_Number_Type;
  79       --  Unit number corresponding to Loc. Value is undefined and not
  80       --  referenced if Loc is set to No_Location.
  81
  82       --  The following components are only used for SPARK cross-references
  83
  84       Ref_Scope : Entity_Id;
  85       --  Entity of the closest subprogram or package enclosing the reference
  86
  87       Ent_Scope : Entity_Id;
  88       --  Entity of the closest subprogram or package enclosing the definition,
  89       --  which should be located in the same file as the definition itself.
  90    end record;
  91
  92    type Xref_Entry is record
  93       Key : Xref_Key;
  94
  95       Ent_Scope_File : Unit_Number_Type;
  96       --  File for entity Ent_Scope
  97
  98       Def : Source_Ptr;
  99       --  Original source location for entity being referenced. Note that these
 100       --  values are used only during the output process, they are not set when
 101       --  the entries are originally built. This is because private entities
 102       --  can be swapped when the initial call is made.
 103
 104       HTable_Next : Xref_Entry_Number;
 105       --  For use only by Static_HTable
 106    end record;
 107
 108    package Xrefs is new Table.Table (
 109      Table_Component_Type => Xref_Entry,
 110      Table_Index_Type     => Xref_Entry_Number,
 111      Table_Low_Bound      => 1,
 112      Table_Initial        => Alloc.Xrefs_Initial,
 113      Table_Increment      => Alloc.Xrefs_Increment,
 114      Table_Name           => "Xrefs");
 115
 116    --------------
 117    -- Xref_Set --
 118    --------------
 119
 120    --  We keep a set of xref entries, in order to avoid inserting duplicate
 121    --  entries into the above Xrefs table. An entry is in Xref_Set if and only
 122    --  if it is in Xrefs.
 123
 124    Num_Buckets : constant := 2**16;
 125
 126    subtype Header_Num is Integer range 0 .. Num_Buckets - 1;
 127    type Null_Type is null record;
 128    pragma Unreferenced (Null_Type);
 129
 130    function Hash (F : Xref_Entry_Number) return Header_Num;
 131
 132    function Equal (F1, F2 : Xref_Entry_Number) return Boolean;
 133
 134    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number);
 135
 136    function  HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number;
 137
 138    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number;
 139
 140    pragma Inline (Hash, Equal, HT_Set_Next, HT_Next, Get_Key);
 141
 142    package Xref_Set is new GNAT.HTable.Static_HTable (
 143      Header_Num,
 144      Element    => Xref_Entry,
 145      Elmt_Ptr   => Xref_Entry_Number,
 146      Null_Ptr   => 0,
 147      Set_Next   => HT_Set_Next,
 148      Next       => HT_Next,
 149      Key        => Xref_Entry_Number,
 150      Get_Key    => Get_Key,
 151      Hash       => Hash,
 152      Equal      => Equal);
 153
 154    -----------------------------
 155    -- SPARK Xrefs Information --
 156    -----------------------------
 157
 158    package body SPARK_Specific is separate;
 159
 160    ------------------------
 161    --  Local Subprograms --
 162    ------------------------
 163
 164    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type);
 165    --  Add an entry to the tables of Xref_Entries, avoiding duplicates
 166
 167    procedure Generate_Prim_Op_References (Typ : Entity_Id);
 168    --  For a tagged type, generate implicit references to its primitive
 169    --  operations, for source navigation. This is done right before emitting
 170    --  cross-reference information rather than at the freeze point of the type
 171    --  in order to handle late bodies that are primitive operations.
 172
 173    function Lt (T1, T2 : Xref_Entry) return Boolean;
 174    --  Order cross-references
 175
 176    ---------------
 177    -- Add_Entry --
 178    ---------------
 179
 180    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type) is
 181    begin
 182       Xrefs.Increment_Last; -- tentative
 183       Xrefs.Table (Xrefs.Last).Key := Key;
 184
 185       --  Set the entry in Xref_Set, and if newly set, keep the above
 186       --  tentative increment.
 187
 188       if Xref_Set.Set_If_Not_Present (Xrefs.Last) then
 189          Xrefs.Table (Xrefs.Last).Ent_Scope_File := Ent_Scope_File;
 190          --  Leave Def and HTable_Next uninitialized
 191
 192          Set_Has_Xref_Entry (Key.Ent);
 193
 194       --  It was already in Xref_Set, so throw away the tentatively-added entry
 195
 196       else
 197          Xrefs.Decrement_Last;
 198       end if;
 199    end Add_Entry;
 200
 201    -----------
 202    -- Equal --
 203    -----------
 204
 205    function Equal (F1, F2 : Xref_Entry_Number) return Boolean is
 206       Result : constant Boolean :=
 207                  Xrefs.Table (F1).Key = Xrefs.Table (F2).Key;
 208    begin
 209       return Result;
 210    end Equal;
 211
 212    -------------------------
 213    -- Generate_Definition --
 214    -------------------------
 215
 216    procedure Generate_Definition (E : Entity_Id) is
 217    begin
 218       pragma Assert (Nkind (E) in N_Entity);
 219
 220       --  Note that we do not test Xref_Entity_Letters here. It is too early
 221       --  to do so, since we are often called before the entity is fully
 222       --  constructed, so that the Ekind is still E_Void.
 223
 224       if Opt.Xref_Active
 225
 226          --  Definition must come from source
 227
 228          --  We make an exception for subprogram child units that have no spec.
 229          --  For these we generate a subprogram declaration for library use,
 230          --  and the corresponding entity does not come from source.
 231          --  Nevertheless, all references will be attached to it and we have
 232          --  to treat is as coming from user code.
 233
 234          and then (Comes_From_Source (E) or else Is_Child_Unit (E))
 235
 236          --  And must have a reasonable source location that is not
 237          --  within an instance (all entities in instances are ignored)
 238
 239          and then Sloc (E) > No_Location
 240          and then Instantiation_Location (Sloc (E)) = No_Location
 241
 242          --  And must be a non-internal name from the main source unit
 243
 244          and then In_Extended_Main_Source_Unit (E)
 245          and then not Is_Internal_Name (Chars (E))
 246       then
 247          Add_Entry
 248            ((Ent => E,
 249              Loc => No_Location,
 250              Typ => ' ',
 251              Eun => Get_Source_Unit (Original_Location (Sloc (E))),
 252              Lun => No_Unit,
 253              Ref_Scope => Empty,
 254              Ent_Scope => Empty),
 255             Ent_Scope_File => No_Unit);
 256
 257          if In_Inlined_Body then
 258             Set_Referenced (E);
 259          end if;
 260       end if;
 261    end Generate_Definition;
 262
 263    ---------------------------------
 264    -- Generate_Operator_Reference --
 265    ---------------------------------
 266
 267    procedure Generate_Operator_Reference
 268      (N : Node_Id;
 269       T : Entity_Id)
 270    is
 271    begin
 272       if not In_Extended_Main_Source_Unit (N) then
 273          return;
 274       end if;
 275
 276       --  If the operator is not a Standard operator, then we generate a real
 277       --  reference to the user defined operator.
 278
 279       if Sloc (Entity (N)) /= Standard_Location then
 280          Generate_Reference (Entity (N), N);
 281
 282          --  A reference to an implicit inequality operator is also a reference
 283          --  to the user-defined equality.
 284
 285          if Nkind (N) = N_Op_Ne
 286            and then not Comes_From_Source (Entity (N))
 287            and then Present (Corresponding_Equality (Entity (N)))
 288          then
 289             Generate_Reference (Corresponding_Equality (Entity (N)), N);
 290          end if;
 291
 292       --  For the case of Standard operators, we mark the result type as
 293       --  referenced. This ensures that in the case where we are using a
 294       --  derived operator, we mark an entity of the unit that implicitly
 295       --  defines this operator as used. Otherwise we may think that no entity
 296       --  of the unit is used. The actual entity marked as referenced is the
 297       --  first subtype, which is the relevant user defined entity.
 298
 299       --  Note: we only do this for operators that come from source. The
 300       --  generated code sometimes reaches for entities that do not need to be
 301       --  explicitly visible (for example, when we expand the code for
 302       --  comparing two record objects, the fields of the record may not be
 303       --  visible).
 304
 305       elsif Comes_From_Source (N) then
 306          Set_Referenced (First_Subtype (T));
 307       end if;
 308    end Generate_Operator_Reference;
 309
 310    ---------------------------------
 311    -- Generate_Prim_Op_References --
 312    ---------------------------------
 313
 314    procedure Generate_Prim_Op_References (Typ : Entity_Id) is
 315       Base_T    : Entity_Id;
 316       Prim      : Elmt_Id;
 317       Prim_List : Elist_Id;
 318
 319    begin
 320       --  Handle subtypes of synchronized types
 321
 322       if Ekind (Typ) = E_Protected_Subtype
 323         or else Ekind (Typ) = E_Task_Subtype
 324       then
 325          Base_T := Etype (Typ);
 326       else
 327          Base_T := Typ;
 328       end if;
 329
 330       --  References to primitive operations are only relevant for tagged types
 331
 332       if not Is_Tagged_Type (Base_T)
 333         or else Is_Class_Wide_Type (Base_T)
 334       then
 335          return;
 336       end if;
 337
 338       --  Ada 2005 (AI-345): For synchronized types generate reference to the
 339       --  wrapper that allow us to dispatch calls through their implemented
 340       --  abstract interface types.
 341
 342       --  The check for Present here is to protect against previously reported
 343       --  critical errors.
 344
 345       Prim_List := Primitive_Operations (Base_T);
 346
 347       if No (Prim_List) then
 348          return;
 349       end if;
 350
 351       Prim := First_Elmt (Prim_List);
 352       while Present (Prim) loop
 353
 354          --  If the operation is derived, get the original for cross-reference
 355          --  reference purposes (it is the original for which we want the xref
 356          --  and for which the comes_from_source test must be performed).
 357
 358          Generate_Reference
 359            (Typ, Ultimate_Alias (Node (Prim)), 'p', Set_Ref => False);
 360          Next_Elmt (Prim);
 361       end loop;
 362    end Generate_Prim_Op_References;
 363
 364    ------------------------
 365    -- Generate_Reference --
 366    ------------------------
 367
 368    procedure Generate_Reference
 369      (E       : Entity_Id;
 370       N       : Node_Id;
 371       Typ     : Character := 'r';
 372       Set_Ref : Boolean   := True;
 373       Force   : Boolean   := False)
 374    is
 375       Actual_Typ : Character := Typ;
 376       Call       : Node_Id;
 377       Def        : Source_Ptr;
 378       Ent        : Entity_Id;
 379       Ent_Scope  : Entity_Id;
 380       Formal     : Entity_Id;
 381       Kind       : Entity_Kind;
 382       Nod        : Node_Id;
 383       Ref        : Source_Ptr;
 384       Ref_Scope  : Entity_Id;
 385
 386       function Get_Through_Renamings (E : Entity_Id) return Entity_Id;
 387       --  Get the enclosing entity through renamings, which may come from
 388       --  source or from the translation of generic instantiations.
 389
 390       function Is_On_LHS (Node : Node_Id) return Boolean;
 391       --  Used to check if a node is on the left hand side of an assignment.
 392       --  The following cases are handled:
 393       --
 394       --   Variable    Node is a direct descendant of left hand side of an
 395       --               assignment statement.
 396       --
 397       --   Prefix      Of an indexed or selected component that is present in
 398       --               a subtree rooted by an assignment statement. There is
 399       --               no restriction of nesting of components, thus cases
 400       --               such as A.B (C).D are handled properly. However a prefix
 401       --               of a dereference (either implicit or explicit) is never
 402       --               considered as on a LHS.
 403       --
 404       --   Out param   Same as above cases, but OUT parameter
 405
 406       function OK_To_Set_Referenced return Boolean;
 407       --  Returns True if the Referenced flag can be set. There are a few
 408       --  exceptions where we do not want to set this flag, see body for
 409       --  details of these exceptional cases.
 410
 411       ---------------------------
 412       -- Get_Through_Renamings --
 413       ---------------------------
 414
 415       function Get_Through_Renamings (E : Entity_Id) return Entity_Id is
 416          Result : Entity_Id := E;
 417
 418       begin
 419          while Present (Result)
 420            and then Is_Object (Result)
 421            and then Present (Renamed_Object (Result))
 422          loop
 423             Result := Get_Enclosing_Object (Renamed_Object (Result));
 424          end loop;
 425
 426          return Result;
 427       end Get_Through_Renamings;
 428
 429       ---------------
 430       -- Is_On_LHS --
 431       ---------------
 432
 433       --  ??? There are several routines here and there that perform a similar
 434       --      (but subtly different) computation, which should be factored:
 435
 436       --      Sem_Util.Is_LHS
 437       --      Sem_Util.May_Be_Lvalue
 438       --      Sem_Util.Known_To_Be_Assigned
 439       --      Exp_Ch2.Expand_Entry_Parameter.In_Assignment_Context
 440       --      Exp_Smem.Is_Out_Actual
 441
 442       function Is_On_LHS (Node : Node_Id) return Boolean is
 443          N : Node_Id;
 444          P : Node_Id;
 445          K : Node_Kind;
 446
 447       begin
 448          --  Only identifiers are considered, is this necessary???
 449
 450          if Nkind (Node) /= N_Identifier then
 451             return False;
 452          end if;
 453
 454          --  Immediate return if appeared as OUT parameter
 455
 456          if Kind = E_Out_Parameter then
 457             return True;
 458          end if;
 459
 460          --  Search for assignment statement subtree root
 461
 462          N := Node;
 463          loop
 464             P := Parent (N);
 465             K := Nkind (P);
 466
 467             if K = N_Assignment_Statement then
 468                return Name (P) = N;
 469
 470             --  Check whether the parent is a component and the current node is
 471             --  its prefix, but return False if the current node has an access
 472             --  type, as in that case the selected or indexed component is an
 473             --  implicit dereference, and the LHS is the designated object, not
 474             --  the access object.
 475
 476             --  ??? case of a slice assignment?
 477
 478             elsif (K = N_Selected_Component or else K = N_Indexed_Component)
 479               and then Prefix (P) = N
 480             then
 481                --  Check for access type. First a special test, In some cases
 482                --  this is called too early (see comments in Find_Direct_Name),
 483                --  at a point where the tree is not fully typed yet. In that
 484                --  case we may lack an Etype for N, and we can't check the
 485                --  Etype. For now, we always return False in such a case,
 486                --  but this is clearly not right in all cases ???
 487
 488                if No (Etype (N)) then
 489                   return False;
 490
 491                elsif Is_Access_Type (Etype (N)) then
 492                   return False;
 493
 494                --  Access type case dealt with, keep going
 495
 496                else
 497                   N := P;
 498                end if;
 499
 500             --  All other cases, definitely not on left side
 501
 502             else
 503                return False;
 504             end if;
 505          end loop;
 506       end Is_On_LHS;
 507
 508       ---------------------------
 509       -- OK_To_Set_Referenced --
 510       ---------------------------
 511
 512       function OK_To_Set_Referenced return Boolean is
 513          P : Node_Id;
 514
 515       begin
 516          --  A reference from a pragma Unreferenced or pragma Unmodified or
 517          --  pragma Warnings does not cause the Referenced flag to be set.
 518          --  This avoids silly warnings about things being referenced and
 519          --  not assigned when the only reference is from the pragma.
 520
 521          if Nkind (N) = N_Identifier then
 522             P := Parent (N);
 523
 524             if Nkind (P) = N_Pragma_Argument_Association then
 525                P := Parent (P);
 526
 527                if Nkind (P) = N_Pragma then
 528                   if Nam_In (Pragma_Name_Unmapped (P),
 529                              Name_Warnings,
 530                              Name_Unmodified,
 531                              Name_Unreferenced)
 532                   then
 533                      return False;
 534                   end if;
 535                end if;
 536
 537             --  A reference to a formal in a named parameter association does
 538             --  not make the formal referenced. Formals that are unused in the
 539             --  subprogram body are properly flagged as such, even if calls
 540             --  elsewhere use named notation.
 541
 542             elsif Nkind (P) = N_Parameter_Association
 543               and then N = Selector_Name (P)
 544             then
 545                return False;
 546             end if;
 547          end if;
 548
 549          return True;
 550       end OK_To_Set_Referenced;
 551
 552    --  Start of processing for Generate_Reference
 553
 554    begin
 555       pragma Assert (Nkind (E) in N_Entity);
 556       Find_Actual (N, Formal, Call);
 557
 558       if Present (Formal) then
 559          Kind := Ekind (Formal);
 560       else
 561          Kind := E_Void;
 562       end if;
 563
 564       --  Check for obsolescent reference to package ASCII. GNAT treats this
 565       --  element of annex J specially since in practice, programs make a lot
 566       --  of use of this feature, so we don't include it in the set of features
 567       --  diagnosed when Warn_On_Obsolescent_Features mode is set. However we
 568       --  are required to note it as a violation of the RM defined restriction.
 569
 570       if E = Standard_ASCII then
 571          Check_Restriction (No_Obsolescent_Features, N);
 572       end if;
 573
 574       --  Check for reference to entity marked with Is_Obsolescent
 575
 576       --  Note that we always allow obsolescent references in the compiler
 577       --  itself and the run time, since we assume that we know what we are
 578       --  doing in such cases. For example the calls in Ada.Characters.Handling
 579       --  to its own obsolescent subprograms are just fine.
 580
 581       --  In any case we only generate warnings if we are in the extended main
 582       --  source unit, and the entity itself is not in the extended main source
 583       --  unit, since we assume the source unit itself knows what is going on
 584       --  (and for sure we do not want silly warnings, e.g. on the end line of
 585       --  an obsolescent procedure body).
 586
 587       if Is_Obsolescent (E)
 588         and then not GNAT_Mode
 589         and then not In_Extended_Main_Source_Unit (E)
 590         and then In_Extended_Main_Source_Unit (N)
 591       then
 592          Check_Restriction (No_Obsolescent_Features, N);
 593
 594          if Warn_On_Obsolescent_Feature then
 595             Output_Obsolescent_Entity_Warnings (N, E);
 596          end if;
 597       end if;
 598
 599       --  Warn if reference to Ada 2005 entity not in Ada 2005 mode. We only
 600       --  detect real explicit references (modifications and references).
 601
 602       if Comes_From_Source (N)
 603         and then Is_Ada_2005_Only (E)
 604         and then Ada_Version < Ada_2005
 605         and then Warn_On_Ada_2005_Compatibility
 606         and then (Typ = 'm' or else Typ = 'r' or else Typ = 's')
 607       then
 608          Error_Msg_NE ("& is only defined in Ada 2005?y?", N, E);
 609       end if;
 610
 611       --  Warn if reference to Ada 2012 entity not in Ada 2012 mode. We only
 612       --  detect real explicit references (modifications and references).
 613
 614       if Comes_From_Source (N)
 615         and then Is_Ada_2012_Only (E)
 616         and then Ada_Version < Ada_2012
 617         and then Warn_On_Ada_2012_Compatibility
 618         and then (Typ = 'm' or else Typ = 'r')
 619       then
 620          Error_Msg_NE ("& is only defined in Ada 2012?y?", N, E);
 621       end if;
 622
 623       --  Do not generate references if we are within a postcondition sub-
 624       --  program, because the reference does not comes from source, and the
 625       --  pre-analysis of the aspect has already created an entry for the ALI
 626       --  file at the proper source location.
 627
 628       if Chars (Current_Scope) = Name_uPostconditions then
 629          return;
 630       end if;
 631
 632       --  Never collect references if not in main source unit. However, we omit
 633       --  this test if Typ is 'e' or 'k', since these entries are structural,
 634       --  and it is useful to have them in units that reference packages as
 635       --  well as units that define packages. We also omit the test for the
 636       --  case of 'p' since we want to include inherited primitive operations
 637       --  from other packages.
 638
 639       --  We also omit this test is this is a body reference for a subprogram
 640       --  instantiation. In this case the reference is to the generic body,
 641       --  which clearly need not be in the main unit containing the instance.
 642       --  For the same reason we accept an implicit reference generated for
 643       --  a default in an instance.
 644
 645       --  We also set the referenced flag in a generic package that is not in
 646       --  then main source unit, when the variable is of a formal private type,
 647       --  to warn in the instance if the corresponding type is not a fully
 648       --  initialized type.
 649
 650       if not In_Extended_Main_Source_Unit (N) then
 651          if Typ = 'e' or else
 652             Typ = 'I' or else
 653             Typ = 'p' or else
 654             Typ = 'i' or else
 655             Typ = 'k'
 656            or else (Typ = 'b' and then Is_Generic_Instance (E))
 657
 658             --  Allow the generation of references to reads, writes and calls
 659             --  in SPARK mode when the related context comes from an instance.
 660
 661            or else
 662              (GNATprove_Mode
 663                and then In_Extended_Main_Code_Unit (N)
 664                and then (Typ = 'm' or else Typ = 'r' or else Typ = 's'))
 665          then
 666             null;
 667
 668          elsif In_Instance_Body
 669            and then In_Extended_Main_Code_Unit (N)
 670            and then Is_Generic_Type (Etype (E))
 671          then
 672             Set_Referenced (E);
 673             return;
 674
 675          elsif Inside_A_Generic
 676            and then Is_Generic_Type (Etype (E))
 677          then
 678             Set_Referenced (E);
 679             return;
 680
 681          else
 682             return;
 683          end if;
 684       end if;
 685
 686       --  For reference type p, the entity must be in main source unit
 687
 688       if Typ = 'p' and then not In_Extended_Main_Source_Unit (E) then
 689          return;
 690       end if;
 691
 692       --  Unless the reference is forced, we ignore references where the
 693       --  reference itself does not come from source.
 694
 695       if not Force and then not Comes_From_Source (N) then
 696          return;
 697       end if;
 698
 699       --  Deal with setting entity as referenced, unless suppressed. Note that
 700       --  we still do Set_Referenced on entities that do not come from source.
 701       --  This situation arises when we have a source reference to a derived
 702       --  operation, where the derived operation itself does not come from
 703       --  source, but we still want to mark it as referenced, since we really
 704       --  are referencing an entity in the corresponding package (this avoids
 705       --  wrong complaints that the package contains no referenced entities).
 706
 707       if Set_Ref then
 708
 709          --  Assignable object appearing on left side of assignment or as
 710          --  an out parameter.
 711
 712          if Is_Assignable (E)
 713            and then Is_On_LHS (N)
 714            and then Ekind (E) /= E_In_Out_Parameter
 715          then
 716             --  For objects that are renamings, just set as simply referenced
 717             --  we do not try to do assignment type tracking in this case.
 718
 719             if Present (Renamed_Object (E)) then
 720                Set_Referenced (E);
 721
 722             --  Out parameter case
 723
 724             elsif Kind = E_Out_Parameter then
 725
 726                --  If warning mode for all out parameters is set, or this is
 727                --  the only warning parameter, then we want to mark this for
 728                --  later warning logic by setting Referenced_As_Out_Parameter
 729
 730                if Warn_On_Modified_As_Out_Parameter (Formal) then
 731                   Set_Referenced_As_Out_Parameter (E, True);
 732                   Set_Referenced_As_LHS (E, False);
 733
 734                --  For OUT parameter not covered by the above cases, we simply
 735                --  regard it as a normal reference (in this case we do not
 736                --  want any of the warning machinery for out parameters).
 737
 738                else
 739                   Set_Referenced (E);
 740                end if;
 741
 742             --  For the left hand of an assignment case, we do nothing here.
 743             --  The processing for Analyze_Assignment_Statement will set the
 744             --  Referenced_As_LHS flag.
 745
 746             else
 747                null;
 748             end if;
 749
 750          --  Check for a reference in a pragma that should not count as a
 751          --  making the variable referenced for warning purposes.
 752
 753          elsif Is_Non_Significant_Pragma_Reference (N) then
 754             null;
 755
 756          --  A reference in an attribute definition clause does not count as a
 757          --  reference except for the case of Address. The reason that 'Address
 758          --  is an exception is that it creates an alias through which the
 759          --  variable may be referenced.
 760
 761          elsif Nkind (Parent (N)) = N_Attribute_Definition_Clause
 762            and then Chars (Parent (N)) /= Name_Address
 763            and then N = Name (Parent (N))
 764          then
 765             null;
 766
 767          --  Constant completion does not count as a reference
 768
 769          elsif Typ = 'c'
 770            and then Ekind (E) = E_Constant
 771          then
 772             null;
 773
 774          --  Record representation clause does not count as a reference
 775
 776          elsif Nkind (N) = N_Identifier
 777            and then Nkind (Parent (N)) = N_Record_Representation_Clause
 778          then
 779             null;
 780
 781          --  Discriminants do not need to produce a reference to record type
 782
 783          elsif Typ = 'd'
 784            and then Nkind (Parent (N)) = N_Discriminant_Specification
 785          then
 786             null;
 787
 788          --  All other cases
 789
 790          else
 791             --  Special processing for IN OUT parameters, where we have an
 792             --  implicit assignment to a simple variable.
 793
 794             if Kind = E_In_Out_Parameter
 795               and then Is_Assignable (E)
 796             then
 797                --  For sure this counts as a normal read reference
 798
 799                Set_Referenced (E);
 800                Set_Last_Assignment (E, Empty);
 801
 802                --  We count it as being referenced as an out parameter if the
 803                --  option is set to warn on all out parameters, except that we
 804                --  have a special exclusion for an intrinsic subprogram, which
 805                --  is most likely an instantiation of Unchecked_Deallocation
 806                --  which we do not want to consider as an assignment since it
 807                --  generates false positives. We also exclude the case of an
 808                --  IN OUT parameter if the name of the procedure is Free,
 809                --  since we suspect similar semantics.
 810
 811                if Warn_On_All_Unread_Out_Parameters
 812                  and then Is_Entity_Name (Name (Call))
 813                  and then not Is_Intrinsic_Subprogram (Entity (Name (Call)))
 814                  and then Chars (Name (Call)) /= Name_Free
 815                then
 816                   Set_Referenced_As_Out_Parameter (E, True);
 817                   Set_Referenced_As_LHS (E, False);
 818                end if;
 819
 820             --  Don't count a recursive reference within a subprogram as a
 821             --  reference (that allows detection of a recursive subprogram
 822             --  whose only references are recursive calls as unreferenced).
 823
 824             elsif Is_Subprogram (E)
 825               and then E = Nearest_Dynamic_Scope (Current_Scope)
 826             then
 827                null;
 828
 829             --  Any other occurrence counts as referencing the entity
 830
 831             elsif OK_To_Set_Referenced then
 832                Set_Referenced (E);
 833
 834                --  If variable, this is an OK reference after an assignment
 835                --  so we can clear the Last_Assignment indication.
 836
 837                if Is_Assignable (E) then
 838                   Set_Last_Assignment (E, Empty);
 839                end if;
 840             end if;
 841          end if;
 842
 843          --  Check for pragma Unreferenced given and reference is within
 844          --  this source unit (occasion for possible warning to be issued).
 845          --  Note that the entity may be marked as unreferenced by pragma
 846          --  Unused.
 847
 848          if Has_Unreferenced (E)
 849            and then In_Same_Extended_Unit (E, N)
 850          then
 851             --  A reference as a named parameter in a call does not count as a
 852             --  violation of pragma Unreferenced for this purpose...
 853
 854             if Nkind (N) = N_Identifier
 855               and then Nkind (Parent (N)) = N_Parameter_Association
 856               and then Selector_Name (Parent (N)) = N
 857             then
 858                null;
 859
 860             --  ... Neither does a reference to a variable on the left side of
 861             --  an assignment.
 862
 863             elsif Is_On_LHS (N) then
 864                null;
 865
 866             --  Do not consider F'Result as a violation of pragma Unreferenced
 867             --  since the attribute acts as an anonymous alias of the function
 868             --  result and not as a real reference to the function.
 869
 870             elsif Ekind_In (E, E_Function, E_Generic_Function)
 871               and then Is_Entity_Name (N)
 872               and then Is_Attribute_Result (Parent (N))
 873             then
 874                null;
 875
 876             --  No warning if the reference is in a call that does not come
 877             --  from source (e.g. a call to a controlled type primitive).
 878
 879             elsif not Comes_From_Source (Parent (N))
 880               and then Nkind (Parent (N)) = N_Procedure_Call_Statement
 881             then
 882                null;
 883
 884             --  For entry formals, we want to place the warning message on the
 885             --  corresponding entity in the accept statement. The current scope
 886             --  is the body of the accept, so we find the formal whose name
 887             --  matches that of the entry formal (there is no link between the
 888             --  two entities, and the one in the accept statement is only used
 889             --  for conformance checking).
 890
 891             elsif Ekind (Scope (E)) = E_Entry then
 892                declare
 893                   BE : Entity_Id;
 894
 895                begin
 896                   BE := First_Entity (Current_Scope);
 897                   while Present (BE) loop
 898                      if Chars (BE) = Chars (E) then
 899                         if Has_Pragma_Unused (E) then
 900                            Error_Msg_NE -- CODEFIX
 901                              ("??pragma Unused given for&!", N, BE);
 902                         else
 903                            Error_Msg_NE -- CODEFIX
 904                              ("??pragma Unreferenced given for&!", N, BE);
 905                         end if;
 906                         exit;
 907                      end if;
 908
 909                      Next_Entity (BE);
 910                   end loop;
 911                end;
 912
 913             --  Here we issue the warning, since this is a real reference
 914
 915             elsif Has_Pragma_Unused (E) then
 916                Error_Msg_NE -- CODEFIX
 917                  ("??pragma Unused given for&!", N, E);
 918             else
 919                Error_Msg_NE -- CODEFIX
 920                  ("??pragma Unreferenced given for&!", N, E);
 921             end if;
 922          end if;
 923
 924          --  If this is a subprogram instance, mark as well the internal
 925          --  subprogram in the wrapper package, which may be a visible
 926          --  compilation unit.
 927
 928          if Is_Overloadable (E)
 929            and then Is_Generic_Instance (E)
 930            and then Present (Alias (E))
 931          then
 932             Set_Referenced (Alias (E));
 933          end if;
 934       end if;
 935
 936       --  Generate reference if all conditions are met:
 937
 938       if
 939          --  Cross referencing must be active
 940
 941          Opt.Xref_Active
 942
 943          --  The entity must be one for which we collect references
 944
 945          and then Xref_Entity_Letters (Ekind (E)) /= ' '
 946
 947          --  Both Sloc values must be set to something sensible
 948
 949          and then Sloc (E) > No_Location
 950          and then Sloc (N) > No_Location
 951
 952          --  Ignore references from within an instance. The only exceptions to
 953          --  this are default subprograms, for which we generate an implicit
 954          --  reference and compilations in SPARK mode.
 955
 956          and then
 957            (Instantiation_Location (Sloc (N)) = No_Location
 958              or else Typ = 'i'
 959              or else GNATprove_Mode)
 960
 961         --  Ignore dummy references
 962
 963         and then Typ /= ' '
 964       then
 965          if Nkind_In (N, N_Identifier,
 966                          N_Defining_Identifier,
 967                          N_Defining_Operator_Symbol,
 968                          N_Operator_Symbol,
 969                          N_Defining_Character_Literal)
 970            or else Nkind (N) in N_Op
 971            or else (Nkind (N) = N_Character_Literal
 972                      and then Sloc (Entity (N)) /= Standard_Location)
 973          then
 974             Nod := N;
 975
 976          elsif Nkind_In (N, N_Expanded_Name, N_Selected_Component) then
 977             Nod := Selector_Name (N);
 978
 979          else
 980             return;
 981          end if;
 982
 983          --  Normal case of source entity comes from source
 984
 985          if Comes_From_Source (E) then
 986             Ent := E;
 987
 988          --  Because a declaration may be generated for a subprogram body
 989          --  without declaration in GNATprove mode, for inlining, some
 990          --  parameters may end up being marked as not coming from source
 991          --  although they are. Take these into account specially.
 992
 993          elsif GNATprove_Mode and then Ekind (E) in Formal_Kind then
 994             Ent := E;
 995
 996          --  Entity does not come from source, but is a derived subprogram and
 997          --  the derived subprogram comes from source (after one or more
 998          --  derivations) in which case the reference is to parent subprogram.
 999
1000          elsif Is_Overloadable (E)
1001            and then Present (Alias (E))
1002          then
1003             Ent := Alias (E);
1004             while not Comes_From_Source (Ent) loop
1005                if No (Alias (Ent)) then
1006                   return;
1007                end if;
1008
1009                Ent := Alias (Ent);
1010             end loop;
1011
1012          --  The internally created defining entity for a child subprogram
1013          --  that has no previous spec has valid references.
1014
1015          elsif Is_Overloadable (E)
1016            and then Is_Child_Unit (E)
1017          then
1018             Ent := E;
1019
1020          --  Ditto for the formals of such a subprogram
1021
1022          elsif Is_Overloadable (Scope (E))
1023            and then Is_Child_Unit (Scope (E))
1024          then
1025             Ent := E;
1026
1027          --  Record components of discriminated subtypes or derived types must
1028          --  be treated as references to the original component.
1029
1030          elsif Ekind (E) = E_Component
1031            and then Comes_From_Source (Original_Record_Component (E))
1032          then
1033             Ent := Original_Record_Component (E);
1034
1035          --  If this is an expanded reference to a discriminant, recover the
1036          --  original discriminant, which gets the reference.
1037
1038          elsif Ekind (E) = E_In_Parameter
1039            and then  Present (Discriminal_Link (E))
1040          then
1041             Ent := Discriminal_Link (E);
1042             Set_Referenced (Ent);
1043
1044          --  Ignore reference to any other entity that is not from source
1045
1046          else
1047             return;
1048          end if;
1049
1050          --  In SPARK mode, consider the underlying entity renamed instead of
1051          --  the renaming, which is needed to compute a valid set of effects
1052          --  (reads, writes) for the enclosing subprogram.
1053
1054          if GNATprove_Mode then
1055             Ent := Get_Through_Renamings (Ent);
1056
1057             --  If no enclosing object, then it could be a reference to any
1058             --  location not tracked individually, like heap-allocated data.
1059             --  Conservatively approximate this possibility by generating a
1060             --  dereference, and return.
1061
1062             if No (Ent) then
1063                if Actual_Typ = 'w' then
1064                   SPARK_Specific.Generate_Dereference (Nod, 'r');
1065                   SPARK_Specific.Generate_Dereference (Nod, 'w');
1066                else
1067                   SPARK_Specific.Generate_Dereference (Nod, 'r');
1068                end if;
1069
1070                return;
1071             end if;
1072          end if;
1073
1074          --  Record reference to entity
1075
1076          if Actual_Typ = 'p'
1077            and then Is_Subprogram (Nod)
1078            and then Present (Overridden_Operation (Nod))
1079          then
1080             Actual_Typ := 'P';
1081          end if;
1082
1083          --  Comment needed here for special SPARK code ???
1084
1085          if GNATprove_Mode then
1086             Ref := Sloc (Nod);
1087             Def := Sloc (Ent);
1088
1089             Ref_Scope :=
1090               SPARK_Specific.Enclosing_Subprogram_Or_Library_Package (Nod);
1091             Ent_Scope :=
1092               SPARK_Specific.Enclosing_Subprogram_Or_Library_Package (Ent);
1093
1094             --  Since we are reaching through renamings in SPARK mode, we may
1095             --  end up with standard constants. Ignore those.
1096
1097             if Sloc (Ent_Scope) <= Standard_Location
1098               or else Def <= Standard_Location
1099             then
1100                return;
1101             end if;
1102
1103             Add_Entry
1104               ((Ent       => Ent,
1105                 Loc       => Ref,
1106                 Typ       => Actual_Typ,
1107                 Eun       => Get_Top_Level_Code_Unit (Def),
1108                 Lun       => Get_Top_Level_Code_Unit (Ref),
1109                 Ref_Scope => Ref_Scope,
1110                 Ent_Scope => Ent_Scope),
1111                Ent_Scope_File => Get_Top_Level_Code_Unit (Ent));
1112
1113          else
1114             Ref := Original_Location (Sloc (Nod));
1115             Def := Original_Location (Sloc (Ent));
1116
1117             --  If this is an operator symbol, skip the initial quote for
1118             --  navigation purposes. This is not done for the end label,
1119             --  where we want the actual position after the closing quote.
1120
1121             if Typ = 't' then
1122                null;
1123
1124             elsif Nkind (N) = N_Defining_Operator_Symbol
1125               or else Nkind (Nod) = N_Operator_Symbol
1126             then
1127                Ref := Ref + 1;
1128             end if;
1129
1130             Add_Entry
1131               ((Ent       => Ent,
1132                 Loc       => Ref,
1133                 Typ       => Actual_Typ,
1134                 Eun       => Get_Source_Unit (Def),
1135                 Lun       => Get_Source_Unit (Ref),
1136                 Ref_Scope => Empty,
1137                 Ent_Scope => Empty),
1138                Ent_Scope_File => No_Unit);
1139
1140             --  Generate reference to the first private entity
1141
1142             if Typ = 'e'
1143               and then Comes_From_Source (E)
1144               and then Nkind (Ent) = N_Defining_Identifier
1145               and then (Is_Package_Or_Generic_Package (Ent)
1146                          or else Is_Concurrent_Type (Ent))
1147               and then Present (First_Private_Entity (E))
1148               and then In_Extended_Main_Source_Unit (N)
1149             then
1150                --  Handle case in which the full-view and partial-view of the
1151                --  first private entity are swapped.
1152
1153                declare
1154                   First_Private : Entity_Id := First_Private_Entity (E);
1155
1156                begin
1157                   if Is_Private_Type (First_Private)
1158                     and then Present (Full_View (First_Private))
1159                   then
1160                      First_Private := Full_View (First_Private);
1161                   end if;
1162
1163                   Add_Entry
1164                     ((Ent       => Ent,
1165                       Loc       => Sloc (First_Private),
1166                       Typ       => 'E',
1167                       Eun       => Get_Source_Unit (Def),
1168                       Lun       => Get_Source_Unit (Ref),
1169                       Ref_Scope => Empty,
1170                       Ent_Scope => Empty),
1171                      Ent_Scope_File => No_Unit);
1172                end;
1173             end if;
1174          end if;
1175       end if;
1176    end Generate_Reference;
1177
1178    -----------------------------------
1179    -- Generate_Reference_To_Formals --
1180    -----------------------------------
1181
1182    procedure Generate_Reference_To_Formals (E : Entity_Id) is
1183       Formal : Entity_Id;
1184
1185    begin
1186       if Is_Generic_Subprogram (E) then
1187          Formal := First_Entity (E);
1188
1189          while Present (Formal)
1190            and then not Is_Formal (Formal)
1191          loop
1192             Next_Entity (Formal);
1193          end loop;
1194
1195       elsif Ekind (E) in Access_Subprogram_Kind then
1196          Formal := First_Formal (Designated_Type (E));
1197
1198       else
1199          Formal := First_Formal (E);
1200       end if;
1201
1202       while Present (Formal) loop
1203          if Ekind (Formal) = E_In_Parameter then
1204
1205             if Nkind (Parameter_Type (Parent (Formal))) = N_Access_Definition
1206             then
1207                Generate_Reference (E, Formal, '^', False);
1208             else
1209                Generate_Reference (E, Formal, '>', False);
1210             end if;
1211
1212          elsif Ekind (Formal) = E_In_Out_Parameter then
1213             Generate_Reference (E, Formal, '=', False);
1214
1215          else
1216             Generate_Reference (E, Formal, '<', False);
1217          end if;
1218
1219          Next_Formal (Formal);
1220       end loop;
1221    end Generate_Reference_To_Formals;
1222
1223    -------------------------------------------
1224    -- Generate_Reference_To_Generic_Formals --
1225    -------------------------------------------
1226
1227    procedure Generate_Reference_To_Generic_Formals (E : Entity_Id) is
1228       Formal : Entity_Id;
1229
1230    begin
1231       Formal := First_Entity (E);
1232       while Present (Formal) loop
1233          if Comes_From_Source (Formal) then
1234             Generate_Reference (E, Formal, 'z', False);
1235          end if;
1236
1237          Next_Entity (Formal);
1238       end loop;
1239    end Generate_Reference_To_Generic_Formals;
1240
1241    -------------
1242    -- Get_Key --
1243    -------------
1244
1245    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number is
1246    begin
1247       return E;
1248    end Get_Key;
1249
1250    ----------------------------
1251    -- Has_Deferred_Reference --
1252    ----------------------------
1253
1254    function Has_Deferred_Reference (Ent : Entity_Id) return Boolean is
1255    begin
1256       for J in Deferred_References.First .. Deferred_References.Last loop
1257          if Deferred_References.Table (J).E = Ent then
1258             return True;
1259          end if;
1260       end loop;
1261
1262       return False;
1263    end Has_Deferred_Reference;
1264
1265    ----------
1266    -- Hash --
1267    ----------
1268
1269    function Hash (F : Xref_Entry_Number) return Header_Num is
1270       --  It is unlikely to have two references to the same entity at the same
1271       --  source location, so the hash function depends only on the Ent and Loc
1272       --  fields.
1273
1274       XE : Xref_Entry renames Xrefs.Table (F);
1275       type M is mod 2**32;
1276
1277       H : constant M := M (XE.Key.Ent) + 2 ** 7 * M (abs XE.Key.Loc);
1278       --  It would be more natural to write:
1279       --
1280       --    H : constant M := M'Mod (XE.Key.Ent) + 2**7 * M'Mod (XE.Key.Loc);
1281       --
1282       --  But we can't use M'Mod, because it prevents bootstrapping with older
1283       --  compilers. Loc can be negative, so we do "abs" before converting.
1284       --  One day this can be cleaned up ???
1285
1286    begin
1287       return Header_Num (H mod Num_Buckets);
1288    end Hash;
1289
1290    -----------------
1291    -- HT_Set_Next --
1292    -----------------
1293
1294    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number) is
1295    begin
1296       Xrefs.Table (E).HTable_Next := Next;
1297    end HT_Set_Next;
1298
1299    -------------
1300    -- HT_Next --
1301    -------------
1302
1303    function HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number is
1304    begin
1305       return Xrefs.Table (E).HTable_Next;
1306    end HT_Next;
1307
1308    ----------------
1309    -- Initialize --
1310    ----------------
1311
1312    procedure Initialize is
1313    begin
1314       Xrefs.Init;
1315    end Initialize;
1316
1317    --------
1318    -- Lt --
1319    --------
1320
1321    function Lt (T1, T2 : Xref_Entry) return Boolean is
1322    begin
1323       --  First test: if entity is in different unit, sort by unit
1324
1325       if T1.Key.Eun /= T2.Key.Eun then
1326          return Dependency_Num (T1.Key.Eun) < Dependency_Num (T2.Key.Eun);
1327
1328       --  Second test: within same unit, sort by entity Sloc
1329
1330       elsif T1.Def /= T2.Def then
1331          return T1.Def < T2.Def;
1332
1333       --  Third test: sort definitions ahead of references
1334
1335       elsif T1.Key.Loc = No_Location then
1336          return True;
1337
1338       elsif T2.Key.Loc = No_Location then
1339          return False;
1340
1341       --  Fourth test: for same entity, sort by reference location unit
1342
1343       elsif T1.Key.Lun /= T2.Key.Lun then
1344          return Dependency_Num (T1.Key.Lun) < Dependency_Num (T2.Key.Lun);
1345
1346       --  Fifth test: order of location within referencing unit
1347
1348       elsif T1.Key.Loc /= T2.Key.Loc then
1349          return T1.Key.Loc < T2.Key.Loc;
1350
1351       --  Finally, for two locations at the same address, we prefer
1352       --  the one that does NOT have the type 'r' so that a modification
1353       --  or extension takes preference, when there are more than one
1354       --  reference at the same location. As a result, in the case of
1355       --  entities that are in-out actuals, the read reference follows
1356       --  the modify reference.
1357
1358       else
1359          return T2.Key.Typ = 'r';
1360       end if;
1361    end Lt;
1362
1363    -----------------------
1364    -- Output_References --
1365    -----------------------
1366
1367    procedure Output_References is
1368
1369       procedure Get_Type_Reference
1370         (Ent   : Entity_Id;
1371          Tref  : out Entity_Id;
1372          Left  : out Character;
1373          Right : out Character);
1374       --  Given an Entity_Id Ent, determines whether a type reference is
1375       --  required. If so, Tref is set to the entity for the type reference
1376       --  and Left and Right are set to the left/right brackets to be output
1377       --  for the reference. If no type reference is required, then Tref is
1378       --  set to Empty, and Left/Right are set to space.
1379
1380       procedure Output_Import_Export_Info (Ent : Entity_Id);
1381       --  Output language and external name information for an interfaced
1382       --  entity, using the format <language, external_name>.
1383
1384       ------------------------
1385       -- Get_Type_Reference --
1386       ------------------------
1387
1388       procedure Get_Type_Reference
1389         (Ent   : Entity_Id;
1390          Tref  : out Entity_Id;
1391          Left  : out Character;
1392          Right : out Character)
1393       is
1394          Sav : Entity_Id;
1395
1396       begin
1397          --  See if we have a type reference
1398
1399          Tref := Ent;
1400          Left := '{';
1401          Right := '}';
1402
1403          loop
1404             Sav := Tref;
1405
1406             --  Processing for types
1407
1408             if Is_Type (Tref) then
1409
1410                --  Case of base type
1411
1412                if Base_Type (Tref) = Tref then
1413
1414                   --  If derived, then get first subtype
1415
1416                   if Tref /= Etype (Tref) then
1417                      Tref := First_Subtype (Etype (Tref));
1418
1419                      --  Set brackets for derived type, but don't override
1420                      --  pointer case since the fact that something is a
1421                      --  pointer is more important.
1422
1423                      if Left /= '(' then
1424                         Left := '<';
1425                         Right := '>';
1426                      end if;
1427
1428                   --  If the completion of a private type is itself a derived
1429                   --  type, we need the parent of the full view.
1430
1431                   elsif Is_Private_Type (Tref)
1432                     and then Present (Full_View (Tref))
1433                     and then Etype (Full_View (Tref)) /= Full_View (Tref)
1434                   then
1435                      Tref := Etype (Full_View (Tref));
1436
1437                      if Left /= '(' then
1438                         Left := '<';
1439                         Right := '>';
1440                      end if;
1441
1442                   --  If non-derived pointer, get directly designated type.
1443                   --  If the type has a full view, all references are on the
1444                   --  partial view that is seen first.
1445
1446                   elsif Is_Access_Type (Tref) then
1447                      Tref := Directly_Designated_Type (Tref);
1448                      Left := '(';
1449                      Right := ')';
1450
1451                   elsif Is_Private_Type (Tref)
1452                     and then Present (Full_View (Tref))
1453                   then
1454                      if Is_Access_Type (Full_View (Tref)) then
1455                         Tref := Directly_Designated_Type (Full_View (Tref));
1456                         Left := '(';
1457                         Right := ')';
1458
1459                      --  If the full view is an array type, we also retrieve
1460                      --  the corresponding component type, because the ali
1461                      --  entry already indicates that this is an array.
1462
1463                      elsif Is_Array_Type (Full_View (Tref)) then
1464                         Tref := Component_Type (Full_View (Tref));
1465                         Left := '(';
1466                         Right := ')';
1467                      end if;
1468
1469                   --  If non-derived array, get component type. Skip component
1470                   --  type for case of String or Wide_String, saves worthwhile
1471                   --  space.
1472
1473                   elsif Is_Array_Type (Tref)
1474                     and then Tref /= Standard_String
1475                     and then Tref /= Standard_Wide_String
1476                   then
1477                      Tref := Component_Type (Tref);
1478                      Left := '(';
1479                      Right := ')';
1480
1481                   --  For other non-derived base types, nothing
1482
1483                   else
1484                      exit;
1485                   end if;
1486
1487                --  For a subtype, go to ancestor subtype
1488
1489                else
1490                   Tref := Ancestor_Subtype (Tref);
1491
1492                   --  If no ancestor subtype, go to base type
1493
1494                   if No (Tref) then
1495                      Tref := Base_Type (Sav);
1496                   end if;
1497                end if;
1498
1499             --  For objects, functions, enum literals, just get type from
1500             --  Etype field.
1501
1502             elsif Is_Object (Tref)
1503               or else Ekind (Tref) = E_Enumeration_Literal
1504               or else Ekind (Tref) = E_Function
1505               or else Ekind (Tref) = E_Operator
1506             then
1507                Tref := Etype (Tref);
1508
1509                --  Another special case: an object of a classwide type
1510                --  initialized with a tag-indeterminate call gets a subtype
1511                --  of the classwide type during expansion. See if the original
1512                --  type in the declaration is named, and return it instead
1513                --  of going to the root type. The expression may be a class-
1514                --  wide function call whose result is on the secondary stack,
1515                --  which forces the declaration to be rewritten as a renaming,
1516                --  so examine the source declaration.
1517
1518                if Ekind (Tref) = E_Class_Wide_Subtype then
1519                   declare
1520                      Decl : constant Node_Id := Original_Node (Parent (Ent));
1521                   begin
1522                      if Nkind (Decl) = N_Object_Declaration
1523                        and then Is_Entity_Name
1524                                   (Original_Node (Object_Definition (Decl)))
1525                      then
1526                         Tref :=
1527                           Entity (Original_Node (Object_Definition (Decl)));
1528                      end if;
1529                   end;
1530
1531                --  For a function that returns a class-wide type, Tref is
1532                --  already correct.
1533
1534                elsif Is_Overloadable (Ent)
1535                  and then Is_Class_Wide_Type (Tref)
1536                then
1537                   return;
1538                end if;
1539
1540             --  For anything else, exit
1541
1542             else
1543                exit;
1544             end if;
1545
1546             --  Exit if no type reference, or we are stuck in some loop trying
1547             --  to find the type reference, or if the type is standard void
1548             --  type (the latter is an implementation artifact that should not
1549             --  show up in the generated cross-references).
1550
1551             exit when No (Tref)
1552               or else Tref = Sav
1553               or else Tref = Standard_Void_Type;
1554
1555             --  If we have a usable type reference, return, otherwise keep
1556             --  looking for something useful (we are looking for something
1557             --  that either comes from source or standard)
1558
1559             if Sloc (Tref) = Standard_Location
1560               or else Comes_From_Source (Tref)
1561             then
1562                --  If the reference is a subtype created for a generic actual,
1563                --  go actual directly, the inner subtype is not user visible.
1564
1565                if Nkind (Parent (Tref)) = N_Subtype_Declaration
1566                  and then not Comes_From_Source (Parent (Tref))
1567                  and then
1568                   (Is_Wrapper_Package (Scope (Tref))
1569                      or else Is_Generic_Instance (Scope (Tref)))
1570                then
1571                   Tref := First_Subtype (Base_Type (Tref));
1572                end if;
1573
1574                return;
1575             end if;
1576          end loop;
1577
1578          --  If we fall through the loop, no type reference
1579
1580          Tref := Empty;
1581          Left := ' ';
1582          Right := ' ';
1583       end Get_Type_Reference;
1584
1585       -------------------------------
1586       -- Output_Import_Export_Info --
1587       -------------------------------
1588
1589       procedure Output_Import_Export_Info (Ent : Entity_Id) is
1590          Language_Name : Name_Id;
1591          Conv          : constant Convention_Id := Convention (Ent);
1592
1593       begin
1594          --  Generate language name from convention
1595
1596          if Conv  = Convention_C then
1597             Language_Name := Name_C;
1598
1599          elsif Conv = Convention_CPP then
1600             Language_Name := Name_CPP;
1601
1602          elsif Conv = Convention_Ada then
1603             Language_Name := Name_Ada;
1604
1605          else
1606             --  For the moment we ignore all other cases ???
1607
1608             return;
1609          end if;
1610
1611          Write_Info_Char ('<');
1612          Get_Unqualified_Name_String (Language_Name);
1613
1614          for J in 1 .. Name_Len loop
1615             Write_Info_Char (Name_Buffer (J));
1616          end loop;
1617
1618          if Present (Interface_Name (Ent)) then
1619             Write_Info_Char (',');
1620             String_To_Name_Buffer (Strval (Interface_Name (Ent)));
1621
1622             for J in 1 .. Name_Len loop
1623                Write_Info_Char (Name_Buffer (J));
1624             end loop;
1625          end if;
1626
1627          Write_Info_Char ('>');
1628       end Output_Import_Export_Info;
1629
1630    --  Start of processing for Output_References
1631
1632    begin
1633       --  First we add references to the primitive operations of tagged types
1634       --  declared in the main unit.
1635
1636       Handle_Prim_Ops : declare
1637          Ent  : Entity_Id;
1638
1639       begin
1640          for J in 1 .. Xrefs.Last loop
1641             Ent := Xrefs.Table (J).Key.Ent;
1642
1643             if Is_Type (Ent)
1644               and then Is_Tagged_Type (Ent)
1645               and then Is_Base_Type (Ent)
1646               and then In_Extended_Main_Source_Unit (Ent)
1647             then
1648                Generate_Prim_Op_References (Ent);
1649             end if;
1650          end loop;
1651       end Handle_Prim_Ops;
1652
1653       --  Before we go ahead and output the references we have a problem
1654       --  that needs dealing with. So far we have captured things that are
1655       --  definitely referenced by the main unit, or defined in the main
1656       --  unit. That's because we don't want to clutter up the ali file
1657       --  for this unit with definition lines for entities in other units
1658       --  that are not referenced.
1659
1660       --  But there is a glitch. We may reference an entity in another unit,
1661       --  and it may have a type reference to an entity that is not directly
1662       --  referenced in the main unit, which may mean that there is no xref
1663       --  entry for this entity yet in the list of references.
1664
1665       --  If we don't do something about this, we will end with an orphan type
1666       --  reference, i.e. it will point to an entity that does not appear
1667       --  within the generated references in the ali file. That is not good for
1668       --  tools using the xref information.
1669
1670       --  To fix this, we go through the references adding definition entries
1671       --  for any unreferenced entities that can be referenced in a type
1672       --  reference. There is a recursion problem here, and that is dealt with
1673       --  by making sure that this traversal also traverses any entries that
1674       --  get added by the traversal.
1675
1676       Handle_Orphan_Type_References : declare
1677          J    : Nat;
1678          Tref : Entity_Id;
1679          Ent  : Entity_Id;
1680
1681          L, R : Character;
1682          pragma Warnings (Off, L);
1683          pragma Warnings (Off, R);
1684
1685          procedure New_Entry (E : Entity_Id);
1686          --  Make an additional entry into the Xref table for a type entity
1687          --  that is related to the current entity (parent, type ancestor,
1688          --  progenitor, etc.).
1689
1690          ----------------
1691          -- New_Entry --
1692          ----------------
1693
1694          procedure New_Entry (E : Entity_Id) is
1695          begin
1696             pragma Assert (Present (E));
1697
1698             if not Has_Xref_Entry (Implementation_Base_Type (E))
1699               and then Sloc (E) > No_Location
1700             then
1701                Add_Entry
1702                  ((Ent       => E,
1703                    Loc       => No_Location,
1704                    Typ       => Character'First,
1705                    Eun       => Get_Source_Unit (Original_Location (Sloc (E))),
1706                    Lun       => No_Unit,
1707                    Ref_Scope => Empty,
1708                    Ent_Scope => Empty),
1709                   Ent_Scope_File => No_Unit);
1710             end if;
1711          end New_Entry;
1712
1713       --  Start of processing for Handle_Orphan_Type_References
1714
1715       begin
1716          --  Note that this is not a for loop for a very good reason. The
1717          --  processing of items in the table can add new items to the table,
1718          --  and they must be processed as well.
1719
1720          J := 1;
1721          while J <= Xrefs.Last loop
1722             Ent := Xrefs.Table (J).Key.Ent;
1723
1724             --  Do not generate reference information for an ignored Ghost
1725             --  entity because neither the entity nor its references will
1726             --  appear in the final tree.
1727
1728             if Is_Ignored_Ghost_Entity (Ent) then
1729                goto Orphan_Continue;
1730             end if;
1731
1732             Get_Type_Reference (Ent, Tref, L, R);
1733
1734             if Present (Tref)
1735               and then not Has_Xref_Entry (Tref)
1736               and then Sloc (Tref) > No_Location
1737             then
1738                New_Entry (Tref);
1739
1740                if Is_Record_Type (Ent)
1741                  and then Present (Interfaces (Ent))
1742                then
1743                   --  Add an entry for each one of the given interfaces
1744                   --  implemented by type Ent.
1745
1746                   declare
1747                      Elmt : Elmt_Id := First_Elmt (Interfaces (Ent));
1748                   begin
1749                      while Present (Elmt) loop
1750                         New_Entry (Node (Elmt));
1751                         Next_Elmt (Elmt);
1752                      end loop;
1753                   end;
1754                end if;
1755             end if;
1756
1757             --  Collect inherited primitive operations that may be declared in
1758             --  another unit and have no visible reference in the current one.
1759
1760             if Is_Type (Ent)
1761               and then Is_Tagged_Type (Ent)
1762               and then Is_Derived_Type (Ent)
1763               and then Is_Base_Type (Ent)
1764               and then In_Extended_Main_Source_Unit (Ent)
1765             then
1766                declare
1767                   Op_List : constant Elist_Id := Primitive_Operations (Ent);
1768                   Op      : Elmt_Id;
1769                   Prim    : Entity_Id;
1770
1771                   function Parent_Op (E : Entity_Id) return Entity_Id;
1772                   --  Find original operation, which may be inherited through
1773                   --  several derivations.
1774
1775                   function Parent_Op (E : Entity_Id) return Entity_Id is
1776                      Orig_Op : constant Entity_Id := Alias (E);
1777
1778                   begin
1779                      if No (Orig_Op) then
1780                         return Empty;
1781
1782                      elsif not Comes_From_Source (E)
1783                        and then not Has_Xref_Entry (Orig_Op)
1784                        and then Comes_From_Source (Orig_Op)
1785                      then
1786                         return Orig_Op;
1787                      else
1788                         return Parent_Op (Orig_Op);
1789                      end if;
1790                   end Parent_Op;
1791
1792                begin
1793                   Op := First_Elmt (Op_List);
1794                   while Present (Op) loop
1795                      Prim := Parent_Op (Node (Op));
1796
1797                      if Present (Prim) then
1798                         Add_Entry
1799                           ((Ent       => Prim,
1800                             Loc       => No_Location,
1801                             Typ       => Character'First,
1802                             Eun       => Get_Source_Unit (Sloc (Prim)),
1803                             Lun       => No_Unit,
1804                             Ref_Scope => Empty,
1805                             Ent_Scope => Empty),
1806                            Ent_Scope_File => No_Unit);
1807                      end if;
1808
1809                      Next_Elmt (Op);
1810                   end loop;
1811                end;
1812             end if;
1813
1814             <<Orphan_Continue>>
1815             J := J + 1;
1816          end loop;
1817       end Handle_Orphan_Type_References;
1818
1819       --  Now we have all the references, including those for any embedded type
1820       --  references, so we can sort them, and output them.
1821
1822       Output_Refs : declare
1823          Nrefs : constant Nat := Xrefs.Last;
1824          --  Number of references in table
1825
1826          Rnums : array (0 .. Nrefs) of Nat;
1827          --  This array contains numbers of references in the Xrefs table.
1828          --  This list is sorted in output order. The extra 0'th entry is
1829          --  convenient for the call to sort. When we sort the table, we
1830          --  move the entries in Rnums around, but we do not move the
1831          --  original table entries.
1832
1833          Curxu : Unit_Number_Type;
1834          --  Current xref unit
1835
1836          Curru : Unit_Number_Type;
1837          --  Current reference unit for one entity
1838
1839          Curent : Entity_Id;
1840          --  Current entity
1841
1842          Curnam : String (1 .. Name_Buffer'Length);
1843          Curlen : Natural;
1844          --  Simple name and length of current entity
1845
1846          Curdef : Source_Ptr;
1847          --  Original source location for current entity
1848
1849          Crloc : Source_Ptr;
1850          --  Current reference location
1851
1852          Ctyp : Character;
1853          --  Entity type character
1854
1855          Prevt : Character;
1856          --  reference kind of previous reference
1857
1858          Tref : Entity_Id;
1859          --  Type reference
1860
1861          Rref : Node_Id;
1862          --  Renaming reference
1863
1864          Trunit : Unit_Number_Type;
1865          --  Unit number for type reference
1866
1867          function Lt (Op1, Op2 : Natural) return Boolean;
1868          --  Comparison function for Sort call
1869
1870          function Name_Change (X : Entity_Id) return Boolean;
1871          --  Determines if entity X has a different simple name from Curent
1872
1873          procedure Move (From : Natural; To : Natural);
1874          --  Move procedure for Sort call
1875
1876          package Sorting is new GNAT.Heap_Sort_G (Move, Lt);
1877
1878          --------
1879          -- Lt --
1880          --------
1881
1882          function Lt (Op1, Op2 : Natural) return Boolean is
1883             T1 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op1)));
1884             T2 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op2)));
1885
1886          begin
1887             return Lt (T1, T2);
1888          end Lt;
1889
1890          ----------
1891          -- Move --
1892          ----------
1893
1894          procedure Move (From : Natural; To : Natural) is
1895          begin
1896             Rnums (Nat (To)) := Rnums (Nat (From));
1897          end Move;
1898
1899          -----------------
1900          -- Name_Change --
1901          -----------------
1902
1903          --  Why a string comparison here??? Why not compare Name_Id values???
1904
1905          function Name_Change (X : Entity_Id) return Boolean is
1906          begin
1907             Get_Unqualified_Name_String (Chars (X));
1908
1909             if Name_Len /= Curlen then
1910                return True;
1911             else
1912                return Name_Buffer (1 .. Curlen) /= Curnam (1 .. Curlen);
1913             end if;
1914          end Name_Change;
1915
1916       --  Start of processing for Output_Refs
1917
1918       begin
1919          --  Capture the definition Sloc values. We delay doing this till now,
1920          --  since at the time the reference or definition is made, private
1921          --  types may be swapped, and the Sloc value may be incorrect. We
1922          --  also set up the pointer vector for the sort.
1923
1924          --  For user-defined operators we need to skip the initial quote and
1925          --  point to the first character of the name, for navigation purposes.
1926
1927          for J in 1 .. Nrefs loop
1928             declare
1929                E   : constant Entity_Id  := Xrefs.Table (J).Key.Ent;
1930                Loc : constant Source_Ptr := Original_Location (Sloc (E));
1931
1932             begin
1933                Rnums (J) := J;
1934
1935                if Nkind (E) = N_Defining_Operator_Symbol then
1936                   Xrefs.Table (J).Def := Loc + 1;
1937                else
1938                   Xrefs.Table (J).Def := Loc;
1939                end if;
1940             end;
1941          end loop;
1942
1943          --  Sort the references
1944
1945          Sorting.Sort (Integer (Nrefs));
1946
1947          --  Initialize loop through references
1948
1949          Curxu  := No_Unit;
1950          Curent := Empty;
1951          Curdef := No_Location;
1952          Curru  := No_Unit;
1953          Crloc  := No_Location;
1954          Prevt  := 'm';
1955
1956          --  Loop to output references
1957
1958          for Refno in 1 .. Nrefs loop
1959             Output_One_Ref : declare
1960                Ent : Entity_Id;
1961
1962                XE : Xref_Entry renames Xrefs.Table (Rnums (Refno));
1963                --  The current entry to be accessed
1964
1965                Left  : Character;
1966                Right : Character;
1967                --  Used for {} or <> or () for type reference
1968
1969                procedure Check_Type_Reference
1970                  (Ent            : Entity_Id;
1971                   List_Interface : Boolean;
1972                   Is_Component   : Boolean := False);
1973                --  Find whether there is a meaningful type reference for
1974                --  Ent, and display it accordingly. If List_Interface is
1975                --  true, then Ent is a progenitor interface of the current
1976                --  type entity being listed. In that case list it as is,
1977                --  without looking for a type reference for it. Flag is also
1978                --  used for index types of an array type, where the caller
1979                --  supplies the intended type reference. Is_Component serves
1980                --  the same purpose, to display the component type of a
1981                --  derived array type, for which only the parent type has
1982                --  ben displayed so far.
1983
1984                procedure Output_Instantiation_Refs (Loc : Source_Ptr);
1985                --  Recursive procedure to output instantiation references for
1986                --  the given source ptr in [file|line[...]] form. No output
1987                --  if the given location is not a generic template reference.
1988
1989                procedure Output_Overridden_Op (Old_E : Entity_Id);
1990                --  For a subprogram that is overriding, display information
1991                --  about the inherited operation that it overrides.
1992
1993                --------------------------
1994                -- Check_Type_Reference --
1995                --------------------------
1996
1997                procedure Check_Type_Reference
1998                  (Ent            : Entity_Id;
1999                   List_Interface : Boolean;
2000                   Is_Component   : Boolean := False)
2001                is
2002                begin
2003                   if List_Interface then
2004
2005                      --  This is a progenitor interface of the type for which
2006                      --  xref information is being generated.
2007
2008                      Tref  := Ent;
2009                      Left  := '<';
2010                      Right := '>';
2011
2012                   --  The following is not documented in lib-xref.ads ???
2013
2014                   elsif Is_Component then
2015                      Tref  := Ent;
2016                      Left  := '(';
2017                      Right := ')';
2018
2019                   else
2020                      Get_Type_Reference (Ent, Tref, Left, Right);
2021                   end if;
2022
2023                   if Present (Tref) then
2024
2025                      --  Case of standard entity, output name
2026
2027                      if Sloc (Tref) = Standard_Location then
2028                         Write_Info_Char (Left);
2029                         Write_Info_Name (Chars (Tref));
2030                         Write_Info_Char (Right);
2031
2032                      --  Case of source entity, output location
2033
2034                      else
2035                         Write_Info_Char (Left);
2036                         Trunit := Get_Source_Unit (Sloc (Tref));
2037
2038                         if Trunit /= Curxu then
2039                            Write_Info_Nat (Dependency_Num (Trunit));
2040                            Write_Info_Char ('|');
2041                         end if;
2042
2043                         Write_Info_Nat
2044                           (Int (Get_Logical_Line_Number (Sloc (Tref))));
2045
2046                         declare
2047                            Ent  : Entity_Id;
2048                            Ctyp : Character;
2049
2050                         begin
2051                            Ent := Tref;
2052                            Ctyp := Xref_Entity_Letters (Ekind (Ent));
2053
2054                            if Ctyp = '+'
2055                              and then Present (Full_View (Ent))
2056                            then
2057                               Ent := Underlying_Type (Ent);
2058
2059                               if Present (Ent) then
2060                                  Ctyp := Xref_Entity_Letters (Ekind (Ent));
2061                               end if;
2062                            end if;
2063
2064                            Write_Info_Char (Ctyp);
2065                         end;
2066
2067                         Write_Info_Nat
2068                           (Int (Get_Column_Number (Sloc (Tref))));
2069
2070                         --  If the type comes from an instantiation, add the
2071                         --  corresponding info.
2072
2073                         Output_Instantiation_Refs (Sloc (Tref));
2074                         Write_Info_Char (Right);
2075                      end if;
2076                   end if;
2077                end Check_Type_Reference;
2078
2079                -------------------------------
2080                -- Output_Instantiation_Refs --
2081                -------------------------------
2082
2083                procedure Output_Instantiation_Refs (Loc : Source_Ptr) is
2084                   Iloc : constant Source_Ptr := Instantiation_Location (Loc);
2085                   Lun  : Unit_Number_Type;
2086                   Cu   : constant Unit_Number_Type := Curru;
2087
2088                begin
2089                   --  Nothing to do if this is not an instantiation
2090
2091                   if Iloc = No_Location then
2092                      return;
2093                   end if;
2094
2095                   --  Output instantiation reference
2096
2097                   Write_Info_Char ('[');
2098                   Lun := Get_Source_Unit (Iloc);
2099
2100                   if Lun /= Curru then
2101                      Curru := Lun;
2102                      Write_Info_Nat (Dependency_Num (Curru));
2103                      Write_Info_Char ('|');
2104                   end if;
2105
2106                   Write_Info_Nat (Int (Get_Logical_Line_Number (Iloc)));
2107
2108                   --  Recursive call to get nested instantiations
2109
2110                   Output_Instantiation_Refs (Iloc);
2111
2112                   --  Output final ] after call to get proper nesting
2113
2114                   Write_Info_Char (']');
2115                   Curru := Cu;
2116                   return;
2117                end Output_Instantiation_Refs;
2118
2119                --------------------------
2120                -- Output_Overridden_Op --
2121                --------------------------
2122
2123                procedure Output_Overridden_Op (Old_E : Entity_Id) is
2124                   Op : Entity_Id;
2125
2126                begin
2127                   --  The overridden operation has an implicit declaration
2128                   --  at the point of derivation. What we want to display
2129                   --  is the original operation, which has the actual body
2130                   --  (or abstract declaration) that is being overridden.
2131                   --  The overridden operation is not always set, e.g. when
2132                   --  it is a predefined operator.
2133
2134                   if No (Old_E) then
2135                      return;
2136
2137                   --  Follow alias chain if one is present
2138
2139                   elsif Present (Alias (Old_E)) then
2140
2141                      --  The subprogram may have been implicitly inherited
2142                      --  through several levels of derivation, so find the
2143                      --  ultimate (source) ancestor.
2144
2145                      Op := Ultimate_Alias (Old_E);
2146
2147                   --  Normal case of no alias present. We omit generated
2148                   --  primitives like tagged equality, that have no source
2149                   --  representation.
2150
2151                   else
2152                      Op := Old_E;
2153                   end if;
2154
2155                   if Present (Op)
2156                     and then Sloc (Op) /= Standard_Location
2157                     and then Comes_From_Source (Op)
2158                   then
2159                      declare
2160                         Loc      : constant Source_Ptr := Sloc (Op);
2161                         Par_Unit : constant Unit_Number_Type :=
2162                                      Get_Source_Unit (Loc);
2163
2164                      begin
2165                         Write_Info_Char ('<');
2166
2167                         if Par_Unit /= Curxu then
2168                            Write_Info_Nat (Dependency_Num (Par_Unit));
2169                            Write_Info_Char ('|');
2170                         end if;
2171
2172                         Write_Info_Nat (Int (Get_Logical_Line_Number (Loc)));
2173                         Write_Info_Char ('p');
2174                         Write_Info_Nat (Int (Get_Column_Number (Loc)));
2175                         Write_Info_Char ('>');
2176                      end;
2177                   end if;
2178                end Output_Overridden_Op;
2179
2180             --  Start of processing for Output_One_Ref
2181
2182             begin
2183                Ent := XE.Key.Ent;
2184
2185                --  Do not generate reference information for an ignored Ghost
2186                --  entity because neither the entity nor its references will
2187                --  appear in the final tree.
2188
2189                if Is_Ignored_Ghost_Entity (Ent) then
2190                   goto Continue;
2191                end if;
2192
2193                Ctyp := Xref_Entity_Letters (Ekind (Ent));
2194
2195                --  Skip reference if it is the only reference to an entity,
2196                --  and it is an END line reference, and the entity is not in
2197                --  the current extended source. This prevents junk entries
2198                --  consisting only of packages with END lines, where no
2199                --  entity from the package is actually referenced.
2200
2201                if XE.Key.Typ = 'e'
2202                  and then Ent /= Curent
2203                  and then (Refno = Nrefs
2204                             or else
2205                               Ent /= Xrefs.Table (Rnums (Refno + 1)).Key.Ent)
2206                  and then not In_Extended_Main_Source_Unit (Ent)
2207                then
2208                   goto Continue;
2209                end if;
2210
2211                --  For private type, get full view type
2212
2213                if Ctyp = '+'
2214                  and then Present (Full_View (XE.Key.Ent))
2215                then
2216                   Ent := Underlying_Type (Ent);
2217
2218                   if Present (Ent) then
2219                      Ctyp := Xref_Entity_Letters (Ekind (Ent));
2220                   end if;
2221                end if;
2222
2223                --  Special exception for Boolean
2224
2225                if Ctyp = 'E' and then Is_Boolean_Type (Ent) then
2226                   Ctyp := 'B';
2227                end if;
2228
2229                --  For variable reference, get corresponding type
2230
2231                if Ctyp = '*' then
2232                   Ent := Etype (XE.Key.Ent);
2233                   Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
2234
2235                   --  If variable is private type, get full view type
2236
2237                   if Ctyp = '+'
2238                     and then Present (Full_View (Etype (XE.Key.Ent)))
2239                   then
2240                      Ent := Underlying_Type (Etype (XE.Key.Ent));
2241
2242                      if Present (Ent) then
2243                         Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
2244                      end if;
2245
2246                   elsif Is_Generic_Type (Ent) then
2247
2248                      --  If the type of the entity is a generic private type,
2249                      --  there is no usable full view, so retain the indication
2250                      --  that this is an object.
2251
2252                      Ctyp := '*';
2253                   end if;
2254
2255                   --  Special handling for access parameters and objects and
2256                   --  components of an anonymous access type.
2257
2258                   if Ekind_In (Etype (XE.Key.Ent),
2259                                E_Anonymous_Access_Type,
2260                                E_Anonymous_Access_Subprogram_Type,
2261                                E_Anonymous_Access_Protected_Subprogram_Type)
2262                   then
2263                      if Is_Formal (XE.Key.Ent)
2264                        or else
2265                          Ekind_In
2266                            (XE.Key.Ent, E_Variable, E_Constant, E_Component)
2267                      then
2268                         Ctyp := 'p';
2269                      end if;
2270
2271                      --  Special handling for Boolean
2272
2273                   elsif Ctyp = 'e' and then Is_Boolean_Type (Ent) then
2274                      Ctyp := 'b';
2275                   end if;
2276                end if;
2277
2278                --  Special handling for abstract types and operations
2279
2280                if Is_Overloadable (XE.Key.Ent)
2281                  and then Is_Abstract_Subprogram (XE.Key.Ent)
2282                then
2283                   if Ctyp = 'U' then
2284                      Ctyp := 'x';            --  Abstract procedure
2285
2286                   elsif Ctyp = 'V' then
2287                      Ctyp := 'y';            --  Abstract function
2288                   end if;
2289
2290                elsif Is_Type (XE.Key.Ent)
2291                  and then Is_Abstract_Type (XE.Key.Ent)
2292                then
2293                   if Is_Interface (XE.Key.Ent) then
2294                      Ctyp := 'h';
2295
2296                   elsif Ctyp = 'R' then
2297                      Ctyp := 'H';            --  Abstract type
2298                   end if;
2299                end if;
2300
2301                --  Only output reference if interesting type of entity
2302
2303                if Ctyp = ' '
2304
2305                --  Suppress references to object definitions, used for local
2306                --  references.
2307
2308                  or else XE.Key.Typ = 'D'
2309                  or else XE.Key.Typ = 'I'
2310
2311                --  Suppress self references, except for bodies that act as
2312                --  specs.
2313
2314                  or else (XE.Key.Loc = XE.Def
2315                            and then
2316                              (XE.Key.Typ /= 'b'
2317                                or else not Is_Subprogram (XE.Key.Ent)))
2318
2319                --  Also suppress definitions of body formals (we only
2320                --  treat these as references, and the references were
2321                --  separately recorded).
2322
2323                  or else (Is_Formal (XE.Key.Ent)
2324                            and then Present (Spec_Entity (XE.Key.Ent)))
2325                then
2326                   null;
2327
2328                else
2329                   --  Start new Xref section if new xref unit
2330
2331                   if XE.Key.Eun /= Curxu then
2332                      if Write_Info_Col > 1 then
2333                         Write_Info_EOL;
2334                      end if;
2335
2336                      Curxu := XE.Key.Eun;
2337
2338                      Write_Info_Initiate ('X');
2339                      Write_Info_Char (' ');
2340                      Write_Info_Nat (Dependency_Num (XE.Key.Eun));
2341                      Write_Info_Char (' ');
2342                      Write_Info_Name
2343                        (Reference_Name (Source_Index (XE.Key.Eun)));
2344                   end if;
2345
2346                   --  Start new Entity line if new entity. Note that we
2347                   --  consider two entities the same if they have the same
2348                   --  name and source location. This causes entities in
2349                   --  instantiations to be treated as though they referred
2350                   --  to the template.
2351
2352                   if No (Curent)
2353                     or else
2354                       (XE.Key.Ent /= Curent
2355                          and then
2356                            (Name_Change (XE.Key.Ent) or else XE.Def /= Curdef))
2357                   then
2358                      Curent := XE.Key.Ent;
2359                      Curdef := XE.Def;
2360
2361                      Get_Unqualified_Name_String (Chars (XE.Key.Ent));
2362                      Curlen := Name_Len;
2363                      Curnam (1 .. Curlen) := Name_Buffer (1 .. Curlen);
2364
2365                      if Write_Info_Col > 1 then
2366                         Write_Info_EOL;
2367                      end if;
2368
2369                      --  Write column number information
2370
2371                      Write_Info_Nat (Int (Get_Logical_Line_Number (XE.Def)));
2372                      Write_Info_Char (Ctyp);
2373                      Write_Info_Nat (Int (Get_Column_Number (XE.Def)));
2374
2375                      --  Write level information
2376
2377                      Write_Level_Info : declare
2378                         function Is_Visible_Generic_Entity
2379                           (E : Entity_Id) return Boolean;
2380                         --  Check whether E is declared in the visible part
2381                         --  of a generic package. For source navigation
2382                         --  purposes, treat this as a visible entity.
2383
2384                         function Is_Private_Record_Component
2385                           (E : Entity_Id) return Boolean;
2386                         --  Check whether E is a non-inherited component of a
2387                         --  private extension. Even if the enclosing record is
2388                         --  public, we want to treat the component as private
2389                         --  for navigation purposes.
2390
2391                         ---------------------------------
2392                         -- Is_Private_Record_Component --
2393                         ---------------------------------
2394
2395                         function Is_Private_Record_Component
2396                           (E : Entity_Id) return Boolean
2397                         is
2398                            S : constant Entity_Id := Scope (E);
2399                         begin
2400                            return
2401                              Ekind (E) = E_Component
2402                                and then Nkind (Declaration_Node (S)) =
2403                                  N_Private_Extension_Declaration
2404                                and then Original_Record_Component (E) = E;
2405                         end Is_Private_Record_Component;
2406
2407                         -------------------------------
2408                         -- Is_Visible_Generic_Entity --
2409                         -------------------------------
2410
2411                         function Is_Visible_Generic_Entity
2412                           (E : Entity_Id) return Boolean
2413                         is
2414                            Par : Node_Id;
2415
2416                         begin
2417                            --  The Present check here is an error defense
2418
2419                            if Present (Scope (E))
2420                              and then Ekind (Scope (E)) /= E_Generic_Package
2421                            then
2422                               return False;
2423                            end if;
2424
2425                            Par := Parent (E);
2426                            while Present (Par) loop
2427                               if
2428                                 Nkind (Par) = N_Generic_Package_Declaration
2429                               then
2430                                  --  Entity is a generic formal
2431
2432                                  return False;
2433
2434                               elsif
2435                                 Nkind (Parent (Par)) = N_Package_Specification
2436                               then
2437                                  return
2438                                    Is_List_Member (Par)
2439                                      and then List_Containing (Par) =
2440                                        Visible_Declarations (Parent (Par));
2441                               else
2442                                  Par := Parent (Par);
2443                               end if;
2444                            end loop;
2445
2446                            return False;
2447                         end Is_Visible_Generic_Entity;
2448
2449                      --  Start of processing for Write_Level_Info
2450
2451                      begin
2452                         if Is_Hidden (Curent)
2453                           or else Is_Private_Record_Component (Curent)
2454                         then
2455                            Write_Info_Char (' ');
2456
2457                         elsif
2458                            Is_Public (Curent)
2459                              or else Is_Visible_Generic_Entity (Curent)
2460                         then
2461                            Write_Info_Char ('*');
2462
2463                         else
2464                            Write_Info_Char (' ');
2465                         end if;
2466                      end Write_Level_Info;
2467
2468                      --  Output entity name. We use the occurrence from the
2469                      --  actual source program at the definition point.
2470
2471                      declare
2472                         Ent_Name : constant String :=
2473                                      Exact_Source_Name (Sloc (XE.Key.Ent));
2474                      begin
2475                         for C in Ent_Name'Range loop
2476                            Write_Info_Char (Ent_Name (C));
2477                         end loop;
2478                      end;
2479
2480                      --  See if we have a renaming reference
2481
2482                      if Is_Object (XE.Key.Ent)
2483                        and then Present (Renamed_Object (XE.Key.Ent))
2484                      then
2485                         Rref := Renamed_Object (XE.Key.Ent);
2486
2487                      elsif Is_Overloadable (XE.Key.Ent)
2488                        and then Nkind (Parent (Declaration_Node (XE.Key.Ent)))
2489                                            = N_Subprogram_Renaming_Declaration
2490                      then
2491                         Rref := Name (Parent (Declaration_Node (XE.Key.Ent)));
2492
2493                      elsif Ekind (XE.Key.Ent) = E_Package
2494                        and then Nkind (Declaration_Node (XE.Key.Ent)) =
2495                                          N_Package_Renaming_Declaration
2496                      then
2497                         Rref := Name (Declaration_Node (XE.Key.Ent));
2498
2499                      else
2500                         Rref := Empty;
2501                      end if;
2502
2503                      if Present (Rref) then
2504                         if Nkind (Rref) = N_Expanded_Name then
2505                            Rref := Selector_Name (Rref);
2506                         end if;
2507
2508                         if Nkind (Rref) = N_Identifier
2509                           or else Nkind (Rref) = N_Operator_Symbol
2510                         then
2511                            null;
2512
2513                         --  For renamed array components, use the array name
2514                         --  for the renamed entity, which reflect the fact that
2515                         --  in general the whole array is aliased.
2516
2517                         elsif Nkind (Rref) = N_Indexed_Component then
2518                            if Nkind (Prefix (Rref)) = N_Identifier then
2519                               Rref := Prefix (Rref);
2520                            elsif Nkind (Prefix (Rref)) = N_Expanded_Name then
2521                               Rref := Selector_Name (Prefix (Rref));
2522                            else
2523                               Rref := Empty;
2524                            end if;
2525
2526                         else
2527                            Rref := Empty;
2528                         end if;
2529                      end if;
2530
2531                      --  Write out renaming reference if we have one
2532
2533                      if Present (Rref) then
2534                         Write_Info_Char ('=');
2535                         Write_Info_Nat
2536                           (Int (Get_Logical_Line_Number (Sloc (Rref))));
2537                         Write_Info_Char (':');
2538                         Write_Info_Nat
2539                           (Int (Get_Column_Number (Sloc (Rref))));
2540                      end if;
2541
2542                      --  Indicate that the entity is in the unit of the current
2543                      --  xref section.
2544
2545                      Curru := Curxu;
2546
2547                      --  Write out information about generic parent, if entity
2548                      --  is an instance.
2549
2550                      if Is_Generic_Instance (XE.Key.Ent) then
2551                         declare
2552                            Gen_Par : constant Entity_Id :=
2553                                        Generic_Parent
2554                                          (Specification
2555                                             (Unit_Declaration_Node
2556                                                (XE.Key.Ent)));
2557                            Loc     : constant Source_Ptr := Sloc (Gen_Par);
2558                            Gen_U   : constant Unit_Number_Type :=
2559                                        Get_Source_Unit (Loc);
2560
2561                         begin
2562                            Write_Info_Char ('[');
2563
2564                            if Curru /= Gen_U then
2565                               Write_Info_Nat (Dependency_Num (Gen_U));
2566                               Write_Info_Char ('|');
2567                            end if;
2568
2569                            Write_Info_Nat
2570                              (Int (Get_Logical_Line_Number (Loc)));
2571                            Write_Info_Char (']');
2572                         end;
2573                      end if;
2574
2575                      --  See if we have a type reference and if so output
2576
2577                      Check_Type_Reference (XE.Key.Ent, False);
2578
2579                      --  Additional information for types with progenitors,
2580                      --  including synchronized tagged types.
2581
2582                      declare
2583                         Typ  : constant Entity_Id := XE.Key.Ent;
2584                         Elmt : Elmt_Id;
2585
2586                      begin
2587                         if Is_Record_Type (Typ)
2588                           and then Present (Interfaces (Typ))
2589                         then
2590                            Elmt := First_Elmt (Interfaces (Typ));
2591
2592                         elsif Is_Concurrent_Type (Typ)
2593                           and then Present (Corresponding_Record_Type (Typ))
2594                           and then Present (
2595                             Interfaces (Corresponding_Record_Type (Typ)))
2596                         then
2597                            Elmt :=
2598                              First_Elmt (
2599                               Interfaces (Corresponding_Record_Type (Typ)));
2600
2601                         else
2602                            Elmt := No_Elmt;
2603                         end if;
2604
2605                         while Present (Elmt) loop
2606                            Check_Type_Reference (Node (Elmt), True);
2607                            Next_Elmt (Elmt);
2608                         end loop;
2609                      end;
2610
2611                      --  For array types, list index types as well. (This is
2612                      --  not C, indexes have distinct types).
2613
2614                      if Is_Array_Type (XE.Key.Ent) then
2615                         declare
2616                            A_Typ : constant Entity_Id := XE.Key.Ent;
2617                            Indx : Node_Id;
2618
2619                         begin
2620                            --  If this is a derived array type, we have
2621                            --  output the parent type, so add the component
2622                            --  type now.
2623
2624                            if Is_Derived_Type (A_Typ) then
2625                               Check_Type_Reference
2626                                 (Component_Type (A_Typ), False, True);
2627                            end if;
2628
2629                            --  Add references to index types.
2630
2631                            Indx := First_Index (XE.Key.Ent);
2632                            while Present (Indx) loop
2633                               Check_Type_Reference
2634                                 (First_Subtype (Etype (Indx)), True);
2635                               Next_Index (Indx);
2636                            end loop;
2637                         end;
2638                      end if;
2639
2640                      --  If the entity is an overriding operation, write info
2641                      --  on operation that was overridden.
2642
2643                      if Is_Subprogram (XE.Key.Ent)
2644                        and then Present (Overridden_Operation (XE.Key.Ent))
2645                      then
2646                         Output_Overridden_Op
2647                           (Overridden_Operation (XE.Key.Ent));
2648                      end if;
2649
2650                      --  End of processing for entity output
2651
2652                      Crloc := No_Location;
2653                   end if;
2654
2655                   --  Output the reference if it is not as the same location
2656                   --  as the previous one, or it is a read-reference that
2657                   --  indicates that the entity is an in-out actual in a call.
2658
2659                   if XE.Key.Loc /= No_Location
2660                     and then
2661                       (XE.Key.Loc /= Crloc
2662                         or else (Prevt = 'm' and then  XE.Key.Typ = 'r'))
2663                   then
2664                      Crloc := XE.Key.Loc;
2665                      Prevt := XE.Key.Typ;
2666
2667                      --  Start continuation if line full, else blank
2668
2669                      if Write_Info_Col > 72 then
2670                         Write_Info_EOL;
2671                         Write_Info_Initiate ('.');
2672                      end if;
2673
2674                      Write_Info_Char (' ');
2675
2676                      --  Output file number if changed
2677
2678                      if XE.Key.Lun /= Curru then
2679                         Curru := XE.Key.Lun;
2680                         Write_Info_Nat (Dependency_Num (Curru));
2681                         Write_Info_Char ('|');
2682                      end if;
2683
2684                      Write_Info_Nat
2685                        (Int (Get_Logical_Line_Number (XE.Key.Loc)));
2686                      Write_Info_Char (XE.Key.Typ);
2687
2688                      if Is_Overloadable (XE.Key.Ent) then
2689                         if (Is_Imported (XE.Key.Ent) and then XE.Key.Typ = 'b')
2690                              or else
2691                            (Is_Exported (XE.Key.Ent) and then XE.Key.Typ = 'i')
2692                         then
2693                            Output_Import_Export_Info (XE.Key.Ent);
2694                         end if;
2695                      end if;
2696
2697                      Write_Info_Nat (Int (Get_Column_Number (XE.Key.Loc)));
2698
2699                      Output_Instantiation_Refs (Sloc (XE.Key.Ent));
2700                   end if;
2701                end if;
2702             end Output_One_Ref;
2703
2704          <<Continue>>
2705             null;
2706          end loop;
2707
2708          Write_Info_EOL;
2709       end Output_Refs;
2710    end Output_References;
2711
2712    ---------------------------------
2713    -- Process_Deferred_References --
2714    ---------------------------------
2715
2716    procedure Process_Deferred_References is
2717    begin
2718       for J in Deferred_References.First .. Deferred_References.Last loop
2719          declare
2720             D : Deferred_Reference_Entry renames Deferred_References.Table (J);
2721
2722          begin
2723             case Is_LHS (D.N) is
2724                when Yes =>
2725                   Generate_Reference (D.E, D.N, 'm');
2726
2727                when No =>
2728                   Generate_Reference (D.E, D.N, 'r');
2729
2730                --  Not clear if Unknown can occur at this stage, but if it
2731                --  does we will treat it as a normal reference.
2732
2733                when Unknown =>
2734                   Generate_Reference (D.E, D.N, 'r');
2735             end case;
2736          end;
2737       end loop;
2738
2739       --  Clear processed entries from table
2740
2741       Deferred_References.Init;
2742    end Process_Deferred_References;
2743
2744 --  Start of elaboration for Lib.Xref
2745
2746 begin
2747    --  Reset is necessary because Elmt_Ptr does not default to Null_Ptr,
2748    --  because it's not an access type.
2749
2750    Xref_Set.Reset;
2751 end Lib.Xref;