gcc/ada/a-cofove.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --         A D A . C O N T A I N E R S . F O R M A L _ V E C T O R S        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2014, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This spec is derived from package Ada.Containers.Bounded_Vectors in the Ada
  33 --  2012 RM. The modifications are meant to facilitate formal proofs by making
  34 --  it easier to express properties, and by making the specification of this
  35 --  unit compatible with SPARK 2014. Note that the API of this unit may be
  36 --  subject to incompatible changes as SPARK 2014 evolves.
  37
  38 generic
  39    type Index_Type is range <>;
  40    type Element_Type is private;
  41
  42    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  43
  44    Bounded : Boolean := True;
  45    --  If True, the containers are bounded; the initial capacity is the maximum
  46    --  size, and heap allocation will be avoided. If False, the containers can
  47    --  grow via heap allocation.
  48
  49 package Ada.Containers.Formal_Vectors with
  50   SPARK_Mode
  51 is
  52    pragma Annotate (GNATprove, External_Axiomatization);
  53
  54    subtype Extended_Index is Index_Type'Base
  55    range Index_Type'First - 1 ..
  56      Index_Type'Min (Index_Type'Base'Last - 1, Index_Type'Last) + 1;
  57
  58    No_Index : constant Extended_Index := Extended_Index'First;
  59
  60    subtype Capacity_Range is
  61      Count_Type range 0 .. Count_Type (Index_Type'Last - Index_Type'First + 1);
  62
  63    type Vector (Capacity : Capacity_Range) is limited private with
  64      Default_Initial_Condition;
  65    --  In the bounded case, Capacity is the capacity of the container, which
  66    --  never changes. In the unbounded case, Capacity is the initial capacity
  67    --  of the container, and operations such as Reserve_Capacity and Append can
  68    --  increase the capacity. The capacity never shrinks, except in the case of
  69    --  Clear.
  70    --
  71    --  Note that all objects of type Vector are constrained, including in the
  72    --  unbounded case; you can't assign from one object to another if the
  73    --  Capacity is different.
  74
  75    function Empty_Vector return Vector;
  76
  77    function "=" (Left, Right : Vector) return Boolean with
  78      Global => null;
  79
  80    function To_Vector
  81      (New_Item : Element_Type;
  82       Length   : Capacity_Range) return Vector
  83    with
  84      Global => null;
  85
  86    function Capacity (Container : Vector) return Capacity_Range with
  87      Global => null;
  88
  89    procedure Reserve_Capacity
  90      (Container : in out Vector;
  91       Capacity  : Capacity_Range)
  92    with
  93      Global => null,
  94      Pre    => (if Bounded then Capacity <= Container.Capacity);
  95
  96    function Length (Container : Vector) return Capacity_Range with
  97      Global => null;
  98
  99    function Is_Empty (Container : Vector) return Boolean with
 100      Global => null;
 101
 102    procedure Clear (Container : in out Vector) with
 103      Global => null;
 104    --  Note that this reclaims storage in the unbounded case. You need to call
 105    --  this before a container goes out of scope in order to avoid storage
 106    --  leaks. In addition, "X := ..." can leak unless you Clear(X) first.
 107
 108    procedure Assign (Target : in out Vector; Source : Vector) with
 109      Global => null,
 110      Pre    => (if Bounded then Length (Source) <= Target.Capacity);
 111
 112    function Copy
 113      (Source   : Vector;
 114       Capacity : Capacity_Range := 0) return Vector
 115    with
 116      Global => null,
 117      Pre    => (if Bounded then (Capacity = 0 or Length (Source) <= Capacity));
 118
 119    function Element
 120      (Container : Vector;
 121       Index     : Index_Type) return Element_Type
 122    with
 123      Global => null,
 124      Pre    => Index in First_Index (Container) .. Last_Index (Container);
 125
 126    procedure Replace_Element
 127      (Container : in out Vector;
 128       Index     : Index_Type;
 129       New_Item  : Element_Type)
 130    with
 131      Global => null,
 132      Pre    => Index in First_Index (Container) .. Last_Index (Container);
 133
 134    procedure Append
 135      (Container : in out Vector;
 136       New_Item  : Vector)
 137    with
 138      Global => null,
 139      Pre    => (if Bounded then
 140                  Length (Container) + Length (New_Item) <= Container.Capacity);
 141
 142    procedure Append
 143      (Container : in out Vector;
 144       New_Item  : Element_Type)
 145    with
 146      Global => null,
 147      Pre    => (if Bounded then
 148                   Length (Container) < Container.Capacity);
 149
 150    procedure Delete_Last
 151      (Container : in out Vector)
 152    with
 153      Global => null;
 154
 155    procedure Reverse_Elements (Container : in out Vector) with
 156      Global => null;
 157
 158    procedure Swap (Container : in out Vector; I, J : Index_Type) with
 159      Global => null,
 160      Pre    => I in First_Index (Container) .. Last_Index (Container)
 161       and then J in First_Index (Container) .. Last_Index (Container);
 162
 163    function First_Index (Container : Vector) return Index_Type with
 164      Global => null;
 165
 166    function First_Element (Container : Vector) return Element_Type with
 167      Global => null,
 168      Pre    => not Is_Empty (Container);
 169
 170    function Last_Index (Container : Vector) return Extended_Index with
 171      Global => null;
 172
 173    function Last_Element (Container : Vector) return Element_Type with
 174      Global => null,
 175      Pre    => not Is_Empty (Container);
 176
 177    function Find_Index
 178      (Container : Vector;
 179       Item      : Element_Type;
 180       Index     : Index_Type := Index_Type'First) return Extended_Index
 181    with
 182      Global => null;
 183
 184    function Reverse_Find_Index
 185      (Container : Vector;
 186       Item      : Element_Type;
 187       Index     : Index_Type := Index_Type'Last) return Extended_Index
 188    with
 189      Global => null;
 190
 191    function Contains
 192      (Container : Vector;
 193       Item      : Element_Type) return Boolean
 194    with
 195      Global => null;
 196
 197    function Has_Element
 198      (Container : Vector;
 199       Position  : Extended_Index) return Boolean
 200    with
 201      Global => null;
 202
 203    generic
 204       with function "<" (Left, Right : Element_Type) return Boolean is <>;
 205    package Generic_Sorting is
 206
 207       function Is_Sorted (Container : Vector) return Boolean with
 208         Global => null;
 209
 210       procedure Sort (Container : in out Vector) with
 211         Global => null;
 212
 213    end Generic_Sorting;
 214
 215    function First_To_Previous
 216      (Container : Vector;
 217       Current   : Index_Type) return Vector
 218    with
 219      Ghost,
 220      Global => null,
 221      Pre    => Current in First_Index (Container) .. Last_Index (Container);
 222
 223    function Current_To_Last
 224      (Container : Vector;
 225       Current   : Index_Type) return Vector
 226    with
 227      Ghost,
 228      Global => null,
 229      Pre    => Current in First_Index (Container) .. Last_Index (Container);
 230    --  First_To_Previous returns a container containing all elements preceding
 231    --  Current (excluded) in Container. Current_To_Last returns a container
 232    --  containing all elements following Current (included) in Container.
 233    --  These two new functions can be used to express invariant properties in
 234    --  loops which iterate over containers. First_To_Previous returns the part
 235    --  of the container already scanned and Current_To_Last the part not
 236    --  scanned yet.
 237
 238 private
 239    pragma SPARK_Mode (Off);
 240
 241    pragma Inline (First_Index);
 242    pragma Inline (Last_Index);
 243    pragma Inline (Element);
 244    pragma Inline (First_Element);
 245    pragma Inline (Last_Element);
 246    pragma Inline (Replace_Element);
 247    pragma Inline (Contains);
 248
 249    type Elements_Array is array (Capacity_Range range <>) of Element_Type;
 250    function "=" (L, R : Elements_Array) return Boolean is abstract;
 251
 252    type Elements_Array_Ptr is access all Elements_Array;
 253
 254    type Vector (Capacity : Capacity_Range) is limited record
 255       --  In the bounded case, the elements are stored in Elements. In the
 256       --  unbounded case, the elements are initially stored in Elements, until
 257       --  we run out of room, then we switch to Elements_Ptr.
 258       Last         : Extended_Index := No_Index;
 259       Elements_Ptr : Elements_Array_Ptr := null;
 260       Elements     : aliased Elements_Array (1 .. Capacity);
 261    end record;
 262
 263    --  The primary reason Vector is limited is that in the unbounded case, once
 264    --  Elements_Ptr is in use, assignment statements won't work. "X := Y;" will
 265    --  cause X and Y to share state; that is, X.Elements_Ptr = Y.Elements_Ptr,
 266    --  so for example "Append (X, ...);" will modify BOTH X and Y. That would
 267    --  allow SPARK to "prove" things that are false. We could fix that by
 268    --  making Vector a controlled type, and override Adjust to make a deep
 269    --  copy, but finalization is not allowed in SPARK.
 270    --
 271    --  Note that (unfortunately) this means that 'Old and 'Loop_Entry are not
 272    --  allowed on Vectors.
 273
 274    function Empty_Vector return Vector is
 275      ((Capacity => 0, others => <>));
 276
 277 end Ada.Containers.Formal_Vectors;