gcc/ada/g-boubuf.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                  G N A T . B O U N D E D _ B U F F E R S                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                     Copyright (C) 2003-2006, AdaCore                     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package provides a thread-safe generic bounded buffer abstraction.
  35 --  Instances are useful directly or as parts of the implementations of other
  36 --  abstractions, such as mailboxes.
  37
  38 --  Bounded_Buffer is declared explicitly as a protected type, rather than as
  39 --  a simple limited private type completed as a protected type, so that
  40 --  clients may make calls accordingly (i.e., conditional/timed entry calls).
  41
  42 with System;
  43
  44 generic
  45    type Element is private;
  46    --  The type of the values contained within buffer objects
  47
  48 package GNAT.Bounded_Buffers is
  49    pragma Pure;
  50
  51    type Content is array (Positive range <>) of Element;
  52    --  Content is an internal artefact that cannot be hidden because protected
  53    --  types cannot contain type declarations.
  54
  55    Default_Ceiling : constant System.Priority := System.Default_Priority;
  56    --  A convenience value for the Ceiling discriminant
  57
  58    protected type Bounded_Buffer
  59       (Capacity : Positive;
  60       --  Objects of type Bounded_Buffer specify the maximum number of Element
  61       --  values they can hold via the discriminant Capacity.
  62
  63       Ceiling : System.Priority)
  64       --  Users must specify the ceiling priority for the object. If the
  65       --  Real-Time Systems Annex is not in use this value is not important.
  66    is
  67       pragma Priority (Ceiling);
  68
  69       entry Insert (Item : Element);
  70       --  Insert Item into the buffer, blocks caller until space is available
  71
  72       entry Remove (Item : out Element);
  73       --  Remove next available Element from buffer. Blocks caller until an
  74       --  Element is available.
  75
  76       function Empty return Boolean;
  77       --  Returns whether the instance contains any Elements.
  78       --  Note: State may change immediately after call returns.
  79
  80       function Full return Boolean;
  81       --  Returns whether any space remains within the instance.
  82       --  Note: State may change immediately after call returns.
  83
  84       function Extent return Natural;
  85       --  Returns the number of Element values currently held
  86       --  within the instance.
  87       --  Note: State may change immediately after call returns.
  88
  89    private
  90       Values   : Content (1 .. Capacity);
  91       --  The container for the values held by the buffer instance
  92
  93       Next_In  : Positive := 1;
  94       --  The index of the next Element inserted. Wraps around
  95
  96       Next_Out : Positive := 1;
  97       --  The index of the next Element removed. Wraps around
  98
  99       Count    : Natural  := 0;
 100       --  The number of Elements currently held
 101    end Bounded_Buffer;
 102
 103 end GNAT.Bounded_Buffers;