libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  gcc_version          (x.y.z format)
  36 dnl  SUBDIRS
  37 dnl Substs:
  38 dnl  glibcxx_builddir     (absolute path)
  39 dnl  glibcxx_srcdir       (absolute path)
  40 dnl  toplevel_srcdir      (absolute path)
  41 dnl  with_cross_host
  42 dnl  with_newlib
  43 dnl  with_target_subdir
  44 dnl plus
  45 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  46 dnl  - default settings for all AM_CONFITIONAL test variables
  47 dnl  - lots of tools, like CC and CXX
  48 dnl
  49 AC_DEFUN([GLIBCXX_CONFIGURE], [
  50   # Keep these sync'd with the list in Makefile.am.  The first provides an
  51   # expandable list at autoconf time; the second provides an expandable list
  52   # (i.e., shell variable) at configure time.
  53   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  54   SUBDIRS='glibcxx_SUBDIRS'
  55
  56   # These need to be absolute paths, yet at the same time need to
  57   # canonicalize only relative paths, because then amd will not unmount
  58   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  59   glibcxx_builddir=`${PWDCMD-pwd}`
  60   case $srcdir in
  61     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  62     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  63   esac
  64   toplevel_srcdir=${glibcxx_srcdir}/..
  65   AC_SUBST(glibcxx_builddir)
  66   AC_SUBST(glibcxx_srcdir)
  67   AC_SUBST(toplevel_srcdir)
  68
  69   # We use these options to decide which functions to include.  They are
  70   # set from the top level.
  71   AC_ARG_WITH([target-subdir],
  72     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  73                    [configuring in a subdirectory]))
  74
  75   AC_ARG_WITH([cross-host],
  76     AC_HELP_STRING([--with-cross-host=HOST],
  77                    [configuring with a cross compiler]))
  78
  79   AC_ARG_WITH([newlib],
  80     AC_HELP_STRING([--with-newlib],
  81                    [assume newlib as a system C library]))
  82
  83   # We're almost certainly being configured before anything else which uses
  84   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  85   # we not cache the value of CXX that we "discover" here, because it's set
  86   # to something unique for us and libjava.  Other target libraries need to
  87   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  88   # process by sneakily renaming the cache variable.  This also lets us debug
  89   # the value of "our" CXX in postmortems.
  90   #
  91   # We must also force CXX to /not/ be a precious variable, otherwise the
  92   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  93   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  94   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  95   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  96   #
  97   # -fno-builtin must be present here so that a non-conflicting form of
  98   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  99
 100   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103   save_CXXFLAGS="$CXXFLAGS"
 104   CXXFLAGS="$CXXFLAGS -fno-builtin"
 105   AC_PROG_CC
 106   AC_PROG_CXX
 107   CXXFLAGS="$save_CXXFLAGS"
 108   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109   AC_SUBST(CFLAGS)
 110   AC_SUBST(CXXFLAGS)
 111
 112   # For directory versioning (e.g., headers) and other variables.
 113   AC_MSG_CHECKING([for GCC version number])
 114   gcc_version=`$CXX -dumpversion`
 115   AC_MSG_RESULT($gcc_version)
 116
 117   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 118   # available).  Uncomment the next line to force a particular method.
 119   AC_PROG_LN_S
 120   #LN_S='cp -p'
 121
 122   AC_CHECK_TOOL(AS, as)
 123   AC_CHECK_TOOL(AR, ar)
 124   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 125
 126   AM_MAINTAINER_MODE
 127
 128   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 129   # which are themselves conditionally expanded.
 130   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 131   ## other macros from doing the same.  This should be automated.)  -pme
 132   need_libmath=no
 133   enable_wchar_t=no
 134   #enable_libstdcxx_debug=no
 135   #enable_libstdcxx_pch=no
 136   #enable_cheaders=c
 137   #c_compatibility=no
 138   #enable_abi_check=no
 139   #enable_symvers=no
 140   #enable_hosted_libstdcxx=yes
 141
 142   # Find platform-specific directories containing configuration info.
 143   # Also possibly modify flags used elsewhere, as needed by the platform.
 144   GLIBCXX_CHECK_HOST
 145 ])
 146
 147
 148 m4_include([linkage.m4])
 149 m4_include([../config/no-executables.m4])
 150
 151
 152 dnl
 153 dnl Tests for newer compiler features, or features that are present in newer
 154 dnl compiler versions but not older compiler versions still in use, should
 155 dnl be placed here.
 156 dnl
 157 dnl Defines:
 158 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 159 dnl   new inlining code or the new system_header pragma will die on -Werror.
 160 dnl   Leave it out by default and use maint-mode to use it.
 161 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 162 dnl   compiler supports it and the user has not requested debug mode.
 163 dnl
 164 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 165   # All these tests are for C++; save the language and the compiler flags.
 166   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 167   # found in GLIBCXX_CONFIGURE.
 168   AC_LANG_SAVE
 169   AC_LANG_CPLUSPLUS
 170   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 171   ac_save_CXXFLAGS="$CXXFLAGS"
 172
 173   # Check for maintainer-mode bits.
 174   if test x"$USE_MAINTAINER_MODE" = xno; then
 175     WERROR=''
 176   else
 177     WERROR='-Werror'
 178   fi
 179
 180   # Check for -ffunction-sections -fdata-sections
 181   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 182   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 183   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 184   if test "$ac_test_CXXFLAGS" = set; then
 185     CXXFLAGS="$ac_save_CXXFLAGS"
 186   else
 187     # this is the suspicious part
 188     CXXFLAGS=''
 189   fi
 190   if test x"$ac_fdsections" = x"yes"; then
 191     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 192   fi
 193   AC_MSG_RESULT($ac_fdsections)
 194
 195   AC_LANG_RESTORE
 196   AC_SUBST(WERROR)
 197   AC_SUBST(SECTION_FLAGS)
 198 ])
 199
 200
 201 dnl
 202 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 203 dnl the native linker is in use, all variables will be defined to something
 204 dnl safe (like an empty string).
 205 dnl
 206 dnl Defines:
 207 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 208 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 209 dnl  LD (as a side effect of testing)
 210 dnl Sets:
 211 dnl  with_gnu_ld
 212 dnl  glibcxx_gnu_ld_version (possibly)
 213 dnl
 214 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 215 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 216 dnl
 217 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 218   # If we're not using GNU ld, then there's no point in even trying these
 219   # tests.  Check for that first.  We should have already tested for gld
 220   # by now (in libtool), but require it now just to be safe...
 221   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 222   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 223   AC_REQUIRE([AC_PROG_LD])
 224   AC_REQUIRE([AC_PROG_AWK])
 225
 226   # The name set by libtool depends on the version of libtool.  Shame on us
 227   # for depending on an impl detail, but c'est la vie.  Older versions used
 228   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 229   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 230   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 231   # set (hence we're using an older libtool), then set it.
 232   if test x${with_gnu_ld+set} != xset; then
 233     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 234       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 235       with_gnu_ld=no
 236     else
 237       with_gnu_ld=$ac_cv_prog_gnu_ld
 238     fi
 239   fi
 240
 241   # Start by getting the version number.  I think the libtool test already
 242   # does some of this, but throws away the result.
 243   changequote(,)
 244   ldver=`$LD --version 2>/dev/null | head -1 | \
 245          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 246   changequote([,])
 247   glibcxx_gnu_ld_version=`echo $ldver | \
 248          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 249
 250   # Set --gc-sections.
 251   if test "$with_gnu_ld" = "notbroken"; then
 252     # GNU ld it is!  Joy and bunny rabbits!
 253
 254     # All these tests are for C++; save the language and the compiler flags.
 255     # Need to do this so that g++ won't try to link in libstdc++
 256     ac_test_CFLAGS="${CFLAGS+set}"
 257     ac_save_CFLAGS="$CFLAGS"
 258     CFLAGS='-x c++  -Wl,--gc-sections'
 259
 260     # Check for -Wl,--gc-sections
 261     # XXX This test is broken at the moment, as symbols required for linking
 262     # are now in libsupc++ (not built yet).  In addition, this test has
 263     # cored on solaris in the past.  In addition, --gc-sections doesn't
 264     # really work at the moment (keeps on discarding used sections, first
 265     # .eh_frame and now some of the glibc sections for iconv).
 266     # Bzzzzt.  Thanks for playing, maybe next time.
 267     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 268     AC_TRY_RUN([
 269      int main(void)
 270      {
 271        try { throw 1; }
 272        catch (...) { };
 273        return 0;
 274      }
 275     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 276     if test "$ac_test_CFLAGS" = set; then
 277       CFLAGS="$ac_save_CFLAGS"
 278     else
 279       # this is the suspicious part
 280       CFLAGS=''
 281     fi
 282     if test "$ac_sectionLDflags" = "yes"; then
 283       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 284     fi
 285     AC_MSG_RESULT($ac_sectionLDflags)
 286   fi
 287
 288   # Set linker optimization flags.
 289   if test x"$with_gnu_ld" = x"yes"; then
 290     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 291   fi
 292
 293   AC_SUBST(SECTION_LDFLAGS)
 294   AC_SUBST(OPT_LDFLAGS)
 295 ])
 296
 297
 298 dnl
 299 dnl Check to see if this target can enable the wchar_t parts.
 300 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 301 dnl must have been previously checked.)  By default, wide characters are
 302 dnl disabled.
 303 dnl
 304 dnl Defines:
 305 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 306 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 307 dnl Substs:
 308 dnl  LIBICONV to a -l string containing the iconv library, if needed.
 309 dnl
 310 AC_DEFUN([GLIBCXX_CHECK_WCHAR_T_SUPPORT], [
 311   # Test wchar.h for mbstate_t, which is needed for char_traits and
 312   # others even if wchar_t support is not on.
 313   AC_MSG_CHECKING([for mbstate_t])
 314   AC_TRY_COMPILE([#include <wchar.h>],
 315   [mbstate_t teststate;],
 316   have_mbstate_t=yes, have_mbstate_t=no)
 317   AC_MSG_RESULT($have_mbstate_t)
 318   if test x"$have_mbstate_t" = xyes; then
 319     AC_DEFINE(HAVE_MBSTATE_T)
 320   fi
 321
 322   # Sanity check for existence of ISO C99 headers for extended encoding.
 323   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 324   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 325
 326   # Only continue checking if the ISO C99 headers exist and support is on.
 327   if test x"$ac_has_wchar_h" = xyes &&
 328      test x"$ac_has_wctype_h" = xyes &&
 329      test x"$enable_c_mbchar" != xno; then
 330
 331     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 332     # numeric_limits can instantiate type_traits<wchar_t>
 333     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 334     AC_TRY_COMPILE([#include <wchar.h>],
 335     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 336     has_wchar_minmax=yes, has_wchar_minmax=no)
 337     AC_MSG_RESULT($has_wchar_minmax)
 338
 339     # Test wchar.h for WEOF, which is what we use to determine whether
 340     # to specialize for char_traits<wchar_t> or not.
 341     AC_MSG_CHECKING([for WEOF])
 342     AC_TRY_COMPILE([
 343       #include <wchar.h>
 344       #include <stddef.h>],
 345     [wint_t i = WEOF;],
 346     has_weof=yes, has_weof=no)
 347     AC_MSG_RESULT($has_weof)
 348
 349     # Tests for wide character functions used in char_traits<wchar_t>.
 350     ac_wfuncs=yes
 351     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 352     [],[ac_wfuncs=no])
 353
 354     # Checks for names injected into std:: by the c_std headers.
 355     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 356     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 357     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 358     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 359     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 360     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 361     [],[ac_wfuncs=no])
 362
 363     # Checks for wide character functions that are not required
 364     # for basic wchar_t support.  Don't disable support if they are missing.
 365     # Injection of these is wrapped with guard macros.
 366     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 367
 368     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 369     if test x"$has_weof" = xyes &&
 370        test x"$has_wchar_minmax" = xyes &&
 371        test x"$ac_wfuncs" = xyes;
 372     then
 373       ac_isoC99_wchar_t=yes
 374     else
 375       ac_isoC99_wchar_t=no
 376     fi
 377     AC_MSG_RESULT($ac_isoC99_wchar_t)
 378
 379     # Use iconv for wchar_t to char conversions. As such, check for
 380     # X/Open Portability Guide, version 2 features (XPG2).
 381     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 382     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 383
 384     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 385     AC_CHECK_LIB(iconv, iconv, LIBICONV="-liconv")
 386     ac_save_LIBS="$LIBS"
 387     LIBS="$LIBS $LIBICONV"
 388     AC_SUBST(LIBICONV)
 389
 390     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 391     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 392
 393     LIBS="$ac_save_LIBS"
 394
 395     AC_MSG_CHECKING([for XPG2 wchar_t support])
 396     if test x"$ac_has_iconv_h" = xyes &&
 397        test x"$ac_has_langinfo_h" = xyes &&
 398        test x"$ac_XPG2funcs" = xyes;
 399     then
 400       ac_XPG2_wchar_t=yes
 401     else
 402       ac_XPG2_wchar_t=no
 403     fi
 404     AC_MSG_RESULT($ac_XPG2_wchar_t)
 405
 406     # At the moment, only enable wchar_t specializations if all the
 407     # above support is present.
 408     if test x"$ac_isoC99_wchar_t" = xyes &&
 409        test x"$ac_XPG2_wchar_t" = xyes;
 410     then
 411       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 412       enable_wchar_t=yes
 413     fi
 414   fi
 415   AC_MSG_CHECKING([for enabled wchar_t specializations])
 416   AC_MSG_RESULT($enable_wchar_t)
 417 ])
 418
 419
 420 dnl
 421 dnl Check for headers for, and arguments to, the setrlimit() function.
 422 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 423 dnl
 424 dnl Defines:
 425 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 426 dnl  various HAVE_LIMIT_* for individual limit names
 427 dnl
 428 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 429   AC_TRY_COMPILE(
 430     [#include <unistd.h>
 431      #include <sys/time.h>
 432      #include <sys/resource.h>
 433     ],
 434     [ int f = RLIMIT_$1 ; ],
 435     [glibcxx_mresult=1], [glibcxx_mresult=0])
 436   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 437                      [Only used in build directory testsuite_hooks.h.])
 438 ])
 439
 440 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 441   setrlimit_have_headers=yes
 442   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 443                    [],
 444                    [setrlimit_have_headers=no])
 445   # If don't have the headers, then we can't run the tests now, and we
 446   # won't be seeing any of these during testsuite compilation.
 447   if test $setrlimit_have_headers = yes; then
 448     # Can't do these in a loop, else the resulting syntax is wrong.
 449     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 450     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 451     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 452     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 453     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 454
 455     # Check for rlimit, setrlimit.
 456     AC_CACHE_VAL(ac_setrlimit, [
 457       AC_TRY_COMPILE(
 458         [#include <unistd.h>
 459          #include <sys/time.h>
 460          #include <sys/resource.h>
 461         ],
 462         [struct rlimit r;
 463          setrlimit(0, &r);],
 464         [ac_setrlimit=yes], [ac_setrlimit=no])
 465     ])
 466   fi
 467
 468   AC_MSG_CHECKING([for testsuite resource limits support])
 469   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 470     ac_res_limits=yes
 471     AC_DEFINE(_GLIBCXX_RES_LIMITS)
 472   else
 473     ac_res_limits=no
 474   fi
 475   AC_MSG_RESULT($ac_res_limits)
 476 ])
 477
 478
 479 dnl
 480 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 481 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 482 dnl
 483 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 484   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 485     AC_TRY_LINK(
 486       [#include <sys/stat.h>],
 487       [struct stat buffer;
 488        fstat(0, &buffer);
 489        S_ISREG(buffer.st_mode);],
 490       [glibcxx_cv_S_ISREG=yes],
 491       [glibcxx_cv_S_ISREG=no])
 492   ])
 493   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 494     AC_TRY_LINK(
 495       [#include <sys/stat.h>],
 496       [struct stat buffer;
 497        fstat(0, &buffer);
 498        S_IFREG & buffer.st_mode;],
 499       [glibcxx_cv_S_IFREG=yes],
 500       [glibcxx_cv_S_IFREG=no])
 501   ])
 502   if test $glibcxx_cv_S_ISREG = yes; then
 503     AC_DEFINE(HAVE_S_ISREG)
 504   elif test $glibcxx_cv_S_IFREG = yes; then
 505     AC_DEFINE(HAVE_S_IFREG)
 506   fi
 507 ])
 508
 509
 510 dnl
 511 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 512 dnl
 513 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 514   AC_CACHE_VAL(glibcxx_cv_POLL, [
 515     AC_TRY_LINK(
 516       [#include <poll.h>],
 517       [struct pollfd pfd[1];
 518        pfd[0].events = POLLIN;
 519        poll(pfd, 1, 0);],
 520       [glibcxx_cv_POLL=yes],
 521       [glibcxx_cv_POLL=no])
 522   ])
 523   if test $glibcxx_cv_POLL = yes; then
 524     AC_DEFINE(HAVE_POLL)
 525   fi
 526 ])
 527
 528
 529 dnl
 530 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 531 dnl
 532 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 533   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 534     AC_TRY_LINK(
 535       [#include <sys/uio.h>],
 536       [struct iovec iov[2];
 537        writev(0, iov, 0);],
 538       [glibcxx_cv_WRITEV=yes],
 539       [glibcxx_cv_WRITEV=no])
 540   ])
 541   if test $glibcxx_cv_WRITEV = yes; then
 542     AC_DEFINE(HAVE_WRITEV)
 543   fi
 544 ])
 545
 546
 547 dnl
 548 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 549 dnl
 550 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 551   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 552     AC_TRY_COMPILE(
 553       [#include <stdint.h>],
 554       [int64_t var;],
 555       [glibcxx_cv_INT64_T=yes],
 556       [glibcxx_cv_INT64_T=no])
 557   ])
 558   if test $glibcxx_cv_INT64_T = yes; then
 559     AC_DEFINE(HAVE_INT64_T)
 560   fi
 561 ])
 562
 563
 564 dnl
 565 dnl Check whether LFS support is available.
 566 dnl
 567 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 568   AC_LANG_SAVE
 569   AC_LANG_CPLUSPLUS
 570   ac_save_CXXFLAGS="$CXXFLAGS"
 571   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 572   AC_CACHE_VAL(glibcxx_cv_LFS, [
 573     AC_TRY_LINK(
 574       [#include <unistd.h>
 575        #include <stdio.h>
 576       ],
 577       [FILE* fp;
 578        fopen64("t", "w");
 579        fseeko64(fp, 0, SEEK_CUR);
 580        ftello64(fp);
 581        lseek64(1, 0, SEEK_CUR);],
 582       [glibcxx_cv_LFS=yes],
 583       [glibcxx_cv_LFS=no])
 584   ])
 585   if test $glibcxx_cv_LFS = yes; then
 586     AC_DEFINE(_GLIBCXX_USE_LFS)
 587   fi
 588   CXXFLAGS="$ac_save_CXXFLAGS"
 589   AC_LANG_RESTORE
 590 ])
 591
 592
 593 dnl
 594 dnl Does any necessary configuration of the testsuite directory.  Generates
 595 dnl the testsuite_hooks.h header.
 596 dnl
 597 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 598 dnl
 599 dnl Sets:
 600 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 601 dnl Substs:
 602 dnl  baseline_dir
 603 dnl
 604 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 605   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 606     # Do checks for resource limit functions.
 607     GLIBCXX_CHECK_SETRLIMIT
 608
 609     # Look for setenv, so that extended locale tests can be performed.
 610     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 611
 612     if test $enable_symvers = no; then
 613       enable_abi_check=no
 614     else
 615       case "$host" in
 616         *-*-cygwin*)
 617           enable_abi_check=no ;;
 618         *)
 619           enable_abi_check=yes ;;
 620       esac
 621     fi
 622   else
 623     # Only build this as native, since automake does not understand
 624     # CXX_FOR_BUILD.
 625     enable_abi_check=no
 626   fi
 627
 628   # Export file names for ABI checking.
 629   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 630   AC_SUBST(baseline_dir)
 631
 632   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 633   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 634 ])
 635
 636
 637 dnl
 638 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 639 dnl
 640 dnl Substs:
 641 dnl  GLIBCXX_INCLUDES
 642 dnl  TOPLEVEL_INCLUDES
 643 dnl
 644 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 645   # Used for every C++ compile we perform.
 646   GLIBCXX_INCLUDES="\
 647 -I$glibcxx_builddir/include/$host_alias \
 648 -I$glibcxx_builddir/include \
 649 -I$glibcxx_srcdir/libsupc++"
 650
 651   # For Canadian crosses, pick this up too.
 652   if test $CANADIAN = yes; then
 653     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 654   fi
 655
 656   # Stuff in the actual top level.  Currently only used by libsupc++ to
 657   # get unwind* headers from the gcc dir.
 658   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 659   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 660
 661   # Now, export this to all the little Makefiles....
 662   AC_SUBST(GLIBCXX_INCLUDES)
 663   AC_SUBST(TOPLEVEL_INCLUDES)
 664 ])
 665
 666
 667 dnl
 668 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 669 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 670 dnl
 671 dnl Substs:
 672 dnl  OPTIMIZE_CXXFLAGS
 673 dnl  WARN_FLAGS
 674 dnl
 675 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 676   # Optimization flags that are probably a good idea for thrill-seekers. Just
 677   # uncomment the lines below and make, everything else is ready to go...
 678   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 679   OPTIMIZE_CXXFLAGS=
 680   AC_SUBST(OPTIMIZE_CXXFLAGS)
 681
 682   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 683   AC_SUBST(WARN_FLAGS)
 684 ])
 685
 686
 687 dnl
 688 dnl All installation directory information is determined here.
 689 dnl
 690 dnl Substs:
 691 dnl  gxx_install_dir
 692 dnl  glibcxx_prefixdir
 693 dnl  glibcxx_toolexecdir
 694 dnl  glibcxx_toolexeclibdir
 695 dnl
 696 dnl Assumes cross_compiling bits already done, and with_cross_host in
 697 dnl particular.
 698 dnl
 699 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 700   glibcxx_toolexecdir=no
 701   glibcxx_toolexeclibdir=no
 702   glibcxx_prefixdir=$prefix
 703
 704   AC_MSG_CHECKING([for gxx-include-dir])
 705   AC_ARG_WITH([gxx-include-dir],
 706     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 707                    [installation directory for include files]),
 708     [case "$withval" in
 709       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 710       no)  gxx_include_dir=no ;;
 711       *)   gxx_include_dir=$withval ;;
 712      esac],
 713     [gxx_include_dir=no])
 714   AC_MSG_RESULT($gxx_include_dir)
 715
 716   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 717   AC_ARG_ENABLE([version-specific-runtime-libs],
 718     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 719                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 720     [case "$enableval" in
 721       yes) version_specific_libs=yes ;;
 722       no)  version_specific_libs=no ;;
 723       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 724      esac],
 725     [version_specific_libs=no])
 726   AC_MSG_RESULT($version_specific_libs)
 727
 728   # Default case for install directory for include files.
 729   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 730     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 731   fi
 732
 733   # Version-specific runtime libs processing.
 734   if test $version_specific_libs = yes; then
 735     # Need the gcc compiler version to know where to install libraries
 736     # and header files if --enable-version-specific-runtime-libs option
 737     # is selected.  FIXME: these variables are misnamed, there are
 738     # no executables installed in _toolexecdir or _toolexeclibdir.
 739     if test x"$gxx_include_dir" = x"no"; then
 740       gxx_include_dir='${libdir}/gcc/${host_alias}/'$gcc_version/include/c++
 741     fi
 742     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 743     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 744   fi
 745
 746   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 747   # Install a library built with a cross compiler in tooldir, not libdir.
 748   if test x"$glibcxx_toolexecdir" = x"no"; then
 749     if test -n "$with_cross_host" &&
 750        test x"$with_cross_host" != x"no"; then
 751       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 752       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 753     else
 754       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 755       glibcxx_toolexeclibdir='${libdir}'
 756     fi
 757     multi_os_directory=`$CXX -print-multi-os-directory`
 758     case $multi_os_directory in
 759       .) ;; # Avoid trailing /.
 760       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 761     esac
 762   fi
 763
 764   AC_MSG_CHECKING([for install location])
 765   AC_MSG_RESULT($gxx_include_dir)
 766
 767   AC_SUBST(glibcxx_prefixdir)
 768   AC_SUBST(gxx_include_dir)
 769   AC_SUBST(glibcxx_toolexecdir)
 770   AC_SUBST(glibcxx_toolexeclibdir)
 771 ])
 772
 773
 774 dnl
 775 dnl GLIBCXX_ENABLE
 776 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 777 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 778 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 779 dnl
 780 dnl See docs/html/17_intro/configury.html#enable for documentation.
 781 dnl
 782 m4_define([GLIBCXX_ENABLE],[dnl
 783 m4_define([_g_switch],[--enable-$1])dnl
 784 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 785  AC_ARG_ENABLE($1,_g_help,
 786   m4_bmatch([$5],
 787    [^permit ],
 788      [[
 789       case "$enableval" in
 790        m4_bpatsubst([$5],[permit ])) ;;
 791        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 792           dnl Idea for future:  generate a URL pointing to
 793           dnl "onlinedocs/configopts.html#whatever"
 794       esac
 795      ]],
 796    [^$],
 797      [[
 798       case "$enableval" in
 799        yes|no) ;;
 800        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 801       esac
 802      ]],
 803    [[$5]]),
 804   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 805 m4_undefine([_g_switch])dnl
 806 m4_undefine([_g_help])dnl
 807 ])
 808
 809
 810 dnl
 811 dnl Check for ISO/IEC 9899:1999 "C99" support.
 812 dnl
 813 dnl --enable-c99 defines _GLIBCXX_USE_C99
 814 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 815 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 816 dnl       Where DEFAULT is either `yes' or `no'.
 817 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 818 dnl
 819 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 820   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 821
 822   AC_LANG_SAVE
 823   AC_LANG_CPLUSPLUS
 824
 825   # Check for the existence of <math.h> functions used if C99 is enabled.
 826   ac_c99_math=yes;
 827   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 828   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 829   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 830   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 831   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 832   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 833   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 834   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 835   AC_TRY_COMPILE([#include <math.h>],
 836                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 837   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 838   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 839   AC_TRY_COMPILE([#include <math.h>],
 840                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 841   AC_TRY_COMPILE([#include <math.h>],
 842                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 843   AC_MSG_RESULT($ac_c99_math)
 844
 845   if test x"$ac_c99_math" = x"yes"; then
 846     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 847   fi
 848
 849   # Check for the existence in <stdio.h> of vscanf, et. al.
 850   ac_c99_stdio=yes;
 851   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 852   AC_TRY_COMPILE([#include <stdio.h>],
 853                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 854   AC_TRY_COMPILE([#include <stdio.h>
 855                   #include <stdarg.h>
 856                   void foo(char* fmt, ...)
 857                   {va_list args; va_start(args, fmt);
 858                   vfscanf(stderr, "%i", args);}],
 859                   [],, [ac_c99_stdio=no])
 860   AC_TRY_COMPILE([#include <stdio.h>
 861                   #include <stdarg.h>
 862                   void foo(char* fmt, ...)
 863                   {va_list args; va_start(args, fmt);
 864                   vscanf("%i", args);}],
 865                   [],, [ac_c99_stdio=no])
 866   AC_TRY_COMPILE([#include <stdio.h>
 867                   #include <stdarg.h>
 868                   void foo(char* fmt, ...)
 869                   {va_list args; va_start(args, fmt);
 870                   vsnprintf(fmt, 0, "%i", args);}],
 871                   [],, [ac_c99_stdio=no])
 872   AC_TRY_COMPILE([#include <stdio.h>
 873                   #include <stdarg.h>
 874                   void foo(char* fmt, ...)
 875                   {va_list args; va_start(args, fmt);
 876                   vsscanf(fmt, "%i", args);}],
 877                   [],, [ac_c99_stdio=no])
 878   AC_MSG_RESULT($ac_c99_stdio)
 879
 880   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 881   ac_c99_stdlib=yes;
 882   AC_MSG_CHECKING([for lldiv_t declaration])
 883   AC_CACHE_VAL(ac_c99_lldiv_t, [
 884   AC_TRY_COMPILE([#include <stdlib.h>],
 885                    [ lldiv_t mydivt;],
 886                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 887   ])
 888   AC_MSG_RESULT($ac_c99_lldiv_t)
 889
 890   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 891   AC_TRY_COMPILE([#include <stdlib.h>],
 892                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 893   AC_TRY_COMPILE([#include <stdlib.h>],
 894                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 895   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 896   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 897   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 898   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 899   if test x"$ac_c99_lldiv_t" = x"no"; then
 900     ac_c99_stdlib=no;
 901   fi;
 902   AC_MSG_RESULT($ac_c99_stdlib)
 903
 904   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 905   # XXX the wchar.h checks should be rolled into the general C99 bits.
 906   ac_c99_wchar=yes;
 907   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 908   AC_TRY_COMPILE([#include <wchar.h>],
 909                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 910   AC_TRY_COMPILE([#include <wchar.h>],
 911                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 912   AC_TRY_COMPILE([#include <wchar.h>],
 913                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 914   AC_MSG_RESULT($ac_c99_wchar)
 915
 916   AC_MSG_CHECKING([for enabled ISO C99 support])
 917   if test x"$ac_c99_math" = x"no" ||
 918      test x"$ac_c99_stdio" = x"no" ||
 919      test x"$ac_c99_stdlib" = x"no" ||
 920      test x"$ac_c99_wchar" = x"no"; then
 921     enable_c99=no;
 922   fi;
 923   AC_MSG_RESULT($enable_c99)
 924
 925   if test x"$ac_99_math" = x"yes"; then
 926     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 927   fi
 928
 929   # Option parsed, now set things appropriately
 930   if test x"$enable_c99" = x"yes"; then
 931     AC_DEFINE(_GLIBCXX_USE_C99)
 932   fi
 933
 934   AC_LANG_RESTORE
 935 ])
 936
 937
 938 dnl
 939 dnl Check for what type of C headers to use.
 940 dnl
 941 dnl --enable-cheaders= [does stuff].
 942 dnl --disable-cheaders [does not do anything, really].
 943 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 944 dnl       Where DEFAULT is either `c' or `c_std'.
 945 dnl
 946 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
 947   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 948     [construct "C" headers for g++], [permit c|c_std])
 949   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 950
 951   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 952
 953   AC_SUBST(C_INCLUDE_DIR)
 954   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 955   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 956   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 957 ])
 958
 959
 960 dnl
 961 dnl Check for which locale library to use.  The choice is mapped to
 962 dnl a subdirectory of config/locale.
 963 dnl
 964 dnl Default is generic.
 965 dnl
 966 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
 967   AC_MSG_CHECKING([for C locale to use])
 968   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 969     [use MODEL for target locale package],
 970     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 971
 972   # If they didn't use this option switch, or if they specified --enable
 973   # with no specific model, we'll have to look for one.  If they
 974   # specified --disable (???), do likewise.
 975   if test $enable_clocale = no || test $enable_clocale = yes; then
 976      enable_clocale=auto
 977   fi
 978
 979   # Either a known package, or "auto"
 980   enable_clocale_flag=$enable_clocale
 981
 982   # Probe for locale support if no specific model is specified.
 983   # Default to "generic".
 984   if test $enable_clocale_flag = auto; then
 985     case x${target_os} in
 986       xlinux* | xgnu* | xkfreebsd*-gnu | xknetbsd*-gnu)
 987         AC_EGREP_CPP([_GLIBCXX_ok], [
 988         #include <features.h>
 989         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
 990           _GLIBCXX_ok
 991         #endif
 992         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
 993
 994         # Test for bugs early in glibc-2.2.x series
 995           if test x$enable_clocale_flag = xgnu; then
 996           AC_TRY_RUN([
 997           #define _GNU_SOURCE 1
 998           #include <locale.h>
 999           #include <string.h>
1000           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1001           extern __typeof(newlocale) __newlocale;
1002           extern __typeof(duplocale) __duplocale;
1003           extern __typeof(strcoll_l) __strcoll_l;
1004           #endif
1005           int main()
1006           {
1007               const char __one[] = "Äuglein Augmen";
1008               const char __two[] = "Äuglein";
1009               int i;
1010               int j;
1011               __locale_t        loc;
1012                __locale_t        loc_dup;
1013               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1014               loc_dup = __duplocale(loc);
1015               i = __strcoll_l(__one, __two, loc);
1016               j = __strcoll_l(__one, __two, loc_dup);
1017               return 0;
1018           }
1019           ],
1020           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1021           [enable_clocale_flag=generic])
1022           fi
1023
1024         # ... at some point put __strxfrm_l tests in as well.
1025         ;;
1026       *)
1027         enable_clocale_flag=generic
1028         ;;
1029     esac
1030   fi
1031
1032   # Deal with gettext issues.  Default to not using it (=no) until we detect
1033   # support for it later.  Let the user turn it off via --e/d, but let that
1034   # default to on for easier handling.
1035   USE_NLS=no
1036   AC_ARG_ENABLE(nls,
1037     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1038     [],
1039     [enable_nls=yes])
1040
1041   # Set configure bits for specified locale package
1042   case ${enable_clocale_flag} in
1043     generic)
1044       AC_MSG_RESULT(generic)
1045
1046       CLOCALE_H=config/locale/generic/c_locale.h
1047       CLOCALE_CC=config/locale/generic/c_locale.cc
1048       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1049       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1050       CCOLLATE_CC=config/locale/generic/collate_members.cc
1051       CCTYPE_CC=config/locale/generic/ctype_members.cc
1052       CMESSAGES_H=config/locale/generic/messages_members.h
1053       CMESSAGES_CC=config/locale/generic/messages_members.cc
1054       CMONEY_CC=config/locale/generic/monetary_members.cc
1055       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1056       CTIME_H=config/locale/generic/time_members.h
1057       CTIME_CC=config/locale/generic/time_members.cc
1058       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1059       ;;
1060     gnu)
1061       AC_MSG_RESULT(gnu)
1062
1063       # Declare intention to use gettext, and add support for specific
1064       # languages.
1065       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1066       ALL_LINGUAS="de fr"
1067
1068       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1069       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1070       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1071         USE_NLS=yes
1072       fi
1073       # Export the build objects.
1074       for ling in $ALL_LINGUAS; do \
1075         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1076         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1077       done
1078       AC_SUBST(glibcxx_MOFILES)
1079       AC_SUBST(glibcxx_POFILES)
1080
1081       CLOCALE_H=config/locale/gnu/c_locale.h
1082       CLOCALE_CC=config/locale/gnu/c_locale.cc
1083       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1084       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1085       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1086       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1087       CMESSAGES_H=config/locale/gnu/messages_members.h
1088       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1089       CMONEY_CC=config/locale/gnu/monetary_members.cc
1090       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1091       CTIME_H=config/locale/gnu/time_members.h
1092       CTIME_CC=config/locale/gnu/time_members.cc
1093       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1094       ;;
1095     ieee_1003.1-2001)
1096       AC_MSG_RESULT(IEEE 1003.1)
1097
1098       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1099       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1100       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1101       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1102       CCOLLATE_CC=config/locale/generic/collate_members.cc
1103       CCTYPE_CC=config/locale/generic/ctype_members.cc
1104       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1105       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1106       CMONEY_CC=config/locale/generic/monetary_members.cc
1107       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1108       CTIME_H=config/locale/generic/time_members.h
1109       CTIME_CC=config/locale/generic/time_members.cc
1110       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1111       ;;
1112   esac
1113
1114   # This is where the testsuite looks for locale catalogs, using the
1115   # -DLOCALEDIR define during testsuite compilation.
1116   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1117   AC_SUBST(glibcxx_localedir)
1118
1119   # A standalone libintl (e.g., GNU libintl) may be in use.
1120   if test $USE_NLS = yes; then
1121     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1122     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1123   fi
1124   if test $USE_NLS = yes; then
1125     AC_DEFINE(_GLIBCXX_USE_NLS)
1126   fi
1127
1128   AC_SUBST(USE_NLS)
1129   AC_SUBST(CLOCALE_H)
1130   AC_SUBST(CCODECVT_H)
1131   AC_SUBST(CMESSAGES_H)
1132   AC_SUBST(CCODECVT_CC)
1133   AC_SUBST(CCOLLATE_CC)
1134   AC_SUBST(CCTYPE_CC)
1135   AC_SUBST(CMESSAGES_CC)
1136   AC_SUBST(CMONEY_CC)
1137   AC_SUBST(CNUMERIC_CC)
1138   AC_SUBST(CTIME_H)
1139   AC_SUBST(CTIME_CC)
1140   AC_SUBST(CLOCALE_CC)
1141   AC_SUBST(CLOCALE_INTERNAL_H)
1142 ])
1143
1144
1145 dnl
1146 dnl Check for which std::allocator base class to use.  The choice is
1147 dnl mapped from a subdirectory of include/ext.
1148 dnl
1149 dnl Default is new.
1150 dnl
1151 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1152   AC_MSG_CHECKING([for std::allocator base class to use])
1153   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1154     [use KIND for target std::allocator base],
1155     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1156   # If they didn't use this option switch, or if they specified --enable
1157   # with no specific model, we'll have to look for one.  If they
1158   # specified --disable (???), do likewise.
1159   if test $enable_libstdcxx_allocator = no || test $enable_libstdcxx_allocator = yes; then
1160      enable_libstdcxx_allocator=auto
1161   fi
1162
1163   # Either a known package, or "auto"
1164   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1165
1166   # Probe for host-specific support if no specific model is specified.
1167   # Default to "new".
1168   if test $enable_libstdcxx_allocator_flag = auto; then
1169     case ${target_os} in
1170       *)
1171         enable_libstdcxx_allocator_flag=new
1172         ;;
1173     esac
1174   fi
1175   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1176
1177
1178   # Set configure bits for specified locale package
1179   case ${enable_libstdcxx_allocator_flag} in
1180     bitmap)
1181       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1182       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1183       ;;
1184     malloc)
1185       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1186       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1187       ;;
1188     mt)
1189       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1190       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1191       ;;
1192     new)
1193       ALLOCATOR_H=config/allocator/new_allocator_base.h
1194       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1195       ;;
1196     pool)
1197       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1198       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1199       ;;
1200   esac
1201
1202   AC_SUBST(ALLOCATOR_H)
1203   AC_SUBST(ALLOCATOR_NAME)
1204 ])
1205
1206
1207 dnl
1208 dnl Check for whether the Boost-derived checks should be turned on.
1209 dnl
1210 dnl --enable-concept-checks turns them on.
1211 dnl --disable-concept-checks leaves them off.
1212 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1213 dnl       Where DEFAULT is either `yes' or `no'.
1214 dnl
1215 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1216   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1217   if test $enable_concept_checks = yes; then
1218     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1219   fi
1220 ])
1221
1222
1223 dnl
1224 dnl Check for which I/O library to use:  stdio, or something specific.
1225 dnl
1226 dnl Default is stdio.
1227 dnl
1228 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1229   AC_MSG_CHECKING([for underlying I/O to use])
1230   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1231     [use target-specific I/O package], [permit stdio])
1232
1233   # Now that libio has been removed, you can have any color you want as long
1234   # as it's black.  This is one big no-op until other packages are added, but
1235   # showing the framework never hurts.
1236   case ${enable_cstdio} in
1237     stdio)
1238       CSTDIO_H=config/io/c_io_stdio.h
1239       BASIC_FILE_H=config/io/basic_file_stdio.h
1240       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1241       AC_MSG_RESULT(stdio)
1242       ;;
1243   esac
1244
1245   AC_SUBST(CSTDIO_H)
1246   AC_SUBST(BASIC_FILE_H)
1247   AC_SUBST(BASIC_FILE_CC)
1248 ])
1249
1250
1251 dnl
1252 dnl Check for "unusual" flags to pass to the compiler while building.
1253 dnl
1254 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1255 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1256 dnl --disable-cxx-flags passes nothing.
1257 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1258 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1259 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1260 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1261 dnl       If "default flags" is an empty string, the effect is the same
1262 dnl       as --disable or --enable=no.
1263 dnl
1264 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1265   AC_MSG_CHECKING([for extra compiler flags for building])
1266   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1267     [pass compiler FLAGS when building library],
1268     [case "x$enable_cxx_flags" in
1269       xno | x)   enable_cxx_flags= ;;
1270       x-*)       ;;
1271       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1272      esac])
1273
1274   # Run through flags (either default or command-line) and set anything
1275   # extra (e.g., #defines) that must accompany particular g++ options.
1276   if test -n "$enable_cxx_flags"; then
1277     for f in $enable_cxx_flags; do
1278       case "$f" in
1279         -fhonor-std)  ;;
1280         -*)  ;;
1281         *)   # and we're trying to pass /what/ exactly?
1282              AC_MSG_ERROR([compiler flags start with a -]) ;;
1283       esac
1284     done
1285   fi
1286
1287   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1288   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1289   AC_SUBST(EXTRA_CXX_FLAGS)
1290 ])
1291
1292
1293 dnl
1294 dnl Check for wide character support.  Has the same effect as the option
1295 dnl in gcc's configure, but in a form that autoconf can mess with.
1296 dnl
1297 dnl --enable-c-mbchar requests all the wchar_t stuff.
1298 dnl --disable-c-mbchar doesn't.
1299 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1300 dnl       Where DEFAULT is either `yes' or `no'.
1301 dnl
1302 AC_DEFUN([GLIBCXX_ENABLE_C_MBCHAR], [
1303   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1304   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1305 ])
1306
1307
1308 dnl
1309 dnl Check to see if debugging libraries are to be built.
1310 dnl
1311 dnl --enable-libstdcxx-debug
1312 dnl builds a separate set of debugging libraries in addition to the
1313 dnl normal (shared, static) libstdc++ binaries.
1314 dnl
1315 dnl --disable-libstdcxx-debug
1316 dnl builds only one (non-debug) version of libstdc++.
1317 dnl
1318 dnl --enable-libstdcxx-debug-flags=FLAGS
1319 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1320 dnl
1321 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1322 dnl       Where DEFAULT is either `yes' or `no'.
1323 dnl
1324 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1325   AC_MSG_CHECKING([for additional debug build])
1326   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1327   AC_MSG_RESULT($enable_libstdcxx_debug)
1328   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1329 ])
1330
1331
1332 dnl
1333 dnl Check for explicit debug flags.
1334 dnl
1335 dnl --enable-libstdcxx-debug-flags='-O1'
1336 dnl is a general method for passing flags to be used when
1337 dnl building debug libraries with --enable-debug.
1338 dnl
1339 dnl --disable-libstdcxx-debug-flags does nothing.
1340 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1341 dnl       If "default flags" is an empty string, the effect is the same
1342 dnl       as --disable or --enable=no.
1343 dnl
1344 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1345   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1346     [pass compiler FLAGS when building debug library],
1347     [case "x$enable_libstdcxx_debug_flags" in
1348       xno | x)    enable_libstdcxx_debug_flags= ;;
1349       x-*)        ;;
1350       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1351      esac])
1352
1353   # Option parsed, now set things appropriately
1354   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1355   AC_SUBST(DEBUG_FLAGS)
1356
1357   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1358 ])
1359
1360
1361 dnl
1362 dnl Check if the user only wants a freestanding library implementation.
1363 dnl
1364 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1365 dnl installing only the headers required by [17.4.1.3] and the language
1366 dnl support library.  More than that will be built (to keep the Makefiles
1367 dnl conveniently clean), but not installed.
1368 dnl
1369 dnl Sets:
1370 dnl  is_hosted  (yes/no)
1371 dnl
1372 dnl Defines:
1373 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1374 dnl
1375 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1376   AC_ARG_ENABLE([hosted-libstdcxx],
1377     AC_HELP_STRING([--disable-hosted-libstdcxx],
1378                    [only build freestanding C++ runtime support]),,
1379     [enable_hosted_libstdcxx=yes])
1380   if test "$enable_hosted_libstdcxx" = no; then
1381     AC_MSG_NOTICE([Only freestanding libraries will be built])
1382     is_hosted=no
1383     hosted_define=0
1384     enable_abi_check=no
1385     enable_libstdcxx_pch=no
1386   else
1387     is_hosted=yes
1388     hosted_define=1
1389   fi
1390   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1391   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1392     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1393 ])
1394
1395
1396 dnl
1397 dnl Check for template specializations for the 'long long' type extension.
1398 dnl The result determines only whether 'long long' I/O is enabled; things
1399 dnl like numeric_limits<> specializations are always available.
1400 dnl
1401 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1402 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1403 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1404 dnl       Where DEFAULT is either `yes' or `no'.
1405 dnl
1406 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1407   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1408   if test $enable_long_long = yes; then
1409     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1410   fi
1411 ])
1412
1413
1414 dnl
1415 dnl Check to see if building and using a C++ precompiled header can be done.
1416 dnl
1417 dnl --enable-libstdcxx-pch=yes
1418 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1419 dnl may work, after some light-hearted attempts to puzzle out compiler
1420 dnl support, flip bits on in include/Makefile.am
1421 dnl
1422 dnl --disable-libstdcxx-pch
1423 dnl turns off attempts to use or build stdc++.h.gch.
1424 dnl
1425 dnl Substs:
1426 dnl  glibcxx_PCHFLAGS
1427 dnl
1428 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1429   AC_MSG_CHECKING([for enabled PCH])
1430   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1431   AC_MSG_RESULT([$enable_libstdcxx_pch])
1432
1433   if test $enable_libstdcxx_pch = yes; then
1434     AC_CACHE_CHECK([for compiler with PCH support],
1435       [glibcxx_cv_prog_CXX_pch],
1436       [ac_save_CXXFLAGS="$CXXFLAGS"
1437        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1438        AC_LANG_SAVE
1439        AC_LANG_CPLUSPLUS
1440        echo '#include <math.h>' > conftest.h
1441        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1442                           -o conftest.h.gch 1>&5 2>&1 &&
1443                 echo '#error "pch failed"' > conftest.h &&
1444           echo '#include "conftest.h"' > conftest.cc &&
1445                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1446        then
1447          glibcxx_cv_prog_CXX_pch=yes
1448        else
1449          glibcxx_cv_prog_CXX_pch=no
1450        fi
1451        rm -f conftest*
1452        CXXFLAGS=$ac_save_CXXFLAGS
1453        AC_LANG_RESTORE
1454       ])
1455     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1456   fi
1457
1458   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1459   if test $enable_libstdcxx_pch = yes; then
1460     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1461   else
1462     glibcxx_PCHFLAGS=""
1463   fi
1464   AC_SUBST(glibcxx_PCHFLAGS)
1465 ])
1466
1467
1468 dnl
1469 dnl Check for exception handling support.  If an explicit enable/disable
1470 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1471 dnl target may or may not support call frame exceptions.
1472 dnl
1473 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1474 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1475 dnl Neither one forces an attempt at detection.
1476 dnl
1477 dnl Defines:
1478 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1479 dnl
1480 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
1481   AC_MSG_CHECKING([for exception model to use])
1482   AC_LANG_SAVE
1483   AC_LANG_CPLUSPLUS
1484   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1485     [force use of builtin_setjmp for exceptions],
1486     [permit yes|no|auto])
1487
1488   if test $enable_sjlj_exceptions = auto; then
1489     # Botheration.  Now we've got to detect the exception model.  Link tests
1490     # against libgcc.a are problematic since we've not been given proper -L
1491     # bits for single-tree newlib and libgloss.
1492     #
1493     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1494     cat > conftest.$ac_ext << EOF
1495 [#]line __oline__ "configure"
1496 struct S { ~S(); };
1497 void bar();
1498 void foo()
1499 {
1500   S s;
1501   bar();
1502 }
1503 EOF
1504     old_CXXFLAGS="$CXXFLAGS"
1505     CXXFLAGS=-S
1506     if AC_TRY_EVAL(ac_compile); then
1507       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1508         enable_sjlj_exceptions=yes
1509       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1510         enable_sjlj_exceptions=no
1511       fi
1512     fi
1513     CXXFLAGS="$old_CXXFLAGS"
1514     rm -f conftest*
1515   fi
1516
1517   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1518   # to two different models.
1519   case $enable_sjlj_exceptions in
1520     yes)
1521       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1522         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1523       ac_exception_model_name=sjlj
1524       ;;
1525     no)
1526       ac_exception_model_name="call frame"
1527       ;;
1528     *)
1529       AC_MSG_ERROR([unable to detect exception model])
1530       ;;
1531   esac
1532  AC_LANG_RESTORE
1533  AC_MSG_RESULT($ac_exception_model_name)
1534 ])
1535
1536
1537 dnl
1538 dnl Add version tags to symbols in shared library (or not), additionally
1539 dnl marking other symbols as private/local (or not).
1540 dnl
1541 dnl --enable-symvers=style adds a version script to the linker call when
1542 dnl       creating the shared library.  The choice of version script is
1543 dnl       controlled by 'style'.
1544 dnl --disable-symvers does not.
1545 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1546 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1547 dnl       choose a default style based on linker characteristics.  Passing
1548 dnl       'no' disables versioning.
1549 dnl
1550 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
1551
1552 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1553   [enables symbol versioning of the shared library],
1554   [permit yes|no|gnu])
1555
1556 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1557 # don't know enough about $LD to do tricks...
1558 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1559 # FIXME  The following test is too strict, in theory.
1560 if test $enable_shared = no ||
1561         test "x$LD" = x ||
1562         test x$glibcxx_gnu_ld_version = x; then
1563   enable_symvers=no
1564 fi
1565
1566 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1567 if test $enable_symvers != no; then
1568   AC_MSG_CHECKING([for shared libgcc])
1569   ac_save_CFLAGS="$CFLAGS"
1570   CFLAGS=' -lgcc_s'
1571   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1572   CFLAGS="$ac_save_CFLAGS"
1573   AC_MSG_RESULT($glibcxx_shared_libgcc)
1574 fi
1575
1576 # For GNU ld, we need at least this version.  The format is described in
1577 # GLIBCXX_CHECK_LINKER_FEATURES above.
1578 glibcxx_min_gnu_ld_version=21400
1579 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1580
1581 # Check to see if unspecified "yes" value can win, given results above.
1582 # Change "yes" into either "no" or a style name.
1583 if test $enable_symvers = yes; then
1584   if test $with_gnu_ld = yes &&
1585      test $glibcxx_shared_libgcc = yes;
1586   then
1587     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1588       enable_symvers=gnu
1589     else
1590       # The right tools, the right setup, but too old.  Fallbacks?
1591       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1592       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1593       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1594       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1595       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1596         # Globbing fix is present, proper block support is not.
1597         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1598         dnl enable_symvers=???
1599         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1600         enable_symvers=no
1601       else
1602         # 2.11 or older.
1603         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1604         enable_symvers=no
1605       fi
1606     fi
1607   else
1608     # just fail for now
1609     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1610     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1611     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1612     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1613     enable_symvers=no
1614   fi
1615 fi
1616
1617 # Everything parsed; figure out what file to use.
1618 case $enable_symvers in
1619   no)
1620     SYMVER_MAP=config/linker-map.dummy
1621     ;;
1622   gnu)
1623     SYMVER_MAP=config/linker-map.gnu
1624     AC_DEFINE(_GLIBCXX_SYMVER)
1625     ;;
1626 esac
1627
1628 AC_SUBST(SYMVER_MAP)
1629 AC_SUBST(port_specific_symbol_files)
1630 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1631 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1632 ])
1633
1634
1635 dnl
1636 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1637 dnl We must stage the required headers so that they will be installed
1638 dnl with the library (unlike libgcc, the STL implementation is provided
1639 dnl solely within headers).  Since we must not inject random user-space
1640 dnl macro names into user-provided C++ code, we first stage into <file>-in
1641 dnl and process to <file> with an output command.  The reason for a two-
1642 dnl stage process here is to correctly handle $srcdir!=$objdir without
1643 dnl having to write complex code (the sed commands to clean the macro
1644 dnl namespace are complex and fragile enough as it is).  We must also
1645 dnl add a relative path so that -I- is supported properly.
1646 dnl
1647 dnl Substs:
1648 dnl  glibcxx_thread_h
1649 dnl
1650 dnl Defines:
1651 dnl  HAVE_GTHR_DEFAULT
1652 dnl
1653 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
1654   AC_MSG_CHECKING([for thread model used by GCC])
1655   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1656   AC_MSG_RESULT([$target_thread_file])
1657
1658   if test $target_thread_file != single; then
1659     AC_DEFINE(HAVE_GTHR_DEFAULT)
1660   fi
1661
1662   glibcxx_thread_h=gthr-$target_thread_file.h
1663   AC_SUBST(glibcxx_thread_h)
1664 ])
1665
1666
1667 # Check whether LC_MESSAGES is available in <locale.h>.
1668 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1669 #
1670 # This file file be copied and used freely without restrictions.  It can
1671 # be used in projects which are not available under the GNU Public License
1672 # but which still want to provide support for the GNU gettext functionality.
1673 # Please note that the actual code is *not* freely available.
1674
1675 # serial 1
1676 AC_DEFUN([AC_LC_MESSAGES], [
1677   AC_CHECK_HEADER(locale.h, [
1678     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1679       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1680        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1681     if test $ac_cv_val_LC_MESSAGES = yes; then
1682       AC_DEFINE(HAVE_LC_MESSAGES)
1683     fi
1684   ])
1685 ])
1686
1687
1688 sinclude([../libtool.m4])
1689 dnl The lines below arrange for aclocal not to bring an installed
1690 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1691 dnl add a definition of LIBTOOL to Makefile.in.
1692 ifelse(,,,[AC_SUBST(LIBTOOL)
1693 AC_DEFUN([AM_PROG_LIBTOOL])
1694 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1695 AC_DEFUN([AC_PROG_LD])
1696 ])
1697
1698 dnl vim:et:ts=2:sw=2