libstdc++-v3/config/linker-map.gnu

   1 ## Linker script for GNU ld 2.11.94+ only.
   2 ##
   3 ## Copyright (C) 2002 Free Software Foundation, Inc.
   4 ##
   5 ## This file is part of the libstdc++ version 3 distribution.
   6 ##
   7 ## This file is part of the GNU ISO C++ Library.  This library is free
   8 ## software; you can redistribute it and/or modify it under the
   9 ## terms of the GNU General Public License as published by the
  10 ## Free Software Foundation; either version 2, or (at your option)
  11 ## any later version.
  12 ##
  13 ## This library is distributed in the hope that it will be useful,
  14 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ## GNU General Public License for more details.
  17 ##
  18 ## You should have received a copy of the GNU General Public License along
  19 ## with this library; see the file COPYING.  If not, write to the Free
  20 ## Software Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307,
  21 ## USA.
  22
  23
  24 GLIBCPP_3.1 {
  25
  26   global:
  27
  28     # Names inside the 'extern' block are demangled names.
  29     # All but the last are terminated with a semicolon.
  30     extern "C++"
  31     {
  32       std::[A-Za-z]*;
  33       std::__throw_*;
  34       std::__basic_file*;
  35       std::__num_base*;
  36       std::__timepunct*;
  37       std::__numeric_limits_base*
  38     };
  39
  40     # Names not in an 'extern' block are mangled names.
  41     _ZSt9has_facet*;
  42
  43     # operator new(unsigned)
  44     _Znwj;
  45     # operator new(unsigned, std::nothrow_t const&)
  46     _ZnwjRKSt9nothrow_t;
  47     # operator new(unsigned long)
  48     _Znwm;
  49     # operator new(unsigned long, std::nothrow_t const&)
  50     _ZnwmRKSt9nothrow_t;
  51
  52     # operator delete(void*)
  53     _ZdlPv;
  54     # operator delete(void*, std::nothrow_t const&)
  55     _ZdlPvRKSt9nothrow_t;
  56
  57     # operator new[](unsigned)
  58     _Znaj;
  59     # operator new[](unsigned, std::nothrow_t const&)
  60     _ZnajRKSt9nothrow_t;
  61     # operator new[](unsigned long)
  62     _Znam;
  63     # operator new[](unsigned long, std::nothrow_t const&)
  64     _ZnamRKSt9nothrow_t;
  65
  66     # operator delete[](void*)
  67     _ZdaPv;
  68     # operator delete[](void*, std::nothrow_t const&)
  69     _ZdaPvRKSt9nothrow_t;
  70
  71     # vtable
  72     _ZTV*;
  73     _ZTT*;
  74
  75     # typeinfo
  76     _ZTI*;
  77     _ZTS*;
  78
  79     # function-scope static objects requires a guard variable.
  80     _ZGV*;
  81
  82     # virtual function thunks
  83     _ZTh*;
  84     _ZTv*;
  85     _ZTc*;
  86
  87     # std::__convert_to_v
  88     _ZSt14__convert_to_v*;
  89
  90   local:
  91     *;
  92 };
  93
  94
  95 # Symbols in the support library (libsupc++) have their own tag.
  96 CXXABI_1 {
  97
  98   global:
  99     __cxa_*;
 100     __gxx_personality_v0;
 101     __dynamic_cast;
 102
 103     # __gnu_cxx::_verbose_terminate_handler()
 104     _ZN9__gnu_cxx27__verbose_terminate_handlerEv;
 105
 106   local:
 107     *;
 108 };