configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-libcilkrts \
 154                 target-liboffloadmic \
 155                 target-libhsail-rt \
 156                 target-libatomic \
 157                 target-libitm \
 158                 target-libstdc++-v3 \
 159                 target-libsanitizer \
 160                 target-libvtv \
 161                 target-libmpx \
 162                 target-libssp \
 163                 target-libquadmath \
 164                 target-libgfortran \
 165                 target-libffi \
 166                 target-libobjc \
 167                 target-libada \
 168                 target-libgo"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # some tools are so dependent upon X11 that if we're not building with X,
 252 # it's not even worth trying to configure, much less build, that tool.
 253
 254 case ${with_x} in
 255   yes | "") ;; # the default value for this tree is that X11 is available
 256   no)
 257     skipdirs="${skipdirs} tk itcl libgui"
 258     # We won't be able to build gdbtk without X.
 259     enable_gdbtk=no
 260     ;;
 261   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 262 esac
 263
 264 # Some are only suitable for cross toolchains.
 265 # Remove these if host=target.
 266 cross_only="target-libgloss target-newlib target-opcodes"
 267
 268 case $is_cross_compiler in
 269   no) skipdirs="${skipdirs} ${cross_only}" ;;
 270 esac
 271
 272 # If both --with-headers and --with-libs are specified, default to
 273 # --without-newlib.
 274 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 275    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 276   if test x"${with_newlib}" = x ; then
 277     with_newlib=no
 278   fi
 279 fi
 280
 281 # Recognize --with-newlib/--without-newlib.
 282 case ${with_newlib} in
 283   no) skipdirs="${skipdirs} target-newlib" ;;
 284   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 285 esac
 286
 287 AC_ARG_ENABLE(as-accelerator-for,
 288 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 289                 [build as offload target compiler.
 290                 Specify offload host triple by ARG])])
 291
 292 AC_ARG_ENABLE(offload-targets,
 293 [AS_HELP_STRING([--enable-offload-targets=LIST],
 294                 [enable offloading to devices from comma-separated LIST of
 295                 TARGET[=DIR]. Use optional path to find offload target compiler
 296                 during the build])],
 297 [
 298   if test x"$enable_offload_targets" = x; then
 299     AC_MSG_ERROR([no offload targets specified])
 300   fi
 301 ], [enable_offload_targets=])
 302
 303 # Handle --enable-gold, --enable-ld.
 304 # --disable-gold [--enable-ld]
 305 #     Build only ld.  Default option.
 306 # --enable-gold [--enable-ld]
 307 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 308 #     as "ld.bfd" and "ld".
 309 # --enable-gold=default [--enable-ld]
 310 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 311 #     install ld as "ld.bfd".
 312 # --enable-gold[=default] --disable-ld
 313 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 314 # --enable-gold --enable-ld=default
 315 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 316 #     and ld.bfd).
 317 #     In other words, ld is default
 318 # --enable-gold=default --enable-ld=default
 319 #     Error.
 320
 321 default_ld=
 322 AC_ARG_ENABLE(gold,
 323 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 324                 [build gold @<:@ARG={default,yes,no}@:>@])],
 325 ENABLE_GOLD=$enableval,
 326 ENABLE_GOLD=no)
 327 case "${ENABLE_GOLD}" in
 328   yes|default)
 329     # Check for ELF target.
 330     is_elf=no
 331     case "${target}" in
 332       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 333       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 334       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 335       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 336         case "${target}" in
 337           *-*-linux*aout* | *-*-linux*oldld*)
 338             ;;
 339           *)
 340             is_elf=yes
 341             ;;
 342         esac
 343     esac
 344
 345     if test "$is_elf" = "yes"; then
 346       # Check for target supported by gold.
 347       case "${target}" in
 348         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 349         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 350           configdirs="$configdirs gold"
 351           if test x${ENABLE_GOLD} = xdefault; then
 352             default_ld=gold
 353           fi
 354           ENABLE_GOLD=yes
 355           ;;
 356       esac
 357     fi
 358     ;;
 359   no)
 360     ;;
 361   *)
 362     AC_MSG_ERROR([invalid --enable-gold argument])
 363     ;;
 364 esac
 365
 366 AC_ARG_ENABLE(ld,
 367 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 368                 [build ld @<:@ARG={default,yes,no}@:>@])],
 369 ENABLE_LD=$enableval,
 370 ENABLE_LD=yes)
 371
 372 case "${ENABLE_LD}" in
 373   default)
 374     if test x${default_ld} != x; then
 375       AC_MSG_ERROR([either gold or ld can be the default ld])
 376     fi
 377     ;;
 378   yes)
 379     ;;
 380   no)
 381     if test x${ENABLE_GOLD} != xyes; then
 382       AC_MSG_WARN([neither ld nor gold are enabled])
 383     fi
 384     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 385     ;;
 386   *)
 387     AC_MSG_ERROR([invalid --enable-ld argument])
 388     ;;
 389 esac
 390
 391 # PR gas/19109
 392 # Decide the default method for compressing debug sections.
 393 # Provide a configure time option to override our default.
 394 AC_ARG_ENABLE(compressed_debug_sections,
 395 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 396                 [Enable compressed debug sections for gas, gold or ld by
 397                  default])],
 398 [
 399   if test x"$enable_compressed_debug_sections" = xyes; then
 400     AC_MSG_ERROR([no program with compressed debug sections specified])
 401   fi
 402 ], [enable_compressed_debug_sections=])
 403
 404 # Configure extra directories which are host specific
 405
 406 case "${host}" in
 407   *-cygwin*)
 408     configdirs="$configdirs libtermcap" ;;
 409 esac
 410
 411 # A target can indicate whether a language isn't supported for some reason.
 412 # Only spaces may be used in this macro; not newlines or tabs.
 413 unsupported_languages=
 414
 415 # Remove more programs from consideration, based on the host or
 416 # target this usually means that a port of the program doesn't
 417 # exist yet.
 418
 419 case "${host}" in
 420   i[[3456789]]86-*-msdosdjgpp*)
 421     noconfigdirs="$noconfigdirs tcl tk itcl"
 422     ;;
 423 esac
 424
 425
 426 AC_ARG_ENABLE(libquadmath,
 427 AS_HELP_STRING([--disable-libquadmath],
 428   [do not build libquadmath directory]),
 429 ENABLE_LIBQUADMATH=$enableval,
 430 ENABLE_LIBQUADMATH=yes)
 431 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 432   noconfigdirs="$noconfigdirs target-libquadmath"
 433 fi
 434
 435
 436 AC_ARG_ENABLE(libquadmath-support,
 437 AS_HELP_STRING([--disable-libquadmath-support],
 438   [disable libquadmath support for Fortran]),
 439 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 440 ENABLE_LIBQUADMATH_SUPPORT=yes)
 441 enable_libquadmath_support=
 442 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 443   enable_libquadmath_support=no
 444 fi
 445
 446
 447 AC_ARG_ENABLE(libada,
 448 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 449 ENABLE_LIBADA=$enableval,
 450 ENABLE_LIBADA=yes)
 451 if test "${ENABLE_LIBADA}" != "yes" ; then
 452   noconfigdirs="$noconfigdirs gnattools"
 453 fi
 454
 455 AC_ARG_ENABLE(libssp,
 456 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 457 ENABLE_LIBSSP=$enableval,
 458 ENABLE_LIBSSP=yes)
 459
 460 AC_ARG_ENABLE(libstdcxx,
 461 AS_HELP_STRING([--disable-libstdcxx],
 462   [do not build libstdc++-v3 directory]),
 463 ENABLE_LIBSTDCXX=$enableval,
 464 ENABLE_LIBSTDCXX=default)
 465 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 466   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 467 fi]
 468
 469 # If this is accelerator compiler and its target is intelmic we enable
 470 # target liboffloadmic by default.  If this is compiler with offloading
 471 # for intelmic we enable host liboffloadmic by default.  Otherwise
 472 # liboffloadmic is disabled by default.
 473 AC_ARG_ENABLE([liboffloadmic],
 474 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 475                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 476 [case "$enableval" in
 477   no | host | target)
 478     enable_liboffloadmic=$enableval ;;
 479   *)
 480     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 481 esac],
 482 [if test x"$enable_as_accelerator_for" != x; then
 483   case "${target}" in
 484     *-intelmic-* | *-intelmicemul-*)
 485       enable_liboffloadmic=target
 486       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 487       ;;
 488     *)
 489       enable_liboffloadmic=no
 490       ;;
 491   esac
 492 else
 493   case "${enable_offload_targets}" in
 494     *-intelmic-* | *-intelmicemul-*)
 495       enable_liboffloadmic=host
 496       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 497       ;;
 498     *)
 499       enable_liboffloadmic=no
 500       ;;
 501     esac
 502 fi])
 503 AC_SUBST(extra_liboffloadmic_configure_flags)
 504
 505 # Enable libgomp by default on hosted POSIX systems, and a few others.
 506 if test x$enable_libgomp = x ; then
 507     case "${target}" in
 508     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 509         ;;
 510     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 511         ;;
 512     *-*-solaris2* | *-*-hpux11*)
 513         ;;
 514     *-*-darwin* | *-*-aix*)
 515         ;;
 516     nvptx*-*-*)
 517         ;;
 518     *)
 519         noconfigdirs="$noconfigdirs target-libgomp"
 520         ;;
 521     esac
 522 fi
 523
 524 # Disable libatomic on unsupported systems.
 525 if test -d ${srcdir}/libatomic; then
 526     if test x$enable_libatomic = x; then
 527         AC_MSG_CHECKING([for libatomic support])
 528         if (srcdir=${srcdir}/libatomic; \
 529                 . ${srcdir}/configure.tgt; \
 530                 test -n "$UNSUPPORTED")
 531         then
 532             AC_MSG_RESULT([no])
 533             noconfigdirs="$noconfigdirs target-libatomic"
 534         else
 535             AC_MSG_RESULT([yes])
 536         fi
 537     fi
 538 fi
 539
 540 # Disable libcilkrts on unsupported systems.
 541 if test -d ${srcdir}/libcilkrts; then
 542     if test x$enable_libcilkrts = x; then
 543         AC_MSG_CHECKING([for libcilkrts support])
 544         if (srcdir=${srcdir}/libcilkrts; \
 545                 . ${srcdir}/configure.tgt; \
 546                 test -n "$UNSUPPORTED")
 547         then
 548             AC_MSG_RESULT([no])
 549             noconfigdirs="$noconfigdirs target-libcilkrts"
 550         else
 551             AC_MSG_RESULT([yes])
 552         fi
 553     fi
 554 fi
 555
 556 # Disable liboffloadmic on unsupported systems.
 557 if test -d ${srcdir}/liboffloadmic; then
 558     if test x$enable_liboffloadmic != xno; then
 559         AC_MSG_CHECKING([for liboffloadmic support])
 560         if (srcdir=${srcdir}/liboffloadmic; \
 561                 . ${srcdir}/configure.tgt; \
 562                 test -n "$UNSUPPORTED")
 563         then
 564             AC_MSG_RESULT([no])
 565             noconfigdirs="$noconfigdirs target-liboffloadmic"
 566         else
 567             AC_MSG_RESULT([yes])
 568         fi
 569     fi
 570 fi
 571
 572 # Disable libitm on unsupported systems.
 573 if test -d ${srcdir}/libitm; then
 574     if test x$enable_libitm = x; then
 575         AC_MSG_CHECKING([for libitm support])
 576         if (srcdir=${srcdir}/libitm; \
 577                 . ${srcdir}/configure.tgt; \
 578                 test -n "$UNSUPPORTED")
 579         then
 580             AC_MSG_RESULT([no])
 581             noconfigdirs="$noconfigdirs target-libitm"
 582         else
 583             AC_MSG_RESULT([yes])
 584         fi
 585     fi
 586 fi
 587
 588 # Disable libsanitizer on unsupported systems.
 589 if test -d ${srcdir}/libsanitizer; then
 590     if test x$enable_libsanitizer = x; then
 591         AC_MSG_CHECKING([for libsanitizer support])
 592         if (srcdir=${srcdir}/libsanitizer; \
 593                 . ${srcdir}/configure.tgt; \
 594                 test -n "$UNSUPPORTED")
 595         then
 596             AC_MSG_RESULT([no])
 597             noconfigdirs="$noconfigdirs target-libsanitizer"
 598         else
 599             AC_MSG_RESULT([yes])
 600         fi
 601     fi
 602 fi
 603
 604 # Disable libvtv on unsupported systems.
 605 if test -d ${srcdir}/libvtv; then
 606     if test x$enable_libvtv = x; then
 607         AC_MSG_CHECKING([for libvtv support])
 608         if (srcdir=${srcdir}/libvtv; \
 609                 . ${srcdir}/configure.tgt; \
 610                 test "$VTV_SUPPORTED" != "yes")
 611         then
 612             AC_MSG_RESULT([no])
 613             noconfigdirs="$noconfigdirs target-libvtv"
 614         else
 615             AC_MSG_RESULT([yes])
 616         fi
 617     fi
 618 fi
 619
 620
 621 # Enable libmpx on supported systems by request.
 622 if test -d ${srcdir}/libmpx; then
 623     if test x$enable_libmpx = x; then
 624        AC_MSG_CHECKING([for libmpx support])
 625        if (srcdir=${srcdir}/libmpx; \
 626                . ${srcdir}/configure.tgt; \
 627                test "$LIBMPX_SUPPORTED" != "yes")
 628        then
 629            AC_MSG_RESULT([no])
 630            noconfigdirs="$noconfigdirs target-libmpx"
 631        else
 632            AC_MSG_RESULT([yes])
 633        fi
 634     fi
 635 fi
 636
 637 # Disable libhsail-rt on unsupported systems.
 638 if test -d ${srcdir}/libhsail-rt; then
 639     if test x$enable_libhsail_rt = x; then
 640         AC_MSG_CHECKING([for libhsail-rt support])
 641         if (srcdir=${srcdir}/libhsail-rt; \
 642                 . ${srcdir}/configure.tgt; \
 643                 test -n "$UNSUPPORTED")
 644         then
 645             AC_MSG_RESULT([no])
 646             unsupported_languages="$unsupported_languages brig"
 647             # This implicitly disables also target-libhsail-rt as it won't
 648             # get added to the build without BRIG FE.
 649         else
 650             AC_MSG_RESULT([yes])
 651         fi
 652     fi
 653 fi
 654
 655
 656 # Disable libquadmath for some systems.
 657 case "${target}" in
 658   avr-*-*)
 659     noconfigdirs="$noconfigdirs target-libquadmath"
 660     ;;
 661   # libquadmath is unused on AIX and libquadmath build process use of
 662   # LD_LIBRARY_PATH can break AIX bootstrap.
 663   powerpc-*-aix* | rs6000-*-aix*)
 664     noconfigdirs="$noconfigdirs target-libquadmath"
 665     ;;
 666 esac
 667
 668 # Disable libssp for some systems.
 669 case "${target}" in
 670   avr-*-*)
 671     # No hosted I/O support.
 672     noconfigdirs="$noconfigdirs target-libssp"
 673     ;;
 674   powerpc-*-aix* | rs6000-*-aix*)
 675     noconfigdirs="$noconfigdirs target-libssp"
 676     ;;
 677   rl78-*-*)
 678     # libssp uses a misaligned load to trigger a fault, but the RL78
 679     # doesn't fault for those - instead, it gives a build-time error
 680     # for explicit misaligned loads.
 681     noconfigdirs="$noconfigdirs target-libssp"
 682     ;;
 683   visium-*-*)
 684     # No hosted I/O support.
 685     noconfigdirs="$noconfigdirs target-libssp"
 686     ;;
 687 esac
 688
 689 # Disable libstdc++-v3 for some systems.
 690 # Allow user to override this if they pass --enable-libstdc++-v3
 691 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 692   case "${target}" in
 693     *-*-vxworks*)
 694       # VxWorks uses the Dinkumware C++ library.
 695       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 696       ;;
 697     arm*-wince-pe*)
 698       # the C++ libraries don't build on top of CE's C libraries
 699       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 700       ;;
 701     avr-*-*)
 702       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 703       ;;
 704     ft32-*-*)
 705       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 706       ;;
 707   esac
 708 fi
 709
 710 # Disable Fortran for some systems.
 711 case "${target}" in
 712   mmix-*-*)
 713     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 714     unsupported_languages="$unsupported_languages fortran"
 715     ;;
 716 esac
 717
 718 # Disable libffi for some systems.
 719 case "${target}" in
 720   powerpc-*-darwin*)
 721     ;;
 722   i[[3456789]]86-*-darwin*)
 723     ;;
 724   x86_64-*-darwin[[912]]*)
 725     ;;
 726   *-*-darwin*)
 727     noconfigdirs="$noconfigdirs target-libffi"
 728     ;;
 729   *-*-netware*)
 730     noconfigdirs="$noconfigdirs target-libffi"
 731     ;;
 732   *-*-phoenix*)
 733     noconfigdirs="$noconfigdirs target-libffi"
 734     ;;
 735   *-*-rtems*)
 736     noconfigdirs="$noconfigdirs target-libffi"
 737     ;;
 738   *-*-tpf*)
 739     noconfigdirs="$noconfigdirs target-libffi"
 740     ;;
 741   *-*-uclinux*)
 742     noconfigdirs="$noconfigdirs target-libffi"
 743     ;;
 744   *-*-vxworks*)
 745     noconfigdirs="$noconfigdirs target-libffi"
 746     ;;
 747   aarch64*-*-freebsd*)
 748     noconfigdirs="$noconfigdirs target-libffi"
 749     ;;
 750   alpha*-*-*vms*)
 751     noconfigdirs="$noconfigdirs target-libffi"
 752     ;;
 753   arm*-*-freebsd*)
 754     noconfigdirs="$noconfigdirs target-libffi"
 755     ;;
 756   arm-wince-pe)
 757     noconfigdirs="$noconfigdirs target-libffi"
 758     ;;
 759   arm*-*-symbianelf*)
 760     noconfigdirs="$noconfigdirs target-libffi"
 761     ;;
 762   cris-*-* | crisv32-*-*)
 763     case "${target}" in
 764       *-*-linux*)
 765         ;;
 766       *) # See PR46792 regarding target-libffi.
 767         noconfigdirs="$noconfigdirs target-libffi";;
 768     esac
 769     ;;
 770   hppa*64*-*-hpux*)
 771     noconfigdirs="$noconfigdirs target-libffi"
 772     ;;
 773   hppa*-hp-hpux11*)
 774     ;;
 775   hppa*-*-hpux*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   ia64*-*-*vms*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   i[[3456789]]86-w64-mingw*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   i[[3456789]]86-*-mingw*)
 785     noconfigdirs="$noconfigdirs target-libffi"
 786     ;;
 787   x86_64-*-mingw*)
 788     noconfigdirs="$noconfigdirs target-libffi"
 789     ;;
 790   mmix-*-*)
 791     noconfigdirs="$noconfigdirs target-libffi"
 792     ;;
 793   powerpc-*-aix*)
 794     # copied from rs6000-*-* entry
 795     noconfigdirs="$noconfigdirs target-libffi"
 796     ;;
 797   rs6000-*-aix*)
 798     noconfigdirs="$noconfigdirs target-libffi"
 799     ;;
 800   ft32-*-*)
 801     noconfigdirs="$noconfigdirs target-libffi"
 802     ;;
 803   *-*-lynxos*)
 804     noconfigdirs="$noconfigdirs target-libffi"
 805     ;;
 806 esac
 807
 808 # Disable the go frontend on systems where it is known to not work. Please keep
 809 # this in sync with contrib/config-list.mk.
 810 case "${target}" in
 811 *-*-darwin* | *-*-cygwin* | *-*-mingw* | *-*-aix*)
 812     unsupported_languages="$unsupported_languages go"
 813     ;;
 814 esac
 815
 816 # Disable libgo for some systems where it is known to not work.
 817 # For testing, you can easily override this with --enable-libgo.
 818 if test x$enable_libgo = x; then
 819     case "${target}" in
 820     *-*-darwin*)
 821         # PR 46986
 822         noconfigdirs="$noconfigdirs target-libgo"
 823         ;;
 824     *-*-cygwin* | *-*-mingw*)
 825         noconfigdirs="$noconfigdirs target-libgo"
 826         ;;
 827     *-*-aix*)
 828         noconfigdirs="$noconfigdirs target-libgo"
 829         ;;
 830     esac
 831 fi
 832
 833 # Default libgloss CPU subdirectory.
 834 libgloss_dir="$target_cpu"
 835
 836 case "${target}" in
 837   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 838     libgloss_dir=wince
 839     ;;
 840   aarch64*-*-* )
 841     libgloss_dir=aarch64
 842     ;;
 843   arm*-*-*)
 844     libgloss_dir=arm
 845     ;;
 846   cris-*-* | crisv32-*-*)
 847     libgloss_dir=cris
 848     ;;
 849   hppa*-*-*)
 850     libgloss_dir=pa
 851     ;;
 852   i[[3456789]]86-*-*)
 853     libgloss_dir=i386
 854     ;;
 855   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 856     libgloss_dir=m68hc11
 857     ;;
 858   m68*-*-* | fido-*-*)
 859     libgloss_dir=m68k
 860     ;;
 861   mips*-*-*)
 862     libgloss_dir=mips
 863     ;;
 864   powerpc*-*-*)
 865     libgloss_dir=rs6000
 866     ;;
 867   sparc*-*-*)
 868     libgloss_dir=sparc
 869     ;;
 870 esac
 871
 872 # Disable newlib and libgloss for various target OSes.
 873 case "${target}" in
 874   alpha*-dec-osf*)
 875     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 876     ;;
 877   i[[3456789]]86-*-linux*)
 878     # This section makes it possible to build newlib natively on linux.
 879     # If we are using a cross compiler then don't configure newlib.
 880     if test x${is_cross_compiler} != xno ; then
 881       noconfigdirs="$noconfigdirs target-newlib"
 882     fi
 883     noconfigdirs="$noconfigdirs target-libgloss"
 884     # If we are not using a cross compiler, do configure newlib.
 885     # Note however, that newlib will only be configured in this situation
 886     # if the --with-newlib option has been given, because otherwise
 887     # 'target-newlib' will appear in skipdirs.
 888     ;;
 889   i[[3456789]]86-*-rdos*)
 890     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 891     ;;
 892   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 893     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 894     ;;
 895   sparc-*-sunos4*)
 896     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 897     ;;
 898   *-*-aix*)
 899     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 900     ;;
 901   *-*-beos*)
 902     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 903     ;;
 904   *-*-chorusos)
 905     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 906     ;;
 907   *-*-dragonfly*)
 908     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 909     ;;
 910   *-*-freebsd*)
 911     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 912     ;;
 913   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 914     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 915     ;;
 916   *-*-lynxos*)
 917     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 918     ;;
 919   *-*-mingw*)
 920     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 921     ;;
 922   *-*-netbsd*)
 923     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 924     ;;
 925   *-*-netware*)
 926     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 927     ;;
 928   *-*-tpf*)
 929     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 930     ;;
 931   *-*-uclinux*)
 932     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 933     ;;
 934   *-*-vxworks*)
 935     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 936     ;;
 937 esac
 938
 939 case "${target}" in
 940   *-*-chorusos)
 941     ;;
 942   aarch64-*-darwin*)
 943     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 944     noconfigdirs="$noconfigdirs sim target-rda"
 945     ;;
 946   arm-*-darwin*)
 947     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 948     noconfigdirs="$noconfigdirs sim target-rda"
 949     ;;
 950   powerpc-*-darwin*)
 951     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 952     noconfigdirs="$noconfigdirs sim target-rda"
 953     ;;
 954   i[[3456789]]86-*-darwin*)
 955     noconfigdirs="$noconfigdirs ld gprof"
 956     noconfigdirs="$noconfigdirs sim target-rda"
 957     ;;
 958   x86_64-*-darwin[[912]]*)
 959     noconfigdirs="$noconfigdirs ld gas gprof"
 960     noconfigdirs="$noconfigdirs sim target-rda"
 961     ;;
 962   *-*-darwin*)
 963     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 964     noconfigdirs="$noconfigdirs sim target-rda"
 965     ;;
 966   *-*-dragonfly*)
 967     ;;
 968   *-*-freebsd*)
 969     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 970         && test -f /usr/local/include/gmp.h; then
 971       with_gmp=/usr/local
 972     fi
 973     ;;
 974   *-*-kaos*)
 975     # Remove unsupported stuff on all kaOS configurations.
 976     noconfigdirs="$noconfigdirs target-libgloss"
 977     ;;
 978   *-*-netbsd*)
 979     ;;
 980   *-*-netware*)
 981     ;;
 982   *-*-phoenix*)
 983     noconfigdirs="$noconfigdirs target-libgloss"
 984     ;;
 985   *-*-rtems*)
 986     noconfigdirs="$noconfigdirs target-libgloss"
 987     # this is not caught below because this stanza matches earlier
 988     case $target in
 989       or1k*-*-*) noconfigdirs="$noconfigdirs gdb" ;;
 990     esac
 991     ;;
 992     # The tpf target doesn't support gdb yet.
 993   *-*-tpf*)
 994     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 995     ;;
 996   *-*-uclinux*)
 997     noconfigdirs="$noconfigdirs target-rda"
 998     ;;
 999   *-*-vxworks*)
