gcc/gengtype-lex.l

   1 /* -*- indented-text -*- */
   2 /* Process source files and output type information.
   3    Copyright (C) 2002-2014 Free Software Foundation, Inc.
   4
   5 This file is part of GCC.
   6
   7 GCC is free software; you can redistribute it and/or modify it under
   8 the terms of the GNU General Public License as published by the Free
   9 Software Foundation; either version 3, or (at your option) any later
  10 version.
  11
  12 GCC is distributed in the hope that it will be useful, but WITHOUT ANY
  13 WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 for more details.
  16
  17 You should have received a copy of the GNU General Public License
  18 along with GCC; see the file COPYING3.  If not see
  19 <http://www.gnu.org/licenses/>.  */
  20
  21 %option noinput
  22
  23 %{
  24 #ifdef HOST_GENERATOR_FILE
  25 #include "config.h"
  26 #define GENERATOR_FILE 1
  27 #else
  28 #include "bconfig.h"
  29 #endif
  30 #include "system.h"
  31
  32 #define malloc xmalloc
  33 #define realloc xrealloc
  34
  35 #include "gengtype.h"
  36
  37 #define YY_DECL int yylex (const char **yylval)
  38 #define yyterminate() return EOF_TOKEN
  39
  40 struct fileloc lexer_line;
  41 int lexer_toplevel_done;
  42
  43 static void
  44 update_lineno (const char *l, size_t len)
  45 {
  46   while (len-- > 0)
  47     if (*l++ == '\n')
  48       lexer_line.line++;
  49 }
  50
  51 %}
  52
  53 CID     [[:alpha:]_][[:alnum:]_]*
  54 WS      [[:space:]]+
  55 HWS     [ \t\r\v\f]*
  56 IWORD   short|long|(un)?signed|char|int|HOST_WIDE_INT|uint64_t|int64_t|bool|size_t|BOOL_BITFIELD|CPPCHAR_SIGNED_T|ino_t|dev_t|HARD_REG_SET
  57 ITYPE   {IWORD}({WS}{IWORD})*
  58     /* Include '::' in identifiers to capture C++ scope qualifiers.  */
  59 ID      {CID}({HWS}::{HWS}{CID})*
  60 EOID    [^[:alnum:]_]
  61 CXX_KEYWORD inline|public:|private:|protected:|template|operator|friend|static
  62
  63 %x in_struct in_struct_comment in_comment
  64 %option warn noyywrap nounput nodefault perf-report
  65 %option 8bit never-interactive
  66 %%
  67   /* Do this on entry to yylex():  */
  68   *yylval = 0;
  69   if (lexer_toplevel_done)
  70     {
  71       BEGIN(INITIAL);
  72       lexer_toplevel_done = 0;
  73     }
  74
  75   /* Things we look for in skipping mode: */
  76 <INITIAL>{
  77 ^{HWS}typedef/{EOID} {
  78   BEGIN(in_struct);
  79   return TYPEDEF;
  80 }
  81 ^{HWS}struct/{EOID} {
  82   BEGIN(in_struct);
  83   return STRUCT;
  84 }
  85 ^{HWS}union/{EOID} {
  86   BEGIN(in_struct);
  87   return UNION;
  88 }
  89 ^{HWS}class/{EOID} {
  90   BEGIN(in_struct);
  91   return STRUCT;
  92 }
  93 ^{HWS}extern/{EOID} {
  94   BEGIN(in_struct);
  95   return EXTERN;
  96 }
  97 ^{HWS}static/{EOID} {
  98   BEGIN(in_struct);
  99   return STATIC;
 100 }
 101 }
 102
 103     /* Parsing inside a struct, union or class declaration.  */
 104 <in_struct>{
 105 "/*"                            { BEGIN(in_struct_comment); }
 106 "//".*\n                        { lexer_line.line++; }
 107
 108 {WS}                            { update_lineno (yytext, yyleng); }
 109 \\\n                            { lexer_line.line++; }
 110
 111 "const"/{EOID}                  /* don't care */
 112 {CXX_KEYWORD}/{EOID}                    |
 113 "~"                                     |
 114 "^"                                     |
 115 "&"                                     {
 116     *yylval = XDUPVAR (const char, yytext, yyleng, yyleng + 1);
 117     return IGNORABLE_CXX_KEYWORD;
 118 }
 119 "GTY"/{EOID}                    { return GTY_TOKEN; }
 120 "union"/{EOID}                  { return UNION; }
 121 "struct"/{EOID}                 { return STRUCT; }
 122 "class"/{EOID}                  { return STRUCT; }
 123 "typedef"/{EOID}                { return TYPEDEF; }
 124 "enum"/{EOID}                   { return ENUM; }
 125 "ptr_alias"/{EOID}              { return PTR_ALIAS; }
 126 "nested_ptr"/{EOID}             { return NESTED_PTR; }
 127 "user"/{EOID}                   { return USER_GTY; }
 128 [0-9]+                          { return NUM; }
 129 "param"[0-9]*"_is"/{EOID}               {
 130   *yylval = XDUPVAR (const char, yytext, yyleng, yyleng+1);
 131   return PARAM_IS;
 132 }
 133
 134 {IWORD}({WS}{IWORD})*/{EOID}            |
 135 "ENUM_BITFIELD"{WS}?"("{WS}?{ID}{WS}?")"        {
 136   size_t len;
 137
 138   for (len = yyleng; ISSPACE (yytext[len-1]); len--)
 139     ;
 140
 141   *yylval = XDUPVAR (const char, yytext, len, len+1);
 142   update_lineno (yytext, yyleng);
 143   return SCALAR;
 144 }
 145
 146 {ID}/{EOID}                     {
 147   *yylval = XDUPVAR (const char, yytext, yyleng, yyleng+1);
 148   return ID;
 149 }
 150
 151 \"([^"\\]|\\.)*\"               {
 152   *yylval = XDUPVAR (const char, yytext+1, yyleng-2, yyleng-1);
 153   return STRING;
 154 }
 155   /* This "terminal" avoids having to parse integer constant expressions.  */
 156 "["[^\[\]]*"]"                  {
 157   *yylval = XDUPVAR (const char, yytext+1, yyleng-2, yyleng-1);
 158   return ARRAY;
 159 }
 160 "'"("\\".|[^\\])"'"             {
 161   *yylval = XDUPVAR (const char, yytext+1, yyleng-2, yyleng);
 162   return CHAR;
 163 }
 164
 165 "..."                           { return ELLIPSIS; }
 166 [(){},*:<>;=%|+\!\?\.-]         { return yytext[0]; }
 167
 168    /* ignore pp-directives */
 169 ^{HWS}"#"{HWS}[a-z_]+[^\n]*\n   {lexer_line.line++;}
 170
 171 .                               {
 172   error_at_line (&lexer_line, "unexpected character `%s'", yytext);
 173 }
 174 }
 175
 176 "/*"                    { BEGIN(in_comment); }
 177 "//".*\n                { lexer_line.line++; }
 178 \n                      { lexer_line.line++; }
 179 {ID}                    |
 180 "'"("\\".|[^\\])"'"     |
 181 [^"/\n]                 /* do nothing */
 182 \"([^"\\]|\\.|\\\n)*\"  { update_lineno (yytext, yyleng); }
 183 "/"/[^*]                /* do nothing */
 184
 185 <in_comment,in_struct_comment>{
 186 \n              { lexer_line.line++; }
 187 [^*\n]{16}      |
 188 [^*\n]          /* do nothing */
 189 "*"/[^/]        /* do nothing */
 190 }
 191
 192 <in_comment>"*/"        { BEGIN(INITIAL); }
 193 <in_struct_comment>"*/" { BEGIN(in_struct); }
 194
 195 ["/]                    |
 196 <in_struct_comment,in_comment>"*"       {
 197   error_at_line (&lexer_line,
 198                  "unterminated comment or string; unexpected EOF");
 199 }
 200
 201 ^{HWS}"#"{HWS}"define"{WS}"GTY(" /* do nothing */
 202
 203 %%
 204
 205 void
 206 yybegin (const char *fname)
 207 {
 208   yyin = fopen (fname, "r");
 209   if (yyin == NULL)
 210     {
 211       perror (fname);
 212       exit (1);
 213     }
 214   lexer_line.file = input_file_by_name (fname);
 215   lexer_line.line = 1;
 216 }
 217
 218 void
 219 yyend (void)
 220 {
 221   fclose (yyin);
 222 }