libiberty/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.13)
   4 AC_INIT(xmalloc.c)
   5
   6 # This works around the fact that libtool configuration may change LD
   7 # for this particular configuration, but some shells, instead of
   8 # keeping the changes in LD private, export them just because LD is
   9 # exported.  We don't use libtool yet, but some day we might, so...
  10 ORIGINAL_LD_FOR_MULTILIBS=$LD
  11
  12 dnl We use these options to decide which functions to include.
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  15 AC_ARG_WITH(build-subdir,
  16 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  17 AC_ARG_WITH(cross-host,
  18 [  --with-cross-host=HOST           Configuring with a cross compiler])
  19 AC_ARG_WITH(newlib,
  20 [  --with-newlib                    Configuring with newlib])
  21
  22 if test "${srcdir}" = "."; then
  23   if test -n "${with_build_subdir}"; then
  24     libiberty_topdir="${srcdir}/../.."
  25     with_target_subdir=
  26   elif test -z "${with_target_subdir}"; then
  27     libiberty_topdir="${srcdir}/.."
  28   else
  29     if test "${with_target_subdir}" != "."; then
  30       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  31     else
  32       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  33     fi
  34   fi
  35 else
  36   libiberty_topdir="${srcdir}/.."
  37 fi
  38 AC_SUBST(libiberty_topdir)
  39 AC_CONFIG_AUX_DIR($libiberty_topdir)
  40
  41 dnl Very limited version of automake's enable-maintainer-mode
  42
  43 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  44   dnl maintainer-mode is disabled by default
  45   AC_ARG_ENABLE(maintainer-mode,
  46 [  --enable-maintainer-mode
  47                           enable make rules and dependencies not useful
  48                           (and sometimes confusing) to the casual installer],
  49       maintainer_mode=$enableval,
  50       maintainer_mode=no)
  51
  52 AC_MSG_RESULT($maintainer_mode)
  53
  54 if test "$maintainer_mode" = "yes"; then
  55   MAINT=''
  56   NOTMAINT='#'
  57 else
  58   MAINT='#'
  59   NOTMAINT=''
  60 fi
  61 AC_SUBST(MAINT)dnl
  62 AC_SUBST(NOTMAINT)dnl
  63
  64 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  65 # rely on it - libiberty is built before texinfo.
  66 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  67 if test "x$MAKEINFO" = "x"; then
  68     MAKEINFO="@echo makeinfo missing; true"
  69     BUILD_INFO=
  70 else
  71     BUILD_INFO=info
  72     case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  73       x*\ [[1-3]].* )
  74         MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is too old. Info documentation will not be built.])
  78         ;;
  79     esac
  80 fi
  81 AC_SUBST(MAKEINFO)
  82 AC_SUBST(BUILD_INFO)
  83
  84 AC_CHECK_PROG(PERL, perl, perl, )
  85 if test x"$PERL" = x""; then
  86   HAVE_PERL='#'
  87 else
  88   HAVE_PERL=''
  89 fi
  90 AC_SUBST(HAVE_PERL)
  91
  92 AC_CANONICAL_HOST
  93
  94 dnl When we start using automake:
  95 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
  96
  97 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  98 dnl to call AC_CHECK_PROG.
  99 AC_CHECK_TOOL(AR, ar)
 100 AC_CHECK_TOOL(RANLIB, ranlib, :)
 101
 102 LIB_AC_PROG_CC
 103
 104 AC_PROG_CC_C_O
 105 # autoconf is lame and doesn't give us any substitution variable for this.
 106 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 107   NO_MINUS_C_MINUS_O=yes
 108 else
 109   OUTPUT_OPTION='-o $@'
 110 fi
 111 AC_SUBST(NO_MINUS_C_MINUS_O)
 112 AC_SUBST(OUTPUT_OPTION)
 113
 114 AC_ISC_POSIX
 115 AC_C_CONST
 116 AC_C_INLINE
 117
 118 dnl When we start using libtool:
 119 dnl Default to a non shared library.  This may be overridden by the
 120 dnl configure option --enable-shared.
 121 dnl AM_DISABLE_SHARED
 122
 123 dnl When we start using libtool:
 124 dnl AM_PROG_LIBTOOL
 125
 126 dnl When we start using automake:
 127 dnl AM_CONFIG_HEADER(config.h:config.in)
 128 AC_CONFIG_HEADER(config.h:config.in)
 129
 130 dnl When we start using automake:
 131 dnl AM_MAINTAINER_MODE
 132 dnl AC_EXEEXT
 133
 134 dnl When we start using automake:
 135 dnl AM_PROG_INSTALL
 136 AC_PROG_INSTALL
 137
 138 . ${srcdir}/config.table
 139 host_makefile_frag=${frag}
 140 AC_SUBST_FILE(host_makefile_frag)
 141
 142 # It's OK to check for header files.  Although the compiler may not be
 143 # able to link anything, it had better be able to at least compile
 144 # something.
 145 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h)
 146 AC_HEADER_SYS_WAIT
 147 AC_HEADER_TIME
 148
 149 libiberty_AC_DECLARE_ERRNO
 150
 151 AC_CHECK_TYPE(uintptr_t, unsigned long)
 152
 153 if test $ac_cv_type_uintptr_t = yes
 154 then
 155   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 156 fi
 157
 158 AC_TYPE_PID_T
 159
 160 # This is the list of functions which libiberty will provide if they
 161 # are not available on the host.
 162
 163 funcs="asprintf"
 164 funcs="$funcs atexit"
 165 funcs="$funcs basename"
 166 funcs="$funcs bcmp"
 167 funcs="$funcs bcopy"
 168 funcs="$funcs bsearch"
 169 funcs="$funcs bzero"
 170 funcs="$funcs calloc"
 171 funcs="$funcs clock"
 172 funcs="$funcs ffs"
 173 funcs="$funcs getcwd"
 174 funcs="$funcs getpagesize"
 175 funcs="$funcs index"
 176 funcs="$funcs insque"
 177 funcs="$funcs memchr"
 178 funcs="$funcs memcmp"
 179 funcs="$funcs memcpy"
 180 funcs="$funcs memmove"
 181 funcs="$funcs memset"
 182 funcs="$funcs mkstemps"
 183 funcs="$funcs putenv"
 184 funcs="$funcs random"
 185 funcs="$funcs rename"
 186 funcs="$funcs rindex"
 187 funcs="$funcs setenv"
 188 funcs="$funcs sigsetmask"
 189 funcs="$funcs strcasecmp"
 190 funcs="$funcs strchr"
 191 funcs="$funcs strdup"
 192 funcs="$funcs strncasecmp"
 193 funcs="$funcs strrchr"
 194 funcs="$funcs strstr"
 195 funcs="$funcs strtod"
 196 funcs="$funcs strtol"
 197 funcs="$funcs strtoul"
 198 funcs="$funcs tmpnam"
 199 funcs="$funcs vasprintf"
 200 funcs="$funcs vfprintf"
 201 funcs="$funcs vprintf"
 202 funcs="$funcs vsprintf"
 203 funcs="$funcs waitpid"
 204
 205 # Also in the old function.def file: alloca, vfork, getopt.
 206
 207 vars="sys_errlist sys_nerr sys_siglist"
 208
 209 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 210
 211 # These are neither executed nor required, but they help keep
 212 # autoheader happy without adding a bunch of text to acconfig.h.
 213 if test "x" = "y"; then
 214   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock)
 215   AC_CHECK_FUNCS(getcwd getpagesize index insque mkstemps memchr memcmp memcpy)
 216   AC_CHECK_FUNCS(memmove memset putenv random rename rindex sigsetmask)
 217   AC_CHECK_FUNCS(strcasecmp setenv strchr strdup strncasecmp strrchr strstr)
 218   AC_CHECK_FUNCS(strtod strtol strtoul tmpnam vasprintf vfprintf vprintf)
 219   AC_CHECK_FUNCS(vsprintf waitpid getrusage on_exit psignal strerror strsignal)
 220   AC_CHECK_FUNCS(sysconf times sbrk gettimeofday ffs)
 221   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 222   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 223   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 224 fi
 225
 226 # For each of these functions, if the host does not provide the
 227 # function we want to put FN.o in LIBOBJS, and if the host does
 228 # provide the function, we want to define HAVE_FN in config.h.
 229
 230 setobjs=
 231 CHECK=
 232 target_header_dir=
 233 if test -n "${with_target_subdir}"; then
 234
 235   # We are being configured as a target library.  AC_REPLACE_FUNCS
 236   # may not work correctly, because the compiler may not be able to
 237   # link executables.  Note that we may still be being configured
 238   # native.
 239
 240   # If we are being configured for newlib, we know which functions
 241   # newlib provide and which ones we will be expected to provide.
 242
 243   if test "x${with_newlib}" = "xyes"; then
 244     LIBOBJS="asprintf.o basename.o insque.o random.o strdup.o vasprintf.o"
 245
 246     for f in $funcs; do
 247       case "$f" in
 248         asprintf | basename | insque | random | strdup | vasprintf)
 249           ;;
 250         *)
 251           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 252           AC_DEFINE_UNQUOTED($n)
 253           ;;
 254       esac
 255     done
 256
 257     # newlib doesnt provide any of the variables in $vars, so we
 258     # dont have to check them here.
 259
 260     # Of the functions in $checkfuncs, newlib only has strerror.
 261     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 262
 263     setobjs=yes
 264
 265   fi
 266
 267   # We may wish to install the target headers somewhere.
 268   AC_ARG_ENABLE(install-libiberty,
 269   [  --enable-install-libiberty       Install headers for end users],
 270   enable_install_libiberty=$enableval,
 271   enable_install_libiberty=no)dnl
 272
 273   # Option parsed, now set things appropriately.
 274   case x"$enable_install_libiberty" in
 275     xyes|x)
 276       target_header_dir=libiberty
 277       ;;
 278     xno)
 279       target_header_dir=
 280       ;;
 281     *)
 282       # This could be sanity-checked in various ways...
 283       target_header_dir="${enable_install_libiberty}"
 284       ;;
 285   esac
 286
 287
 288 else
 289
 290    # Not a target library, so we set things up to run the test suite.
 291    CHECK=check-cplus-dem
 292
 293 fi
 294
 295 AC_SUBST(CHECK)
 296 AC_SUBST(target_header_dir)
 297
 298 case "${host}" in
 299   *-*-cygwin* | *-*-mingw*)
 300     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_ERRLIST)
 301     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_NERR)
 302     ;;
 303 esac
 304
 305 if test -z "${setobjs}"; then
 306   case "${host}" in
 307
 308   *-*-vxworks*)
 309     # Handle VxWorks configuration specially, since on VxWorks the
 310     # libraries are actually on the target board, not in the file
 311     # system.
 312     LIBOBJS="basename.o getpagesize.o insque.o random.o strcasecmp.o"
 313     LIBOBJS="$LIBOBJS strncasecmp.o strdup.o vfork.o waitpid.o vasprintf.o"
 314     for f in $funcs; do
 315       case "$f" in
 316         basename | getpagesize | insque | random | strcasecmp)
 317           ;;
 318         strncasecmp | strdup | vfork | waitpid | vasprintf)
 319           ;;
 320         *)
 321           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 322           AC_DEFINE_UNQUOTED($n)
 323           ;;
 324       esac
 325     done
 326
 327     # VxWorks doesn't provide any of the variables in $vars, so we
 328     # don't have to check them here.
 329
 330     # Of the functions in $checkfuncs, VxWorks only has strerror.
 331     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 332
 333     setobjs=yes
 334     ;;
 335
 336   esac
 337 fi
 338
 339 if test -z "${setobjs}"; then
 340
 341   case "${host}" in
 342
 343   *-*-cygwin*)
 344     # The Cygwin library actually uses a couple of files from
 345     # libiberty when it is built.  If we are building a native
 346     # Cygwin, and we run the tests, we will appear to have these
 347     # files.  However, when we go on to build winsup, we will wind up
 348     # with a library which does not have the files, since they should
 349     # have come from libiberty.
 350
 351     # We handle this by removing the functions the winsup library
 352     # provides from our shell variables, so that they appear to be
 353     # missing.
 354
 355     # DJ - only if we're *building* cygwin, not just building *with* cygwin
 356
 357     if test -n "${with_target_subdir}"
 358     then
 359       funcs="`echo $funcs | sed -e 's/random//'`"
 360       LIBOBJS="$LIBOBJS random.o"
 361       vars="`echo $vars | sed -e 's/sys_siglist//'`"
 362       checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 363     fi
 364     ;;
 365
 366   *-*-mingw32*)
 367     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 368     # macros, so the test below won't find them.
 369     libiberty_cv_var_sys_nerr=yes
 370     libiberty_cv_var_sys_errlist=yes
 371     ;;
 372
 373   *-*-uwin*)
 374     # Under some versions of uwin, vfork is notoriously buggy and the test
 375     # can hang configure; on other versions, vfork exists just as a stub.
 376     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 377     ac_cv_func_vfork_works=no
 378     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 379     # macros (actually, these are imported from a DLL, but the end effect
 380     # is the same), so the test below won't find them.
 381     libiberty_cv_var_sys_nerr=yes
 382     libiberty_cv_var_sys_errlist=yes
 383     ;;
 384
 385   *-*-*vms*)
 386     # Under VMS, vfork works very different than on Unix. The standard test
 387     # won't work, and it isn't easily adaptable. It makes more sense to
 388     # just force it.
 389     ac_cv_func_vfork_works=yes
 390     ;;
 391
 392   esac
 393
 394   # We haven't set the list of objects yet.  Use the standard autoconf
 395   # tests.  This will only work if the compiler works.
 396   AC_PROG_CC_WORKS
 397   AC_REPLACE_FUNCS($funcs)
 398   libiberty_AC_FUNC_C_ALLOCA
 399   AC_FUNC_VFORK
 400   if test $ac_cv_func_vfork_works = no; then
 401     LIBOBJS="$LIBOBJS vfork.o"
 402   fi
 403   # We only need _doprnt if we might use it to implement v*printf.
 404   if test $ac_cv_func_vprintf != yes \
 405      || test $ac_cv_func_vfprintf != yes \
 406      || test $ac_cv_func_vsprintf != yes; then
 407     AC_REPLACE_FUNCS(_doprnt)
 408   else
 409     AC_CHECK_FUNCS(_doprnt)
 410   fi
 411
 412   for v in $vars; do
 413     AC_MSG_CHECKING([for $v])
 414     AC_CACHE_VAL(libiberty_cv_var_$v,
 415       [AC_TRY_LINK([int *p;], [extern int $v []; p = $v;],
 416                    [eval "libiberty_cv_var_$v=yes"],
 417                    [eval "libiberty_cv_var_$v=no"])])
 418     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 419       AC_MSG_RESULT(yes)
 420       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 421       AC_DEFINE_UNQUOTED($n)
 422     else
 423       AC_MSG_RESULT(no)
 424     fi
 425   done
 426   AC_CHECK_FUNCS($checkfuncs)
 427 fi
 428
 429 # Figure out which version of pexecute to use.
 430 case "${host}" in
 431      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32.o  ;;
 432      *-*-msdosdjgpp*)           pexecute=pex-djgpp.o  ;;
 433      *-*-msdos*)                pexecute=pex-msdos.o  ;;
 434      *-*-os2-emx*)              pexecute=pex-os2.o    ;;
 435      *)                         pexecute=pex-unix.o   ;;
 436 esac
 437 AC_SUBST(pexecute)
 438
 439 libiberty_AC_FUNC_STRNCMP
 440
 441 # Install a library built with a cross compiler in $(tooldir) rather
 442 # than $(libdir).
 443 if test -z "${with_cross_host}"; then
 444   INSTALL_DEST=libdir
 445 else
 446   INSTALL_DEST=tooldir
 447 fi
 448 AC_SUBST(INSTALL_DEST)
 449
 450 # We need multilib support, but only if configuring for the target.
 451 AC_OUTPUT(Makefile testsuite/Makefile,
 452 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 453 if test -n "$CONFIG_FILES"; then
 454   if test -n "${with_build_subdir}" || test -n "${with_target_subdir}"; then
 455     # FIXME: We shouldn't need to set ac_file
 456     ac_file=Makefile
 457     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 458     . ${libiberty_topdir}/config-ml.in
 459   fi
 460 fi],
 461 srcdir=${srcdir}
 462 host=${host}
 463 target=${target}
 464 with_target_subdir=${with_target_subdir}
 465 with_build_subdir=${with_build_subdir}
 466 with_multisubdir=${with_multisubdir}
 467 ac_configure_args="--enable-multilib ${ac_configure_args}"
 468 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 469 libiberty_topdir=${libiberty_topdir}
 470 )