gcc/ada/s-strcom.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --                S Y S T E M . S T R I N G _ C O M P A R E                 --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 pragma Compiler_Unit_Warning;
  33
  34 with Ada.Unchecked_Conversion;
  35
  36 package body System.String_Compare is
  37
  38    type Word is mod 2 ** 32;
  39    --  Used to process operands by words
  40
  41    type Big_Words is array (Natural) of Word;
  42    type Big_Words_Ptr is access Big_Words;
  43    for Big_Words_Ptr'Storage_Size use 0;
  44    --  Array type used to access by words
  45
  46    type Byte is mod 2 ** 8;
  47    --  Used to process operands by bytes
  48
  49    type Big_Bytes is array (Natural) of Byte;
  50    type Big_Bytes_Ptr is access Big_Bytes;
  51    for Big_Bytes_Ptr'Storage_Size use 0;
  52    --  Array type used to access by bytes
  53
  54    function To_Big_Words is new
  55      Ada.Unchecked_Conversion (System.Address, Big_Words_Ptr);
  56
  57    function To_Big_Bytes is new
  58      Ada.Unchecked_Conversion (System.Address, Big_Bytes_Ptr);
  59
  60    -----------------
  61    -- Str_Compare --
  62    -----------------
  63
  64    function Str_Compare
  65      (Left      : System.Address;
  66       Right     : System.Address;
  67       Left_Len  : Natural;
  68       Right_Len : Natural) return Integer
  69    is
  70       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
  71
  72    begin
  73       --  If operands are non-aligned, or length is too short, go by bytes
  74
  75       if (((Left or Right) and 2#11#) /= 0) or else Compare_Len < 4 then
  76          return Str_Compare_Bytes (Left, Right, Left_Len, Right_Len);
  77       end if;
  78
  79       --  Here we can go by words
  80
  81       declare
  82          LeftP  : constant Big_Words_Ptr := To_Big_Words (Left);
  83          RightP : constant Big_Words_Ptr := To_Big_Words (Right);
  84          Clen4  : constant Natural       := Compare_Len / 4 - 1;
  85          Clen4F : constant Natural       := Clen4 * 4;
  86
  87       begin
  88          for J in 0 .. Clen4 loop
  89             if LeftP (J) /= RightP (J) then
  90                return Str_Compare_Bytes
  91                         (Left  + Address (4 * J),
  92                          Right + Address (4 * J),
  93                          4, 4);
  94             end if;
  95          end loop;
  96
  97          return Str_Compare_Bytes
  98                   (Left      + Address (Clen4F),
  99                    Right     + Address (Clen4F),
 100                    Left_Len  - Clen4F,
 101                    Right_Len - Clen4F);
 102       end;
 103    end Str_Compare;
 104
 105    -----------------------
 106    -- Str_Compare_Bytes --
 107    -----------------------
 108
 109    function Str_Compare_Bytes
 110      (Left      : System.Address;
 111       Right     : System.Address;
 112       Left_Len  : Natural;
 113       Right_Len : Natural) return Integer
 114    is
 115       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
 116
 117       LeftP  : constant Big_Bytes_Ptr := To_Big_Bytes (Left);
 118       RightP : constant Big_Bytes_Ptr := To_Big_Bytes (Right);
 119
 120    begin
 121       for J in 0 .. Compare_Len - 1 loop
 122          if LeftP (J) /= RightP (J) then
 123             if LeftP (J) > RightP (J) then
 124                return +1;
 125             else
 126                return -1;
 127             end if;
 128          end if;
 129       end loop;
 130
 131       if Left_Len = Right_Len then
 132          return 0;
 133       elsif Left_Len > Right_Len then
 134          return +1;
 135       else
 136          return -1;
 137       end if;
 138    end Str_Compare_Bytes;
 139
 140 end System.String_Compare;