libstdc++-v3/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT(package-unused, version-unused,, libstdc++)
   6 AC_CONFIG_SRCDIR(src/ios.cc)
   7 AC_CONFIG_HEADER(config.h)
   8
   9 # This works around the fact that libtool configuration may change LD
  10 # for this particular configuration, but some shells, instead of
  11 # keeping the changes in LD private, export them just because LD is
  12 # exported.  Only used at the end of this file.
  13 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  14
  15 # For libtool versioning info, format is CURRENT:REVISION:AGE
  16 libtool_VERSION=6:0:0
  17 AC_SUBST(libtool_VERSION)
  18
  19 # Find the rest of the source tree framework.
  20 GLIBCXX_TOPREL_CONFIGURE
  21
  22 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  23 #
  24 # You will slowly go insane if you do not grok the following fact:  when
  25 # building v3 as part of the compiler, the top-level /target/ becomes the
  26 # library's /host/.  configure then causes --target to default to --host,
  27 # exactly like any other package using autoconf.  Therefore, 'target' and
  28 # 'host' will always be the same.  This makes sense both for native and
  29 # cross compilers, just think about it for a little while.  :-)
  30 #
  31 # Also, if v3 is being configured as part of a cross compiler, the top-level
  32 # configure script will pass the "real" host as $with_cross_host.
  33 #
  34 # Do not delete or change the following two lines.  For why, see
  35 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  36 AC_CANONICAL_SYSTEM
  37 target_alias=${target_alias-$host_alias}
  38
  39 # Handy for debugging:
  40 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  41
  42 if test "$build" != "$host"; then
  43   # We are being configured with some form of cross compiler.
  44   GLIBCXX_IS_NATIVE=false
  45   GCC_NO_EXECUTABLES
  46 else
  47   GLIBCXX_IS_NATIVE=true
  48 fi
  49
  50 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  51 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  52 #  1.x:  minimum required version
  53 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  54 #              of other PACKAGE_* variables will, however, and there's nothing
  55 #              we can do about that; they come from AC_INIT).
  56 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  57 #            file in the top srcdir, etc, etc), so stop complaining.
  58 #  no-dependencies:  turns off auto dependency generation (just for now)
  59 #  -Wall:  turns on all automake warnings...
  60 #  -Wno-portability:  ...except this one, since GNU make is now required.
  61 AM_INIT_AUTOMAKE([1.7.6 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  62
  63 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  64 # up critical shell variables.
  65 GLIBCXX_CONFIGURE
  66
  67 #AC_MSG_NOTICE([====== Starting libtool configuration])
  68 AC_LIBTOOL_DLOPEN
  69 AM_PROG_LIBTOOL
  70 AC_SUBST(enable_shared)
  71 AC_SUBST(enable_static)
  72 #AC_MSG_NOTICE([====== Finished libtool configuration]) ; sleep 10
  73
  74 # Possibly disable most of the library.
  75 ## XXX Consider skipping unncessary tests altogether in this case, rather
  76 ## than just ignoring the results.  Faster /and/ more correct, win win.
  77 GLIBCXX_ENABLE_HOSTED
  78
  79 # Check for support bits and g++ features that don't require linking.
  80 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  81 GLIBCXX_ENABLE_PCH($is_hosted)
  82
  83 # Enable all the variable C++ runtime options.
  84 # NB: C_MBCHAR must come early.
  85 GLIBCXX_ENABLE_CSTDIO
  86 GLIBCXX_ENABLE_CLOCALE
  87 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
  88 GLIBCXX_ENABLE_C_MBCHAR([yes])
  89 GLIBCXX_ENABLE_C99([yes])
  90 GLIBCXX_ENABLE_LONG_LONG([yes])
  91 GLIBCXX_ENABLE_THREADS
  92 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
  93 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
  94 GLIBCXX_ENABLE_DEBUG([no])
  95 GLIBCXX_ENABLE_CXX_FLAGS
  96
  97 # No surprises, no surprises...
  98 if test $atomicity_dir = cpu/generic ; then
  99   AC_MSG_WARN([No native atomic operations are provided for this platform.])
 100   if test $target_thread_file = single; then
 101     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
 102     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
 103   else
 104     AC_MSG_WARN([They will be faked using a mutex.])
 105     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
 106   fi
 107 fi
 108
 109
 110 if $GLIBCXX_IS_NATIVE; then
 111
 112   # We can do more elaborate tests that assume a working linker.
 113   CANADIAN=no
 114
 115   # Check for available headers.
 116   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 117   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 118   sys/types.h])
 119
 120   GLIBCXX_CHECK_COMPILER_FEATURES
 121   GLIBCXX_CHECK_LINKER_FEATURES
 122   GLIBCXX_CHECK_MATH_SUPPORT
 123   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 124   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 125   GLIBCXX_CHECK_WCHAR_T_SUPPORT
 126   GLIBCXX_CHECK_STDLIB_SUPPORT
 127
 128   # For showmanyc_helper().
 129   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 130   GLIBCXX_CHECK_POLL
 131   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 132
 133   # For xsputn_2().
 134   AC_CHECK_HEADERS(sys/uio.h)
 135   GLIBCXX_CHECK_WRITEV
 136
 137   # For the __streamoff_base_type typedef.
 138   GLIBCXX_CHECK_INT64_T
 139
 140   # For LFS support.
 141   GLIBCXX_CHECK_LFS
 142
 143   AC_LC_MESSAGES
 144
 145   AC_TRY_COMPILE(
 146     [#include <setjmp.h>],
 147     [sigjmp_buf env;
 148      while (! sigsetjmp (env, 1))
 149        siglongjmp (env, 1);
 150     ],
 151     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 152
 153   AC_FUNC_MMAP
 154
 155 else
 156
 157   # This lets us hard-code the functionality we know we'll have in the cross
 158   # target environment.  "Let" is a sugar-coated word placed on an especially
 159   # dull and tedious hack, actually.
 160   #
 161   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 162   # that involve linking, can't be used:
 163   #    "cannot open sim-crt0.o"
 164   #    "cannot open crt0.o"
 165   # etc.  All this is because there currently exists no unified, consistent
 166   # way for top level CC information to be passed down to target directories:
 167   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 168   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 169   # crosses can be removed.
 170
 171   # If Canadian cross, then don't pick up tools from the build directory.
 172   # Used only in GLIBCXX_EXPORT_INCLUDES.
 173   if test -n "$with_cross_host" &&
 174      test x"$build_alias" != x"$with_cross_host" &&
 175      test x"$build" != x"$target";
 176   then
 177     CANADIAN=yes
 178   else
 179     CANADIAN=no
 180   fi
 181
 182   # Construct crosses by hand, eliminating bits that need ld...
 183   # GLIBCXX_CHECK_COMPILER_FEATURES
 184   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 185   # GLIBCXX_CHECK_MATH_SUPPORT
 186
 187   # First, test for "known" system libraries.  We may be using newlib even
 188   # on a hosted environment.
 189   if test "x${with_newlib}" = "xyes"; then
 190     os_include_dir="os/newlib"
 191     AC_DEFINE(HAVE_HYPOT)
 192
 193     # GLIBCXX_CHECK_STDLIB_SUPPORT
 194     AC_DEFINE(HAVE_STRTOF)
 195     AC_DEFINE(HAVE_STRTOLD)
 196     # AC_FUNC_MMAP
 197     AC_DEFINE(HAVE_MMAP)
 198
 199     AC_DEFINE(HAVE_ACOSF)
 200     AC_DEFINE(HAVE_ASINF)
 201     AC_DEFINE(HAVE_ATAN2F)
 202     AC_DEFINE(HAVE_ATANF)
 203     AC_DEFINE(HAVE_CEILF)
 204     AC_DEFINE(HAVE_COPYSIGN)
 205     AC_DEFINE(HAVE_COPYSIGNF)
 206     AC_DEFINE(HAVE_COSF)
 207     AC_DEFINE(HAVE_COSHF)
 208     AC_DEFINE(HAVE_EXPF)
 209     AC_DEFINE(HAVE_FABSF)
 210     AC_DEFINE(HAVE_FLOORF)
 211     AC_DEFINE(HAVE_FMODF)
 212     AC_DEFINE(HAVE_FREXPF)
 213     AC_DEFINE(HAVE_LDEXPF)
 214     AC_DEFINE(HAVE_LOG10F)
 215     AC_DEFINE(HAVE_LOGF)
 216     AC_DEFINE(HAVE_MODFF)
 217     AC_DEFINE(HAVE_POWF)
 218     AC_DEFINE(HAVE_SINF)
 219     AC_DEFINE(HAVE_SINHF)
 220     AC_DEFINE(HAVE_SQRTF)
 221     AC_DEFINE(HAVE_TANF)
 222     AC_DEFINE(HAVE_TANHF)
 223
 224     AC_DEFINE(HAVE_S_ISREG)
 225     AC_DEFINE(HAVE_S_IFREG)
 226   else
 227     m4_include([crossconfig.m4])
 228   fi
 229
 230   # At some point, we should differentiate between architectures
 231   # like x86, which have long double versions, and alpha/powerpc/etc.,
 232   # which don't. For the time being, punt.
 233   if test x"long_double_math_on_this_cpu" = x"yes"; then
 234     AC_DEFINE(HAVE_ACOSL)
 235     AC_DEFINE(HAVE_ASINL)
 236     AC_DEFINE(HAVE_ATAN2L)
 237     AC_DEFINE(HAVE_ATANL)
 238     AC_DEFINE(HAVE_CEILL)
 239     AC_DEFINE(HAVE_COPYSIGNL)
 240     AC_DEFINE(HAVE_COSL)
 241     AC_DEFINE(HAVE_COSHL)
 242     AC_DEFINE(HAVE_EXPL)
 243     AC_DEFINE(HAVE_FABSL)
 244     AC_DEFINE(HAVE_FLOORL)
 245     AC_DEFINE(HAVE_FMODL)
 246     AC_DEFINE(HAVE_FREXPL)
 247     AC_DEFINE(HAVE_LDEXPL)
 248     AC_DEFINE(HAVE_LOG10L)
 249     AC_DEFINE(HAVE_LOGL)
 250     AC_DEFINE(HAVE_MODFL)
 251     AC_DEFINE(HAVE_POWL)
 252     AC_DEFINE(HAVE_SINCOSL)
 253     AC_DEFINE(HAVE_SINL)
 254     AC_DEFINE(HAVE_SINHL)
 255     AC_DEFINE(HAVE_SQRTL)
 256     AC_DEFINE(HAVE_TANL)
 257     AC_DEFINE(HAVE_TANHL)
 258   fi
 259
 260 fi
 261
 262 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 263 GLIBCXX_ENABLE_SYMVERS([yes])
 264
 265 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 266 GLIBCXX_CONFIGURE_TESTSUITE
 267
 268 # Propagate the target-specific source directories through the build chain.
 269 # (Nothing currently uses cpu_include_dir directly; only atomicity_include_dir
 270 # uses it, and it only gets used in this file.)
 271 ATOMICITY_SRCDIR=config/${atomicity_dir}
 272 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 273 OS_INC_SRCDIR=config/${os_include_dir}
 274 AC_SUBST(ATOMICITY_SRCDIR)
 275 AC_SUBST(ATOMIC_WORD_SRCDIR)
 276 AC_SUBST(OS_INC_SRCDIR)
 277
 278 # Determine cross-compile flags and AM_CONDITIONALs.
 279 #AC_SUBST(GLIBCXX_IS_NATIVE)
 280 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 281 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 282 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 283 GLIBCXX_EVALUATE_CONDITIONALS
 284
 285 AC_CACHE_SAVE
 286
 287 if test ${multilib} = yes; then
 288   multilib_arg="--enable-multilib"
 289 else
 290   multilib_arg=
 291 fi
 292
 293 # Export all the install information.
 294 GLIBCXX_EXPORT_INSTALL_INFO
 295
 296 # Export all the include and flag information to Makefiles.
 297 GLIBCXX_EXPORT_INCLUDES
 298 GLIBCXX_EXPORT_FLAGS
 299
 300 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
 301    grep "enable shared" > /dev/null;
 302 then
 303   LIBSUPCXX_PICFLAGS=-prefer-pic
 304 else
 305   LIBSUPCXX_PICFLAGS=
 306 fi
 307 AC_SUBST(LIBSUPCXX_PICFLAGS)
 308
 309 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 310 dnl which can all be called multiple times as needed, plus one (different)
 311 dnl AC_OUTPUT macro.  This one lists the files to be created:
 312 AC_CONFIG_FILES( \
 313   Makefile \
 314   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 315   )
 316 AC_CONFIG_FILES([scripts/check_survey],[chmod +x scripts/check_survey])
 317 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 318
 319 dnl These commands are run at the end of config.status:
 320 AC_CONFIG_COMMANDS([default],
 321 [if test -n "$CONFIG_FILES"; then
 322    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 323    # that multilib installs will end up installed in the correct place.
 324    # The testsuite needs it for multilib-aware ABI baseline files.
 325    # To work around this not being passed down from config-ml.in ->
 326    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 327    # append it here.  Only modify Makefiles that have just been created.
 328    #
 329    # Also, get rid of this simulated-VPATH thing that automake does.
 330    cat > vpsed << \_EOF
 331 s!`test -f '$<' || echo '$(srcdir)/'`!!
 332 _EOF
 333    for i in $SUBDIRS; do
 334     case $CONFIG_FILES in
 335      *${i}/Makefile*)
 336        #echo "Adding MULTISUBDIR to $i/Makefile"
 337        sed -f vpsed $i/Makefile > tmp
 338        grep '^MULTISUBDIR =' Makefile >> tmp
 339        mv tmp $i/Makefile
 340        ;;
 341     esac
 342    done
 343    rm vpsed
 344  fi
 345  (cd include && ${MAKE-make})
 346 ],
 347 [
 348 # Variables needed in config.status (file generation) which aren't already
 349 # passed by autoconf.
 350 SUBDIRS="$SUBDIRS"
 351 ])
 352
 353 dnl And this actually makes things happen:
 354 AC_OUTPUT