c++tools/configure.ac

   1 # Configure script for c++tools
   2 #   Copyright (C) 2020-2023 Free Software Foundation, Inc.
   3 #   Written by Nathan Sidwell <nathan@acm.org> while at FaceBook
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 # C++ has grown a C++20 mapper server.  This may be used to provide
  20 # and/or learn and/or build required modules.  This sample server
  21 # shows how the protocol introduced by wg21.link/p1184 may be used.
  22 # By default g++ uses an in-process mapper.
  23
  24 sinclude(../config/acx.m4)
  25 sinclude(../config/ax_lib_socket_nsl.m4)
  26
  27 AC_INIT(c++tools)
  28
  29 AC_CONFIG_SRCDIR([server.cc])
  30
  31 # Determine the noncanonical names used for directories.
  32 ACX_NONCANONICAL_TARGET
  33
  34 AC_CANONICAL_SYSTEM
  35 AC_PROG_INSTALL
  36 test -z "$INSTALL_PROGRAM" && INSTALL_PROGRAM='${INSTALL}'
  37 AC_SUBST(INSTALL_PROGRAM)
  38
  39 AC_PROG_CXX
  40 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  41 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  42 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  43
  44 AC_LANG(C++)
  45
  46 dnl Enabled by default
  47 AC_MSG_CHECKING([whether to build C++ tools])
  48   AC_ARG_ENABLE(c++-tools,
  49     [AS_HELP_STRING([--enable-c++-tools],
  50                     [build auxiliary c++ tools])],
  51       cxx_aux_tools=$enableval,
  52       cxx_aux_tools=yes)
  53
  54 AC_MSG_RESULT($cxx_aux_tools)
  55 CXX_AUX_TOOLS="$cxx_aux_tools"
  56 AC_SUBST(CXX_AUX_TOOLS)
  57
  58 AC_ARG_ENABLE([maintainer-mode],
  59 AS_HELP_STRING([--enable-maintainer-mode],
  60 [enable maintainer mode.  Add rules to rebuild configurey bits]),,
  61 [enable_maintainer_mode=no])
  62 case "$enable_maintainer_mode" in
  63   yes) maintainer_mode=yes ;;
  64   no) maintainer_mode=no ;;
  65   *) AC_MSG_ERROR([unknown maintainer mode $enable_maintainer_mode]) ;;
  66 esac
  67 AC_MSG_CHECKING([maintainer-mode])
  68 AC_MSG_RESULT([$maintainer_mode])
  69 test "$maintainer_mode" = yes && MAINTAINER=yes
  70 AC_SUBST(MAINTAINER)
  71
  72 # Handle configuration of checking; for the tools in this directory we
  73 # default to release checking and stricter checks do not change this.
  74
  75 AC_ARG_ENABLE(checking,
  76 [AS_HELP_STRING([[--enable-checking[=LIST]]],
  77                 [enable expensive run-time checks.  With LIST,
  78                  enable only specific categories of checks.
  79                  Categories are: yes,no,all,none,release.])],
  80 [ac_checking_flags="${enableval}"],[
  81 # Default to checking.
  82 ac_checking_flags=yes
  83 ])
  84 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
  85 for check in release $ac_checking_flags
  86 do
  87         case $check in
  88         # these set all the flags to specific states
  89         yes|all|release|assert) ac_assert_checking=1 ; ;;
  90         no|none) ac_assert_checking= ; ;;
  91         *) ;;
  92         esac
  93 done
  94 IFS="$ac_save_IFS"
  95
  96 if test x$ac_assert_checking != x ; then
  97   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
  98 [Define if you want assertions enabled.  This is a cheap check.])
  99 fi
 100
 101 # Check whether --enable-default-pie was given.
 102 AC_ARG_ENABLE(default-pie,
 103 [AS_HELP_STRING([--enable-default-pie],
 104                   [enable Position Independent Executable as default])],
 105 [PICFLAG=-fPIE], [PICFLAG=])
 106
 107 # Enable --enable-host-pie
 108 AC_ARG_ENABLE(host-pie,
 109 [AS_HELP_STRING([--enable-host-pie],
 110                 [build host code as PIE])],
 111 [PICFLAG=-fPIE; LD_PICFLAG=-pie], [])
 112 AC_SUBST(PICFLAG)
 113
 114 # Enable --enable-host-bind-now
 115 AC_ARG_ENABLE(host-bind-now,
 116 [AS_HELP_STRING([--enable-host-bind-now],
 117        [link host code as BIND_NOW])],
 118 [LD_PICFLAG="$LD_PICFLAG -Wl,-z,now"], [])
 119 AC_SUBST(enable_host_bind_now)
 120 AC_SUBST(LD_PICFLAG)
 121
 122 # Check if O_CLOEXEC is defined by fcntl
 123 AC_CACHE_CHECK(for O_CLOEXEC, ac_cv_o_cloexec, [
 124 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 125 #include <fcntl.h>]], [[
 126 return open ("/dev/null", O_RDONLY | O_CLOEXEC);]])],
 127 [ac_cv_o_cloexec=yes],[ac_cv_o_cloexec=no])])
 128 if test $ac_cv_o_cloexec = yes; then
 129   AC_DEFINE(HOST_HAS_O_CLOEXEC, 1,
 130   [Define if O_CLOEXEC supported by fcntl.])
 131 fi
 132
 133 AC_CHECK_HEADERS(sys/mman.h)
 134
 135 # C++ Modules would like some networking features to provide the mapping
 136 # server.  You can still use modules without them though.
 137 # The following network-related checks could probably do with some
 138 # Windows and other non-linux defenses and checking.
 139
 140 # Local socket connectivity wants AF_UNIX networking
 141 # Check for AF_UNIX networking
 142 AC_CACHE_CHECK(for AF_UNIX, ac_cv_af_unix, [
 143 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 144 #include <sys/types.h>
 145 #include <sys/socket.h>
 146 #include <sys/un.h>
 147 #include <netinet/in.h>]],[[
 148 sockaddr_un un;
 149 un.sun_family = AF_UNSPEC;
 150 int fd = socket (AF_UNIX, SOCK_STREAM, 0);
 151 connect (fd, (sockaddr *)&un, sizeof (un));]])],
 152 [ac_cv_af_unix=yes],
 153 [ac_cv_af_unix=no])])
 154 if test $ac_cv_af_unix = yes; then
 155   AC_DEFINE(HAVE_AF_UNIX, 1,
 156   [Define if AF_UNIX supported.])
 157 fi
 158
 159 # Remote socket connectivity wants AF_INET6 networking
 160 # Check for AF_INET6 networking
 161 AC_CACHE_CHECK(for AF_INET6, ac_cv_af_inet6, [
 162 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 163 #include <sys/types.h>
 164 #include <sys/socket.h>
 165 #include <netinet/in.h>
 166 #include <netdb.h>]],[[
 167 sockaddr_in6 in6;
 168 in6.sin6_family = AF_UNSPEC;
 169 struct addrinfo *addrs = 0;
 170 struct addrinfo hints;
 171 hints.ai_flags = 0;
 172 hints.ai_family = AF_INET6;
 173 hints.ai_socktype = SOCK_STREAM;
 174 hints.ai_protocol = 0;
 175 hints.ai_canonname = 0;
 176 hints.ai_addr = 0;
 177 hints.ai_next = 0;
 178 int e = getaddrinfo ("localhost", 0, &hints, &addrs);
 179 const char *str = gai_strerror (e);
 180 freeaddrinfo (addrs);
 181 int fd = socket (AF_INET6, SOCK_STREAM, 0);
 182 connect (fd, (sockaddr *)&in6, sizeof (in6));]])],
 183 [ac_cv_af_inet6=yes],
 184 [ac_cv_af_inet6=no])])
 185 if test $ac_cv_af_inet6 = yes; then
 186   AC_DEFINE(HAVE_AF_INET6, 1,
 187   [Define if AF_INET6 supported.])
 188 fi
 189
 190 # Efficient server response wants epoll
 191 # Check for epoll_create, epoll_ctl, epoll_pwait
 192 AC_CACHE_CHECK(for epoll, ac_cv_epoll, [
 193 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 194 #include <sys/epoll.h>]],[[
 195 int fd = epoll_create (1);
 196 epoll_event ev;
 197 ev.events = EPOLLIN;
 198 ev.data.fd = 0;
 199 epoll_ctl (fd, EPOLL_CTL_ADD, 0, &ev);
 200 epoll_pwait (fd, 0, 0, -1, 0);]])],
 201 [ac_cv_epoll=yes],
 202 [ac_cv_epoll=no])])
 203 if test $ac_cv_epoll = yes; then
 204   AC_DEFINE(HAVE_EPOLL, 1,
 205   [Define if epoll_create, epoll_ctl, epoll_pwait provided.])
 206 fi
 207
 208 # If we can't use epoll, try pselect.
 209 # Check for pselect
 210 AC_CACHE_CHECK(for pselect, ac_cv_pselect, [
 211 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 212 #include <sys/select.h>]],[[
 213 pselect (0, 0, 0, 0, 0, 0);]])],
 214 [ac_cv_pselect=yes],
 215 [ac_cv_pselect=no])])
 216 if test $ac_cv_pselect = yes; then
 217   AC_DEFINE(HAVE_PSELECT, 1,
 218   [Define if pselect provided.])
 219 fi
 220
 221 # And failing that, use good old select.
 222 # If we can't even use this, the server is serialized.
 223 # Check for select
 224 AC_CACHE_CHECK(for select, ac_cv_select, [
 225 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 226 #include <sys/select.h>]],[[
 227 select (0, 0, 0, 0, 0);]])],
 228 [ac_cv_select=yes],
 229 [ac_cv_select=no])])
 230 if test $ac_cv_select = yes; then
 231   AC_DEFINE(HAVE_SELECT, 1,
 232   [Define if select provided.])
 233 fi
 234
 235 # Avoid some fnctl calls by using accept4, when available.
 236 # Check for accept4
 237 AC_CACHE_CHECK(for accept4, ac_cv_accept4, [
 238 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 239 #include <sys/socket.h>]],[[
 240 int err = accept4 (1, 0, 0, SOCK_NONBLOCK);]])],
 241 [ac_cv_accept4=yes],
 242 [ac_cv_accept4=no])])
 243 if test $ac_cv_accept4 = yes; then
 244   AC_DEFINE(HAVE_ACCEPT4, 1,
 245   [Define if accept4 provided.])
 246 fi
 247
 248 # For better server messages, look for a way to stringize network addresses
 249 # Check for inet_ntop
 250 AC_CACHE_CHECK(for inet_ntop, ac_cv_inet_ntop, [
 251 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 252 #include <arpa/inet.h>
 253 #include <netinet/in.h>]],[[
 254 sockaddr_in6 in6;
 255 char buf[INET6_ADDRSTRLEN];
 256 const char *str = inet_ntop (AF_INET6, &in6, buf, sizeof (buf));]])],
 257 [ac_cv_inet_ntop=yes],
 258 [ac_cv_inet_ntop=no])])
 259 if test $ac_cv_inet_ntop = yes; then
 260   AC_DEFINE(HAVE_INET_NTOP, 1,
 261   [Define if inet_ntop provided.])
 262 fi
 263
 264 # Determine what GCC version number to use in filesystem paths.
 265 GCC_BASE_VER
 266
 267 # Solaris needs libsocket and libnsl for socket functions before 11.4.
 268 # libcody uses those.
 269 save_LIBS="$LIBS"
 270 LIBS=
 271 AX_LIB_SOCKET_NSL
 272 NETLIBS="$LIBS"
 273 LIBS="$save_LIBS"
 274 AC_SUBST(NETLIBS)
 275
 276 AC_CONFIG_HEADERS([config.h])
 277 AC_CONFIG_FILES([Makefile])
 278
 279 AC_OUTPUT