gcc/ada/s-carsi8.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                   GNU ADA RUNTIME LIBRARY COMPONENTS                     --
   4 --                                                                          --
   5 --         S Y S T E M . C O M P A R E _ A R R A Y _ S I G N E D _ 8        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System.Address_Operations; use System.Address_Operations;
  35
  36 with Unchecked_Conversion;
  37
  38 package body System.Compare_Array_Signed_8 is
  39
  40    type Word is mod 2 ** 32;
  41    --  Used to process operands by words
  42
  43    type Big_Words is array (Natural) of Word;
  44    type Big_Words_Ptr is access Big_Words;
  45    --  Array type used to access by words
  46
  47    type Byte is range -128 .. +127;
  48    for Byte'Size use 8;
  49    --  Used to process operands by bytes
  50
  51    type Big_Bytes is array (Natural) of Byte;
  52    type Big_Bytes_Ptr is access Big_Bytes;
  53    --  Array type used to access by bytes
  54
  55    function To_Big_Words is new
  56      Unchecked_Conversion (System.Address, Big_Words_Ptr);
  57
  58    function To_Big_Bytes is new
  59      Unchecked_Conversion (System.Address, Big_Bytes_Ptr);
  60
  61    ----------------------
  62    -- Compare_Array_S8 --
  63    ----------------------
  64
  65    function Compare_Array_S8
  66      (Left      : System.Address;
  67       Right     : System.Address;
  68       Left_Len  : Natural;
  69       Right_Len : Natural) return Integer
  70    is
  71       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
  72
  73    begin
  74       --  If operands are non-aligned, or length is too short, go by bytes
  75
  76       if ModA (OrA (Left, Right), 4) /= 0 or else Compare_Len < 4 then
  77          return Compare_Array_S8_Unaligned (Left, Right, Left_Len, Right_Len);
  78       end if;
  79
  80       --  Here we can go by words
  81
  82       declare
  83          LeftP  : constant Big_Words_Ptr := To_Big_Words (Left);
  84          RightP : constant Big_Words_Ptr := To_Big_Words (Right);
  85          Clen4  : constant Natural       := Compare_Len / 4 - 1;
  86          Clen4F : constant Natural       := Clen4 * 4;
  87
  88       begin
  89          for J in 0 .. Clen4 loop
  90             if LeftP (J) /= RightP (J) then
  91                return Compare_Array_S8_Unaligned
  92                         (AddA (Left,  Address (4 * J)),
  93                          AddA (Right, Address (4 * J)),
  94                          4, 4);
  95             end if;
  96          end loop;
  97
  98          return Compare_Array_S8_Unaligned
  99                   (AddA (Left,  Address (Clen4F)),
 100                    AddA (Right, Address (Clen4F)),
 101                    Left_Len  - Clen4F,
 102                    Right_Len - Clen4F);
 103       end;
 104    end Compare_Array_S8;
 105
 106    --------------------------------
 107    -- Compare_Array_S8_Unaligned --
 108    --------------------------------
 109
 110    function Compare_Array_S8_Unaligned
 111      (Left      : System.Address;
 112       Right     : System.Address;
 113       Left_Len  : Natural;
 114       Right_Len : Natural) return Integer
 115    is
 116       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
 117
 118       LeftP  : constant Big_Bytes_Ptr := To_Big_Bytes (Left);
 119       RightP : constant Big_Bytes_Ptr := To_Big_Bytes (Right);
 120
 121    begin
 122       for J in 0 .. Compare_Len - 1 loop
 123          if LeftP (J) /= RightP (J) then
 124             if LeftP (J) > RightP (J) then
 125                return +1;
 126             else
 127                return -1;
 128             end if;
 129          end if;
 130       end loop;
 131
 132       if Left_Len = Right_Len then
 133          return 0;
 134       elsif Left_Len > Right_Len then
 135          return +1;
 136       else
 137          return -1;
 138       end if;
 139    end Compare_Array_S8_Unaligned;
 140
 141 end System.Compare_Array_Signed_8;