gcc/ada/sem_scil.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ S C I L                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2009-2023, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Einfo;          use Einfo;
  27 with Einfo.Entities; use Einfo.Entities;
  28 with Einfo.Utils;    use Einfo.Utils;
  29 with Nlists;         use Nlists;
  30 with Rtsfind;        use Rtsfind;
  31 with Sem_Aux;        use Sem_Aux;
  32 with Sinfo;          use Sinfo;
  33 with Sinfo.Nodes;    use Sinfo.Nodes;
  34 with Stand;          use Stand;
  35 with SCIL_LL;        use SCIL_LL;
  36
  37 package body Sem_SCIL is
  38
  39    ---------------------
  40    -- Check_SCIL_Node --
  41    ---------------------
  42
  43    function Check_SCIL_Node (N : Node_Id) return Traverse_Result is
  44       SCIL_Node : constant Node_Id := Get_SCIL_Node (N);
  45       Ctrl_Tag  : Node_Id;
  46       Ctrl_Typ  : Entity_Id;
  47
  48    begin
  49       --  For nodes that do not have SCIL node continue traversing the tree
  50
  51       if No (SCIL_Node) then
  52          return OK;
  53       end if;
  54
  55       case Nkind (SCIL_Node) is
  56          when N_SCIL_Dispatch_Table_Tag_Init =>
  57             pragma Assert (Nkind (N) = N_Object_Declaration);
  58             null;
  59
  60          when N_SCIL_Dispatching_Call =>
  61             Ctrl_Tag := SCIL_Controlling_Tag (SCIL_Node);
  62
  63             --  Parent of SCIL dispatching call nodes MUST be a subprogram call
  64
  65             if Nkind (N) not in N_Subprogram_Call then
  66                raise Program_Error;
  67
  68             --  In simple cases the controlling tag is the tag of the
  69             --  controlling argument (i.e. Obj.Tag).
  70
  71             elsif Nkind (Ctrl_Tag) = N_Selected_Component then
  72                Ctrl_Typ := Etype (Ctrl_Tag);
  73
  74                --  Interface types are unsupported
  75
  76                if Is_Interface (Ctrl_Typ)
  77                  or else Is_RTE (Ctrl_Typ, RE_Interface_Tag)
  78                then
  79                   null;
  80
  81                else
  82                   pragma Assert (Is_RTE (Ctrl_Typ, RE_Tag));
  83                   null;
  84                end if;
  85
  86             --  When the controlling tag of a dispatching call is an identifier
  87             --  the SCIL_Controlling_Tag attribute references the corresponding
  88             --  object or parameter declaration. Interface types are still
  89             --  unsupported.
  90
  91             elsif Nkind (Ctrl_Tag) in N_Object_Renaming_Declaration
  92                                     | N_Object_Declaration
  93                                     | N_Parameter_Specification
  94                                     | N_Discriminant_Specification
  95             then
  96                Ctrl_Typ := Etype (Defining_Identifier (Ctrl_Tag));
  97
  98                --  Interface types are unsupported.
  99
 100                if Is_Interface (Ctrl_Typ)
 101                  or else Is_RTE (Ctrl_Typ, RE_Interface_Tag)
 102                  or else (Is_Access_Type (Ctrl_Typ)
 103                            and then
 104                              Is_Interface
 105                                (Available_View
 106                                  (Base_Type (Designated_Type (Ctrl_Typ)))))
 107                then
 108                   null;
 109
 110                else
 111                   pragma Assert
 112                     (Is_RTE (Ctrl_Typ, RE_Tag)
 113                        or else
 114                          (Is_Access_Type (Ctrl_Typ)
 115                             and then
 116                           Is_RTE
 117                             (Available_View
 118                                (Base_Type (Designated_Type (Ctrl_Typ))),
 119                              RE_Tag)));
 120                   null;
 121                end if;
 122
 123             --  Interface types are unsupported
 124
 125             elsif Is_Interface (Etype (Ctrl_Tag)) then
 126                null;
 127
 128             else
 129                pragma Assert (False);
 130                raise Program_Error;
 131             end if;
 132
 133             return Skip;
 134
 135          when N_SCIL_Membership_Test =>
 136
 137             --  Check contents of the boolean expression associated with the
 138             --  membership test.
 139
 140             pragma Assert
 141               (Nkind (N) in
 142                  N_Identifier | N_And_Then | N_Or_Else |
 143                  N_Expression_With_Actions | N_Function_Call
 144               and then Etype (N) = Standard_Boolean);
 145
 146             --  Check the entity identifier of the associated tagged type (that
 147             --  is, in testing for membership in T'Class, the entity id of the
 148             --  specific type T).
 149
 150             --  Note: When the SCIL node is generated the private and full-view
 151             --    of the tagged types may have been swapped and hence the node
 152             --    referenced by attribute SCIL_Entity may be the private view.
 153             --    Therefore, in order to uniformly locate the full-view we use
 154             --    attribute Underlying_Type.
 155
 156             pragma Assert
 157               (Is_Tagged_Type (Underlying_Type (SCIL_Entity (SCIL_Node))));
 158
 159             --  Interface types are unsupported
 160
 161             pragma Assert
 162               (not Is_Interface (Underlying_Type (SCIL_Entity (SCIL_Node))));
 163
 164             --  Check the decoration of the expression that denotes the tag
 165             --  value being tested
 166
 167             Ctrl_Tag := SCIL_Tag_Value (SCIL_Node);
 168
 169             case Nkind (Ctrl_Tag) is
 170
 171                --  For class-wide membership tests the SCIL tag value is the
 172                --  tag of the tested object (i.e. Obj.Tag).
 173
 174                when N_Selected_Component =>
 175                   pragma Assert (Is_RTE (Etype (Ctrl_Tag), RE_Tag));
 176                   null;
 177
 178                when others =>
 179                   pragma Assert (False);
 180                   null;
 181             end case;
 182
 183             return Skip;
 184
 185          when others =>
 186             pragma Assert (False);
 187             raise Program_Error;
 188       end case;
 189
 190       return Skip;
 191    end Check_SCIL_Node;
 192
 193    -------------------------
 194    -- First_Non_SCIL_Node --
 195    -------------------------
 196
 197    function First_Non_SCIL_Node (L : List_Id) return Node_Id is
 198       N : Node_Id;
 199
 200    begin
 201       N := First (L);
 202       while Nkind (N) in N_SCIL_Node loop
 203          Next (N);
 204       end loop;
 205
 206       return N;
 207    end First_Non_SCIL_Node;
 208
 209    ------------------------
 210    -- Next_Non_SCIL_Node --
 211    ------------------------
 212
 213    function Next_Non_SCIL_Node (N : Node_Id) return Node_Id is
 214       Aux_N : Node_Id;
 215
 216    begin
 217       Aux_N := Next (N);
 218       while Nkind (Aux_N) in N_SCIL_Node loop
 219          Next (Aux_N);
 220       end loop;
 221
 222       return Aux_N;
 223    end Next_Non_SCIL_Node;
 224
 225 end Sem_SCIL;