gcc/ada/types.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                T Y P E S                                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package contains host independent type definitions which are used
  35 --  in more than one unit in the compiler. They are gathered here for easy
  36 --  reference, though in some cases the full description is found in the
  37 --  relevant module which implements the definition. The main reason that
  38 --  they are not in their "natural" specs is that this would cause a lot of
  39 --  inter-spec dependencies, and in particular some awkward circular
  40 --  dependencies would have to be dealt with.
  41
  42 --  WARNING: There is a C version of this package. Any changes to this
  43 --  source file must be properly reflected in the C header file types.h
  44
  45 --  Note: the declarations in this package reflect an expectation that the
  46 --  host machine has an efficient integer base type with a range at least
  47 --  32 bits 2s-complement. If there are any machines for which this is not
  48 --  a correct assumption, a significant number of changes will be required!
  49
  50 with Unchecked_Deallocation;
  51
  52 package Types is
  53    pragma Preelaborate;
  54
  55    -------------------------------
  56    -- General Use Integer Types --
  57    -------------------------------
  58
  59    type Int is range -2 ** 31 .. +2 ** 31 - 1;
  60    --  Signed 32-bit integer
  61
  62    type Dint is range -2 ** 63 .. +2 ** 63 - 1;
  63    --  Double length (64-bit) integer
  64
  65    subtype Nat is Int range 0 .. Int'Last;
  66    --  Non-negative Int values
  67
  68    subtype Pos is Int range 1 .. Int'Last;
  69    --  Positive Int values
  70
  71    type Word is mod 2 ** 32;
  72    --  Unsigned 32-bit integer
  73
  74    type Short is range -32768 .. +32767;
  75    for Short'Size use 16;
  76    --  16-bit signed integer
  77
  78    type Byte is mod 2 ** 8;
  79    for Byte'Size use 8;
  80    --  8-bit unsigned integer
  81
  82    type size_t is mod 2 ** Standard'Address_Size;
  83    --  Memory size value, for use in calls to C routines
  84
  85    --------------------------------------
  86    -- 8-Bit Character and String Types --
  87    --------------------------------------
  88
  89    --  We use Standard.Character and Standard.String freely, since we are
  90    --  compiling ourselves, and we properly implement the required 8-bit
  91    --  character code as required in Ada 95. This section defines a few
  92    --  general use constants and subtypes.
  93
  94    EOF : constant Character := ASCII.SUB;
  95    --  The character SUB (16#1A#) is used in DOS and other systems derived
  96    --  from DOS (OS/2, NT etc) to signal the end of a text file. Internally
  97    --  all source files are ended by an EOF character, even on Unix systems.
  98    --  An EOF character acts as the end of file only as the last character
  99    --  of a source buffer, in any other position, it is treated as a blank
 100    --  if it appears between tokens, and as an illegal character otherwise.
 101    --  This makes life easier dealing with files that originated from DOS,
 102    --  including concatenated files with interspersed EOF characters.
 103
 104    subtype Graphic_Character is Character range ' ' .. '~';
 105    --  Graphic characters, as defined in ARM
 106
 107    subtype Line_Terminator is Character range ASCII.LF .. ASCII.CR;
 108    --  Line terminator characters (LF, VT, FF, CR)
 109    --
 110    --  This definition is dubious now that we have two more wide character
 111    --  sequences that constitute a line terminator. Every reference to
 112    --  this subtype needs checking to make sure the wide character case
 113    --  is handled appropriately. ???
 114
 115    subtype Upper_Half_Character is
 116      Character range Character'Val (16#80#) .. Character'Val (16#FF#);
 117    --  Characters with the upper bit set
 118
 119    type Character_Ptr is access all Character;
 120    type String_Ptr    is access all String;
 121    --  Standard character and string pointers
 122
 123    procedure Free is new Unchecked_Deallocation (String, String_Ptr);
 124    --  Procedure for freeing dynamically allocated String values
 125
 126    subtype Word_Hex_String is String (1 .. 8);
 127    --  Type used to represent Word value as 8 hex digits, with lower case
 128    --  letters for the alphabetic cases.
 129
 130    function Get_Hex_String (W : Word) return Word_Hex_String;
 131    --  Convert word value to 8-character hex string
 132
 133    -----------------------------------------
 134    -- Types Used for Text Buffer Handling --
 135    -----------------------------------------
 136
 137    --  We can't use type String for text buffers, since we must use the
 138    --  standard 32-bit integer as an index value, since we count on all
 139    --  index values being the same size.
 140
 141    type Text_Ptr is new Int;
 142    --  Type used for subscripts in text buffer
 143
 144    type Text_Buffer is array (Text_Ptr range <>) of Character;
 145    --  Text buffer used to hold source file or library information file
 146
 147    type Text_Buffer_Ptr is access all Text_Buffer;
 148    --  Text buffers for input files are allocated dynamically and this type
 149    --  is used to reference these text buffers.
 150
 151    procedure Free is new Unchecked_Deallocation (Text_Buffer, Text_Buffer_Ptr);
 152    --  Procedure for freeing dynamically allocated text buffers
 153
 154    ------------------------------------------
 155    -- Types Used for Source Input Handling --
 156    ------------------------------------------
 157
 158    type Logical_Line_Number is range 0 .. Int'Last;
 159    for Logical_Line_Number'Size use 32;
 160    --  Line number type, used for storing logical line numbers (i.e. line
 161    --  numbers that include effects of any Source_Reference pragmas in the
 162    --  source file). The value zero indicates a line containing a source
 163    --  reference pragma.
 164
 165    No_Line_Number : constant Logical_Line_Number := 0;
 166    --  Special value used to indicate no line number
 167
 168    type Physical_Line_Number is range 1 .. Int'Last;
 169    for Physical_Line_Number'Size use 32;
 170    --  Line number type, used for storing physical line numbers (i.e.
 171    --  line numbers in the physical file being compiled, unaffected by
 172    --  the presence of source reference pragmas.
 173
 174    type Column_Number is range 0 .. 32767;
 175    for Column_Number'Size use 16;
 176    --  Column number (assume that 2**15 - 1 is large enough). The range for
 177    --  this type is used to compute Hostparm.Max_Line_Length. See also the
 178    --  processing for -gnatyM in Stylesw).
 179
 180    No_Column_Number : constant Column_Number := 0;
 181    --  Special value used to indicate no column number
 182
 183    subtype Source_Buffer is Text_Buffer;
 184    --  Type used to store text of a source file . The buffer for the main
 185    --  source (the source specified on the command line) has a lower bound
 186    --  starting at zero. Subsequent subsidiary sources have lower bounds
 187    --  which are one greater than the previous upper bound.
 188
 189    subtype Big_Source_Buffer is Text_Buffer (0 .. Text_Ptr'Last);
 190    --  This is a virtual type used as the designated type of the access
 191    --  type Source_Buffer_Ptr, see Osint.Read_Source_File for details.
 192
 193    type Source_Buffer_Ptr is access all Big_Source_Buffer;
 194    --  Pointer to source buffer. We use virtual origin addressing for
 195    --  source buffers, with thin pointers. The pointer points to a virtual
 196    --  instance of type Big_Source_Buffer, where the actual type is in fact
 197    --  of type Source_Buffer. The address is adjusted so that the virtual
 198    --  origin addressing works correctly. See Osint.Read_Source_Buffer for
 199    --  further details.
 200
 201    subtype Source_Ptr is Text_Ptr;
 202    --  Type used to represent a source location, which is a subscript of a
 203    --  character in the source buffer. As noted above, diffferent source
 204    --  buffers have different ranges, so it is possible to tell from a
 205    --  Source_Ptr value which source it refers to. Note that negative numbers
 206    --  are allowed to accommodate the following special values.
 207
 208    No_Location : constant Source_Ptr := -1;
 209    --  Value used to indicate no source position set in a node. A test for
 210    --  a Source_Ptr value being > No_Location is the approved way to test
 211    --  for a standard value that does not include No_Location or any of the
 212    --  following special definitions.
 213
 214    Standard_Location : constant Source_Ptr := -2;
 215    --  Used for all nodes in the representation of package Standard other
 216    --  than nodes representing the contents of Standard.ASCII. Note that
 217    --  testing for <= Standard_Location tests for both Standard_Location
 218    --  and for Standard_ASCII_Location.
 219
 220    Standard_ASCII_Location : constant Source_Ptr := -3;
 221    --  Used for all nodes in the presentation of package Standard.ASCII
 222
 223    System_Location : constant Source_Ptr := -4;
 224    --  Used to identify locations of pragmas scanned by Targparm, where we
 225    --  know the location is in System, but we don't know exactly what line.
 226
 227    First_Source_Ptr : constant Source_Ptr := 0;
 228    --  Starting source pointer index value for first source program
 229
 230    -------------------------------------
 231    -- Range Definitions for Tree Data --
 232    -------------------------------------
 233
 234    --  The tree has fields that can hold any of the following types:
 235
 236    --    Pointers to other tree nodes (type Node_Id)
 237    --    List pointers (type List_Id)
 238    --    Element list pointers (type Elist_Id)
 239    --    Names (type Name_Id)
 240    --    Strings (type String_Id)
 241    --    Universal integers (type Uint)
 242    --    Universal reals (type Ureal)
 243
 244    --  In most contexts, the strongly typed interface determines which of
 245    --  these types is present. However, there are some situations (involving
 246    --  untyped traversals of the tree), where it is convenient to be easily
 247    --  able to distinguish these values. The underlying representation in all
 248    --  cases is an integer type Union_Id, and we ensure that the range of
 249    --  the various possible values for each of the above types is disjoint
 250    --  so that this distinction is possible.
 251
 252    type Union_Id is new Int;
 253    --  The type in the tree for a union of possible ID values
 254
 255    --  Note: it is also helpful for debugging purposes to make these ranges
 256    --  distinct. If a bug leads to misidentification of a value, then it will
 257    --  typically result in an out of range value and a Constraint_Error.
 258
 259    List_Low_Bound : constant := -100_000_000;
 260    --  The List_Id values are subscripts into an array of list headers which
 261    --  has List_Low_Bound as its lower bound. This value is chosen so that all
 262    --  List_Id values are negative, and the value zero is in the range of both
 263    --  List_Id and Node_Id values (see further description below).
 264
 265    List_High_Bound : constant := 0;
 266    --  Maximum List_Id subscript value. This allows up to 100 million list
 267    --  Id values, which is in practice infinite, and there is no need to
 268    --  check the range. The range overlaps the node range by one element
 269    --  (with value zero), which is used both for the Empty node, and for
 270    --  indicating no list. The fact that the same value is used is convenient
 271    --  because it means that the default value of Empty applies to both nodes
 272    --  and lists, and also is more efficient to test for.
 273
 274    Node_Low_Bound : constant := 0;
 275    --  The tree Id values start at zero, because we use zero for Empty (to
 276    --  allow a zero test for Empty). Actual tree node subscripts start at 0
 277    --  since Empty is a legitimate node value.
 278
 279    Node_High_Bound : constant := 099_999_999;
 280    --  Maximum number of nodes that can be allocated is 100 million, which
 281    --  is in practice infinite, and there is no need to check the range.
 282
 283    Elist_Low_Bound : constant := 100_000_000;
 284    --  The Elist_Id values are subscripts into an array of elist headers which
 285    --  has Elist_Low_Bound as its lower bound.
 286
 287    Elist_High_Bound : constant := 199_999_999;
 288    --  Maximum Elist_Id subscript value. This allows up to 100 million Elists,
 289    --  which is in practice infinite and there is no need to check the range.
 290
 291    Elmt_Low_Bound : constant := 200_000_000;
 292    --  Low bound of element Id values. The use of these values is internal to
 293    --  the Elists package, but the definition of the range is included here
 294    --  since it must be disjoint from other Id values. The Elmt_Id values are
 295    --  subscripts into an array of list elements which has this as lower bound.
 296
 297    Elmt_High_Bound : constant := 299_999_999;
 298    --  Upper bound of Elmt_Id values. This allows up to 100 million element
 299    --  list members, which is in practice infinite (no range check needed).
 300
 301    Names_Low_Bound : constant := 300_000_000;
 302    --  Low bound for name Id values
 303
 304    Names_High_Bound : constant := 399_999_999;
 305    --  Maximum number of names that can be allocated is 100 million, which is
 306    --  in practice infinite and there is no need to check the range.
 307
 308    Strings_Low_Bound : constant := 400_000_000;
 309    --  Low bound for string Id values
 310
 311    Strings_High_Bound : constant := 499_999_999;
 312    --  Maximum number of strings that can be allocated is 100 million, which
 313    --  is in practice infinite and there is no need to check the range.
 314
 315    Ureal_Low_Bound : constant := 500_000_000;
 316    --  Low bound for Ureal values
 317
 318    Ureal_High_Bound : constant := 599_999_999;
 319    --  Maximum number of Ureal values stored is 100_000_000 which is in
 320    --  practice infinite so that no check is required.
 321
 322    Uint_Low_Bound : constant := 600_000_000;
 323    --  Low bound for Uint values
 324
 325    Uint_Table_Start : constant := 2_000_000_000;
 326    --  Location where table entries for universal integers start (see
 327    --  Uintp spec for details of the representation of Uint values).
 328
 329    Uint_High_Bound : constant := 2_099_999_999;
 330    --  The range of Uint values is very large, since a substantial part
 331    --  of this range is used to store direct values, see Uintp for details.
 332
 333    --  The following subtype definitions are used to provide convenient names
 334    --  for membership tests on Int values to see what data type range they
 335    --  lie in. Such tests appear only in the lowest level packages.
 336
 337    subtype List_Range      is Union_Id
 338      range List_Low_Bound   .. List_High_Bound;
 339
 340    subtype Node_Range      is Union_Id
 341      range Node_Low_Bound   .. Node_High_Bound;
 342
 343    subtype Elist_Range     is Union_Id
 344      range Elist_Low_Bound  .. Elist_High_Bound;
 345
 346    subtype Elmt_Range      is Union_Id
 347      range Elmt_Low_Bound   .. Elmt_High_Bound;
 348
 349    subtype Names_Range     is Union_Id
 350      range Names_Low_Bound   .. Names_High_Bound;
 351
 352    subtype Strings_Range   is Union_Id
 353      range Strings_Low_Bound .. Strings_High_Bound;
 354
 355    subtype Uint_Range      is Union_Id
 356      range Uint_Low_Bound    .. Uint_High_Bound;
 357
 358    subtype Ureal_Range     is Union_Id
 359      range Ureal_Low_Bound    .. Ureal_High_Bound;
 360
 361    -----------------------------
 362    -- Types for Namet Package --
 363    -----------------------------
 364
 365    --  Name_Id values are used to identify entries in the names table. Except
 366    --  for the special values No_Name, and Error_Name, they are subscript
 367    --  values for the Names table defined in package Namet.
 368
 369    --  Note that with only a few exceptions, which are clearly documented, the
 370    --  type Name_Id should be regarded as a private type. In particular it is
 371    --  never appropriate to perform arithmetic operations using this type.
 372
 373    type Name_Id is range Names_Low_Bound .. Names_High_Bound;
 374    for Name_Id'Size use 32;
 375    --  Type used to identify entries in the names table
 376
 377    No_Name : constant Name_Id := Names_Low_Bound;
 378    --  The special Name_Id value No_Name is used in the parser to indicate
 379    --  a situation where no name is present (e.g. on a loop or block).
 380
 381    Error_Name : constant Name_Id := Names_Low_Bound +  1;
 382    --  The special Name_Id value Error_Name is used in the parser to
 383    --  indicate that some kind of error was encountered in scanning out
 384    --  the relevant name, so it does not have a representable label.
 385
 386    subtype Error_Name_Or_No_Name is Name_Id range No_Name .. Error_Name;
 387    --  Used to test for either error name or no name
 388
 389    First_Name_Id : constant Name_Id := Names_Low_Bound + 2;
 390    --  Subscript of first entry in names table
 391
 392    ----------------------------
 393    -- Types for Atree Package --
 394    ----------------------------
 395
 396    --  Node_Id values are used to identify nodes in the tree. They are
 397    --  subscripts into the Node table declared in package Tree. Note that
 398    --  the special values Empty and Error are subscripts into this table,
 399    --  See package Atree for further details.
 400
 401    type Node_Id is range Node_Low_Bound .. Node_High_Bound;
 402    --  Type used to identify nodes in the tree
 403
 404    subtype Entity_Id is Node_Id;
 405    --  A synonym for node types, used in the entity package to refer to
 406    --  nodes that are entities (i.e. nodes with an Nkind of N_Defining_xxx)
 407    --  All such nodes are extended nodes and these are the only extended
 408    --  nodes, so that in practice entity and extended nodes are synonymous.
 409
 410    subtype Node_Or_Entity_Id is Node_Id;
 411    --  A synonym for node types, used in cases where a given value may be used
 412    --  to represent either a node or an entity. We like to minimize such uses
 413    --  for obvious reasons of logical type consistency, but where such uses
 414    --  occur, they should be documented by use of this type.
 415
 416    Empty : constant Node_Id := Node_Low_Bound;
 417    --  Used to indicate null node. A node is actually allocated with this
 418    --  Id value, so that Nkind (Empty) = N_Empty. Note that Node_Low_Bound
 419    --  is zero, so Empty = No_List = zero.
 420
 421    Empty_List_Or_Node : constant := 0;
 422    --  This constant is used in situations (e.g. initializing empty fields)
 423    --  where the value set will be used to represent either an empty node
 424    --  or a non-existent list, depending on the context.
 425
 426    Error : constant Node_Id := Node_Low_Bound + 1;
 427    --  Used to indicate that there was an error in the source program. A node
 428    --  is actually allocated at this address, so that Nkind (Error) = N_Error.
 429
 430    Empty_Or_Error : constant Node_Id := Error;
 431    --  Since Empty and Error are the first two Node_Id values, the test for
 432    --  N <= Empty_Or_Error tests to see if N is Empty or Error. This definition
 433    --  provides convenient self-documentation for such tests.
 434
 435    First_Node_Id  : constant Node_Id := Node_Low_Bound;
 436    --  Subscript of first allocated node. Note that Empty and Error are both
 437    --  allocated nodes, whose Nkind fields can be accessed without error.
 438
 439    ------------------------------
 440    -- Types for Nlists Package --
 441    ------------------------------
 442
 443    --  List_Id values are used to identify node lists in the tree. They are
 444    --  subscripts into the Lists table declared in package Tree. Note that
 445    --  the special value Error_List is a subscript in this table, but the
 446    --  value No_List is *not* a valid subscript, and any attempt to apply
 447    --  list operations to No_List will cause a (detected) error.
 448
 449    type List_Id is range List_Low_Bound .. List_High_Bound;
 450    --  Type used to identify a node list
 451
 452    No_List : constant List_Id := List_High_Bound;
 453    --  Used to indicate absence of a list. Note that the value is zero, which
 454    --  is the same as Empty, which is helpful in intializing nodes where a
 455    --  value of zero can represent either an empty node or an empty list.
 456
 457    Error_List : constant List_Id := List_Low_Bound;
 458    --  Used to indicate that there was an error in the source program in a
 459    --  context which would normally require a list. This node appears to be
 460    --  an empty list to the list operations (a null list is actually allocated
 461    --  which has this Id value).
 462
 463    First_List_Id : constant List_Id := Error_List;
 464    --  Subscript of first allocated list header
 465
 466    ------------------------------
 467    -- Types for Elists Package --
 468    ------------------------------
 469
 470    --  Element list Id values are used to identify element lists stored in
 471    --  the tree (see package Tree for further details). They are formed by
 472    --  adding a bias (Element_List_Bias) to subscript values in the same
 473    --  array that is used for node list headers.
 474
 475    type Elist_Id is range Elist_Low_Bound .. Elist_High_Bound;
 476    --  Type used to identify an element list (Elist header table subscript)
 477
 478    No_Elist : constant Elist_Id := Elist_Low_Bound;
 479    --  Used to indicate absense of an element list. Note that this is not
 480    --  an actual Elist header, so element list operations on this value
 481    --  are not valid.
 482
 483    First_Elist_Id : constant Elist_Id := No_Elist + 1;
 484    --  Subscript of first allocated Elist header
 485
 486    --  Element Id values are used to identify individual elements of an
 487    --  element list (see package Elists for further details).
 488
 489    type Elmt_Id is range Elmt_Low_Bound .. Elmt_High_Bound;
 490    --  Type used to identify an element list
 491
 492    No_Elmt : constant Elmt_Id := Elmt_Low_Bound;
 493    --  Used to represent empty element
 494
 495    First_Elmt_Id : constant Elmt_Id := No_Elmt + 1;
 496    --  Subscript of first allocated Elmt table entry
 497
 498    -------------------------------
 499    -- Types for Stringt Package --
 500    -------------------------------
 501
 502    --  String_Id values are used to identify entries in the strings table.
 503    --  They are subscripts into the strings table defined in package Strings.
 504
 505    --  Note that with only a few exceptions, which are clearly documented, the
 506    --  type String_Id should be regarded as a private type. In particular it is
 507    --  never appropriate to perform arithmetic operations using this type.
 508
 509    type String_Id is range Strings_Low_Bound .. Strings_High_Bound;
 510    --  Type used to identify entries in the strings table
 511
 512    No_String : constant String_Id := Strings_Low_Bound;
 513    --  Used to indicate missing string Id. Note that the value zero is used
 514    --  to indicate a missing data value for all the Int types in this section.
 515
 516    First_String_Id : constant String_Id := No_String + 1;
 517    --  First subscript allocated in string table
 518
 519    -------------------------
 520    -- Character Code Type --
 521    -------------------------
 522
 523    --  The type Char is used for character data internally in the compiler,
 524    --  but character codes in the source are represented by the Char_Code
 525    --  type. Each character literal in the source is interpreted as being one
 526    --  of the 16#8000_0000 possible Wide_Wide_Character codes, and a unique
 527    --  Integer Value is assigned, corresponding to the UTF_32 value, which
 528    --  also correspondds to the POS value in the Wide_Wide_Character type,
 529    --  and also corresponds to the POS value in the Wide_Character and
 530    --  Character types for values that are in appropriate range. String
 531    --  literals are similarly interpreted as a sequence of such codes.
 532
 533    type Char_Code_Base is mod 2 ** 32;
 534    for Char_Code_Base'Size use 32;
 535
 536    subtype Char_Code is Char_Code_Base range 0 .. 16#7FFF_FFFF#;
 537    for Char_Code'Value_Size use 32;
 538    for Char_Code'Object_Size use 32;
 539
 540    function Get_Char_Code (C : Character) return Char_Code;
 541    pragma Inline (Get_Char_Code);
 542    --  Function to obtain internal character code from source character. For
 543    --  the moment, the internal character code is simply the Pos value of the
 544    --  input source character, but we provide this interface for possible
 545    --  later support of alternative character sets.
 546
 547    function In_Character_Range (C : Char_Code) return Boolean;
 548    pragma Inline (In_Character_Range);
 549    --  Determines if the given character code is in range of type Character,
 550    --  and if so, returns True. If not, returns False.
 551
 552    function In_Wide_Character_Range (C : Char_Code) return Boolean;
 553    pragma Inline (In_Wide_Character_Range);
 554    --  Determines if the given character code is in range of the type
 555    --  Wide_Character, and if so, returns True. If not, returns False.
 556
 557    function Get_Character (C : Char_Code) return Character;
 558    pragma Inline (Get_Character);
 559    --  For a character C that is in Character range (see above function), this
 560    --  function returns the corresponding Character value. It is an error to
 561    --  call Get_Character if C is not in C haracter range
 562
 563    function Get_Wide_Character (C : Char_Code) return Wide_Character;
 564    --  For a character C that is in Wide_Character range (see above function),
 565    --  this function returns the corresponding Wide_Character value. It is an
 566    --  error to call Get_Wide_Character if C is not in Wide_Character range.
 567
 568    ---------------------------------------
 569    -- Types used for Library Management --
 570    ---------------------------------------
 571
 572    type Unit_Number_Type is new Int;
 573    --  Unit number. The main source is unit 0, and subsidiary sources have
 574    --  non-zero numbers starting with 1. Unit numbers are used to index the
 575    --  file table in Lib.
 576
 577    Main_Unit : constant Unit_Number_Type := 0;
 578    --  Unit number value for main unit
 579
 580    No_Unit : constant Unit_Number_Type := -1;
 581    --  Special value used to signal no unit
 582
 583    type Source_File_Index is new Int range -1 .. Int'Last;
 584    --  Type used to index the source file table (see package Sinput)
 585
 586    Internal_Source_File : constant Source_File_Index :=
 587                             Source_File_Index'First;
 588    --  Value used to indicate the buffer for the source-code-like strings
 589    --  internally created withing the compiler (see package Sinput)
 590
 591    No_Source_File : constant Source_File_Index := 0;
 592    --  Value used to indicate no source file present
 593
 594    subtype File_Name_Type is Name_Id;
 595    --  File names are stored in the names table and this synonym is used to
 596    --  indicate that a Name_Id value is being used to hold a simple file
 597    --  name (which does not include any directory information).
 598
 599    No_File : constant File_Name_Type := File_Name_Type (No_Name);
 600    --  Constant used to indicate no file found
 601
 602    subtype Unit_Name_Type is Name_Id;
 603    --  Unit names are stored in the names table and this synonym is used to
 604    --  indicate that a Name_Id value is being used to hold a unit name.
 605
 606    -----------------------------------
 607    -- Representation of Time Stamps --
 608    -----------------------------------
 609
 610    --  All compiled units are marked with a time stamp which is derived from
 611    --  the source file (we assume that the host system has the concept of a
 612    --  file time stamp which is modified when a file is modified). These
 613    --  time stamps are used to ensure consistency of the set of units that
 614    --  constitutes a library. Time stamps are 12 character strings with
 615    --  with the following format:
 616
 617    --     YYYYMMDDHHMMSS
 618
 619    --       YYYY   year
 620    --       MM     month (2 digits 01-12)
 621    --       DD     day (2 digits 01-31)
 622    --       HH     hour (2 digits 00-23)
 623    --       MM     minutes (2 digits 00-59)
 624    --       SS     seconds (2 digits 00-59)
 625
 626    --  In the case of Unix systems (and other systems which keep the time in
 627    --  GMT), the time stamp is the GMT time of the file, not the local time.
 628    --  This solves problems in using libraries across networks with clients
 629    --  spread across multiple time-zones.
 630
 631    Time_Stamp_Length : constant := 14;
 632    --  Length of time stamp value
 633
 634    subtype Time_Stamp_Index is Natural range 1 .. Time_Stamp_Length;
 635    type Time_Stamp_Type is new String (Time_Stamp_Index);
 636    --  Type used to represent time stamp
 637
 638    Empty_Time_Stamp : constant Time_Stamp_Type := (others => ' ');
 639    --  Type used to represent an empty or missing time stamp. Looks less
 640    --  than any real time stamp if two time stamps are compared. Note that
 641    --  although this is not a private type, clients should not rely on the
 642    --  exact way in which this string is represented, and instead should
 643    --  use the subprograms below.
 644
 645    Dummy_Time_Stamp : constant Time_Stamp_Type := (others => '0');
 646    --  This is used for dummy time stamp values used in the D lines for
 647    --  non-existant files, and is intended to be an impossible value.
 648
 649    function "="  (Left, Right : Time_Stamp_Type) return Boolean;
 650    function "<=" (Left, Right : Time_Stamp_Type) return Boolean;
 651    function ">=" (Left, Right : Time_Stamp_Type) return Boolean;
 652    function "<"  (Left, Right : Time_Stamp_Type) return Boolean;
 653    function ">"  (Left, Right : Time_Stamp_Type) return Boolean;
 654    --  Comparison functions on time stamps. Note that two time stamps
 655    --  are defined as being equal if they have the same day/month/year
 656    --  and the hour/minutes/seconds values are within 2 seconds of one
 657    --  another. This deals with rounding effects in library file time
 658    --  stamps caused by copying operations during installation. We have
 659    --  particularly noticed that WinNT seems susceptible to such changes.
 660    --  Note: the Empty_Time_Stamp value looks equal to itself, and less
 661    --  than any non-empty time stamp value.
 662
 663    procedure Split_Time_Stamp
 664      (TS      : Time_Stamp_Type;
 665       Year    : out Nat;
 666       Month   : out Nat;
 667       Day     : out Nat;
 668       Hour    : out Nat;
 669       Minutes : out Nat;
 670       Seconds : out Nat);
 671    --  Given a time stamp, decompose it into its components
 672
 673    procedure Make_Time_Stamp
 674      (Year    : Nat;
 675       Month   : Nat;
 676       Day     : Nat;
 677       Hour    : Nat;
 678       Minutes : Nat;
 679       Seconds : Nat;
 680       TS      : out Time_Stamp_Type);
 681    --  Given the components of a time stamp, initialize the value
 682
 683    -----------------------------------------------
 684    -- Types used for Pragma Suppress Management --
 685    -----------------------------------------------
 686
 687    type Check_Id is
 688      (Access_Check,
 689       Accessibility_Check,
 690       Alignment_Check,
 691       Discriminant_Check,
 692       Division_Check,
 693       Elaboration_Check,
 694       Index_Check,
 695       Length_Check,
 696       Overflow_Check,
 697       Range_Check,
 698       Storage_Check,
 699       Tag_Check,
 700       Validity_Check,
 701       All_Checks);
 702
 703    --  The following array contains an entry for each recognized check name
 704    --  for pragma Suppress. It is used to represent current settings of scope
 705    --  based suppress actions from pragma Suppress or command line settings.
 706
 707    --  Note: when Suppress_Array (All_Checks) is True, then generally all other
 708    --  specific check entries are set True, except for the Elaboration_Check
 709    --  entry which is set only if an explicit Suppress for this check is given.
 710    --  The reason for this non-uniformity is that we do not want All_Checks to
 711    --  suppress elaboration checking when using the static elaboration model.
 712    --  We recognize only an explicit suppress of Elaboration_Check as a signal
 713    --  that the static elaboration checking should skip a compile time check.
 714
 715    type Suppress_Array is array (Check_Id) of Boolean;
 716    pragma Pack (Suppress_Array);
 717
 718    --  To add a new check type to GNAT, the following steps are required:
 719
 720    --    1.  Add an entry to Snames spec and body for the new name
 721    --    2.  Add an entry to the definition of Check_Id above
 722    --    3.  Add a new function to Checks to handle the new check test
 723    --    4.  Add a new Do_xxx_Check flag to Sinfo (if required)
 724    --    5.  Add appropriate checks for the new test
 725
 726    -----------------------------------
 727    -- Global Exception Declarations --
 728    -----------------------------------
 729
 730    --  This section contains declarations of exceptions that are used
 731    --  throughout the compiler or in other GNAT tools.
 732
 733    Unrecoverable_Error : exception;
 734    --  This exception is raised to immediately terminate the compilation
 735    --  of the current source program. Used in situations where things are
 736    --  bad enough that it doesn't seem worth continuing (e.g. max errors
 737    --  reached, or a required file is not found). Also raised when the
 738    --  compiler finds itself in trouble after an error (see Comperr).
 739
 740    Terminate_Program : exception;
 741    --  This exception is raised to immediately terminate the tool being
 742    --  executed. Each tool where this exception may be raised must have
 743    --  a single exception handler that contains only a null statement and
 744    --  that is the last statement of the program. If needed, procedure
 745    --  Set_Exit_Status is called with the appropriate exit status before
 746    --  raising Terminate_Program.
 747
 748    ---------------------------------
 749    -- Parameter Mechanism Control --
 750    ---------------------------------
 751
 752    --  Function and parameter entities have a field that records the
 753    --  passing mechanism. See specification of Sem_Mech for full details.
 754    --  The following subtype is used to represent values of this type:
 755
 756    subtype Mechanism_Type is Int range -10 .. Int'Last;
 757    --  Type used to represent a mechanism value. This is a subtype rather
 758    --  than a type to avoid some annoying processing problems with certain
 759    --  routines in Einfo (processing them to create the corresponding C).
 760
 761    ------------------------------
 762    -- Run-Time Exception Codes --
 763    ------------------------------
 764
 765    --  When the code generator generates a run-time exception, it provides
 766    --  a reason code which is one of the following. This reason code is used
 767    --  to select the appropriate run-time routine to be called, determining
 768    --  both the exception to be raised, and the message text to be added.
 769
 770    --  The prefix CE/PE/SE indicates the exception to be raised
 771    --    CE = Constraint_Error
 772    --    PE = Program_Error
 773    --    SE = Storage_Error
 774
 775    --  The remaining part of the name indicates the message text to be added,
 776    --  where all letters are lower case, and underscores are converted to
 777    --  spaces (for example CE_Invalid_Data adds the text "invalid data").
 778
 779    --  To add a new code, you need to do the following:
 780
 781    --    1. Modify the type and subtype declarations below appropriately,
 782    --       keeping things in alphabetical order.
 783
 784    --    2. Modify the corresponding definitions in types.h, including
 785    --       the definition of last_reason_code.
 786
 787    --    3. Add a new routine in Ada.Exceptions with the appropriate call
 788    --       and static string constant. Note that there is more than one
 789    --       version of a-except.adb which must be modified.
 790
 791    type RT_Exception_Code is
 792      (CE_Access_Check_Failed,            -- 00
 793       CE_Access_Parameter_Is_Null,       -- 01
 794       CE_Discriminant_Check_Failed,      -- 02
 795       CE_Divide_By_Zero,                 -- 03
 796       CE_Explicit_Raise,                 -- 04
 797       CE_Index_Check_Failed,             -- 05
 798       CE_Invalid_Data,                   -- 06
 799       CE_Length_Check_Failed,            -- 07
 800       CE_Null_Exception_Id,              -- 08
 801       CE_Null_Not_Allowed,               -- 09
 802       CE_Overflow_Check_Failed,          -- 10
 803       CE_Partition_Check_Failed,         -- 11
 804       CE_Range_Check_Failed,             -- 12
 805       CE_Tag_Check_Failed,               -- 13
 806
 807       PE_Access_Before_Elaboration,      -- 14
 808       PE_Accessibility_Check_Failed,     -- 15
 809       PE_All_Guards_Closed,              -- 16
 810       PE_Current_Task_In_Entry_Body,     -- 17
 811       PE_Duplicated_Entry_Address,       -- 18
 812       PE_Explicit_Raise,                 -- 19
 813       PE_Finalize_Raised_Exception,      -- 20
 814       PE_Implicit_Return,                -- 21
 815       PE_Misaligned_Address_Value,       -- 22
 816       PE_Missing_Return,                 -- 23
 817       PE_Overlaid_Controlled_Object,     -- 24
 818       PE_Potentially_Blocking_Operation, -- 25
 819       PE_Stubbed_Subprogram_Called,      -- 26
 820       PE_Unchecked_Union_Restriction,    -- 27
 821       PE_Illegal_RACW_E_4_18,            -- 28
 822
 823       SE_Empty_Storage_Pool,             -- 29
 824       SE_Explicit_Raise,                 -- 30
 825       SE_Infinite_Recursion,             -- 31
 826       SE_Object_Too_Large);              -- 32
 827
 828    subtype RT_CE_Exceptions is RT_Exception_Code range
 829      CE_Access_Check_Failed ..
 830      CE_Tag_Check_Failed;
 831
 832    subtype RT_PE_Exceptions is RT_Exception_Code range
 833      PE_Access_Before_Elaboration ..
 834      PE_Illegal_RACW_E_4_18;
 835
 836    subtype RT_SE_Exceptions is RT_Exception_Code range
 837      SE_Empty_Storage_Pool ..
 838      SE_Object_Too_Large;
 839
 840 end Types;