gcc/ada/a-cuprqu.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                 ADA.CONTAINERS.UNBOUNDED_PRIORITY_QUEUES                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2011-2015, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- This unit was originally developed by Matthew J Heaney.                  --
  32 ------------------------------------------------------------------------------
  33
  34 with System;
  35 with Ada.Containers.Synchronized_Queue_Interfaces;
  36 with Ada.Finalization;
  37
  38 generic
  39    with package Queue_Interfaces is
  40      new Ada.Containers.Synchronized_Queue_Interfaces (<>);
  41
  42    type Queue_Priority is private;
  43
  44    with function Get_Priority
  45      (Element : Queue_Interfaces.Element_Type) return Queue_Priority is <>;
  46
  47    with function Before
  48      (Left, Right : Queue_Priority) return Boolean is <>;
  49
  50    Default_Ceiling : System.Any_Priority := System.Priority'Last;
  51
  52 package Ada.Containers.Unbounded_Priority_Queues is
  53    pragma Annotate (CodePeer, Skip_Analysis);
  54    pragma Preelaborate;
  55
  56    package Implementation is
  57
  58       --  All identifiers in this unit are implementation defined
  59
  60       pragma Implementation_Defined;
  61
  62       type List_Type is tagged limited private;
  63
  64       procedure Enqueue
  65         (List     : in out List_Type;
  66          New_Item : Queue_Interfaces.Element_Type);
  67
  68       procedure Dequeue
  69         (List    : in out List_Type;
  70          Element : out Queue_Interfaces.Element_Type);
  71
  72       procedure Dequeue
  73         (List     : in out List_Type;
  74          At_Least : Queue_Priority;
  75          Element  : in out Queue_Interfaces.Element_Type;
  76          Success  : out Boolean);
  77
  78       function Length (List : List_Type) return Count_Type;
  79
  80       function Max_Length (List : List_Type) return Count_Type;
  81
  82    private
  83
  84       type Node_Type;
  85       type Node_Access is access Node_Type;
  86
  87       type Node_Type is limited record
  88          Element : Queue_Interfaces.Element_Type;
  89          Next    : Node_Access;
  90       end record;
  91
  92       type List_Type is new Ada.Finalization.Limited_Controlled with record
  93          First, Last : Node_Access;
  94          Length      : Count_Type := 0;
  95          Max_Length  : Count_Type := 0;
  96       end record;
  97
  98       overriding procedure Finalize (List : in out List_Type);
  99
 100    end Implementation;
 101
 102    protected type Queue (Ceiling : System.Any_Priority := Default_Ceiling)
 103    with
 104      Priority => Ceiling
 105    is new Queue_Interfaces.Queue with
 106
 107       overriding entry Enqueue (New_Item : Queue_Interfaces.Element_Type);
 108
 109       overriding entry Dequeue (Element : out Queue_Interfaces.Element_Type);
 110
 111       --  The priority queue operation Dequeue_Only_High_Priority had been a
 112       --  protected entry in early drafts of AI05-0159, but it was discovered
 113       --  that that operation as specified was not in fact implementable. The
 114       --  operation was changed from an entry to a protected procedure per the
 115       --  ARG meeting in Edinburgh (June 2011), with a different signature and
 116       --  semantics.
 117
 118       procedure Dequeue_Only_High_Priority
 119         (At_Least : Queue_Priority;
 120          Element  : in out Queue_Interfaces.Element_Type;
 121          Success  : out Boolean);
 122
 123       overriding function Current_Use return Count_Type;
 124
 125       overriding function Peak_Use return Count_Type;
 126
 127    private
 128       List : Implementation.List_Type;
 129    end Queue;
 130
 131 end Ada.Containers.Unbounded_Priority_Queues;