contrib/texi2pod.pl

   1 #! /usr/bin/perl -w
   2
   3 #   Copyright (C) 1999, 2000, 2001, 2003 Free Software Foundation, Inc.
   4
   5 # This file is part of GCC.
   6
   7 # GCC is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11
  12 # GCC is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with GCC; see the file COPYING.  If not, write to
  19 # the Free Software Foundation, 51 Franklin Street, Fifth Floor,
  20 # Boston MA 02110-1301, USA.
  21
  22 # This does trivial (and I mean _trivial_) conversion of Texinfo
  23 # markup to Perl POD format.  It's intended to be used to extract
  24 # something suitable for a manpage from a Texinfo document.
  25
  26 $output = 0;
  27 $skipping = 0;
  28 %sects = ();
  29 $section = "";
  30 @icstack = ();
  31 @endwstack = ();
  32 @skstack = ();
  33 @instack = ();
  34 $shift = "";
  35 %defs = ();
  36 $fnno = 1;
  37 $inf = "";
  38 $ibase = "";
  39 @ipath = ();
  40
  41 while ($_ = shift) {
  42     if (/^-D(.*)$/) {
  43         if ($1 ne "") {
  44             $flag = $1;
  45         } else {
  46             $flag = shift;
  47         }
  48         $value = "";
  49         ($flag, $value) = ($flag =~ /^([^=]+)(?:=(.+))?/);
  50         die "no flag specified for -D\n"
  51             unless $flag ne "";
  52         die "flags may only contain letters, digits, hyphens, dashes and underscores\n"
  53             unless $flag =~ /^[a-zA-Z0-9_-]+$/;
  54         $defs{$flag} = $value;
  55     } elsif (/^-I(.*)$/) {
  56         if ($1 ne "") {
  57             $flag = $1;
  58         } else {
  59             $flag = shift;
  60         }
  61         push (@ipath, $flag);
  62     } elsif (/^-/) {
  63         usage();
  64     } else {
  65         $in = $_, next unless defined $in;
  66         $out = $_, next unless defined $out;
  67         usage();
  68     }
  69 }
  70
  71 if (defined $in) {
  72     $inf = gensym();
  73     open($inf, "<$in") or die "opening \"$in\": $!\n";
  74     $ibase = $1 if $in =~ m|^(.+)/[^/]+$|;
  75 } else {
  76     $inf = \*STDIN;
  77 }
  78
  79 if (defined $out) {
  80     open(STDOUT, ">$out") or die "opening \"$out\": $!\n";
  81 }
  82
  83 while(defined $inf) {
  84 while(<$inf>) {
  85     # Certain commands are discarded without further processing.
  86     /^\@(?:
  87          [a-z]+index            # @*index: useful only in complete manual
  88          |need                  # @need: useful only in printed manual
  89          |(?:end\s+)?group      # @group .. @end group: ditto
  90          |page                  # @page: ditto
  91          |node                  # @node: useful only in .info file
  92          |(?:end\s+)?ifnottex   # @ifnottex .. @end ifnottex: use contents
  93         )\b/x and next;
  94
  95     chomp;
  96
  97     # Look for filename and title markers.
  98     /^\@setfilename\s+([^.]+)/ and $fn = $1, next;
  99     /^\@settitle\s+([^.]+)/ and $tl = postprocess($1), next;
 100
 101     # Identify a man title but keep only the one we are interested in.
 102     /^\@c\s+man\s+title\s+([A-Za-z0-9-]+)\s+(.+)/ and do {
 103         if (exists $defs{$1}) {
 104             $fn = $1;
 105             $tl = postprocess($2);
 106         }
 107         next;
 108     };
 109
 110     # Look for blocks surrounded by @c man begin SECTION ... @c man end.
 111     # This really oughta be @ifman ... @end ifman and the like, but such
 112     # would require rev'ing all other Texinfo translators.
 113     /^\@c\s+man\s+begin\s+([A-Z]+)\s+([A-Za-z0-9-]+)/ and do {
 114         $output = 1 if exists $defs{$2};
 115         $sect = $1;
 116         next;
 117     };
 118     /^\@c\s+man\s+begin\s+([A-Z]+)/ and $sect = $1, $output = 1, next;
 119     /^\@c\s+man\s+end/ and do {
 120         $sects{$sect} = "" unless exists $sects{$sect};
 121         $sects{$sect} .= postprocess($section);
 122         $section = "";
 123         $output = 0;
 124         next;
 125     };
 126
 127     # handle variables
 128     /^\@set\s+([a-zA-Z0-9_-]+)\s*(.*)$/ and do {
 129         $defs{$1} = $2;
 130         next;
 131     };
 132     /^\@clear\s+([a-zA-Z0-9_-]+)/ and do {
 133         delete $defs{$1};
 134         next;
 135     };
 136
 137     next unless $output;
 138
 139     # Discard comments.  (Can't do it above, because then we'd never see
 140     # @c man lines.)
 141     /^\@c\b/ and next;
 142
 143     # End-block handler goes up here because it needs to operate even
 144     # if we are skipping.
 145     /^\@end\s+([a-z]+)/ and do {
 146         # Ignore @end foo, where foo is not an operation which may
 147         # cause us to skip, if we are presently skipping.
 148         my $ended = $1;
 149         next if $skipping && $ended !~ /^(?:ifset|ifclear|ignore|menu|iftex|copying)$/;
 150
 151         die "\@end $ended without \@$ended at line $.\n" unless defined $endw;
 152         die "\@$endw ended by \@end $ended at line $.\n" unless $ended eq $endw;
 153
 154         $endw = pop @endwstack;
 155
 156         if ($ended =~ /^(?:ifset|ifclear|ignore|menu|iftex)$/) {
 157             $skipping = pop @skstack;
 158             next;
 159         } elsif ($ended =~ /^(?:example|smallexample|display)$/) {
 160             $shift = "";
 161             $_ = "";    # need a paragraph break
 162         } elsif ($ended =~ /^(?:itemize|enumerate|[fv]?table)$/) {
 163             $_ = "\n=back\n";
 164             $ic = pop @icstack;
 165         } else {
 166             die "unknown command \@end $ended at line $.\n";
 167         }
 168     };
 169
 170     # We must handle commands which can cause skipping even while we
 171     # are skipping, otherwise we will not process nested conditionals
 172     # correctly.
 173     /^\@ifset\s+([a-zA-Z0-9_-]+)/ and do {
 174         push @endwstack, $endw;
 175         push @skstack, $skipping;
 176         $endw = "ifset";
 177         $skipping = 1 unless exists $defs{$1};
 178         next;
 179     };
 180
 181     /^\@ifclear\s+([a-zA-Z0-9_-]+)/ and do {
 182         push @endwstack, $endw;
 183         push @skstack, $skipping;
 184         $endw = "ifclear";
 185         $skipping = 1 if exists $defs{$1};
 186         next;
 187     };
 188
 189     /^\@(ignore|menu|iftex|copying)\b/ and do {
 190         push @endwstack, $endw;
 191         push @skstack, $skipping;
 192         $endw = $1;
 193         $skipping = 1;
 194         next;
 195     };
 196
 197     next if $skipping;
 198
 199     # Character entities.  First the ones that can be replaced by raw text
 200     # or discarded outright:
 201     s/\@copyright\{\}/(c)/g;
 202     s/\@dots\{\}/.../g;
 203     s/\@enddots\{\}/..../g;
 204     s/\@([.!? ])/$1/g;
 205     s/\@[:-]//g;
 206     s/\@bullet(?:\{\})?/*/g;
 207     s/\@TeX\{\}/TeX/g;
 208     s/\@pounds\{\}/\#/g;
 209     s/\@minus(?:\{\})?/-/g;
 210     s/\\,/,/g;
 211
 212     # Now the ones that have to be replaced by special escapes
 213     # (which will be turned back into text by unmunge())
 214     s/&/&amp;/g;
 215     s/\@\{/&lbrace;/g;
 216     s/\@\}/&rbrace;/g;
 217     s/\@\@/&at;/g;
 218
 219     # Inside a verbatim block, handle @var specially.
 220     if ($shift ne "") {
 221         s/\@var\{([^\}]*)\}/<$1>/g;
 222     }
 223
 224     # POD doesn't interpret E<> inside a verbatim block.
 225     if ($shift eq "") {
 226         s/</&lt;/g;
 227         s/>/&gt;/g;
 228     } else {
 229         s/</&LT;/g;
 230         s/>/&GT;/g;
 231     }
 232
 233     # Single line command handlers.
 234
 235     /^\@include\s+(.+)$/ and do {
 236         push @instack, $inf;
 237         $inf = gensym();
 238         $file = postprocess($1);
 239
 240         # Try cwd and $ibase, then explicit -I paths.
 241         $done = 0;
 242         foreach $path ("", $ibase, @ipath) {
 243             $mypath = $file;
 244             $mypath = $path . "/" . $mypath if ($path ne "");
 245             open($inf, "<" . $mypath) and ($done = 1, last);
 246         }
 247         die "cannot find $file" if !$done;
 248         next;
 249     };
 250
 251     /^\@(?:section|unnumbered|unnumberedsec|center)\s+(.+)$/
 252         and $_ = "\n=head2 $1\n";
 253     /^\@subsection\s+(.+)$/
 254         and $_ = "\n=head3 $1\n";
 255
 256     # Block command handlers:
 257     /^\@itemize(?:\s+(\@[a-z]+|\*|-))?/ and do {
 258         push @endwstack, $endw;
 259         push @icstack, $ic;
 260         if (defined $1) {
 261             $ic = $1;
 262         } else {
 263             $ic = '@bullet';
 264         }
 265         $_ = "\n=over 4\n";
 266         $endw = "itemize";
 267     };
 268
 269     /^\@enumerate(?:\s+([a-zA-Z0-9]+))?/ and do {
 270         push @endwstack, $endw;
 271         push @icstack, $ic;
 272         if (defined $1) {
 273             $ic = $1 . ".";
 274         } else {
 275             $ic = "1.";
 276         }
 277         $_ = "\n=over 4\n";
 278         $endw = "enumerate";
 279     };
 280
 281     /^\@([fv]?table)\s+(\@[a-z]+)/ and do {
 282         push @endwstack, $endw;
 283         push @icstack, $ic;
 284         $endw = $1;
 285         $ic = $2;
 286         $ic =~ s/\@(?:samp|strong|key|gcctabopt|env)/B/;
 287         $ic =~ s/\@(?:code|kbd)/C/;
 288         $ic =~ s/\@(?:dfn|var|emph|cite|i)/I/;
 289         $ic =~ s/\@(?:file)/F/;
 290         $_ = "\n=over 4\n";
 291     };
 292
 293     /^\@((?:small)?example|display)/ and do {
 294         push @endwstack, $endw;
 295         $endw = $1;
 296         $shift = "\t";
 297         $_ = "";        # need a paragraph break
 298     };
 299
 300     /^\@itemx?\s*(.+)?$/ and do {
 301         if (defined $1) {
 302             # Entity escapes prevent munging by the <> processing below.
 303             $_ = "\n=item $ic\&LT;$1\&GT;\n";
 304         } else {
 305             $_ = "\n=item $ic\n";
 306             $ic =~ y/A-Ya-y/B-Zb-z/;
 307             $ic =~ s/(\d+)/$1 + 1/eg;
 308         }
 309     };
 310
 311     $section .= $shift.$_."\n";
 312 }
 313 # End of current file.
 314 close($inf);
 315 $inf = pop @instack;
 316 }
 317
 318 die "No filename or title\n" unless defined $fn && defined $tl;
 319
 320 $sects{NAME} = "$fn \- $tl\n";
 321 $sects{FOOTNOTES} .= "=back\n" if exists $sects{FOOTNOTES};
 322
 323 for $sect (qw(NAME SYNOPSIS DESCRIPTION OPTIONS ENVIRONMENT FILES
 324               BUGS NOTES FOOTNOTES SEEALSO AUTHOR COPYRIGHT)) {
 325     if(exists $sects{$sect}) {
 326         $head = $sect;
 327         $head =~ s/SEEALSO/SEE ALSO/;
 328         print "=head1 $head\n\n";
 329         print scalar unmunge ($sects{$sect});
 330         print "\n";
 331     }
 332 }
 333
 334 sub usage
 335 {
 336     die "usage: $0 [-D toggle...] [infile [outfile]]\n";
 337 }
 338
 339 sub postprocess
 340 {
 341     local $_ = $_[0];
 342
 343     # @value{foo} is replaced by whatever 'foo' is defined as.
 344     while (m/(\@value\{([a-zA-Z0-9_-]+)\})/g) {
 345         if (! exists $defs{$2}) {
 346             print STDERR "Option $2 not defined\n";
 347             s/\Q$1\E//;
 348         } else {
 349             $value = $defs{$2};
 350             s/\Q$1\E/$value/;
 351         }
 352     }
 353
 354     # Formatting commands.
 355     # Temporary escape for @r.
 356     s/\@r\{([^\}]*)\}/R<$1>/g;
 357     s/\@(?:dfn|var|emph|cite|i)\{([^\}]*)\}/I<$1>/g;
 358     s/\@(?:code|kbd)\{([^\}]*)\}/C<$1>/g;
 359     s/\@(?:gccoptlist|samp|strong|key|option|env|command|b)\{([^\}]*)\}/B<$1>/g;
 360     s/\@sc\{([^\}]*)\}/\U$1/g;
 361     s/\@file\{([^\}]*)\}/F<$1>/g;
 362     s/\@w\{([^\}]*)\}/S<$1>/g;
 363     s/\@(?:dmn|math)\{([^\}]*)\}/$1/g;
 364
 365     # keep references of the form @ref{...}, print them bold
 366     s/\@(?:ref)\{([^\}]*)\}/B<$1>/g;
 367
 368     # Change double single quotes to double quotes.
 369     s/''/"/g;
 370     s/``/"/g;
 371
 372     # Cross references are thrown away, as are @noindent and @refill.
 373     # (@noindent is impossible in .pod, and @refill is unnecessary.)
 374     # @* is also impossible in .pod; we discard it and any newline that
 375     # follows it.  Similarly, our macro @gol must be discarded.
 376
 377     s/\(?\@xref\{(?:[^\}]*)\}(?:[^.<]|(?:<[^<>]*>))*\.\)?//g;
 378     s/\s+\(\@pxref\{(?:[^\}]*)\}\)//g;
 379     s/;\s+\@pxref\{(?:[^\}]*)\}//g;
 380     s/\@noindent\s*//g;
 381     s/\@refill//g;
 382     s/\@gol//g;
 383     s/\@\*\s*\n?//g;
 384
 385     # @uref can take one, two, or three arguments, with different
 386     # semantics each time.  @url and @email are just like @uref with
 387     # one argument, for our purposes.
 388     s/\@(?:uref|url|email)\{([^\},]*)\}/&lt;B<$1>&gt;/g;
 389     s/\@uref\{([^\},]*),([^\},]*)\}/$2 (C<$1>)/g;
 390     s/\@uref\{([^\},]*),([^\},]*),([^\},]*)\}/$3/g;
 391
 392     # Un-escape <> at this point.
 393     s/&LT;/</g;
 394     s/&GT;/>/g;
 395
 396     # Now un-nest all B<>, I<>, R<>.  Theoretically we could have
 397     # indefinitely deep nesting; in practice, one level suffices.
 398     1 while s/([BIR])<([^<>]*)([BIR])<([^<>]*)>/$1<$2>$3<$4>$1</g;
 399
 400     # Replace R<...> with bare ...; eliminate empty markup, B<>;
 401     # shift white space at the ends of [BI]<...> expressions outside
 402     # the expression.
 403     s/R<([^<>]*)>/$1/g;
 404     s/[BI]<>//g;
 405     s/([BI])<(\s+)([^>]+)>/$2$1<$3>/g;
 406     s/([BI])<([^>]+?)(\s+)>/$1<$2>$3/g;
 407
 408     # Extract footnotes.  This has to be done after all other
 409     # processing because otherwise the regexp will choke on formatting
 410     # inside @footnote.
 411     while (/\@footnote/g) {
 412         s/\@footnote\{([^\}]+)\}/[$fnno]/;
 413         add_footnote($1, $fnno);
 414         $fnno++;
 415     }
 416
 417     return $_;
 418 }
 419
 420 sub unmunge
 421 {
 422     # Replace escaped symbols with their equivalents.
 423     local $_ = $_[0];
 424
 425     s/&lt;/E<lt>/g;
 426     s/&gt;/E<gt>/g;
 427     s/&lbrace;/\{/g;
 428     s/&rbrace;/\}/g;
 429     s/&at;/\@/g;
 430     s/&amp;/&/g;
 431     return $_;
 432 }
 433
 434 sub add_footnote
 435 {
 436     unless (exists $sects{FOOTNOTES}) {
 437         $sects{FOOTNOTES} = "\n=over 4\n\n";
 438     }
 439
 440     $sects{FOOTNOTES} .= "=item $fnno.\n\n"; $fnno++;
 441     $sects{FOOTNOTES} .= $_[0];
 442     $sects{FOOTNOTES} .= "\n\n";
 443 }
 444
 445 # stolen from Symbol.pm
 446 {
 447     my $genseq = 0;
 448     sub gensym
 449     {
 450         my $name = "GEN" . $genseq++;
 451         my $ref = \*{$name};
 452         delete $::{$name};
 453         return $ref;
 454     }
 455 }