libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT([libffi], [2.1], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AM_ENABLE_MULTILIB(, ..)
   9
  10 AC_CANONICAL_SYSTEM
  11 target_alias=${target_alias-$host_alias}
  12
  13 . ${srcdir}/configure.host
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 AC_PROG_CC
  25 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  26
  27 AC_SUBST(CFLAGS)
  28
  29 AM_PROG_AS
  30 AM_PROG_CC_C_O
  31 AC_PROG_LIBTOOL
  32
  33 AM_MAINTAINER_MODE
  34
  35 AC_CHECK_HEADERS(sys/mman.h)
  36 AC_CHECK_FUNCS(mmap)
  37 AC_FUNC_MMAP_BLACKLIST
  38
  39 dnl The -no-testsuite modules omit the test subdir.
  40 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  41
  42 TARGETDIR="unknown"
  43 case "$host" in
  44 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
  45 i*86-*-gnu*) TARGET=X86; TARGETDIR=x86;;
  46 i*86-*-solaris2.1[[0-9]]*) TARGET=X86_64; TARGETDIR=x86;;
  47 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
  48 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
  49 i*86-*-freebsd* | i*86-*-kfreebsd*-gnu) TARGET=X86; TARGETDIR=x86;;
  50 i*86-*-netbsdelf* | i*86-*-knetbsd*-gnu) TARGET=X86; TARGETDIR=x86;;
  51 i*86-*-rtems*) TARGET=X86; TARGETDIR=x86;;
  52 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
  53 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
  54 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
  55 frv-*-*) TARGET=FRV; TARGETDIR=frv;;
  56 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
  57 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
  58 sparc-*-linux* | sparc-*-netbsdelf* | sparc-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
  59 sparc*-*-rtems*) TARGET=SPARC; TARGETDIR=sparc;;
  60 sparc64-*-linux* | sparc64-*-freebsd* | sparc64-*-netbsd* | sparc64-*-knetbsd*-gnu) TARGET=SPARC; TARGETDIR=sparc;;
  61 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu | alpha*-*-netbsd* | alpha*-*-knetbsd*-gnu) TARGET=ALPHA; TARGETDIR=alpha;;
  62 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
  63 m32r*-*-linux* ) TARGET=M32R; TARGETDIR=m32r;;
  64 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
  65 mips64*-*);;
  66 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS_IRIX; TARGETDIR=mips;;
  67 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
  68 powerpc*-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
  69 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
  70 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
  71 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  72 powerpc-*-freebsd*) TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc;;
  73 powerpc*-*-rtems*) TARGET=POWERPC; TARGETDIR=powerpc;;
  74 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  75 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
  76 arm*-*-netbsdelf* | arm*-*-knetbsd*-gnu) TARGET=ARM; TARGETDIR=arm;;
  77 arm*-*-rtems*) TARGET=ARM; TARGETDIR=arm;;
  78 cris-*-*) TARGET=LIBFFI_CRIS; TARGETDIR=cris;;
  79 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  80 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  81 x86_64-*-linux* | x86_64-*-freebsd* | x86_64-*-kfreebsd*-gnu) TARGET=X86_64; TARGETDIR=x86;;
  82 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
  83 sh-*-rtems*) TARGET=SH; TARGETDIR=sh;;
  84 sh64-*-linux* | sh5*-*-linux*) TARGET=SH64; TARGETDIR=sh64;;
  85 hppa*-*-linux* | parisc*-*-linux*) TARGET=PA_LINUX; TARGETDIR=pa;;
  86 hppa*64-*-hpux*) TARGET=PA64_HPUX; TARGETDIR=pa;;
  87 hppa*-*-hpux*) TARGET=PA_HPUX; TARGETDIR=pa;;
  88 esac
  89
  90 AC_SUBST(AM_RUNTESTFLAGS)
  91
  92 if test $TARGETDIR = unknown; then
  93   AC_MSG_ERROR(["libffi has not been ported to $host."])
  94 fi
  95
  96 AM_CONDITIONAL(MIPS_IRIX, test x$TARGET = xMIPS_IRIX)
  97 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
  98 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
  99 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 100 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 101 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 102 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 103 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 104 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 105 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 106 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 107 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 108 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 109 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 110 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 111 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 112 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 113 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 114 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 115 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 116 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 117 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 118 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 119
 120 case x$TARGET in
 121   xMIPS*) TARGET=MIPS ;;
 122   *) ;;
 123 esac
 124
 125 AC_HEADER_STDC
 126 AC_CHECK_FUNCS(memcpy)
 127 AC_FUNC_ALLOCA
 128
 129 AC_CHECK_SIZEOF(double)
 130 AC_CHECK_SIZEOF(long double)
 131
 132 # Also AC_SUBST this variable for ffi.h.
 133 HAVE_LONG_DOUBLE=0
 134 if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 135   if test $ac_cv_sizeof_long_double != 0; then
 136     HAVE_LONG_DOUBLE=1
 137     AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 138   fi
 139 fi
 140 AC_SUBST(HAVE_LONG_DOUBLE)
 141
 142 AC_C_BIGENDIAN
 143
 144 if test x$TARGET = xSPARC; then
 145     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 146         libffi_cv_as_sparc_ua_pcrel, [
 147         save_CFLAGS="$CFLAGS"
 148         save_LDFLAGS="$LDFLAGS"
 149         CFLAGS="$CFLAGS -fpic"
 150         LDFLAGS="$LDFLAGS -shared"
 151         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 152                     [libffi_cv_as_sparc_ua_pcrel=yes],
 153                     [libffi_cv_as_sparc_ua_pcrel=no])
 154         CFLAGS="$save_CFLAGS"
 155         LDFLAGS="$save_LDFLAGS"])
 156     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 157         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 158                   [Define if your assembler and linker support unaligned PC relative relocs.])
 159     fi
 160
 161     AC_CACHE_CHECK([assembler .register pseudo-op support],
 162        libffi_cv_as_register_pseudo_op, [
 163        libffi_cv_as_register_pseudo_op=unknown
 164        # Check if we have .register
 165        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 166                        [libffi_cv_as_register_pseudo_op=yes],
 167                        [libffi_cv_as_register_pseudo_op=no])
 168     ])
 169     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 170        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 171                [Define if your assembler supports .register.])
 172     fi
 173 fi
 174
 175 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 176     libffi_cv_ro_eh_frame, [
 177         libffi_cv_ro_eh_frame=no
 178         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 179         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 180             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 181                 libffi_cv_ro_eh_frame=yes
 182             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 183                  | grep -v '#write' > /dev/null; then
 184                 libffi_cv_ro_eh_frame=yes
 185             fi
 186         fi
 187         rm -f conftest.*
 188     ])
 189 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 190     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 191               [Define if .eh_frame sections should be read-only.])
 192     AC_DEFINE(EH_FRAME_FLAGS, "a",
 193               [Define to the flags needed for the .section .eh_frame directive.])
 194 else
 195     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 196               [Define to the flags needed for the .section .eh_frame directive.])
 197 fi
 198
 199 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 200     libffi_cv_hidden_visibility_attribute, [
 201         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 202         libffi_cv_hidden_visibility_attribute=no
 203         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 204             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 205                 libffi_cv_hidden_visibility_attribute=yes
 206             fi
 207         fi
 208         rm -f conftest.*
 209     ])
 210 if test $libffi_cv_hidden_visibility_attribute = yes; then
 211     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 212               [Define if __attribute__((visibility("hidden"))) is supported.])
 213 fi
 214
 215 AH_BOTTOM([
 216 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 217 #ifdef LIBFFI_ASM
 218 #define FFI_HIDDEN(name) .hidden name
 219 #else
 220 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 221 #endif
 222 #else
 223 #ifdef LIBFFI_ASM
 224 #define FFI_HIDDEN(name)
 225 #else
 226 #define FFI_HIDDEN
 227 #endif
 228 #endif
 229 ])
 230
 231 AC_SUBST(TARGET)
 232 AC_SUBST(TARGETDIR)
 233
 234 AC_SUBST(SHELL)
 235
 236 AC_ARG_ENABLE(debug,
 237 [  --enable-debug          debugging mode],
 238   if test "$enable_debug" = "yes"; then
 239     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 240   fi)
 241
 242 AC_ARG_ENABLE(structs,
 243 [  --disable-structs       omit code for struct support],
 244   if test "$enable_structs" = "no"; then
 245     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 246   fi)
 247
 248 AC_ARG_ENABLE(raw-api,
 249 [  --disable-raw-api       make the raw api unavailable],
 250   if test "$enable_raw_api" = "no"; then
 251     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 252   fi)
 253
 254 AC_ARG_ENABLE(purify-safety,
 255 [  --enable-purify-safety  purify-safe mode],
 256   if test "$enable_purify_safety" = "yes"; then
 257     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 258   fi)
 259
 260 if test -n "$with_cross_host" &&
 261    test x"$with_cross_host" != x"no"; then
 262   toolexecdir='$(exec_prefix)/$(target_alias)'
 263   toolexeclibdir='$(toolexecdir)/lib'
 264 else
 265   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 266   toolexeclibdir='$(libdir)'
 267 fi
 268 multi_os_directory=`$CC -print-multi-os-directory`
 269 case $multi_os_directory in
 270   .) ;; # Avoid trailing /.
 271   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 272 esac
 273 AC_SUBST(toolexecdir)
 274 AC_SUBST(toolexeclibdir)
 275
 276 if test "${multilib}" = "yes"; then
 277   multilib_arg="--enable-multilib"
 278 else
 279   multilib_arg=
 280 fi
 281
 282 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 283 AC_CONFIG_COMMANDS(src, [
 284 test -d src || mkdir src
 285 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 286 ], [TARGETDIR="$TARGETDIR"])
 287
 288 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 289
 290 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile)
 291
 292 AC_OUTPUT