contrib/analyze_brprob

   1 #!/usr/bin/awk -f
   2 # Script to analyze experimental results of our branch prediction heuristics
   3 # Contributed by Jan Hubicka, SuSE Inc.
   4 # Copyright (C) 2001, 2003 Free Software Foundation, Inc.
   5 #
   6 # This file is part of GCC.
   7 #
   8 # GCC is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3, or (at your option)
  11 # any later version.
  12 #
  13 # GCC is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with GCC; see the file COPYING.  If not, write to
  20 # the Free Software Foundation, 51 Franklin Street, Fifth Floor,
  21 # Boston, MA 02110-1301, USA.
  22 #
  23 #
  24 # This script is used to calculate two basic properties of the branch prediction
  25 # heuristics - coverage and hitrate.  Coverage is number of executions of a given
  26 # branch matched by the heuristics and hitrate is probability that once branch is
  27 # predicted as taken it is really taken.
  28 #
  29 # These values are useful to determine the quality of given heuristics.  Hitrate
  30 # may be directly used in predict.c.
  31 #
  32 # Usage:
  33 #  Step 1: Compile and profile your program.  You need to use -fprofile-arcs
  34 #    flag to get the profiles
  35 #  Step 2: Generate log files.  The information about given heuristics are
  36 #    saved into ipa-profile dumps.  You need to pass the -fdimp-ipa-profile switch
  37 #    to the compiler as well
  38 #    as -fbranch-probabilities to get the results of profiling noted in the dumps.
  39 #    Ensure that there are no "Arc profiling: some edge counts were bad." warnings.
  40 #  Step 3: Run this script to concatenate all *.profile files:
  41 #    analyze_brprob `find . -name *.profile`
  42 #    the information is collected and print once all files are parsed.  This
  43 #    may take a while.
  44 #    Note that the script does use bc to perform long arithmetic.
  45 #  Step 4: Read the results.  Basically the following table is printed:
  46 #  (this is just an example from a very early stage of branch prediction pass
  47 #   development, so please don't take these numbers seriously)
  48 #
  49 #HEURISTICS                  BRANCHES  (REL)  HITRATE             COVERAGE  (REL)
  50 #opcode                          2889  83.7%  94.96%/ 97.62%      7516383  75.3%
  51 #pointer                          246   7.1%  99.69%/ 99.86%       118791   1.2%
  52 #loop header                      449  13.0%  98.32%/ 99.07%        43553   0.4%
  53 #first match                     3450 100.0%  89.92%/ 97.27%      9979782 100.0%
  54 #loop exit                        924  26.8%  88.95%/ 95.58%      9026266  90.4%
  55 #error return                     150   4.3%  64.48%/ 86.81%       453542   4.5%
  56 #call                             803  23.3%  51.66%/ 98.61%      3614037  36.2%
  57 #loop branch                       51   1.5%  99.26%/ 99.27%        26854   0.3%
  58 #noreturn call                    951  27.6% 100.00%/100.00%      1759809  17.6%
  59 #
  60 #  The heuristic called "first match" is a heuristic used by GCC branch
  61 #  prediction pass and it predicts 89.92% branches correctly.
  62 #
  63 #  The quality of heuristics can be rated using both, coverage and hitrate
  64 #  parameters.  For example "loop branch" heuristics (predicting loopback edge
  65 #  as taken) have both very high hitrate and coverage, so it is very useful.
  66 #  On the other hand, "exit block" heuristics (predicting exit edges as not
  67 #  taken) have good hitrate, but poor coverage, so only 3 branches have been
  68 #  predicted.  The "loop header" heuristic has problems, since it tends to
  69 #  misspredict.
  70 #
  71 #  The implementation of this script is somewhat brute force.  My awk skills
  72 #  are limited.
  73
  74 function longeval(e)
  75 {
  76   e = "echo \"scale = 2 ;"e"\" | bc"
  77   e | getline res
  78   close (e)
  79   return res
  80 }
  81
  82 BEGIN {nnames = 0}
  83
  84 /^  .* heuristics: .*.$/ {
  85     name=$0
  86     sub (/^  /,"",name)
  87     sub (/ heuristics: .*.$/,"",name)
  88     if (!(name in branches))
  89       {
  90         names[nnames] = name
  91         branches[name]=0
  92         counts[name]=0
  93         hits[name]=0
  94         phits[name]=0
  95         nnames++
  96       }
  97     branches[name]+=1
  98   }
  99
 100 /^  .* heuristics: .*. exec [0-9]* hit [0-9]* (.*.)$/ {
 101     name=$0
 102     sub (/^  /,"",name)
 103     sub (/ heuristics: .*. exec [0-9]* hit [0-9]* (.*.)$/,"",name)
 104     pred=$0
 105     sub (/^  .* heuristics: /,"",pred)
 106     sub (/. exec [0-9]* hit [0-9]* (.*.)$/,"",pred)
 107     count=$0
 108     sub (/^  .* heuristics: .*. exec /,"",count)
 109     sub (/ hit [0-9]* (.*.)$/,"",count)
 110     hit=$0
 111     sub (/^  .* heuristics: .*. exec [0-9]* hit /,"",hit)
 112     sub (/ (.*.)$/,"",hit)
 113
 114     if (int(pred) < 50.0)
 115       {
 116         hit = count"-"hit;
 117       }
 118     counts[name]=counts[name] "+" count
 119     hits[name]=hits[name] "+" hit
 120     phits[name]=phits[name] "+(("hit")<"count"/2)*("count"-("hit"))+(("hit")>="count"/2)*("hit")"
 121
 122     #BC crashes on long strings.  Irritating.
 123     if (length(counts[name]) > 2000)
 124       counts[name] = longeval(counts[name])
 125     if (length(hits[name]) > 2000)
 126       hits[name] = longeval(hits[name])
 127     if (length(phits[name]) > 2000)
 128       phits[name] = longeval(phits[name])
 129   }
 130 END {
 131   # Heuristics called combined predicts just everything.
 132   maxcounts = longeval(counts["combined"])
 133   maxbranches = branches["combined"]
 134   max = names["combined"]
 135   printf("HEURISTICS                 BRANCHES  (REL)  HITRATE              COVERAGE  (REL)\n")
 136   for (i = 0; i < nnames ; i++)
 137    {
 138      name = names[i]
 139      counts[name] = longeval(counts[name])
 140      printf ("%-26s %8i %5.1f%% %6s%% / %6s%% %12s %5.1f%%\n",
 141              name,
 142              branches[name], branches[name] * 100 / maxbranches,
 143              longeval("("hits[name]") * 100 /(" counts[name]"-0.00001)"),
 144              longeval("("phits[name]") * 100 /(" counts[name]"-0.00001)"),
 145              counts[name], longeval(counts[name]" * 100 / ("maxcounts"-0.00001)"))
 146    }
 147 }