gcc/ada/types.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                T Y P E S                                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This package contains host independent type definitions which are used
  33 --  in more than one unit in the compiler. They are gathered here for easy
  34 --  reference, although in some cases the full description is found in the
  35 --  relevant module which implements the definition. The main reason that they
  36 --  are not in their "natural" specs is that this would cause a lot of inter-
  37 --  spec dependencies, and in particular some awkward circular dependencies
  38 --  would have to be dealt with.
  39
  40 --  WARNING: There is a C version of this package. Any changes to this source
  41 --  file must be properly reflected in the C header file types.h declarations.
  42
  43 --  Note: the declarations in this package reflect an expectation that the host
  44 --  machine has an efficient integer base type with a range at least 32 bits
  45 --  2s-complement. If there are any machines for which this is not a correct
  46 --  assumption, a significant number of changes will be required!
  47
  48 with System;
  49 with Unchecked_Conversion;
  50 with Unchecked_Deallocation;
  51
  52 package Types is
  53    pragma Preelaborate;
  54
  55    -------------------------------
  56    -- General Use Integer Types --
  57    -------------------------------
  58
  59    type Int is range -2 ** 31 .. +2 ** 31 - 1;
  60    --  Signed 32-bit integer
  61
  62    subtype Nat is Int range 0 .. Int'Last;
  63    --  Non-negative Int values
  64
  65    subtype Pos is Int range 1 .. Int'Last;
  66    --  Positive Int values
  67
  68    type Word is mod 2 ** 32;
  69    --  Unsigned 32-bit integer
  70
  71    type Short is range -32768 .. +32767;
  72    for Short'Size use 16;
  73    --  16-bit signed integer
  74
  75    type Byte is mod 2 ** 8;
  76    for Byte'Size use 8;
  77    --  8-bit unsigned integer
  78
  79    type size_t is mod 2 ** Standard'Address_Size;
  80    --  Memory size value, for use in calls to C routines
  81
  82    --------------------------------------
  83    -- 8-Bit Character and String Types --
  84    --------------------------------------
  85
  86    --  We use Standard.Character and Standard.String freely, since we are
  87    --  compiling ourselves, and we properly implement the required 8-bit
  88    --  character code as required in Ada 95. This section defines a few
  89    --  general use constants and subtypes.
  90
  91    EOF : constant Character := ASCII.SUB;
  92    --  The character SUB (16#1A#) is used in DOS and other systems derived
  93    --  from DOS (XP, NT etc) to signal the end of a text file. Internally
  94    --  all source files are ended by an EOF character, even on Unix systems.
  95    --  An EOF character acts as the end of file only as the last character
  96    --  of a source buffer, in any other position, it is treated as a blank
  97    --  if it appears between tokens, and as an illegal character otherwise.
  98    --  This makes life easier dealing with files that originated from DOS,
  99    --  including concatenated files with interspersed EOF characters.
 100
 101    subtype Graphic_Character is Character range ' ' .. '~';
 102    --  Graphic characters, as defined in ARM
 103
 104    subtype Line_Terminator is Character range ASCII.LF .. ASCII.CR;
 105    --  Line terminator characters (LF, VT, FF, CR)
 106    --
 107    --  This definition is dubious now that we have two more wide character
 108    --  sequences that constitute a line terminator. Every reference to this
 109    --  subtype needs checking to make sure the wide character case is handled
 110    --  appropriately. ???
 111
 112    subtype Upper_Half_Character is
 113      Character range Character'Val (16#80#) .. Character'Val (16#FF#);
 114    --  Characters with the upper bit set
 115
 116    type Character_Ptr is access all Character;
 117    type String_Ptr    is access all String;
 118    --  Standard character and string pointers
 119
 120    procedure Free is new Unchecked_Deallocation (String, String_Ptr);
 121    --  Procedure for freeing dynamically allocated String values
 122
 123    subtype Big_String is String (Positive);
 124    type Big_String_Ptr is access all Big_String;
 125    for Big_String_Ptr'Storage_Size use 0;
 126    --  Virtual type for handling imported big strings
 127
 128    function To_Big_String_Ptr is
 129      new Unchecked_Conversion (System.Address, Big_String_Ptr);
 130    --  Used to obtain Big_String_Ptr values from external addresses
 131
 132    subtype Word_Hex_String is String (1 .. 8);
 133    --  Type used to represent Word value as 8 hex digits, with lower case
 134    --  letters for the alphabetic cases.
 135
 136    function Get_Hex_String (W : Word) return Word_Hex_String;
 137    --  Convert word value to 8-character hex string
 138
 139    -----------------------------------------
 140    -- Types Used for Text Buffer Handling --
 141    -----------------------------------------
 142
 143    --  We can not use type String for text buffers, since we must use the
 144    --  standard 32-bit integer as an index value, since we count on all index
 145    --  values being the same size.
 146
 147    type Text_Ptr is new Int;
 148    --  Type used for subscripts in text buffer
 149
 150    type Text_Buffer is array (Text_Ptr range <>) of Character;
 151    --  Text buffer used to hold source file or library information file
 152
 153    type Text_Buffer_Ptr is access all Text_Buffer;
 154    --  Text buffers for input files are allocated dynamically and this type
 155    --  is used to reference these text buffers.
 156
 157    procedure Free is new Unchecked_Deallocation (Text_Buffer, Text_Buffer_Ptr);
 158    --  Procedure for freeing dynamically allocated text buffers
 159
 160    ------------------------------------------
 161    -- Types Used for Source Input Handling --
 162    ------------------------------------------
 163
 164    type Logical_Line_Number is range 0 .. Int'Last;
 165    for Logical_Line_Number'Size use 32;
 166    --  Line number type, used for storing logical line numbers (i.e. line
 167    --  numbers that include effects of any Source_Reference pragmas in the
 168    --  source file). The value zero indicates a line containing a source
 169    --  reference pragma.
 170
 171    No_Line_Number : constant Logical_Line_Number := 0;
 172    --  Special value used to indicate no line number
 173
 174    type Physical_Line_Number is range 1 .. Int'Last;
 175    for Physical_Line_Number'Size use 32;
 176    --  Line number type, used for storing physical line numbers (i.e. line
 177    --  numbers in the physical file being compiled, unaffected by the presence
 178    --  of source reference pragmas.
 179
 180    type Column_Number is range 0 .. 32767;
 181    for Column_Number'Size use 16;
 182    --  Column number (assume that 2**15 - 1 is large enough). The range for
 183    --  this type is used to compute Hostparm.Max_Line_Length. See also the
 184    --  processing for -gnatyM in Stylesw).
 185
 186    No_Column_Number : constant Column_Number := 0;
 187    --  Special value used to indicate no column number
 188
 189    subtype Source_Buffer is Text_Buffer;
 190    --  Type used to store text of a source file . The buffer for the main
 191    --  source (the source specified on the command line) has a lower bound
 192    --  starting at zero. Subsequent subsidiary sources have lower bounds
 193    --  which are one greater than the previous upper bound.
 194
 195    subtype Big_Source_Buffer is Text_Buffer (0 .. Text_Ptr'Last);
 196    --  This is a virtual type used as the designated type of the access type
 197    --  Source_Buffer_Ptr, see Osint.Read_Source_File for details.
 198
 199    type Source_Buffer_Ptr is access all Big_Source_Buffer;
 200    for Source_Buffer_Ptr'Storage_Size use 0;
 201    --  Pointer to source buffer. We use virtual origin addressing for source
 202    --  buffers, with thin pointers. The pointer points to a virtual instance
 203    --  of type Big_Source_Buffer, where the actual type is in fact of type
 204    --  Source_Buffer. The address is adjusted so that the virtual origin
 205    --  addressing works correctly. See Osint.Read_Source_Buffer for further
 206    --  details.
 207
 208    subtype Source_Ptr is Text_Ptr;
 209    --  Type used to represent a source location, which is a subscript of a
 210    --  character in the source buffer. As noted above, different source buffers
 211    --  have different ranges, so it is possible to tell from a Source_Ptr value
 212    --  which source it refers to. Note that negative numbers are allowed to
 213    --  accommodate the following special values.
 214
 215    No_Location : constant Source_Ptr := -1;
 216    --  Value used to indicate no source position set in a node. A test for a
 217    --  Source_Ptr value being > No_Location is the approved way to test for a
 218    --  standard value that does not include No_Location or any of the following
 219    --  special definitions. One important use of No_Location is to label
 220    --  generated nodes that we don't want the debugger to see in normal mode
 221    --  (very often we conditionalize so that we set No_Location in normal mode
 222    --  and the corresponding source line in -gnatD mode).
 223
 224    Standard_Location : constant Source_Ptr := -2;
 225    --  Used for all nodes in the representation of package Standard other than
 226    --  nodes representing the contents of Standard.ASCII. Note that testing for
 227    --  a value being <= Standard_Location tests for both Standard_Location and
 228    --  for Standard_ASCII_Location.
 229
 230    Standard_ASCII_Location : constant Source_Ptr := -3;
 231    --  Used for all nodes in the presentation of package Standard.ASCII
 232
 233    System_Location : constant Source_Ptr := -4;
 234    --  Used to identify locations of pragmas scanned by Targparm, where we know
 235    --  the location is in System, but we don't know exactly what line.
 236
 237    First_Source_Ptr : constant Source_Ptr := 0;
 238    --  Starting source pointer index value for first source program
 239
 240    -------------------------------------
 241    -- Range Definitions for Tree Data --
 242    -------------------------------------
 243
 244    --  The tree has fields that can hold any of the following types:
 245
 246    --    Pointers to other tree nodes (type Node_Id)
 247    --    List pointers (type List_Id)
 248    --    Element list pointers (type Elist_Id)
 249    --    Names (type Name_Id)
 250    --    Strings (type String_Id)
 251    --    Universal integers (type Uint)
 252    --    Universal reals (type Ureal)
 253
 254    --  In most contexts, the strongly typed interface determines which of
 255    --  these types is present. However, there are some situations (involving
 256    --  untyped traversals of the tree), where it is convenient to be easily
 257    --  able to distinguish these values. The underlying representation in all
 258    --  cases is an integer type Union_Id, and we ensure that the range of
 259    --  the various possible values for each of the above types is disjoint
 260    --  so that this distinction is possible.
 261
 262    type Union_Id is new Int;
 263    --  The type in the tree for a union of possible ID values
 264
 265    --  Note: it is also helpful for debugging purposes to make these ranges
 266    --  distinct. If a bug leads to misidentification of a value, then it will
 267    --  typically result in an out of range value and a Constraint_Error.
 268
 269    List_Low_Bound : constant := -100_000_000;
 270    --  The List_Id values are subscripts into an array of list headers which
 271    --  has List_Low_Bound as its lower bound. This value is chosen so that all
 272    --  List_Id values are negative, and the value zero is in the range of both
 273    --  List_Id and Node_Id values (see further description below).
 274
 275    List_High_Bound : constant := 0;
 276    --  Maximum List_Id subscript value. This allows up to 100 million list Id
 277    --  values, which is in practice infinite, and there is no need to check the
 278    --  range. The range overlaps the node range by one element (with value
 279    --  zero), which is used both for the Empty node, and for indicating no
 280    --  list. The fact that the same value is used is convenient because it
 281    --  means that the default value of Empty applies to both nodes and lists,
 282    --  and also is more efficient to test for.
 283
 284    Node_Low_Bound : constant := 0;
 285    --  The tree Id values start at zero, because we use zero for Empty (to
 286    --  allow a zero test for Empty). Actual tree node subscripts start at 0
 287    --  since Empty is a legitimate node value.
 288
 289    Node_High_Bound : constant := 099_999_999;
 290    --  Maximum number of nodes that can be allocated is 100 million, which
 291    --  is in practice infinite, and there is no need to check the range.
 292
 293    Elist_Low_Bound : constant := 100_000_000;
 294    --  The Elist_Id values are subscripts into an array of elist headers which
 295    --  has Elist_Low_Bound as its lower bound.
 296
 297    Elist_High_Bound : constant := 199_999_999;
 298    --  Maximum Elist_Id subscript value. This allows up to 100 million Elists,
 299    --  which is in practice infinite and there is no need to check the range.
 300
 301    Elmt_Low_Bound : constant := 200_000_000;
 302    --  Low bound of element Id values. The use of these values is internal to
 303    --  the Elists package, but the definition of the range is included here
 304    --  since it must be disjoint from other Id values. The Elmt_Id values are
 305    --  subscripts into an array of list elements which has this as lower bound.
 306
 307    Elmt_High_Bound : constant := 299_999_999;
 308    --  Upper bound of Elmt_Id values. This allows up to 100 million element
 309    --  list members, which is in practice infinite (no range check needed).
 310
 311    Names_Low_Bound : constant := 300_000_000;
 312    --  Low bound for name Id values
 313
 314    Names_High_Bound : constant := 399_999_999;
 315    --  Maximum number of names that can be allocated is 100 million, which is
 316    --  in practice infinite and there is no need to check the range.
 317
 318    Strings_Low_Bound : constant := 400_000_000;
 319    --  Low bound for string Id values
 320
 321    Strings_High_Bound : constant := 499_999_999;
 322    --  Maximum number of strings that can be allocated is 100 million, which
 323    --  is in practice infinite and there is no need to check the range.
 324
 325    Ureal_Low_Bound : constant := 500_000_000;
 326    --  Low bound for Ureal values
 327
 328    Ureal_High_Bound : constant := 599_999_999;
 329    --  Maximum number of Ureal values stored is 100_000_000 which is in
 330    --  practice infinite so that no check is required.
 331
 332    Uint_Low_Bound : constant := 600_000_000;
 333    --  Low bound for Uint values
 334
 335    Uint_Table_Start : constant := 2_000_000_000;
 336    --  Location where table entries for universal integers start (see
 337    --  Uintp spec for details of the representation of Uint values).
 338
 339    Uint_High_Bound : constant := 2_099_999_999;
 340    --  The range of Uint values is very large, since a substantial part
 341    --  of this range is used to store direct values, see Uintp for details.
 342
 343    --  The following subtype definitions are used to provide convenient names
 344    --  for membership tests on Int values to see what data type range they
 345    --  lie in. Such tests appear only in the lowest level packages.
 346
 347    subtype List_Range      is Union_Id
 348      range List_Low_Bound    .. List_High_Bound;
 349
 350    subtype Node_Range      is Union_Id
 351      range Node_Low_Bound    .. Node_High_Bound;
 352
 353    subtype Elist_Range     is Union_Id
 354      range Elist_Low_Bound   .. Elist_High_Bound;
 355
 356    subtype Elmt_Range      is Union_Id
 357      range Elmt_Low_Bound    .. Elmt_High_Bound;
 358
 359    subtype Names_Range     is Union_Id
 360      range Names_Low_Bound   .. Names_High_Bound;
 361
 362    subtype Strings_Range   is Union_Id
 363      range Strings_Low_Bound .. Strings_High_Bound;
 364
 365    subtype Uint_Range      is Union_Id
 366      range Uint_Low_Bound    .. Uint_High_Bound;
 367
 368    subtype Ureal_Range     is Union_Id
 369      range Ureal_Low_Bound   .. Ureal_High_Bound;
 370
 371    -----------------------------
 372    -- Types for Atree Package --
 373    -----------------------------
 374
 375    --  Node_Id values are used to identify nodes in the tree. They are
 376    --  subscripts into the Nodes table declared in package Atree. Note that
 377    --  the special values Empty and Error are subscripts into this table.
 378    --  See package Atree for further details.
 379
 380    type Node_Id is range Node_Low_Bound .. Node_High_Bound;
 381    --  Type used to identify nodes in the tree
 382
 383    subtype Entity_Id is Node_Id;
 384    --  A synonym for node types, used in the Einfo package to refer to nodes
 385    --  that are entities (i.e. nodes with an Nkind of N_Defining_xxx). All such
 386    --  nodes are extended nodes and these are the only extended nodes, so that
 387    --  in practice entity and extended nodes are synonymous.
 388
 389    subtype Node_Or_Entity_Id is Node_Id;
 390    --  A synonym for node types, used in cases where a given value may be used
 391    --  to represent either a node or an entity. We like to minimize such uses
 392    --  for obvious reasons of logical type consistency, but where such uses
 393    --  occur, they should be documented by use of this type.
 394
 395    Empty : constant Node_Id := Node_Low_Bound;
 396    --  Used to indicate null node. A node is actually allocated with this
 397    --  Id value, so that Nkind (Empty) = N_Empty. Note that Node_Low_Bound
 398    --  is zero, so Empty = No_List = zero.
 399
 400    Empty_List_Or_Node : constant := 0;
 401    --  This constant is used in situations (e.g. initializing empty fields)
 402    --  where the value set will be used to represent either an empty node or
 403    --  a non-existent list, depending on the context.
 404
 405    Error : constant Node_Id := Node_Low_Bound + 1;
 406    --  Used to indicate an error in the source program. A node is actually
 407    --  allocated with this Id value, so that Nkind (Error) = N_Error.
 408
 409    Empty_Or_Error : constant Node_Id := Error;
 410    --  Since Empty and Error are the first two Node_Id values, the test for
 411    --  N <= Empty_Or_Error tests to see if N is Empty or Error. This definition
 412    --  provides convenient self-documentation for such tests.
 413
 414    First_Node_Id  : constant Node_Id := Node_Low_Bound;
 415    --  Subscript of first allocated node. Note that Empty and Error are both
 416    --  allocated nodes, whose Nkind fields can be accessed without error.
 417
 418    ------------------------------
 419    -- Types for Nlists Package --
 420    ------------------------------
 421
 422    --  List_Id values are used to identify node lists stored in the tree, so
 423    --  that each node can be on at most one such list (see package Nlists for
 424    --  further details). Note that the special value Error_List is a subscript
 425    --  in this table, but the value No_List is *not* a valid subscript, and any
 426    --  attempt to apply list operations to No_List will cause a (detected)
 427    --  error.
 428
 429    type List_Id is range List_Low_Bound .. List_High_Bound;
 430    --  Type used to identify a node list
 431
 432    No_List : constant List_Id := List_High_Bound;
 433    --  Used to indicate absence of a list. Note that the value is zero, which
 434    --  is the same as Empty, which is helpful in initializing nodes where a
 435    --  value of zero can represent either an empty node or an empty list.
 436
 437    Error_List : constant List_Id := List_Low_Bound;
 438    --  Used to indicate that there was an error in the source program in a
 439    --  context which would normally require a list. This node appears to be
 440    --  an empty list to the list operations (a null list is actually allocated
 441    --  which has this Id value).
 442
 443    First_List_Id : constant List_Id := Error_List;
 444    --  Subscript of first allocated list header
 445
 446    ------------------------------
 447    -- Types for Elists Package --
 448    ------------------------------
 449
 450    --  Element list Id values are used to identify element lists stored outside
 451    --  of the tree, allowing nodes to be members of more than one such list
 452    --  (see package Elists for further details).
 453
 454    type Elist_Id is range Elist_Low_Bound .. Elist_High_Bound;
 455    --  Type used to identify an element list (Elist header table subscript)
 456
 457    No_Elist : constant Elist_Id := Elist_Low_Bound;
 458    --  Used to indicate absence of an element list. Note that this is not an
 459    --  actual Elist header, so element list operations on this value are not
 460    --  valid.
 461
 462    First_Elist_Id : constant Elist_Id := No_Elist + 1;
 463    --  Subscript of first allocated Elist header
 464
 465    --  Element Id values are used to identify individual elements of an element
 466    --  list (see package Elists for further details).
 467
 468    type Elmt_Id is range Elmt_Low_Bound .. Elmt_High_Bound;
 469    --  Type used to identify an element list
 470
 471    No_Elmt : constant Elmt_Id := Elmt_Low_Bound;
 472    --  Used to represent empty element
 473
 474    First_Elmt_Id : constant Elmt_Id := No_Elmt + 1;
 475    --  Subscript of first allocated Elmt table entry
 476
 477    -------------------------------
 478    -- Types for Stringt Package --
 479    -------------------------------
 480
 481    --  String_Id values are used to identify entries in the strings table. They
 482    --  are subscripts into the Strings table defined in package Stringt.
 483
 484    --  Note that with only a few exceptions, which are clearly documented, the
 485    --  type String_Id should be regarded as a private type. In particular it is
 486    --  never appropriate to perform arithmetic operations using this type.
 487    --  Doesn't this also apply to all other *_Id types???
 488
 489    type String_Id is range Strings_Low_Bound .. Strings_High_Bound;
 490    --  Type used to identify entries in the strings table
 491
 492    No_String : constant String_Id := Strings_Low_Bound;
 493    --  Used to indicate missing string Id. Note that the value zero is used
 494    --  to indicate a missing data value for all the Int types in this section.
 495
 496    First_String_Id : constant String_Id := No_String + 1;
 497    --  First subscript allocated in string table
 498
 499    -------------------------
 500    -- Character Code Type --
 501    -------------------------
 502
 503    --  The type Char is used for character data internally in the compiler, but
 504    --  character codes in the source are represented by the Char_Code type.
 505    --  Each character literal in the source is interpreted as being one of the
 506    --  16#7FFF_FFFF# possible Wide_Wide_Character codes, and a unique Integer
 507    --  value is assigned, corresponding to the UTF-32 value, which also
 508    --  corresponds to the Pos value in the Wide_Wide_Character type, and also
 509    --  corresponds to the Pos value in the Wide_Character and Character types
 510    --  for values that are in appropriate range. String literals are similarly
 511    --  interpreted as a sequence of such codes.
 512
 513    type Char_Code_Base is mod 2 ** 32;
 514    for Char_Code_Base'Size use 32;
 515
 516    subtype Char_Code is Char_Code_Base range 0 .. 16#7FFF_FFFF#;
 517    for Char_Code'Value_Size use 32;
 518    for Char_Code'Object_Size use 32;
 519
 520    function Get_Char_Code (C : Character) return Char_Code;
 521    pragma Inline (Get_Char_Code);
 522    --  Function to obtain internal character code from source character. For
 523    --  the moment, the internal character code is simply the Pos value of the
 524    --  input source character, but we provide this interface for possible
 525    --  later support of alternative character sets.
 526
 527    function In_Character_Range (C : Char_Code) return Boolean;
 528    pragma Inline (In_Character_Range);
 529    --  Determines if the given character code is in range of type Character,
 530    --  and if so, returns True. If not, returns False.
 531
 532    function In_Wide_Character_Range (C : Char_Code) return Boolean;
 533    pragma Inline (In_Wide_Character_Range);
 534    --  Determines if the given character code is in range of the type
 535    --  Wide_Character, and if so, returns True. If not, returns False.
 536
 537    function Get_Character (C : Char_Code) return Character;
 538    pragma Inline (Get_Character);
 539    --  For a character C that is in Character range (see above function), this
 540    --  function returns the corresponding Character value. It is an error to
 541    --  call Get_Character if C is not in Character range.
 542
 543    function Get_Wide_Character (C : Char_Code) return Wide_Character;
 544    --  For a character C that is in Wide_Character range (see above function),
 545    --  this function returns the corresponding Wide_Character value. It is an
 546    --  error to call Get_Wide_Character if C is not in Wide_Character range.
 547
 548    ---------------------------------------
 549    -- Types used for Library Management --
 550    ---------------------------------------
 551
 552    type Unit_Number_Type is new Int;
 553    --  Unit number. The main source is unit 0, and subsidiary sources have
 554    --  non-zero numbers starting with 1. Unit numbers are used to index the
 555    --  Units table in package Lib.
 556
 557    Main_Unit : constant Unit_Number_Type := 0;
 558    --  Unit number value for main unit
 559
 560    No_Unit : constant Unit_Number_Type := -1;
 561    --  Special value used to signal no unit
 562
 563    type Source_File_Index is new Int range -1 .. Int'Last;
 564    --  Type used to index the source file table (see package Sinput)
 565
 566    Internal_Source_File : constant Source_File_Index :=
 567                             Source_File_Index'First;
 568    --  Value used to indicate the buffer for the source-code-like strings
 569    --  internally created withing the compiler (see package Sinput)
 570
 571    No_Source_File : constant Source_File_Index := 0;
 572    --  Value used to indicate no source file present
 573
 574    -----------------------------------
 575    -- Representation of Time Stamps --
 576    -----------------------------------
 577
 578    --  All compiled units are marked with a time stamp which is derived from
 579    --  the source file (we assume that the host system has the concept of a
 580    --  file time stamp which is modified when a file is modified). These
 581    --  time stamps are used to ensure consistency of the set of units that
 582    --  constitutes a library. Time stamps are 12 character strings with
 583    --  with the following format:
 584
 585    --     YYYYMMDDHHMMSS
 586
 587    --       YYYY   year
 588    --       MM     month (2 digits 01-12)
 589    --       DD     day (2 digits 01-31)
 590    --       HH     hour (2 digits 00-23)
 591    --       MM     minutes (2 digits 00-59)
 592    --       SS     seconds (2 digits 00-59)
 593
 594    --  In the case of Unix systems (and other systems which keep the time in
 595    --  GMT), the time stamp is the GMT time of the file, not the local time.
 596    --  This solves problems in using libraries across networks with clients
 597    --  spread across multiple time-zones.
 598
 599    Time_Stamp_Length : constant := 14;
 600    --  Length of time stamp value
 601
 602    subtype Time_Stamp_Index is Natural range 1 .. Time_Stamp_Length;
 603    type Time_Stamp_Type is new String (Time_Stamp_Index);
 604    --  Type used to represent time stamp
 605
 606    Empty_Time_Stamp : constant Time_Stamp_Type := (others => ' ');
 607    --  Value representing an empty or missing time stamp. Looks less than any
 608    --  real time stamp if two time stamps are compared. Note that although this
 609    --  is not private, clients should not rely on the exact way in which this
 610    --  string is represented, and instead should use the subprograms below.
 611
 612    Dummy_Time_Stamp : constant Time_Stamp_Type := (others => '0');
 613    --  This is used for dummy time stamp values used in the D lines for
 614    --  non-existent files, and is intended to be an impossible value.
 615
 616    function "="  (Left, Right : Time_Stamp_Type) return Boolean;
 617    function "<=" (Left, Right : Time_Stamp_Type) return Boolean;
 618    function ">=" (Left, Right : Time_Stamp_Type) return Boolean;
 619    function "<"  (Left, Right : Time_Stamp_Type) return Boolean;
 620    function ">"  (Left, Right : Time_Stamp_Type) return Boolean;
 621    --  Comparison functions on time stamps. Note that two time stamps are
 622    --  defined as being equal if they have the same day/month/year and the
 623    --  hour/minutes/seconds values are within 2 seconds of one another. This
 624    --  deals with rounding effects in library file time stamps caused by
 625    --  copying operations during installation. We have particularly noticed
 626    --  that WinNT seems susceptible to such changes.
 627    --
 628    --  Note : the Empty_Time_Stamp value looks equal to itself, and less than
 629    --  any non-empty time stamp value.
 630
 631    procedure Split_Time_Stamp
 632      (TS      : Time_Stamp_Type;
 633       Year    : out Nat;
 634       Month   : out Nat;
 635       Day     : out Nat;
 636       Hour    : out Nat;
 637       Minutes : out Nat;
 638       Seconds : out Nat);
 639    --  Given a time stamp, decompose it into its components
 640
 641    procedure Make_Time_Stamp
 642      (Year    : Nat;
 643       Month   : Nat;
 644       Day     : Nat;
 645       Hour    : Nat;
 646       Minutes : Nat;
 647       Seconds : Nat;
 648       TS      : out Time_Stamp_Type);
 649    --  Given the components of a time stamp, initialize the value
 650
 651    -----------------------------------------------
 652    -- Types used for Pragma Suppress Management --
 653    -----------------------------------------------
 654
 655    type Check_Id is new Nat;
 656    --  Type used to represent a check id
 657
 658    No_Check_Id         : constant := 0;
 659    --  Check_Id value used to indicate no check
 660
 661    Access_Check        : constant :=  1;
 662    Accessibility_Check : constant :=  2;
 663    Alignment_Check     : constant :=  3;
 664    Discriminant_Check  : constant :=  4;
 665    Division_Check      : constant :=  5;
 666    Elaboration_Check   : constant :=  6;
 667    Index_Check         : constant :=  7;
 668    Length_Check        : constant :=  8;
 669    Overflow_Check      : constant :=  9;
 670    Range_Check         : constant := 10;
 671    Storage_Check       : constant := 11;
 672    Tag_Check           : constant := 12;
 673    Validity_Check      : constant := 13;
 674    --  Values used to represent individual predefined checks
 675
 676    All_Checks          : constant := 14;
 677    --  Value used to represent All_Checks value
 678
 679    subtype Predefined_Check_Id is Check_Id range 1 .. All_Checks;
 680    --  Subtype for predefined checks, including All_Checks
 681
 682    --  The following array contains an entry for each recognized check name
 683    --  for pragma Suppress. It is used to represent current settings of scope
 684    --  based suppress actions from pragma Suppress or command line settings.
 685
 686    --  Note: when Suppress_Array (All_Checks) is True, then generally all other
 687    --  specific check entries are set True, except for the Elaboration_Check
 688    --  entry which is set only if an explicit Suppress for this check is given.
 689    --  The reason for this non-uniformity is that we do not want All_Checks to
 690    --  suppress elaboration checking when using the static elaboration model.
 691    --  We recognize only an explicit suppress of Elaboration_Check as a signal
 692    --  that the static elaboration checking should skip a compile time check.
 693
 694    type Suppress_Array is array (Predefined_Check_Id) of Boolean;
 695    pragma Pack (Suppress_Array);
 696
 697    --  To add a new check type to GNAT, the following steps are required:
 698
 699    --    1.  Add an entry to Snames spec and body for the new name
 700    --    2.  Add an entry to the definition of Check_Id above
 701    --    3.  Add a new function to Checks to handle the new check test
 702    --    4.  Add a new Do_xxx_Check flag to Sinfo (if required)
 703    --    5.  Add appropriate checks for the new test
 704
 705    -----------------------------------
 706    -- Global Exception Declarations --
 707    -----------------------------------
 708
 709    --  This section contains declarations of exceptions that are used
 710    --  throughout the compiler or in other GNAT tools.
 711
 712    Unrecoverable_Error : exception;
 713    --  This exception is raised to immediately terminate the compilation of the
 714    --  current source program. Used in situations where things are bad enough
 715    --  that it doesn't seem worth continuing (e.g. max errors reached, or a
 716    --  required file is not found). Also raised when the compiler finds itself
 717    --  in trouble after an error (see Comperr).
 718
 719    Terminate_Program : exception;
 720    --  This exception is raised to immediately terminate the tool being
 721    --  executed. Each tool where this exception may be raised must have a
 722    --  single exception handler that contains only a null statement and that is
 723    --  the last statement of the program. If needed, procedure Set_Exit_Status
 724    --  is called with the appropriate exit status before raising
 725    --  Terminate_Program.
 726
 727    ---------------------------------
 728    -- Parameter Mechanism Control --
 729    ---------------------------------
 730
 731    --  Function and parameter entities have a field that records the passing
 732    --  mechanism. See specification of Sem_Mech for full details. The following
 733    --  subtype is used to represent values of this type:
 734
 735    subtype Mechanism_Type is Int range -18 .. Int'Last;
 736    --  Type used to represent a mechanism value. This is a subtype rather than
 737    --  a type to avoid some annoying processing problems with certain routines
 738    --  in Einfo (processing them to create the corresponding C).
 739
 740    ------------------------------
 741    -- Run-Time Exception Codes --
 742    ------------------------------
 743
 744    --  When the code generator generates a run-time exception, it provides a
 745    --  reason code which is one of the following. This reason code is used to
 746    --  select the appropriate run-time routine to be called, determining both
 747    --  the exception to be raised, and the message text to be added.
 748
 749    --  The prefix CE/PE/SE indicates the exception to be raised
 750    --    CE = Constraint_Error
 751    --    PE = Program_Error
 752    --    SE = Storage_Error
 753
 754    --  The remaining part of the name indicates the message text to be added,
 755    --  where all letters are lower case, and underscores are converted to
 756    --  spaces (for example CE_Invalid_Data adds the text "invalid data").
 757
 758    --  To add a new code, you need to do the following:
 759
 760    --    1. Modify the type and subtype declarations below appropriately,
 761    --       keeping things in alphabetical order.
 762
 763    --    2. Modify the corresponding definitions in types.h, including the
 764    --       definition of last_reason_code.
 765
 766    --    3. Add a new routine in Ada.Exceptions with the appropriate call and
 767    --       static string constant. Note that there is more than one version
 768    --       of a-except.adb which must be modified.
 769
 770    type RT_Exception_Code is
 771      (CE_Access_Check_Failed,            -- 00
 772       CE_Access_Parameter_Is_Null,       -- 01
 773       CE_Discriminant_Check_Failed,      -- 02
 774       CE_Divide_By_Zero,                 -- 03
 775       CE_Explicit_Raise,                 -- 04
 776       CE_Index_Check_Failed,             -- 05
 777       CE_Invalid_Data,                   -- 06
 778       CE_Length_Check_Failed,            -- 07
 779       CE_Null_Exception_Id,              -- 08
 780       CE_Null_Not_Allowed,               -- 09
 781       CE_Overflow_Check_Failed,          -- 10
 782       CE_Partition_Check_Failed,         -- 11
 783       CE_Range_Check_Failed,             -- 12
 784       CE_Tag_Check_Failed,               -- 13
 785
 786       PE_Access_Before_Elaboration,      -- 14
 787       PE_Accessibility_Check_Failed,     -- 15
 788       PE_Address_Of_Intrinsic,           -- 16
 789       PE_All_Guards_Closed,              -- 17
 790       PE_Current_Task_In_Entry_Body,     -- 18
 791       PE_Duplicated_Entry_Address,       -- 19
 792       PE_Explicit_Raise,                 -- 20
 793       PE_Finalize_Raised_Exception,      -- 21
 794       PE_Implicit_Return,                -- 22
 795       PE_Misaligned_Address_Value,       -- 23
 796       PE_Missing_Return,                 -- 24
 797       PE_Overlaid_Controlled_Object,     -- 25
 798       PE_Potentially_Blocking_Operation, -- 26
 799       PE_Stubbed_Subprogram_Called,      -- 27
 800       PE_Unchecked_Union_Restriction,    -- 28
 801       PE_Non_Transportable_Actual,       -- 29
 802
 803       SE_Empty_Storage_Pool,             -- 30
 804       SE_Explicit_Raise,                 -- 31
 805       SE_Infinite_Recursion,             -- 32
 806       SE_Object_Too_Large);              -- 33
 807
 808    subtype RT_CE_Exceptions is RT_Exception_Code range
 809      CE_Access_Check_Failed ..
 810      CE_Tag_Check_Failed;
 811
 812    subtype RT_PE_Exceptions is RT_Exception_Code range
 813      PE_Access_Before_Elaboration ..
 814      PE_Non_Transportable_Actual;
 815
 816    subtype RT_SE_Exceptions is RT_Exception_Code range
 817      SE_Empty_Storage_Pool ..
 818      SE_Object_Too_Large;
 819
 820 end Types;