gcc/ada/back_end.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                            B A C K _ E N D                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2014, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Debug;    use Debug;
  28 with Elists;   use Elists;
  29 with Errout;   use Errout;
  30 with Lib;      use Lib;
  31 with Osint;    use Osint;
  32 with Opt;      use Opt;
  33 with Osint.C;  use Osint.C;
  34 with Namet;    use Namet;
  35 with Nlists;   use Nlists;
  36 with Stand;    use Stand;
  37 with Sinput;   use Sinput;
  38 with Stringt;  use Stringt;
  39 with Switch;   use Switch;
  40 with Switch.C; use Switch.C;
  41 with System;   use System;
  42 with Types;    use Types;
  43
  44 with System.OS_Lib; use System.OS_Lib;
  45
  46 package body Back_End is
  47
  48    type Arg_Array is array (Nat) of Big_String_Ptr;
  49    type Arg_Array_Ptr is access Arg_Array;
  50    --  Types to access compiler arguments
  51
  52    flag_stack_check : Int;
  53    pragma Import (C, flag_stack_check);
  54    --  Indicates if stack checking is enabled, imported from misc.c
  55
  56    save_argc : Nat;
  57    pragma Import (C, save_argc);
  58    --  Saved value of argc (number of arguments), imported from misc.c
  59
  60    save_argv : Arg_Array_Ptr;
  61    pragma Import (C, save_argv);
  62    --  Saved value of argv (argument pointers), imported from misc.c
  63
  64    function Len_Arg (Arg : Pos) return Nat;
  65    --  Determine length of argument number Arg on original gnat1 command line
  66
  67    -------------------
  68    -- Call_Back_End --
  69    -------------------
  70
  71    procedure Call_Back_End (Mode : Back_End_Mode_Type) is
  72
  73       --  The Source_File_Record type has a lot of components that are
  74       --  meaningless to the back end, so a new record type is created
  75       --  here to contain the needed information for each file.
  76
  77       type File_Info_Type is record
  78          File_Name        : File_Name_Type;
  79          Instance         : Instance_Id;
  80          Num_Source_Lines : Nat;
  81       end record;
  82
  83       File_Info_Array : array (1 .. Last_Source_File) of File_Info_Type;
  84
  85       procedure gigi
  86         (gnat_root                     : Int;
  87          max_gnat_node                 : Int;
  88          number_name                   : Nat;
  89          nodes_ptr                     : Address;
  90          flags_ptr                     : Address;
  91
  92          next_node_ptr                 : Address;
  93          prev_node_ptr                 : Address;
  94          elists_ptr                    : Address;
  95          elmts_ptr                     : Address;
  96
  97          strings_ptr                   : Address;
  98          string_chars_ptr              : Address;
  99          list_headers_ptr              : Address;
 100          number_file                   : Nat;
 101
 102          file_info_ptr                 : Address;
 103          gigi_standard_boolean         : Entity_Id;
 104          gigi_standard_integer         : Entity_Id;
 105          gigi_standard_character       : Entity_Id;
 106          gigi_standard_long_long_float : Entity_Id;
 107          gigi_standard_exception_type  : Entity_Id;
 108          gigi_operating_mode           : Back_End_Mode_Type);
 109
 110       pragma Import (C, gigi);
 111
 112    begin
 113       --  Skip call if in -gnatdH mode
 114
 115       if Debug_Flag_HH then
 116          return;
 117       end if;
 118
 119       --  The back end needs to know the maximum line number that can appear
 120       --  in a Sloc, in other words the maximum logical line number.
 121
 122       for J in 1 .. Last_Source_File loop
 123          File_Info_Array (J).File_Name        := Full_Debug_Name (J);
 124          File_Info_Array (J).Instance         := Instance (J);
 125          File_Info_Array (J).Num_Source_Lines :=
 126            Nat (Physical_To_Logical (Last_Source_Line (J), J));
 127       end loop;
 128
 129       --  Deal with case of generating SCIL, we should not be here!
 130
 131       if Generate_SCIL then
 132          Error_Msg_N ("'S'C'I'L generation not available", Cunit (Main_Unit));
 133
 134          if CodePeer_Mode
 135            or else (Mode /= Generate_Object
 136                      and then not Back_Annotate_Rep_Info)
 137          then
 138             return;
 139          end if;
 140       end if;
 141
 142       --  The actual call to the back end
 143
 144       gigi
 145         (gnat_root          => Int (Cunit (Main_Unit)),
 146          max_gnat_node      => Int (Last_Node_Id - First_Node_Id + 1),
 147          number_name        => Name_Entries_Count,
 148          nodes_ptr          => Nodes_Address,
 149          flags_ptr          => Flags_Address,
 150
 151          next_node_ptr      => Next_Node_Address,
 152          prev_node_ptr      => Prev_Node_Address,
 153          elists_ptr         => Elists_Address,
 154          elmts_ptr          => Elmts_Address,
 155
 156          strings_ptr        => Strings_Address,
 157          string_chars_ptr   => String_Chars_Address,
 158          list_headers_ptr   => Lists_Address,
 159          number_file        => Num_Source_Files,
 160
 161          file_info_ptr                 => File_Info_Array'Address,
 162          gigi_standard_boolean         => Standard_Boolean,
 163          gigi_standard_integer         => Standard_Integer,
 164          gigi_standard_character       => Standard_Character,
 165          gigi_standard_long_long_float => Standard_Long_Long_Float,
 166          gigi_standard_exception_type  => Standard_Exception_Type,
 167          gigi_operating_mode           => Mode);
 168    end Call_Back_End;
 169
 170    -------------------------------
 171    -- Gen_Or_Update_Object_File --
 172    -------------------------------
 173
 174    procedure Gen_Or_Update_Object_File is
 175    begin
 176       null;
 177    end Gen_Or_Update_Object_File;
 178
 179    -------------
 180    -- Len_Arg --
 181    -------------
 182
 183    function Len_Arg (Arg : Pos) return Nat is
 184    begin
 185       for J in 1 .. Nat'Last loop
 186          if save_argv (Arg).all (Natural (J)) = ASCII.NUL then
 187             return J - 1;
 188          end if;
 189       end loop;
 190
 191       raise Program_Error;
 192    end Len_Arg;
 193
 194    -----------------------------
 195    -- Scan_Compiler_Arguments --
 196    -----------------------------
 197
 198    procedure Scan_Compiler_Arguments is
 199       Next_Arg : Positive;
 200       --  Next argument to be scanned
 201
 202       Output_File_Name_Seen : Boolean := False;
 203       --  Set to True after having scanned file_name for switch "-gnatO file"
 204
 205       procedure Scan_Back_End_Switches (Switch_Chars : String);
 206       --  Procedure to scan out switches stored in Switch_Chars. The first
 207       --  character is known to be a valid switch character, and there are no
 208       --  blanks or other switch terminator characters in the string, so the
 209       --  entire string should consist of valid switch characters, except that
 210       --  an optional terminating NUL character is allowed.
 211       --
 212       --  Back end switches have already been checked and processed by GCC in
 213       --  toplev.c, so no errors can occur and control will always return. The
 214       --  switches must still be scanned to skip "-o" or internal GCC switches
 215       --  with their argument.
 216
 217       ----------------------------
 218       -- Scan_Back_End_Switches --
 219       ----------------------------
 220
 221       procedure Scan_Back_End_Switches (Switch_Chars : String) is
 222          First : constant Positive := Switch_Chars'First + 1;
 223          Last  : constant Natural  := Switch_Last (Switch_Chars);
 224
 225       begin
 226          --  Skip -o or internal GCC switches together with their argument
 227
 228          if Switch_Chars (First .. Last) = "o"
 229            or else Is_Internal_GCC_Switch (Switch_Chars)
 230          then
 231             Next_Arg := Next_Arg + 1;
 232
 233          --  Do not record -quiet switch
 234
 235          elsif Switch_Chars (First .. Last) = "quiet" then
 236             null;
 237
 238          --  Store any other GCC switches. Also do special processing for some
 239          --  specific switches that the Ada front-end knows about.
 240
 241          else
 242             Store_Compilation_Switch (Switch_Chars);
 243
 244             --  Back end switch -fno-inline also sets the Suppress_All_Inlining
 245             --  front end flag to entirely inhibit all inlining.
 246
 247             if Switch_Chars (First .. Last) = "fno-inline" then
 248                Opt.Suppress_All_Inlining := True;
 249
 250             --  Back end switch -fpreserve-control-flow also sets the front end
 251             --  flag that inhibits improper control flow transformations.
 252
 253             elsif Switch_Chars (First .. Last) = "fpreserve-control-flow" then
 254                Opt.Suppress_Control_Flow_Optimizations := True;
 255
 256             --  Back end switch -fdump-scos, which exists primarily for C, is
 257             --  also accepted for Ada as a synonym of -gnateS.
 258
 259             elsif Switch_Chars (First .. Last) = "fdump-scos" then
 260                Opt.Generate_SCO := True;
 261                Opt.Generate_SCO_Instance_Table := True;
 262             end if;
 263          end if;
 264       end Scan_Back_End_Switches;
 265
 266       --  Local variables
 267
 268       Arg_Count : constant Natural := Natural (save_argc - 1);
 269       Args      : Argument_List (1 .. Arg_Count);
 270
 271    --  Start of processing for Scan_Compiler_Arguments
 272
 273    begin
 274       --  Acquire stack checking mode directly from GCC. The reason we do this
 275       --  is to make sure that the indication of stack checking being enabled
 276       --  is the same in the front end and the back end. This status obtained
 277       --  from gcc is affected by more than just the switch -fstack-check.
 278
 279       Opt.Stack_Checking_Enabled := (flag_stack_check /= 0);
 280
 281       --  Put the arguments in Args
 282
 283       for Arg in Pos range 1 .. save_argc - 1 loop
 284          declare
 285             Argv_Ptr : constant Big_String_Ptr := save_argv (Arg);
 286             Argv_Len : constant Nat            := Len_Arg (Arg);
 287             Argv     : constant String         :=
 288                          Argv_Ptr (1 .. Natural (Argv_Len));
 289          begin
 290             Args (Positive (Arg)) := new String'(Argv);
 291          end;
 292       end loop;
 293
 294       --  Loop through command line arguments, storing them for later access
 295
 296       Next_Arg := 1;
 297       while Next_Arg <= Args'Last loop
 298          Look_At_Arg : declare
 299             Argv : constant String := Args (Next_Arg).all;
 300
 301          begin
 302             --  If the previous switch has set the Output_File_Name_Present
 303             --  flag (that is we have seen a -gnatO), then the next argument
 304             --  is the name of the output object file.
 305
 306             if Output_File_Name_Present and then not Output_File_Name_Seen then
 307                if Is_Switch (Argv) then
 308                   Fail ("Object file name missing after -gnatO");
 309                else
 310                   Set_Output_Object_File_Name (Argv);
 311                   Output_File_Name_Seen := True;
 312                end if;
 313
 314             --  If the previous switch has set the Search_Directory_Present
 315             --  flag (that is if we have just seen -I), then the next argument
 316             --  is a search directory path.
 317
 318             elsif Search_Directory_Present then
 319                if Is_Switch (Argv) then
 320                   Fail ("search directory missing after -I");
 321                else
 322                   Add_Src_Search_Dir (Argv);
 323                   Search_Directory_Present := False;
 324                end if;
 325
 326             --  If not a switch, must be a file name
 327
 328             elsif not Is_Switch (Argv) then
 329                Add_File (Argv);
 330
 331             --  We must recognize -nostdinc to suppress visibility on the
 332             --  standard GNAT RTL sources. This is also a gcc switch.
 333
 334             elsif Argv (Argv'First + 1 .. Argv'Last) = "nostdinc" then
 335                Opt.No_Stdinc := True;
 336                Scan_Back_End_Switches (Argv);
 337
 338             --  We must recognize -nostdlib to suppress visibility on the
 339             --  standard GNAT RTL objects.
 340
 341             elsif Argv (Argv'First + 1 .. Argv'Last) = "nostdlib" then
 342                Opt.No_Stdlib := True;
 343
 344             elsif Is_Front_End_Switch (Argv) then
 345                Scan_Front_End_Switches (Argv, Args, Next_Arg);
 346
 347             --  All non-front-end switches are back-end switches
 348
 349             else
 350                Scan_Back_End_Switches (Argv);
 351             end if;
 352          end Look_At_Arg;
 353
 354          Next_Arg := Next_Arg + 1;
 355       end loop;
 356    end Scan_Compiler_Arguments;
 357
 358 end Back_End;