boehm-gc/configure.in

   1 # Copyright (c) 1999-2001 by Red Hat, Inc. All rights reserved.
   2 #
   3 # THIS MATERIAL IS PROVIDED AS IS, WITH ABSOLUTELY NO WARRANTY EXPRESSED
   4 # OR IMPLIED.  ANY USE IS AT YOUR OWN RISK.
   5 #
   6 # Permission is hereby granted to use or copy this program
   7 # for any purpose,  provided the above notices are retained on all copies.
   8 # Permission to modify the code and to distribute modified code is granted,
   9 # provided the above notices are retained, and a notice that the code was
  10 # modified is included with the above copyright notice.
  11 #
  12 # Original author: Tom Tromey
  13
  14 dnl Process this file with autoconf to produce configure.
  15
  16 AC_INIT(gcj_mlc.c)
  17
  18 dnl Can't be done in GC_CONFIGURE because that confuses automake.
  19 AC_CONFIG_AUX_DIR(.)
  20
  21 GC_CONFIGURE(.)
  22
  23 AM_PROG_LIBTOOL
  24
  25 dnl We use these options to decide which functions to include.
  26 AC_ARG_WITH(target-subdir,
  27 [  --with-target-subdir=SUBDIR
  28                           configuring with a cross compiler])
  29 AC_ARG_WITH(cross-host,
  30 [  --with-cross-host=HOST  configuring with a cross compiler])
  31
  32 AM_MAINTAINER_MODE
  33 # automake wants to see AC_EXEEXT.  But we don't need it.  And having
  34 # it is actually a problem, because the compiler we're passed can't
  35 # necessarily do a full link.  So we fool automake here.
  36 if false; then
  37   # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
  38   # to nothing, so nothing would remain between `then' and `fi' if it
  39   # were not for the `:' below.
  40   :
  41   AC_EXEEXT
  42 fi
  43
  44 AC_MSG_CHECKING([for thread model used by GCC])
  45 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
  46 if test -z "$THREADS"; then
  47    THREADS=no
  48 fi
  49 AC_MSG_RESULT([$THREADS])
  50
  51 AC_ARG_ENABLE(parallel-mark,
  52 [  --enable-parallel-mark       parallelize marking and free list construction],
  53    [case "$THREADS" in
  54       no | none | single)
  55         AC_MSG_ERROR([Parallel mark requires --enable-threads=x spec])
  56         ;;
  57     esac]
  58 )
  59
  60 INCLUDES=-I${srcdir}/include
  61 THREADLIBS=
  62 case "$THREADS" in
  63  no | none | single)
  64     THREADS=none
  65     ;;
  66  posix | pthreads)
  67     THREADS=posix
  68     THREADLIBS=-lpthread
  69     case "$host" in
  70      x86-*-linux* | ia64-*-linux* | i586-*-linux* | i686-*-linux*)
  71         AC_DEFINE(GC_LINUX_THREADS)
  72         AC_DEFINE(_REENTRANT)
  73         if test "${enable_parallel_mark}"; then
  74           AC_DEFINE(PARALLEL_MARK)
  75         fi
  76         AC_DEFINE(THREAD_LOCAL_ALLOC)
  77         ;;
  78      *-*-linux*)
  79         AC_DEFINE(GC_LINUX_THREADS)
  80         AC_DEFINE(_REENTRANT)
  81         ;;
  82      *-*-hpux*)
  83         AC_MSG_WARN("Only HP/UX 11 threads are supported.")
  84         AC_DEFINE(GC_HPUX_THREADS)
  85         AC_DEFINE(_POSIX_C_SOURCE,199506L)
  86         if test "${enable_parallel_mark}" = yes; then
  87           AC_DEFINE(PARALLEL_MARK)
  88         fi
  89         AC_DEFINE(THREAD_LOCAL_ALLOC)
  90         THREADLIBS="-lpthread -lrt"
  91         ;;
  92      *-*-freebsd*)
  93         AC_MSG_WARN("Threaded GC is prone to deadlock before FreeBSD 4.5.")
  94         AC_MSG_WARN("Related symptom is pthread_join returns spurious EINTR.")
  95         AC_DEFINE(GC_FREEBSD_THREADS)
  96         INCLUDES="$INCLUDES -pthread"
  97         THREADLIBS=-pthread
  98         ;;
  99      *-*-solaris*)
 100         AC_DEFINE(GC_SOLARIS_THREADS)
 101         AC_DEFINE(GC_SOLARIS_PTHREADS)
 102         ;;
 103      *-*-irix*)
 104         AC_DEFINE(GC_IRIX_THREADS)
 105         ;;
 106      *-*-cygwin*)
 107         THREADLIBS=
 108         ;;
 109     esac
 110     ;;
 111  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 112     AC_MSG_ERROR(thread package $THREADS not yet supported)
 113     ;;
 114  *)
 115     AC_MSG_ERROR($THREADS is an unknown thread package)
 116     ;;
 117 esac
 118 AC_SUBST(THREADLIBS)
 119
 120 AC_CHECK_LIB(dl, dlopen, EXTRA_TEST_LIBS="$EXTRA_TEST_LIBS -ldl")
 121 AC_SUBST(EXTRA_TEST_LIBS)
 122
 123 target_all=libgcjgc.la
 124 AC_SUBST(target_all)
 125
 126 dnl If the target is an eCos system, use the appropriate eCos
 127 dnl I/O routines.
 128 dnl FIXME: this should not be a local option but a global target
 129 dnl system; at present there is no eCos target.
 130 TARGET_ECOS="no"
 131 AC_ARG_WITH(ecos,
 132 [  --with-ecos             enable runtime eCos target support],
 133 TARGET_ECOS="$with_ecos"
 134 )
 135
 136 addobjs=
 137 CXXINCLUDES=
 138 case "$TARGET_ECOS" in
 139    no)
 140       ;;
 141    *)
 142       AC_DEFINE(ECOS)
 143       CXXINCLUDES="-I${TARGET_ECOS}/include"
 144       addobjs="$addobjs ecos.lo"
 145       ;;
 146 esac
 147 AC_SUBST(CXX)
 148
 149 AC_SUBST(INCLUDES)
 150 AC_SUBST(CXXINCLUDES)
 151
 152 machdep=
 153 case "$host" in
 154  alpha*-*-*)
 155     machdep="alpha_mach_dep.lo"
 156     ;;
 157  alpha-*-openbsd*)
 158     if test x"${ac_cv_lib_dl_dlopen}" != xyes ; then
 159        AC_MSG_WARN(OpenBSD/Alpha without dlopen(). Shared library support is disabled)
 160        AM_DISABLE_SHARED
 161     fi
 162     ;;
 163  i?86-*-solaris2.[[89]]*)
 164     AC_DEFINE(SOLARIS25_PROC_VDB_BUG_FIXED)
 165     ;;
 166  mipstx39-*-elf*)
 167     machdep="mips_ultrix_mach_dep.lo"
 168     AC_DEFINE(STACKBASE, __stackbase)
 169     AC_DEFINE(DATASTART_IS_ETEXT)
 170     ;;
 171  mips-dec-ultrix*)
 172     machdep="mips_ultrix_mach-dep.lo"
 173     ;;
 174  mips-*-*)
 175     machdep="mips_sgi_mach_dep.lo"
 176     AC_DEFINE(NO_EXECUTE_PERMISSION)
 177     ;;
 178  sparc-sun-solaris2.3*)
 179     AC_DEFINE(SUNOS53_SHARED_LIB)
 180     ;;
 181  ia64-*-hpux*)
 182     machdep="mach_dep.lo ia64_save_regs_in_stack.lo"
 183     ;;
 184 esac
 185 if test x"$machdep" = x; then
 186    machdep="mach_dep.lo"
 187 fi
 188 addobjs="$addobjs $machdep"
 189 AC_SUBST(addobjs)
 190
 191 dnl As of 4.13a2, the collector will not properly work on Solaris when
 192 dnl built with gcc and -O.  So we remove -O in the appropriate case.
 193 case "$host" in
 194  sparc-sun-solaris2*)
 195     if test "$GCC" = yes; then
 196        new_CFLAGS=
 197        for i in $CFLAGS; do
 198           case "$i" in
 199            -O*)
 200               ;;
 201            *)
 202               new_CFLAGS="$new_CFLAGS $i"
 203               ;;
 204           esac
 205        done
 206        CFLAGS="$new_CFLAGS"
 207     fi
 208     ;;
 209 esac
 210
 211 dnl We need to override the top-level CFLAGS.  This is how we do it.
 212 MY_CFLAGS="$CFLAGS"
 213 AC_SUBST(MY_CFLAGS)
 214
 215 dnl Include defines that have become de facto standard.
 216 dnl ALL_INTERIOR_POINTERS can be overridden in startup code.
 217 AC_DEFINE(SILENT)
 218 AC_DEFINE(NO_SIGNALS)
 219 AC_DEFINE(NO_EXECUTE_PERMISSION)
 220 AC_DEFINE(ALL_INTERIOR_POINTERS)
 221
 222 dnl By default, make the library as general as possible.
 223 AC_DEFINE(JAVA_FINALIZATION)
 224 AC_DEFINE(GC_GCJ_SUPPORT)
 225 AC_DEFINE(ATOMIC_UNCOLLECTABLE)
 226
 227 dnl This is something of a hack.  When cross-compiling we turn off
 228 dnl some functionality.  We also enable the "small" configuration.
 229 dnl These is only correct when targetting an embedded system.  FIXME.
 230 if test -n "${with_cross_host}"; then
 231    AC_DEFINE(NO_SIGSET)
 232    AC_DEFINE(NO_CLOCK)
 233    AC_DEFINE(SMALL_CONFIG)
 234    AC_DEFINE(NO_DEBUGGING)
 235 fi
 236
 237 AC_ARG_ENABLE(full-debug,
 238 [  --enable-full-debug  include full support for pointer backtracing etc.],
 239 [ if test "$enable_full_debug" = "yes"; then
 240     AC_MSG_WARN("Must define GC_DEBUG and use debug alloc. in clients.")
 241     AC_DEFINE(KEEP_BACK_PTRS)
 242     AC_DEFINE(DBG_HDRS_ALL)
 243     case $host in
 244       x86-*-linux* | i586-*-linux* | i686-*-linux* )
 245         AC_MSG_WARN("Client must not use -fomit-frame-pointer.")
 246         AC_DEFINE(SAVE_CALL_COUNT, 8)
 247       ;;
 248     esac ]
 249   fi)
 250
 251 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 252
 253 if test "${multilib}" = "yes"; then
 254   multilib_arg="--enable-multilib"
 255 else
 256   multilib_arg=
 257 fi
 258
 259 AC_OUTPUT(Makefile include/Makefile, [
 260 dnl Put all the -D options in a file.
 261 echo "$DEFS" > boehm-cflags
 262
 263 if test -n "$CONFIG_FILES"; then
 264   ac_file=Makefile . ${gc_basedir}/../config-ml.in
 265 fi],
 266 srcdir=${srcdir}
 267 host=${host}
 268 target=${target}
 269 with_multisubdir=${with_multisubdir}
 270 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 271 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 272 gc_basedir=${gc_basedir}
 273 CC="${CC}"
 274 DEFS="$DEFS"
 275 )