libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_INIT(package-unused, version-unused,, libstdc++)
   4 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  Only used at the end of this file.
  11 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 # Find the rest of the source tree framework.
  14 AM_ENABLE_MULTILIB(, ..)
  15
  16 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  17 #
  18 # You will slowly go insane if you do not grok the following fact:  when
  19 # building v3 as part of the compiler, the top-level /target/ becomes the
  20 # library's /host/.  configure then causes --target to default to --host,
  21 # exactly like any other package using autoconf.  Therefore, 'target' and
  22 # 'host' will always be the same.  This makes sense both for native and
  23 # cross compilers, just think about it for a little while.  :-)
  24 #
  25 # Also, if v3 is being configured as part of a cross compiler, the top-level
  26 # configure script will pass the "real" host as $with_cross_host.
  27 #
  28 # Do not delete or change the following two lines.  For why, see
  29 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  30 AC_CANONICAL_SYSTEM
  31 target_alias=${target_alias-$host_alias}
  32
  33 # Handy for debugging:
  34 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  35
  36 if test "$build" != "$host"; then
  37   # We are being configured with some form of cross compiler.
  38   GLIBCXX_IS_NATIVE=false
  39   case "$host","$target" in
  40     # Darwin crosses can use the host system's libraries and headers,
  41     # because of the fat library support.  Of course, it must be the
  42     # same version of Darwin on both sides.  Allow the user to
  43     # just say --target=foo-darwin without a version number to mean
  44     # "the version on this system".
  45       *-*-darwin*,*-*-darwin*)
  46         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  47         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  48         if test $hostos = $targetos -o $targetos = darwin ; then
  49           GLIBCXX_IS_NATIVE=true
  50         fi
  51         ;;
  52
  53       *)
  54         GCC_NO_EXECUTABLES
  55         ;;
  56   esac
  57 else
  58   GLIBCXX_IS_NATIVE=true
  59 fi
  60
  61 # In the case that we're building without headers, we won't have <stdio.h>
  62 # available. In these cases, we have to instruct autotools to never include
  63 # <stdio.h> as a part of default headers.
  64 m4_version_prereq([2.70], [], [
  65 if test "x$with_headers" = "xno"; then
  66   ac_includes_default=`echo "$ac_includes_default" | sed '/^#include <stdio.h>$/d'`
  67 fi
  68 ])
  69
  70 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  71 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  72 #  1.x:  minimum required version
  73 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  74 #              of other PACKAGE_* variables will, however, and there's nothing
  75 #              we can do about that; they come from AC_INIT).
  76 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  77 #            file in the top srcdir, etc, etc), so stop complaining.
  78 #  no-dependencies:  turns off auto dependency generation (just for now)
  79 #  no-dist:  we don't want 'dist' and related rules.
  80 #  -Wall:  turns on all automake warnings...
  81 #  -Wno-portability:  ...except this one, since GNU make is now required.
  82 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  83 AH_TEMPLATE(PACKAGE, [Name of package])
  84 AH_TEMPLATE(VERSION, [Version number of package])
  85
  86 # -fno-builtin must be present here so that a non-conflicting form of
  87 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  88
  89 save_CXXFLAGS="$CXXFLAGS"
  90 CXXFLAGS="$CXXFLAGS -fno-builtin"
  91 AC_PROG_CC
  92 AC_PROG_CXX
  93 CXXFLAGS="$save_CXXFLAGS"
  94
  95 AC_SYS_LARGEFILE
  96
  97 # Runs configure.host, and assorted other critical bits.  Sets
  98 # up critical shell variables.
  99 GLIBCXX_CONFIGURE
 100
 101 # Libtool setup.
 102 if test "x${with_newlib}" != "xyes" &&
 103     test "x${with_avrlibc}" != "xyes" &&
 104     test "x$with_headers" != "xno"; then
 105   AC_LIBTOOL_DLOPEN
 106 fi
 107 AM_PROG_LIBTOOL
 108 ACX_LT_HOST_FLAGS
 109 AC_SUBST(enable_shared)
 110 AC_SUBST(enable_static)
 111
 112 if test "$enable_vtable_verify" = yes; then
 113   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 114   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 115 fi
 116
 117
 118 # libtool variables for C++ shared and position-independent compiles.
 119 #
 120 # Use glibcxx_lt_pic_flag to designate the automake variable
 121 # used to encapsulate the default libtool approach to creating objects
 122 # with position-independent code. Default: -prefer-pic.
 123 #
 124 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 125 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 126 #
 127 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 128 # creating position-independent objects. This varies with the target
 129 # hardware and operating system, but is often: -DPIC -fPIC.
 130 if test "$enable_shared" = yes; then
 131   glibcxx_lt_pic_flag="-prefer-pic"
 132   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 133   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 134
 135 else
 136   glibcxx_lt_pic_flag=
 137   glibcxx_compiler_pic_flag=
 138   glibcxx_compiler_shared_flag=
 139 fi
 140 AC_SUBST(glibcxx_lt_pic_flag)
 141 AC_SUBST(glibcxx_compiler_pic_flag)
 142 AC_SUBST(glibcxx_compiler_shared_flag)
 143
 144 # Override the libtool's pic_flag and pic_mode.
 145 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 146 # NB: this impacts --with-pic and --without-pic.
 147 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 148 pic_mode='default'
 149
 150 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 151 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 152
 153 # Possibly disable most of the library.
 154 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 155 ## than just ignoring the results.  Faster /and/ more correct, win win.
 156 GLIBCXX_ENABLE_HOSTED
 157
 158 # Enable descriptive messages to standard output on termination.
 159 GLIBCXX_ENABLE_VERBOSE
 160
 161 # Enable compiler support that doesn't require linking.
 162 GLIBCXX_ENABLE_PCH($is_hosted)
 163 GLIBCXX_ENABLE_THREADS
 164 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 165 GLIBCXX_ENABLE_LOCK_POLICY
 166 GLIBCXX_ENABLE_DECIMAL_FLOAT
 167 GLIBCXX_ENABLE_FLOAT128
 168 if test "$enable_float128" = yes; then
 169   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 170 fi
 171
 172 # Checks for compiler support that doesn't require linking.
 173 GLIBCXX_CHECK_COMPILER_FEATURES
 174
 175 # Enable all the variable C++ runtime options that don't require linking.
 176 GLIBCXX_ENABLE_CSTDIO
 177 GLIBCXX_ENABLE_CLOCALE
 178 GLIBCXX_ENABLE_ALLOCATOR
 179 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 180 GLIBCXX_ENABLE_LONG_LONG([yes])
 181 GLIBCXX_ENABLE_WCHAR_T([yes])
 182 GLIBCXX_ENABLE_C99([yes])
 183 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 184 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0 -D_GLIBCXX_ASSERTIONS"])
 185 GLIBCXX_ENABLE_DEBUG([no])
 186 GLIBCXX_ENABLE_PARALLEL([yes])
 187 GLIBCXX_ENABLE_CXX_FLAGS
 188 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 189 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 190 GLIBCXX_ENABLE_PYTHON
 191 GLIBCXX_ENABLE_WERROR([no])
 192 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 193
 194 # Checks for operating systems support that doesn't require linking.
 195 GLIBCXX_CHECK_STDIO_PROTO
 196 GLIBCXX_CHECK_MATH11_PROTO
 197 GLIBCXX_CHECK_UCHAR_H
 198
 199 # For LFS support.
 200 GLIBCXX_CHECK_LFS
 201
 202 # For showmanyc_helper().
 203 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 204 GLIBCXX_CHECK_POLL
 205 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 206
 207 # For xsputn_2().
 208 AC_CHECK_HEADERS(sys/uio.h)
 209 GLIBCXX_CHECK_WRITEV
 210
 211 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 212 # so that the check is done with the C compiler (not C++).
 213 # Checking with C++ can break a canadian cross build if either
 214 # file does not exist in C but does in C++.
 215 AC_CHECK_HEADERS(fenv.h complex.h)
 216
 217 # For C99 support to TR1.
 218 GLIBCXX_CHECK_C99_TR1
 219
 220 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 221 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 222
 223 # For gettimeofday support.
 224 GLIBCXX_CHECK_GETTIMEOFDAY
 225
 226 # For clock_gettime, nanosleep and sched_yield support.
 227 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 228
 229 # Check for tmpnam which is obsolescent in POSIX.1-2008
 230 GLIBCXX_CHECK_TMPNAM
 231
 232 # For pthread_cond_clockwait
 233 GLIBCXX_CHECK_PTHREAD_COND_CLOCKWAIT
 234
 235 # For pthread_mutex_clocklock
 236 GLIBCXX_CHECK_PTHREAD_MUTEX_CLOCKLOCK
 237
 238 # For pthread_rwlock_clockrdlock and pthread_rwlock_clockwrlock
 239 GLIBCXX_CHECK_PTHREAD_RWLOCK_CLOCKLOCK
 240
 241 AC_LC_MESSAGES
 242
 243 # For hardware_concurrency
 244 AC_CHECK_HEADERS(sys/sysinfo.h)
 245 GLIBCXX_CHECK_GET_NPROCS
 246 AC_CHECK_HEADERS(unistd.h)
 247 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 248 GLIBCXX_CHECK_SC_NPROC_ONLN
 249 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 250 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 251 GLIBCXX_CHECK_SDT_H
 252
 253 # Check for available headers.
 254 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 255 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 256 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 257 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 258 wchar.h wctype.h linux/types.h])
 259
 260 AC_CHECK_HEADERS([linux/random.h], [], [],
 261 [[#ifdef HAVE_LINUX_TYPES_H
 262 # include <linux/types.h>
 263 #endif
 264 ]])
 265
 266 AC_CHECK_HEADERS([xlocale.h])
 267
 268 # Only do link tests if native. Else, hardcode.
 269 if $GLIBCXX_IS_NATIVE; then
 270
 271   # We can do more elaborate tests that assume a working linker.
 272   CANADIAN=no
 273
 274   GLIBCXX_CHECK_LINKER_FEATURES
 275   GLIBCXX_CHECK_MATH_SUPPORT
 276   GLIBCXX_CHECK_STDLIB_SUPPORT
 277
 278   # For /dev/random and /dev/urandom for std::random_device.
 279   GLIBCXX_CHECK_DEV_RANDOM
 280
 281   # For TLS support.
 282   GCC_CHECK_TLS
 283
 284   AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
 285   AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 286   AC_CHECK_FUNCS(_wfopen)
 287   AC_CHECK_FUNCS(secure_getenv)
 288
 289   # C11 functions for C++17 library
 290   AC_CHECK_FUNCS(timespec_get)
 291
 292   # For Networking TS.
 293   AC_CHECK_FUNCS(sockatmark)
 294
 295   # Non-standard functions used by C++17 std::from_chars
 296   AC_CHECK_FUNCS(uselocale)
 297
 298   # For iconv support.
 299   AM_ICONV
 300
 301 else
 302
 303   # This lets us hard-code the functionality we know we'll have in the cross
 304   # target environment.  "Let" is a sugar-coated word placed on an especially
 305   # dull and tedious hack, actually.
 306   #
 307   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 308   # that involve linking, can't be used:
 309   #    "cannot open sim-crt0.o"
 310   #    "cannot open crt0.o"
 311   # etc.  All this is because there currently exists no unified, consistent
 312   # way for top level CC information to be passed down to target directories:
 313   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 314   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 315   # crosses can be removed.
 316
 317   # If Canadian cross, then don't pick up tools from the build directory.
 318   # Used only in GLIBCXX_EXPORT_INCLUDES.
 319   if test -n "$with_cross_host" &&
 320      test x"$build_alias" != x"$with_cross_host" &&
 321      test x"$build" != x"$target";
 322   then
 323     CANADIAN=yes
 324   else
 325     CANADIAN=no
 326   fi
 327
 328   # Construct crosses by hand, eliminating bits that need ld...
 329   # GLIBCXX_CHECK_MATH_SUPPORT
 330
 331   # First, test for "known" system libraries.  We may be using newlib even
 332   # on a hosted environment.
 333   if test "x${with_newlib}" = "xyes"; then
 334     os_include_dir="os/newlib"
 335     AC_DEFINE(HAVE_HYPOT)
 336
 337     # GLIBCXX_CHECK_STDLIB_SUPPORT
 338     AC_DEFINE(HAVE_STRTOF)
 339
 340     AC_DEFINE(HAVE_ACOSF)
 341     AC_DEFINE(HAVE_ASINF)
 342     AC_DEFINE(HAVE_ATAN2F)
 343     AC_DEFINE(HAVE_ATANF)
 344     AC_DEFINE(HAVE_CEILF)
 345     AC_DEFINE(HAVE_COSF)
 346     AC_DEFINE(HAVE_COSHF)
 347     AC_DEFINE(HAVE_EXPF)
 348     AC_DEFINE(HAVE_FABSF)
 349     AC_DEFINE(HAVE_FLOORF)
 350     AC_DEFINE(HAVE_FMODF)
 351     AC_DEFINE(HAVE_FREXPF)
 352     AC_DEFINE(HAVE_LDEXPF)
 353     AC_DEFINE(HAVE_LOG10F)
 354     AC_DEFINE(HAVE_LOGF)
 355     AC_DEFINE(HAVE_MODFF)
 356     AC_DEFINE(HAVE_POWF)
 357     AC_DEFINE(HAVE_SINF)
 358     AC_DEFINE(HAVE_SINHF)
 359     AC_DEFINE(HAVE_SQRTF)
 360     AC_DEFINE(HAVE_TANF)
 361     AC_DEFINE(HAVE_TANHF)
 362
 363     AC_DEFINE(HAVE_ICONV)
 364     AC_DEFINE(HAVE_MEMALIGN)
 365
 366     case "${target}" in
 367       *-rtems*)
 368         case "${target}" in
 369           bfin* | lm32* | mips* | moxie* | or1k* | v850*)
 370             ;;
 371           *)
 372             AC_DEFINE(HAVE_TLS)
 373             ;;
 374         esac
 375         AC_DEFINE(HAVE_ALIGNED_ALLOC)
 376         AC_DEFINE(HAVE_AT_QUICK_EXIT)
 377         AC_DEFINE(HAVE_LINK)
 378         AC_DEFINE(HAVE_QUICK_EXIT)
 379         AC_DEFINE(HAVE_READLINK)
 380         AC_DEFINE(HAVE_SETENV)
 381         AC_DEFINE(HAVE_SLEEP)
 382         AC_DEFINE(HAVE_SOCKATMARK)
 383         AC_DEFINE(HAVE_STRERROR_L)
 384         AC_DEFINE(HAVE_SYMLINK)
 385         AC_DEFINE(HAVE_TRUNCATE)
 386         AC_DEFINE(HAVE_USLEEP)
 387         ;;
 388     esac
 389   elif test "x$with_headers" != "xno"; then
 390     GLIBCXX_CROSSCONFIG
 391   fi
 392
 393   # At some point, we should differentiate between architectures
 394   # like x86, which have long double versions, and alpha/powerpc/etc.,
 395   # which don't. For the time being, punt.
 396   if test x"long_double_math_on_this_cpu" = x"yes"; then
 397     AC_DEFINE(HAVE_ACOSL)
 398     AC_DEFINE(HAVE_ASINL)
 399     AC_DEFINE(HAVE_ATAN2L)
 400     AC_DEFINE(HAVE_ATANL)
 401     AC_DEFINE(HAVE_CEILL)
 402     AC_DEFINE(HAVE_COSL)
 403     AC_DEFINE(HAVE_COSHL)
 404     AC_DEFINE(HAVE_EXPL)
 405     AC_DEFINE(HAVE_FABSL)
 406     AC_DEFINE(HAVE_FLOORL)
 407     AC_DEFINE(HAVE_FMODL)
 408     AC_DEFINE(HAVE_FREXPL)
 409     AC_DEFINE(HAVE_LDEXPL)
 410     AC_DEFINE(HAVE_LOG10L)
 411     AC_DEFINE(HAVE_LOGL)
 412     AC_DEFINE(HAVE_MODFL)
 413     AC_DEFINE(HAVE_POWL)
 414     AC_DEFINE(HAVE_SINCOSL)
 415     AC_DEFINE(HAVE_SINL)
 416     AC_DEFINE(HAVE_SINHL)
 417     AC_DEFINE(HAVE_SQRTL)
 418     AC_DEFINE(HAVE_TANL)
 419     AC_DEFINE(HAVE_TANHL)
 420   fi
 421 fi
 422
 423 # Check for _Unwind_GetIPInfo.
 424 GCC_CHECK_UNWIND_GETIPINFO
 425
 426 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 427
 428 GLIBCXX_ENABLE_SYMVERS([yes])
 429 AC_SUBST(libtool_VERSION)
 430
 431 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 432
 433 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 434 GLIBCXX_DEFAULT_ABI
 435
 436 ac_ldbl_compat=no
 437 ac_ldbl_alt128_compat=no
 438 ac_ldbl_ieee128_default=no
 439 LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
 440 LONG_DOUBLE_128_FLAGS=
 441 LONG_DOUBLE_ALT128_COMPAT_FLAGS=
 442 case "$target" in
 443   powerpc*-*-linux* | \
 444   sparc*-*-linux* | \
 445   s390*-*-linux* | \
 446   alpha*-*-linux*)
 447   AC_TRY_COMPILE(, [
 448 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 449 #error no need for long double compatibility
 450 #endif
 451   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 452   if test "$ac_ldbl_compat" = yes; then
 453     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 454               [Define if compatibility should be provided for -mlong-double-64.])
 455     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 456     case "$target" in
 457       powerpc*-*-linux*)
 458         LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute"
 459         # Check for IEEE128 support in libm:
 460         AC_CHECK_LIB(m, __frexpieee128,
 461                      [ac_ldbl_ieee128_in_libc=yes],
 462                      [ac_ldbl_ieee128_in_libc=no])
 463         if test $ac_ldbl_ieee128_in_libc = yes; then
 464           # Determine which long double format is the compiler's default:
 465           AC_TRY_COMPILE(, [
 466             #ifndef __LONG_DOUBLE_IEEE128__
 467             #error compiler defaults to ibm128
 468             #endif
 469           ], [ac_ldbl_ieee128_default=yes], [ac_ldbl_ieee128_default=no])
 470           # Library objects should use default long double format.
 471           if test "$ac_ldbl_ieee128_default" = yes; then
 472             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 473             # Except for the ones that explicitly use these flags:
 474             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ibmlongdouble -mno-gnu-attribute -Wno-psabi"
 475           else
 476             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 477             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ieeelongdouble -mno-gnu-attribute -Wno-psabi"
 478           fi
 479           AC_DEFINE([_GLIBCXX_LONG_DOUBLE_ALT128_COMPAT],1,
 480                 [Define if compatibility should be provided for alternative 128-bit long double formats.])
 481           port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/os/gnu-linux/ldbl-ieee128-extra.ver"
 482           ac_ldbl_alt128_compat=yes
 483         else
 484           ac_ldbl_alt128_compat=no
 485         fi
 486         ;;
 487     esac
 488   fi
 489 esac
 490 AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
 491 AC_SUBST(LONG_DOUBLE_128_FLAGS)
 492 AC_SUBST(LONG_DOUBLE_ALT128_COMPAT_FLAGS)
 493 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 494 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_ALT128_COMPAT, test $ac_ldbl_alt128_compat = yes)
 495
 496 # Check if assembler supports disabling hardware capability support.
 497 GCC_CHECK_ASSEMBLER_HWCAP
 498
 499 # Check if assembler supports rdrand opcode.
 500 GLIBCXX_CHECK_X86_RDRAND
 501 # Check if assembler supports rdseed opcode.
 502 GLIBCXX_CHECK_X86_RDSEED
 503
 504 # Check for other random number APIs
 505 GLIBCXX_CHECK_GETENTROPY
 506 GLIBCXX_CHECK_ARC4RANDOM
 507
 508 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 509 GLIBCXX_CONFIGURE_TESTSUITE
 510
 511 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 512 GLIBCXX_CHECK_GTHREADS
 513
 514 # For Filesystem TS.
 515 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 516 GLIBCXX_ENABLE_FILESYSTEM_TS
 517 GLIBCXX_CHECK_FILESYSTEM_DEPS
 518
 519 GLIBCXX_ENABLE_BACKTRACE
 520
 521 # For Networking TS.
 522 AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/socket.h sys/uio.h poll.h netdb.h arpa/inet.h netinet/in.h netinet/tcp.h])
 523 AC_CHECK_DECL(F_GETFL,,,[#include <fcntl.h>])
 524 AC_CHECK_DECL(F_SETFL,,,[#include <fcntl.h>])
 525 if test "$ac_cv_have_decl_F_GETFL$ac_cv_have_decl_F_SETFL" = yesyes ; then
 526   AC_CHECK_DECL(O_NONBLOCK,,,[#include <fcntl.h>])
 527 fi
 528
 529 # For Transactional Memory TS
 530 GLIBCXX_CHECK_SIZE_T_MANGLING
 531
 532 # Check which release added std::exception_ptr for the target
 533 GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
 534
 535 # For libsupc++/eh_alloc.cc defaults.
 536 GLIBCXX_EMERGENCY_EH_ALLOC
 537
 538 # For src/c++20/tzdb.cc defaults.
 539 GLIBCXX_ZONEINFO_DIR
 540
 541 # Define documentation rules conditionally.
 542
 543 # See if makeinfo has been installed and is modern enough
 544 # that we can use it.
 545 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 546                    [GNU texinfo.* \([0-9][0-9.]*\)],
 547                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 548 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 549
 550 # Check for doxygen
 551 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 552 AC_CHECK_PROG([DOT], dot, yes, no)
 553
 554 # Check for docbook
 555 AC_CHECK_PROG([XMLCATALOG], xmlcatalog, yes, no)
 556 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 557 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 558 GLIBCXX_CONFIGURE_DOCBOOK
 559
 560 # Check for xml/html dependencies.
 561 AM_CONDITIONAL(BUILD_XML,
 562                test $ac_cv_prog_DOXYGEN = "yes" &&
 563                test $ac_cv_prog_DOT = "yes" &&
 564                test $ac_cv_prog_XSLTPROC = "yes" &&
 565                test $ac_cv_prog_XMLLINT = "yes" &&
 566                test $glibcxx_stylesheets = "yes")
 567
 568 AM_CONDITIONAL(BUILD_HTML,
 569                test $ac_cv_prog_DOXYGEN = "yes" &&
 570                test $ac_cv_prog_DOT = "yes" &&
 571                test $ac_cv_prog_XSLTPROC = "yes" &&
 572                test $ac_cv_prog_XMLLINT = "yes" &&
 573                test $glibcxx_stylesheets = "yes")
 574
 575 # Check for man dependencies.
 576 AM_CONDITIONAL(BUILD_MAN,
 577                test $ac_cv_prog_DOXYGEN = "yes" &&
 578                test $ac_cv_prog_DOT = "yes")
 579
 580 # Check for pdf dependencies.
 581 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 582 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 583 AM_CONDITIONAL(BUILD_PDF,
 584                test $ac_cv_prog_DOXYGEN = "yes" &&
 585                test $ac_cv_prog_DOT = "yes" &&
 586                test $ac_cv_prog_XSLTPROC = "yes" &&
 587                test $ac_cv_prog_XMLLINT = "yes" &&
 588                test $ac_cv_prog_DBLATEX = "yes" &&
 589                test $ac_cv_prog_PDFLATEX = "yes")
 590
 591 case "$build" in
 592  *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
 593  * ) glibcxx_include_dir_notparallel=no ;;
 594 esac
 595 AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
 596                test $glibcxx_include_dir_notparallel = "yes")
 597
 598 # Propagate the target-specific source directories through the build chain.
 599 ATOMICITY_SRCDIR=config/${atomicity_dir}
 600 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 601 ATOMIC_FLAGS=${atomic_flags}
 602 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 603 OS_INC_SRCDIR=config/${os_include_dir}
 604 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 605 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 606 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 607 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 608 AC_SUBST(ATOMICITY_SRCDIR)
 609 AC_SUBST(ATOMIC_WORD_SRCDIR)
 610 AC_SUBST(ATOMIC_FLAGS)
 611 AC_SUBST(CPU_DEFINES_SRCDIR)
 612 AC_SUBST(ABI_TWEAKS_SRCDIR)
 613 AC_SUBST(OS_INC_SRCDIR)
 614 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 615 AC_SUBST(CPU_OPT_EXT_RANDOM)
 616 AC_SUBST(CPU_OPT_BITS_RANDOM)
 617
 618 # Conditionalize the makefile for this target machine.
 619 tmake_file_=
 620 for f in ${tmake_file}
 621 do
 622         if test -f ${srcdir}/config/$f
 623         then
 624                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 625         fi
 626 done
 627 tmake_file="${tmake_file_}"
 628 AC_SUBST(tmake_file)
 629
 630 # Add CET specific flags if Intel CET is enabled.
 631 GCC_CET_FLAGS(CET_FLAGS)
 632 EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
 633 EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
 634 AC_SUBST(EXTRA_CFLAGS)
 635 AC_SUBST(EXTRA_CXX_FLAGS)
 636
 637 # Determine cross-compile flags and AM_CONDITIONALs.
 638 #AC_SUBST(GLIBCXX_IS_NATIVE)
 639 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 640 GLIBCXX_EVALUATE_CONDITIONALS
 641
 642 AC_CACHE_SAVE
 643
 644 if test ${multilib} = yes; then
 645   multilib_arg="--enable-multilib"
 646 else
 647   multilib_arg=
 648 fi
 649
 650 # Export all the install information.
 651 GLIBCXX_EXPORT_INSTALL_INFO
 652
 653 # Export all the include and flag information to Makefiles.
 654 GLIBCXX_EXPORT_INCLUDES
 655 GLIBCXX_EXPORT_FLAGS
 656
 657 # Determine what GCC version number to use in filesystem paths.
 658 GCC_BASE_VER
 659
 660 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 661 dnl which can all be called multiple times as needed, plus one (different)
 662 dnl AC_OUTPUT macro.  This one lists the files to be created:
 663 AC_CONFIG_FILES(Makefile)
 664 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 665 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 666 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 667 AC_CONFIG_FILES([src/libbacktrace/backtrace-supported.h])
 668
 669 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 670 # that multilib installs will end up installed in the correct place.
 671 # The testsuite needs it for multilib-aware ABI baseline files.
 672 # To work around this not being passed down from config-ml.in ->
 673 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 674 # append it here.  Only modify Makefiles that have just been created.
 675 #
 676 # Also, get rid of this simulated-VPATH thing that automake does.
 677 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 678   [cat > vpsed$$ << \_EOF
 679 s!`test -f '$<' || echo '$(srcdir)/'`!!
 680 _EOF
 681    sed -f vpsed$$ $ac_file > tmp$$
 682    mv tmp$$ $ac_file
 683    rm vpsed$$
 684    echo 'MULTISUBDIR =' >> $ac_file
 685    ml_norecursion=yes
 686    . ${multi_basedir}/config-ml.in
 687    AS_UNSET([ml_norecursion])
 688 ])
 689
 690 AC_CONFIG_COMMANDS([generate-headers],
 691   [(cd include && ${MAKE-make} pch_build= )])
 692
 693 dnl And this actually makes things happen:
 694 AC_OUTPUT