gcc/ada/lib-load.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . L O A D                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This child package contains the function used to load a separately
  27 --  compiled unit, as well as the routine used to initialize the unit
  28 --  table and load the main source file.
  29
  30 package Lib.Load is
  31
  32    -------------------------------
  33    -- Handling of Renamed Units --
  34    -------------------------------
  35
  36    --  A compilation unit can be a renaming of another compilation unit.
  37    --  Such renamed units are not allowed as parent units, that is you
  38    --  cannot declare a unit:
  39
  40    --     with x;
  41    --     package x.y is end;
  42
  43    --  where x is a renaming of some other package. However you can refer
  44    --  to a renamed unit in a with clause:
  45
  46    --     package p is end;
  47
  48    --     package p.q is end;
  49
  50    --     with p;
  51    --     package pr renames p;
  52
  53    --     with pr.q ....
  54
  55    --  This means that in the context of a with clause, the normal fixed
  56    --  correspondence between unit and file names is broken. In the above
  57    --  example, there is no file named pr-q.ads, since the actual child
  58    --  unit is p.q, and it will be found in file p-q.ads.
  59
  60    --  In order to deal with this case, we have to first load pr.ads, and
  61    --  then discover that it is a renaming of p, so that we know that pr.q
  62    --  really refers to p.q. Furthermore this can happen at any level:
  63
  64    --     with p.q;
  65    --     package p.r renames p.q;
  66
  67    --     with p.q;
  68    --     package p.q.s is end;
  69
  70    --     with p.r.s ...
  71
  72    --  Now we have a case where the parent p.r is a child unit and is
  73    --  a renaming. This shows that renaming can occur at any level.
  74
  75    --  Finally, consider:
  76
  77    --     with pr.q.s ...
  78
  79    --  Here the parent pr.q is not itself a renaming, but it really refers
  80    --  to the unit p.q, and again we cannot know this without loading the
  81    --  parent. The bottom line here is that while the file name of a unit
  82    --  always corresponds to the unit name, the unit name as given to the
  83    --  Load_Unit function may not be the real unit.
  84
  85    -----------------
  86    -- Subprograms --
  87    -----------------
  88
  89    procedure Initialize;
  90    --  Initialize internal tables
  91
  92    procedure Initialize_Version (U : Unit_Number_Type);
  93    --  This is called once the source file corresponding to unit U has been
  94    --  fully scanned. At that point the checksum is computed, and can be used
  95    --  to initialize the version number.
  96
  97    procedure Load_Main_Source;
  98    --  Called at the start of compiling a new main source unit to initialize
  99    --  the library processing for the new main source. Establishes and
 100    --  initializes the units table entry for the new main unit (leaving
 101    --  the Unit_File_Name entry of Main_Unit set to No_File if there are no
 102    --  more files. Otherwise the main source file has been opened and read
 103    --  and then closed on return.
 104
 105    function Load_Unit
 106      (Load_Name         : Unit_Name_Type;
 107       Required          : Boolean;
 108       Error_Node        : Node_Id;
 109       Subunit           : Boolean;
 110       Corr_Body         : Unit_Number_Type := No_Unit;
 111       Renamings         : Boolean          := False;
 112       With_Node         : Node_Id          := Empty) return Unit_Number_Type;
 113    --  This function loads and parses the unit specified by Load_Name (or
 114    --  returns the unit number for the previously constructed units table
 115    --  entry if this is not the first call for this unit). Required indicates
 116    --  the behavior on a file not found condition, as further described below,
 117    --  and Error_Node is the node in the calling program to which error
 118    --  messages are to be attached.
 119    --
 120    --  If the corresponding file is found, the value returned by Load is the
 121    --  unit number that indexes the corresponding entry in the units table. If
 122    --  a serious enough parser error occurs to prevent subsequent semantic
 123    --  analysis, then the Fatal_Error flag of the returned entry is set and
 124    --  in addition, the fatal error flag of the calling unit is also set.
 125    --
 126    --  If the corresponding file is not found, then the behavior depends on
 127    --  the setting of Required. If Required is False, then No_Unit is returned
 128    --  and no error messages are issued. If Required is True, then an error
 129    --  message is posted, and No_Unit is returned.
 130    --
 131    --  A special case arises in the call from Rtsfind, where Error_Node is set
 132    --  to Empty. In this case Required is False, and the caller in any case
 133    --  treats any error as fatal.
 134    --
 135    --  The Subunit parameter is True to load a subunit, and False to load
 136    --  any other kind of unit (including all specs, package bodies, and
 137    --  subprogram bodies).
 138    --
 139    --  The Corr_Body argument is normally defaulted. It is set only in the
 140    --  case of loading the corresponding spec when the main unit is a body.
 141    --  In this case, Corr_Body is the unit number of this corresponding
 142    --  body. This is used to set the Serial_Ref_Unit field of the unit
 143    --  table entry. It is also used to deal with the special processing
 144    --  required by RM 10.1.4(4). See description in lib.ads.
 145    --
 146    --  Renamings activates the handling of renamed units as separately
 147    --  described in the documentation of this unit. If this parameter is
 148    --  set to True, then Load_Name may not be the real unit name and it
 149    --  is necessary to load parents to find the real name.
 150    --
 151    --  With_Node is set to the with_clause or limited_with_clause causing
 152    --  the unit to be loaded, and is used to bypass the circular dependency
 153    --  check in the case of a limited_with_clause (Ada 2005, AI-50217).
 154
 155    procedure Change_Main_Unit_To_Spec;
 156    --  This procedure is called if the main unit file contains a No_Body pragma
 157    --  and no other tokens. The effect is, if possible, to change the main unit
 158    --  from the body it references now, to the corresponding spec. This has the
 159    --  effect of ignoring the body, which is what we want. If it is impossible
 160    --  to successfully make the change, then the call has no effect, and the
 161    --  file is unchanged (this will lead to an error complaining about the
 162    --  inappropriate No_Body spec).
 163
 164    function Create_Dummy_Package_Unit
 165      (With_Node : Node_Id;
 166       Spec_Name : Unit_Name_Type) return Unit_Number_Type;
 167    --  With_Node is the Node_Id of a with statement for which the file could
 168    --  not be found, and Spec_Name is the corresponding unit name. This call
 169    --  creates a dummy package unit so that compilation can continue without
 170    --  blowing up when the missing unit is referenced.
 171
 172    procedure Make_Child_Decl_Unit (N : Node_Id);
 173    --  For a child subprogram body without a spec, we create a subprogram
 174    --  declaration in order to attach the required parent link. We create
 175    --  a Units_Table entry for this declaration, in order to maintain a
 176    --  one-to-one correspondence between compilation units and table entries.
 177
 178    procedure Make_Instance_Unit (N : Node_Id; In_Main : Boolean);
 179    --  When a compilation unit is an instantiation, it contains both the
 180    --  declaration and the body of the instance, each of which can have its
 181    --  own elaboration routine. The file itself corresponds to the declaration.
 182    --  We create an additional entry for the body, so that the binder can
 183    --  generate the proper elaboration calls to both. The argument N is the
 184    --  compilation unit node created for the body.
 185    --
 186    --  If the instance is not the main program, we still generate the instance
 187    --  body even though we do not generate code for it. In that case we still
 188    --  generate a compilation unit node for it, and we need to make an entry
 189    --  for it in the units table, so as to maintain a one-to-one mapping
 190    --  between table and nodes. The table entry is used among other things to
 191    --  provide a canonical traversal order for context units for Inspector.
 192    --  The flag In_Main indicates whether the instance is the main unit.
 193
 194    procedure Version_Update (U : Node_Id; From : Node_Id);
 195    --  This routine is called when unit U is found to be semantically
 196    --  dependent on unit From. It updates the version of U to register
 197    --  dependence on the version of From. The arguments are compilation
 198    --  unit nodes for the relevant library nodes.
 199
 200 end Lib.Load;