1000     ;;
1001   alpha*-dec-osf*)
1002     # ld works, but does not support shared libraries.
1003     # gas doesn't generate exception information.
1004     noconfigdirs="$noconfigdirs gas ld"
1005     ;;
1006   alpha*-*-*vms*)
1007     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1008     ;;
1009   alpha*-*-*)
1010     # newlib is not 64 bit ready
1011     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1012     ;;
1013   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1014     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1015     ;;
1016   arc*-*-*)
1017     noconfigdirs="$noconfigdirs sim"
1018     ;;
1019   arm-*-pe*)
1020     noconfigdirs="$noconfigdirs target-libgloss"
1021     ;;
1022   arm-*-riscix*)
1023     noconfigdirs="$noconfigdirs ld target-libgloss"
1024     ;;
1025   avr-*-*)
1026     if test x${with_avrlibc} != xno; then
1027       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1028     fi
1029     ;;
1030   c4x-*-* | tic4x-*-*)
1031     noconfigdirs="$noconfigdirs target-libgloss"
1032     ;;
1033   tic54x-*-*)
1034     noconfigdirs="$noconfigdirs target-libgloss gdb"
1035     ;;
1036   d10v-*-*)
1037     noconfigdirs="$noconfigdirs target-libgloss"
1038     ;;
1039   d30v-*-*)
1040     noconfigdirs="$noconfigdirs gdb"
1041     ;;
1042   fr30-*-elf*)
1043     noconfigdirs="$noconfigdirs gdb"
1044     ;;
1045   ft32-*-*)
1046     noconfigdirs="$noconfigdirs target-rda gprof"
1047     ;;
1048   moxie-*-*)
1049     noconfigdirs="$noconfigdirs"
1050     ;;
1051   h8300*-*-*)
1052     noconfigdirs="$noconfigdirs target-libgloss"
1053     ;;
1054   h8500-*-*)
1055     noconfigdirs="$noconfigdirs target-libgloss"
1056     ;;
1057   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1058     ;;
1059   hppa*64*-*-hpux*)
1060     noconfigdirs="$noconfigdirs gdb"
1061     ;;
1062   hppa*-*-hpux11*)
1063     noconfigdirs="$noconfigdirs gdb ld"
1064     ;;
1065   hppa*64*-*-linux*)
1066     ;;
1067   hppa*-*-linux*)
1068     ;;
1069   hppa*-*-*elf* | \
1070   hppa*-*-lites* | \
1071   hppa*-*-openbsd* | \
1072   hppa*64*-*-*)
1073     ;;
1074   hppa*-*-pro*)
1075     ;;
1076   hppa*-*-*)
1077     noconfigdirs="$noconfigdirs ld"
1078     ;;
1079   i960-*-*)
1080     noconfigdirs="$noconfigdirs gdb"
1081     ;;
1082   ia64*-*-elf*)
1083     # No gdb support yet.
1084     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1085     ;;
1086   ia64*-**-hpux*)
1087     # No ld support yet.
1088     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1089     ;;
1090   ia64*-*-*vms*)
1091     # No ld support yet.
1092     noconfigdirs="$noconfigdirs libgui itcl ld"
1093     ;;
1094   i[[3456789]]86-w64-mingw*)
1095     ;;
1096   i[[3456789]]86-*-mingw*)
1097     target_configdirs="$target_configdirs target-winsup"
1098     ;;
1099   *-*-cygwin*)
1100     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1101     noconfigdirs="$noconfigdirs target-libgloss"
1102     # always build newlib if winsup directory is present.
1103     if test -d "$srcdir/winsup/cygwin"; then
1104       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1105     elif test -d "$srcdir/newlib"; then
1106       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1107     fi
1108     ;;
1109   i[[3456789]]86-*-pe)
1110     noconfigdirs="$noconfigdirs target-libgloss"
1111     ;;
1112   i[[3456789]]86-*-sco3.2v5*)
1113     # The linker does not yet know about weak symbols in COFF,
1114     # and is not configured to handle mixed ELF and COFF.
1115     noconfigdirs="$noconfigdirs ld target-libgloss"
1116     ;;
1117   i[[3456789]]86-*-sco*)
1118     noconfigdirs="$noconfigdirs gprof target-libgloss"
1119     ;;
1120   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1121     noconfigdirs="$noconfigdirs target-libgloss"
1122     ;;
1123   i[[3456789]]86-*-sysv4*)
1124     noconfigdirs="$noconfigdirs target-libgloss"
1125     ;;
1126   i[[3456789]]86-*-beos*)
1127     noconfigdirs="$noconfigdirs gdb"
1128     ;;
1129   i[[3456789]]86-*-rdos*)
1130     noconfigdirs="$noconfigdirs gdb"
1131     ;;
1132   mmix-*-*)
1133     noconfigdirs="$noconfigdirs gdb"
1134     ;;
1135   mt-*-*)
1136     noconfigdirs="$noconfigdirs sim"
1137     ;;
1138   powerpc-*-aix*)
1139     # copied from rs6000-*-* entry
1140     noconfigdirs="$noconfigdirs gprof"
1141     ;;
1142   powerpc*-*-winnt* | powerpc*-*-pe*)
1143     target_configdirs="$target_configdirs target-winsup"
1144     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1145     # always build newlib.
1146     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1147     ;;
1148     # This is temporary until we can link against shared libraries
1149   powerpcle-*-solaris*)
1150     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1151     ;;
1152   powerpc-*-beos*)
1153     noconfigdirs="$noconfigdirs gdb"
1154     ;;
1155   rs6000-*-lynxos*)
1156     noconfigdirs="$noconfigdirs gprof"
1157     ;;
1158   rs6000-*-aix*)
1159     noconfigdirs="$noconfigdirs gprof"
1160     ;;
1161   rs6000-*-*)
1162     noconfigdirs="$noconfigdirs gprof"
1163     ;;
1164   m68k-apollo-*)
1165     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1166     ;;
1167   microblaze*)
1168     noconfigdirs="$noconfigdirs gprof"
1169     ;;
1170   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1171     if test x$with_newlib = xyes; then
1172       noconfigdirs="$noconfigdirs gprof"
1173     fi
1174     ;;
1175   mips*-*-irix5*)
1176     noconfigdirs="$noconfigdirs gprof target-libgloss"
1177     ;;
1178   mips*-*-irix6*)
1179     noconfigdirs="$noconfigdirs gprof target-libgloss"
1180     ;;
1181   mips*-*-bsd*)
1182     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1183     ;;
1184   mips*-*-linux*)
1185     ;;
1186   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1187   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1188     noconfigdirs="$noconfigdirs ld gas gprof"
1189     ;;
1190   mips*-*-*)
1191     noconfigdirs="$noconfigdirs gprof"
1192     ;;
1193   nvptx*-*-*)
1194     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1195     ;;
1196   or1k*-*-*)
1197     noconfigdirs="$noconfigdirs gdb"
1198     ;;
1199   sh-*-*)
1200     case "${target}" in
1201       sh*-*-elf)
1202          ;;
1203       *)
1204          noconfigdirs="$noconfigdirs target-libgloss" ;;
1205     esac
1206     ;;
1207   sparc-*-sunos4*)
1208     if test x${is_cross_compiler} = xno ; then
1209            use_gnu_ld=no
1210     fi
1211     ;;
1212   tic6x-*-*)
1213     noconfigdirs="$noconfigdirs sim"
1214     ;;
1215   tilepro*-*-* | tilegx*-*-*)
1216     noconfigdirs="$noconfigdirs sim"
1217     ;;
1218   v810-*-*)
1219     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1220     ;;
1221   vax-*-*)
1222     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1223     ;;
1224 esac
1225
1226 # If we aren't building newlib, then don't build libgloss, since libgloss
1227 # depends upon some newlib header files.
1228 case "${noconfigdirs}" in
1229   *target-libgloss*) ;;
1230   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1231 esac
1232
1233 # Work in distributions that contain no compiler tools, like Autoconf.
1234 host_makefile_frag=/dev/null
1235 if test -d ${srcdir}/config ; then
1236 case "${host}" in
1237   i[[3456789]]86-*-msdosdjgpp*)
1238     host_makefile_frag="config/mh-djgpp"
1239     ;;
1240   *-cygwin*)
1241     ACX_CHECK_CYGWIN_CAT_WORKS
1242     host_makefile_frag="config/mh-cygwin"
1243     ;;
1244   *-mingw*)
1245     host_makefile_frag="config/mh-mingw"
1246     ;;
1247   alpha*-linux*)
1248     host_makefile_frag="config/mh-alpha-linux"
1249     ;;
1250   hppa*-hp-hpux10*)
1251     host_makefile_frag="config/mh-pa-hpux10"
1252     ;;
1253   hppa*-hp-hpux*)
1254     host_makefile_frag="config/mh-pa"
1255     ;;
1256   hppa*-*)
1257     host_makefile_frag="config/mh-pa"
1258     ;;
1259   *-*-darwin*)
1260     host_makefile_frag="config/mh-darwin"
1261     ;;
1262   powerpc-*-aix*)
1263     host_makefile_frag="config/mh-ppc-aix"
1264     ;;
1265   rs6000-*-aix*)
1266     host_makefile_frag="config/mh-ppc-aix"
1267     ;;
1268 esac
1269 fi
1270
1271 if test "${build}" != "${host}" ; then
1272   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1273   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1274   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1275   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1276   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1277   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1278   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1279   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1280   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1281   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1282   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1283   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1284 else
1285   AR_FOR_BUILD="\$(AR)"
1286   AS_FOR_BUILD="\$(AS)"
1287   CC_FOR_BUILD="\$(CC)"
1288   CXX_FOR_BUILD="\$(CXX)"
1289   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1290   GOC_FOR_BUILD="\$(GOC)"
1291   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1292   LD_FOR_BUILD="\$(LD)"
1293   NM_FOR_BUILD="\$(NM)"
1294   RANLIB_FOR_BUILD="\$(RANLIB)"
1295   WINDRES_FOR_BUILD="\$(WINDRES)"
1296   WINDMC_FOR_BUILD="\$(WINDMC)"
1297 fi
1298
1299 AC_PROG_CC
1300 AC_PROG_CXX
1301
1302 # We must set the default linker to the linker used by gcc for the correct
1303 # operation of libtool.  If LD is not defined and we are using gcc, try to
1304 # set the LD default to the ld used by gcc.
1305 if test -z "$LD"; then
1306   if test "$GCC" = yes; then
1307     case $build in
1308     *-*-mingw*)
1309       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1310     *)
1311       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1312     esac
1313     case $gcc_prog_ld in
1314     # Accept absolute paths.
1315     [[\\/]* | [A-Za-z]:[\\/]*)]
1316       LD="$gcc_prog_ld" ;;
1317     esac
1318   fi
1319 fi
1320
1321 # Check whether -static-libstdc++ -static-libgcc is supported.
1322 have_static_libs=no
1323 if test "$GCC" = yes; then
1324   saved_LDFLAGS="$LDFLAGS"
1325
1326   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1327   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1328   AC_LANG_PUSH(C++)
1329   AC_LINK_IFELSE([
1330 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1331 #error -static-libstdc++ not implemented
1332 #endif
1333 int main() {}],
1334     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1335     [AC_MSG_RESULT([no])])
1336   AC_LANG_POP(C++)
1337
1338   LDFLAGS="$saved_LDFLAGS"
1339 fi
1340
1341 ACX_PROG_GNAT
1342 ACX_PROG_CMP_IGNORE_INITIAL
1343
1344 AC_ARG_ENABLE([bootstrap],
1345 [AS_HELP_STRING([--enable-bootstrap],
1346                 [enable bootstrapping @<:@yes if native build@:>@])],,
1347 enable_bootstrap=default)
1348
1349 # Issue errors and warnings for invalid/strange bootstrap combinations.
1350 if test -r $srcdir/gcc/configure; then
1351   have_compiler=yes
1352 else
1353   have_compiler=no
1354 fi
1355
1356 case "$have_compiler:$host:$target:$enable_bootstrap" in
1357   *:*:*:no) ;;
1358
1359   # Default behavior.  Enable bootstrap if we have a compiler
1360   # and we are in a native configuration.
1361   yes:$build:$build:default)
1362     enable_bootstrap=yes ;;
1363
1364   *:*:*:default)
1365     enable_bootstrap=no ;;
1366
1367   # We have a compiler and we are in a native configuration, bootstrap is ok
1368   yes:$build:$build:yes)
1369     ;;
1370
1371   # Other configurations, but we have a compiler.  Assume the user knows
1372   # what he's doing.
1373   yes:*:*:yes)
1374     AC_MSG_WARN([trying to bootstrap a cross compiler])
1375     ;;
1376
1377   # No compiler: if they passed --enable-bootstrap explicitly, fail
1378   no:*:*:yes)
1379     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1380
1381   # Fail if wrong command line
1382   *)
1383     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1384     ;;
1385 esac
1386
1387 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1388 # C++98 compiler can still start the bootstrap.
1389 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1390   CXX="$CXX -std=gnu++98"
1391 fi
1392
1393 # Used for setting $lt_cv_objdir
1394 _LT_CHECK_OBJDIR
1395
1396 # Check for GMP, MPFR and MPC
1397 gmplibs="-lmpc -lmpfr -lgmp"
1398 gmpinc=
1399 have_gmp=no
1400
1401 # Specify a location for mpc
1402 # check for this first so it ends up on the link line before mpfr.
1403 AC_ARG_WITH(mpc,
1404 [AS_HELP_STRING([--with-mpc=PATH],
1405                 [specify prefix directory for installed MPC package.
1406                  Equivalent to --with-mpc-include=PATH/include
1407                  plus --with-mpc-lib=PATH/lib])])
1408 AC_ARG_WITH(mpc-include,
1409 [AS_HELP_STRING([--with-mpc-include=PATH],
1410                 [specify directory for installed MPC include files])])
1411 AC_ARG_WITH(mpc-lib,
1412 [AS_HELP_STRING([--with-mpc-lib=PATH],
1413                 [specify directory for the installed MPC library])])
1414
1415 if test "x$with_mpc" != x; then
1416   gmplibs="-L$with_mpc/lib $gmplibs"
1417   gmpinc="-I$with_mpc/include $gmpinc"
1418 fi
1419 if test "x$with_mpc_include" != x; then
1420   gmpinc="-I$with_mpc_include $gmpinc"
1421 fi
1422 if test "x$with_mpc_lib" != x; then
1423   gmplibs="-L$with_mpc_lib $gmplibs"
1424 fi
1425 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1426   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1427   gmpinc='-I$$s/mpc/src '"$gmpinc"
1428   # Do not test the mpc version.  Assume that it is sufficient, since
1429   # it is in the source tree, and the library has not been built yet
1430   # but it would be included on the link line in the version check below
1431   # hence making the test fail.
1432   have_gmp=yes
1433 fi
1434
1435 # Specify a location for mpfr
1436 # check for this first so it ends up on the link line before gmp.
1437 AC_ARG_WITH(mpfr-dir,
1438 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1439 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1440 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1441
1442 AC_ARG_WITH(mpfr,
1443 [AS_HELP_STRING([--with-mpfr=PATH],
1444                 [specify prefix directory for installed MPFR package.
1445                  Equivalent to --with-mpfr-include=PATH/include
1446                  plus --with-mpfr-lib=PATH/lib])])
1447 AC_ARG_WITH(mpfr-include,
1448 [AS_HELP_STRING([--with-mpfr-include=PATH],
1449                 [specify directory for installed MPFR include files])])
1450 AC_ARG_WITH(mpfr-lib,
1451 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1452                 [specify directory for the installed MPFR library])])
1453
1454 if test "x$with_mpfr" != x; then
1455   gmplibs="-L$with_mpfr/lib $gmplibs"
1456   gmpinc="-I$with_mpfr/include $gmpinc"
1457 fi
1458 if test "x$with_mpfr_include" != x; then
1459   gmpinc="-I$with_mpfr_include $gmpinc"
1460 fi
1461 if test "x$with_mpfr_lib" != x; then
1462   gmplibs="-L$with_mpfr_lib $gmplibs"
1463 fi
1464 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1465   # MPFR v3.1.0 moved the sources into a src sub-directory.
1466   if ! test -d ${srcdir}/mpfr/src; then
1467     AC_MSG_ERROR([dnl
1468 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1469   fi
1470   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1471   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1472   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1473   # Do not test the mpfr version.  Assume that it is sufficient, since
1474   # it is in the source tree, and the library has not been built yet
1475   # but it would be included on the link line in the version check below
1476   # hence making the test fail.
1477   have_gmp=yes
1478 fi
1479
1480 # Specify a location for gmp
1481 AC_ARG_WITH(gmp-dir,
1482 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1483 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1484 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1485
1486 AC_ARG_WITH(gmp,
1487 [AS_HELP_STRING([--with-gmp=PATH],
1488                 [specify prefix directory for the installed GMP package.
1489                  Equivalent to --with-gmp-include=PATH/include
1490                  plus --with-gmp-lib=PATH/lib])])
1491 AC_ARG_WITH(gmp-include,
1492 [AS_HELP_STRING([--with-gmp-include=PATH],
1493                 [specify directory for installed GMP include files])])
1494 AC_ARG_WITH(gmp-lib,
1495 [AS_HELP_STRING([--with-gmp-lib=PATH],
1496                 [specify directory for the installed GMP library])])
1497
1498
1499 if test "x$with_gmp" != x; then
1500   gmplibs="-L$with_gmp/lib $gmplibs"
1501   gmpinc="-I$with_gmp/include $gmpinc"
1502 fi
1503 if test "x$with_gmp_include" != x; then
1504   gmpinc="-I$with_gmp_include $gmpinc"
1505 fi
1506 if test "x$with_gmp_lib" != x; then
1507   gmplibs="-L$with_gmp_lib $gmplibs"
1508 fi
1509 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1510   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1511   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1512   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1513   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1514   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1515   # Do not test the gmp version.  Assume that it is sufficient, since
1516   # it is in the source tree, and the library has not been built yet
1517   # but it would be included on the link line in the version check below
1518   # hence making the test fail.
1519   have_gmp=yes
1520 fi
1521
1522 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1523   have_gmp=yes
1524   saved_CFLAGS="$CFLAGS"
1525   CFLAGS="$CFLAGS $gmpinc"
1526   # Check for the recommended and required versions of GMP.
1527   AC_MSG_CHECKING([for the correct version of gmp.h])
1528   AC_TRY_COMPILE([#include "gmp.h"],[
1529   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1530   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1531   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1532   choke me
1533   #endif
1534   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1535   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1536   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1537   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1538   choke me
1539   #endif
1540   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1541    [AC_MSG_RESULT([no]); have_gmp=no])
1542
1543   # If we have GMP, check the MPFR version.
1544   if test x"$have_gmp" = xyes; then
1545     # Check for the recommended and required versions of MPFR.
1546     AC_MSG_CHECKING([for the correct version of mpfr.h])
1547     AC_TRY_COMPILE([#include <gmp.h>
1548     #include <mpfr.h>],[
1549     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1550     choke me
1551     #endif
1552     ], [AC_TRY_COMPILE([#include <gmp.h>
1553     #include <mpfr.h>],[
1554     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1555     choke me
1556     #endif
1557     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1558      [AC_MSG_RESULT([no]); have_gmp=no])
1559   fi
1560
1561   # Check for the MPC header version.
1562   if test x"$have_gmp" = xyes ; then
1563     # Check for the recommended and required versions of MPC.
1564     AC_MSG_CHECKING([for the correct version of mpc.h])
1565     AC_TRY_COMPILE([#include <mpc.h>],[
1566     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1567     choke me
1568     #endif
1569     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1570     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1571     choke me
1572     #endif
1573     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1574      [AC_MSG_RESULT([no]); have_gmp=no])
1575   fi
1576
1577   # Now check the MPFR library.
1578   if test x"$have_gmp" = xyes; then
1579     saved_LIBS="$LIBS"
1580     LIBS="$LIBS $gmplibs"
1581     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1582     AC_TRY_LINK([#include <mpc.h>],[
1583     mpfr_t n;
1584     mpfr_t x;
1585     mpc_t c;
1586     int t;
1587     mpfr_init (n);
1588     mpfr_init (x);
1589     mpfr_atan2 (n, n, x, GMP_RNDN);
1590     mpfr_erfc (n, x, GMP_RNDN);
1591     mpfr_subnormalize (x, t, GMP_RNDN);
1592     mpfr_clear(n);
1593     mpfr_clear(x);
1594     mpc_init2 (c, 53);
1595     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1596     mpc_cosh (c, c, MPC_RNDNN);
1597     mpc_pow (c, c, c, MPC_RNDNN);
1598     mpc_acosh (c, c, MPC_RNDNN);
1599     mpc_clear (c);
1600     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1601     LIBS="$saved_LIBS"
1602   fi
1603
1604   CFLAGS="$saved_CFLAGS"
1605
1606 # The library versions listed in the error message below should match
1607 # the HARD-minimums enforced above.
1608   if test x$have_gmp != xyes; then
1609     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1610 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1611 their locations.  Source code for these libraries can be found at
1612 their respective hosting sites as well as at
1613 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1614 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1615 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1616 make sure that you have installed both the libraries and the header
1617 files.  They may be located in separate packages.])
1618   fi
1619 fi
1620
1621 # Flags needed for both GMP, MPFR and/or MPC.
1622 AC_SUBST(gmplibs)
1623 AC_SUBST(gmpinc)
1624 AC_SUBST(extra_mpfr_configure_flags)
1625 AC_SUBST(extra_mpc_gmp_configure_flags)
1626 AC_SUBST(extra_mpc_mpfr_configure_flags)
1627 AC_SUBST(extra_isl_gmp_configure_flags)
1628
1629 # Libraries to use for stage1 or when not bootstrapping.
1630 AC_ARG_WITH(stage1-libs,
1631 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1632 [if test "$withval" = "no" -o "$withval" = "yes"; then
1633    stage1_libs=
1634  else
1635    stage1_libs=$withval
1636  fi],
1637 [stage1_libs=])
1638 AC_SUBST(stage1_libs)
1639
1640 # Linker flags to use for stage1 or when not bootstrapping.
1641 AC_ARG_WITH(stage1-ldflags,
1642 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1643 [if test "$withval" = "no" -o "$withval" = "yes"; then
1644    stage1_ldflags=
1645  else
1646    stage1_ldflags=$withval
1647  fi],
1648 [stage1_ldflags=
1649  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1650  # if supported.  But if the user explicitly specified the libraries to use,
1651  # trust that they are doing what they want.
1652  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1653    stage1_ldflags="-static-libstdc++ -static-libgcc"
1654  fi])
1655 AC_SUBST(stage1_ldflags)
1656
1657 # Libraries to use for stage2 and later builds.
1658 AC_ARG_WITH(boot-libs,
1659 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1660 [if test "$withval" = "no" -o "$withval" = "yes"; then
1661    poststage1_libs=
1662  else
1663    poststage1_libs=$withval
1664  fi],
1665 [poststage1_libs=])
1666 AC_SUBST(poststage1_libs)
1667
1668 # Linker flags to use for stage2 and later builds.
1669 AC_ARG_WITH(boot-ldflags,
1670 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1671                 [linker flags for stage2 and later])],
1672 [if test "$withval" = "no" -o "$withval" = "yes"; then
1673    poststage1_ldflags=
1674  else
1675    poststage1_ldflags=$withval
1676  fi],
1677 [poststage1_ldflags=
1678  # In stages 2 and 3, default to linking libstdc++ and libgcc
1679  # statically.  But if the user explicitly specified the libraries to
1680  # use, trust that they are doing what they want.
1681  if test "$poststage1_libs" = ""; then
1682    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1683  fi])
1684 AC_SUBST(poststage1_ldflags)
1685
1686 # GCC GRAPHITE dependency isl.
1687 # Basic setup is inlined here, actual checks are in config/isl.m4
1688
1689 AC_ARG_WITH(isl,
1690   [AS_HELP_STRING(
1691    [--with-isl=PATH],
1692    [Specify prefix directory for the installed isl package.
1693     Equivalent to --with-isl-include=PATH/include
1694     plus --with-isl-lib=PATH/lib])])
1695
1696 # Treat --without-isl as a request to disable
1697 # GRAPHITE support and skip all following checks.
1698 if test "x$with_isl" != "xno"; then
1699   # Check for isl
1700   dnl Provide configure switches and initialize islinc & isllibs
1701   dnl with user input.
1702   ISL_INIT_FLAGS
1703   dnl The versions of isl that work for Graphite
1704   ISL_CHECK_VERSION()
1705   dnl Only execute fail-action, if isl has been requested.
1706   ISL_IF_FAILED([
1707     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1708 fi
1709
1710 # If the isl check failed, disable builds of in-tree variant of isl
1711 if test "x$with_isl" = xno ||
1712    test "x$gcc_cv_isl" = xno; then
1713   noconfigdirs="$noconfigdirs isl"
1714   islinc=
1715 fi
1716
1717 AC_SUBST(isllibs)
1718 AC_SUBST(islinc)
1719
1720 # Check for LTO support.
1721 AC_ARG_ENABLE(lto,
1722 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1723 enable_lto=$enableval,
1724 enable_lto=yes; default_enable_lto=yes)
1725
1726 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1727   build_lto_plugin=yes
1728 ],[if test x"$default_enable_lto" = x"yes" ; then
1729     case $target in
1730       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1731       # On other non-ELF platforms, LTO has yet to be validated.
1732       *) enable_lto=no ;;
1733     esac
1734   else
1735   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1736   # It would also be nice to check the binutils support, but we don't
1737   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1738   # warn during gcc/ subconfigure; unless you're bootstrapping with
1739   # -flto it won't be needed until after installation anyway.
1740     case $target in
1741       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1742       *) if test x"$enable_lto" = x"yes"; then
1743         AC_MSG_ERROR([LTO support is not enabled for this target.])
1744         fi
1745       ;;
1746     esac
1747   fi
1748   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1749   # Build it unless LTO was explicitly disabled.
1750   case $target in
1751     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1752     *) ;;
1753   esac
1754 ])
1755
1756 AC_ARG_ENABLE(linker-plugin-configure-flags,
1757   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1758     [additional flags for configuring linker plugins @<:@none@:>@])],
1759   extra_linker_plugin_configure_flags=$enableval,
1760   extra_linker_plugin_configure_flags=)
1761 AC_SUBST(extra_linker_plugin_configure_flags)
1762 AC_ARG_ENABLE(linker-plugin-flags,
1763   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1764     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1765   extra_linker_plugin_flags=$enableval,
1766   extra_linker_plugin_flags=)
1767 AC_SUBST(extra_linker_plugin_flags)
1768
1769
1770 # By default, C and C++ are the only stage 1 languages.
1771 stage1_languages=,c,
1772
1773 # Target libraries that we bootstrap.
1774 bootstrap_target_libs=,target-libgcc,
1775
1776 # Figure out what language subdirectories are present.
1777 # Look if the user specified --enable-languages="..."; if not, use
1778 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1779 # go away some day.
1780 # NB:  embedded tabs in this IF block -- do not untabify
1781 if test -d ${srcdir}/gcc; then
1782   if test x"${enable_languages+set}" != xset; then
1783     if test x"${LANGUAGES+set}" = xset; then
1784       enable_languages="${LANGUAGES}"
1785         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1786     else
1787       enable_languages=all
1788     fi
1789   else
1790     if test x"${enable_languages}" = x ||
1791        test x"${enable_languages}" = xyes;
1792        then
1793       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1794       exit 1
1795     fi
1796   fi
1797   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1798
1799   # 'f95' is the old name for the 'fortran' language. We issue a warning
1800   # and make the substitution.
1801   case ,${enable_languages}, in
1802     *,f95,*)
1803       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1804       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1805       ;;
1806   esac
1807
1808   # If bootstrapping, C++ must be enabled.
1809   case ",$enable_languages,:$enable_bootstrap" in
1810     *,c++,*:*) ;;
1811     *:yes)
1812       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1813         enable_languages="${enable_languages},c++"
1814       else
1815         AC_MSG_ERROR([bootstrapping requires c++ sources])
1816       fi
1817       ;;
1818   esac
1819
1820   # First scan to see if an enabled language requires some other language.
1821   # We assume that a given config-lang.in will list all the language
1822   # front ends it requires, even if some are required indirectly.
1823   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1824     case ${lang_frag} in
1825       ..) ;;
1826       # The odd quoting in the next line works around
1827       # an apparent bug in bash 1.12 on linux.
1828       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1829       *)
1830         # From the config-lang.in, get $language, $lang_requires, and
1831         # $lang_requires_boot_languages.
1832         language=
1833         lang_requires=
1834         lang_requires_boot_languages=
1835         . ${lang_frag}
1836         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1837           case ,${enable_languages}, in
1838             *,$other,*) ;;
1839             *,all,*) ;;
1840             *,$language,*)
1841               echo " \`$other' language required by \`$language'; enabling" 1>&2
1842               enable_languages="${enable_languages},${other}"
1843               ;;
1844           esac
1845         done
1846         for other in ${lang_requires_boot_languages} ; do
1847           if test "$other" != "c"; then
1848             case ,${enable_stage1_languages}, in
1849               *,$other,*) ;;
1850               *,all,*) ;;
1851               *)
1852                 case ,${enable_languages}, in
1853                   *,$language,*)
1854                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1855                     enable_stage1_languages="$enable_stage1_languages,${other}"
1856                     ;;
1857                 esac
1858                 ;;
1859             esac
1860           fi
1861         done
1862         ;;
1863     esac
1864   done
1865
1866   new_enable_languages=,c,
1867
1868   # If LTO is enabled, add the LTO front end.
1869   if test "$enable_lto" = "yes" ; then
1870     case ,${enable_languages}, in
1871       *,lto,*) ;;
1872       *) enable_languages="${enable_languages},lto" ;;
1873     esac
1874     if test "${build_lto_plugin}" = "yes" ; then
1875       configdirs="$configdirs lto-plugin"
1876     fi
1877   fi
1878
1879   # If we're building an offloading compiler, add the LTO front end.
1880   if test x"$enable_as_accelerator_for" != x ; then
1881     case ,${enable_languages}, in
1882       *,lto,*) ;;
1883       *) enable_languages="${enable_languages},lto" ;;
1884     esac
1885   fi
1886
1887   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1888   potential_languages=,c,
1889
1890   enabled_target_libs=
1891   disabled_target_libs=
1892
1893   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1894     case ${lang_frag} in
1895       ..) ;;
1896       # The odd quoting in the next line works around
1897       # an apparent bug in bash 1.12 on linux.
1898       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1899       *)
1900         # From the config-lang.in, get $language, $target_libs,
1901         # $lang_dirs, $boot_language, and $build_by_default
1902         language=
1903         target_libs=
1904         lang_dirs=
1905         subdir_requires=
1906         boot_language=no
1907         build_by_default=yes
1908         . ${lang_frag}
1909         if test x${language} = x; then
1910           echo "${lang_frag} doesn't set \$language." 1>&2
1911           exit 1
1912         fi
1913
1914         if test "$language" = "c++"; then
1915           boot_language=yes
1916         fi
1917
1918         add_this_lang=no
1919         case ,${enable_languages}, in
1920           *,${language},*)
1921             # Language was explicitly selected; include it
1922             # unless it is C, which is enabled by default.
1923             if test "$language" != "c"; then
1924               add_this_lang=yes
1925             fi
1926             ;;
1927           *,all,*)
1928             # 'all' was selected, select it if it is a default language
1929             if test "$language" != "c"; then
1930               add_this_lang=${build_by_default}
1931             fi
1932             ;;
1933         esac
1934
1935         # Disable languages that need other directories if these aren't available.
1936         for i in $subdir_requires; do
1937           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1938           case ,${enable_languages}, in
1939             *,${language},*)
1940               # Specifically requested language; tell them.
1941               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1942               ;;
1943             *)
1944               # Silently disable.
1945               add_this_lang=unsupported
1946               ;;
1947           esac
1948         done
1949
1950         # Disable Ada if no preexisting GNAT is available.
1951         case ,${enable_languages},:${language}:${have_gnat} in
1952           *,${language},*:ada:no)
1953             # Specifically requested language; tell them.
1954             AC_MSG_ERROR([GNAT is required to build $language])
1955             ;;
1956           *:ada:no)
1957             # Silently disable.
1958             add_this_lang=unsupported
1959             ;;
1960         esac
1961
1962         # Disable a language that is unsupported by the target.
1963         case " $unsupported_languages " in
1964           *" $language "*)
1965             add_this_lang=unsupported
1966             ;;
1967         esac
1968
1969         case $add_this_lang in
1970           unsupported)
1971             # Remove language-dependent dirs.
1972             disabled_target_libs="$disabled_target_libs $target_libs"
1973             noconfigdirs="$noconfigdirs $lang_dirs"
1974             ;;
1975           no)
1976             # Remove language-dependent dirs; still show language as supported.
1977             disabled_target_libs="$disabled_target_libs $target_libs"
1978             noconfigdirs="$noconfigdirs $lang_dirs"
1979             potential_languages="${potential_languages}${language},"
1980             ;;
1981           yes)
1982             new_enable_languages="${new_enable_languages}${language},"
1983             potential_languages="${potential_languages}${language},"
1984             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1985             enabled_target_libs="$enabled_target_libs $target_libs"
1986             case "${boot_language}:,$enable_stage1_languages," in
1987               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1988                 # Add to (comma-separated) list of stage 1 languages.
1989                 case ",$stage1_languages," in
1990                   *,$language,* | ,yes, | ,all,) ;;
1991                   *) stage1_languages="${stage1_languages}${language}," ;;
1992                 esac
1993                 # We need to bootstrap any supporting libraries.
1994                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1995                 ;;
1996             esac
1997             ;;
1998         esac
1999         ;;
2000     esac
2001   done
2002
2003   # Add target libraries which are only needed for disabled languages
2004   # to noconfigdirs.
2005   if test -n "$disabled_target_libs"; then
2006     for dir in $disabled_target_libs; do
2007       case " $enabled_target_libs " in
2008       *" ${dir} "*) ;;
2009       *) noconfigdirs="$noconfigdirs $dir" ;;
2010       esac
2011     done
2012   fi
2013
2014   AC_ARG_ENABLE(stage1-languages,
2015   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2016                   [choose additional languages to build during
2017                   stage1.  Mostly useful for compiler development])],
2018   [case ,${enable_stage1_languages}, in
2019     ,no,|,,)
2020       # Set it to something that will have no effect in the loop below
2021       enable_stage1_languages=c ;;
2022     ,yes,)
2023       enable_stage1_languages=`echo $new_enable_languages | \
2024         sed -e "s/^,//" -e "s/,$//" ` ;;
2025     *,all,*)
2026       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2027         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2028   esac
2029
2030   # Add "good" languages from enable_stage1_languages to stage1_languages,
2031   # while "bad" languages go in missing_languages.  Leave no duplicates.
2032   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2033     case $potential_languages in
2034       *,$i,*)
2035         case $stage1_languages in
2036           *,$i,*) ;;
2037           *) stage1_languages="$stage1_languages$i," ;;
2038         esac ;;
2039       *)
2040         case $missing_languages in
2041           *,$i,*) ;;
2042           *) missing_languages="$missing_languages$i," ;;
2043         esac ;;
2044      esac
2045   done])
2046
2047   # Remove leading/trailing commas that were added for simplicity
2048   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2049   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2050   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2051   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2052
2053   if test "x$missing_languages" != x; then
2054     AC_MSG_ERROR([
2055 The following requested languages could not be built: ${missing_languages}
2056 Supported languages are: ${potential_languages}])
2057   fi
2058   if test "x$new_enable_languages" != "x$enable_languages"; then
2059     echo The following languages will be built: ${new_enable_languages}
2060     enable_languages="$new_enable_languages"
2061   fi
2062
2063   AC_SUBST(stage1_languages)
2064   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2065 fi
2066
2067 # Handle --disable-<component> generically.
2068 for dir in $configdirs $build_configdirs $target_configdirs ; do
2069   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2070   varname=`echo $dirname | sed -e s/+/_/g`
2071   if eval test x\${enable_${varname}} "=" xno ; then
2072     noconfigdirs="$noconfigdirs $dir"
2073   fi
2074 done
2075
2076 # Check for Boehm's garbage collector
2077 AC_ARG_ENABLE(objc-gc,
2078 [AS_HELP_STRING([--enable-objc-gc],
2079                 [enable use of Boehm's garbage collector with the
2080                  GNU Objective-C runtime])])
2081 AC_ARG_WITH([target-bdw-gc],
2082 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2083                 [specify prefix directory for installed bdw-gc package.
2084                  Equivalent to --with-target-bdw-gc-include=PATH/include
2085                  plus --with-target-bdw-gc-lib=PATH/lib])])
2086 AC_ARG_WITH([target-bdw-gc-include],
2087 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2088                 [specify directories for installed bdw-gc include files])])
2089 AC_ARG_WITH([target-bdw-gc-lib],
2090 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2091                 [specify directories for installed bdw-gc library])])
2092
2093 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2094   AC_MSG_CHECKING([for bdw garbage collector])
2095   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2096     dnl no bdw-gw options, assume default locations
2097     AC_MSG_RESULT([using bdw-gc in default locations])
2098   else
2099     dnl bdw-gw options, first error checking, complete checking in libobjc
2100     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2101       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2102     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2103       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2104     else
2105       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2106     fi
2107   fi
2108 esac
2109
2110 # Disable libcilkrts, libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2111 case ,${enable_languages}, in
2112   *,c++,*)
2113     # Disable libcilkrts, libitm, libsanitizer if we're not building libstdc++
2114     case "${noconfigdirs}" in
2115       *target-libstdc++-v3*)
2116         noconfigdirs="$noconfigdirs target-libcilkrts target-libitm target-libsanitizer"
2117         ;;
2118       *) ;;
2119     esac
2120     ;;
2121   *)
2122     noconfigdirs="$noconfigdirs target-libcilkrts target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2123     ;;
2124 esac
2125
2126 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2127 # $build_configdirs and $target_configdirs.
2128 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2129
2130 notsupp=""
2131 for dir in . $skipdirs $noconfigdirs ; do
2132   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2133   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2134     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2135     if test -r $srcdir/$dirname/configure ; then
2136       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2137         true
2138       else
2139         notsupp="$notsupp $dir"
2140       fi
2141     fi
2142   fi
2143   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2144     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2145     if test -r $srcdir/$dirname/configure ; then
2146       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2147         true
2148       else
2149         notsupp="$notsupp $dir"
2150       fi
2151     fi
2152   fi
2153   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2154     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2155     if test -r $srcdir/$dirname/configure ; then
2156       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2157         true
2158       else
2159         notsupp="$notsupp $dir"
2160       fi
2161     fi
2162   fi
2163 done
2164
2165 # Quietly strip out all directories which aren't configurable in this tree.
2166 # This relies on all configurable subdirectories being autoconfiscated, which
2167 # is now the case.
2168 build_configdirs_all="$build_configdirs"
2169 build_configdirs=
2170 for i in ${build_configdirs_all} ; do
2171   j=`echo $i | sed -e s/build-//g`
2172   if test -f ${srcdir}/$j/configure ; then
2173     build_configdirs="${build_configdirs} $i"
2174   fi
2175 done
2176
2177 configdirs_all="$configdirs"
2178 configdirs=
2179 for i in ${configdirs_all} ; do
2180   if test -f ${srcdir}/$i/configure ; then
2181     configdirs="${configdirs} $i"
2182   fi
2183 done
2184
2185 target_configdirs_all="$target_configdirs"
2186 target_configdirs=
2187 for i in ${target_configdirs_all} ; do
2188   j=`echo $i | sed -e s/target-//g`
2189   if test -f ${srcdir}/$j/configure ; then
2190     target_configdirs="${target_configdirs} $i"
2191   fi
2192 done
2193
2194 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2195 # so we have to add it after the preceding checks.
2196 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2197 then
2198   case " $configdirs " in
2199     *" libiberty "*)
2200       # If we can build libiberty, we can also build libiberty-linker-plugin.
2201       configdirs="$configdirs libiberty-linker-plugin"
2202       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2203         --with-libiberty=../libiberty-linker-plugin";;
2204     *)
2205       AC_MSG_ERROR([libiberty missing]);;
2206   esac
2207 fi
2208
2209 # Sometimes we have special requirements for the host libiberty.
2210 extra_host_libiberty_configure_flags=
2211 extra_host_zlib_configure_flags=
2212 case " $configdirs " in
2213   *" lto-plugin "* | *" libcc1 "*)
2214     # When these are to be built as shared libraries, the same applies to
2215     # libiberty.
2216     extra_host_libiberty_configure_flags=--enable-shared
2217     ;;
2218   *" bfd "*)
2219     # When bfd is to be built as a shared library, the same applies to
2220     # zlib.
2221     if test "$enable_shared" = "yes"; then
2222       extra_host_zlib_configure_flags=--enable-host-shared
2223     fi
2224     ;;
2225 esac
2226 AC_SUBST(extra_host_libiberty_configure_flags)
2227 AC_SUBST(extra_host_zlib_configure_flags)
2228
2229 # Produce a warning message for the subdirs we can't configure.
2230 # This isn't especially interesting in the Cygnus tree, but in the individual
2231 # FSF releases, it's important to let people know when their machine isn't
2232 # supported by the one or two programs in a package.
2233
2234 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2235   # If $appdirs is non-empty, at least one of those directories must still
2236   # be configured, or we error out.  (E.g., if the gas release supports a
2237   # specified target in some subdirs but not the gas subdir, we shouldn't
2238   # pretend that all is well.)
2239   if test -n "$appdirs" ; then
2240     for dir in $appdirs ; do
2241       if test -r $dir/Makefile.in ; then
2242         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2243           appdirs=""
2244           break
2245         fi
2246         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2247           appdirs=""
2248           break
2249         fi
2250       fi
2251     done
2252     if test -n "$appdirs" ; then
2253       echo "*** This configuration is not supported by this package." 1>&2
2254       exit 1
2255     fi
2256   fi
2257   # Okay, some application will build, or we don't care to check.  Still
2258   # notify of subdirs not getting built.
2259   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2260   echo "    ${notsupp}" 1>&2
2261   echo "    (Any other directories should still work fine.)" 1>&2
2262 fi
2263
2264 case "$host" in
2265   *msdosdjgpp*)
2266     enable_gdbtk=no ;;
2267 esac
2268
2269 # To find our prefix, in gcc_cv_tool_prefix.
2270 ACX_TOOL_DIRS
2271
2272 copy_dirs=
2273
2274 AC_ARG_WITH([build-sysroot],
2275   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2276                   [use sysroot as the system root during the build])],
2277   [if test x"$withval" != x ; then
2278      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2279    fi],
2280   [SYSROOT_CFLAGS_FOR_TARGET=])
2281 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2282
2283 AC_ARG_WITH([debug-prefix-map],
2284   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2285                   [map A to B, C to D ... in debug information])],
2286   [if test x"$withval" != x; then
2287      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2288      for debug_map in $withval; do
2289        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2290      done
2291    fi],
2292   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2293 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2294
2295 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2296 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2297 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2298 # We want to ensure that TARGET libraries (which we know are built with
2299 # gcc) are built with "-O2 -g", so include those options when setting
2300 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2301 if test "x$CFLAGS_FOR_TARGET" = x; then
2302   if test "x${is_cross_compiler}" = xyes; then
2303     CFLAGS_FOR_TARGET="-g -O2"
2304   else
2305     CFLAGS_FOR_TARGET=$CFLAGS
2306     case " $CFLAGS " in
2307       *" -O2 "*) ;;
2308       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2309     esac
2310     case " $CFLAGS " in
2311       *" -g "* | *" -g3 "*) ;;
2312       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2313     esac
2314   fi
2315 fi
2316 AC_SUBST(CFLAGS_FOR_TARGET)
2317
2318 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2319   if test "x${is_cross_compiler}" = xyes; then
2320     CXXFLAGS_FOR_TARGET="-g -O2"
2321   else
2322     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2323     case " $CXXFLAGS " in
2324       *" -O2 "*) ;;
2325       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2326     esac
2327     case " $CXXFLAGS " in
2328       *" -g "* | *" -g3 "*) ;;
2329       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2330     esac
2331   fi
2332 fi
2333 AC_SUBST(CXXFLAGS_FOR_TARGET)
2334
2335 AC_SUBST(LDFLAGS_FOR_TARGET)
2336
2337 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2338 # the named directory are copied to $(tooldir)/sys-include.
2339 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2340   if test x${is_cross_compiler} = xno ; then
2341     echo 1>&2 '***' --with-headers is only supported when cross compiling
2342     exit 1
2343   fi
2344   if test x"${with_headers}" != xyes ; then
2345     x=${gcc_cv_tool_prefix}
2346     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2347   fi
2348 fi
2349
2350 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2351 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2352 # are permitted.
2353 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2354   if test x${is_cross_compiler} = xno ; then
2355     echo 1>&2 '***' --with-libs is only supported when cross compiling
2356     exit 1
2357   fi
2358   if test x"${with_libs}" != xyes ; then
2359     # Copy the libraries in reverse order, so that files in the first named
2360     # library override files in subsequent libraries.
2361     x=${gcc_cv_tool_prefix}
2362     for l in ${with_libs}; do
2363       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2364     done
2365   fi
2366 fi
2367
2368 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2369 #
2370 # This is done by determining whether or not the appropriate directory
2371 # is available, and by checking whether or not specific configurations
2372 # have requested that this magic not happen.
2373 #
2374 # The command line options always override the explicit settings in
2375 # configure.ac, and the settings in configure.ac override this magic.
2376 #
2377 # If the default for a toolchain is to use GNU as and ld, and you don't
2378 # want to do that, then you should use the --without-gnu-as and
2379 # --without-gnu-ld options for the configure script.  Similarly, if
2380 # the default is to use the included zlib and you don't want to do that,
2381 # you should use the --with-system-zlib option for the configure script.
2382
2383 if test x${use_gnu_as} = x &&
2384    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2385   with_gnu_as=yes
2386   extra_host_args="$extra_host_args --with-gnu-as"
2387 fi
2388
2389 if test x${use_gnu_ld} = x &&
2390    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2391   with_gnu_ld=yes
2392   extra_host_args="$extra_host_args --with-gnu-ld"
2393 fi
2394
2395 if test x${use_included_zlib} = x &&
2396    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2397   :
2398 else
2399   with_system_zlib=yes
2400   extra_host_args="$extra_host_args --with-system-zlib"
2401 fi
2402
2403 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2404 # can detect this case.
2405
2406 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2407   with_newlib=yes
2408   extra_host_args="$extra_host_args --with-newlib"
2409 fi
2410
2411 # Handle ${copy_dirs}
2412 set fnord ${copy_dirs}
2413 shift
2414 while test $# != 0 ; do
2415   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2416     :
2417   else
2418     echo Copying $1 to $2
2419
2420     # Use the install script to create the directory and all required
2421     # parent directories.
2422     if test -d $2 ; then
2423       :
2424     else
2425       echo >config.temp
2426       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2427     fi
2428
2429     # Copy the directory, assuming we have tar.
2430     # FIXME: Should we use B in the second tar?  Not all systems support it.
2431     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2432
2433     # It is the responsibility of the user to correctly adjust all
2434     # symlinks.  If somebody can figure out how to handle them correctly
2435     # here, feel free to add the code.
2436
2437     echo $1 > $2/COPIED
2438   fi
2439   shift; shift
2440 done
2441
2442 # Determine a target-dependent exec_prefix that the installed
2443 # gcc will search in.  Keep this list sorted by triplet, with
2444 # the *-*-osname triplets last.
2445 md_exec_prefix=
2446 case "${target}" in
2447   i[[34567]]86-pc-msdosdjgpp*)
2448     md_exec_prefix=/dev/env/DJDIR/bin
2449     ;;
2450   *-*-hpux* | \
2451   *-*-nto-qnx* | \
2452   *-*-solaris2*)
2453     md_exec_prefix=/usr/ccs/bin
2454     ;;
2455 esac
2456
2457 extra_arflags_for_target=
2458 extra_nmflags_for_target=
2459 extra_ranlibflags_for_target=
2460 target_makefile_frag=/dev/null
2461 case "${target}" in
2462   spu-*-*)
2463     target_makefile_frag="config/mt-spu"
2464     ;;
2465   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2466     target_makefile_frag="config/mt-sde"
2467     ;;
2468   mipsisa*-*-elfoabi*)
2469     target_makefile_frag="config/mt-mips-elfoabi"
2470     ;;
2471   mips*-*-*linux* | mips*-*-gnu*)
2472     target_makefile_frag="config/mt-mips-gnu"
2473     ;;
2474   nios2-*-elf*)
2475     target_makefile_frag="config/mt-nios2-elf"
2476     ;;
2477   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2478     target_makefile_frag="config/mt-gnu"
2479     ;;
2480   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2481     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2482     # commands to handle both 32-bit and 64-bit objects.  These flags are
2483     # harmless if we're using GNU nm or ar.
2484     extra_arflags_for_target=" -X32_64"
2485     extra_nmflags_for_target=" -B -X32_64"
2486     ;;
2487 esac
2488
2489 alphaieee_frag=/dev/null
2490 case $target in
2491   alpha*-*-*)
2492     # This just makes sure to use the -mieee option to build target libs.
2493     # This should probably be set individually by each library.
2494     alphaieee_frag="config/mt-alphaieee"
2495     ;;
2496 esac
2497
2498 # If --enable-target-optspace always use -Os instead of -O2 to build
2499 # the target libraries, similarly if it is not specified, use -Os
2500 # on selected platforms.
2501 ospace_frag=/dev/null
2502 case "${enable_target_optspace}:${target}" in
2503   yes:*)
2504     ospace_frag="config/mt-ospace"
2505     ;;
2506   :d30v-*)
2507     ospace_frag="config/mt-d30v"
2508     ;;
2509   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2510     ospace_frag="config/mt-ospace"
2511     ;;
2512   no:* | :*)
2513     ;;
2514   *)
2515     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2516     ;;
2517 esac
2518
2519 # Some systems (e.g., one of the i386-aix systems the gas testers are
2520 # using) don't handle "\$" correctly, so don't use it here.
2521 tooldir='${exec_prefix}'/${target_noncanonical}
2522 build_tooldir=${tooldir}
2523
2524 # Create a .gdbinit file which runs the one in srcdir
2525 # and tells GDB to look there for source files.
2526
2527 if test -r ${srcdir}/.gdbinit ; then
2528   case ${srcdir} in
2529     .) ;;
2530     *) cat > ./.gdbinit <<EOF
2531 # ${NO_EDIT}
2532 dir ${srcdir}
2533 dir .
2534 source ${srcdir}/.gdbinit
2535 EOF
2536     ;;
2537   esac
2538 fi
2539
2540 # Make sure that the compiler is able to generate an executable.  If it
2541 # can't, we are probably in trouble.  We don't care whether we can run the
2542 # executable--we might be using a cross compiler--we only care whether it
2543 # can be created.  At this point the main configure script has set CC.
2544 we_are_ok=no
2545 echo "int main () { return 0; }" > conftest.c
2546 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2547 if test $? = 0 ; then
2548   if test -s conftest || test -s conftest.exe ; then
2549     we_are_ok=yes
2550   fi
2551 fi
2552 case $we_are_ok in
2553   no)
2554     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2555     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2556     rm -f conftest*
2557     exit 1
2558     ;;
2559 esac
2560 rm -f conftest*
2561
2562 # Decide which environment variable is used to find dynamic libraries.
2563 case "${host}" in
2564   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2565   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2566   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2567   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2568 esac
2569
2570 # On systems where the dynamic library environment variable is PATH,
2571 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2572 # built executables to PATH.
2573 if test "$RPATH_ENVVAR" = PATH; then
2574   GCC_SHLIB_SUBDIR=/shlib
2575 else
2576   GCC_SHLIB_SUBDIR=
2577 fi
2578
2579 # Adjust the toplevel makefile according to whether bootstrap was selected.
2580 case $enable_bootstrap in
2581   yes)
2582     bootstrap_suffix=bootstrap
2583     BUILD_CONFIG=bootstrap-debug
2584     ;;
2585   no)
2586     bootstrap_suffix=no-bootstrap
2587     BUILD_CONFIG=
2588     ;;
2589 esac
2590
2591 AC_MSG_CHECKING(for default BUILD_CONFIG)
2592
2593 AC_ARG_WITH([build-config],
2594   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2595                   [use config/NAME.mk build configuration])],
2596   [case $with_build_config in
2597    yes) with_build_config= ;;
2598    no) with_build_config= BUILD_CONFIG= ;;
2599    esac])
2600
2601 if test "x${with_build_config}" != x; then
2602   BUILD_CONFIG=$with_build_config
2603 else
2604   case $BUILD_CONFIG in
2605   bootstrap-debug)
2606     if echo "int f (void) { return 0; }" > conftest.c &&
2607        ${CC} -c conftest.c &&
2608        mv conftest.o conftest.o.g0 &&
2609        ${CC} -c -g conftest.c &&
2610        mv conftest.o conftest.o.g &&
2611        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2612       :
2613     else
2614       BUILD_CONFIG=
2615     fi
2616     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2617     ;;
2618   esac
2619 fi
2620 AC_MSG_RESULT($BUILD_CONFIG)
2621 AC_SUBST(BUILD_CONFIG)
2622
2623 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2624 AC_MSG_CHECKING([for --enable-vtable-verify])
2625 AC_ARG_ENABLE(vtable-verify,
2626 [AS_HELP_STRING([--enable-vtable-verify],
2627                 [Enable vtable verification feature])],
2628 [case "$enableval" in
2629  yes) enable_vtable_verify=yes ;;
2630  no)  enable_vtable_verify=no ;;
2631  *)   enable_vtable_verify=no;;
2632  esac],
2633 [enable_vtable_verify=no])
2634 AC_MSG_RESULT($enable_vtable_verify)
2635
2636 # Record target_configdirs and the configure arguments for target and
2637 # build configuration in Makefile.
2638 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2639 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2640 bootstrap_fixincludes=no
2641
2642 # If we are building libgomp, bootstrap it.
2643 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2644   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2645 fi
2646
2647 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2648 # or bootstrap-ubsan, bootstrap it.
2649 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2650   case "$BUILD_CONFIG" in
2651     *bootstrap-asan* | *bootstrap-ubsan* )
2652       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2653       bootstrap_fixincludes=yes
2654       ;;
2655   esac
2656 fi
2657
2658 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2659 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2660    test "$enable_vtable_verify" != no; then
2661   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2662 fi
2663
2664 # If we are building libmpx and $BUILD_CONFIG contains bootstrap-mpx,
2665 # bootstrap it.
2666 if echo " ${target_configdirs} " | grep " libmpx " > /dev/null 2>&1; then
2667   case "$BUILD_CONFIG" in
2668     *bootstrap-mpx* )
2669       bootstrap_target_libs=${bootstrap_target_libs}target-libmpx,
2670       ;;
2671   esac
2672 fi
2673
2674 # Determine whether gdb needs tk/tcl or not.
2675 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2676 # and in that case we want gdb to be built without tk.  Ugh!
2677 # In fact I believe gdb is the *only* package directly dependent on tk,
2678 # so we should be able to put the 'maybe's in unconditionally and
2679 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2680 # 100% sure that that's safe though.
2681
2682 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2683 case "$enable_gdbtk" in
2684   no)
2685     GDB_TK="" ;;
2686   yes)
2687     GDB_TK="${gdb_tk}" ;;
2688   *)
2689     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2690     # distro.  Eventually someone will fix this and move Insight, nee
2691     # gdbtk to a separate directory.
2692     if test -d ${srcdir}/gdb/gdbtk ; then
2693       GDB_TK="${gdb_tk}"
2694     else
2695       GDB_TK=""
2696     fi
2697     ;;
2698 esac
2699 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2700 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2701
2702 # Strip out unwanted targets.
2703
2704 # While at that, we remove Makefiles if we were started for recursive
2705 # configuration, so that the top-level Makefile reconfigures them,
2706 # like we used to do when configure itself was recursive.
2707
2708 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2709 # but now we're fixing up the Makefile ourselves with the additional
2710 # commands passed to AC_CONFIG_FILES.  Use separate variables
2711 # extrasub-{build,host,target} not because there is any reason to split
2712 # the substitutions up that way, but only to remain below the limit of
2713 # 99 commands in a script, for HP-UX sed.
2714 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2715
2716 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2717   yes:yes:*\ gold\ *:*,c++,*) ;;
2718   yes:yes:*\ gold\ *:*)
2719     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2720     ;;
2721 esac
2722
2723 extrasub_build=
2724 for module in ${build_configdirs} ; do
2725   if test -z "${no_recursion}" \
2726      && test -f ${build_subdir}/${module}/Makefile; then
2727     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2728     rm -f ${build_subdir}/${module}/Makefile
2729   fi
2730   extrasub_build="$extrasub_build
2731 /^@if build-$module\$/d
2732 /^@endif build-$module\$/d
2733 /^@if build-$module-$bootstrap_suffix\$/d
2734 /^@endif build-$module-$bootstrap_suffix\$/d"
2735 done
2736 extrasub_host=
2737 for module in ${configdirs} ; do
2738   if test -z "${no_recursion}"; then
2739     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2740       if test -f ${file}; then
2741         echo 1>&2 "*** removing ${file} to force reconfigure"
2742         rm -f ${file}
2743       fi
2744     done
2745   fi
2746   case ${module},${bootstrap_fixincludes} in
2747     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2748     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2749   esac
2750   extrasub_host="$extrasub_host
2751 /^@if $module\$/d
2752 /^@endif $module\$/d
2753 /^@if $module-$host_bootstrap_suffix\$/d
2754 /^@endif $module-$host_bootstrap_suffix\$/d"
2755 done
2756 extrasub_target=
2757 for module in ${target_configdirs} ; do
2758   if test -z "${no_recursion}" \
2759      && test -f ${target_subdir}/${module}/Makefile; then
2760     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2761     rm -f ${target_subdir}/${module}/Makefile
2762   fi
2763
2764   # We only bootstrap target libraries listed in bootstrap_target_libs.
2765   case $bootstrap_target_libs in
2766     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2767     *) target_bootstrap_suffix=no-bootstrap ;;
2768   esac
2769
2770   extrasub_target="$extrasub_target
2771 /^@if target-$module\$/d
2772 /^@endif target-$module\$/d
2773 /^@if target-$module-$target_bootstrap_suffix\$/d
2774 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2775 done
2776
2777 # Do the final fixup along with target modules.
2778 extrasub_target="$extrasub_target
2779 /^@if /,/^@endif /d"
2780
2781 # Create the serialization dependencies.  This uses a temporary file.
2782
2783 AC_ARG_ENABLE([serial-configure],
2784 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2785                 [force sequential configuration of
2786                  sub-packages for the host, target or build
2787                  machine, or all sub-packages])])
2788
2789 case ${enable_serial_configure} in
2790   yes)
2791     enable_serial_build_configure=yes
2792     enable_serial_host_configure=yes
2793     enable_serial_target_configure=yes
2794     ;;
2795 esac
2796
2797 # These force 'configure's to be done one at a time, to avoid problems
2798 # with contention over a shared config.cache.
2799 rm -f serdep.tmp
2800 echo '# serdep.tmp' > serdep.tmp
2801 olditem=
2802 test "x${enable_serial_build_configure}" = xyes &&
2803 for item in ${build_configdirs} ; do
2804   case ${olditem} in
2805     "") ;;
2806     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2807   esac
2808   olditem=${item}
2809 done
2810 olditem=
2811 test "x${enable_serial_host_configure}" = xyes &&
2812 for item in ${configdirs} ; do
2813   case ${olditem} in
2814     "") ;;
2815     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2816   esac
2817   olditem=${item}
2818 done
2819 olditem=
2820 test "x${enable_serial_target_configure}" = xyes &&
2821 for item in ${target_configdirs} ; do
2822   case ${olditem} in
2823     "") ;;
2824     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2825   esac
2826   olditem=${item}
2827 done
2828 serialization_dependencies=serdep.tmp
2829 AC_SUBST_FILE(serialization_dependencies)
2830
2831 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2832 # target, nonopt, and variable assignments.  These are the ones we
2833 # might not want to pass down to subconfigures.  The exception being
2834 # --cache-file=/dev/null, which is used to turn off the use of cache
2835 # files altogether, and which should be passed on to subconfigures.
2836 # Also strip program-prefix, program-suffix, and program-transform-name,
2837 # so that we can pass down a consistent program-transform-name.
2838 baseargs=
2839 tbaseargs=
2840 keep_next=no
2841 skip_next=no
2842 eval "set -- $ac_configure_args"
2843 for ac_arg
2844 do
2845   if test X"$skip_next" = X"yes"; then
2846     skip_next=no
2847     continue
2848   fi
2849   if test X"$keep_next" = X"yes"; then
2850     case $ac_arg in
2851       *\'*)
2852         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2853     esac
2854     baseargs="$baseargs '$ac_arg'"
2855     tbaseargs="$tbaseargs '$ac_arg'"
2856     keep_next=no
2857     continue
2858   fi
2859
2860   # Handle separated arguments.  Based on the logic generated by
2861   # autoconf 2.59.
2862   case $ac_arg in
2863     *=* | --config-cache | -C | -disable-* | --disable-* \
2864       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2865       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2866       | -with-* | --with-* | -without-* | --without-* | --x)
2867       separate_arg=no
2868       ;;
2869     -*)
2870       separate_arg=yes
2871       ;;
2872     *)
2873       separate_arg=no
2874       ;;
2875   esac
2876
2877   skip_targ=no
2878   case $ac_arg in
2879 changequote(,)
2880   --with-* | --without-*)
2881     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2882
2883     case $libopt in
2884     *[-_]include)
2885       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2886       ;;
2887     *[-_]lib)
2888       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2889       ;;
2890     *)
2891       lib=$libopt
2892       ;;
2893     esac
2894 changequote([,])
2895
2896     case $lib in
2897     mpc | mpfr | gmp | isl)
2898       # If we're processing --with-$lib, --with-$lib-include or
2899       # --with-$lib-lib, for one of the libs above, and target is
2900       # different from host, don't pass the current argument to any
2901       # target library's configure.
2902       if test x$is_cross_compiler = xyes; then
2903         skip_targ=yes
2904       fi
2905       ;;
2906     esac
2907     ;;
2908   esac
2909
2910   case "$ac_arg" in
2911     --cache-file=/dev/null | \
2912     -cache-file=/dev/null )
2913       # Handled here to avoid the test to skip args below.
2914       baseargs="$baseargs '$ac_arg'"
2915       tbaseargs="$tbaseargs '$ac_arg'"
2916       # Assert: $separate_arg should always be no.
2917       keep_next=$separate_arg
2918       ;;
2919     --no*)
2920       continue
2921       ;;
2922     --c* | \
2923     --sr* | \
2924     --ho* | \
2925     --bu* | \
2926     --t* | \
2927     --program-* | \
2928     -cache_file* | \
2929     -srcdir* | \
2930     -host* | \
2931     -build* | \
2932     -target* | \
2933     -program-prefix* | \
2934     -program-suffix* | \
2935     -program-transform-name* )
2936       skip_next=$separate_arg
2937       continue
2938       ;;
2939     -*)
2940       # An option.  Add it.
2941       case $ac_arg in
2942         *\'*)
2943           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2944       esac
2945       baseargs="$baseargs '$ac_arg'"
2946       if test X"$skip_targ" = Xno; then
2947         tbaseargs="$tbaseargs '$ac_arg'"
2948       fi
2949       keep_next=$separate_arg
2950       ;;
2951     *)
2952       # Either a variable assignment, or a nonopt (triplet).  Don't
2953       # pass it down; let the Makefile handle this.
2954       continue
2955       ;;
2956   esac
2957 done
2958 # Remove the initial space we just introduced and, as these will be
2959 # expanded by make, quote '$'.
2960 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2961
2962 # Add in --program-transform-name, after --program-prefix and
2963 # --program-suffix have been applied to it.  Autoconf has already
2964 # doubled dollar signs and backslashes in program_transform_name; we want
2965 # the backslashes un-doubled, and then the entire thing wrapped in single
2966 # quotes, because this will be expanded first by make and then by the shell.
2967 # Also, because we want to override the logic in subdir configure scripts to
2968 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2969 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2970 ${program_transform_name}
2971 EOF_SED
2972 gcc_transform_name=`cat conftestsed.out`
2973 rm -f conftestsed.out
2974 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2975 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2976 if test "$silent" = yes; then
2977   baseargs="$baseargs --silent"
2978   tbaseargs="$tbaseargs --silent"
2979 fi
2980 baseargs="$baseargs --disable-option-checking"
2981 tbaseargs="$tbaseargs --disable-option-checking"
2982
2983 # Record and document user additions to sub configure arguments.
2984 AC_ARG_VAR([build_configargs],
2985            [additional configure arguments for build directories])
2986 AC_ARG_VAR([host_configargs],
2987            [additional configure arguments for host directories])
2988 AC_ARG_VAR([target_configargs],
2989            [additional configure arguments for target directories])
2990
2991 # For the build-side libraries, we just need to pretend we're native,
2992 # and not use the same cache file.  Multilibs are neither needed nor
2993 # desired.  We can't even use the same cache file for all build-side
2994 # libraries, as they're compiled differently; some with C, some with
2995 # C++ or with different feature-enabling options.
2996 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
2997
2998 # For host modules, accept cache file option, or specification as blank.
2999 case "${cache_file}" in
3000 "") # empty
3001   cache_file_option="" ;;
3002 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3003   cache_file_option="--cache-file=${cache_file}" ;;
3004 *) # relative path
3005   cache_file_option="--cache-file=../${cache_file}" ;;
3006 esac
3007
3008 # Host dirs don't like to share a cache file either, horribly enough.
3009 # This seems to be due to autoconf 2.5x stupidity.
3010 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3011
3012 target_configargs="$target_configargs ${tbaseargs}"
3013
3014 # Passing a --with-cross-host argument lets the target libraries know
3015 # whether they are being built with a cross-compiler or being built
3016 # native.  However, it would be better to use other mechanisms to make the
3017 # sorts of decisions they want to make on this basis.  Please consider
3018 # this option to be deprecated.  FIXME.
3019 if test x${is_cross_compiler} = xyes ; then
3020   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3021 fi
3022
3023 # Special user-friendly check for native x86_64-linux build, if
3024 # multilib is not explicitly enabled.
3025 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3026   x86_64-*linux*:yes:$build:$build:)
3027     # Make sure we have a development environment that handles 32-bit
3028     dev64=no
3029     echo "int main () { return 0; }" > conftest.c
3030     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3031     if test $? = 0 ; then
3032       if test -s conftest || test -s conftest.exe ; then
3033         dev64=yes
3034       fi
3035     fi
3036     rm -f conftest*
3037     if test x${dev64} != xyes ; then
3038       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3039     fi
3040     ;;
3041 esac
3042
3043 # Default to --enable-multilib.
3044 if test x${enable_multilib} = x ; then
3045   target_configargs="--enable-multilib ${target_configargs}"
3046 fi
3047
3048 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3049 # changed from the earlier setting of with_newlib.
3050 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3051   target_configargs="--with-newlib ${target_configargs}"
3052 fi
3053
3054 # Different target subdirs use different values of certain variables
3055 # (notably CXX).  Worse, multilibs use *lots* of different values.
3056 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3057 # it doesn't automatically accept command-line overrides of them.
3058 # This means it's not safe for target subdirs to share a cache file,
3059 # which is disgusting, but there you have it.  Hopefully this can be
3060 # fixed in future.  It's still worthwhile to use a cache file for each
3061 # directory.  I think.
3062
3063 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3064 # We need to pass --target, as newer autoconf's requires consistency
3065 # for target_alias and gcc doesn't manage it consistently.
3066 target_configargs="--cache-file=./config.cache ${target_configargs}"
3067
3068 FLAGS_FOR_TARGET=
3069 case " $target_configdirs " in
3070  *" newlib "*)
3071   case " $target_configargs " in
3072   *" --with-newlib "*)
3073    case "$target" in
3074     *-cygwin*)
3075       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3076       ;;
3077    esac
3078
3079    # If we're not building GCC, don't discard standard headers.
3080    if test -d ${srcdir}/gcc; then
3081      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3082
3083      if test "${build}" != "${host}"; then
3084        # On Canadian crosses, CC_FOR_TARGET will have already been set
3085        # by `configure', so we won't have an opportunity to add -Bgcc/
3086        # to it.  This is right: we don't want to search that directory
3087        # for binaries, but we want the header files in there, so add
3088        # them explicitly.
3089        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3090
3091        # Someone might think of using the pre-installed headers on
3092        # Canadian crosses, in case the installed compiler is not fully
3093        # compatible with the compiler being built.  In this case, it
3094        # would be better to flag an error than risking having
3095        # incompatible object files being constructed.  We can't
3096        # guarantee that an error will be flagged, but let's hope the
3097        # compiler will do it, when presented with incompatible header
3098        # files.
3099      fi
3100    fi
3101
3102    case "${target}-${is_cross_compiler}" in
3103    i[[3456789]]86-*-linux*-no)
3104       # Here host == target, so we don't need to build gcc,
3105       # so we don't want to discard standard headers.
3106       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3107       ;;
3108    *)
3109       # If we're building newlib, use its generic headers last, but search
3110       # for any libc-related directories first (so make it the last -B
3111       # switch).
3112       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3113
3114       # If we're building libgloss, find the startup file, simulator library
3115       # and linker script.
3116       case " $target_configdirs " in
3117         *" libgloss "*)
3118         # Look for startup file, simulator library and maybe linker script.
3119         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3120         # Look for libnosys.a in case the target needs it.
3121         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3122         # Most targets have the linker script in the source directory.
3123         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3124         ;;
3125       esac
3126       ;;
3127    esac
3128    ;;
3129   esac
3130   ;;
3131 esac
3132
3133 case "$target" in
3134   x86_64-*mingw* | *-w64-mingw*)
3135   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3136   # however, use a symlink named 'mingw' in ${prefix} .
3137     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3138     ;;
3139   *-mingw*)
3140   # MinGW can't be handled as Cygwin above since it does not use newlib.
3141     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3142     ;;
3143 esac
3144
3145 # Allow the user to override the flags for
3146 # our build compiler if desired.
3147 if test x"${build}" = x"${host}" ; then
3148   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3149   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3150   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3151 fi
3152
3153 # On Canadian crosses, we'll be searching the right directories for
3154 # the previously-installed cross compiler, so don't bother to add
3155 # flags for directories within the install tree of the compiler
3156 # being built; programs in there won't even run.
3157 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3158   # Search for pre-installed headers if nothing else fits.
3159   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3160 fi
3161
3162 if test "x${use_gnu_ld}" = x &&
3163    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3164   # Arrange for us to find uninstalled linker scripts.
3165   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3166 fi
3167
3168 # Search for other target-specific linker scripts and such.
3169 case "${target}" in
3170   mep*)
3171     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3172     ;;
3173 esac
3174
3175 # Makefile fragments.
3176 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3177 do
3178   eval fragval=\$$frag
3179   if test $fragval != /dev/null; then
3180     eval $frag=${srcdir}/$fragval
3181   fi
3182 done
3183 AC_SUBST_FILE(host_makefile_frag)
3184 AC_SUBST_FILE(target_makefile_frag)
3185 AC_SUBST_FILE(alphaieee_frag)
3186 AC_SUBST_FILE(ospace_frag)
3187
3188 # Miscellanea: directories, flags, etc.
3189 AC_SUBST(RPATH_ENVVAR)
3190 AC_SUBST(GCC_SHLIB_SUBDIR)
3191 AC_SUBST(tooldir)
3192 AC_SUBST(build_tooldir)
3193 AC_SUBST(CONFIGURE_GDB_TK)
3194 AC_SUBST(GDB_TK)
3195 AC_SUBST(INSTALL_GDB_TK)
3196
3197 # Build module lists & subconfigure args.
3198 AC_SUBST(build_configargs)
3199 AC_SUBST(build_configdirs)
3200
3201 # Host module lists & subconfigure args.
3202 AC_SUBST(host_configargs)
3203 AC_SUBST(configdirs)
3204 AC_SUBST(target_configdirs)
3205
3206 # Target module lists & subconfigure args.
3207 AC_SUBST(target_configargs)
3208
3209
3210 # Build tools.
3211 AC_SUBST(AR_FOR_BUILD)
3212 AC_SUBST(AS_FOR_BUILD)
3213 AC_SUBST(CC_FOR_BUILD)
3214 AC_SUBST(CFLAGS_FOR_BUILD)
3215 AC_SUBST(CXXFLAGS_FOR_BUILD)
3216 AC_SUBST(CXX_FOR_BUILD)
3217 AC_SUBST(DLLTOOL_FOR_BUILD)
3218 AC_SUBST(GFORTRAN_FOR_BUILD)
3219 AC_SUBST(GOC_FOR_BUILD)
3220 AC_SUBST(LDFLAGS_FOR_BUILD)
3221 AC_SUBST(LD_FOR_BUILD)
3222 AC_SUBST(NM_FOR_BUILD)
3223 AC_SUBST(RANLIB_FOR_BUILD)
3224 AC_SUBST(WINDMC_FOR_BUILD)
3225 AC_SUBST(WINDRES_FOR_BUILD)
3226
3227 # Generate default definitions for YACC, M4, LEX and other programs that run
3228 # on the build machine.  These are used if the Makefile can't locate these
3229 # programs in objdir.
3230 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3231
3232 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3233 case " $build_configdirs " in
3234   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3235 esac
3236
3237 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3238 case " $build_configdirs " in
3239   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3240 esac
3241
3242 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3243 case " $build_configdirs " in
3244   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3245 esac
3246
3247 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3248 case " $build_configdirs " in
3249   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3250   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3251 esac
3252
3253 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3254 case " $build_configdirs " in
3255   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3256 esac
3257
3258 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3259 case " $build_configdirs " in
3260   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3261   *)
3262 changequote(,)
3263     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3264     # higher, else we use the "missing" dummy.
3265     if ${MAKEINFO} --version \
3266        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3267       :
3268     else
3269       MAKEINFO="$MISSING makeinfo"
3270     fi
3271     ;;
3272 changequote([,])
3273 esac
3274
3275 # FIXME: expect and dejagnu may become build tools?
3276
3277 AC_CHECK_PROGS(EXPECT, expect, expect)
3278 case " $configdirs " in
3279   *" expect "*)
3280     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3281     ;;
3282 esac
3283
3284 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3285 case " $configdirs " in
3286   *" dejagnu "*)
3287     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3288     ;;
3289 esac
3290
3291
3292 # Host tools.
3293 NCN_STRICT_CHECK_TOOLS(AR, ar)
3294 NCN_STRICT_CHECK_TOOLS(AS, as)
3295 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3296 NCN_STRICT_CHECK_TOOLS(LD, ld)
3297 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3298 NCN_STRICT_CHECK_TOOLS(NM, nm)
3299 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3300 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3301 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3302 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3303 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3304 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3305 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3306 AC_SUBST(CC)
3307 AC_SUBST(CXX)
3308 AC_SUBST(CFLAGS)
3309 AC_SUBST(CXXFLAGS)
3310
3311 # Target tools.
3312 AC_ARG_WITH([build-time-tools],
3313   [AS_HELP_STRING([--with-build-time-tools=PATH],
3314                   [use given path to find target tools during the build])],
3315   [case x"$withval" in
3316      x/*) ;;
3317      *)
3318        with_build_time_tools=
3319        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3320        ;;
3321    esac],
3322   [with_build_time_tools=])
3323
3324 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3325 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3326 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3327 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3328 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3329
3330 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3331 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3332 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3333 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3334 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3335 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3336 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3337 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3338 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3339 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3340 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3341 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3342 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3343
3344 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3345
3346 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3347 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3348 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3349 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3350 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3351                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3352                 c++)
3353 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3354                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3355                 c++)
3356 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3357 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3358 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3359                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3360 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3361                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3362 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3363 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3364 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3365 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3366 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3367 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3368 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3369 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3370 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3371 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3372
3373 AC_SUBST(FLAGS_FOR_TARGET)
3374 AC_SUBST(RAW_CXX_FOR_TARGET)
3375
3376 # Certain tools may need extra flags.
3377 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3378 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3379 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3380
3381 # When building target libraries, except in a Canadian cross, we use
3382 # the same toolchain as the compiler we just built.
3383 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3384 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3385 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3386 if test $host = $build; then
3387   case " $configdirs " in
3388     *" gcc "*)
3389       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3390       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3391       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3392       ;;
3393   esac
3394 fi
3395
3396 AC_SUBST(COMPILER_AS_FOR_TARGET)
3397 AC_SUBST(COMPILER_LD_FOR_TARGET)
3398 AC_SUBST(COMPILER_NM_FOR_TARGET)
3399
3400 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3401 AC_ARG_ENABLE(maintainer-mode,
3402 [AS_HELP_STRING([--enable-maintainer-mode],
3403                 [enable make rules and dependencies not useful
3404                  (and sometimes confusing) to the casual installer])],
3405       USE_MAINTAINER_MODE=$enableval,
3406       USE_MAINTAINER_MODE=no)
3407 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3408 AC_SUBST(MAINTAINER_MODE_TRUE)
3409 AC_SUBST(MAINTAINER_MODE_FALSE)
3410 if test "$USE_MAINTAINER_MODE" = yes; then
3411   MAINTAINER_MODE_TRUE=
3412   MAINTAINER_MODE_FALSE='#'
3413 else
3414   MAINTAINER_MODE_TRUE='#'
3415   MAINTAINER_MODE_FALSE=
3416 fi
3417 MAINT=$MAINTAINER_MODE_TRUE
3418 AC_SUBST(MAINT)dnl
3419
3420 # ---------------------
3421 # GCC bootstrap support
3422 # ---------------------
3423
3424 # Stage specific cflags for build.
3425 stage1_cflags="-g"
3426 case $build in
3427   vax-*-*)
3428     case ${GCC} in
3429       yes) stage1_cflags="-g -Wa,-J" ;;
3430       *) stage1_cflags="-g -J" ;;
3431     esac ;;
3432 esac
3433
3434 AC_SUBST(stage1_cflags)
3435
3436 # Enable --enable-checking in stage1 of the compiler.
3437 AC_ARG_ENABLE(stage1-checking,
3438 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3439                 [choose additional checking for stage1 of the compiler])],
3440 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3441 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3442   # For --disable-checking or implicit --enable-checking=release, avoid
3443   # setting --enable-checking=gc in the default stage1 checking for LTO
3444   # bootstraps.  See PR62077.
3445   case $BUILD_CONFIG in
3446     *lto*)
3447       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3448     *)
3449       stage1_checking=--enable-checking=yes,types;;
3450   esac
3451   if test "x$enable_checking" = x && \
3452      test -d ${srcdir}/gcc && \
3453      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3454     stage1_checking=--enable-checking=yes,types,extra
3455   fi
3456 else
3457   stage1_checking=--enable-checking=$enable_checking,types
3458 fi])
3459 AC_SUBST(stage1_checking)
3460
3461 # Enable -Werror in bootstrap stage2 and later.
3462 AC_ARG_ENABLE(werror,
3463 [AS_HELP_STRING([--enable-werror],
3464                 [enable -Werror in bootstrap stage2 and later])], [],
3465 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3466   enable_werror=yes
3467 else
3468   enable_werror=no
3469 fi])
3470 case ${enable_werror} in
3471   yes) stage2_werror_flag="--enable-werror-always" ;;
3472   *) stage2_werror_flag="" ;;
3473 esac
3474 AC_SUBST(stage2_werror_flag)
3475
3476 # Enable --enable-host-shared.
3477 AC_ARG_ENABLE(host-shared,
3478 [AS_HELP_STRING([--enable-host-shared],
3479                 [build host code as shared libraries])],
3480 [host_shared=$enableval], [host_shared=no])
3481 AC_SUBST(host_shared)
3482
3483 # PR jit/64780: Require the user to explicitly specify
3484 # --enable-host-shared if the jit is enabled, hinting
3485 # that they might want to do a separate configure/build of
3486 # the jit, to avoid users from slowing down the rest of the
3487 # compiler by enabling the jit.
3488 if test ${host_shared} = "no" ; then
3489   case "${enable_languages}" in
3490     *jit*)
3491       AC_MSG_ERROR([
3492 Enabling language "jit" requires --enable-host-shared.
3493
3494 --enable-host-shared typically slows the rest of the compiler down by
3495 a few %, so you must explicitly enable it.
3496
3497 If you want to build both the jit and the regular compiler, it is often
3498 best to do this via two separate configure/builds, in separate
3499 directories, to avoid imposing the performance cost of
3500 --enable-host-shared on the regular compiler.])
3501       ;;
3502     *)
3503       ;;
3504   esac
3505 fi
3506
3507 # Specify what files to not compare during bootstrap.
3508
3509 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3510 case "$target" in
3511   hppa*64*-*-hpux*) ;;
3512   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3513   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3514 esac
3515 AC_SUBST(compare_exclusions)
3516
3517 AC_CONFIG_FILES([Makefile],
3518   [sed "$extrasub_build" Makefile |
3519    sed "$extrasub_host" |
3520    sed "$extrasub_target" > mf$$
3521    mv -f mf$$ Makefile],
3522   [extrasub_build="$extrasub_build"
3523    extrasub_host="$extrasub_host"
3524    extrasub_target="$extrasub_target"])
3525 AC_OUTPUT