libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_INIT(package-unused, version-unused,, libgo)
  10 AC_CONFIG_SRCDIR(Makefile.am)
  11 AC_CONFIG_HEADER(config.h)
  12
  13 libtool_VERSION=17:0:0
  14 AC_SUBST(libtool_VERSION)
  15
  16 AM_ENABLE_MULTILIB(, ..)
  17
  18 AC_CANONICAL_SYSTEM
  19 target_alias=${target_alias-$host_alias}
  20
  21 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist subdir-objects -Wall -Wno-portability -Wno-override])
  22 AH_TEMPLATE(PACKAGE, [Name of package])
  23 AH_TEMPLATE(VERSION, [Version number of package])
  24
  25 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  26 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  27 AC_PROG_CC
  28 AC_PROG_GO
  29 AM_PROG_AS
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 case ${host} in
  35   *-*-aix*)
  36     # static hash tables crashes on AIX when libgo is built with O2
  37     CFLAGS="$CFLAGS -fno-section-anchors"
  38     GOCFLAGS="$GOCFLAGS -fno-section-anchors"
  39
  40     # Check default architecture for FAT library creation
  41     if test -z "`$CC -x c -E /dev/null -g3 -o - | grep 64BIT`" ; then
  42         AIX_EXTRA_ARCH='64'
  43     else
  44         AIX_EXTRA_ARCH='32'
  45     fi
  46     AC_SUBST(AIX_EXTRA_ARCH)
  47     ;;
  48 esac
  49
  50 AM_MAINTAINER_MODE
  51
  52 AC_PROG_LD
  53 AC_PROG_RANLIB
  54 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  55
  56 AC_LIBTOOL_DLOPEN
  57 AM_PROG_LIBTOOL
  58 AC_SUBST(enable_shared)
  59 AC_SUBST(enable_static)
  60
  61 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  62 AC_SUBST(CC_FOR_BUILD)
  63
  64 AC_PROG_AWK
  65
  66 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  67 AC_SUBST(WARN_FLAGS)
  68
  69 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  70                                       [turns on -Werror @<:@default=yes@:>@])])
  71 if test "x$enable_werror" != "xno"; then
  72   WERROR="-Werror"
  73 fi
  74 AC_SUBST(WERROR)
  75
  76 glibgo_toolexecdir=no
  77 glibgo_toolexeclibdir=no
  78
  79 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  80 AC_ARG_ENABLE([version-specific-runtime-libs],
  81   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  82                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  83   [case "$enableval" in
  84     yes) version_specific_libs=yes ;;
  85     no)  version_specific_libs=no ;;
  86     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  87    esac],
  88   [version_specific_libs=no])
  89 AC_MSG_RESULT($version_specific_libs)
  90
  91 GCC_WITH_TOOLEXECLIBDIR
  92
  93 # Version-specific runtime libs processing.
  94 if test $version_specific_libs = yes; then
  95   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  96   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  97 fi
  98
  99 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
 100 # Install a library built with a cross compiler in tooldir, not libdir.
 101 if test -n "$with_cross_host" &&
 102    test x"$with_cross_host" != x"no"; then
 103   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
 104   case ${with_toolexeclibdir} in
 105     no)
 106       nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
 107       ;;
 108     *)
 109       nover_glibgo_toolexeclibdir=${with_toolexeclibdir}
 110       ;;
 111   esac
 112 else
 113   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
 114   nover_glibgo_toolexeclibdir='${libdir}'
 115 fi
 116 multi_os_directory=`$GOC -print-multi-os-directory`
 117 case $multi_os_directory in
 118   .) ;; # Avoid trailing /.
 119   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
 120 esac
 121
 122 if test x"$glibgo_toolexecdir" = x"no"; then
 123   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
 124   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 125 fi
 126
 127 AC_SUBST(glibgo_toolexecdir)
 128 AC_SUBST(glibgo_toolexeclibdir)
 129 AC_SUBST(nover_glibgo_toolexeclibdir)
 130
 131 # See if the user wants to configure without libffi.  Some
 132 # architectures don't support it.  FIXME: We should set a default
 133 # based on the host.
 134 AC_ARG_WITH(libffi,
 135   AS_HELP_STRING([--without-libffi],
 136                  [don't use libffi]),
 137   [:],
 138   [with_libffi=${with_libffi_default-yes}])
 139
 140 LIBFFI=
 141 LIBFFIINCS=
 142 if test "$with_libffi" != no; then
 143    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 144    LIBFFI=../libffi/libffi_convenience.la
 145    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 146 fi
 147 AC_SUBST(LIBFFI)
 148 AC_SUBST(LIBFFIINCS)
 149 AM_CONDITIONAL(USE_LIBFFI, test "$with_libffi" != "no")
 150
 151 # See if the user wants to configure without libatomic. This is useful if we are
 152 # on an architecture for which libgo does not need an atomic support library and
 153 # libatomic does not support our C compiler.
 154 AC_ARG_WITH(libatomic,
 155   AS_HELP_STRING([--without-libatomic],
 156                  [don't use libatomic]),
 157   [:],
 158   [with_libatomic=${with_libatomic_default-yes}])
 159
 160 LIBATOMIC=
 161 if test "$with_libatomic" != no; then
 162    LIBATOMIC=../libatomic/libatomic_convenience.la
 163 fi
 164 AC_SUBST(LIBATOMIC)
 165
 166 # Used to tell GNU make to include a file without telling automake to
 167 # include it.
 168 go_include="-include"
 169 AC_SUBST(go_include)
 170
 171 # All known GOOS values.  This is the union of all operating systems
 172 # supported by the gofrontend and all operating systems supported by
 173 # the gc toolchain.
 174 ALLGOOS="aix android darwin dragonfly freebsd hurd illumos irix js linux netbsd openbsd plan9 rtems solaris windows"
 175
 176 is_darwin=no
 177 is_freebsd=no
 178 is_irix=no
 179 is_linux=no
 180 is_netbsd=no
 181 is_openbsd=no
 182 is_dragonfly=no
 183 is_rtems=no
 184 is_solaris=no
 185 is_aix=no
 186 is_hurd=no
 187 GOOS=unknown
 188 case ${host} in
 189   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 190   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 191   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 192   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 193   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 194   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 195   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 196   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 197   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 198   *-*-aix*)      is_aix=yes;     GOOS=aix ;;
 199   *-*-gnu*)      is_hurd=yes;    GOOS=hurd ;;
 200 esac
 201 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 202 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 203 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 204 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 205 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 206 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 207 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 208 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 209 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 210 AM_CONDITIONAL(LIBGO_IS_AIX, test $is_aix = yes)
 211 AM_CONDITIONAL(LIBGO_IS_HURD, test $is_hurd = yes)
 212 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 213 AC_SUBST(GOOS)
 214 AC_SUBST(ALLGOOS)
 215
 216 dnl Test whether we need to use DejaGNU or whether we can use the
 217 dnl simpler gotest approach.  We can only use gotest for a native
 218 dnl build.
 219 USE_DEJAGNU=no
 220 case ${host} in
 221   *-*-rtems*) USE_DEJAGNU=yes ;;
 222   ${build}) ;;
 223   *) USE_DEJAGNU=yes ;;
 224 esac
 225 AC_SUBST(USE_DEJAGNU)
 226
 227 # All known GOARCH values.  This is the union of all architectures
 228 # supported by the gofrontend and all architectures supported by the
 229 # gc toolchain.
 230 # To add a new architecture:
 231 # - add it to this list
 232 # - if appropriate, add an entry to ALLGOARCHFAMILY below
 233 # - add an entry to the case on ${host} below to set GOARCH
 234 # - update goarchList in libgo/go/go/build/syslist.go
 235 # - update goarch.sh to report the values for this architecture
 236 # - update go-set-goarch in gcc/testsuite/go.test/go-test.exp
 237 # - update ptrSizeMap and intSizeMap in libgo/go/cmd/cgo/main.go
 238 # - update arch lists in libgo/match.sh
 239 # - update arch lists in libgo/testsuite/gotest
 240 # - update +build lines in several places
 241 #   - libgo/go/runtime/lfstack_NNbit.go
 242 #   - libgo/go/runtime/hashNN.go
 243 #   - libgo/go/runtime/unalignedN.go
 244 #   - libgo/go/syscall/endian_XX.go
 245 #   - possibly others
 246 # - possibly update files in libgo/go/internal/syscall/unix
 247 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mips mipsle mips64 mips64le mips64p32 mips64p32le nios2 ppc ppc64 ppc64le riscv riscv64 s390 s390x sh shbe sparc sparc64 wasm"
 248
 249 # All known GOARCH family values.
 250 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 NIOS2 PPC PPC64 RISCV RISCV64 S390 S390X SH SPARC SPARC64 WASM"
 251
 252 GOARCH=unknown
 253 case ${host} in
 254   alpha*-*-*)
 255     GOARCH=alpha
 256     ;;
 257   aarch64-*-*)
 258     GOARCH=arm64
 259     ;;
 260   aarch64_be-*-*)
 261     GOARCH=arm64be
 262     ;;
 263   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 264     GOARCH=arm
 265     case ${host} in
 266       arm*b*-*-*)
 267         GOARCH=armbe
 268         ;;
 269     esac
 270     ;;
 271 changequote(,)dnl
 272   i[34567]86-*-* | x86_64-*-*)
 273 changequote([,])dnl
 274     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 275 #ifdef __x86_64__
 276 #error 64-bit
 277 #endif
 278 ])],
 279         [GOARCH=386],
 280         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 281 #ifdef __ILP32__
 282 #error x32
 283 #endif
 284 ])],
 285         [GOARCH=amd64],
 286         [GOARCH=amd64p32]))
 287     ;;
 288   ia64-*-*)
 289     GOARCH=ia64
 290     ;;
 291   m68k*-*-*)
 292     GOARCH=m68k
 293     ;;
 294   mips*-*-*)
 295     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 296 #if _MIPS_SIM != _ABIO32
 297 #error not o32
 298 #endif
 299 ])],
 300 [mips_abi="o32"],
 301         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 302 #if _MIPS_SIM != _ABIN32
 303 #error not n32
 304 #endif
 305 ])],
 306 [mips_abi="n32"],
 307         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 308 #if _MIPS_SIM != _ABI64
 309 #error not n64
 310 #endif
 311 ])],
 312 [mips_abi="n64"],
 313         [AC_MSG_ERROR([unknown MIPS ABI])
 314 [mips_abi="n32"]])])])
 315     case "$mips_abi" in
 316     "o32") GOARCH=mips ;;
 317     "n32") GOARCH=mips64p32 ;;
 318     "n64") GOARCH=mips64 ;;
 319     esac
 320     case "${host}" in
 321     mips*el-*-*)
 322         GOARCH="${GOARCH}le"
 323         ;;
 324     esac
 325     ;;
 326   nios2-*-*)
 327     GOARCH=nios2
 328     ;;
 329   rs6000*-*-* | powerpc*-*-*)
 330     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 331 #ifdef _ARCH_PPC64
 332 #error 64-bit
 333 #endif
 334 ])],
 335 [GOARCH=ppc],
 336     [
 337 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 338 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 339 #error 64be
 340 #endif
 341 ])],
 342 [GOARCH=ppc64le],
 343 [GOARCH=ppc64])])
 344     ;;
 345   riscv64-*-*)
 346     GOARCH=riscv64
 347     ;;
 348   s390*-*-*)
 349     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 350 #if defined(__s390x__)
 351 #error 64-bit
 352 #endif
 353 ])],
 354 [GOARCH=s390],
 355 [GOARCH=s390x])
 356     ;;
 357   sh3eb*-*-* | sh4eb*-*-*)
 358     GOARCH=shbe
 359     ;;
 360   sh3*-*-* | sh4*-*-*)
 361     GOARCH=sh
 362     ;;
 363   sparc*-*-*)
 364     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 365 #if defined(__sparcv9) || defined(__arch64__)
 366 #error 64-bit
 367 #endif
 368 ])],
 369 [GOARCH=sparc],
 370 [GOARCH=sparc64])
 371     ;;
 372 esac
 373 AC_SUBST(GOARCH)
 374 AC_SUBST(ALLGOARCH)
 375 AC_SUBST(ALLGOARCHFAMILY)
 376
 377 AM_CONDITIONAL(LIBGO_IS_X86, test "$GOARCH" = "386" -o "$GOARCH" = "amd64" -o "$GOARCH" = "amd64p32")
 378
 379 FUNCTION_DESCRIPTORS=false
 380 case ${host} in
 381   rs6000*-*-* | powerpc*-*-*)
 382     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 383 #if _CALL_ELF == 1
 384 #error descriptors
 385 #endif
 386 ])],
 387         [FUNCTION_DESCRIPTORS=false],
 388         [FUNCTION_DESCRIPTORS=true])
 389     ;;
 390 esac
 391 AC_SUBST(FUNCTION_DESCRIPTORS)
 392
 393 dnl Some files are only present when needed for specific architectures.
 394 GO_LIBCALL_OS_FILE=
 395 GO_LIBCALL_OS_ARCH_FILE=
 396 GO_SYSCALL_OS_FILE=
 397 GO_SYSCALL_OS_ARCH_FILE=
 398 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 399   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 400 fi
 401 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 402   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 403 fi
 404 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 405   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 406 fi
 407 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 408   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 409 fi
 410 AC_SUBST(GO_LIBCALL_OS_FILE)
 411 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 412 AC_SUBST(GO_SYSCALL_OS_FILE)
 413 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 414
 415 dnl Special flags used to generate sysinfo.go.
 416 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 417 case "$target" in
 418     mips-sgi-irix6.5*)
 419         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 420         # msghdr in <sys/socket.h>.
 421         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 422         ;;
 423     *-*-solaris2.*)
 424         # Solaris 10+ needs this so struct msghdr gets the msg_control
 425         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 426         # above doesn't work with C99.
 427         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 428         ;;
 429 esac
 430 AC_SUBST(OSCFLAGS)
 431
 432 dnl Check if assembler supports disabling hardware capability support.
 433 GCC_CHECK_ASSEMBLER_HWCAP
 434
 435 dnl Use -fsplit-stack when compiling C code if available.
 436 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 437 [libgo_cv_c_split_stack_supported],
 438 [CFLAGS_hold=$CFLAGS
 439 CFLAGS="$CFLAGS -fsplit-stack"
 440 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 441 [libgo_cv_c_split_stack_supported=yes],
 442 [libgo_cv_c_split_stack_supported=no])
 443 CFLAGS=$CFLAGS_hold])
 444
 445 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 446 dnl reject split-stack code calling non-split-stack code on targets
 447 dnl they don't support.
 448 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 449 [libgo_cv_c_linker_split_non_split],
 450 [cat > conftest1.c << EOF
 451 extern void f();
 452 int main() { f(); return 0; }
 453 EOF
 454 cat > conftest2.c << EOF
 455 void f() {}
 456 EOF
 457 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 458 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 459 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 460   libgo_cv_c_linker_split_non_split=yes
 461 else
 462   libgo_cv_c_linker_split_non_split=no
 463 fi
 464 rm -f conftest1.* conftest2.* conftest])
 465
 466 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 467   SPLIT_STACK=-fsplit-stack
 468   AC_DEFINE(USING_SPLIT_STACK, 1,
 469                 [Define if the compiler supports -fsplit-stack])
 470 else
 471   SPLIT_STACK=
 472 fi
 473 AC_SUBST(SPLIT_STACK)
 474 AM_CONDITIONAL(USING_SPLIT_STACK,
 475         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 476
 477 dnl If the compiler supports split-stack but the linker does not, then
 478 dnl we need to explicitly disable split-stack for Go.
 479 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 480   GO_SPLIT_STACK=-fno-split-stack
 481 else
 482   GO_SPLIT_STACK=
 483 fi
 484 AC_SUBST(GO_SPLIT_STACK)
 485
 486 dnl Check whether the linker does stack munging when calling from
 487 dnl split-stack into non-split-stack code.  We check this by looking
 488 dnl at the --help output.  FIXME: This is only half right: it's
 489 dnl possible for the linker to support this for some targets but not
 490 dnl others.
 491 dnl This is slightly different from the above check, which is whether
 492 dnl the linker permits the call at all.
 493 AC_CACHE_CHECK([whether linker supports split stack],
 494 [libgo_cv_c_linker_supports_split_stack],
 495 [libgo_cv_c_linker_supports_split_stack=no
 496 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 497   libgo_cv_c_linker_supports_split_stack=yes
 498 fi])
 499 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 500   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 501             [Define if the linker support split stack adjustments])
 502 fi
 503
 504 AC_CACHE_CHECK([whether compiler is llgo],
 505 [libgo_cv_c_goc_is_llgo],
 506 [libgo_cv_c_goc_is_llgo=no
 507 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 508   libgo_cv_c_goc_is_llgo=yes
 509 fi])
 510 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 511
 512 dnl Test for the -lm library.
 513 MATH_LIBS=
 514 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 515 AC_SUBST(MATH_LIBS)
 516
 517 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 518 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 519   [libgo_cv_lib_sockets=
 520    libgo_check_both=no
 521    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 522    if test "$libgo_check_socket" = "yes"; then
 523      unset ac_cv_func_connect
 524      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 525                   libgo_check_both=yes)
 526    fi
 527    if test "$libgo_check_both" = "yes"; then
 528      libgo_old_libs=$LIBS
 529      LIBS="$LIBS -lsocket -lnsl"
 530      unset ac_cv_func_accept
 531      AC_CHECK_FUNC(accept,
 532                    [libgo_check_nsl=no
 533                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 534      unset ac_cv_func_accept
 535      LIBS=$libgo_old_libs
 536    fi
 537    unset ac_cv_func_gethostbyname
 538    libgo_old_libs="$LIBS"
 539    AC_CHECK_FUNC(gethostbyname, ,
 540                  [AC_CHECK_LIB(nsl, main,
 541                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 542    unset ac_cv_func_gethostbyname
 543    AC_CHECK_FUNC(sendfile, ,
 544                  [AC_CHECK_LIB(sendfile, main,
 545                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 546    LIBS=$libgo_old_libs
 547 ])
 548 NET_LIBS="$libgo_cv_lib_sockets"
 549 AC_SUBST(NET_LIBS)
 550
 551 dnl Test whether the compiler supports the -pthread option.
 552 AC_CACHE_CHECK([whether -pthread is supported],
 553 [libgo_cv_lib_pthread],
 554 [CFLAGS_hold=$CFLAGS
 555 CFLAGS="$CFLAGS -pthread -L../libatomic/.libs"
 556 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 557 [libgo_cv_lib_pthread=yes],
 558 [libgo_cv_lib_pthread=no])
 559 CFLAGS=$CFLAGS_hold])
 560 PTHREAD_CFLAGS=
 561 if test "$libgo_cv_lib_pthread" = yes; then
 562   # RISC-V apparently adds -latomic when using -pthread.
 563   PTHREAD_CFLAGS="-pthread -L../libatomic/.libs"
 564 fi
 565 AC_SUBST(PTHREAD_CFLAGS)
 566
 567 dnl Test for the -lpthread library.
 568 PTHREAD_LIBS=
 569 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 570 AC_SUBST(PTHREAD_LIBS)
 571
 572 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 573 AC_SEARCH_LIBS([sched_yield], [rt])
 574 AC_SEARCH_LIBS([nanosleep], [rt])
 575 AC_SEARCH_LIBS([clock_gettime], [rt])
 576
 577 AC_C_BIGENDIAN
 578
 579 GCC_CHECK_UNWIND_GETIPINFO
 580
 581 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/ptrace.h linux/reboot.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 582
 583 AC_CHECK_HEADERS([netinet/icmp6.h], [], [],
 584 [#include <netinet/in.h>
 585 ])
 586
 587 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 588 [#ifdef HAVE_SYS_SOCKET_H
 589 #include <sys/socket.h>
 590 #endif
 591 ])
 592
 593 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 594
 595 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr memmem)
 596 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 597 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 598
 599 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice syscall tee unlinkat unshare utimensat)
 600 AC_TYPE_OFF_T
 601 AC_CHECK_TYPES([loff_t])
 602
 603 LIBS_hold="$LIBS"
 604 LIBS="$LIBS -lm"
 605 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 606 LIBS="$LIBS_hold"
 607
 608 CFLAGS_hold="$CFLAGS"
 609 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 610 LIBS_hold="$LIBS"
 611 LIBS="$LIBS $PTHREAD_LIBS"
 612 AC_CHECK_FUNCS(sem_timedwait)
 613 CFLAGS="$CFLAGS_hold"
 614 LIBS="$LIBS_hold"
 615
 616 LIBS_hold="$LIBS"
 617 LIBS="$LIBS $MATH_LIBS"
 618 AC_CHECK_FUNCS(matherr)
 619 LIBS="$LIBS_hold"
 620
 621 dnl For x86 we want to use the -minline-all-stringops option to avoid
 622 dnl forcing a stack split when calling memcpy and friends.
 623 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 624 [libgo_cv_c_stringops],
 625 [CFLAGS_hold=$CFLAGS
 626 CFLAGS="$CFLAGS -minline-all-stringops"
 627 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 628 [libgo_cv_c_stringops=yes],
 629 [libgo_cv_c_stringops=no])
 630 CFLAGS=$CFLAGS_hold])
 631 STRINGOPS_FLAG=
 632 if test "$libgo_cv_c_stringops" = yes; then
 633   STRINGOPS_FLAG=-minline-all-stringops
 634 fi
 635 AC_SUBST(STRINGOPS_FLAG)
 636
 637 dnl For x86 we want to compile the math library with -mfancy-math-387
 638 dnl so that we can use the builtin instructions directly.
 639 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 640 [libgo_cv_c_fancymath],
 641 [CFLAGS_hold=$CFLAGS
 642 CFLAGS="$CFLAGS -mfancy-math-387"
 643 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 644 [libgo_cv_c_fancymath=yes],
 645 [libgo_cv_c_fancymath=no])
 646 CFLAGS=$CFLAGS_hold])
 647 MATH_FLAG=
 648 if test "$libgo_cv_c_fancymath" = yes; then
 649   MATH_FLAG="-mfancy-math-387"
 650 fi
 651 MATH_FLAG="${MATH_FLAG} -ffp-contract=off -fno-math-errno -fno-trapping-math"
 652 AC_SUBST(MATH_FLAG)
 653
 654 CFLAGS_hold=$CFLAGS
 655 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 656 AC_CHECK_TYPES([off64_t])
 657 CFLAGS=$CFLAGS_hold
 658
 659 dnl Work out the size of the epoll_events struct on GNU/Linux.
 660 AC_CACHE_CHECK([epoll_event size],
 661 [libgo_cv_c_epoll_event_size],
 662 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 663 [sizeof (struct epoll_event)],
 664 [#include <sys/epoll.h>],
 665 [libgo_cv_c_epoll_event_size=0])])
 666 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 667 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 668
 669 dnl Work out the offset of the fd field in the epoll_events struct on
 670 dnl GNU/Linux.
 671 AC_CACHE_CHECK([epoll_event data.fd offset],
 672 [libgo_cv_c_epoll_event_fd_offset],
 673 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 674 [offsetof (struct epoll_event, data.fd)],
 675 [#include <stddef.h>
 676 #include <sys/epoll.h>],
 677 [libgo_cv_c_epoll_event_fd_offset=0])])
 678 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 679 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 680
 681 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 682 dnl in Solaris 11.4 for XPG7 compatibility.
 683 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 684                 [have_stat_timespec=yes], [have_stat_timespec=no])
 685 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 686
 687 dnl See if struct exception is defined in <math.h>.
 688 AC_CHECK_TYPE([struct exception],
 689 [libgo_has_struct_exception=yes],
 690 [libgo_has_struct_exception=no],
 691 [#include <math.h>])
 692 if test "$libgo_has_struct_exception" = "yes"; then
 693   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 694             [Define to 1 if <math.h> defines struct exception])
 695 fi
 696
 697 dnl See whether setcontext changes the value of TLS variables.
 698 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 699 [libgo_cv_lib_setcontext_clobbers_tls],
 700 [CFLAGS_hold="$CFLAGS"
 701 CFLAGS="$PTHREAD_CFLAGS"
 702 LIBS_hold="$LIBS"
 703 LIBS="$LIBS $PTHREAD_LIBS"
 704 AC_CHECK_SIZEOF([void *])
 705 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 706 AC_RUN_IFELSE(
 707   [AC_LANG_SOURCE([
 708 #include <pthread.h>
 709 #include <stdlib.h>
 710 #include <ucontext.h>
 711 #include <unistd.h>
 712
 713 __thread int tls;
 714
 715 static char stack[[10 * 1024 * 1024]];
 716 static ucontext_t c;
 717
 718 /* Called via makecontext/setcontext.  */
 719
 720 static void
 721 cfn (void)
 722 {
 723   exit (tls);
 724 }
 725
 726 /* Called via pthread_create.  */
 727
 728 static void *
 729 tfn (void *dummy)
 730 {
 731   /* The thread should still see this value after calling
 732      setcontext.  */
 733   tls = 0;
 734
 735   setcontext (&c);
 736
 737   /* The call to setcontext should not return.  */
 738   abort ();
 739 }
 740
 741 int
 742 main ()
 743 {
 744   pthread_t tid;
 745
 746   /* The thread should not see this value.  */
 747   tls = 1;
 748
 749   if (getcontext (&c) < 0)
 750     abort ();
 751
 752   c.uc_stack.ss_sp = stack;
 753 #ifdef MAKECONTEXT_STACK_TOP
 754   c.uc_stack.ss_sp += sizeof stack;
 755 #endif
 756   c.uc_stack.ss_flags = 0;
 757   c.uc_stack.ss_size = sizeof stack;
 758   c.uc_link = NULL;
 759   makecontext (&c, cfn, 0);
 760
 761   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 762     abort ();
 763
 764   if (pthread_join (tid, NULL) != 0)
 765     abort ();
 766
 767   /* The thread should have called exit.  */
 768   abort ();
 769 }
 770 ])],
 771 [libgo_cv_lib_setcontext_clobbers_tls=no],
 772 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 773 [case "$target:$ptr_type_size" in
 774   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 775     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 776   *)
 777     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 778  esac
 779 ])
 780 CFLAGS="$CFLAGS_hold"
 781 LIBS="$LIBS_hold"
 782 ])
 783 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 784   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 785             [Define if setcontext clobbers TLS variables])
 786 fi
 787
 788 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 789 libgo_cv_ro_eh_frame, [
 790 libgo_cv_ro_eh_frame=no
 791 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 792 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 793   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 794     libgo_cv_ro_eh_frame=yes
 795   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 796        | grep -v '#write' > /dev/null; then
 797     libgo_cv_ro_eh_frame=yes
 798   fi
 799 fi
 800 rm -f conftest.*
 801 ])
 802 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 803   AC_DEFINE(EH_FRAME_FLAGS, "a",
 804             [Define to the flags needed for the .section .eh_frame directive.])
 805 else
 806   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 807             [Define to the flags needed for the .section .eh_frame directive.])
 808 fi
 809
 810 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 811 [libgo_cv_c_unused_arguments],
 812 [CFLAGS_hold=$CFLAGS
 813 CFLAGS="$CFLAGS -Qunused-arguments"
 814 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 815 [libgo_cv_c_unused_arguments=yes],
 816 [libgo_cv_c_unused_arguments=no])
 817 CFLAGS=$CFLAGS_hold])
 818
 819 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 820 libgo_cv_as_comdat_gnu, [
 821 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 822 CFLAGS_hold=$CFLAGS
 823 if test "$libgo_cv_c_unused_arguments" = yes; then
 824   CFLAGS="$CFLAGS -Qunused-arguments"
 825 fi
 826 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 827   libgo_cv_as_comdat_gnu=yes
 828 else
 829   libgo_cv_as_comdat_gnu=no
 830 fi
 831 CFLAGS=$CFLAGS_hold
 832 ])
 833 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 834   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 835             [Define if your assembler supports GNU comdat group syntax.])
 836 fi
 837
 838 AC_CACHE_CHECK([assembler supports pc related relocs],
 839 libgo_cv_as_x86_pcrel, [
 840 libgo_cv_as_x86_pcrel=yes
 841 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 842 CFLAGS_hold=$CFLAGS
 843 if test "$libgo_cv_c_unused_arguments" = yes; then
 844   CFLAGS="$CFLAGS -Qunused-arguments"
 845 fi
 846 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 847     libgo_cv_as_x86_pcrel=no
 848 fi
 849 CFLAGS=$CFLAGS_hold
 850 ])
 851 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 852   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 853             [Define if your assembler supports PC relative relocs.])
 854 fi
 855
 856 AC_CACHE_CHECK([assembler supports unwind section type],
 857 libgo_cv_as_x86_64_unwind_section_type, [
 858 libgo_cv_as_x86_64_unwind_section_type=yes
 859 echo '.section .eh_frame,"a",@unwind' > conftest.s
 860 CFLAGS_hold=$CFLAGS
 861 if test "$libgo_cv_c_unused_arguments" = yes; then
 862   CFLAGS="$CFLAGS -Qunused-arguments"
 863 fi
 864 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 865     libgo_cv_as_x86_64_unwind_section_type=no
 866 fi
 867 CFLAGS=$CFLAGS_hold
 868 ])
 869 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 870   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 871             [Define if your assembler supports unwind section type.])
 872 fi
 873
 874 AC_CACHE_CHECK([assembler supports AES instructions],
 875 libgo_cv_as_x86_aes, [
 876 libgo_cv_as_x86_aes=yes
 877 echo 'aesenc %xmm0, %xmm1' > conftest.s
 878 CFLAGS_hold=$CFLAGS
 879 if test "$libgo_cv_c_unused_arguments" = yes; then
 880   CFLAGS="$CFLAGS -Qunused-arguments"
 881 fi
 882 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i error > /dev/null; then
 883     libgo_cv_as_x86_aes=no
 884 fi
 885 CFLAGS=$CFLAGS_hold
 886 ])
 887 if test "x$libgo_cv_as_x86_aes" = xyes; then
 888   AC_DEFINE(HAVE_AS_X86_AES, 1,
 889             [Define if your assembler supports AES instructions.])
 890 fi
 891
 892 dnl Test whether the linker supports the -static option.
 893 AC_CACHE_CHECK([whether -static is supported],
 894 [libgo_cv_ld_static],
 895 [LDFLAGS_hold=$LDFLAGS
 896 LDFLAGS="$LDFLAGS -static"
 897 AC_LINK_IFELSE([AC_LANG_PROGRAM(,)],
 898 [libgo_cv_ld_static=yes],
 899 [libgo_cv_ld_static=no])
 900 LDFLAGS=$LDFLAGS_hold])
 901 AM_CONDITIONAL(HAVE_STATIC_LINK, test "$libgo_cv_ld_static" = yes)
 902
 903 AC_CACHE_SAVE
 904
 905 if test ${multilib} = yes; then
 906   multilib_arg="--enable-multilib"
 907 else
 908   multilib_arg=
 909 fi
 910
 911 AC_CONFIG_FILES(Makefile testsuite/Makefile testsuite/libgo-test-support.exp)
 912
 913 AC_CONFIG_COMMANDS([default],
 914 [if test -n "$CONFIG_FILES"; then
 915    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 916    # that multilib installs will end up installed in the correct place.
 917    # The testsuite needs it for multilib-aware ABI baseline files.
 918    # To work around this not being passed down from config-ml.in ->
 919    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 920    # append it here.  Only modify Makefiles that have just been created.
 921    #
 922    # Also, get rid of this simulated-VPATH thing that automake does.
 923    cat > vpsed << \_EOF
 924 s!`test -f '$<' || echo '$(srcdir)/'`!!
 925 _EOF
 926    for i in $SUBDIRS; do
 927     case $CONFIG_FILES in
 928      *${i}/Makefile*)
 929        #echo "Adding MULTISUBDIR to $i/Makefile"
 930        sed -f vpsed $i/Makefile > tmp
 931        grep '^MULTISUBDIR =' Makefile >> tmp
 932        mv tmp $i/Makefile
 933        ;;
 934     esac
 935    done
 936    rm vpsed
 937  fi
 938 ],
 939 [
 940 # Variables needed in config.status (file generation) which aren't already
 941 # passed by autoconf.
 942 SUBDIRS="$SUBDIRS"
 943 ])
 944
 945 AC_OUTPUT