libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_INIT([GNU Offloading and Multi Processing Runtime Library], 1.0,,[libgomp])
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # -------
   8 # Options
   9 # -------
  10
  11 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  12 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  13    [Specify that runtime libraries should be installed in a compiler-specific directory],
  14    permit yes|no)
  15 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  16
  17 # We would like our source tree to be readonly. However when releases or
  18 # pre-releases are generated, the flex/bison generated files as well as the
  19 # various formats of manuals need to be included along with the rest of the
  20 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  21 # just that.
  22 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  23 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  24    [put copies of generated files in source dir intended for creating source
  25     tarballs for users without texinfo bison or flex.],
  26    permit yes|no)
  27 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  28 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  29
  30
  31 # -------
  32 # -------
  33
  34 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  35 #
  36 # You will slowly go insane if you do not grok the following fact:  when
  37 # building this library, the top-level /target/ becomes the library's /host/.
  38 #
  39 # configure then causes --target to default to --host, exactly like any
  40 # other package using autoconf.  Therefore, 'target' and 'host' will
  41 # always be the same.  This makes sense both for native and cross compilers
  42 # just think about it for a little while.  :-)
  43 #
  44 # Also, if this library is being configured as part of a cross compiler, the
  45 # top-level configure script will pass the "real" host as $with_cross_host.
  46 #
  47 # Do not delete or change the following two lines.  For why, see
  48 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  49 AC_CANONICAL_SYSTEM
  50 target_alias=${target_alias-$host_alias}
  51
  52 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  53 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  54 #  1.9.0:  minimum required version
  55 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  56 #              of other PACKAGE_* variables will, however, and there's nothing
  57 #              we can do about that; they come from AC_INIT).
  58 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  59 #            file in the top srcdir, etc, etc), so stop complaining.
  60 #  no-dist:  we don't want 'dist' and related rules.
  61 #  -Wall:  turns on all automake warnings...
  62 #  -Wno-portability:  ...except this one, since GNU make is required.
  63 #  -Wno-override: ... and this one, since we do want this in testsuite.
  64 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  65 AM_ENABLE_MULTILIB(, ..)
  66
  67 GCC_WITH_TOOLEXECLIBDIR
  68
  69 # Calculate toolexeclibdir
  70 # Also toolexecdir, though it's only used in toolexeclibdir
  71 case ${enable_version_specific_runtime_libs} in
  72   yes)
  73     # Need the gcc compiler version to know where to install libraries
  74     # and header files if --enable-version-specific-runtime-libs option
  75     # is selected.
  76     toolexecdir='$(libdir)/gcc/$(target_alias)'
  77     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  78     ;;
  79   no)
  80     if test -n "$with_cross_host" &&
  81        test x"$with_cross_host" != x"no"; then
  82       # Install a library built with a cross compiler in tooldir, not libdir.
  83       toolexecdir='$(exec_prefix)/$(target_alias)'
  84       case ${with_toolexeclibdir} in
  85         no)
  86           toolexeclibdir='$(toolexecdir)/lib'
  87           ;;
  88         *)
  89           toolexeclibdir=${with_toolexeclibdir}
  90           ;;
  91       esac
  92     else
  93       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  94       toolexeclibdir='$(libdir)'
  95     fi
  96     multi_os_directory=`$CC -print-multi-os-directory`
  97     case $multi_os_directory in
  98       .) ;; # Avoid trailing /.
  99       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 100     esac
 101     ;;
 102 esac
 103 AC_SUBST(toolexecdir)
 104 AC_SUBST(toolexeclibdir)
 105
 106 # Check the compiler.
 107 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 108 # We must force CC to /not/ be precious variables; otherwise
 109 # the wrong, non-multilib-adjusted value will be used in multilibs.
 110 # As a side effect, we have to subst CFLAGS ourselves.
 111
 112 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 113 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 114 AC_PROG_CC
 115 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 116
 117 AC_SUBST(CFLAGS)
 118
 119 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 120 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 121 # in both places for now and restore CFLAGS at the end of config.
 122 save_CFLAGS="$CFLAGS"
 123
 124 AC_ARG_ENABLE([werror],
 125   [AS_HELP_STRING([--disable-werror], [disable building with -Werror])])
 126 # Add -Wall -Werror if we are using GCC.
 127 AS_IF([test "x$GCC" = "xyes"],
 128   [XCFLAGS="$XCFLAGS -Wall"])
 129 AS_IF([test "x$enable_werror" != "xno" && test "x$GCC" = "xyes"],
 130   [XCFLAGS="$XCFLAGS -Werror"])
 131
 132 # Find other programs we need.
 133 AC_CHECK_TOOL(AR, ar)
 134 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 135 AC_PROG_MAKE_SET
 136 AC_PROG_INSTALL
 137
 138 # See if makeinfo has been installed and is modern enough
 139 # that we can use it.
 140 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 141                    [GNU texinfo.* \([0-9][0-9.]*\)],
 142                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 143 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 144
 145
 146 # Configure libtool
 147 AM_PROG_LIBTOOL
 148 ACX_LT_HOST_FLAGS
 149 AC_SUBST(enable_shared)
 150 AC_SUBST(enable_static)
 151
 152 AM_MAINTAINER_MODE
 153
 154 # We optionally test libgomp C++ support, and for that want to use the proper
 155 # C++ driver, 'g++' (or 'xg++' for build-tree testing).  Given that build of
 156 # target libstdc++-v3 depends on target libgomp (see '../Makefile.def'), we
 157 # cannot make build of target libgomp depend on target libstdc++-v3: circular
 158 # dependency.  We thus cannot instantiate 'AC_PROG_CXX' here: we'd get
 159 # '-funconfigured-libstdc++-v3' (see '../configure.ac').  Therefore, just
 160 # capture 'CXX', and we'll fix this up at 'make check' time (see
 161 # 'testsuite/lib/libgomp.exp:libgomp_init').
 162 AC_SUBST(CXX)
 163
 164 # Create a spec file, so that compile/link tests don't fail
 165 test -f libgfortran.spec || touch libgfortran.spec
 166 FCFLAGS="$FCFLAGS -L."
 167
 168 # We need 'gfortran' to compile parts of the library, and test libgomp Fortran
 169 # support.
 170 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 171 #AC_PROG_FC(gfortran)
 172 case `echo $GFORTRAN` in
 173   -* | no* )
 174     FC=no ;;
 175   *)
 176     set dummy $GFORTRAN; ac_word=$2
 177     if test -x "$ac_word"; then
 178       FC="$GFORTRAN"
 179     else
 180       FC=no
 181     fi ;;
 182 esac
 183 AC_PROG_FC(gfortran)
 184 FCFLAGS="$FCFLAGS -Wall -L../libgfortran"
 185
 186 # For libtool versioning info, format is CURRENT:REVISION:AGE
 187 libtool_VERSION=1:0:0
 188 AC_SUBST(libtool_VERSION)
 189
 190 # Check header files.
 191 AC_STDC_HEADERS
 192 AC_HEADER_TIME
 193 ACX_HEADER_STRING
 194 AC_CHECK_HEADERS(pthread.h unistd.h semaphore.h sys/loadavg.h sys/sysctl.h sys/time.h)
 195
 196 XPCFLAGS=""
 197 case "$host" in
 198   *-*-rtems*)
 199     # RTEMS supports Pthreads, but the library is not available at GCC build time.
 200     ;;
 201   nvptx*-*-* | amdgcn*-*-*)
 202     # NVPTX does not support Pthreads, has its own code replacement.
 203     libgomp_use_pthreads=no
 204     # NVPTX is an accelerator-only target
 205     libgomp_offloaded_only=yes
 206     ;;
 207   *)
 208     # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 209     # In case the pthread.h system header is not found, this test will fail.
 210     CFLAGS="$CFLAGS -pthread"
 211     AC_LINK_IFELSE(
 212      [AC_LANG_PROGRAM(
 213       [#include <pthread.h>
 214        void *g(void *d) { return NULL; }],
 215       [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 216      [XPCFLAGS=" -Wc,-pthread"],
 217      [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 218       AC_LINK_IFELSE(
 219        [AC_LANG_PROGRAM(
 220         [#include <pthread.h>
 221          void *g(void *d) { return NULL; }],
 222         [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 223        [],
 224        [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 225 esac
 226
 227 if test x$libgomp_use_pthreads != xno; then
 228   AC_DEFINE(LIBGOMP_USE_PTHREADS, 1,
 229             [Define to 1 if libgomp should use POSIX threads.])
 230 fi
 231
 232 if test x$libgomp_offloaded_only = xyes; then
 233   AC_DEFINE(LIBGOMP_OFFLOADED_ONLY, 1,
 234             [Define to 1 if building libgomp for an accelerator-only target.])
 235 fi
 236
 237 if test "x$enable_offload_defaulted" = xyes; then
 238   AC_DEFINE(OFFLOAD_DEFAULTED, 1,
 239     [Define to 1 to if -foffload is defaulted])
 240 fi
 241
 242 AC_CHECK_SIZEOF([void *])
 243
 244 m4_include([plugin/configfrag.ac])
 245
 246 # Check for functions needed.
 247 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 248 AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 249
 250 # Check for broken semaphore implementation on darwin.
 251 # sem_init returns: sem_init error: Function not implemented.
 252 case "$host" in
 253   *-darwin*)
 254     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 255         Define if the POSIX Semaphores do not work on your system.)
 256     ;;
 257 esac
 258
 259 # RTEMS specific checks
 260 case "$host" in
 261   *-*-rtems*)
 262     AC_CHECK_TYPES([struct _Mutex_Control],[],[],[#include <sys/lock.h>])
 263     ;;
 264 esac
 265
 266 GCC_LINUX_FUTEX(:)
 267
 268 # Check for pthread_{,attr_}[sg]etaffinity_np.
 269 AC_LINK_IFELSE(
 270  [AC_LANG_PROGRAM(
 271   [#define _GNU_SOURCE
 272    #include <pthread.h>],
 273   [cpu_set_t cpuset;
 274    pthread_attr_t attr;
 275    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 276    if (CPU_ISSET (0, &cpuset))
 277      CPU_SET (1, &cpuset);
 278    else
 279      CPU_ZERO (&cpuset);
 280    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 281    pthread_attr_init (&attr);
 282    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 283    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 284   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 285 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 286
 287 # At least for glibc, clock_gettime is in librt.  But don't pull that
 288 # in if it still doesn't give us the function we want.
 289 if test $ac_cv_func_clock_gettime = no; then
 290   AC_CHECK_LIB(rt, clock_gettime,
 291     [LIBS="-lrt $LIBS"
 292      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 293                [Define to 1 if you have the `clock_gettime' function.])])
 294 fi
 295
 296 # Check for uname.
 297 AC_COMPILE_IFELSE(
 298  [AC_LANG_PROGRAM(
 299   [#include <string.h>
 300    #include <stdlib.h>
 301    #include <sys/utsname.h>],
 302   [struct utsname buf;
 303    volatile size_t len = 0;
 304    if (!uname (buf))
 305      len = strlen (buf.nodename);])],
 306   AC_DEFINE(HAVE_UNAME, 1,
 307 [       Define if uname is supported and struct utsname has nodename field.]))
 308
 309 # Check for gethostname.
 310 AC_COMPILE_IFELSE(
 311  [AC_LANG_PROGRAM(
 312   [#include <unistd.h>],
 313   [
 314 changequote(,)dnl
 315    char buf[256];
 316    if (gethostname (buf, sizeof (buf) - 1) == 0)
 317      buf[255] = '\0';
 318 changequote([,])dnl
 319   ])],
 320   AC_DEFINE(HAVE_GETHOSTNAME, 1,
 321 [       Define if gethostname is supported.]))
 322
 323 # Check for getpid.
 324 AC_COMPILE_IFELSE(
 325  [AC_LANG_PROGRAM(
 326   [#include <unistd.h>],
 327   [int pid = getpid ();])],
 328   AC_DEFINE(HAVE_GETPID, 1,
 329 [       Define if getpid is supported.]))
 330
 331 # See if we support thread-local storage.
 332 GCC_CHECK_TLS
 333
 334 # See if we have emulated thread-local storage.
 335 GCC_CHECK_EMUTLS
 336
 337 # See what sort of export controls are available.
 338 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 339 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 340 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 341 LIBGOMP_ENABLE_SYMVERS
 342
 343 if test $enable_symvers = gnu; then
 344   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 345             [Define to 1 if GNU symbol versioning is used for libgomp.])
 346 fi
 347
 348 # Determine cpu count to limit testsuite parallelism.
 349 AX_COUNT_CPUS
 350 AC_SUBST(CPU_COUNT)
 351
 352 AC_MSG_NOTICE([checking for flock implementation])
 353 AC_CHECK_PROGS(FLOCK, flock)
 354 # Fallback if 'perl' is available.
 355 if test -z "$FLOCK"; then
 356   AC_CHECK_PROG(FLOCK, perl, $srcdir/testsuite/flock)
 357 fi
 358
 359 # Get target configury.
 360 . ${srcdir}/configure.tgt
 361 CFLAGS="$save_CFLAGS $XCFLAGS"
 362
 363 # Check for __sync_val_compare_and_swap, but only after the target has
 364 # had a chance to set XCFLAGS.
 365 LIBGOMP_CHECK_SYNC_BUILTINS
 366
 367 XCFLAGS="$XCFLAGS$XPCFLAGS"
 368
 369 # Add CET specific flags if CET is enabled
 370 GCC_CET_FLAGS(CET_FLAGS)
 371 XCFLAGS="$XCFLAGS $CET_FLAGS"
 372 FCFLAGS="$FCFLAGS $CET_FLAGS"
 373
 374 AC_SUBST(config_path)
 375 AC_SUBST(XCFLAGS)
 376 AC_SUBST(XLDFLAGS)
 377
 378 # Conditionalize the makefile for this target machine.
 379 tmake_file_=
 380 for f in ${tmake_file}
 381 do
 382         if test -f ${srcdir}/config/$f
 383         then
 384                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 385         fi
 386 done
 387 tmake_file="${tmake_file_}"
 388 AC_SUBST(tmake_file)
 389
 390 # Cleanup and exit.
 391 CFLAGS="$save_CFLAGS"
 392 AC_CACHE_SAVE
 393
 394 if test ${multilib} = yes; then
 395   multilib_arg="--enable-multilib"
 396 else
 397   multilib_arg=
 398 fi
 399
 400 # Set up the set of libraries that we need to link against for libgomp.
 401 # Note that the GOMP_SELF_SPEC in gcc.c may force -pthread,
 402 # which will force linkage against -lpthread (or equivalent for the system).
 403 # That's not 100% ideal, but about the best we can do easily.
 404 if test $enable_shared = yes; then
 405   link_gomp="-lgomp %{static: $LIBS${DL_LIBS:+ $DL_LIBS}}"
 406 else
 407   link_gomp="-lgomp $LIBS${DL_LIBS:+ $DL_LIBS}"
 408 fi
 409 AC_SUBST(link_gomp)
 410
 411 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 412
 413 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 414 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 415 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 416 # need to copy this macro to our acinclude.m4.
 417 save_CFLAGS="$CFLAGS"
 418 for i in $config_path; do
 419   if test -f $srcdir/config/$i/omp-lock.h; then
 420     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 421     break
 422   fi
 423 done
 424
 425 _AC_COMPUTE_INT([sizeof (__INTPTR_TYPE__)], [INTPTR_T_KIND])
 426 _AC_COMPUTE_INT([sizeof (__int128)], [OMP_INT128_SIZE],,[OMP_INT128_SIZE=0])
 427 _AC_COMPUTE_INT([2*sizeof (__INTPTR_TYPE__)], [OMP_DEPEND_KIND],,
 428                 [OMP_DEPEND_KIND=0])
 429 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 430   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 431 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 432 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 433 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 434 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 435   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 436 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 437 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 438 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 439
 440 # If the lock fits in an integer, then arrange for Fortran to use that
 441 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 442 # Except that we don't have a way at present to multi-lib the installed
 443 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 444 # actual target.
 445 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 446 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 447 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 448   OMP_LOCK_KIND=8
 449 fi
 450 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 451   OMP_NEST_LOCK_KIND=8
 452 fi
 453 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 454 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 455 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 456   OMP_LOCK_25_KIND=8
 457 fi
 458 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 459   OMP_NEST_LOCK_25_KIND=8
 460 fi
 461 if test "$ac_cv_fc_compiler_gnu" = yes; then
 462   if test $OMP_DEPEND_KIND -eq 16; then
 463     if test $OMP_INT128_SIZE -ne 16; then
 464       AC_MSG_ERROR([unsupported system, cannot find Fortran int kind=16, needed for omp_depend_kind])
 465     fi
 466   else
 467     if test $OMP_DEPEND_KIND -ne 8; then
 468       AC_MSG_ERROR([unsupported system, cannot find Fortran integer kind for omp_depend_kind])
 469     fi
 470   fi
 471 fi
 472
 473 AC_SUBST(INTPTR_T_KIND)
 474 AC_SUBST(OMP_LOCK_SIZE)
 475 AC_SUBST(OMP_LOCK_ALIGN)
 476 AC_SUBST(OMP_NEST_LOCK_SIZE)
 477 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 478 AC_SUBST(OMP_LOCK_KIND)
 479 AC_SUBST(OMP_NEST_LOCK_KIND)
 480 AC_SUBST(OMP_LOCK_25_SIZE)
 481 AC_SUBST(OMP_LOCK_25_ALIGN)
 482 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 483 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 484 AC_SUBST(OMP_LOCK_25_KIND)
 485 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 486 AC_SUBST(OMP_DEPEND_KIND)
 487 CFLAGS="$save_CFLAGS"
 488
 489 # Determine what GCC version number to use in filesystem paths.
 490 GCC_BASE_VER
 491
 492 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 493 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 494 AC_CONFIG_FILES([testsuite/libgomp-test-support.pt.exp:testsuite/libgomp-test-support.exp.in])
 495 AC_CONFIG_FILES([testsuite/libgomp-site-extra.exp])
 496 AC_OUTPUT