libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13
  14 AC_PREREQ(2.64)
  15 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  16 AC_CONFIG_SRCDIR([static-object.mk])
  17
  18 # The libgcc should not depend on any header files
  19 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  20   [m4_divert_text([DEFAULTS],
  21     [ac_includes_default='/* none */'])])
  22
  23 AC_ARG_WITH(target-subdir,
  24 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  25 AC_ARG_WITH(cross-host,
  26 [  --with-cross-host=HOST           Configuring with a cross compiler])
  27 AC_ARG_WITH(ld,
  28 [  --with-ld               arrange to use the specified ld (full pathname)])
  29
  30 if test "${srcdir}" = "."; then
  31   if test -n "${with_build_subdir}"; then
  32     libgcc_topdir="${srcdir}/../.."
  33     with_target_subdir=
  34   elif test -z "${with_target_subdir}"; then
  35     libgcc_topdir="${srcdir}/.."
  36   else
  37     if test "${with_target_subdir}" != "."; then
  38       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  39     else
  40       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  41     fi
  42   fi
  43 else
  44   libgcc_topdir="${srcdir}/.."
  45 fi
  46 AC_SUBST(libgcc_topdir)
  47 AC_CONFIG_AUX_DIR($libgcc_topdir)
  48 AC_CONFIG_HEADER(auto-target.h:config.in)
  49
  50 AC_ARG_ENABLE(shared,
  51 [  --disable-shared        don't provide a shared libgcc],
  52 [
  53   case $enable_shared in
  54   yes | no) ;;
  55   *)
  56     enable_shared=no
  57     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  58     for pkg in $enableval; do
  59       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  60         enable_shared=yes
  61       fi
  62     done
  63     IFS="$ac_save_ifs"
  64     ;;
  65   esac
  66 ], [enable_shared=yes])
  67 AC_SUBST(enable_shared)
  68
  69 AC_ARG_ENABLE(vtable-verify,
  70 [  --enable-vtable-verify    Enable vtable verification feature ],
  71 [case "$enableval" in
  72  yes) enable_vtable_verify=yes ;;
  73  no)  enable_vtable_verify=no ;;
  74  *)   enable_vtable_verify=no;;
  75  esac],
  76 [enable_vtable_verify=no])
  77 AC_SUBST(enable_vtable_verify)
  78
  79 AC_ARG_WITH(aix-soname,
  80 [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
  81     [shared library versioning (aka "SONAME") variant to provide on AIX])],
  82 [case "${host}:${enable_shared}" in
  83  power*-*-aix[[5-9]]*:yes)
  84    AC_MSG_CHECKING([which variant of shared library versioning to provide for shared libgcc])
  85    case ${withval} in
  86      aix|svr4|both) ;;
  87      *) AC_MSG_ERROR([Unknown argument to --with-aix-soname]);;
  88    esac
  89    AC_MSG_RESULT($withval)
  90    ;;
  91  *) with_aix_soname=aix ;;
  92  esac
  93 ], [with_aix_soname=aix])
  94 AC_SUBST(with_aix_soname)
  95
  96 GCC_PICFLAG
  97 AC_SUBST(PICFLAG)
  98
  99 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 100 AC_ARG_ENABLE(version-specific-runtime-libs,
 101 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 102 [case "$enableval" in
 103  yes) version_specific_libs=yes ;;
 104  no)  version_specific_libs=no ;;
 105  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 106  esac],
 107 [version_specific_libs=no])
 108 AC_MSG_RESULT($version_specific_libs)
 109
 110 AC_ARG_WITH(slibdir,
 111 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
 112 slibdir="$with_slibdir",
 113 if test "${version_specific_libs}" = yes; then
 114   slibdir='$(libsubdir)'
 115 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
 116   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 117 else
 118   slibdir='$(libdir)'
 119 fi)
 120 AC_SUBST(slibdir)
 121
 122 # Command-line options.
 123 # Very limited version of AC_MAINTAINER_MODE.
 124 AC_ARG_ENABLE([maintainer-mode],
 125   [AC_HELP_STRING([--enable-maintainer-mode],
 126                  [enable make rules and dependencies not useful (and
 127                   sometimes confusing) to the casual installer])],
 128   [case ${enable_maintainer_mode} in
 129      yes) MAINT='' ;;
 130      no) MAINT='#' ;;
 131      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 132    esac
 133    maintainer_mode=${enableval}],
 134   [MAINT='#'])
 135 AC_SUBST([MAINT])dnl
 136
 137 AC_PROG_INSTALL
 138
 139 AC_PROG_AWK
 140 # We need awk; bail out if it's missing.
 141 case ${AWK} in
 142   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 143 esac
 144
 145 AC_CANONICAL_HOST
 146 ACX_NONCANONICAL_HOST
 147 ACX_NONCANONICAL_TARGET
 148 GCC_TOPLEV_SUBDIRS
 149
 150 # Calculate toolexeclibdir
 151 # Also toolexecdir, though it's only used in toolexeclibdir
 152 case ${version_specific_libs} in
 153   yes)
 154     # Need the gcc compiler version to know where to install libraries
 155     # and header files if --enable-version-specific-runtime-libs option
 156     # is selected.
 157     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 158     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 159     ;;
 160   no)
 161     if test -n "$with_cross_host" &&
 162        test x"$with_cross_host" != x"no"; then
 163       # Install a library built with a cross compiler in tooldir, not libdir.
 164       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 165       toolexeclibdir='$(toolexecdir)/lib'
 166     else
 167       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 168       toolexeclibdir='$(libdir)'
 169     fi
 170     multi_os_directory=`$CC -print-multi-os-directory`
 171     case $multi_os_directory in
 172       .) ;; # Avoid trailing /.
 173       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 174     esac
 175     ;;
 176 esac
 177 AC_SUBST(toolexecdir)
 178 AC_SUBST(toolexeclibdir)
 179
 180 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 181 dnl to call AC_CHECK_PROG.
 182 AC_CHECK_TOOL(AR, ar)
 183 AC_CHECK_TOOL(LIPO, lipo, :)
 184 AC_CHECK_TOOL(NM, nm)
 185 AC_CHECK_TOOL(RANLIB, ranlib, :)
 186 AC_CHECK_TOOL(STRIP, strip, :)
 187 AC_PROG_LN_S
 188
 189 GCC_NO_EXECUTABLES
 190 AC_PROG_CC
 191 AC_PROG_CPP_WERROR
 192
 193 AC_CHECK_SIZEOF([double])
 194 AC_CHECK_SIZEOF([long double])
 195 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 196 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 197 AC_SUBST(double_type_size)
 198 AC_SUBST(long_double_type_size)
 199
 200 # Check for decimal float support.
 201 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 202                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 203 #include <fenv.h>
 204 ]], [[
 205 _Decimal32 x;
 206 int fe_except =
 207   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 208 ]])],
 209                                   [libgcc_cv_dfp=yes],
 210                                   [libgcc_cv_dfp=no])])
 211 decimal_float=$libgcc_cv_dfp
 212 AC_SUBST(decimal_float)
 213
 214 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 215
 216 # Check for fixed-point support.
 217 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 218                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 219                                   [libgcc_cv_fixed_point=no])])
 220 fixed_point=$libgcc_cv_fixed_point
 221 AC_SUBST(fixed_point)
 222
 223 # For platforms with the unwind ABI which includes an unwind library,
 224 # libunwind, we can choose to use the system libunwind.
 225 # config.gcc also contains tests of with_system_libunwind.
 226 GCC_CHECK_UNWIND_GETIPINFO
 227
 228 # The sjlj test is almost duplicated here and in libgo/configure.ac (for C),
 229 # libstdc++-v3/acinclude.m4 and libjava/configure.ac (for C++), and
 230 # libobjc/configure.ac (for Objective-C).
 231 # FIXME: This should be centralized in config/sjlj.m4.
 232 AC_ARG_ENABLE(sjlj-exceptions,
 233   AC_HELP_STRING([--enable-sjlj-exceptions],
 234                  [force use of builtin_setjmp for exceptions]),
 235   [case "$enableval" in
 236    yes|no|auto) ;;
 237    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 238    esac],
 239   [enable_sjlj_exceptions=auto])
 240
 241 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 242 [libgcc_cv_lib_sjlj_exceptions],
 243 [AC_LANG_CONFTEST(
 244   [AC_LANG_SOURCE([
 245 void bar ();
 246 void clean (int *);
 247 void foo ()
 248 {
 249   int i __attribute__ ((cleanup (clean)));
 250   bar();
 251 }
 252 ])])
 253 CFLAGS_hold=$CFLAGS
 254 CFLAGS="--save-temps -fexceptions"
 255 libgcc_cv_lib_sjlj_exceptions=unknown
 256 AS_IF([ac_fn_c_try_compile],
 257   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 258     libgcc_cv_lib_sjlj_exceptions=yes
 259   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 260     libgcc_cv_lib_sjlj_exceptions=no
 261   fi])
 262 CFLAGS=$CFLAGS_hold
 263 rm -f conftest*
 264 ])
 265
 266 if test "$enable_sjlj_exceptions" = "auto"; then
 267   enable_sjlj_exceptions=$libgcc_cv_lib_sjlj_exceptions
 268 fi
 269
 270 case $enable_sjlj_exceptions in
 271 yes)
 272   AC_DEFINE(LIBGCC_SJLJ_EXCEPTIONS, 1,
 273         [Define if the C compiler is configured for setjmp/longjmp exceptions.])
 274   ;;
 275 no)
 276   ;;
 277 *)
 278   AC_MSG_ERROR([unable to detect exception model])
 279   ;;
 280 esac
 281
 282 AC_ARG_ENABLE([explicit-exception-frame-registration],
 283   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 284      [register exception tables explicitly at module start, for use
 285       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 286 [
 287 force_explicit_eh_registry=
 288 if test "$enable_explicit_exception_frame_registration" = yes; then
 289   if test "$enable_sjlj_exceptions" = yes; then
 290     AC_MSG_ERROR([Can't enable both of --enable-sjlj-exceptions
 291                   and --enable-explicit-exception-frame-registration])
 292   fi
 293   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 294 fi
 295 ])
 296 AC_SUBST([force_explicit_eh_registry])
 297
 298 AC_LIB_PROG_LD_GNU
 299
 300 AC_MSG_CHECKING([for thread model used by GCC])
 301 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 302 AC_MSG_RESULT([$target_thread_file])
 303
 304 # Check for assembler CFI support.
 305 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 306                [AC_COMPILE_IFELSE(
 307 [asm("\n\
 308         .text\n\
 309         .cfi_startproc\n\
 310         .cfi_personality 0, symbol\n\
 311         .cfi_endproc");],
 312   [libgcc_cv_cfi=yes],
 313   [libgcc_cv_cfi=no])])
 314
 315 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 316 # word size rather than the address size.
 317 cat > conftest.c <<EOF
 318 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 319     || defined(__mips64)
 320 host_address=64
 321 #else
 322 host_address=32
 323 #endif
 324 EOF
 325 eval `${CC-cc} -E conftest.c | grep host_address=`
 326 rm -f conftest.c
 327
 328 case ${host} in
 329 mips*-*-*)
 330   AC_CACHE_CHECK([whether the target is hard-float],
 331                  [libgcc_cv_mips_hard_float],
 332                  [AC_COMPILE_IFELSE(
 333     [#ifndef __mips_hard_float
 334      #error FOO
 335      #endif],
 336     [libgcc_cv_mips_hard_float=yes],
 337     [libgcc_cv_mips_hard_float=no])])
 338 esac
 339
 340 # Determine the version of glibc, if any, used on the target.
 341 AC_MSG_CHECKING([for target glibc version])
 342 AC_ARG_WITH([glibc-version],
 343   [AS_HELP_STRING([--with-glibc-version=M.N],
 344     [assume GCC used with glibc version M.N or later])], [
 345 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
 346   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
 347   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
 348 else
 349   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
 350 fi], [
 351 AC_COMPUTE_INT([glibc_version_major], [__GLIBC__],
 352                                       [#include <features.h>],
 353                                       [glibc_version_major=0])
 354 AC_COMPUTE_INT([glibc_version_minor], [__GLIBC_MINOR__],
 355                                       [#include <features.h>],
 356                                       [glibc_version_minor=0])])
 357 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
 358
 359 # Determine floating-point type for powerpc*-*-linux*.
 360 # Single-precision-only FPRs are not a supported configuration for
 361 # this target, so are not allowed for in this test.
 362 case ${host} in
 363 powerpc*-*-linux*)
 364   cat > conftest.c <<EOF
 365 #ifdef __powerpc64__
 366 ppc_fp_type=64
 367 #elif defined _SOFT_FLOAT
 368 ppc_fp_type=soft
 369 #elif defined _SOFT_DOUBLE
 370 ppc_fp_type=e500v1
 371 #elif defined __NO_FPRS__
 372 ppc_fp_type=e500v2
 373 #else
 374 ppc_fp_type=hard
 375 #endif
 376 EOF
 377 eval `${CC-cc} -E conftest.c | grep ppc_fp_type=`
 378 rm -f conftest.c
 379 # glibc 2.19 and later provide all the soft-fp functions, with proper
 380 # interactions with <fenv.h> exception and rounding mode handling, so
 381 # make libgcc's versions into compat symbols if a recent enough glibc
 382 # version is being used.
 383 ppc_fp_compat=
 384 case ${ppc_fp_type} in
 385 soft|e500v1|e500v2)
 386   if test $glibc_version_major -gt 2 \
 387     || ( test $glibc_version_major -eq 2 \
 388         && test $glibc_version_minor -ge 19 ); then
 389     ppc_fp_compat="t-softfp-compat"
 390   fi
 391   ;;
 392 esac
 393 ;;
 394 esac
 395
 396 # Collect host-machine-specific information.
 397 . ${srcdir}/config.host
 398
 399 # Used for constructing correct paths for offload compilers.
 400 accel_dir_suffix=
 401 if test x"$enable_as_accelerator_for" != x; then
 402   accel_dir_suffix=/accel/${target_noncanonical}
 403   case "${target_noncanonical}" in
 404     *-intelmicemul-*)
 405       # In this case we expect offload compiler to be built as native, so we
 406       # need to change install directory for driver to be able to find libgcc.
 407       host_noncanonical=${enable_as_accelerator_for} ;;
 408   esac
 409 fi
 410 AC_SUBST(accel_dir_suffix)
 411
 412 if test x"$enable_offload_targets" != x; then
 413   extra_parts="${extra_parts} crtoffloadbegin.o crtoffloadend.o"
 414 fi
 415
 416 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 417 # This is after config.host so we can augment tmake_file.
 418 # Link with -nostartfiles -nodefaultlibs since neither are present while
 419 # building libgcc.
 420 case ${host} in
 421 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 422   cat > conftest.s <<EOF
 423         .section        .eh_frame,"a",@unwind
 424         .zero   4
 425         .section        .jcr,"aw",@progbits
 426         .zero   8
 427 EOF
 428   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 429       tmake_file="${tmake_file} i386/t-crtstuff"
 430   fi
 431   ;;
 432 esac
 433
 434 # Check for visibility support.  This is after config.host so that
 435 # we can check for asm_hidden_op.
 436 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 437     libgcc_cv_hidden_visibility_attribute, [
 438         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 439         libgcc_cv_hidden_visibility_attribute=no
 440         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 441             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 442                 libgcc_cv_hidden_visibility_attribute=yes
 443             fi
 444         fi
 445         rm -f conftest.*
 446     ])
 447
 448 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 449     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 450 else
 451     vis_hide=
 452 fi
 453 AC_SUBST(vis_hide)
 454
 455 # See if we have thread-local storage.  We can only test assembler
 456 # since link-time and run-time tests require the newly built
 457 # gcc, which can't be used to build executable due to that libgcc
 458 # is yet to be built here.
 459 GCC_CHECK_CC_TLS
 460 set_have_cc_tls=
 461 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 462   set_have_cc_tls="-DHAVE_CC_TLS"
 463 fi
 464 AC_SUBST(set_have_cc_tls)
 465
 466 # See if we have emulated thread-local storage.
 467 GCC_CHECK_EMUTLS
 468 set_use_emutls=
 469 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 470   set_use_emutls="-DUSE_EMUTLS"
 471 fi
 472 AC_SUBST(set_use_emutls)
 473
 474 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 475 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 476   [[void ip (void) __attribute__ ((constructor (1)));]])],
 477   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 478 if test $libgcc_cv_init_priority = yes; then
 479   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 480   [Define if the compiler supports init priority.])
 481 fi
 482
 483 # Conditionalize the sfp-machine.h header for this target machine.
 484 if test -z "${sfp_machine_header}"; then
 485         sfp_machine_header=$cpu_type/sfp-machine.h
 486         if test -f ${srcdir}/config/${sfp_machine_header}; then
 487                 :
 488         else
 489                 sfp_machine_header=no-sfp-machine.h
 490         fi
 491 fi
 492 AC_SUBST(sfp_machine_header)
 493
 494 # Conditionalize the makefile for this target machine.
 495 tmake_file_=
 496 for f in ${tmake_file}
 497 do
 498         if test -f ${srcdir}/config/$f
 499         then
 500                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 501         fi
 502 done
 503 tmake_file="${tmake_file_}"
 504 AC_SUBST(tmake_file)
 505
 506 # Likewise export definitions for libgcc_tm.h
 507 tm_file_=
 508 for f in ${tm_file}
 509 do
 510         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 511 done
 512 tm_file="${tm_file_}"
 513 AC_SUBST(tm_file)
 514 AC_SUBST(tm_defines)
 515
 516 # Map from thread model to thread header.
 517 GCC_AC_THREAD_HEADER([$target_thread_file])
 518
 519 # Substitute configuration variables
 520 AC_SUBST(cpu_type)
 521 AC_SUBST(extra_parts)
 522 AC_SUBST(asm_hidden_op)
 523 AC_CONFIG_LINKS([enable-execute-stack.c:$enable_execute_stack])
 524 AC_CONFIG_LINKS([unwind.h:$unwind_header])
 525 AC_CONFIG_LINKS([md-unwind-support.h:config/$md_unwind_header])
 526 AC_CONFIG_LINKS([sfp-machine.h:config/$sfp_machine_header])
 527 AC_CONFIG_LINKS([gthr-default.h:$thread_header])
 528
 529 # We need multilib support.
 530 AC_CONFIG_FILES([Makefile])
 531 AC_CONFIG_COMMANDS([default],
 532   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 533 if test -n "$CONFIG_FILES"; then
 534   # FIXME: We shouldn't need to set ac_file
 535   ac_file=Makefile
 536   . ${libgcc_topdir}/config-ml.in
 537 fi]],
 538 [[srcdir=${srcdir}
 539 host=${host}
 540 with_target_subdir=${with_target_subdir}
 541 with_multisubdir=${with_multisubdir}
 542 ac_configure_args="--enable-multilib ${ac_configure_args}"
 543 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 544 libgcc_topdir=${libgcc_topdir}
 545 CC="${CC}"
 546 ]])
 547 AC_OUTPUT