libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=10:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$GOC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124
 125 # See if the user wants to configure without libatomic. This is useful if we are
 126 # on an architecture for which libgo does not need an atomic support library and
 127 # libatomic does not support our C compiler.
 128 AC_ARG_WITH(libatomic,
 129   AS_HELP_STRING([--without-libatomic],
 130                  [don't use libatomic]),
 131   [:],
 132   [with_libatomic=${with_libatomic_default-yes}])
 133
 134 LIBATOMIC=
 135 if test "$with_libatomic" != no; then
 136    LIBATOMIC=../libatomic/libatomic_convenience.la
 137 fi
 138 AC_SUBST(LIBATOMIC)
 139
 140 # Used to tell GNU make to include a file without telling automake to
 141 # include it.
 142 go_include="-include"
 143 AC_SUBST(go_include)
 144
 145 is_darwin=no
 146 is_freebsd=no
 147 is_irix=no
 148 is_linux=no
 149 is_netbsd=no
 150 is_openbsd=no
 151 is_dragonfly=no
 152 is_rtems=no
 153 is_solaris=no
 154 GOOS=unknown
 155 case ${host} in
 156   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 157   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 158   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 159   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 160   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 161   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 162   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 163   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 164   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 165 esac
 166 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 167 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 168 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 169 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 170 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 171 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 172 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 173 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 174 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 175 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 176 AC_SUBST(GOOS)
 177
 178 dnl Test whether we need to use DejaGNU or whether we can use the
 179 dnl simpler gotest approach.  We can only use gotest for a native
 180 dnl build.
 181 USE_DEJAGNU=no
 182 case ${host} in
 183   *-*-rtems*) USE_DEJAGNU=yes ;;
 184   ${build}) ;;
 185   *) USE_DEJAGNU=yes ;;
 186 esac
 187 AC_SUBST(USE_DEJAGNU)
 188
 189 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 190 is_386=no
 191 is_alpha=no
 192 is_arm=no
 193 is_arm64=no
 194 is_ia64=no
 195 is_m68k=no
 196 mips_abi=unknown
 197 is_ppc=no
 198 is_ppc64=no
 199 is_ppc64le=no
 200 is_s390=no
 201 is_s390x=no
 202 is_sparc=no
 203 is_sparc64=no
 204 is_x86_64=no
 205 GOARCH=unknown
 206 case ${host} in
 207   alpha*-*-*)
 208     is_alpha=yes
 209     GOARCH=alpha
 210     ;;
 211   aarch64-*-*)
 212     is_arm64=yes
 213     GOARCH=arm64
 214     ;;
 215   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 216     is_arm=yes
 217     GOARCH=arm
 218     ;;
 219 changequote(,)dnl
 220   i[34567]86-*-* | x86_64-*-*)
 221 changequote([,])dnl
 222     AC_COMPILE_IFELSE([
 223 #ifdef __x86_64__
 224 #error 64-bit
 225 #endif],
 226 [is_386=yes], [is_x86_64=yes])
 227     if test "$is_386" = "yes"; then
 228       GOARCH=386
 229     else
 230       GOARCH=amd64
 231     fi
 232     ;;
 233   ia64-*-*)
 234     is_ia64=yes
 235     GOARCH=ia64
 236     ;;
 237   m68k*-*-*)
 238     is_m68k=yes
 239     GOARCH=m68k
 240     ;;
 241   mips*-*-*)
 242     AC_COMPILE_IFELSE([
 243 #if _MIPS_SIM != _ABIO32
 244 #error not o32
 245 #endif],
 246 [mips_abi="o32"],
 247         [AC_COMPILE_IFELSE([
 248 #if _MIPS_SIM != _ABIN32
 249 #error not n32
 250 #endif],
 251 [mips_abi="n32"],
 252         [AC_COMPILE_IFELSE([
 253 #if _MIPS_SIM != _ABI64
 254 #error not n64
 255 #endif],
 256 [mips_abi="n64"],
 257         [AC_COMPILE_IFELSE([
 258 #if _MIPS_SIM != _ABIO64
 259 #error not o64
 260 #endif],
 261 [mips_abi="o64"],
 262         [AC_MSG_ERROR([unknown MIPS ABI])
 263 [mips_abi="n32"]])])])])
 264     case "$mips_abi" in
 265     "o32") GOARCH=mipso32 ;;
 266     "n32") GOARCH=mipsn32 ;;
 267     "n64") GOARCH=mipsn64 ;;
 268     "o64") GOARCH=mipso64 ;;
 269     esac
 270     ;;
 271   rs6000*-*-* | powerpc*-*-*)
 272     AC_COMPILE_IFELSE([
 273 #ifdef _ARCH_PPC64
 274 #error 64-bit
 275 #endif],
 276 [is_ppc=yes],
 277     [AC_COMPILE_IFELSE([
 278 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 279 #error 64be
 280 #endif],
 281 [is_ppc64le=yes],[is_ppc64=yes])])
 282     if test "$is_ppc" = "yes"; then
 283       GOARCH=ppc
 284     elif test "$is_ppc64" = "yes"; then
 285       GOARCH=ppc64
 286     else
 287       GOARCH=ppc64le
 288     fi
 289     ;;
 290   s390*-*-*)
 291     AC_COMPILE_IFELSE([
 292 #if defined(__s390x__)
 293 #error 64-bit
 294 #endif],
 295 [is_s390=yes], [is_s390x=yes])
 296     if test "$is_s390" = "yes"; then
 297       GOARCH=s390
 298     else
 299       GOARCH=s390x
 300     fi
 301     ;;
 302   sparc*-*-*)
 303     AC_COMPILE_IFELSE([
 304 #if defined(__sparcv9) || defined(__arch64__)
 305 #error 64-bit
 306 #endif],
 307 [is_sparc=yes], [is_sparc64=yes])
 308     if test "$is_sparc" = "yes"; then
 309       GOARCH=sparc
 310     else
 311       GOARCH=sparc64
 312     fi
 313     ;;
 314 esac
 315 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 316 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 317 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 318 AM_CONDITIONAL(LIBGO_IS_ARM64, test $is_arm64 = yes)
 319 AM_CONDITIONAL(LIBGO_IS_IA64, test $is_ia64 = yes)
 320 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 321 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 322 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 323 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 324 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 325 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 326 AM_CONDITIONAL(LIBGO_IS_MIPS64, test $mips_abi = n64 -o $mips_abi = o64)
 327 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 328 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 329 AM_CONDITIONAL(LIBGO_IS_PPC64LE, test $is_ppc64le = yes)
 330 AM_CONDITIONAL(LIBGO_IS_S390, test $is_s390 = yes)
 331 AM_CONDITIONAL(LIBGO_IS_S390X, test $is_s390x = yes)
 332 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 333 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 334 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 335 AC_SUBST(GOARCH)
 336
 337 dnl Some files are only present when needed for specific architectures.
 338 GO_LIBCALL_OS_FILE=
 339 GO_LIBCALL_OS_ARCH_FILE=
 340 GO_SYSCALL_OS_FILE=
 341 GO_SYSCALL_OS_ARCH_FILE=
 342 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 343   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 344 fi
 345 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 346   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 347 fi
 348 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 349   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 350 fi
 351 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 352   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 353 fi
 354 AC_SUBST(GO_LIBCALL_OS_FILE)
 355 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 356 AC_SUBST(GO_SYSCALL_OS_FILE)
 357 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 358
 359 dnl Special flags used to generate sysinfo.go.
 360 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 361 case "$target" in
 362     mips-sgi-irix6.5*)
 363         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 364         # msghdr in <sys/socket.h>.
 365         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 366         ;;
 367     *-*-solaris2.1[[01]])
 368         # Solaris 10+ needs this so struct msghdr gets the msg_control
 369         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 370         # above doesn't work with C99.
 371         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 372         ;;
 373 esac
 374 AC_SUBST(OSCFLAGS)
 375
 376 dnl Use -fsplit-stack when compiling C code if available.
 377 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 378 [libgo_cv_c_split_stack_supported],
 379 [CFLAGS_hold=$CFLAGS
 380 CFLAGS="$CFLAGS -fsplit-stack"
 381 AC_COMPILE_IFELSE([[int i;]],
 382 [libgo_cv_c_split_stack_supported=yes],
 383 [libgo_cv_c_split_stack_supported=no])
 384 CFLAGS=$CFLAGS_hold])
 385
 386 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 387 dnl reject split-stack code calling non-split-stack code on targets
 388 dnl they don't support.
 389 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 390 [libgo_cv_c_linker_split_non_split],
 391 [cat > conftest1.c << EOF
 392 extern void f();
 393 int main() { f(); return 0; }
 394 EOF
 395 cat > conftest2.c << EOF
 396 void f() {}
 397 EOF
 398 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c
 399 $CC -c $CFLAGS $CPPFLAGS conftest2.c
 400 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext; then
 401   libgo_cv_c_linker_split_non_split=yes
 402 else
 403   libgo_cv_c_linker_split_non_split=no
 404 fi
 405 rm -f conftest1.* conftest2.* conftest])
 406
 407 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 408   SPLIT_STACK=-fsplit-stack
 409   AC_DEFINE(USING_SPLIT_STACK, 1,
 410                 [Define if the compiler supports -fsplit-stack])
 411 else
 412   SPLIT_STACK=
 413 fi
 414 AC_SUBST(SPLIT_STACK)
 415 AM_CONDITIONAL(USING_SPLIT_STACK,
 416         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 417
 418 dnl If the compiler supports split-stack but the linker does not, then
 419 dnl we need to explicitly disable split-stack for Go.
 420 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 421   GO_SPLIT_STACK=-fno-split-stack
 422 else
 423   GO_SPLIT_STACK=
 424 fi
 425 AC_SUBST(GO_SPLIT_STACK)
 426
 427 dnl Check whether the linker does stack munging when calling from
 428 dnl split-stack into non-split-stack code.  We check this by looking
 429 dnl at the --help output.  FIXME: This is only half right: it's
 430 dnl possible for the linker to support this for some targets but not
 431 dnl others.
 432 dnl This is slightly different from the above check, which is whether
 433 dnl the linker permits the call at all.
 434 AC_CACHE_CHECK([whether linker supports split stack],
 435 [libgo_cv_c_linker_supports_split_stack],
 436 [libgo_cv_c_linker_supports_split_stack=no
 437 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 438   libgo_cv_c_linker_supports_split_stack=yes
 439 fi])
 440 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 441   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 442             [Define if the linker support split stack adjustments])
 443 fi
 444
 445 AC_CACHE_CHECK([whether compiler is llgo],
 446 [libgo_cv_c_goc_is_llgo],
 447 [libgo_cv_c_goc_is_llgo=no
 448 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 449   libgo_cv_c_goc_is_llgo=yes
 450 fi])
 451 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 452
 453 dnl Test for the -lm library.
 454 MATH_LIBS=
 455 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 456 AC_SUBST(MATH_LIBS)
 457
 458 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 459 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 460   [libgo_cv_lib_sockets=
 461    libgo_check_both=no
 462    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 463    if test "$libgo_check_socket" = "yes"; then
 464      unset ac_cv_func_connect
 465      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 466                   libgo_check_both=yes)
 467    fi
 468    if test "$libgo_check_both" = "yes"; then
 469      libgo_old_libs=$LIBS
 470      LIBS="$LIBS -lsocket -lnsl"
 471      unset ac_cv_func_accept
 472      AC_CHECK_FUNC(accept,
 473                    [libgo_check_nsl=no
 474                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 475      unset ac_cv_func_accept
 476      LIBS=$libgo_old_libs
 477    fi
 478    unset ac_cv_func_gethostbyname
 479    libgo_old_libs="$LIBS"
 480    AC_CHECK_FUNC(gethostbyname, ,
 481                  [AC_CHECK_LIB(nsl, main,
 482                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 483    unset ac_cv_func_gethostbyname
 484    AC_CHECK_FUNC(sendfile, ,
 485                  [AC_CHECK_LIB(sendfile, main,
 486                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 487    LIBS=$libgo_old_libs
 488 ])
 489 NET_LIBS="$libgo_cv_lib_sockets"
 490 AC_SUBST(NET_LIBS)
 491
 492 dnl Test whether the compiler supports the -pthread option.
 493 AC_CACHE_CHECK([whether -pthread is supported],
 494 [libgo_cv_lib_pthread],
 495 [CFLAGS_hold=$CFLAGS
 496 CFLAGS="$CFLAGS -pthread"
 497 AC_COMPILE_IFELSE([[int i;]],
 498 [libgo_cv_lib_pthread=yes],
 499 [libgo_cv_lib_pthread=no])
 500 CFLAGS=$CFLAGS_hold])
 501 PTHREAD_CFLAGS=
 502 if test "$libgo_cv_lib_pthread" = yes; then
 503   PTHREAD_CFLAGS=-pthread
 504 fi
 505 AC_SUBST(PTHREAD_CFLAGS)
 506
 507 dnl Test for the -lpthread library.
 508 PTHREAD_LIBS=
 509 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 510 AC_SUBST(PTHREAD_LIBS)
 511
 512 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 513 AC_SEARCH_LIBS([sched_yield], [rt])
 514 AC_SEARCH_LIBS([nanosleep], [rt])
 515 AC_SEARCH_LIBS([clock_gettime], [rt])
 516
 517 AC_C_BIGENDIAN
 518
 519 GCC_CHECK_UNWIND_GETIPINFO
 520
 521 AC_CHECK_HEADERS(sched.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 522
 523 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 524 [#ifdef HAVE_SYS_SOCKET_H
 525 #include <sys/socket.h>
 526 #endif
 527 ])
 528
 529 AC_CACHE_CHECK([whether <ustat.h> can be used],
 530 [libgo_cv_c_ustat_h],
 531 [CFLAGS_hold=$CFLAGS
 532 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 533 AC_COMPILE_IFELSE(
 534 [AC_LANG_SOURCE([
 535 #include <sys/types.h>
 536 #ifdef HAVE_LINUX_FILTER_H
 537 #include <linux/filter.h>
 538 #endif
 539 #include <ustat.h>
 540 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 541 CFLAGS=$CFLAGS_hold])
 542 if test $libgo_cv_c_ustat_h = yes; then
 543   AC_DEFINE(HAVE_USTAT_H, 1,
 544     [Define to 1 if you have the <ustat.h> header file and it works.])
 545 fi
 546
 547 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 548
 549 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr)
 550 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 551 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 552
 553 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 554 AC_TYPE_OFF_T
 555 AC_CHECK_TYPES([loff_t])
 556
 557 LIBS_hold="$LIBS"
 558 LIBS="$LIBS -lm"
 559 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 560 LIBS="$LIBS_hold"
 561
 562 CFLAGS_hold="$CFLAGS"
 563 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 564 LIBS_hold="$LIBS"
 565 LIBS="$LIBS $PTHREAD_LIBS"
 566 AC_CHECK_FUNCS(sem_timedwait)
 567 CFLAGS="$CFLAGS_hold"
 568 LIBS="$LIBS_hold"
 569
 570 LIBS_hold="$LIBS"
 571 LIBS="$LIBS $MATH_LIBS"
 572 AC_CHECK_FUNCS(matherr)
 573 LIBS="$LIBS_hold"
 574
 575 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 576 [libgo_cv_func___sync_bool_compare_and_swap_4],
 577 [AC_LINK_IFELSE([
 578 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 579 uint32 i;
 580 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 581 ],
 582 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 583 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 584 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 585   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 586     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 587 fi
 588
 589 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 590 [libgo_cv_func___sync_bool_compare_and_swap_8],
 591 [AC_LINK_IFELSE([
 592 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 593 uint64 i;
 594 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 595 ],
 596 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 597 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 598 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 599   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 600     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 601 fi
 602
 603 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 604 [libgo_cv_func___sync_fetch_and_add_4],
 605 [AC_LINK_IFELSE([
 606 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 607 uint32 i;
 608 int main() { return __sync_fetch_and_add (&i, 1); }
 609 ],
 610 [libgo_cv_func___sync_fetch_and_add_4=yes],
 611 [libgo_cv_func___sync_fetch_and_add_4=no])])
 612 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 613   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 614     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 615 fi
 616
 617 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 618 [libgo_cv_func___sync_add_and_fetch_8],
 619 [AC_LINK_IFELSE([
 620 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 621 uint64 i;
 622 int main() { return __sync_add_and_fetch (&i, 1); }
 623 ],
 624 [libgo_cv_func___sync_add_and_fetch_8=yes],
 625 [libgo_cv_func___sync_add_and_fetch_8=no])])
 626 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 627   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 628     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 629 fi
 630
 631 dnl For x86 we want to use the -minline-all-stringops option to avoid
 632 dnl forcing a stack split when calling memcpy and friends.
 633 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 634 [libgo_cv_c_stringops],
 635 [CFLAGS_hold=$CFLAGS
 636 CFLAGS="$CFLAGS -minline-all-stringops"
 637 AC_COMPILE_IFELSE([int i;],
 638 [libgo_cv_c_stringops=yes],
 639 [libgo_cv_c_stringops=no])
 640 CFLAGS=$CFLAGS_hold])
 641 STRINGOPS_FLAG=
 642 if test "$libgo_cv_c_stringops" = yes; then
 643   STRINGOPS_FLAG=-minline-all-stringops
 644 fi
 645 AC_SUBST(STRINGOPS_FLAG)
 646
 647 dnl For x86 we want to compile the math library with -mfancy-math-387
 648 dnl -funsafe-math-optimizations so that we can use the builtin
 649 dnl instructions directly.
 650 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 651 [libgo_cv_c_fancymath],
 652 [CFLAGS_hold=$CFLAGS
 653 CFLAGS="$CFLAGS -mfancy-math-387"
 654 AC_COMPILE_IFELSE([int i;],
 655 [libgo_cv_c_fancymath=yes],
 656 [libgo_cv_c_fancymath=no])
 657 CFLAGS=$CFLAGS_hold])
 658 MATH_FLAG=
 659 if test "$libgo_cv_c_fancymath" = yes; then
 660   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 661 else
 662   MATH_FLAG="-ffp-contract=off"
 663 fi
 664 AC_SUBST(MATH_FLAG)
 665
 666 CFLAGS_hold=$CFLAGS
 667 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 668 AC_CHECK_TYPES([off64_t])
 669 CFLAGS=$CFLAGS_hold
 670
 671 dnl Work out the size of the epoll_events struct on GNU/Linux.
 672 AC_CACHE_CHECK([epoll_event size],
 673 [libgo_cv_c_epoll_event_size],
 674 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 675 [sizeof (struct epoll_event)],
 676 [#include <sys/epoll.h>],
 677 [libgo_cv_c_epoll_event_size=0])])
 678 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 679 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 680
 681 dnl Work out the offset of the fd field in the epoll_events struct on
 682 dnl GNU/Linux.
 683 AC_CACHE_CHECK([epoll_event data.fd offset],
 684 [libgo_cv_c_epoll_event_fd_offset],
 685 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 686 [offsetof (struct epoll_event, data.fd)],
 687 [#include <stddef.h>
 688 #include <sys/epoll.h>],
 689 [libgo_cv_c_epoll_event_fd_offset=0])])
 690 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 691 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 692
 693 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 694 dnl in Solaris 12 for XPG7 compatibility.
 695 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 696                 [have_stat_timespec=yes], [have_stat_timespec=no])
 697 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 698
 699 dnl See if struct exception is defined in <math.h>.
 700 AC_CHECK_TYPE([struct exception],
 701 [libgo_has_struct_exception=yes],
 702 [libgo_has_struct_exception=no],
 703 [#include <math.h>])
 704 if test "$libgo_has_struct_exception" = "yes"; then
 705   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 706             [Define to 1 if <math.h> defines struct exception])
 707 fi
 708
 709 dnl See whether setcontext changes the value of TLS variables.
 710 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 711 [libgo_cv_lib_setcontext_clobbers_tls],
 712 [CFLAGS_hold="$CFLAGS"
 713 CFLAGS="$PTHREAD_CFLAGS"
 714 LIBS_hold="$LIBS"
 715 LIBS="$LIBS $PTHREAD_LIBS"
 716 AC_CHECK_SIZEOF([void *])
 717 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 718 AC_RUN_IFELSE(
 719   [AC_LANG_SOURCE([
 720 #include <pthread.h>
 721 #include <stdlib.h>
 722 #include <ucontext.h>
 723 #include <unistd.h>
 724
 725 __thread int tls;
 726
 727 static char stack[[10 * 1024 * 1024]];
 728 static ucontext_t c;
 729
 730 /* Called via makecontext/setcontext.  */
 731
 732 static void
 733 cfn (void)
 734 {
 735   exit (tls);
 736 }
 737
 738 /* Called via pthread_create.  */
 739
 740 static void *
 741 tfn (void *dummy)
 742 {
 743   /* The thread should still see this value after calling
 744      setcontext.  */
 745   tls = 0;
 746
 747   setcontext (&c);
 748
 749   /* The call to setcontext should not return.  */
 750   abort ();
 751 }
 752
 753 int
 754 main ()
 755 {
 756   pthread_t tid;
 757
 758   /* The thread should not see this value.  */
 759   tls = 1;
 760
 761   if (getcontext (&c) < 0)
 762     abort ();
 763
 764   c.uc_stack.ss_sp = stack;
 765 #ifdef MAKECONTEXT_STACK_TOP
 766   c.uc_stack.ss_sp += sizeof stack;
 767 #endif
 768   c.uc_stack.ss_flags = 0;
 769   c.uc_stack.ss_size = sizeof stack;
 770   c.uc_link = NULL;
 771   makecontext (&c, cfn, 0);
 772
 773   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 774     abort ();
 775
 776   if (pthread_join (tid, NULL) != 0)
 777     abort ();
 778
 779   /* The thread should have called exit.  */
 780   abort ();
 781 }
 782 ])],
 783 [libgo_cv_lib_setcontext_clobbers_tls=no],
 784 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 785 [case "$target:$ptr_type_size" in
 786   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 787     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 788   *)
 789     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 790  esac
 791 ])
 792 CFLAGS="$CFLAGS_hold"
 793 LIBS="$LIBS_hold"
 794 ])
 795 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 796   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 797             [Define if setcontext clobbers TLS variables])
 798 fi
 799
 800 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 801 libgo_cv_ro_eh_frame, [
 802 libgo_cv_ro_eh_frame=no
 803 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 804 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 805   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 806     libgo_cv_ro_eh_frame=yes
 807   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 808        | grep -v '#write' > /dev/null; then
 809     libgo_cv_ro_eh_frame=yes
 810   fi
 811 fi
 812 rm -f conftest.*
 813 ])
 814 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 815   AC_DEFINE(EH_FRAME_FLAGS, "a",
 816             [Define to the flags needed for the .section .eh_frame directive.])
 817 else
 818   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 819             [Define to the flags needed for the .section .eh_frame directive.])
 820 fi
 821
 822 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 823 [libgo_cv_c_unused_arguments],
 824 [CFLAGS_hold=$CFLAGS
 825 CFLAGS="$CFLAGS -Qunused-arguments"
 826 AC_COMPILE_IFELSE([[int i;]],
 827 [libgo_cv_c_unused_arguments=yes],
 828 [libgo_cv_c_unused_arguments=no])
 829 CFLAGS=$CFLAGS_hold])
 830
 831 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 832 libgo_cv_as_comdat_gnu, [
 833 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 834 CFLAGS_hold=$CFLAGS
 835 if test "$libgo_cv_c_unused_arguments" = yes; then
 836   CFLAGS="$CFLAGS -Qunused-arguments"
 837 fi
 838 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 839   libgo_cv_as_comdat_gnu=yes
 840 else
 841   libgo_cv_as_comdat_gnu=no
 842 fi
 843 CFLAGS=$CFLAGS_hold
 844 ])
 845 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 846   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 847             [Define if your assembler supports GNU comdat group syntax.])
 848 fi
 849
 850 AC_CACHE_CHECK([assembler supports pc related relocs],
 851 libgo_cv_as_x86_pcrel, [
 852 libgo_cv_as_x86_pcrel=yes
 853 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 854 CFLAGS_hold=$CFLAGS
 855 if test "$libgo_cv_c_unused_arguments" = yes; then
 856   CFLAGS="$CFLAGS -Qunused-arguments"
 857 fi
 858 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 859     libgo_cv_as_x86_pcrel=no
 860 fi
 861 CFLAGS=$CFLAGS_hold
 862 ])
 863 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 864   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 865             [Define if your assembler supports PC relative relocs.])
 866 fi
 867
 868 AC_CACHE_CHECK([assembler supports unwind section type],
 869 libgo_cv_as_x86_64_unwind_section_type, [
 870 libgo_cv_as_x86_64_unwind_section_type=yes
 871 echo '.section .eh_frame,"a",@unwind' > conftest.s
 872 CFLAGS_hold=$CFLAGS
 873 if test "$libgo_cv_c_unused_arguments" = yes; then
 874   CFLAGS="$CFLAGS -Qunused-arguments"
 875 fi
 876 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 877     libgo_cv_as_x86_64_unwind_section_type=no
 878 fi
 879 CFLAGS=$CFLAGS_hold
 880 ])
 881 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 882   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 883             [Define if your assembler supports unwind section type.])
 884 fi
 885
 886 AC_CACHE_SAVE
 887
 888 if test ${multilib} = yes; then
 889   multilib_arg="--enable-multilib"
 890 else
 891   multilib_arg=
 892 fi
 893
 894 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 895
 896 AC_CONFIG_COMMANDS([default],
 897 [if test -n "$CONFIG_FILES"; then
 898    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 899    # that multilib installs will end up installed in the correct place.
 900    # The testsuite needs it for multilib-aware ABI baseline files.
 901    # To work around this not being passed down from config-ml.in ->
 902    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 903    # append it here.  Only modify Makefiles that have just been created.
 904    #
 905    # Also, get rid of this simulated-VPATH thing that automake does.
 906    cat > vpsed << \_EOF
 907 s!`test -f '$<' || echo '$(srcdir)/'`!!
 908 _EOF
 909    for i in $SUBDIRS; do
 910     case $CONFIG_FILES in
 911      *${i}/Makefile*)
 912        #echo "Adding MULTISUBDIR to $i/Makefile"
 913        sed -f vpsed $i/Makefile > tmp
 914        grep '^MULTISUBDIR =' Makefile >> tmp
 915        mv tmp $i/Makefile
 916        ;;
 917     esac
 918    done
 919    rm vpsed
 920  fi
 921 ],
 922 [
 923 # Variables needed in config.status (file generation) which aren't already
 924 # passed by autoconf.
 925 SUBDIRS="$SUBDIRS"
 926 ])
 927
 928 AC_OUTPUT