gcc/ada/a-cohama.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --            A D A . C O N T A I N E R S . H A S H E D _ M A P S           --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2005 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- This unit was originally developed by Matthew J Heaney.                  --
  34 ------------------------------------------------------------------------------
  35
  36 with Ada.Containers.Hash_Tables;
  37 with Ada.Streams;
  38 with Ada.Finalization;
  39
  40 generic
  41    type Key_Type is private;
  42
  43    type Element_Type is private;
  44
  45    with function Hash (Key : Key_Type) return Hash_Type;
  46
  47    with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
  48
  49    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  50
  51 package Ada.Containers.Hashed_Maps is
  52    pragma Preelaborate;
  53
  54    type Map is tagged private;
  55
  56    type Cursor is private;
  57
  58    Empty_Map : constant Map;
  59
  60    No_Element : constant Cursor;
  61
  62    function "=" (Left, Right : Map) return Boolean;
  63
  64    function Length (Container : Map) return Count_Type;
  65
  66    function Is_Empty (Container : Map) return Boolean;
  67
  68    procedure Clear (Container : in out Map);
  69
  70    function Key (Position : Cursor) return Key_Type;
  71
  72    function Element (Position : Cursor) return Element_Type;
  73
  74    procedure Query_Element
  75      (Position : Cursor;
  76       Process  : not null access
  77                    procedure (Key : Key_Type; Element : Element_Type));
  78
  79    procedure Update_Element
  80      (Position : Cursor;
  81       Process  : not null access
  82                    procedure (Key : Key_Type; Element : in out Element_Type));
  83
  84    procedure Replace_Element (Position : Cursor; By : Element_Type);
  85
  86    procedure Move (Target : in out Map; Source : in out Map);
  87
  88    procedure Insert
  89      (Container : in out Map;
  90       Key       : Key_Type;
  91       New_Item  : Element_Type;
  92       Position  : out Cursor;
  93       Inserted  : out Boolean);
  94
  95    procedure Insert
  96      (Container : in out Map;
  97       Key       : Key_Type;
  98       Position  : out Cursor;
  99       Inserted  : out Boolean);
 100
 101    procedure Insert
 102      (Container : in out Map;
 103       Key       : Key_Type;
 104       New_Item  : Element_Type);
 105
 106    procedure Include
 107      (Container : in out Map;
 108       Key       : Key_Type;
 109       New_Item  : Element_Type);
 110
 111    procedure Replace
 112      (Container : in out Map;
 113       Key       : Key_Type;
 114       New_Item  : Element_Type);
 115
 116    procedure Delete (Container : in out Map; Key : Key_Type);
 117
 118    procedure Delete (Container : in out Map; Position : in out Cursor);
 119
 120    procedure Exclude (Container : in out Map; Key : Key_Type);
 121
 122    function Contains (Container : Map; Key : Key_Type) return Boolean;
 123
 124    function Find (Container : Map; Key : Key_Type) return Cursor;
 125
 126    function Element (Container : Map; Key : Key_Type) return Element_Type;
 127
 128    function First (Container : Map) return Cursor;
 129
 130    function Next (Position : Cursor) return Cursor;
 131
 132    procedure Next (Position : in out Cursor);
 133
 134    function Has_Element (Position : Cursor) return Boolean;
 135
 136    function Equivalent_Keys (Left, Right : Cursor) return Boolean;
 137
 138    function Equivalent_Keys (Left : Cursor; Right : Key_Type) return Boolean;
 139
 140    function Equivalent_Keys (Left : Key_Type; Right : Cursor) return Boolean;
 141
 142    procedure Iterate
 143      (Container : Map;
 144       Process   : not null access procedure (Position : Cursor));
 145
 146    function Capacity (Container : Map) return Count_Type;
 147
 148    procedure Reserve_Capacity (Container : in out Map;
 149                                Capacity  : Count_Type);
 150
 151 private
 152    pragma Inline ("=");
 153    pragma Inline (Length);
 154    pragma Inline (Is_Empty);
 155    pragma Inline (Clear);
 156    pragma Inline (Key);
 157    pragma Inline (Element);
 158    pragma Inline (Move);
 159    pragma Inline (Contains);
 160    pragma Inline (Capacity);
 161    pragma Inline (Reserve_Capacity);
 162    pragma Inline (Has_Element);
 163    pragma Inline (Equivalent_Keys);
 164
 165    type Node_Type;
 166    type Node_Access is access Node_Type;
 167
 168    type Node_Type is limited record
 169       Key     : Key_Type;
 170       Element : Element_Type;
 171       Next    : Node_Access;
 172    end record;
 173
 174    package HT_Types is new Hash_Tables.Generic_Hash_Table_Types
 175      (Node_Type,
 176       Node_Access);
 177
 178    type Map is new Ada.Finalization.Controlled with record
 179       HT : HT_Types.Hash_Table_Type;
 180    end record;
 181
 182    use HT_Types;
 183    use Ada.Finalization;
 184
 185    procedure Adjust (Container : in out Map);
 186
 187    procedure Finalize (Container : in out Map);
 188
 189    use Ada.Streams;
 190
 191    procedure Write
 192      (Stream    : access Root_Stream_Type'Class;
 193       Container : Map);
 194
 195    for Map'Write use Write;
 196
 197    procedure Read
 198      (Stream    : access Root_Stream_Type'Class;
 199       Container : out Map);
 200
 201    for Map'Read use Read;
 202
 203    Empty_Map : constant Map := (Controlled with HT => (null, 0, 0, 0));
 204
 205    type Map_Access is access constant Map;
 206    for Map_Access'Storage_Size use 0;
 207
 208    type Cursor is
 209       record
 210          Container : Map_Access;
 211          Node      : Node_Access;
 212       end record;
 213
 214    No_Element : constant Cursor := (Container => null, Node => null);
 215
 216 end Ada.Containers.Hashed_Maps;