gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008, 2009 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.64)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 AC_PROG_CXX
 280 ACX_PROG_GNAT([-I"$srcdir"/ada])
 281
 282 # autoconf is lame and doesn't give us any substitution variable for this.
 283 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 284   NO_MINUS_C_MINUS_O=yes
 285 else
 286   OUTPUT_OPTION='-o $@'
 287 fi
 288 AC_SUBST(NO_MINUS_C_MINUS_O)
 289 AC_SUBST(OUTPUT_OPTION)
 290
 291 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 292 # optimizations to be activated explicitly by the toplevel.
 293 case "$CC" in
 294   */prev-gcc/xgcc*) ;;
 295   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 296 esac
 297 AC_SUBST(CFLAGS)
 298
 299 # -------------------------
 300 # Check C compiler features
 301 # -------------------------
 302
 303 AC_USE_SYSTEM_EXTENSIONS
 304 AC_PROG_CPP
 305 AC_C_INLINE
 306
 307 # sizeof(char) is 1 by definition.
 308 AC_CHECK_SIZEOF(void *)
 309 AC_CHECK_SIZEOF(short)
 310 AC_CHECK_SIZEOF(int)
 311 AC_CHECK_SIZEOF(long)
 312 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 313 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 314 GCC_STDINT_TYPES
 315
 316 # ---------------------
 317 # Warnings and checking
 318 # ---------------------
 319
 320 # Check $CC warning features (if it's GCC).
 321 # We want to use -pedantic, but we don't want warnings about
 322 # * 'long long'
 323 # * variadic macros
 324 # * overlong strings
 325 # So, we only use -pedantic if we can disable those warnings.
 326
 327 ACX_PROG_CC_WARNING_OPTS(
 328         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wcast-qual])), [loose_warn])
 329 ACX_PROG_CC_WARNING_OPTS(
 330         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
 331         [c_loose_warn])
 332 ACX_PROG_CC_WARNING_OPTS(
 333         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
 334 ACX_PROG_CC_WARNING_OPTS(
 335         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 336 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 337         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 338                        [-Wno-overlength-strings])), [strict_warn])
 339 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 340
 341 # The above macros do nothing if the compiler is not GCC.  However, the
 342 # Makefile has more goo to add other flags, so these variables are used
 343 # to enable warnings only for GCC.
 344 warn_cflags=
 345 warn_cxxflags=
 346 if test "x$GCC" = "xyes"; then
 347   warn_cflags='$(GCC_WARN_CFLAGS)'
 348   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 349 fi
 350 AC_SUBST(warn_cflags)
 351 AC_SUBST(warn_cxxflags)
 352
 353 # Enable expensive internal checks
 354 is_release=
 355 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 356   is_release=yes
 357 fi
 358
 359 AC_ARG_ENABLE(checking,
 360 [  --enable-checking[=LIST]
 361                           enable expensive run-time checks.  With LIST,
 362                           enable only specific categories of checks.
 363                           Categories are: yes,no,all,none,release.
 364                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
 365                           rtlflag,rtl,runtime,tree,valgrind,types.],
 366 [ac_checking_flags="${enableval}"],[
 367 # Determine the default checks.
 368 if test x$is_release = x ; then
 369   ac_checking_flags=yes
 370 else
 371   ac_checking_flags=release
 372 fi])
 373 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 374 for check in release $ac_checking_flags
 375 do
 376         case $check in
 377         # these set all the flags to specific states
 378         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 379                         ac_fold_checking= ; ac_gc_checking=1 ;
 380                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 381                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 382                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 383                         ac_types_checking=1 ;;
 384         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 385                         ac_fold_checking= ; ac_gc_checking= ;
 386                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 387                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 388                         ac_tree_checking= ; ac_valgrind_checking= ;
 389                         ac_types_checking= ;;
 390         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 391                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 392                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 393                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 394                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 395                         ac_types_checking=1 ;;
 396         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 397                         ac_fold_checking= ; ac_gc_checking= ;
 398                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 399                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 400                         ac_tree_checking= ; ac_valgrind_checking= ;
 401                         ac_types_checking= ;;
 402         # these enable particular checks
 403         assert)         ac_assert_checking=1 ;;
 404         df)             ac_df_checking=1 ;;
 405         fold)           ac_fold_checking=1 ;;
 406         gc)             ac_gc_checking=1 ;;
 407         gcac)           ac_gc_always_collect=1 ;;
 408         gimple)         ac_gimple_checking=1 ;;
 409         misc)           ac_checking=1 ;;
 410         rtl)            ac_rtl_checking=1 ;;
 411         rtlflag)        ac_rtlflag_checking=1 ;;
 412         runtime)        ac_runtime_checking=1 ;;
 413         tree)           ac_tree_checking=1 ;;
 414         types)          ac_types_checking=1 ;;
 415         valgrind)       ac_valgrind_checking=1 ;;
 416         *)      AC_MSG_ERROR(unknown check category $check) ;;
 417         esac
 418 done
 419 IFS="$ac_save_IFS"
 420
 421 nocommon_flag=""
 422 if test x$ac_checking != x ; then
 423   AC_DEFINE(ENABLE_CHECKING, 1,
 424 [Define if you want more run-time sanity checks.  This one gets a grab
 425    bag of miscellaneous but relatively cheap checks.])
 426   nocommon_flag=-fno-common
 427 fi
 428 AC_SUBST(nocommon_flag)
 429 if test x$ac_df_checking != x ; then
 430   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 431 [Define if you want more run-time sanity checks for dataflow.])
 432 fi
 433 if test x$ac_assert_checking != x ; then
 434   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 435 [Define if you want assertions enabled.  This is a cheap check.])
 436 fi
 437 if test x$ac_gimple_checking != x ; then
 438   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 439 [Define if you want operations on GIMPLE (the basic data structure of
 440 the high-level optimizers) to be checked for dynamic type safety at
 441 runtime.  This is moderately expensive.])
 442 fi
 443 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 444 if test x$ac_runtime_checking != x ; then
 445   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 446 [Define if you want runtime assertions enabled.  This is a cheap check.])
 447 fi
 448 if test x$ac_tree_checking != x ; then
 449   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 450 [Define if you want all operations on trees (the basic data
 451    structure of the front ends) to be checked for dynamic type safety
 452    at runtime.  This is moderately expensive.  The tree browser debugging
 453    routines will also be enabled by this option.
 454    ])
 455   TREEBROWSER=tree-browser.o
 456 fi
 457 if test x$ac_types_checking != x ; then
 458   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 459 [Define if you want all gimple types to be verified after gimplifiation.
 460    This is cheap.
 461    ])
 462 fi
 463 AC_SUBST(TREEBROWSER)
 464 if test x$ac_rtl_checking != x ; then
 465   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 466 [Define if you want all operations on RTL (the basic data structure
 467    of the optimizer and back end) to be checked for dynamic type safety
 468    at runtime.  This is quite expensive.])
 469 fi
 470 if test x$ac_rtlflag_checking != x ; then
 471   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 472 [Define if you want RTL flag accesses to be checked against the RTL
 473    codes that are supported for each access macro.  This is relatively
 474    cheap.])
 475 fi
 476 if test x$ac_gc_checking != x ; then
 477   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 478 [Define if you want the garbage collector to do object poisoning and
 479    other memory allocation checks.  This is quite expensive.])
 480 fi
 481 if test x$ac_gc_always_collect != x ; then
 482   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 483 [Define if you want the garbage collector to operate in maximally
 484    paranoid mode, validating the entire heap and collecting garbage at
 485    every opportunity.  This is extremely expensive.])
 486 fi
 487 if test x$ac_fold_checking != x ; then
 488   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 489 [Define if you want fold checked that it never destructs its argument.
 490    This is quite expensive.])
 491 fi
 492 valgrind_path_defines=
 493 valgrind_command=
 494
 495 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 496 dnl # an if statement.  This was the source of very frustrating bugs
 497 dnl # in converting to autoconf 2.5x!
 498 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 499
 500 if test x$ac_valgrind_checking != x ; then
 501   # It is certainly possible that there's valgrind but no valgrind.h.
 502   # GCC relies on making annotations so we must have both.
 503   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 504   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 505     [[#include <valgrind/memcheck.h>
 506 #ifndef VALGRIND_DISCARD
 507 #error VALGRIND_DISCARD not defined
 508 #endif]])],
 509   [gcc_cv_header_valgrind_memcheck_h=yes],
 510   [gcc_cv_header_valgrind_memcheck_h=no])
 511   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 512   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 513   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 514     [[#include <memcheck.h>
 515 #ifndef VALGRIND_DISCARD
 516 #error VALGRIND_DISCARD not defined
 517 #endif]])],
 518   [gcc_cv_header_memcheck_h=yes],
 519   [gcc_cv_header_memcheck_h=no])
 520   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 521   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 522         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 523   if test "x$valgrind_path" = "x" \
 524     || (test $have_valgrind_h = no \
 525         && test $gcc_cv_header_memcheck_h = no \
 526         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 527         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 528   fi
 529   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 530   valgrind_command="$valgrind_path -q"
 531   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 532 [Define if you want to run subprograms and generated programs
 533    through valgrind (a memory checker).  This is extremely expensive.])
 534   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 535     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 536         [Define if valgrind's valgrind/memcheck.h header is installed.])
 537   fi
 538   if test $gcc_cv_header_memcheck_h = yes; then
 539     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 540         [Define if valgrind's memcheck.h header is installed.])
 541   fi
 542 fi
 543 AC_SUBST(valgrind_path_defines)
 544 AC_SUBST(valgrind_command)
 545
 546 # Enable code coverage collection
 547 AC_ARG_ENABLE(coverage,
 548 [  --enable-coverage[=LEVEL]
 549                           enable compiler's code coverage collection.
 550                           Use to measure compiler performance and locate
 551                           unused parts of the compiler. With LEVEL, specify
 552                           optimization. Values are opt, noopt,
 553                           default is noopt],
 554 [case "${enableval}" in
 555   yes|noopt)
 556     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 557     ;;
 558   opt)
 559     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 560     ;;
 561   no)
 562     # a.k.a. --disable-coverage
 563     coverage_flags=""
 564     ;;
 565   *)
 566     AC_MSG_ERROR(unknown coverage setting $enableval)
 567     ;;
 568 esac],
 569 [coverage_flags=""])
 570 AC_SUBST(coverage_flags)
 571
 572 AC_ARG_ENABLE(gather-detailed-mem-stats,
 573 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 574 [enable_gather_detailed_mem_stats=no])
 575 if test x$enable_gather_detailed_mem_stats = xyes ; then
 576   AC_DEFINE(GATHER_STATISTICS, 1,
 577         [Define to enable detailed memory allocation stats gathering.])
 578 fi
 579
 580 # -------------------------------
 581 # Miscenalleous configure options
 582 # -------------------------------
 583
 584 # See if we are building gcc with C++.
 585 AC_ARG_ENABLE(build-with-cxx,
 586 [  --enable-build-with-cxx build with C++ compiler instead of C compiler],
 587 ENABLE_BUILD_WITH_CXX=$enableval,
 588 ENABLE_BUILD_WITH_CXX=no)
 589 AC_SUBST(ENABLE_BUILD_WITH_CXX)
 590
 591 # With stabs
 592 AC_ARG_WITH(stabs,
 593 [  --with-stabs            arrange to use stabs instead of host debug format],
 594 stabs="$with_stabs",
 595 stabs=no)
 596
 597 # Determine whether or not multilibs are enabled.
 598 AC_ARG_ENABLE(multilib,
 599 [  --enable-multilib       enable library support for multiple ABIs],
 600 [], [enable_multilib=yes])
 601 AC_SUBST(enable_multilib)
 602
 603 # Enable __cxa_atexit for C++.
 604 AC_ARG_ENABLE(__cxa_atexit,
 605 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 606 [], [])
 607
 608 # Enable C extension for decimal float if target supports it.
 609 AC_ARG_ENABLE(decimal-float,
 610 [  --enable-decimal-float={no,yes,bid,dpd}
 611                         enable decimal float extension to C.  Selecting 'bid'
 612                         or 'dpd' choses which decimal floating point format
 613                         to use],
 614 [
 615   case $enable_decimal_float in
 616     yes | no | bid | dpd) ;;
 617     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 618 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 619   esac
 620 ],
 621 [
 622   case $target in
 623     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 624       enable_decimal_float=yes
 625       ;;
 626     *)
 627       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 628       enable_decimal_float=no
 629       ;;
 630   esac
 631 ])
 632
 633 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 634 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 635 [Define to 1 to enable decimal float extension to C.])
 636
 637 # x86's use BID format instead of DPD
 638 case x$enable_decimal_float in
 639   xyes)
 640     case $target in
 641       i?86*-*-linux* | x86_64*-*-linux*)
 642         enable_decimal_float=bid
 643         ;;
 644       *)
 645         enable_decimal_float=dpd
 646         ;;
 647     esac
 648     ;;
 649   xno)
 650     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 651     # dependency on libdecnumber.
 652     enable_decimal_float=dpd
 653     ;;
 654 esac
 655 AC_SUBST(enable_decimal_float)
 656
 657 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 658 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 659 [Define to 1 to specify that we are using the BID decimal floating
 660 point format instead of DPD])
 661
 662 # Enable C extension for fixed-point arithmetic.
 663 AC_ARG_ENABLE(fixed-point,
 664 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 665 [
 666 ],
 667 [
 668   case $target in
 669     mips*-*-*)
 670       case $host in
 671         mips*-sgi-irix*)
 672           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 673           enable_fixed_point=no
 674           ;;
 675         *)
 676           enable_fixed_point=yes
 677           ;;
 678       esac
 679       ;;
 680     *)
 681       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 682       enable_fixed_point=no
 683       ;;
 684   esac
 685 ])
 686 AC_SUBST(enable_fixed_point)
 687
 688 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 689 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 690 [Define to 1 to enable fixed-point arithmetic extension to C.])
 691
 692 # Enable threads
 693 # Pass with no value to take the default
 694 # Pass with a value to specify a thread package
 695 AC_ARG_ENABLE(threads,
 696 [  --enable-threads        enable thread usage for target GCC
 697   --enable-threads=LIB    use LIB thread package for target GCC],,
 698 [enable_threads=''])
 699
 700 AC_ARG_ENABLE(tls,
 701 [  --enable-tls            enable or disable generation of tls code
 702                           overriding the assembler check for tls support],
 703 [
 704   case $enable_tls in
 705     yes | no) ;;
 706     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 707 Valid choices are 'yes' and 'no'.]) ;;
 708   esac
 709 ], [enable_tls=''])
 710
 711 AC_ARG_ENABLE(objc-gc,
 712 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 713                           the GNU Objective-C runtime],
 714 if test x$enable_objc_gc = xno; then
 715         objc_boehm_gc=''
 716 else
 717         objc_boehm_gc=1
 718 fi,
 719 objc_boehm_gc='')
 720
 721 AC_ARG_WITH(dwarf2,
 722 [  --with-dwarf2           force the default debug format to be DWARF 2],
 723 dwarf2="$with_dwarf2",
 724 dwarf2=no)
 725
 726 AC_ARG_ENABLE(shared,
 727 [  --disable-shared        don't provide a shared libgcc],
 728 [
 729   case $enable_shared in
 730   yes | no) ;;
 731   *)
 732     enable_shared=no
 733     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 734     for pkg in $enableval; do
 735       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 736         enable_shared=yes
 737       fi
 738     done
 739     IFS="$ac_save_ifs"
 740     ;;
 741   esac
 742 ], [enable_shared=yes])
 743 AC_SUBST(enable_shared)
 744
 745 AC_ARG_WITH(build-sysroot,
 746   [  --with-build-sysroot=sysroot
 747                           use sysroot as the system root during the build])
 748
 749 AC_ARG_WITH(sysroot,
 750 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 751 [
 752  case ${with_sysroot} in
 753  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 754  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 755  esac
 756
 757  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 758  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 759
 760  if test "x$prefix" = xNONE; then
 761   test_prefix=/usr/local
 762  else
 763   test_prefix=$prefix
 764  fi
 765  if test "x$exec_prefix" = xNONE; then
 766   test_exec_prefix=$test_prefix
 767  else
 768   test_exec_prefix=$exec_prefix
 769  fi
 770  case ${TARGET_SYSTEM_ROOT} in
 771  "${test_prefix}"|"${test_prefix}/"*|\
 772  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 773  '${prefix}'|'${prefix}/'*|\
 774  '${exec_prefix}'|'${exec_prefix}/'*)
 775    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 776    TARGET_SYSTEM_ROOT_DEFINE="$t"
 777    ;;
 778  esac
 779 ], [
 780  TARGET_SYSTEM_ROOT=
 781  TARGET_SYSTEM_ROOT_DEFINE=
 782  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 783 ])
 784 AC_SUBST(TARGET_SYSTEM_ROOT)
 785 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 786 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 787
 788 AC_ARG_WITH(specs,
 789   [AS_HELP_STRING([--with-specs=SPECS],
 790                   [add SPECS to driver command-line processing])],
 791   [CONFIGURE_SPECS=$withval],
 792   [CONFIGURE_SPECS=]
 793 )
 794 AC_SUBST(CONFIGURE_SPECS)
 795
 796 # Build with intermodule optimisations
 797 AC_ARG_ENABLE(intermodule,
 798 [  --enable-intermodule    build the compiler in one step],
 799 [case ${enable_intermodule} in
 800   yes) onestep="-onestep";;
 801   *) onestep="";;
 802 esac],
 803 [onestep=""])
 804 AC_SUBST(onestep)
 805
 806 ACX_PKGVERSION([GCC])
 807 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 808
 809 # Sanity check enable_languages in case someone does not run the toplevel
 810 # configure # script.
 811 AC_ARG_ENABLE(languages,
 812 [  --enable-languages=LIST specify which front-ends to build],
 813 [case ,${enable_languages}, in
 814        ,,|,yes,)
 815                 # go safe -- we cannot be much sure without the toplevel
 816                 # configure's
 817                 # analysis of which target libs are present and usable
 818                 enable_languages=c
 819                 ;;
 820          *,all,*)
 821                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 822                 ;;
 823         *,c,*)
 824                 ;;
 825         *)
 826                 enable_languages=c,${enable_languages}
 827                 ;;
 828 esac],
 829 [enable_languages=c])
 830
 831 AC_ARG_WITH(multilib-list,
 832 [  --with-multilib-list    Select multilibs (SH only)],
 833 :,
 834 with_multilib_list=default)
 835
 836 # -------------------------
 837 # Checks for other programs
 838 # -------------------------
 839
 840 AC_PROG_MAKE_SET
 841
 842 # Find some useful tools
 843 AC_PROG_AWK
 844 # We need awk to create options.c and options.h.
 845 # Bail out if it's missing.
 846 case ${AWK} in
 847   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 848 esac
 849
 850 gcc_AC_PROG_LN_S
 851 ACX_PROG_LN($LN_S)
 852 AC_PROG_RANLIB
 853 case "${host}" in
 854 *-*-darwin*)
 855   # By default, the Darwin ranlib will not treat common symbols as
 856   # definitions when  building the archive table of contents.  Other
 857   # ranlibs do that; pass an option to the Darwin ranlib that makes
 858   # it behave similarly.
 859   ranlib_flags="-c"
 860   ;;
 861 *)
 862   ranlib_flags=""
 863 esac
 864 AC_SUBST(ranlib_flags)
 865
 866 gcc_AC_PROG_INSTALL
 867
 868 # See if cmp has --ignore-initial.
 869 gcc_AC_PROG_CMP_IGNORE_INITIAL
 870
 871 # See if we have the mktemp command.
 872 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 873
 874 # See if makeinfo has been installed and is modern enough
 875 # that we can use it.
 876 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 877   [GNU texinfo.* \([0-9][0-9.]*\)],
 878   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 879 if test $gcc_cv_prog_makeinfo_modern = no; then
 880   AC_MSG_WARN([
 881 *** Makeinfo is missing or too old.
 882 *** Info documentation will not be built.])
 883   BUILD_INFO=
 884 else
 885   BUILD_INFO=info
 886 fi
 887 AC_SUBST(BUILD_INFO)
 888
 889 # Is pod2man recent enough to regenerate manpages?
 890 AC_MSG_CHECKING([for recent Pod::Man])
 891 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 892   AC_MSG_RESULT(yes)
 893   GENERATED_MANPAGES=generated-manpages
 894 else
 895   AC_MSG_RESULT(no)
 896   GENERATED_MANPAGES=
 897 fi
 898 AC_SUBST(GENERATED_MANPAGES)
 899
 900 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 901
 902 # How about lex?
 903 dnl Don't use AC_PROG_LEX; we insist on flex.
 904 dnl LEXLIB is not useful in gcc.
 905 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 906
 907 # Bison?
 908 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 909
 910 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 911 # check for build == host before using them.
 912
 913 # NM
 914 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 915   && test -d ../binutils ; then
 916   NM='$(objdir)/../binutils/nm-new'
 917 else
 918   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 919 fi
 920
 921 # AR
 922 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 923   && test -d ../binutils ; then
 924   AR='$(objdir)/../binutils/ar'
 925 else
 926   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 927 fi
 928
 929
 930 # --------------------
 931 # Checks for C headers
 932 # --------------------
 933
 934 # Need to reject headers which give warnings, so that the -Werror bootstrap
 935 # works later. *sigh*  This needs to come before all header checks.
 936 AC_PROG_CPP_WERROR
 937
 938 AC_HEADER_STDC
 939 AC_HEADER_TIME
 940 ACX_HEADER_STRING
 941 AC_HEADER_SYS_WAIT
 942 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 943                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 944                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 945                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 946
 947 # Check for thread headers.
 948 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 949 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 950
 951 # These tests can't be done till we know if we have limits.h.
 952 gcc_AC_C_CHAR_BIT
 953 AC_C_BIGENDIAN
 954
 955 # --------
 956 # UNSORTED
 957 # --------
 958
 959
 960 # These libraries may be used by collect2.
 961 # We may need a special search path to get them linked.
 962 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 963 [save_LIBS="$LIBS"
 964 for libs in '' -lld -lmld \
 965                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 966                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 967 do
 968         LIBS="$libs"
 969         AC_TRY_LINK_FUNC(ldopen,
 970                 [gcc_cv_collect2_libs="$libs"; break])
 971 done
 972 LIBS="$save_LIBS"
 973 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 974 case $gcc_cv_collect2_libs in
 975         "none required")        ;;
 976         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 977 esac
 978 AC_SUBST(COLLECT2_LIBS)
 979
 980 # When building Ada code on Alpha, we need exc_resume which is usually in
 981 # -lexc.  So test for it.
 982 save_LIBS="$LIBS"
 983 LIBS=
 984 AC_SEARCH_LIBS(exc_resume, exc)
 985 GNAT_LIBEXC="$LIBS"
 986 LIBS="$save_LIBS"
 987 AC_SUBST(GNAT_LIBEXC)
 988
 989 # Some systems put ldexp and frexp in libm instead of libc; assume
 990 # they're both in the same place.  jcf-dump needs them.
 991 save_LIBS="$LIBS"
 992 LIBS=
 993 AC_SEARCH_LIBS(ldexp, m)
 994 LDEXP_LIB="$LIBS"
 995 LIBS="$save_LIBS"
 996 AC_SUBST(LDEXP_LIB)
 997
 998 # Use <inttypes.h> only if it exists,
 999 # doesn't clash with <sys/types.h>, and declares intmax_t.
