libffi/acinclude.m4

   1 # mmap(2) blacklisting.  Some platforms provide the mmap library routine
   2 # but don't support all of the features we need from it.
   3 AC_DEFUN([AC_FUNC_MMAP_BLACKLIST],
   4 [
   5 AC_CHECK_HEADER([sys/mman.h],
   6                 [libffi_header_sys_mman_h=yes], [libffi_header_sys_mman_h=no])
   7 AC_CHECK_FUNC([mmap], [libffi_func_mmap=yes], [libffi_func_mmap=no])
   8 if test "$libffi_header_sys_mman_h" != yes \
   9  || test "$libffi_func_mmap" != yes; then
  10    ac_cv_func_mmap_file=no
  11    ac_cv_func_mmap_dev_zero=no
  12    ac_cv_func_mmap_anon=no
  13 else
  14    AC_CACHE_CHECK([whether read-only mmap of a plain file works],
  15   ac_cv_func_mmap_file,
  16   [# Add a system to this blacklist if
  17    # mmap(0, stat_size, PROT_READ, MAP_PRIVATE, fd, 0) doesn't return a
  18    # memory area containing the same data that you'd get if you applied
  19    # read() to the same fd.  The only system known to have a problem here
  20    # is VMS, where text files have record structure.
  21    case "$host_os" in
  22      vms* | ultrix*)
  23         ac_cv_func_mmap_file=no ;;
  24      *)
  25         ac_cv_func_mmap_file=yes;;
  26    esac])
  27    AC_CACHE_CHECK([whether mmap from /dev/zero works],
  28   ac_cv_func_mmap_dev_zero,
  29   [# Add a system to this blacklist if it has mmap() but /dev/zero
  30    # does not exist, or if mmapping /dev/zero does not give anonymous
  31    # zeroed pages with both the following properties:
  32    # 1. If you map N consecutive pages in with one call, and then
  33    #    unmap any subset of those pages, the pages that were not
  34    #    explicitly unmapped remain accessible.
  35    # 2. If you map two adjacent blocks of memory and then unmap them
  36    #    both at once, they must both go away.
  37    # Systems known to be in this category are Windows (all variants),
  38    # VMS, and Darwin.
  39    case "$host_os" in
  40      vms* | cygwin* | pe | mingw* | darwin* | ultrix* | hpux10* | hpux11.00)
  41         ac_cv_func_mmap_dev_zero=no ;;
  42      *)
  43         ac_cv_func_mmap_dev_zero=yes;;
  44    esac])
  45
  46    # Unlike /dev/zero, the MAP_ANON(YMOUS) defines can be probed for.
  47    AC_CACHE_CHECK([for MAP_ANON(YMOUS)], ac_cv_decl_map_anon,
  48     [AC_TRY_COMPILE(
  49 [#include <sys/types.h>
  50 #include <sys/mman.h>
  51 #include <unistd.h>
  52
  53 #ifndef MAP_ANONYMOUS
  54 #define MAP_ANONYMOUS MAP_ANON
  55 #endif
  56 ],
  57 [int n = MAP_ANONYMOUS;],
  58     ac_cv_decl_map_anon=yes,
  59     ac_cv_decl_map_anon=no)])
  60
  61    if test $ac_cv_decl_map_anon = no; then
  62      ac_cv_func_mmap_anon=no
  63    else
  64      AC_CACHE_CHECK([whether mmap with MAP_ANON(YMOUS) works],
  65      ac_cv_func_mmap_anon,
  66   [# Add a system to this blacklist if it has mmap() and MAP_ANON or
  67    # MAP_ANONYMOUS, but using mmap(..., MAP_PRIVATE|MAP_ANONYMOUS, -1, 0)
  68    # doesn't give anonymous zeroed pages with the same properties listed
  69    # above for use of /dev/zero.
  70    # Systems known to be in this category are Windows, VMS, and SCO Unix.
  71    case "$host_os" in
  72      vms* | cygwin* | pe | mingw* | sco* | udk* )
  73         ac_cv_func_mmap_anon=no ;;
  74      *)
  75         ac_cv_func_mmap_anon=yes;;
  76    esac])
  77    fi
  78 fi
  79
  80 if test $ac_cv_func_mmap_file = yes; then
  81   AC_DEFINE(HAVE_MMAP_FILE, 1,
  82             [Define if read-only mmap of a plain file works.])
  83 fi
  84 if test $ac_cv_func_mmap_dev_zero = yes; then
  85   AC_DEFINE(HAVE_MMAP_DEV_ZERO, 1,
  86             [Define if mmap of /dev/zero works.])
  87 fi
  88 if test $ac_cv_func_mmap_anon = yes; then
  89   AC_DEFINE(HAVE_MMAP_ANON, 1,
  90             [Define if mmap with MAP_ANON(YMOUS) works.])
  91 fi
  92 ])
  93
  94 dnl ----------------------------------------------------------------------
  95 dnl This whole bit snagged from libstdc++-v3, via libatomic.
  96
  97 dnl
  98 dnl LIBAT_ENABLE
  99 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 100 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 101 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 102 dnl
 103 dnl See docs/html/17_intro/configury.html#enable for documentation.
 104 dnl
 105 m4_define([LIBAT_ENABLE],[dnl
 106 m4_define([_g_switch],[--enable-$1])dnl
 107 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 108  AC_ARG_ENABLE($1,_g_help,
 109   m4_bmatch([$5],
 110    [^permit ],
 111      [[
 112       case "$enableval" in
 113        m4_bpatsubst([$5],[permit ])) ;;
 114        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 115           dnl Idea for future:  generate a URL pointing to
 116           dnl "onlinedocs/configopts.html#whatever"
 117       esac
 118      ]],
 119    [^$],
 120      [[
 121       case "$enableval" in
 122        yes|no) ;;
 123        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 124       esac
 125      ]],
 126    [[$5]]),
 127   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 128 m4_undefine([_g_switch])dnl
 129 m4_undefine([_g_help])dnl
 130 ])
 131
 132 dnl
 133 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 134 dnl the native linker is in use, all variables will be defined to something
 135 dnl safe (like an empty string).
 136 dnl
 137 dnl Defines:
 138 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 139 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 140 dnl  LD (as a side effect of testing)
 141 dnl Sets:
 142 dnl  with_gnu_ld
 143 dnl  libat_ld_is_gold (possibly)
 144 dnl  libat_gnu_ld_version (possibly)
 145 dnl
 146 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 147 dnl set libat_gnu_ld_version to 12345.  Zeros cause problems.
 148 dnl
 149 AC_DEFUN([LIBAT_CHECK_LINKER_FEATURES], [
 150   # If we're not using GNU ld, then there's no point in even trying these
 151   # tests.  Check for that first.  We should have already tested for gld
 152   # by now (in libtool), but require it now just to be safe...
 153   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 154   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 155   AC_REQUIRE([AC_PROG_LD])
 156   AC_REQUIRE([AC_PROG_AWK])
 157
 158   # The name set by libtool depends on the version of libtool.  Shame on us
 159   # for depending on an impl detail, but c'est la vie.  Older versions used
 160   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 161   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 162   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 163   # set (hence we're using an older libtool), then set it.
 164   if test x${with_gnu_ld+set} != xset; then
 165     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 166       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 167       with_gnu_ld=no
 168     else
 169       with_gnu_ld=$ac_cv_prog_gnu_ld
 170     fi
 171   fi
 172
 173   # Start by getting the version number.  I think the libtool test already
 174   # does some of this, but throws away the result.
 175   libat_ld_is_gold=no
 176   if $LD --version 2>/dev/null | grep 'GNU gold'> /dev/null 2>&1; then
 177     libat_ld_is_gold=yes
 178   fi
 179   changequote(,)
 180   ldver=`$LD --version 2>/dev/null |
 181          sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
 182   changequote([,])
 183   libat_gnu_ld_version=`echo $ldver | \
 184          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 185
 186   # Set --gc-sections.
 187   if test "$with_gnu_ld" = "notbroken"; then
 188     # GNU ld it is!  Joy and bunny rabbits!
 189
 190     # All these tests are for C++; save the language and the compiler flags.
 191     # Need to do this so that g++ won't try to link in libstdc++
 192     ac_test_CFLAGS="${CFLAGS+set}"
 193     ac_save_CFLAGS="$CFLAGS"
 194     CFLAGS='-x c++  -Wl,--gc-sections'
 195
 196     # Check for -Wl,--gc-sections
 197     # XXX This test is broken at the moment, as symbols required for linking
 198     # are now in libsupc++ (not built yet).  In addition, this test has
 199     # cored on solaris in the past.  In addition, --gc-sections doesn't
 200     # really work at the moment (keeps on discarding used sections, first
 201     # .eh_frame and now some of the glibc sections for iconv).
 202     # Bzzzzt.  Thanks for playing, maybe next time.
 203     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 204     AC_TRY_RUN([
 205      int main(void)
 206      {
 207        try { throw 1; }
 208        catch (...) { };
 209        return 0;
 210      }
 211     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 212     if test "$ac_test_CFLAGS" = set; then
 213       CFLAGS="$ac_save_CFLAGS"
 214     else
 215       # this is the suspicious part
 216       CFLAGS=''
 217     fi
 218     if test "$ac_sectionLDflags" = "yes"; then
 219       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 220     fi
 221     AC_MSG_RESULT($ac_sectionLDflags)
 222   fi
 223
 224   # Set linker optimization flags.
 225   if test x"$with_gnu_ld" = x"yes"; then
 226     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 227   fi
 228
 229   AC_SUBST(SECTION_LDFLAGS)
 230   AC_SUBST(OPT_LDFLAGS)
 231 ])
 232
 233
 234 dnl
 235 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 236 dnl the native linker is in use, all variables will be defined to something
 237 dnl safe (like an empty string).
 238 dnl
 239 dnl Defines:
 240 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 241 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 242 dnl  LD (as a side effect of testing)
 243 dnl Sets:
 244 dnl  with_gnu_ld
 245 dnl  libat_ld_is_gold (possibly)
 246 dnl  libat_gnu_ld_version (possibly)
 247 dnl
 248 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 249 dnl set libat_gnu_ld_version to 12345.  Zeros cause problems.
 250 dnl
 251 AC_DEFUN([LIBAT_CHECK_LINKER_FEATURES], [
 252   # If we're not using GNU ld, then there's no point in even trying these
 253   # tests.  Check for that first.  We should have already tested for gld
 254   # by now (in libtool), but require it now just to be safe...
 255   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 256   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 257   AC_REQUIRE([AC_PROG_LD])
 258   AC_REQUIRE([AC_PROG_AWK])
 259
 260   # The name set by libtool depends on the version of libtool.  Shame on us
 261   # for depending on an impl detail, but c'est la vie.  Older versions used
 262   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 263   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 264   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 265   # set (hence we're using an older libtool), then set it.
 266   if test x${with_gnu_ld+set} != xset; then
 267     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 268       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 269       with_gnu_ld=no
 270     else
 271       with_gnu_ld=$ac_cv_prog_gnu_ld
 272     fi
 273   fi
 274
 275   # Start by getting the version number.  I think the libtool test already
 276   # does some of this, but throws away the result.
 277   libat_ld_is_gold=no
 278   if $LD --version 2>/dev/null | grep 'GNU gold'> /dev/null 2>&1; then
 279     libat_ld_is_gold=yes
 280   fi
 281   changequote(,)
 282   ldver=`$LD --version 2>/dev/null |
 283          sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
 284   changequote([,])
 285   libat_gnu_ld_version=`echo $ldver | \
 286          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 287
 288   # Set --gc-sections.
 289   if test "$with_gnu_ld" = "notbroken"; then
 290     # GNU ld it is!  Joy and bunny rabbits!
 291
 292     # All these tests are for C++; save the language and the compiler flags.
 293     # Need to do this so that g++ won't try to link in libstdc++
 294     ac_test_CFLAGS="${CFLAGS+set}"
 295     ac_save_CFLAGS="$CFLAGS"
 296     CFLAGS='-x c++  -Wl,--gc-sections'
 297
 298     # Check for -Wl,--gc-sections
 299     # XXX This test is broken at the moment, as symbols required for linking
 300     # are now in libsupc++ (not built yet).  In addition, this test has
 301     # cored on solaris in the past.  In addition, --gc-sections doesn't
 302     # really work at the moment (keeps on discarding used sections, first
 303     # .eh_frame and now some of the glibc sections for iconv).
 304     # Bzzzzt.  Thanks for playing, maybe next time.
 305     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 306     AC_TRY_RUN([
 307      int main(void)
 308      {
 309        try { throw 1; }
 310        catch (...) { };
 311        return 0;
 312      }
 313     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 314     if test "$ac_test_CFLAGS" = set; then
 315       CFLAGS="$ac_save_CFLAGS"
 316     else
 317       # this is the suspicious part
 318       CFLAGS=''
 319     fi
 320     if test "$ac_sectionLDflags" = "yes"; then
 321       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 322     fi
 323     AC_MSG_RESULT($ac_sectionLDflags)
 324   fi
 325
 326   # Set linker optimization flags.
 327   if test x"$with_gnu_ld" = x"yes"; then
 328     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 329   fi
 330
 331   AC_SUBST(SECTION_LDFLAGS)
 332   AC_SUBST(OPT_LDFLAGS)
 333 ])
 334
 335
 336 dnl
 337 dnl Add version tags to symbols in shared library (or not), additionally
 338 dnl marking other symbols as private/local (or not).
 339 dnl
 340 dnl --enable-symvers=style adds a version script to the linker call when
 341 dnl       creating the shared library.  The choice of version script is
 342 dnl       controlled by 'style'.
 343 dnl --disable-symvers does not.
 344 dnl  +  Usage:  LIBAT_ENABLE_SYMVERS[(DEFAULT)]
 345 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
 346 dnl       choose a default style based on linker characteristics.  Passing
 347 dnl       'no' disables versioning.
 348 dnl
 349 AC_DEFUN([LIBAT_ENABLE_SYMVERS], [
 350
 351 LIBAT_ENABLE(symvers,yes,[=STYLE],
 352   [enables symbol versioning of the shared library],
 353   [permit yes|no|gnu*|sun])
 354
 355 # If we never went through the LIBAT_CHECK_LINKER_FEATURES macro, then we
 356 # don't know enough about $LD to do tricks...
 357 AC_REQUIRE([LIBAT_CHECK_LINKER_FEATURES])
 358
 359 # Turn a 'yes' into a suitable default.
 360 if test x$enable_symvers = xyes ; then
 361   # FIXME  The following test is too strict, in theory.
 362   if test $enable_shared = no || test "x$LD" = x; then
 363     enable_symvers=no
 364   else
 365     if test $with_gnu_ld = yes ; then
 366       enable_symvers=gnu
 367     else
 368       case ${target_os} in
 369         # Sun symbol versioning exists since Solaris 2.5.
 370         solaris2.[[5-9]]* | solaris2.1[[0-9]]*)
 371           enable_symvers=sun ;;
 372         *)
 373           enable_symvers=no ;;
 374       esac
 375     fi
 376   fi
 377 fi
 378
 379 # Check if 'sun' was requested on non-Solaris 2 platforms.
 380 if test x$enable_symvers = xsun ; then
 381   case ${target_os} in
 382     solaris2*)
 383       # All fine.
 384       ;;
 385     *)
 386       # Unlikely to work.
 387       AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
 388       AC_MSG_WARN([=== you are not targetting Solaris 2.])
 389       AC_MSG_WARN([=== Symbol versioning will be disabled.])
 390       enable_symvers=no
 391       ;;
 392   esac
 393 fi
 394
 395 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
 396 if test $enable_symvers != no; then
 397   AC_MSG_CHECKING([for shared libgcc])
 398   ac_save_CFLAGS="$CFLAGS"
 399   CFLAGS=' -lgcc_s'
 400   AC_TRY_LINK(, [return 0;], libat_shared_libgcc=yes, libat_shared_libgcc=no)
 401   CFLAGS="$ac_save_CFLAGS"
 402   if test $libat_shared_libgcc = no; then
 403     cat > conftest.c <<EOF
 404 int main (void) { return 0; }
 405 EOF
 406 changequote(,)dnl
 407     libat_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 408                              -shared -shared-libgcc -o conftest.so \
 409                              conftest.c -v 2>&1 >/dev/null \
 410                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
 411 changequote([,])dnl
 412     rm -f conftest.c conftest.so
 413     if test x${libat_libgcc_s_suffix+set} = xset; then
 414       CFLAGS=" -lgcc_s$libat_libgcc_s_suffix"
 415       AC_TRY_LINK(, [return 0;], libat_shared_libgcc=yes)
 416       CFLAGS="$ac_save_CFLAGS"
 417     fi
 418   fi
 419   AC_MSG_RESULT($libat_shared_libgcc)
 420 fi
 421
 422 # For GNU ld, we need at least this version.  The format is described in
 423 # LIBAT_CHECK_LINKER_FEATURES above.
 424 libat_min_gnu_ld_version=21400
 425 # XXXXXXXXXXX libat_gnu_ld_version=21390
 426
 427 # Check to see if unspecified "yes" value can win, given results above.
 428 # Change "yes" into either "no" or a style name.
 429 if test $enable_symvers != no && test $libat_shared_libgcc = yes; then
 430   if test $with_gnu_ld = yes; then
 431     if test $libat_gnu_ld_version -ge $libat_min_gnu_ld_version ; then
 432       enable_symvers=gnu
 433     elif test $libat_ld_is_gold = yes ; then
 434       enable_symvers=gnu
 435     else
 436       # The right tools, the right setup, but too old.  Fallbacks?
 437       AC_MSG_WARN(=== Linker version $libat_gnu_ld_version is too old for)
 438       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
 439       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
 440       AC_MSG_WARN(=== $libat_min_gnu_ld_version or later and rebuild GCC.)
 441       if test $libat_gnu_ld_version -ge 21200 ; then
 442         # Globbing fix is present, proper block support is not.
 443         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
 444         dnl enable_symvers=???
 445         AC_MSG_WARN([=== Symbol versioning will be disabled.])
 446         enable_symvers=no
 447       else
 448         # 2.11 or older.
 449         AC_MSG_WARN([=== Symbol versioning will be disabled.])
 450         enable_symvers=no
 451       fi
 452     fi
 453   elif test $enable_symvers = sun; then
 454     : All interesting versions of Sun ld support sun style symbol versioning.
 455   else
 456     # just fail for now
 457     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
 458     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
 459     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
 460     AC_MSG_WARN([=== Symbol versioning will be disabled.])
 461     enable_symvers=no
 462   fi
 463 fi
 464 if test $enable_symvers = gnu; then
 465   AC_DEFINE(LIBAT_GNU_SYMBOL_VERSIONING, 1,
 466             [Define to 1 if GNU symbol versioning is used for libatomic.])
 467 fi
 468
 469 AM_CONDITIONAL(LIBAT_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
 470 AM_CONDITIONAL(LIBAT_BUILD_VERSIONED_SHLIB_GNU, test $enable_symvers = gnu)
 471 AM_CONDITIONAL(LIBAT_BUILD_VERSIONED_SHLIB_SUN, test $enable_symvers = sun)
 472 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
 473 ])