gcc/ada/a-cihama.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                      A D A . C O N T A I N E R S .                       --
   6 --               I N D E F I N I T E _ H A S H E D _ M A P S                --
   7 --                                                                          --
   8 --                                 S p e c                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2005 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  25 -- Boston, MA 02110-1301, USA.                                              --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- This unit was originally developed by Matthew J Heaney.                  --
  35 ------------------------------------------------------------------------------
  36
  37 with Ada.Containers.Hash_Tables;
  38 with Ada.Streams;
  39 with Ada.Finalization;
  40
  41 generic
  42    type Key_Type (<>) is private;
  43    type Element_Type (<>) is private;
  44
  45    with function Hash (Key : Key_Type) return Hash_Type;
  46    with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
  47    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  48
  49 package Ada.Containers.Indefinite_Hashed_Maps is
  50    pragma Preelaborate;
  51
  52    type Map is tagged private;
  53    type Cursor is private;
  54
  55    Empty_Map  : constant Map;
  56    No_Element : constant Cursor;
  57
  58    function "=" (Left, Right : Map) return Boolean;
  59
  60    function Length (Container : Map) return Count_Type;
  61
  62    function Is_Empty (Container : Map) return Boolean;
  63
  64    procedure Clear (Container : in out Map);
  65
  66    function Key (Position : Cursor) return Key_Type;
  67
  68    function Element (Position : Cursor) return Element_Type;
  69
  70    procedure Query_Element
  71      (Position : Cursor;
  72       Process  : not null access procedure (Key     : Key_Type;
  73                                             Element : Element_Type));
  74
  75    procedure Update_Element
  76      (Position : Cursor;
  77       Process  : not null access procedure (Key     : Key_Type;
  78                                             Element : in out Element_Type));
  79
  80    procedure Replace_Element
  81      (Position : Cursor;
  82       By       : Element_Type);
  83
  84    procedure Move (Target : in out Map; Source : in out Map);
  85
  86    procedure Insert
  87      (Container : in out Map;
  88       Key       : Key_Type;
  89       New_Item  : Element_Type;
  90       Position  : out Cursor;
  91       Inserted  : out Boolean);
  92
  93    procedure Insert
  94      (Container : in out Map;
  95       Key       : Key_Type;
  96       New_Item  : Element_Type);
  97
  98    procedure Include
  99      (Container : in out Map;
 100       Key       : Key_Type;
 101       New_Item  : Element_Type);
 102
 103    procedure Replace
 104      (Container : in out Map;
 105       Key       : Key_Type;
 106       New_Item  : Element_Type);
 107
 108    procedure Delete
 109      (Container : in out Map;
 110       Key       : Key_Type);
 111
 112    procedure Delete
 113      (Container : in out Map;
 114       Position  : in out Cursor);
 115
 116    procedure Exclude
 117      (Container : in out Map;
 118       Key       : Key_Type);
 119
 120    function Contains
 121      (Container : Map;
 122       Key       : Key_Type) return Boolean;
 123
 124    function Find
 125      (Container : Map;
 126       Key       : Key_Type) return Cursor;
 127
 128    function Element
 129      (Container : Map;
 130       Key       : Key_Type) return Element_Type;
 131
 132    function First (Container : Map) return Cursor;
 133
 134    function Next (Position : Cursor) return Cursor;
 135
 136    procedure Next (Position : in out Cursor);
 137
 138    function Has_Element (Position : Cursor) return Boolean;
 139
 140    function Equivalent_Keys (Left, Right : Cursor)
 141      return Boolean;
 142
 143    function Equivalent_Keys
 144      (Left  : Cursor;
 145       Right : Key_Type) return Boolean;
 146
 147    function Equivalent_Keys
 148      (Left  : Key_Type;
 149       Right : Cursor) return Boolean;
 150
 151    procedure Iterate
 152      (Container : Map;
 153       Process   : not null access procedure (Position : Cursor));
 154
 155    function Capacity (Container : Map) return Count_Type;
 156
 157    procedure Reserve_Capacity
 158      (Container : in out Map;
 159       Capacity  : Count_Type);
 160
 161 private
 162    pragma Inline ("=");
 163    pragma Inline (Length);
 164    pragma Inline (Is_Empty);
 165    pragma Inline (Clear);
 166    pragma Inline (Key);
 167    pragma Inline (Element);
 168    pragma Inline (Move);
 169    pragma Inline (Contains);
 170    pragma Inline (Capacity);
 171    pragma Inline (Reserve_Capacity);
 172    pragma Inline (Has_Element);
 173    pragma Inline (Equivalent_Keys);
 174
 175    type Node_Type;
 176    type Node_Access is access Node_Type;
 177
 178    type Key_Access is access Key_Type;
 179    type Element_Access is access Element_Type;
 180
 181    type Node_Type is limited record
 182       Key     : Key_Access;
 183       Element : Element_Access;
 184       Next    : Node_Access;
 185    end record;
 186
 187    package HT_Types is new Hash_Tables.Generic_Hash_Table_Types
 188      (Node_Type,
 189       Node_Access);
 190
 191    type Map is new Ada.Finalization.Controlled with record
 192       HT : HT_Types.Hash_Table_Type;
 193    end record;
 194
 195    use HT_Types;
 196    use Ada.Finalization;
 197
 198    procedure Adjust (Container : in out Map);
 199
 200    procedure Finalize (Container : in out Map);
 201
 202    type Map_Access is access constant Map;
 203    for Map_Access'Storage_Size use 0;
 204
 205    type Cursor is
 206       record
 207          Container : Map_Access;
 208          Node      : Node_Access;
 209       end record;
 210
 211    No_Element : constant Cursor :=
 212      (Container => null,
 213       Node      => null);
 214
 215    use Ada.Streams;
 216
 217    procedure Write
 218      (Stream    : access Root_Stream_Type'Class;
 219       Container : Map);
 220
 221    for Map'Write use Write;
 222
 223    procedure Read
 224      (Stream    : access Root_Stream_Type'Class;
 225       Container : out Map);
 226
 227    for Map'Read use Read;
 228
 229    Empty_Map : constant Map := (Controlled with HT => (null, 0, 0, 0));
 230
 231 end Ada.Containers.Indefinite_Hashed_Maps;