1000 AC_MSG_CHECKING(for inttypes.h)
1001 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1002 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1003 [[#include <sys/types.h>
1004 #include <inttypes.h>]],
1005   [[intmax_t i = -1;]])],
1006   [gcc_cv_header_inttypes_h=yes],
1007   [gcc_cv_header_inttypes_h=no])])
1008 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1009 if test $gcc_cv_header_inttypes_h = yes; then
1010   AC_DEFINE(HAVE_INTTYPES_H, 1,
1011         [Define if you have a working <inttypes.h> header file.])
1012 fi
1013
1014 dnl Disabled until we have a complete test for buggy enum bitfields.
1015 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1016
1017 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1018   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1019   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1020   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1021   putchar_unlocked putc_unlocked)
1022 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1023         sysconf strsignal getrusage nl_langinfo \
1024         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1025         gcc_UNLOCKED_FUNCS)
1026
1027 if test x$ac_cv_func_mbstowcs = xyes; then
1028   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1029 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1030 int main()
1031 {
1032   mbstowcs(0, "", 0);
1033   return 0;
1034 }]])],
1035     [gcc_cv_func_mbstowcs_works=yes],
1036     [gcc_cv_func_mbstowcs_works=no],
1037     [gcc_cv_func_mbstowcs_works=yes])])
1038   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1039     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1040   [Define this macro if mbstowcs does not crash when its
1041    first argument is NULL.])
1042   fi
1043 fi
1044
1045 AC_CHECK_TYPE(ssize_t, int)
1046 AC_CHECK_TYPE(caddr_t, char *)
1047
1048 gcc_AC_FUNC_MMAP_BLACKLIST
1049
1050 case "${host}" in
1051 *-*-*vms*)
1052   # Under VMS, vfork works very differently than on Unix. The standard test
1053   # won't work, and it isn't easily adaptable. It makes more sense to
1054   # just force it.
1055   ac_cv_func_vfork_works=yes
1056   ;;
1057 esac
1058 AC_FUNC_FORK
1059
1060 AM_ICONV
1061 # Until we have in-tree GNU iconv:
1062 LIBICONV_DEP=
1063 AC_SUBST(LIBICONV_DEP)
1064
1065 AM_LC_MESSAGES
1066
1067 AM_LANGINFO_CODESET
1068
1069 # We will need to find libiberty.h and ansidecl.h
1070 saved_CFLAGS="$CFLAGS"
1071 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1072 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1073         strsignal strstr strverscmp \
1074         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1075         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1076 #include "ansidecl.h"
1077 #include "system.h"])
1078
1079 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1080 #include "ansidecl.h"
1081 #include "system.h"
1082 #ifdef HAVE_SYS_RESOURCE_H
1083 #include <sys/resource.h>
1084 #endif
1085 ])
1086
1087 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1088 #include "ansidecl.h"
1089 #include "system.h"
1090 #ifdef HAVE_SYS_RESOURCE_H
1091 #include <sys/resource.h>
1092 #endif
1093 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1094 [Define to `long' if <sys/resource.h> doesn't define.])])
1095
1096 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1097 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1098 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1099 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1100 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1101 #include "ansidecl.h"
1102 #include "system.h"
1103 #ifdef HAVE_LDFCN_H
1104 #undef FREAD
1105 #undef FWRITE
1106 #include <ldfcn.h>
1107 #endif
1108 ])
1109
1110 gcc_AC_CHECK_DECLS(times, , ,[
1111 #include "ansidecl.h"
1112 #include "system.h"
1113 #ifdef HAVE_SYS_TIMES_H
1114 #include <sys/times.h>
1115 #endif
1116 ])
1117
1118 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1119 #include "ansidecl.h"
1120 #include "system.h"
1121 #include <signal.h>
1122 ])
1123
1124 # More time-related stuff.
1125 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1126 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1127 #include "ansidecl.h"
1128 #include "system.h"
1129 #ifdef HAVE_SYS_TIMES_H
1130 #include <sys/times.h>
1131 #endif
1132 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1133 if test $ac_cv_struct_tms = yes; then
1134   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1135   [Define if <sys/times.h> defines struct tms.])
1136 fi
1137
1138 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1139 # revisit after autoconf 2.50.
1140 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1141 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1142 #include "ansidecl.h"
1143 #include "system.h"
1144 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1145 if test $gcc_cv_type_clock_t = yes; then
1146   AC_DEFINE(HAVE_CLOCK_T, 1,
1147   [Define if <time.h> defines clock_t.])
1148 fi
1149
1150 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1151 CFLAGS="$saved_CFLAGS"
1152
1153 gcc_AC_INITFINI_ARRAY
1154
1155 # mkdir takes a single argument on some systems.
1156 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1157
1158 # File extensions
1159 manext='.1'
1160 objext='.o'
1161 AC_SUBST(manext)
1162 AC_SUBST(objext)
1163
1164 # With Setjmp/Longjmp based exception handling.
1165 AC_ARG_ENABLE(sjlj-exceptions,
1166 [  --enable-sjlj-exceptions
1167                           arrange to use setjmp/longjmp exception handling],
1168 [case $target in
1169   *-*-hpux10*)
1170     if test $enableval != yes; then
1171       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1172       enableval=yes
1173     fi
1174     ;;
1175 esac
1176 force_sjlj_exceptions=yes],
1177 [case $target in
1178   *-*-hpux10*)
1179     force_sjlj_exceptions=yes
1180     enableval=yes
1181     ;;
1182   *)
1183     force_sjlj_exceptions=no
1184     ;;
1185 esac])
1186 if test $force_sjlj_exceptions = yes; then
1187   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1188   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1189     [Define 0/1 to force the choice for exception handling model.])
1190 fi
1191
1192 # For platforms with the unwind ABI which includes an unwind library,
1193 # libunwind, we can choose to use the system libunwind.
1194 # config.gcc also contains tests of with_system_libunwind.
1195 GCC_CHECK_UNWIND_GETIPINFO
1196
1197 # --------------------------------------------------------
1198 # Build, host, and target specific configuration fragments
1199 # --------------------------------------------------------
1200
1201 # Collect build-machine-specific information.
1202 . ${srcdir}/config.build
1203
1204 # Collect host-machine-specific information.
1205 . ${srcdir}/config.host
1206
1207 target_gtfiles=
1208
1209 # Collect target-machine-specific information.
1210 . ${srcdir}/config.gcc
1211
1212 extra_objs="${host_extra_objs} ${extra_objs}"
1213 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1214
1215 # Default the target-machine variables that were not explicitly set.
1216 if test x"$tm_file" = x
1217 then tm_file=$cpu_type/$cpu_type.h; fi
1218
1219 if test x"$extra_headers" = x
1220 then extra_headers=; fi
1221
1222 if test x$md_file = x
1223 then md_file=$cpu_type/$cpu_type.md; fi
1224
1225 if test x$out_file = x
1226 then out_file=$cpu_type/$cpu_type.c; fi
1227
1228 if test x"$tmake_file" = x
1229 then tmake_file=$cpu_type/t-$cpu_type
1230 fi
1231
1232 if test x"$dwarf2" = xyes
1233 then tm_file="$tm_file tm-dwarf2.h"
1234 fi
1235
1236 # Say what files are being used for the output code and MD file.
1237 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1238 echo "Using \`$srcdir/config/$md_file' as machine description file."
1239
1240 # If any of the xm_file variables contain nonexistent files, warn
1241 # about them and drop them.
1242
1243 bx=
1244 for x in $build_xm_file; do
1245   if    test -f $srcdir/config/$x
1246   then      bx="$bx $x"
1247   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1248   fi
1249 done
1250 build_xm_file="$bx"
1251
1252 hx=
1253 for x in $host_xm_file; do
1254   if    test -f $srcdir/config/$x
1255   then      hx="$hx $x"
1256   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1257   fi
1258 done
1259 host_xm_file="$hx"
1260
1261 tx=
1262 for x in $xm_file; do
1263   if    test -f $srcdir/config/$x
1264   then      tx="$tx $x"
1265   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1266   fi
1267 done
1268 xm_file="$tx"
1269
1270 count=a
1271 for f in $tm_file; do
1272         count=${count}x
1273 done
1274 if test $count = ax; then
1275         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1276 else
1277         echo "Using the following target machine macro files:"
1278         for f in $tm_file; do
1279                 echo "  $srcdir/config/$f"
1280         done
1281 fi
1282
1283 if test x$need_64bit_hwint = xyes; then
1284         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1285 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1286 fi
1287
1288 if test x$use_long_long_for_widest_fast_int = xyes; then
1289         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1290 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1291 efficiently supported by the host hardware.])
1292 fi
1293
1294 count=a
1295 for f in $host_xm_file; do
1296         count=${count}x
1297 done
1298 if test $count = a; then
1299         :
1300 elif test $count = ax; then
1301         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1302 else
1303         echo "Using the following host machine macro files:"
1304         for f in $host_xm_file; do
1305                 echo "  $srcdir/config/$f"
1306         done
1307 fi
1308 echo "Using ${out_host_hook_obj} for host machine hooks."
1309
1310 if test "$host_xm_file" != "$build_xm_file"; then
1311         count=a
1312         for f in $build_xm_file; do
1313                 count=${count}x
1314         done
1315         if test $count = a; then
1316                 :
1317         elif test $count = ax; then
1318                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1319         else
1320                 echo "Using the following build machine macro files:"
1321                 for f in $build_xm_file; do
1322                         echo "  $srcdir/config/$f"
1323                 done
1324         fi
1325 fi
1326
1327 case ${host} in
1328   powerpc*-*-darwin*)
1329     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1330       gcc_cv_mcontext_underscores,
1331       AC_COMPILE_IFELSE([
1332 #include <sys/cdefs.h>
1333 #include <sys/signal.h>
1334 #include <ucontext.h>
1335 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1336 ],
1337         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1338       if test $gcc_cv_mcontext_underscores = yes; then
1339         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1340           [mcontext_t fields start with __])
1341       fi
1342     ;;
1343 esac
1344
1345 # ---------
1346 # Threading
1347 # ---------
1348
1349 # Check if a valid thread package
1350 case ${enable_threads} in
1351   "" | no)
1352     # No threads
1353     target_thread_file='single'
1354     ;;
1355   yes)
1356     # default
1357     target_thread_file='single'
1358     ;;
1359   aix | dce | gnat | irix | posix | posix95 | rtems | \
1360   single | solaris | vxworks | win32 | mipssde)
1361     target_thread_file=${enable_threads}
1362     ;;
1363   *)
1364     echo "${enable_threads} is an unknown thread package" 1>&2
1365     exit 1
1366     ;;
1367 esac
1368
1369 if test x${thread_file} = x; then
1370   # No thread file set by target-specific clauses in config.gcc,
1371   # so use file chosen by default logic above
1372   thread_file=${target_thread_file}
1373 fi
1374
1375 # Make gthr-default.h if we have a thread file.
1376 gthread_flags=
1377 if test $thread_file != single; then
1378   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1379   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1380     rm -f gthr-default.h-t
1381   else
1382     mv -f gthr-default.h-t gthr-default.h
1383   fi
1384   gthread_flags=-DHAVE_GTHR_DEFAULT
1385 fi
1386 AC_SUBST(gthread_flags)
1387
1388 # --------
1389 # UNSORTED
1390 # --------
1391
1392 use_cxa_atexit=no
1393 if test x$enable___cxa_atexit = xyes || \
1394    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1395   if test x$host = x$target; then
1396     case $host in
1397       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1398       # keyed to flag_use_cxa_atexit
1399       *-*-mingw32*)
1400         use_cxa_atexit=yes
1401         ;;
1402       *)
1403         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1404           [echo "__cxa_atexit can't be enabled on this target"])
1405         ;;
1406     esac
1407   else
1408     # We can't check for __cxa_atexit when building a cross, so assume
1409     # it is available
1410     use_cxa_atexit=yes
1411   fi
1412   if test x$use_cxa_atexit = xyes; then
1413     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1414       [Define if you want to use __cxa_atexit, rather than atexit, to
1415       register C++ destructors for local statics and global objects.
1416       This is essential for fully standards-compliant handling of
1417       destructors, but requires __cxa_atexit in libc.])
1418   fi
1419 fi
1420
1421 # Look for a file containing extra machine modes.
1422 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1423   extra_modes_file='$(srcdir)'/config/${extra_modes}
1424   AC_SUBST(extra_modes_file)
1425   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1426   [Define to the name of a file containing a list of extra machine modes
1427    for this architecture.])
1428 fi
1429
1430 # Convert extra_options into a form suitable for Makefile use.
1431 extra_opt_files=
1432 for f in $extra_options; do
1433   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1434 done
1435 AC_SUBST(extra_opt_files)
1436
1437 # auto-host.h is the file containing items generated by autoconf and is
1438 # the first file included by config.h.
1439 # If host=build, it is correct to have bconfig include auto-host.h
1440 # as well.  If host!=build, we are in error and need to do more
1441 # work to find out the build config parameters.
1442 if test x$host = x$build
1443 then
1444         build_auto=auto-host.h
1445 else
1446         # We create a subdir, then run autoconf in the subdir.
1447         # To prevent recursion we set host and build for the new
1448         # invocation of configure to the build for this invocation
1449         # of configure.
1450         tempdir=build.$$
1451         rm -rf $tempdir
1452         mkdir $tempdir
1453         cd $tempdir
1454         case ${srcdir} in
1455         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1456         *) realsrcdir=../${srcdir};;
1457         esac
1458         saved_CFLAGS="${CFLAGS}"
1459         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1460         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1461         ${realsrcdir}/configure \
1462                 --enable-languages=${enable_languages-all} \
1463                 --target=$target_alias --host=$build_alias --build=$build_alias
1464         CFLAGS="${saved_CFLAGS}"
1465
1466         # We just finished tests for the build machine, so rename
1467         # the file auto-build.h in the gcc directory.
1468         mv auto-host.h ../auto-build.h
1469         cd ..
1470         rm -rf $tempdir
1471         build_auto=auto-build.h
1472 fi
1473 AC_SUBST(build_subdir)
1474
1475 tm_file="${tm_file} defaults.h"
1476 tm_p_file="${tm_p_file} tm-preds.h"
1477 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1478 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1479 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1480 # put this back in temporarily.
1481 xm_file="auto-host.h ansidecl.h ${xm_file}"
1482
1483 # --------
1484 # UNSORTED
1485 # --------
1486
1487 changequote(,)dnl
1488 # Compile in configure arguments.
1489 if test -f configargs.h ; then
1490         # Being re-configured.
1491         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1492         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1493 else
1494         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1495 fi
1496
1497 # Double all backslashes and backslash all quotes to turn
1498 # gcc_config_arguments into a C string.
1499 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1500 $gcc_config_arguments
1501 EOF
1502 gcc_config_arguments_str=`cat conftest.out`
1503 rm -f conftest.out
1504
1505 cat > configargs.h <<EOF
1506 /* Generated automatically. */
1507 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1508 static const char thread_model[] = "$thread_file";
1509
1510 static const struct {
1511   const char *name, *value;
1512 } configure_default_options[] = $configure_default_options;
1513 EOF
1514 changequote([,])dnl
1515
1516 changequote(,)dnl
1517 gcc_BASEVER=`cat $srcdir/BASE-VER`
1518 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1519 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1520 if test -f $srcdir/REVISION ; then
1521         gcc_REVISION=`cat $srcdir/REVISION`
1522 else
1523         gcc_REVISION=""
1524 fi
1525 cat > plugin-version.h <<EOF
1526 #include "configargs.h"
1527
1528 static char basever[] = "$gcc_BASEVER";
1529 static char datestamp[] = "$gcc_DATESTAMP";
1530 static char devphase[] = "$gcc_DEVPHASE";
1531 static char revision[] = "$gcc_REVISION";
1532
1533 /* FIXME plugins: We should make the version information more precise.
1534    One way to do is to add a checksum. */
1535
1536 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1537                                                 devphase, revision,
1538                                                 configuration_arguments};
1539 EOF
1540 changequote([,])dnl
1541
1542 # Internationalization
1543 ZW_GNU_GETTEXT_SISTER_DIR
1544
1545 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1546 # -liconv on the link line twice.
1547 case "$LIBINTL" in *$LIBICONV*)
1548         LIBICONV= ;;
1549 esac
1550
1551 AC_ARG_ENABLE(secureplt,
1552 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1553 [], [])
1554
1555 AC_ARG_ENABLE(cld,
1556 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1557 [enable_cld=no])
1558
1559 # Windows32 Registry support for specifying GCC installation paths.
1560 AC_ARG_ENABLE(win32-registry,
1561 [  --disable-win32-registry
1562                           disable lookup of installation paths in the
1563                           Registry on Windows hosts
1564   --enable-win32-registry enable registry lookup (default)
1565   --enable-win32-registry=KEY
1566                           use KEY instead of GCC version as the last portion
1567                           of the registry key],,)
1568
1569 case $host_os in
1570   win32 | pe | cygwin* | mingw32* | uwin*)
1571     if test "x$enable_win32_registry" != xno; then
1572       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1573     fi
1574
1575     if test "x$enable_win32_registry" != xno; then
1576       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1577   [Define to 1 if installation paths should be looked up in the Windows
1578    Registry. Ignored on non-Windows hosts.])
1579
1580       if test "x$enable_win32_registry" != xyes \
1581          && test "x$enable_win32_registry" != x; then
1582         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1583   [Define to be the last component of the Windows registry key under which
1584    to look for installation paths.  The full key used will be
1585    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1586    The default is the GCC version number.])
1587       fi
1588     fi
1589   ;;
1590 esac
1591
1592 # Get an absolute path to the GCC top-level source directory
1593 holddir=`${PWDCMD-pwd}`
1594 cd $srcdir
1595 topdir=`${PWDCMD-pwd}`
1596 cd $holddir
1597
1598 # Conditionalize the makefile for this host machine.
1599 xmake_file=
1600 for f in ${host_xmake_file}
1601 do
1602         if test -f ${srcdir}/config/$f
1603         then
1604                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1605         fi
1606 done
1607
1608 # Conditionalize the makefile for this target machine.
1609 tmake_file_=
1610 for f in ${tmake_file}
1611 do
1612         if test -f ${srcdir}/config/$f
1613         then
1614                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1615         fi
1616 done
1617 tmake_file="${tmake_file_}"
1618
1619 out_object_file=`basename $out_file .c`.o
1620
1621 tm_file_list="options.h"
1622 tm_include_list="options.h"
1623 for f in $tm_file; do
1624   case $f in
1625     ./* )
1626        f=`echo $f | sed 's/^..//'`
1627        tm_file_list="${tm_file_list} $f"
1628        tm_include_list="${tm_include_list} $f"
1629        ;;
1630     defaults.h )
1631        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1632        tm_include_list="${tm_include_list} $f"
1633        ;;
1634     * )
1635        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1636        tm_include_list="${tm_include_list} config/$f"
1637        ;;
1638   esac
1639 done
1640
1641 tm_p_file_list=
1642 tm_p_include_list=
1643 for f in $tm_p_file; do
1644   case $f in
1645     tm-preds.h )
1646        tm_p_file_list="${tm_p_file_list} $f"
1647        tm_p_include_list="${tm_p_include_list} $f"
1648        ;;
1649     * )
1650        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1651        tm_p_include_list="${tm_p_include_list} config/$f"
1652   esac
1653 done
1654
1655 xm_file_list=
1656 xm_include_list=
1657 for f in $xm_file; do
1658   case $f in
1659     ansidecl.h )
1660        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1661        xm_include_list="${xm_include_list} $f"
1662        ;;
1663     auto-host.h )
1664        xm_file_list="${xm_file_list} $f"
1665        xm_include_list="${xm_include_list} $f"
1666        ;;
1667     * )
1668        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1669        xm_include_list="${xm_include_list} config/$f"
1670        ;;
1671   esac
1672 done
1673
1674 host_xm_file_list=
1675 host_xm_include_list=
1676 for f in $host_xm_file; do
1677   case $f in
1678     ansidecl.h )
1679        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1680        host_xm_include_list="${host_xm_include_list} $f"
1681        ;;
1682     auto-host.h )
1683        host_xm_file_list="${host_xm_file_list} $f"
1684        host_xm_include_list="${host_xm_include_list} $f"
1685        ;;
1686     * )
1687        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1688        host_xm_include_list="${host_xm_include_list} config/$f"
1689        ;;
1690   esac
1691 done
1692
1693 build_xm_file_list=
1694 for f in $build_xm_file; do
1695   case $f in
1696     ansidecl.h )
1697        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1698        build_xm_include_list="${build_xm_include_list} $f"
1699        ;;
1700     auto-build.h | auto-host.h )
1701        build_xm_file_list="${build_xm_file_list} $f"
1702        build_xm_include_list="${build_xm_include_list} $f"
1703        ;;
1704     * )
1705        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1706        build_xm_include_list="${build_xm_include_list} config/$f"
1707        ;;
1708   esac
1709 done
1710
1711 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1712 # cross-compiler which does not use the native headers and libraries.
1713 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1714 CROSS=                                          AC_SUBST(CROSS)
1715 ALL=all.internal                                AC_SUBST(ALL)
1716 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1717
1718 if test "x$with_build_sysroot" != x; then
1719   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1720 else
1721   # This value is used, even on a native system, because
1722   # CROSS_SYSTEM_HEADER_DIR is just
1723   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1724   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1725 fi
1726
1727 if test x$host != x$target
1728 then
1729         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1730         ALL=all.cross
1731         SYSTEM_HEADER_DIR=$build_system_header_dir
1732         case "$host","$target" in
1733         # Darwin crosses can use the host system's libraries and headers,
1734         # because of the fat library support.  Of course, it must be the
1735         # same version of Darwin on both sides.  Allow the user to
1736         # just say --target=foo-darwin without a version number to mean
1737         # "the version on this system".
1738             *-*-darwin*,*-*-darwin*)
1739                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1740                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1741                 if test $hostos = $targetos -o $targetos = darwin ; then
1742                     CROSS=
1743                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1744                     with_headers=yes
1745                 fi
1746                 ;;
1747
1748             i?86-*-*,x86_64-*-* \
1749             | powerpc*-*-*,powerpc64*-*-*)
1750                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1751         esac
1752 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1753         SYSTEM_HEADER_DIR=$build_system_header_dir
1754 fi
1755
1756 # If this is a cross-compiler that does not
1757 # have its own set of headers then define
1758 # inhibit_libc
1759
1760 # If this is using newlib, without having the headers available now,
1761 # then define inhibit_libc in LIBGCC2_CFLAGS.
1762 # This prevents libgcc2 from containing any code which requires libc
1763 # support.
1764 : ${inhibit_libc=false}
1765 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1766        test x$with_newlib = xyes ; } &&
1767      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1768        inhibit_libc=true
1769 fi
1770 AC_SUBST(inhibit_libc)
1771
1772 # When building gcc with a cross-compiler, we need to adjust things so
1773 # that the generator programs are still built with the native compiler.
1774 # Also, we cannot run fixincludes.
1775
1776 # These are the normal (build=host) settings:
1777 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1778 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1779 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1780 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1781
1782 # And these apply if build != host, or we are generating coverage data
1783 if test x$build != x$host || test "x$coverage_flags" != x
1784 then
1785     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1786     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1787 fi
1788
1789 # Expand extra_headers to include complete path.
1790 # This substitutes for lots of t-* files.
1791 extra_headers_list=
1792 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1793 for file in ${extra_headers} ; do
1794   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1795 done
1796
1797 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1798 if test x"$use_gcc_tgmath" = xyes
1799 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1800 fi
1801
1802 # Define collect2 in Makefile.
1803 case $host_can_use_collect2 in
1804   no) collect2= ;;
1805   *) collect2='collect2$(exeext)' ;;
1806 esac
1807 AC_SUBST([collect2])
1808
1809 # Add a definition of USE_COLLECT2 if system wants one.
1810 case $use_collect2 in
1811   no) use_collect2= ;;
1812   "") ;;
1813   *)
1814     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1815     xm_defines="${xm_defines} USE_COLLECT2"
1816     case $host_can_use_collect2 in
1817       no)
1818         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1819         ;;
1820     esac
1821     ;;
1822 esac
1823
1824 # ---------------------------
1825 # Assembler & linker features
1826 # ---------------------------
1827
1828 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1829 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1830 # However when ld-new is first executed from the build tree, libtool will
1831 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1832 # to the build tree.  While doing this we need to use the previous-stage
1833 # linker, or we have an infinite loop.  The presence of a shell script as
1834 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1835 # the gcc/collect-ld script.  So we need to know how libtool works, or
1836 # exec-tool will fail.
1837
1838 m4_defun([_LT_CONFIG_COMMANDS], [])
1839 AC_PROG_LIBTOOL
1840 AC_SUBST(objdir)
1841 AC_SUBST(enable_fast_install)
1842
1843 # Identify the assembler which will work hand-in-glove with the newly
1844 # built GCC, so that we can examine its features.  This is the assembler
1845 # which will be driven by the driver program.
1846 #
1847 # If build != host, and we aren't building gas in-tree, we identify a
1848 # build->target assembler and hope that it will have the same features
1849 # as the host->target assembler we'll be using.
1850 gcc_cv_gas_major_version=
1851 gcc_cv_gas_minor_version=
1852 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1853
1854 m4_pattern_allow([AS_FOR_TARGET])dnl
1855 AS_VAR_SET_IF(gcc_cv_as,, [
1856 if test -x "$DEFAULT_ASSEMBLER"; then
1857         gcc_cv_as="$DEFAULT_ASSEMBLER"
1858 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1859      && test -f ../gas/Makefile \
1860      && test x$build = x$host; then
1861         gcc_cv_as=../gas/as-new$build_exeext
1862 elif test -x as$build_exeext; then
1863         # Build using assembler in the current directory.
1864         gcc_cv_as=./as$build_exeext
1865 elif test -x $AS_FOR_TARGET; then
1866         gcc_cv_as="$AS_FOR_TARGET"
1867 else
1868         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1869 fi])
1870
1871 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1872 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1873 case "$ORIGINAL_AS_FOR_TARGET" in
1874   ./as | ./as$build_exeext) ;;
1875   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1876 esac
1877
1878 AC_MSG_CHECKING(what assembler to use)
1879 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1880   # Single tree build which includes gas.  We want to prefer it
1881   # over whatever linker top-level may have detected, since
1882   # we'll use what we're building after installation anyway.
1883   AC_MSG_RESULT(newly built gas)
1884   in_tree_gas=yes
1885   _gcc_COMPUTE_GAS_VERSION
1886   in_tree_gas_is_elf=no
1887   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1888      || (grep 'obj_format = multi' ../gas/Makefile \
1889          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1890   then
1891     in_tree_gas_is_elf=yes
1892   fi
1893 else
1894   AC_MSG_RESULT($gcc_cv_as)
1895   in_tree_gas=no
1896 fi
1897
1898 # Identify the linker which will work hand-in-glove with the newly
1899 # built GCC, so that we can examine its features.  This is the linker
1900 # which will be driven by the driver program.
1901 #
1902 # If build != host, and we aren't building gas in-tree, we identify a
1903 # build->target linker and hope that it will have the same features
1904 # as the host->target linker we'll be using.
1905 gcc_cv_gld_major_version=
1906 gcc_cv_gld_minor_version=
1907 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1908 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1909
1910 AS_VAR_SET_IF(gcc_cv_ld,, [
1911 if test -x "$DEFAULT_LINKER"; then
1912         gcc_cv_ld="$DEFAULT_LINKER"
1913 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1914      && test -f ../ld/Makefile \
1915      && test x$build = x$host; then
1916         gcc_cv_ld=../ld/ld-new$build_exeext
1917 elif test -x collect-ld$build_exeext; then
1918         # Build using linker in the current directory.
1919         gcc_cv_ld=./collect-ld$build_exeext
1920 elif test -x $LD_FOR_TARGET; then
1921         gcc_cv_ld="$LD_FOR_TARGET"
1922 else
1923         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1924 fi])
1925
1926 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
1927 PLUGIN_LD=`basename $gcc_cv_ld`
1928 AC_ARG_WITH(plugin-ld,
1929 [  --with-plugin-ld=[[ARG]]  specify the plugin linker],
1930 [if test x"$withval" != x; then
1931    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
1932    PLUGIN_LD="$withval"
1933  fi])
1934 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
1935 AC_DEFINE_UNQUOTED(PLUGIN_LD, "$PLUGIN_LD", [Specify plugin linker])
1936
1937 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1938 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1939 case "$ORIGINAL_LD_FOR_TARGET" in
1940   ./collect-ld | ./collect-ld$build_exeext) ;;
1941   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1942 esac
1943
1944 AC_MSG_CHECKING(what linker to use)
1945 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1946         # Single tree build which includes ld.  We want to prefer it
1947         # over whatever linker top-level may have detected, since
1948         # we'll use what we're building after installation anyway.
1949         AC_MSG_RESULT(newly built ld)
1950         in_tree_ld=yes
1951         in_tree_ld_is_elf=no
1952         if (grep 'EMUL = .*elf' ../ld/Makefile \
1953             || grep 'EMUL = .*linux' ../ld/Makefile \
1954             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1955           in_tree_ld_is_elf=yes
1956         fi
1957         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1958         do
1959 changequote(,)dnl
1960                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1961                 if test x$gcc_cv_gld_version != x; then
1962                         break
1963                 fi
1964         done
1965         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1966         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1967 changequote([,])dnl
1968 else
1969         AC_MSG_RESULT($gcc_cv_ld)
1970         in_tree_ld=no
1971 fi
1972
1973 # Figure out what nm we will be using.
1974 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1975 AS_VAR_SET_IF(gcc_cv_nm,, [
1976 if test -f $gcc_cv_binutils_srcdir/configure.in \
1977      && test -f ../binutils/Makefile \
1978      && test x$build = x$host; then
1979         gcc_cv_nm=../binutils/nm-new$build_exeext
1980 elif test -x nm$build_exeext; then
1981         gcc_cv_nm=./nm$build_exeext
1982 elif test -x $NM_FOR_TARGET; then
1983         gcc_cv_nm="$NM_FOR_TARGET"
1984 else
1985         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1986 fi])
1987
1988 AC_MSG_CHECKING(what nm to use)
1989 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1990         # Single tree build which includes binutils.
1991         AC_MSG_RESULT(newly built nm)
1992         in_tree_nm=yes
1993 else
1994         AC_MSG_RESULT($gcc_cv_nm)
1995         in_tree_nm=no
1996 fi
1997
1998 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1999 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2000 case "$ORIGINAL_NM_FOR_TARGET" in
2001   ./nm | ./nm$build_exeext) ;;
2002   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2003 esac
2004
2005
2006 # Figure out what objdump we will be using.
2007 AS_VAR_SET_IF(gcc_cv_objdump,, [
2008 if test -f $gcc_cv_binutils_srcdir/configure.in \
2009      && test -f ../binutils/Makefile \
2010      && test x$build = x$host; then
2011         # Single tree build which includes binutils.
2012         gcc_cv_objdump=../binutils/objdump$build_exeext
2013 elif test -x objdump$build_exeext; then
2014         gcc_cv_objdump=./objdump$build_exeext
2015 elif test -x $OBJDUMP_FOR_TARGET; then
2016         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2017 else
2018         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2019 fi])
2020
2021 AC_MSG_CHECKING(what objdump to use)
2022 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2023         # Single tree build which includes binutils.
2024         AC_MSG_RESULT(newly built objdump)
2025 elif test x$gcc_cv_objdump = x; then
2026         AC_MSG_RESULT(not found)
2027 else
2028         AC_MSG_RESULT($gcc_cv_objdump)
2029 fi
2030
2031 # Figure out what readelf we will be using.
2032 AS_VAR_SET_IF(gcc_cv_readelf,, [
2033 if test -f $gcc_cv_binutils_srcdir/configure.in \
2034      && test -f ../binutils/Makefile \
2035      && test x$build = x$host; then
2036         # Single tree build which includes binutils.
2037         gcc_cv_readelf=../binutils/readelf$build_exeext
2038 elif test -x readelf$build_exeext; then
2039         gcc_cv_readelf=./readelf$build_exeext
2040 else
2041         AC_PATH_PROG(gcc_cv_readelf, readelf)
2042 fi])
2043
2044 AC_MSG_CHECKING(what readelf to use)
2045 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2046         # Single tree build which includes binutils.
2047         AC_MSG_RESULT(newly built readelf)
2048 elif test x$gcc_cv_readelf = x; then
2049         AC_MSG_RESULT(not found)
2050 else
2051         AC_MSG_RESULT($gcc_cv_readelf)
2052 fi
2053
2054 # Figure out what assembler alignment features are present.
2055 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2056  [2,6,0],,
2057 [.balign 4
2058 .p2align 2],,
2059 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2060   [Define if your assembler supports .balign and .p2align.])])
2061
2062 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2063  [2,8,0],,
2064  [.p2align 4,,7],,
2065 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2066   [Define if your assembler supports specifying the maximum number
2067    of bytes to skip when using the GAS .p2align command.])])
2068
2069 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2070  [2,8,0],,
2071  [.literal16],,
2072 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2073   [Define if your assembler supports .literal16.])])
2074
2075 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2076  [elf,2,9,0],,
2077  [conftest_label1: .word 0
2078 .subsection -1
2079 conftest_label2: .word 0
2080 .previous],
2081  [if test x$gcc_cv_nm != x; then
2082     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2083     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2084     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2085     then :
2086     else gcc_cv_as_subsection_m1=yes
2087     fi
2088     rm -f conftest.nm1 conftest.nm2
2089   fi],
2090  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2091   [Define if your assembler supports .subsection and .subsection -1 starts
2092    emitting at the beginning of your section.])])
2093
2094 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2095  [2,2,0],,
2096  [      .weak foobar],,
2097 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2098
2099 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2100  [2,17,0],,
2101  [      .weakref foobar, barfnot],,
2102 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2103
2104 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2105  [2,15,91],,
2106  [      .SPACE $TEXT$
2107         .NSUBSPA $CODE$,COMDAT],,
2108 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2109
2110 # .hidden needs to be supported in both the assembler and the linker,
2111 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2112 # This is irritatingly difficult to feature test for; we have to check the
2113 # date string after the version number.  If we've got an in-tree
2114 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2115 # to be safe.
2116 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2117 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2118  [elf,2,13,0],,
2119 [       .hidden foobar
2120 foobar:])
2121
2122 changequote(,)dnl
2123 if test $in_tree_ld != yes ; then
2124   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2125   if echo "$ld_ver" | grep GNU > /dev/null; then
2126     ld_vers=`echo $ld_ver | sed -n \
2127         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2128     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2129     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2130     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2131     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2132   fi
2133 fi
2134 changequote([,])dnl
2135
2136 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2137 [if test $in_tree_ld = yes ; then
2138   gcc_cv_ld_hidden=no
2139   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2140      && test $in_tree_ld_is_elf = yes; then
2141      gcc_cv_ld_hidden=yes
2142   fi
2143 else
2144 changequote(,)dnl
2145   gcc_cv_ld_hidden=yes
2146   if echo "$ld_ver" | grep GNU > /dev/null; then
2147     if test 0"$ld_date" -lt 20020404; then
2148       if test -n "$ld_date"; then
2149         # If there was date string, but was earlier than 2002-04-04, fail
2150         gcc_cv_ld_hidden=no
2151       elif test -z "$ld_vers"; then
2152         # If there was no date string nor ld version number, something is wrong
2153         gcc_cv_ld_hidden=no
2154       else
2155         test -z "$ld_vers_patch" && ld_vers_patch=0
2156         if test "$ld_vers_major" -lt 2; then
2157           gcc_cv_ld_hidden=no
2158         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2159           gcc_cv_ld_hidden="no"
2160         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2161           gcc_cv_ld_hidden=no
2162         fi
2163       fi
2164     fi
2165   else
2166     case "${target}" in
2167       hppa64*-*-hpux* | ia64*-*-hpux*)
2168         gcc_cv_ld_hidden=yes
2169         ;;
2170       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2171         gcc_cv_ld_hidden=yes
2172         ;;
2173       *)
2174         gcc_cv_ld_hidden=no
2175         ;;
2176     esac
2177   fi
2178 changequote([,])dnl
2179 fi])
2180 libgcc_visibility=no
2181 AC_SUBST(libgcc_visibility)
2182 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2183 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2184   libgcc_visibility=yes
2185   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2186   [Define if your assembler and linker support .hidden.])
2187 fi
2188
2189 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2190 gcc_cv_ld_ro_rw_mix=unknown
2191 if test $in_tree_ld = yes ; then
2192   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2193      && test $in_tree_ld_is_elf = yes; then
2194     gcc_cv_ld_ro_rw_mix=read-write
2195   fi
2196 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2197   echo '.section myfoosect, "a"' > conftest1.s
2198   echo '.section myfoosect, "aw"' > conftest2.s
2199   echo '.byte 1' >> conftest2.s
2200   echo '.section myfoosect, "a"' > conftest3.s
2201   echo '.byte 0' >> conftest3.s
2202   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2203      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2204      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2205      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2206         conftest2.o conftest3.o > /dev/null 2>&1; then
2207     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2208                          | sed -e '/myfoosect/!d' -e N`
2209     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2210       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2211         gcc_cv_ld_ro_rw_mix=read-only
2212       else
2213         gcc_cv_ld_ro_rw_mix=read-write
2214       fi
2215     fi
2216   fi
2217 changequote(,)dnl
2218   rm -f conftest.* conftest[123].*
2219 changequote([,])dnl
2220 fi
2221 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2222         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2223   [Define if your linker links a mix of read-only
2224    and read-write sections into a read-write section.])
2225 fi
2226 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2227
2228 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2229 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2230   [elf,2,11,0],,
2231 [       .data
2232         .uleb128 L2 - L1
2233 L1:
2234         .uleb128 1280
2235         .sleb128 -1010
2236 L2:],
2237  [# GAS versions before 2.11 do not support uleb128,
2238   # despite appearing to.
2239   # ??? There exists an elf-specific test that will crash
2240   # the assembler.  Perhaps it's better to figure out whether
2241   # arbitrary sections are supported and try the test.
2242   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2243   if echo "$as_ver" | grep GNU > /dev/null; then
2244 changequote(,)dnl
2245     as_vers=`echo $as_ver | sed -n \
2246         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2247     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2248     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2249 changequote([,])dnl
2250     if test $as_major -eq 2 && test $as_minor -lt 11
2251     then :
2252     else gcc_cv_as_leb128=yes
2253     fi
2254   fi],
2255   [AC_DEFINE(HAVE_AS_LEB128, 1,
2256     [Define if your assembler supports .sleb128 and .uleb128.])])
2257
2258 # Check if we have assembler support for unwind directives.
2259 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2260   ,,
2261 [       .text
2262         .cfi_startproc
2263         .cfi_offset 0, 0
2264         .cfi_same_value 1
2265         .cfi_def_cfa 1, 2
2266         .cfi_escape 1, 2, 3, 4, 5
2267         .cfi_endproc],
2268 [case "$target" in
2269   *-*-solaris*)
2270     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2271     # read-only and read-write sections, we need to make sure that the
2272     # assembler used emits read-write .eh_frame sections.
2273     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2274       if test "x$gcc_cv_objdump" != x; then
2275         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2276                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2277           gcc_cv_as_cfi_directive=no
2278         else
2279           gcc_cv_as_cfi_directive=yes
2280         fi
2281       else
2282         # no objdump, err on the side of caution
2283         gcc_cv_as_cfi_directive=no
2284       fi
2285     else
2286       gcc_cv_as_cfi_directive=yes
2287     fi
2288     ;;
2289   *-*-*)
2290     gcc_cv_as_cfi_directive=yes
2291     ;;
2292 esac])
2293 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_readelf != x; then
2294 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2295   ,,
2296 [       .text
2297         .cfi_startproc
2298         .cfi_adjust_cfa_offset 64
2299         .skip 512, 0
2300         .cfi_adjust_cfa_offset 128
2301         .cfi_endproc],
2302 [
2303 changequote(,)dnl
2304 if $gcc_cv_readelf -wf conftest.o 2>/dev/null \
2305     | grep 'DW_CFA_advance_loc[12]:[    ][      ]*512[  ]' >/dev/null; then
2306    gcc_cv_as_cfi_advance_working=yes
2307 fi
2308 changequote([,])dnl
2309 ])
2310 else
2311   # no readelf, err on the side of caution
2312   gcc_cv_as_cfi_advance_working=no
2313 fi
2314 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2315   [`if test $gcc_cv_as_cfi_directive = yes \
2316        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2317   [Define 0/1 if your assembler supports CFI directives.])
2318
2319 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2320   gcc_cv_as_cfi_personality_directive, ,,
2321 [       .text
2322         .cfi_startproc
2323         .cfi_personality 0, symbol
2324         .cfi_endproc])
2325 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2326   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2327     then echo 1; else echo 0; fi`],
2328   [Define 0/1 if your assembler supports .cfi_personality.])
2329
2330 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2331   gcc_cv_as_cfi_sections_directive, ,,
2332 [       .text
2333         .cfi_sections .debug_frame, .eh_frame
2334         .cfi_startproc
2335         .cfi_endproc])
2336 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2337   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2338     then echo 1; else echo 0; fi`],
2339   [Define 0/1 if your assembler supports .cfi_sections.])
2340
2341 # GAS versions up to and including 2.11.0 may mis-optimize
2342 # .eh_frame data.
2343 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2344   [elf,2,12,0],,
2345 [       .text
2346 .LFB1:
2347         .4byte  0
2348 .L1:
2349         .4byte  0
2350 .LFE1:
2351         .section        .eh_frame,"aw",@progbits
2352 __FRAME_BEGIN__:
2353         .4byte  .LECIE1-.LSCIE1
2354 .LSCIE1:
2355         .4byte  0x0
2356         .byte   0x1
2357         .ascii "z\0"
2358         .byte   0x1
2359         .byte   0x78
2360         .byte   0x1a
2361         .byte   0x0
2362         .byte   0x4
2363         .4byte  1
2364         .p2align 1
2365 .LECIE1:
2366 .LSFDE1:
2367         .4byte  .LEFDE1-.LASFDE1
2368 .LASFDE1:
2369         .4byte  .LASFDE1-__FRAME_BEGIN__
2370         .4byte  .LFB1
2371         .4byte  .LFE1-.LFB1
2372         .byte   0x4
2373         .4byte  .LFE1-.LFB1
2374         .byte   0x4
2375         .4byte  .L1-.LFB1
2376 .LEFDE1:],
2377 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2378 cat > conftest.lit <<EOF
2379  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2380  0010 01000000 12000000 18000000 00000000  ................
2381  0020 08000000 04080000 0044               .........D      @&t@
2382 EOF
2383 cat > conftest.big <<EOF
2384  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2385  0010 00000001 00000012 00000018 00000000  ................
2386  0020 00000008 04000000 0844               .........D      @&t@
2387 EOF
2388   # If the assembler didn't choke, and we can objdump,
2389   # and we got the correct data, then succeed.
2390   # The text in the here-document typically retains its unix-style line
2391   # endings, while the output of objdump will use host line endings.
2392   # Therefore, use diff -b for the comparisons.
2393   if test x$gcc_cv_objdump != x \
2394   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2395      | tail -3 > conftest.got \
2396   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2397     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2398   then
2399     gcc_cv_as_eh_frame=yes
2400   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2401     gcc_cv_as_eh_frame=buggy
2402   else
2403     # Uh oh, what do we do now?
2404     gcc_cv_as_eh_frame=no
2405   fi])
2406
2407 if test $gcc_cv_as_eh_frame = buggy; then
2408   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2409   [Define if your assembler mis-optimizes .eh_frame data.])
2410 fi
2411
2412 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2413  [elf,2,12,0], [--fatal-warnings],
2414  [.section .rodata.str, "aMS", @progbits, 1])
2415 if test $gcc_cv_as_shf_merge = no; then
2416   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2417     [elf,2,12,0], [--fatal-warnings],
2418     [.section .rodata.str, "aMS", %progbits, 1])
2419 fi
2420 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2421   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2422 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2423
2424 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2425  [elf,2,16,0], [--fatal-warnings],
2426  [.section .text,"axG",@progbits,.foo,comdat])
2427 if test $gcc_cv_as_comdat_group = yes; then
2428   gcc_cv_as_comdat_group_percent=no
2429 else
2430  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2431    [elf,2,16,0], [--fatal-warnings],
2432    [.section .text,"axG",%progbits,.foo,comdat])
2433 fi
2434 if test $in_tree_ld = yes ; then
2435   comdat_group=no
2436   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2437      && test $in_tree_ld_is_elf = yes; then
2438      comdat_group=yes
2439   fi
2440 elif test x"$ld_vers" != x; then
2441   comdat_group=yes
2442   if test 0"$ld_date" -lt 20050308; then
2443     if test -n "$ld_date"; then
2444       # If there was date string, but was earlier than 2005-03-08, fail
2445       comdat_group=no
2446     elif test "$ld_vers_major" -lt 2; then
2447       comdat_group=no
2448     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2449       comdat_group=no
2450     fi
2451   fi
2452 else
2453   # assume linkers other than GNU ld don't support COMDAT group
2454   comdat_group=no
2455 fi
2456 if test $comdat_group = no; then
2457   gcc_cv_as_comdat_group=no
2458   gcc_cv_as_comdat_group_percent=no
2459 fi
2460 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2461   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2462 [Define 0/1 if your assembler and linker support COMDAT groups.])
2463
2464 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2465  gcc_cv_as_discriminator,
2466  [2,19,51],,
2467 [       .text
2468         .file 1 "conf.c"
2469         .loc 1 1 0 discriminator 1],,
2470 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2471   [Define if your assembler supports the .loc discriminator sub-directive.])])
2472
2473 # Thread-local storage - the check is heavily parameterized.
2474 conftest_s=
2475 tls_first_major=
2476 tls_first_minor=
2477 tls_as_opt=
2478 case "$target" in
2479 changequote(,)dnl
2480   alpha*-*-*)
2481     conftest_s='
2482         .section ".tdata","awT",@progbits
2483 foo:    .long   25
2484         .text
2485         ldq     $27,__tls_get_addr($29)         !literal!1
2486         lda     $16,foo($29)                    !tlsgd!1
2487         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2488         ldq     $27,__tls_get_addr($29)         !literal!2
2489         lda     $16,foo($29)                    !tlsldm!2
2490         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2491         ldq     $1,foo($29)                     !gotdtprel
2492         ldah    $2,foo($29)                     !dtprelhi
2493         lda     $3,foo($2)                      !dtprello
2494         lda     $4,foo($29)                     !dtprel
2495         ldq     $1,foo($29)                     !gottprel
2496         ldah    $2,foo($29)                     !tprelhi
2497         lda     $3,foo($2)                      !tprello
2498         lda     $4,foo($29)                     !tprel'
2499         tls_first_major=2
2500         tls_first_minor=13
2501         tls_as_opt=--fatal-warnings
2502         ;;
2503   cris-*-*|crisv32-*-*)
2504     conftest_s='
2505         .section ".tdata","awT",@progbits
2506 x:      .long   25
2507         .text
2508         move.d x:IE,$r10
2509         nop'
2510         tls_first_major=2
2511         tls_first_minor=20
2512         tls_as_opt=--fatal-warnings
2513         ;;
2514   frv*-*-*)
2515     conftest_s='
2516         .section ".tdata","awT",@progbits
2517 x:      .long   25
2518         .text
2519         call    #gettlsoff(x)'
2520         tls_first_major=2
2521         tls_first_minor=14
2522         ;;
2523   hppa*-*-linux*)
2524     conftest_s='
2525 t1:     .reg    %r20
2526 t2:     .reg    %r21
2527 gp:     .reg    %r19
2528         .section ".tdata","awT",@progbits
2529 foo:    .long   25
2530         .text
2531         .align  4
2532         addil LT%foo-$tls_gdidx$,gp
2533         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2534         b __tls_get_addr
2535         nop
2536         addil LT%foo-$tls_ldidx$,gp
2537         b __tls_get_addr
2538         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2539         addil LR%foo-$tls_dtpoff$,%ret0
2540         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2541         mfctl %cr27,%t1
2542         addil LT%foo-$tls_ieoff$,gp
2543         ldw RT%foo-$tls_ieoff$(%r1),%t2
2544         add %t1,%t2,%t3
2545         mfctl %cr27,%t1
2546         addil LR%foo-$tls_leoff$,%t1
2547         ldo RR%foo-$tls_leoff$(%r1),%t2'
2548         tls_first_major=2
2549         tls_first_minor=15
2550         tls_as_opt=--fatal-warnings
2551         ;;
2552   arm*-*-*)
2553     conftest_s='
2554         .section ".tdata","awT",%progbits
2555 foo:    .long   25
2556         .text
2557 .word foo(gottpoff)
2558 .word foo(tpoff)
2559 .word foo(tlsgd)
2560 .word foo(tlsldm)
2561 .word foo(tlsldo)'
2562         tls_first_major=2
2563         tls_first_minor=17
2564         ;;
2565   i[34567]86-*-*)
2566     conftest_s='
2567         .section ".tdata","awT",@progbits
2568 foo:    .long   25
2569         .text
2570         movl    %gs:0, %eax
2571         leal    foo@TLSGD(,%ebx,1), %eax
2572         leal    foo@TLSLDM(%ebx), %eax
2573         leal    foo@DTPOFF(%eax), %edx
2574         movl    foo@GOTTPOFF(%ebx), %eax
2575         subl    foo@GOTTPOFF(%ebx), %eax
2576         addl    foo@GOTNTPOFF(%ebx), %eax
2577         movl    foo@INDNTPOFF, %eax
2578         movl    $foo@TPOFF, %eax
2579         subl    $foo@TPOFF, %eax
2580         leal    foo@NTPOFF(%ecx), %eax'
2581         tls_first_major=2
2582         tls_first_minor=14
2583         tls_as_opt=--fatal-warnings
2584         ;;
2585   x86_64-*-*)
2586     conftest_s='
2587         .section ".tdata","awT",@progbits
2588 foo:    .long   25
2589         .text
2590         movq    %fs:0, %rax
2591         leaq    foo@TLSGD(%rip), %rdi
2592         leaq    foo@TLSLD(%rip), %rdi
2593         leaq    foo@DTPOFF(%rax), %rdx
2594         movq    foo@GOTTPOFF(%rip), %rax
2595         movq    $foo@TPOFF, %rax'
2596         tls_first_major=2
2597         tls_first_minor=14
2598         tls_as_opt=--fatal-warnings
2599         ;;
2600   ia64-*-*)
2601     conftest_s='
2602         .section ".tdata","awT",@progbits
2603 foo:    data8   25
2604         .text
2605         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2606         addl    r17 = @ltoff(@dtprel(foo#)), gp
2607         addl    r18 = @ltoff(@tprel(foo#)), gp
2608         addl    r19 = @dtprel(foo#), gp
2609         adds    r21 = @dtprel(foo#), r13
2610         movl    r23 = @dtprel(foo#)
2611         addl    r20 = @tprel(foo#), gp
2612         adds    r22 = @tprel(foo#), r13
2613         movl    r24 = @tprel(foo#)'
2614         tls_first_major=2
2615         tls_first_minor=13
2616         tls_as_opt=--fatal-warnings
2617         ;;
2618   mips*-*-*)
2619     conftest_s='
2620         .section .tdata,"awT",@progbits
2621 x:
2622         .word 2
2623         .text
2624         addiu $4, $28, %tlsgd(x)
2625         addiu $4, $28, %tlsldm(x)
2626         lui $4, %dtprel_hi(x)
2627         addiu $4, $4, %dtprel_lo(x)
2628         lw $4, %gottprel(x)($28)
2629         lui $4, %tprel_hi(x)
2630         addiu $4, $4, %tprel_lo(x)'
2631         tls_first_major=2
2632         tls_first_minor=16
2633         tls_as_opt='-32 --fatal-warnings'
2634         ;;
2635   m68k-*-*)
2636     conftest_s='
2637         .section .tdata,"awT",@progbits
2638 x:
2639         .word 2
2640         .text
2641 foo:
2642         move.l x@TLSGD(%a5),%a0
2643         move.l x@TLSLDM(%a5),%a0
2644         move.l x@TLSLDO(%a5),%a0
2645         move.l x@TLSIE(%a5),%a0
2646         move.l x@TLSLE(%a5),%a0'
2647         tls_first_major=2
2648         tls_first_minor=19
2649         tls_as_opt='--fatal-warnings'
2650         ;;
2651   powerpc-*-*)
2652     conftest_s='
2653         .section ".tdata","awT",@progbits
2654         .align 2
2655 ld0:    .space 4
2656 ld1:    .space 4
2657 x1:     .space 4
2658 x2:     .space 4
2659 x3:     .space 4
2660         .text
2661         addi 3,31,ld0@got@tlsgd
2662         bl __tls_get_addr
2663         addi 3,31,x1@got@tlsld
2664         bl __tls_get_addr
2665         addi 9,3,x1@dtprel
2666         addis 9,3,x2@dtprel@ha
2667         addi 9,9,x2@dtprel@l
2668         lwz 9,x3@got@tprel(31)
2669         add 9,9,x@tls
2670         addi 9,2,x1@tprel
2671         addis 9,2,x2@tprel@ha
2672         addi 9,9,x2@tprel@l'
2673         tls_first_major=2
2674         tls_first_minor=14
2675         tls_as_opt="-a32 --fatal-warnings"
2676         ;;
2677   powerpc64-*-*)
2678     conftest_s='
2679         .section ".tdata","awT",@progbits
2680         .align 3
2681 ld0:    .space 8
2682 ld1:    .space 8
2683 x1:     .space 8
2684 x2:     .space 8
2685 x3:     .space 8
2686         .text
2687         addi 3,2,ld0@got@tlsgd
2688         bl .__tls_get_addr
2689         nop
2690         addi 3,2,ld1@toc
2691         bl .__tls_get_addr
2692         nop
2693         addi 3,2,x1@got@tlsld
2694         bl .__tls_get_addr
2695         nop
2696         addi 9,3,x1@dtprel
2697         bl .__tls_get_addr
2698         nop
2699         addis 9,3,x2@dtprel@ha
2700         addi 9,9,x2@dtprel@l
2701         bl .__tls_get_addr
2702         nop
2703         ld 9,x3@got@dtprel(2)
2704         add 9,9,3
2705         bl .__tls_get_addr
2706         nop'
2707         tls_first_major=2
2708         tls_first_minor=14
2709         tls_as_opt="-a64 --fatal-warnings"
2710         ;;
2711   s390-*-*)
2712     conftest_s='
2713         .section ".tdata","awT",@progbits
2714 foo:    .long   25
2715         .text
2716         .long   foo@TLSGD
2717         .long   foo@TLSLDM
2718         .long   foo@DTPOFF
2719         .long   foo@NTPOFF
2720         .long   foo@GOTNTPOFF
2721         .long   foo@INDNTPOFF
2722         l       %r1,foo@GOTNTPOFF(%r12)
2723         l       %r1,0(%r1):tls_load:foo
2724         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2725         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2726         tls_first_major=2
2727         tls_first_minor=14
2728         tls_as_opt="-m31 --fatal-warnings"
2729         ;;
2730   s390x-*-*)
2731     conftest_s='
2732         .section ".tdata","awT",@progbits
2733 foo:    .long   25
2734         .text
2735         .quad   foo@TLSGD
2736         .quad   foo@TLSLDM
2737         .quad   foo@DTPOFF
2738         .quad   foo@NTPOFF
2739         .quad   foo@GOTNTPOFF
2740         lg      %r1,foo@GOTNTPOFF(%r12)
2741         larl    %r1,foo@INDNTPOFF
2742         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2743         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2744         tls_first_major=2
2745         tls_first_minor=14
2746         tls_as_opt="-m64 -Aesame --fatal-warnings"
2747         ;;
2748   sh-*-* | sh[34]-*-*)
2749     conftest_s='
2750         .section ".tdata","awT",@progbits
2751 foo:    .long   25
2752         .text
2753         .long   foo@TLSGD
2754         .long   foo@TLSLDM
2755         .long   foo@DTPOFF
2756         .long   foo@GOTTPOFF
2757         .long   foo@TPOFF'
2758         tls_first_major=2
2759         tls_first_minor=13
2760         tls_as_opt=--fatal-warnings
2761         ;;
2762   sparc*-*-*)
2763     case "$target" in
2764       sparc*-sun-solaris2.[56789]*)
2765         # TLS was introduced in the Solaris 9 4/04 release but
2766         # we do not enable it by default on Solaris 9 either.
2767         if test "x$enable_tls" = xyes ; then
2768           on_solaris=yes
2769         else
2770           enable_tls=no;
2771         fi
2772         ;;
2773       sparc*-sun-solaris2.*)
2774         on_solaris=yes
2775         ;;
2776       *)
2777         on_solaris=no
2778         ;;
2779     esac
2780     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2781       conftest_s='
2782         .section ".tdata",#alloc,#write,#tls
2783 foo:    .long   25
2784         .text
2785         sethi   %tgd_hi22(foo), %o0
2786         add     %o0, %tgd_lo10(foo), %o1
2787         add     %l7, %o1, %o0, %tgd_add(foo)
2788         call    __tls_get_addr, %tgd_call(foo)
2789         sethi   %tldm_hi22(foo), %l1
2790         add     %l1, %tldm_lo10(foo), %l2
2791         add     %l7, %l2, %o0, %tldm_add(foo)
2792         call    __tls_get_addr, %tldm_call(foo)
2793         sethi   %tldo_hix22(foo), %l3
2794         xor     %l3, %tldo_lox10(foo), %l4
2795         add     %o0, %l4, %l5, %tldo_add(foo)
2796         sethi   %tie_hi22(foo), %o3
2797         add     %o3, %tie_lo10(foo), %o3
2798         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2799         add     %g7, %o2, %o4, %tie_add(foo)
2800         sethi   %tle_hix22(foo), %l1
2801         xor     %l1, %tle_lox10(foo), %o5
2802         ld      [%g7 + %o5], %o1'
2803         tls_first_major=0
2804         tls_first_minor=0
2805     else
2806       conftest_s='
2807         .section ".tdata","awT",@progbits
2808 foo:    .long   25
2809         .text
2810         sethi   %tgd_hi22(foo), %o0
2811         add     %o0, %tgd_lo10(foo), %o1
2812         add     %l7, %o1, %o0, %tgd_add(foo)
2813         call    __tls_get_addr, %tgd_call(foo)
2814         sethi   %tldm_hi22(foo), %l1
2815         add     %l1, %tldm_lo10(foo), %l2
2816         add     %l7, %l2, %o0, %tldm_add(foo)
2817         call    __tls_get_addr, %tldm_call(foo)
2818         sethi   %tldo_hix22(foo), %l3
2819         xor     %l3, %tldo_lox10(foo), %l4
2820         add     %o0, %l4, %l5, %tldo_add(foo)
2821         sethi   %tie_hi22(foo), %o3
2822         add     %o3, %tie_lo10(foo), %o3
2823         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2824         add     %g7, %o2, %o4, %tie_add(foo)
2825         sethi   %tle_hix22(foo), %l1
2826         xor     %l1, %tle_lox10(foo), %o5
2827         ld      [%g7 + %o5], %o1'
2828         tls_first_major=2
2829         tls_first_minor=14
2830         tls_as_opt="-32 --fatal-warnings"
2831       fi
2832         ;;
2833   xtensa*-*-*)
2834     conftest_s='
2835         .section ".tdata","awT",@progbits
2836 foo:    .long   25
2837         .text
2838         movi    a8, foo@TLSFUNC
2839         movi    a10, foo@TLSARG
2840         callx8.tls a8, foo@TLSCALL'
2841         tls_first_major=2
2842         tls_first_minor=19
2843         ;;
2844 changequote([,])dnl
2845 esac
2846 set_have_as_tls=no
2847 if test "x$enable_tls" = xno ; then
2848   : # TLS explicitly disabled.
2849 elif test "x$enable_tls" = xyes ; then
2850   set_have_as_tls=yes # TLS explicitly enabled.
2851 elif test -z "$tls_first_major"; then
2852   : # If we don't have a check, assume no support.
2853 else
2854   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2855   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2856   [set_have_as_tls=yes])
2857 fi
2858 if test $set_have_as_tls = yes ; then
2859   AC_DEFINE(HAVE_AS_TLS, 1,
2860             [Define if your assembler supports thread-local storage.])
2861 fi
2862
2863 # Target-specific assembler checks.
2864
2865 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2866 gcc_cv_ld_static_dynamic=no
2867 if test $in_tree_ld = yes ; then
2868   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
2869     gcc_cv_ld_static_dynamic=yes
2870   fi
2871 elif test x$gcc_cv_ld != x; then
2872         # Check if linker supports -Bstatic/-Bdynamic option
2873         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2874           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2875                 gcc_cv_ld_static_dynamic=yes
2876         fi
2877 fi
2878 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2879         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2880 [Define if your linker supports -Bstatic/-Bdynamic option.])
2881 fi
2882 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2883
2884 if test x"$demangler_in_ld" = xyes; then
2885   AC_MSG_CHECKING(linker --demangle support)
2886   gcc_cv_ld_demangle=no
2887   if test $in_tree_ld = yes; then
2888     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2889       gcc_cv_ld_demangle=yes
2890     fi
2891   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2892     # Check if the GNU linker supports --demangle option
2893     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2894       gcc_cv_ld_demangle=yes
2895     fi
2896   fi
2897   if test x"$gcc_cv_ld_demangle" = xyes; then
2898     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2899 [Define if your linker supports --demangle option.])
2900   fi
2901   AC_MSG_RESULT($gcc_cv_ld_demangle)
2902 fi
2903
2904 case "$target" in
2905   # All TARGET_ABI_OSF targets.
2906   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2907     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2908         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2909 [       .set nomacro
2910         .text
2911         extbl   $3, $2, $3      !lituse_bytoff!1
2912         ldq     $2, a($29)      !literal!1
2913         ldq     $4, b($29)      !literal!2
2914         ldq_u   $3, 0($2)       !lituse_base!1
2915         ldq     $27, f($29)     !literal!5
2916         jsr     $26, ($27), f   !lituse_jsr!5
2917         ldah    $29, 0($26)     !gpdisp!3
2918         lda     $0, c($29)      !gprel
2919         ldah    $1, d($29)      !gprelhigh
2920         lda     $1, d($1)       !gprellow
2921         lda     $29, 0($29)     !gpdisp!3],,
2922     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2923   [Define if your assembler supports explicit relocations.])])
2924     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2925         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2926 [       .set nomacro
2927         .text
2928         ldq     $27, a($29)     !literal!1
2929         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2930     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2931   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2932     ;;
2933
2934   cris-*-*)
2935     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2936       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2937       [-no-mul-bug-abort], [.text],,
2938       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2939                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2940     ;;
2941
2942   sparc*-*-*)
2943     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2944       [.register %g2, #scratch],,
2945       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2946                 [Define if your assembler supports .register.])])
2947
2948     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2949       [-relax], [.text],,
2950       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2951                 [Define if your assembler supports -relax option.])])
2952
2953     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2954       gcc_cv_as_sparc_ua_pcrel,,
2955       [-K PIC],
2956 [.text
2957 foo:
2958         nop
2959 .data
2960 .align 4
2961 .byte 0
2962 .uaword %r_disp32(foo)],
2963       [if test x$gcc_cv_ld != x \
2964        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2965          gcc_cv_as_sparc_ua_pcrel=yes
2966        fi
2967        rm -f conftest],
2968       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2969                 [Define if your assembler and linker support unaligned PC relative relocs.])
2970
2971       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2972         gcc_cv_as_sparc_ua_pcrel_hidden,,
2973         [-K PIC],
2974 [.data
2975 .align 4
2976 .byte 0x31
2977 .uaword %r_disp32(foo)
2978 .byte 0x32, 0x33, 0x34
2979 .global foo
2980 .hidden foo
2981 foo:
2982 .skip 4],
2983         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2984          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2985          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2986             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2987             if $gcc_cv_objdump -R conftest 2> /dev/null \
2988                | grep 'DISP32' > /dev/null 2>&1; then
2989                 :
2990             else
2991                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2992             fi
2993          fi
2994          rm -f conftest],
2995          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2996                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2997     ]) # unaligned pcrel relocs
2998
2999     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3000       gcc_cv_as_sparc_offsetable_lo10,,
3001       [-xarch=v9],
3002 [.text
3003         or %g1, %lo(ab) + 12, %g1
3004         or %g1, %lo(ab + 12), %g1],
3005       [if test x$gcc_cv_objdump != x \
3006        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3007           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3008          gcc_cv_as_sparc_offsetable_lo10=yes
3009        fi],
3010        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3011                  [Define if your assembler supports offsetable %lo().])])
3012     ;;
3013
3014 changequote(,)dnl
3015   i[34567]86-*-* | x86_64-*-*)
3016 changequote([,])dnl
3017     case $target_os in
3018       cygwin*)
3019         # Full C++ conformance when using a shared libstdc++-v3 requires some
3020         # support from the Cygwin DLL, which in more recent versions exports
3021         # wrappers to aid in interposing and redirecting operators new, delete,
3022         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3023         # are configuring for a version of Cygwin that exports the wrappers.
3024         if test x$host = x$target; then
3025           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3026         else
3027           # Can't check presence of libc functions during cross-compile, so
3028           # we just have to assume we're building for an up-to-date target.
3029           gcc_ac_cygwin_dll_wrappers=yes
3030         fi
3031         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3032           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3033           [Define if you want to generate code by default that assumes that the
3034            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3035     esac
3036     case $target_os in
3037       cygwin* | pe | mingw32*)
3038         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3039         # definition is used unconditionally to initialise the default state of
3040         # the target option variable that governs usage of the feature.
3041         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3042          [2,19,52],,[.comm foo,1,32])
3043         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3044           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3045           [Define if your assembler supports specifying the alignment
3046            of objects allocated using the GAS .comm command.])
3047         # Used for DWARF 2 in PE
3048         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3049           gcc_cv_as_ix86_pe_secrel32,
3050           [2,15,91],,
3051 [.text
3052 foo:    nop
3053 .data
3054         .secrel32 foo],
3055           [if test x$gcc_cv_ld != x \
3056            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3057              gcc_cv_as_ix86_pe_secrel32=yes
3058            fi
3059            rm -f conftest],
3060           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3061             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3062         ;;
3063     esac
3064
3065     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3066        gcc_cv_as_ix86_filds,,,
3067        [filds mem; fists mem],,
3068        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3069          [Define if your assembler uses filds and fists mnemonics.])])
3070
3071     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3072        gcc_cv_as_ix86_fildq,,,
3073        [fildq mem; fistpq mem],,
3074        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3075          [Define if your assembler uses fildq and fistq mnemonics.])])
3076
3077     gcc_GAS_CHECK_FEATURE([cmov syntax],
3078       gcc_cv_as_ix86_cmov_sun_syntax,,,
3079       [cmovl.l %edx, %eax],,
3080       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3081         [Define if your assembler supports the Sun syntax for cmov.])])
3082
3083     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3084       gcc_cv_as_ix86_ffreep,,,
3085       [ffreep %st(1)],,
3086       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3087         [Define if your assembler supports the ffreep mnemonic.])])
3088
3089     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3090       gcc_cv_as_ix86_sahf,,,
3091       [sahf],,
3092       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3093         [Define if your assembler supports the sahf mnemonic.])])
3094
3095     gcc_GAS_CHECK_FEATURE([swap suffix],
3096       gcc_cv_as_ix86_swap,,,
3097       [movl.s %esp, %ebp],,
3098       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3099         [Define if your assembler supports the swap suffix.])])
3100
3101     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3102       gcc_cv_as_ix86_diff_sect_delta,,,
3103       [.section .rodata
3104 .L1:
3105         .long .L2-.L1
3106         .long .L3-.L1
3107         .text
3108 .L3:    nop
3109 .L2:    nop],,
3110       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3111         [Define if your assembler supports the subtraction of symbols in different sections.])])
3112
3113     # This one is used unconditionally by i386.[ch]; it is to be defined
3114     # to 1 if the feature is present, 0 otherwise.
3115     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3116         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3117 [       .text
3118 .L0:
3119         nop
3120         .data
3121         .long .L0@GOTOFF])
3122     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3123       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3124       [Define true if the assembler supports '.long foo@GOTOFF'.])
3125     ;;
3126
3127   ia64*-*-*)
3128     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3129         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3130 [       .text
3131         addl r15 = @ltoffx(x#), gp
3132         ;;
3133         ld8.mov r16 = [[r15]], x#],,
3134     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3135           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3136
3137     ;;
3138
3139   powerpc*-*-*)
3140     case $target in
3141       *-*-aix*) conftest_s='    .machine "pwr5"
3142         .csect .text[[PR]]
3143         mfcr 3,128';;
3144       *-*-darwin*)
3145         gcc_GAS_CHECK_FEATURE([.machine directive support],
3146           gcc_cv_as_machine_directive,,,
3147           [     .machine ppc7400])
3148         if test x$gcc_cv_as_machine_directive != xyes; then
3149           echo "*** This target requires an assembler supporting \".machine\"" >&2
3150           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3151           test x$build = x$target && exit 1
3152         fi
3153         conftest_s='    .text
3154         mfcr r3,128';;
3155       *) conftest_s='   .machine power4
3156         .text
3157         mfcr 3,128';;
3158     esac
3159
3160     gcc_GAS_CHECK_FEATURE([mfcr field support],
3161       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3162       [$conftest_s],,
3163       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3164           [Define if your assembler supports mfcr field.])])
3165
3166     case $target in
3167       *-*-aix*) conftest_s='    .machine "pwr5"
3168         .csect .text[[PR]]
3169         popcntb 3,3';;
3170       *) conftest_s='   .machine power5
3171         .text
3172         popcntb 3,3';;
3173     esac
3174
3175     gcc_GAS_CHECK_FEATURE([popcntb support],
3176       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3177       [$conftest_s],,
3178       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3179           [Define if your assembler supports popcntb field.])])
3180
3181     case $target in
3182       *-*-aix*) conftest_s='    .machine "pwr5x"
3183         .csect .text[[PR]]
3184         frin 1,1';;
3185       *) conftest_s='   .machine power5
3186         .text
3187         frin 1,1';;
3188     esac
3189
3190     gcc_GAS_CHECK_FEATURE([fp round support],
3191       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3192       [$conftest_s],,
3193       [AC_DEFINE(HAVE_AS_FPRND, 1,
3194           [Define if your assembler supports fprnd.])])
3195
3196     case $target in
3197       *-*-aix*) conftest_s='    .machine "pwr6"
3198         .csect .text[[PR]]
3199         mffgpr 1,3';;
3200       *) conftest_s='   .machine power6
3201         .text
3202         mffgpr 1,3';;
3203     esac
3204
3205     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3206       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3207       [$conftest_s],,
3208       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3209           [Define if your assembler supports mffgpr and mftgpr.])])
3210
3211     case $target in
3212       *-*-aix*) conftest_s='    .csect .text[[PR]]
3213 LCF..0:
3214         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3215       *-*-darwin*)
3216         conftest_s='    .text
3217 LCF0:
3218         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3219       *) conftest_s='   .text
3220 .LCF0:
3221         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3222     esac
3223
3224     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3225       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3226       [$conftest_s],,
3227       [AC_DEFINE(HAVE_AS_REL16, 1,
3228           [Define if your assembler supports R_PPC_REL16 relocs.])])
3229
3230     case $target in
3231       *-*-aix*) conftest_s='    .machine "pwr6"
3232         .csect .text[[PR]]
3233         cmpb 3,4,5';;
3234       *) conftest_s='   .machine power6
3235         .text
3236         cmpb 3,4,5';;
3237     esac
3238
3239     gcc_GAS_CHECK_FEATURE([compare bytes support],
3240       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
3241       [$conftest_s],,
3242       [AC_DEFINE(HAVE_AS_CMPB, 1,
3243           [Define if your assembler supports cmpb.])])
3244
3245     case $target in
3246       *-*-aix*) conftest_s='    .machine "pwr6"
3247         .csect .text[[PR]]
3248         dadd 1,2,3';;
3249       *) conftest_s='   .machine power6
3250         .text
3251         dadd 1,2,3';;
3252     esac
3253
3254     gcc_GAS_CHECK_FEATURE([decimal float support],
3255       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
3256       [$conftest_s],,
3257       [AC_DEFINE(HAVE_AS_DFP, 1,
3258           [Define if your assembler supports DFP instructions.])])
3259
3260     case $target in
3261       *-*-aix*) conftest_s='    .machine "pwr7"
3262         .csect .text[[PR]]
3263         lxvd2x 1,2,3';;
3264       *) conftest_s='   .machine power7
3265         .text
3266         lxvd2x 1,2,3';;
3267     esac
3268
3269     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3270       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
3271       [$conftest_s],,
3272       [AC_DEFINE(HAVE_AS_VSX, 1,
3273           [Define if your assembler supports VSX instructions.])])
3274
3275     case $target in
3276       *-*-aix*) conftest_s='    .machine "pwr7"
3277         .csect .text[[PR]]
3278         popcntd 3,3';;
3279       *) conftest_s='   .machine power7
3280         .text
3281         popcntd 3,3';;
3282     esac
3283
3284     gcc_GAS_CHECK_FEATURE([popcntd support],
3285       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
3286       [$conftest_s],,
3287       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
3288           [Define if your assembler supports POPCNTD instructions.])])
3289
3290     case $target in
3291       *-*-aix*) conftest_s='    .csect .text[[PR]]
3292         lwsync';;
3293       *) conftest_s='   .text
3294         lwsync';;
3295     esac
3296
3297     gcc_GAS_CHECK_FEATURE([lwsync support],
3298       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
3299       [$conftest_s],,
3300       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
3301           [Define if your assembler supports LWSYNC instructions.])])
3302
3303     case $target in
3304       *-*-aix*) conftest_s='    .machine "476"
3305         .csect .text[[PR]]
3306         dci 0';;
3307       *) conftest_s='   .machine "476"
3308         .text
3309         dci 0';;
3310     esac
3311
3312     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
3313       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
3314       [$conftest_s],,
3315       [AC_DEFINE(HAVE_AS_DCI, 1,
3316           [Define if your assembler supports the DCI/ICI instructions.])])
3317
3318     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3319       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3320       [.gnu_attribute 4,1],,
3321       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3322           [Define if your assembler supports .gnu_attribute.])])
3323
3324     gcc_GAS_CHECK_FEATURE([tls marker support],
3325       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3326       [ bl __tls_get_addr(x@tlsgd)],,
3327       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3328           [Define if your assembler supports arg info for __tls_get_addr.])])
3329     ;;
3330
3331   mips*-*-*)
3332     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3333       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3334 [       lw $4,%gp_rel(foo)($4)],,
3335       [if test x$target_cpu_default = x
3336        then target_cpu_default=MASK_EXPLICIT_RELOCS
3337        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3338        fi])
3339     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3340       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3341       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3342                  [Define if the assembler understands -mno-shared.])])
3343
3344     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3345       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3346       [.gnu_attribute 4,1],,
3347       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3348           [Define if your assembler supports .gnu_attribute.])])
3349
3350     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3351       gcc_cv_as_mips_dtprelword, [2,18,0],,
3352       [.section .tdata,"awT",@progbits
3353 x:
3354         .word 2
3355         .text
3356         .dtprelword x+0x8000],,
3357       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3358           [Define if your assembler supports .dtprelword.])])
3359
3360     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
3361     gcc_cv_as_ld_jalr_reloc=no
3362     if test $gcc_cv_as_mips_explicit_relocs = yes; then
3363       if test $in_tree_ld = yes ; then
3364         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
3365            && test $in_tree_ld_is_elf = yes; then
3366           gcc_cv_as_ld_jalr_reloc=yes
3367         fi
3368       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
3369         echo '  .ent x' > conftest.s
3370         echo 'x:        ld $2,%got_disp(y)($3)' >> conftest.s
3371         echo '  ld $25,%call16(y)($28)' >> conftest.s
3372         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
3373         echo '1:        jalr $25' >> conftest.s
3374         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
3375         echo '1:        jalr $25' >> conftest.s
3376         echo '  .end x' >> conftest.s
3377         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
3378            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
3379           if $gcc_cv_objdump -d conftest.so | grep -q jalr \
3380              && $gcc_cv_objdump -d conftest.so | grep -q "bal.*<x>"; then
3381             gcc_cv_as_ld_jalr_reloc=yes
3382           fi
3383         fi
3384         rm -f conftest.*
3385       fi
3386     fi
3387     if test $gcc_cv_as_ld_jalr_reloc = yes; then
3388       if test x$target_cpu_default = x; then
3389         target_cpu_default=MASK_RELAX_PIC_CALLS
3390       else
3391         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
3392       fi
3393     fi
3394     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
3395
3396     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
3397       [gcc_cv_ld_mips_personality_relaxation],
3398       [gcc_cv_ld_mips_personality_relaxation=no
3399        if test $in_tree_ld = yes ; then
3400          if test "$gcc_cv_gld_major_version" -eq 2 \
3401                  -a "$gcc_cv_gld_minor_version" -ge 21 \
3402                  -o "$gcc_cv_gld_major_version" -gt 2; then
3403            gcc_cv_ld_mips_personality_relaxation=yes
3404          fi
3405        elif test x$gcc_cv_as != x \
3406                  -a x$gcc_cv_ld != x \
3407                  -a x$gcc_cv_readelf != x ; then
3408          cat > conftest.s <<EOF
3409         .cfi_startproc
3410         .cfi_personality 0x80,indirect_ptr
3411         .ent test
3412 test:
3413         nop
3414         .end test
3415         .cfi_endproc
3416
3417         .section .data,"aw",@progbits
3418 indirect_ptr:
3419         .dc.a personality
3420 EOF
3421          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
3422             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
3423            if $gcc_cv_readelf -d conftest 2>&1 \
3424               | grep TEXTREL > /dev/null 2>&1; then
3425              :
3426            elif $gcc_cv_readelf --relocs conftest 2>&1 \
3427                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
3428              :
3429            else
3430              gcc_cv_ld_mips_personality_relaxation=yes
3431            fi
3432          fi
3433        fi
3434        rm -f conftest.s conftest.o conftest])
3435     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
3436             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
3437       [Define if your linker can relax absolute .eh_frame personality
3438 pointers into PC-relative form.])
3439     fi
3440     ;;
3441 esac
3442
3443 # Mips and HP-UX need the GNU assembler.
3444 # Linux on IA64 might be able to use the Intel assembler.
3445
3446 case "$target" in
3447   mips*-*-* | *-*-hpux* )
3448     if test x$gas_flag = xyes \
3449        || test x"$host" != x"$build" \
3450        || test ! -x "$gcc_cv_as" \
3451        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3452       :
3453     else
3454       echo "*** This configuration requires the GNU assembler" >&2
3455       exit 1
3456     fi
3457     ;;
3458 esac
3459
3460 # ??? Not all targets support dwarf2 debug_line, even within a version
3461 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3462 # info to the output file.  So, as supported targets are added to gas 2.11,
3463 # add some instruction here to (also) show we expect this might work.
3464 # ??? Once 2.11 is released, probably need to add first known working
3465 # version to the per-target configury.
3466 case "$target" in
3467   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3468   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3469   | xstormy16*-*-* | cris-*-* | crisv32-*-* | xtensa*-*-* | bfin-*-* | score*-*-* \
3470   | spu-*-* | fido*-*-* | m32c-*-*)
3471     insn="nop"
3472     ;;
3473   ia64*-*-* | s390*-*-*)
3474     insn="nop 0"
3475     ;;
3476   mmix-*-*)
3477     insn="swym 0"
3478     ;;
3479 esac
3480 if test x"$insn" != x; then
3481  conftest_s="\
3482         .file 1 \"conftest.s\"
3483         .loc 1 3 0
3484         $insn"
3485  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3486   gcc_cv_as_dwarf2_debug_line,
3487   [elf,2,11,0],, [$conftest_s],
3488   [if test x$gcc_cv_objdump != x \
3489    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3490       | grep debug_line > /dev/null 2>&1; then
3491      gcc_cv_as_dwarf2_debug_line=yes
3492    fi])
3493
3494 # The .debug_line file table must be in the exact order that
3495 # we specified the files, since these indices are also used
3496 # by DW_AT_decl_file.  Approximate this test by testing if
3497 # the assembler bitches if the same index is assigned twice.
3498  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3499   gcc_cv_as_dwarf2_file_buggy,,,
3500 [       .file 1 "foo.s"
3501         .file 1 "bar.s"])
3502
3503  if test $gcc_cv_as_dwarf2_debug_line = yes \
3504  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3505         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3506   [Define if your assembler supports dwarf2 .file/.loc directives,
3507    and preserves file table indices exactly as given.])
3508  fi
3509
3510  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3511   gcc_cv_as_gdwarf2_flag,
3512   [elf,2,11,0], [--gdwarf2], [$insn],,
3513   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3514 [Define if your assembler supports the --gdwarf2 option.])])
3515
3516  gcc_GAS_CHECK_FEATURE([--gstabs option],
3517   gcc_cv_as_gstabs_flag,
3518   [elf,2,11,0], [--gstabs], [$insn],
3519   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3520    # and warns about it, but still exits successfully.  So check for
3521    # this.
3522    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3523    then :
3524    else gcc_cv_as_gstabs_flag=yes
3525    fi],
3526   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3527 [Define if your assembler supports the --gstabs option.])])
3528
3529  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3530   gcc_cv_as_debug_prefix_map_flag,
3531   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3532   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3533 [Define if your assembler supports the --debug-prefix-map option.])])
3534 fi
3535
3536 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
3537  ,,
3538 [.lcomm bar,4,16],,
3539 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
3540   [Define if your assembler supports .lcomm with an alignment field.])])
3541
3542 AC_ARG_ENABLE(gnu-unique-object,
3543  [  --enable-gnu-unique-object  enable the use of the @gnu_unique_object ELF extension on
3544                                 glibc systems],
3545  [case $enable_gnu_unique_object in
3546     yes | no) ;;
3547     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
3548 Valid choices are 'yes' and 'no'.]) ;;
3549   esac],
3550  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
3551    [elf,2,19,52],,
3552    [.type foo, @gnu_unique_object],,
3553 # Also check for ld.so support, i.e. glibc 2.11 or higher.
3554    [if test x$host = x$build -a x$host = x$target &&
3555        glibcver=`ldd --version 2>/dev/null`; then
3556       glibcmajor=`expr "$glibcver" : "ldd (GNU libc) \([[0-9]]*\)"`
3557       glibcminor=`expr "$glibcver" : "ldd (GNU libc) [[0-9]]*\.\([[0-9]]*\)"`
3558       glibcnum=`expr $glibcmajor \* 1000 + $glibcminor`
3559       if test "$glibcnum" -ge 2011 ; then
3560         enable_gnu_unique_object=yes
3561       fi
3562     fi])])
3563 if test x$enable_gnu_unique_object = xyes; then
3564   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
3565    [Define if your assembler supports @gnu_unique_object.])
3566 fi
3567
3568 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3569  [gcc_cv_as_line_zero],
3570  [gcc_cv_as_line_zero=no
3571   if test $in_tree_gas = yes; then
3572     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3573   elif test "x$gcc_cv_as" != x; then
3574     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3575     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3576        test "x`cat conftest.out`" = x
3577     then
3578       gcc_cv_as_line_zero=yes
3579     else
3580       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3581       cat conftest.s >&AS_MESSAGE_LOG_FD
3582       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3583       cat conftest.out >&AS_MESSAGE_LOG_FD
3584     fi
3585     rm -f conftest.o conftest.s conftest.out
3586   fi])
3587 if test "x$gcc_cv_as_line_zero" = xyes; then
3588   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3589 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3590 fi
3591
3592 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3593 gcc_cv_ld_eh_frame_hdr=no
3594 if test $in_tree_ld = yes ; then
3595   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3596      && test $in_tree_ld_is_elf = yes; then
3597     gcc_cv_ld_eh_frame_hdr=yes
3598   fi
3599 elif test x$gcc_cv_ld != x; then
3600         # Check if linker supports --eh-frame-hdr option
3601         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3602                 gcc_cv_ld_eh_frame_hdr=yes
3603         fi
3604 fi
3605 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3606 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3607         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3608 [Define if your linker supports --eh-frame-hdr option.])
3609 fi
3610 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3611
3612 AC_MSG_CHECKING(linker position independent executable support)
3613 gcc_cv_ld_pie=no
3614 if test $in_tree_ld = yes ; then
3615   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3616      && test $in_tree_ld_is_elf = yes; then
3617     gcc_cv_ld_pie=yes
3618   fi
3619 elif test x$gcc_cv_ld != x; then
3620         # Check if linker supports -pie option
3621         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3622                 gcc_cv_ld_pie=yes
3623         fi
3624 fi
3625 if test x"$gcc_cv_ld_pie" = xyes; then
3626         AC_DEFINE(HAVE_LD_PIE, 1,
3627 [Define if your linker supports -pie option.])
3628 fi
3629 AC_MSG_RESULT($gcc_cv_ld_pie)
3630
3631 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3632 gcc_cv_ld_eh_gc_sections=no
3633 if test $in_tree_ld = yes ; then
3634   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3635      && test $in_tree_ld_is_elf = yes; then
3636     gcc_cv_ld_eh_gc_sections=yes
3637   fi
3638 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3639   cat > conftest.s <<EOF
3640         .section        .text
3641 .globl _start
3642         .type _start, @function
3643 _start:
3644         .long foo
3645         .size _start, .-_start
3646         .section        .text.foo,"ax",@progbits
3647         .type foo, @function
3648 foo:
3649         .long 0
3650         .size foo, .-foo
3651         .section        .gcc_except_table.foo,"a",@progbits
3652 .L0:
3653         .long 0
3654         .section        .eh_frame,"a",@progbits
3655         .long .L0
3656 EOF
3657   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3658     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3659          | grep "gc-sections option ignored" > /dev/null; then
3660       gcc_cv_ld_eh_gc_sections=no
3661     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3662       gcc_cv_ld_eh_gc_sections=yes
3663       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3664       if test x$gcc_cv_as_comdat_group != xyes; then
3665         gcc_cv_ld_eh_gc_sections=no
3666         cat > conftest.s <<EOF
3667         .section        .text
3668 .globl _start
3669         .type _start, @function
3670 _start:
3671         .long foo
3672         .size _start, .-_start
3673         .section        .gnu.linkonce.t.foo,"ax",@progbits
3674         .type foo, @function
3675 foo:
3676         .long 0
3677         .size foo, .-foo
3678         .section        .gcc_except_table.foo,"a",@progbits
3679 .L0:
3680         .long 0
3681         .section        .eh_frame,"a",@progbits
3682         .long .L0
3683 EOF
3684         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3685           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3686                | grep "gc-sections option ignored" > /dev/null; then
3687             gcc_cv_ld_eh_gc_sections=no
3688           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3689             gcc_cv_ld_eh_gc_sections=yes
3690           fi
3691         fi
3692       fi
3693     fi
3694   fi
3695   rm -f conftest.s conftest.o conftest
3696 fi
3697 case "$target" in
3698   hppa*-*-linux*)
3699     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3700     gcc_cv_ld_eh_gc_sections=no
3701     ;;
3702 esac
3703 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3704         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3705   [Define if your linker supports garbage collection of
3706    sections in presence of EH frames.])
3707 fi
3708 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3709
3710 # --------
3711 # UNSORTED
3712 # --------
3713
3714 AC_CACHE_CHECK(linker --as-needed support,
3715 gcc_cv_ld_as_needed,
3716 [gcc_cv_ld_as_needed=no
3717 if test $in_tree_ld = yes ; then
3718   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3719      && test $in_tree_ld_is_elf = yes; then
3720     gcc_cv_ld_as_needed=yes
3721   fi
3722 elif test x$gcc_cv_ld != x; then
3723         # Check if linker supports --as-needed and --no-as-needed options
3724         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3725                 gcc_cv_ld_as_needed=yes
3726         fi
3727 fi
3728 ])
3729 if test x"$gcc_cv_ld_as_needed" = xyes; then
3730         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3731 [Define if your linker supports --as-needed and --no-as-needed options.])
3732 fi
3733
3734 case "$target:$tm_file" in
3735   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3736     AC_CACHE_CHECK(linker support for omitting dot symbols,
3737     gcc_cv_ld_no_dot_syms,
3738     [gcc_cv_ld_no_dot_syms=no
3739     if test $in_tree_ld = yes ; then
3740       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3741         gcc_cv_ld_no_dot_syms=yes
3742       fi
3743     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3744       cat > conftest1.s <<EOF
3745         .text
3746         bl .foo
3747 EOF
3748       cat > conftest2.s <<EOF
3749         .section ".opd","aw"
3750         .align 3
3751         .globl foo
3752         .type foo,@function
3753 foo:
3754         .quad .LEfoo,.TOC.@tocbase,0
3755         .text
3756 .LEfoo:
3757         blr
3758         .size foo,.-.LEfoo
3759 EOF
3760       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3761          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3762          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3763         gcc_cv_ld_no_dot_syms=yes
3764       fi
3765       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3766     fi
3767     ])
3768     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3769       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3770     [Define if your PowerPC64 linker only needs function descriptor syms.])
3771     fi
3772     ;;
3773 esac
3774
3775 AC_CACHE_CHECK(linker --build-id support,
3776   gcc_cv_ld_buildid,
3777   [gcc_cv_ld_buildid=no
3778   if test $in_tree_ld = yes ; then
3779     if test "$gcc_cv_gld_major_version" -eq 2 -a \
3780        "$gcc_cv_gld_minor_version" -ge 18 -o \
3781        "$gcc_cv_gld_major_version" -gt 2 \
3782        && test $in_tree_ld_is_elf = yes; then
3783       gcc_cv_ld_buildid=yes
3784     fi
3785   elif test x$gcc_cv_ld != x; then
3786     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
3787       gcc_cv_ld_buildid=yes
3788     fi
3789   fi])
3790 if test x"$gcc_cv_ld_buildid" = xyes; then
3791   AC_DEFINE(HAVE_LD_BUILDID, 1,
3792   [Define if your linker supports --build-id.])
3793 fi
3794
3795 AC_ARG_ENABLE(linker-build-id,
3796 [  --enable-linker-build-id
3797                           compiler will always pass --build-id to linker],
3798 [],
3799 enable_linker_build_id=no)
3800
3801 if test x"$enable_linker_build_id" = xyes; then
3802   if test x"$gcc_cv_ld_buildid" = xyes; then
3803     AC_DEFINE(ENABLE_LD_BUILDID, 1,
3804     [Define if gcc should always pass --build-id to linker.])
3805   else
3806     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
3807   fi
3808 fi
3809
3810 AC_CACHE_CHECK(linker --sysroot support,
3811   gcc_cv_ld_sysroot,
3812   [gcc_cv_ld_sysroot=no
3813   if test $in_tree_ld = yes ; then
3814       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3815         gcc_cv_ld_sysroot=yes
3816       fi
3817   elif test x$gcc_cv_ld != x; then
3818     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3819       gcc_cv_ld_sysroot=yes
3820     fi
3821   fi])
3822 if test x"$gcc_cv_ld_sysroot" = xyes; then
3823   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3824   [Define if your linker supports --sysroot.])
3825 fi
3826
3827 if test x$with_sysroot = x && test x$host = x$target \
3828    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3829    && test "$prefix" != "NONE"; then
3830   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3831 [Define to PREFIX/include if cpp should also search that directory.])
3832 fi
3833
3834 # Test for stack protector support in target C library.
3835 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3836       gcc_cv_libc_provides_ssp,
3837       [gcc_cv_libc_provides_ssp=no
3838     case "$target" in
3839        *-*-linux* | *-*-kfreebsd*-gnu | *-*-knetbsd*-gnu)
3840       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3841         if test "x$with_sysroot" = x; then
3842           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3843         elif test "x$with_build_sysroot" != "x"; then
3844           glibc_header_dir="${with_build_sysroot}/usr/include"
3845         elif test "x$with_sysroot" = xyes; then
3846           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3847         else
3848           glibc_header_dir="${with_sysroot}/usr/include"
3849         fi
3850       else
3851         glibc_header_dir=/usr/include
3852       fi
3853       # glibc 2.4 and later provides __stack_chk_fail and
3854       # either __stack_chk_guard, or TLS access to stack guard canary.
3855       if test -f $glibc_header_dir/features.h \
3856          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3857             $glibc_header_dir/features.h > /dev/null; then
3858         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3859            $glibc_header_dir/features.h > /dev/null; then
3860           gcc_cv_libc_provides_ssp=yes
3861         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3862              $glibc_header_dir/features.h > /dev/null \
3863              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3864              $glibc_header_dir/features.h > /dev/null; then
3865           gcc_cv_libc_provides_ssp=yes
3866         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3867              $glibc_header_dir/features.h > /dev/null && \
3868              test -f $glibc_header_dir/bits/uClibc_config.h && \
3869              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3870              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3871           gcc_cv_libc_provides_ssp=yes
3872         fi
3873       fi
3874         ;;
3875        *-*-gnu*)
3876          # Avoid complicated tests (see
3877          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
3878          # simply assert that glibc does provide this, which is true for all
3879          # realistically usable GNU/Hurd configurations.
3880          gcc_cv_libc_provides_ssp=yes;;
3881        *-*-darwin* | *-*-freebsd*)
3882          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3883            [echo "no __stack_chk_fail on this target"])
3884         ;;
3885   *) gcc_cv_libc_provides_ssp=no ;;
3886     esac])
3887
3888 if test x$gcc_cv_libc_provides_ssp = xyes; then
3889   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3890             [Define if your target C library provides stack protector support])
3891 fi
3892
3893 # Check if TFmode long double should be used by default or not.
3894 # Some glibc targets used DFmode long double, but with glibc 2.4
3895 # and later they can use TFmode.
3896 case "$target" in
3897   powerpc*-*-linux* | \
3898   powerpc*-*-gnu* | \
3899   sparc*-*-linux* | \
3900   s390*-*-linux* | \
3901   alpha*-*-linux*)
3902     AC_ARG_WITH(long-double-128,
3903 [  --with-long-double-128  Use 128-bit long double by default.],
3904       gcc_cv_target_ldbl128="$with_long_double_128",
3905       [gcc_cv_target_ldbl128=no
3906       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3907         if test "x$with_sysroot" = x; then
3908           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3909         elif test "x$with_build_sysroot" != "x"; then
3910           glibc_header_dir="${with_build_sysroot}/usr/include"
3911         elif test "x$with_sysroot" = xyes; then
3912           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3913         else
3914           glibc_header_dir="${with_sysroot}/usr/include"
3915         fi
3916       else
3917         glibc_header_dir=/usr/include
3918       fi
3919 changequote(,)dnl
3920       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3921         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3922       && gcc_cv_target_ldbl128=yes
3923 changequote([,])dnl
3924       ])
3925     ;;
3926 esac
3927 if test x$gcc_cv_target_ldbl128 = xyes; then
3928   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3929             [Define if TFmode long double should be the default])
3930 fi
3931
3932 # Find out what GC implementation we want, or may, use.
3933 AC_ARG_WITH(gc,
3934 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3935                           with the compiler],
3936 [case "$withval" in
3937   page)
3938     GGC=ggc-$withval
3939     ;;
3940   zone)
3941     GGC=ggc-$withval
3942     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3943     ;;
3944   *)
3945     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3946     ;;
3947 esac],
3948 [GGC=ggc-page])
3949 AC_SUBST(GGC)
3950 echo "Using $GGC for garbage collection."
3951
3952 # Libraries to use on the host.  This will normally be set by the top
3953 # level Makefile.  Here we simply capture the value for our Makefile.
3954 if test -z "${HOST_LIBS+set}"; then
3955   HOST_LIBS=
3956 fi
3957 AC_SUBST(HOST_LIBS)
3958
3959 # Use the system's zlib library.
3960 zlibdir=-L../zlib
3961 zlibinc="-I\$(srcdir)/../zlib"
3962 AC_ARG_WITH(system-zlib,
3963 [  --with-system-zlib      use installed libz],
3964 zlibdir=
3965 zlibinc=
3966 )
3967 AC_SUBST(zlibdir)
3968 AC_SUBST(zlibinc)
3969
3970 dnl Very limited version of automake's enable-maintainer-mode
3971
3972 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3973   dnl maintainer-mode is disabled by default
3974   AC_ARG_ENABLE(maintainer-mode,
3975 [  --enable-maintainer-mode
3976                           enable make rules and dependencies not useful
3977                           (and sometimes confusing) to the casual installer],
3978       maintainer_mode=$enableval,
3979       maintainer_mode=no)
3980
3981 AC_MSG_RESULT($maintainer_mode)
3982
3983 if test "$maintainer_mode" = "yes"; then
3984   MAINT=''
3985 else
3986   MAINT='#'
3987 fi
3988 AC_SUBST(MAINT)dnl
3989
3990 # --------------
3991 # Language hooks
3992 # --------------
3993
3994 # Make empty files to contain the specs and options for each language.
3995 # Then add #include lines to for a compiler that has specs and/or options.
3996
3997 subdirs=
3998 lang_opt_files=
3999 lang_specs_files=
4000 lang_tree_files=
4001 # These (without "all_") are set in each config-lang.in.
4002 # `language' must be a single word so is spelled singularly.
4003 all_languages=
4004 all_compilers=
4005 all_outputs='Makefile gccbug'
4006 # List of language makefile fragments.
4007 all_lang_makefrags=
4008 # List of language subdirectory makefiles.  Deprecated.
4009 all_lang_makefiles=
4010 # Additional files for gengtype
4011 all_gtfiles="$target_gtfiles"
4012
4013 # These are the languages that are set in --enable-languages,
4014 # and are available in the GCC tree.
4015 all_selected_languages=
4016
4017 # Add the language fragments.
4018 # Languages are added via two mechanisms.  Some information must be
4019 # recorded in makefile variables, these are defined in config-lang.in.
4020 # We accumulate them and plug them into the main Makefile.
4021 # The other mechanism is a set of hooks for each of the main targets
4022 # like `clean', `install', etc.
4023
4024 language_hooks="Make-hooks"
4025
4026 for lang in ${srcdir}/*/config-lang.in
4027 do
4028 changequote(,)dnl
4029         test "$lang" = "${srcdir}/*/config-lang.in" && continue
4030
4031         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
4032         if test "x$lang_alias" = x
4033         then
4034               echo "$lang doesn't set \$language." 1>&2
4035               exit 1
4036         fi
4037         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
4038         subdirs="$subdirs $subdir"
4039
4040         # $gcc_subdir is where the gcc integration files are to be found
4041         # for a language, both for internal compiler purposes (compiler
4042         # sources implementing front-end to GCC tree converters), and for
4043         # build infrastructure purposes (Make-lang.in, etc.)
4044         #
4045         # This will be <subdir> (relative to $srcdir) if a line like
4046         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
4047         # is found in <langdir>/config-lang.in, and will remain <langdir>
4048         # otherwise.
4049         #
4050         # Except for the language alias (fetched above), the regular
4051         # "config-lang.in" contents are always retrieved from $gcc_subdir,
4052         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
4053         # only this and the language alias.
4054
4055         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
4056         if [ "$gcc_subdir" = "" ]; then
4057            gcc_subdir="$subdir"
4058         fi
4059
4060         case ",$enable_languages," in
4061         *,$lang_alias,*)
4062             all_selected_languages="$all_selected_languages $lang_alias"
4063             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
4064                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
4065             fi
4066             ;;
4067         esac
4068 changequote([,])dnl
4069
4070         language=
4071         boot_language=
4072         compilers=
4073         outputs=
4074         gtfiles=
4075         subdir_requires=
4076         . ${srcdir}/$gcc_subdir/config-lang.in
4077         if test "x$language" = x
4078         then
4079                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
4080                 exit 1
4081         fi
4082
4083         ok=:
4084         case ",$enable_languages," in
4085                 *,$lang_alias,*) ;;
4086                 *)
4087                         for i in $subdir_requires; do
4088                                 test -f "${srcdir}/$i/config-lang.in" && continue
4089                                 ok=false
4090                                 break
4091                         done
4092                 ;;
4093         esac
4094         $ok || continue
4095
4096         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
4097         if test -f $srcdir/$gcc_subdir/lang.opt; then
4098             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
4099         fi
4100         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
4101             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
4102         fi
4103         if test -f ${srcdir}/$gcc_subdir/Makefile.in
4104                 then all_lang_makefiles="$gcc_subdir/Makefile"
4105         fi
4106         all_languages="$all_languages $language"
4107         all_compilers="$all_compilers $compilers"
4108         all_outputs="$all_outputs $outputs"
4109         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
4110         case ",$enable_languages," in
4111                 *,lto,*)
4112                     AC_DEFINE(ENABLE_LTO, 1, [Define to enable LTO support.])
4113                     enable_lto=yes
4114                     AC_SUBST(enable_lto)
4115                     ;;
4116                 *) ;;
4117         esac
4118 done
4119
4120 # Pick up gtfiles for c
4121 gtfiles=
4122 . ${srcdir}/c-config-lang.in
4123 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
4124
4125 check_languages=
4126 for language in $all_selected_languages
4127 do
4128         check_languages="$check_languages check-$language"
4129 done
4130
4131 # We link each language in with a set of hooks, reached indirectly via
4132 # lang.${target}.  Only do so for selected languages.
4133
4134 rm -f Make-hooks
4135 touch Make-hooks
4136 target_list="all.cross start.encap rest.encap tags \
4137         install-common install-man install-info install-pdf dvi pdf \
4138         html uninstall info man srcextra srcman srcinfo \
4139         mostlyclean clean distclean maintainer-clean install-plugin"
4140
4141 for t in $target_list
4142 do
4143         x=
4144         for lang in $all_selected_languages
4145         do
4146                 x="$x $lang.$t"
4147         done
4148         echo "lang.$t: $x" >> Make-hooks
4149 done
4150
4151 # --------
4152 # UNSORTED
4153 # --------
4154
4155 # Create .gdbinit.
4156
4157 echo "dir ." > .gdbinit
4158 echo "dir ${srcdir}" >> .gdbinit
4159 if test x$gdb_needs_out_file_path = xyes
4160 then
4161         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
4162 fi
4163 if test "x$subdirs" != x; then
4164         for s in $subdirs
4165         do
4166                 echo "dir ${srcdir}/$s" >> .gdbinit
4167         done
4168 fi
4169 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
4170
4171 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
4172 AC_SUBST(gcc_tooldir)
4173 AC_SUBST(dollar)
4174
4175 # Find a directory in which to install a shared libgcc.
4176
4177 AC_ARG_ENABLE(version-specific-runtime-libs,
4178 [  --enable-version-specific-runtime-libs
4179                           specify that runtime libraries should be
4180                           installed in a compiler-specific directory])
4181
4182 AC_ARG_WITH(slibdir,
4183 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
4184 slibdir="$with_slibdir",
4185 if test "${enable_version_specific_runtime_libs+set}" = set; then
4186   slibdir='$(libsubdir)'
4187 elif test "$host" != "$target"; then
4188   slibdir='$(build_tooldir)/lib'
4189 else
4190   slibdir='$(libdir)'
4191 fi)
4192 AC_SUBST(slibdir)
4193
4194 # Substitute configuration variables
4195 AC_SUBST(subdirs)
4196 AC_SUBST(srcdir)
4197 AC_SUBST(all_compilers)
4198 AC_SUBST(all_gtfiles)
4199 AC_SUBST(all_lang_makefrags)
4200 AC_SUBST(all_lang_makefiles)
4201 AC_SUBST(all_languages)
4202 AC_SUBST(all_selected_languages)
4203 AC_SUBST(build_exeext)
4204 AC_SUBST(build_install_headers_dir)
4205 AC_SUBST(build_xm_file_list)
4206 AC_SUBST(build_xm_include_list)
4207 AC_SUBST(build_xm_defines)
4208 AC_SUBST(build_file_translate)
4209 AC_SUBST(check_languages)
4210 AC_SUBST(cpp_install_dir)
4211 AC_SUBST(xmake_file)
4212 AC_SUBST(tmake_file)
4213 AC_SUBST(TM_ENDIAN_CONFIG)
4214 AC_SUBST(TM_MULTILIB_CONFIG)
4215 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
4216 AC_SUBST(extra_gcc_objs)
4217 AC_SUBST(extra_headers_list)
4218 AC_SUBST(extra_objs)
4219 AC_SUBST(extra_parts)
4220 AC_SUBST(extra_passes)
4221 AC_SUBST(extra_programs)
4222 AC_SUBST(float_h_file)
4223 AC_SUBST(gcc_config_arguments)
4224 AC_SUBST(gcc_gxx_include_dir)
4225 AC_SUBST(host_exeext)
4226 AC_SUBST(host_xm_file_list)
4227 AC_SUBST(host_xm_include_list)
4228 AC_SUBST(host_xm_defines)
4229 AC_SUBST(out_host_hook_obj)
4230 AC_SUBST(install)
4231 AC_SUBST(lang_opt_files)
4232 AC_SUBST(lang_specs_files)
4233 AC_SUBST(lang_tree_files)
4234 AC_SUBST(local_prefix)
4235 AC_SUBST(md_file)
4236 AC_SUBST(objc_boehm_gc)
4237 AC_SUBST(out_file)
4238 AC_SUBST(out_object_file)
4239 AC_SUBST(thread_file)
4240 AC_SUBST(tm_file_list)
4241 AC_SUBST(tm_include_list)
4242 AC_SUBST(tm_defines)
4243 AC_SUBST(tm_p_file_list)
4244 AC_SUBST(tm_p_include_list)
4245 AC_SUBST(xm_file_list)
4246 AC_SUBST(xm_include_list)
4247 AC_SUBST(xm_defines)
4248 AC_SUBST(use_gcc_stdint)
4249 AC_SUBST(c_target_objs)
4250 AC_SUBST(cxx_target_objs)
4251 AC_SUBST(fortran_target_objs)
4252 AC_SUBST(target_cpu_default)
4253
4254 AC_SUBST_FILE(language_hooks)
4255
4256 # Echo link setup.
4257 if test x${build} = x${host} ; then
4258   if test x${host} = x${target} ; then
4259     echo "Links are now set up to build a native compiler for ${target}." 1>&2
4260   else
4261     echo "Links are now set up to build a cross-compiler" 1>&2
4262     echo " from ${host} to ${target}." 1>&2
4263   fi
4264 else
4265   if test x${host} = x${target} ; then
4266     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
4267     echo " for ${target}." 1>&2
4268   else
4269     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
4270     echo " from ${host} to ${target}." 1>&2
4271   fi
4272 fi
4273
4274 AC_ARG_VAR(GMPLIBS,[How to link GMP])
4275 AC_ARG_VAR(GMPINC,[How to find GMP include files])
4276
4277 AC_ARG_VAR(PPLLIBS,[How to link PPL])
4278 AC_ARG_VAR(PPLINC,[How to find PPL include files])
4279
4280 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
4281 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
4282 if test "x${CLOOGLIBS}" != "x" ; then
4283    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
4284 fi
4285
4286 AC_ARG_VAR(LIBELFLIBS,[How to link libelf])
4287 AC_ARG_VAR(LIBELFINC,[How to find libelf include files])
4288 if test "x${LIBELFLIBS}" != "x" ; then
4289    AC_DEFINE(HAVE_libelf, 1, [Define if libelf is in use.])
4290 fi
4291
4292 # Check for plugin support
4293 AC_ARG_ENABLE(plugin,
4294 [  --enable-plugin         enable plugin support],
4295 enable_plugin=$enableval,
4296 enable_plugin=yes; default_plugin=yes)
4297
4298 pluginlibs=
4299 if test x"$enable_plugin" = x"yes"; then
4300   # Check that the host supports -rdynamic and -ldl
4301   have_rdynamic=no
4302   have_dl=no
4303   saved_LDFLAGS="$LDFLAGS"
4304   saved_LIBS="$LIBS"
4305   LIBS=
4306
4307   # Check -rdynamic
4308   LDFLAGS="$LDFLAGS -rdynamic"
4309   AC_MSG_CHECKING([for -rdynamic])
4310   AC_TRY_LINK([],[return 0;],
4311     [AC_MSG_RESULT([yes]); have_rdynamic=yes],
4312     [AC_MSG_RESULT([no])])
4313   if test x"$have_rdynamic" = x"yes" ; then
4314     pluginlibs="-rdynamic"
4315   fi
4316
4317   # Check -ldl
4318   AC_SEARCH_LIBS([dlopen], [dl])
4319   if test x"$ac_cv_search_dlopen" = x"-ldl"; then
4320     pluginlibs="$pluginlibs -ldl"
4321   fi
4322
4323   # Check that we can build shared objects with -fPIC -shared
4324   LDFLAGS="$LDFLAGS -fPIC -shared"
4325   AC_MSG_CHECKING([for -fPIC -shared])
4326   AC_TRY_LINK(
4327     [extern int X;],[return X == 0;],
4328     [AC_MSG_RESULT([yes]); have_pic_shared=yes],
4329     [AC_MSG_RESULT([no]); have_pic_shared=no])
4330   if test x"$have_pic_shared" != x"yes" -o x"$ac_cv_search_dlopen" = x"no"; then
4331     pluginlibs=
4332     enable_plugin=no
4333   fi
4334
4335   # If plugin support had been requested but not available, fail.
4336   if test x"$enable_plugin" = x"no" ; then
4337     if test x"$default_plugin" != x"yes"; then
4338       AC_MSG_ERROR([
4339 Building GCC with plugin support requires a host that supports
4340 -fPIC, -shared, -ldl and -rdynamic.])
4341     fi
4342   fi
4343
4344   LDFLAGS="$saved_LDFLAGS"
4345   LIBS="$saved_LIBS"
4346 fi
4347
4348 AC_SUBST(pluginlibs)
4349 AC_SUBST(enable_plugin)
4350 if test x"$enable_plugin" = x"yes"; then
4351   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
4352 fi
4353
4354 # Configure the subdirectories
4355 # AC_CONFIG_SUBDIRS($subdirs)
4356
4357 # Create the Makefile
4358 # and configure language subdirectories
4359 AC_CONFIG_FILES($all_outputs)
4360
4361 AC_CONFIG_COMMANDS([default],
4362 [
4363 case ${CONFIG_HEADERS} in
4364   *auto-host.h:config.in*)
4365   echo > cstamp-h ;;
4366 esac
4367 # Make sure all the subdirs exist.
4368 for d in $subdirs doc build
4369 do
4370     test -d $d || mkdir $d
4371 done
4372 ],
4373 [subdirs='$subdirs'])
4374 AC_OUTPUT