libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([xmalloc.c])
   5
   6 # This works around the fact that libtool configuration may change LD
   7 # for this particular configuration, but some shells, instead of
   8 # keeping the changes in LD private, export them just because LD is
   9 # exported.  We don't use libtool yet, but some day we might, so...
  10 ORIGINAL_LD_FOR_MULTILIBS=$LD
  11
  12 dnl We use these options to decide which functions to include.
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  15 AC_ARG_WITH(build-subdir,
  16 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  17 AC_ARG_WITH(cross-host,
  18 [  --with-cross-host=HOST           Configuring with a cross compiler])
  19 AC_ARG_WITH(newlib,
  20 [  --with-newlib                    Configuring with newlib])
  21
  22 if test "${srcdir}" = "."; then
  23   if test -n "${with_build_subdir}"; then
  24     libiberty_topdir="${srcdir}/../.."
  25     with_target_subdir=
  26   elif test -z "${with_target_subdir}"; then
  27     libiberty_topdir="${srcdir}/.."
  28   else
  29     if test "${with_target_subdir}" != "."; then
  30       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  31     else
  32       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  33     fi
  34   fi
  35 else
  36   libiberty_topdir="${srcdir}/.."
  37 fi
  38 AC_SUBST(libiberty_topdir)
  39 AC_CONFIG_AUX_DIR($libiberty_topdir)
  40
  41 dnl Very limited version of automake's enable-maintainer-mode
  42
  43 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  44   dnl maintainer-mode is disabled by default
  45   AC_ARG_ENABLE(maintainer-mode,
  46 [  --enable-maintainer-mode
  47                           enable make rules and dependencies not useful
  48                           (and sometimes confusing) to the casual installer],
  49       maintainer_mode=$enableval,
  50       maintainer_mode=no)
  51
  52 AC_MSG_RESULT($maintainer_mode)
  53
  54 if test "$maintainer_mode" = "yes"; then
  55   MAINT=''
  56   NOTMAINT='#'
  57 else
  58   MAINT='#'
  59   NOTMAINT=''
  60 fi
  61 AC_SUBST(MAINT)dnl
  62 AC_SUBST(NOTMAINT)dnl
  63
  64 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  65 # rely on it - libiberty is built before texinfo.
  66 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  67 if test "x$MAKEINFO" = "x"; then
  68     MAKEINFO="@echo makeinfo missing; true"
  69     BUILD_INFO=
  70 else
  71     BUILD_INFO=info
  72     case "$MAKEINFO" in
  73       */missing\ makeinfo*)
  74         BUILD_INFO=
  75         AC_MSG_WARN([
  76 *** Makeinfo is missing. Info documentation will not be built.])
  77         ;;
  78       *)
  79         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  80           x*\ [[1-3]].* )
  81             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  82             BUILD_INFO=
  83             AC_MSG_WARN([
  84 *** Makeinfo is too old. Info documentation will not be built.])
  85           ;;
  86         esac
  87         ;;
  88     esac
  89 fi
  90 AC_SUBST(MAKEINFO)
  91 AC_SUBST(BUILD_INFO)
  92
  93 AC_CHECK_PROG(PERL, perl, perl, )
  94 if test x"$PERL" = x""; then
  95   HAVE_PERL='#'
  96 else
  97   HAVE_PERL=''
  98 fi
  99 AC_SUBST(HAVE_PERL)
 100
 101 AC_CANONICAL_HOST
 102
 103 dnl When we start using automake:
 104 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 105
 106 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 107 dnl to call AC_CHECK_PROG.
 108 AC_CHECK_TOOL(AR, ar)
 109 AC_CHECK_TOOL(RANLIB, ranlib, :)
 110
 111 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 112 # Add --enable-multilib to configure.
 113 # Default to --enable-multilib
 114 AC_ARG_ENABLE(multilib,
 115 [  --enable-multilib       build many library versions (default)],
 116 [case "$enableval" in
 117   yes) multilib=yes ;;
 118   no)  multilib=no ;;
 119   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 120  esac],
 121               [multilib=yes])
 122
 123 # Even if the default multilib is not a cross compilation,
 124 # it may be that some of the other multilibs are.
 125 if test $cross_compiling = no && test $multilib = yes \
 126    && test "x${with_multisubdir}" != x ; then
 127    cross_compiling=maybe
 128 fi
 129
 130 # We may wish to install the target headers somewhere.
 131 AC_MSG_CHECKING([whether to install libiberty headers and static library])
 132 dnl install-libiberty is disabled by default
 133
 134 AC_ARG_ENABLE(install-libiberty,
 135 [  --enable-install-libiberty       Install headers and library for end users],
 136 enable_install_libiberty=$enableval,
 137 enable_install_libiberty=no)dnl
 138
 139 # Option parsed, now set things appropriately.
 140 case x"$enable_install_libiberty" in
 141   xyes|x)
 142     target_header_dir=libiberty
 143     ;;
 144   xno)
 145     target_header_dir=
 146     ;;
 147   *)
 148     # This could be sanity-checked in various ways...
 149     target_header_dir="${enable_install_libiberty}"
 150     ;;
 151 esac
 152 AC_MSG_RESULT($enable_install_libiberty)
 153 AC_MSG_NOTICE([target_header_dir = $target_header_dir])
 154
 155 GCC_NO_EXECUTABLES
 156 AC_PROG_CC
 157 AC_GNU_SOURCE
 158 AC_SYS_LARGEFILE
 159 AC_PROG_CPP_WERROR
 160
 161 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 162                           -Wstrict-prototypes \
 163                           -Wshadow=local], [ac_libiberty_warn_cflags])
 164 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 165
 166 AC_PROG_CC_C_O
 167 # autoconf is lame and doesn't give us any substitution variable for this.
 168 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 169   NO_MINUS_C_MINUS_O=yes
 170 else
 171   OUTPUT_OPTION='-o $@'
 172 fi
 173 AC_SUBST(NO_MINUS_C_MINUS_O)
 174 AC_SUBST(OUTPUT_OPTION)
 175
 176 AC_C_CONST
 177 AC_C_INLINE
 178 AC_C_BIGENDIAN
 179
 180 dnl When we start using libtool:
 181 dnl Default to a non shared library.  This may be overridden by the
 182 dnl configure option --enable-shared.
 183 dnl AM_DISABLE_SHARED
 184
 185 dnl When we start using libtool:
 186 dnl AM_PROG_LIBTOOL
 187
 188 dnl When we start using automake:
 189 dnl AM_CONFIG_HEADER(config.h:config.in)
 190 AC_CONFIG_HEADER(config.h:config.in)
 191
 192 dnl When we start using automake:
 193 dnl AM_MAINTAINER_MODE
 194 dnl AC_EXEEXT
 195
 196 dnl When we start using automake:
 197 dnl AM_PROG_INSTALL
 198 AC_PROG_INSTALL
 199
 200 # Don't build the shared library for build.
 201 if [[ -n "${with_build_subdir}" ]]; then
 202   enable_shared=no
 203 fi
 204
 205 frag=
 206 case "${host}" in
 207   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 208                         frag=mh-aix ;;
 209   *-*-cxux7*)           frag=mh-cxux7 ;;
 210   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 211   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 212   i370-*-opened*)       frag=mh-openedition ;;
 213   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 214 esac
 215
 216 if [[ -n "${frag}" ]]; then
 217   frag=${libiberty_topdir}/libiberty/config/$frag
 218 fi
 219
 220 GCC_PICFLAG
 221
 222 # If they didn't specify --enable-shared, don't generate shared libs.
 223 case "${enable_shared}" in
 224   yes) shared=yes ;;
 225   no) shared=no ;;
 226   "") shared=no ;;
 227   *) shared=yes ;;
 228 esac
 229
 230 # ...unless --enable-host-shared was passed from top-level config:
 231 if [[ "${enable_host_shared}" = "yes" ]]; then
 232   shared=yes
 233 fi
 234
 235 if [[ "${shared}" != "yes" ]]; then
 236   PICFLAG=
 237 fi
 238 AC_SUBST(PICFLAG)
 239
 240 NOASANFLAG=
 241 case " ${CFLAGS} " in
 242   *\ -fsanitize=address\ *) NOASANFLAG=-fno-sanitize=address ;;
 243   *\ -fsanitize=hwaddress\ *) NOASANFLAG=-fno-sanitize=hwaddress ;;
 244 esac
 245 AC_SUBST(NOASANFLAG)
 246
 247 GCC_CET_HOST_FLAGS(CET_HOST_FLAGS)
 248 AC_SUBST(CET_HOST_FLAGS)
 249
 250 echo "# Warning: this fragment is automatically generated" > temp-frag
 251
 252 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 253   echo "Appending ${frag} to xhost-mkfrag"
 254   echo "# Following fragment copied from ${frag}" >> temp-frag
 255   cat ${frag} >> temp-frag
 256 fi
 257
 258 # record if we want to build shared libs.
 259 if [[ "${shared}" = "yes" ]]; then
 260   echo enable_shared = yes >> temp-frag
 261 else
 262   echo enable_shared = no >> temp-frag
 263 fi
 264
 265 frag=xhost-mkfrag
 266 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 267
 268 host_makefile_frag=${frag}
 269 AC_SUBST_FILE(host_makefile_frag)
 270
 271 # It's OK to check for header files.  Although the compiler may not be
 272 # able to link anything, it had better be able to at least compile
 273 # something.
 274 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 275 AC_HEADER_SYS_WAIT
 276 AC_HEADER_TIME
 277
 278 libiberty_AC_DECLARE_ERRNO
 279
 280 # Determine sizes of some types.
 281 AC_CHECK_SIZEOF([int])
 282 AC_CHECK_SIZEOF([long])
 283 AC_CHECK_SIZEOF([size_t])
 284
 285 # Check for presense of long long
 286 AC_CHECK_TYPE([long long],
 287   [AC_DEFINE(HAVE_LONG_LONG, 1, [Define if you have the `long long' type.]) AC_CHECK_SIZEOF([long long])],
 288   [])
 289
 290 # Look for a 64-bit type.
 291 AC_MSG_CHECKING([for a 64-bit type])
 292 AC_CACHE_VAL(liberty_cv_uint64,
 293 [AC_TRY_COMPILE(
 294 [#ifdef HAVE_STDINT_H
 295 #include <stdint.h>
 296 #endif],
 297 [extern uint64_t foo;],
 298 liberty_cv_uint64=uint64_t,
 299 [AC_TRY_COMPILE(
 300 [#ifdef HAVE_LIMITS_H
 301 #include <limits.h>
 302 #endif
 303 #ifndef CHAR_BIT
 304 #define CHAR_BIT 8
 305 #endif],
 306 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 307 liberty_cv_uint64="unsigned long",
 308 [AC_TRY_COMPILE(
 309 [#ifdef HAVE_LIMITS_H
 310 #include <limits.h>
 311 #endif
 312 #ifndef CHAR_BIT
 313 #define CHAR_BIT 8
 314 #endif],
 315 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 316 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 317 AC_MSG_RESULT($liberty_cv_uint64)
 318 if test "$liberty_cv_uint64" != none; then
 319   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 320                      [Define to an unsigned 64-bit type available in the compiler.])
 321 fi
 322
 323 AC_TYPE_INTPTR_T
 324 AC_TYPE_UINTPTR_T
 325 AC_TYPE_SSIZE_T
 326
 327 # Given the above check, we always have uintptr_t or a fallback
 328 # definition.  So define HAVE_UINTPTR_T in case any imported code
 329 # relies on it.
 330 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 331
 332 AC_TYPE_PID_T
 333
 334 # This is the list of functions which libiberty will provide if they
 335 # are not available on the host.
 336
 337 funcs="asprintf"
 338 funcs="$funcs atexit"
 339 funcs="$funcs basename"
 340 funcs="$funcs bcmp"
 341 funcs="$funcs bcopy"
 342 funcs="$funcs bsearch"
 343 funcs="$funcs bzero"
 344 funcs="$funcs calloc"
 345 funcs="$funcs clock"
 346 funcs="$funcs ffs"
 347 funcs="$funcs getcwd"
 348 funcs="$funcs getpagesize"
 349 funcs="$funcs gettimeofday"
 350 funcs="$funcs index"
 351 funcs="$funcs insque"
 352 funcs="$funcs memchr"
 353 funcs="$funcs memcmp"
 354 funcs="$funcs memcpy"
 355 funcs="$funcs memmem"
 356 funcs="$funcs memmove"
 357 funcs="$funcs mempcpy"
 358 funcs="$funcs memset"
 359 funcs="$funcs mkstemps"
 360 funcs="$funcs putenv"
 361 funcs="$funcs random"
 362 funcs="$funcs rename"
 363 funcs="$funcs rindex"
 364 funcs="$funcs setenv"
 365 funcs="$funcs snprintf"
 366 funcs="$funcs sigsetmask"
 367 funcs="$funcs stpcpy"
 368 funcs="$funcs stpncpy"
 369 funcs="$funcs strcasecmp"
 370 funcs="$funcs strchr"
 371 funcs="$funcs strdup"
 372 funcs="$funcs strncasecmp"
 373 funcs="$funcs strndup"
 374 funcs="$funcs strnlen"
 375 funcs="$funcs strrchr"
 376 funcs="$funcs strstr"
 377 funcs="$funcs strtod"
 378 funcs="$funcs strtol"
 379 funcs="$funcs strtoul"
 380 funcs="$funcs strtoll"
 381 funcs="$funcs strtoull"
 382 funcs="$funcs strverscmp"
 383 funcs="$funcs tmpnam"
 384 funcs="$funcs vasprintf"
 385 funcs="$funcs vfprintf"
 386 funcs="$funcs vprintf"
 387 funcs="$funcs vsnprintf"
 388 funcs="$funcs vsprintf"
 389 funcs="$funcs waitpid"
 390 funcs="$funcs setproctitle"
 391
 392 # Also in the old function.def file: alloca, vfork, getopt.
 393
 394 vars="sys_errlist sys_nerr sys_siglist"
 395
 396 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 397  getsysinfo gettimeofday on_exit pipe2 psignal pstat_getdynamic pstat_getstatic \
 398  realpath setrlimit sbrk spawnve spawnvpe strerror strsignal sysconf sysctl \
 399  sysmp table times wait3 wait4"
 400
 401 # These are neither executed nor required, but they help keep
 402 # autoheader happy without adding a bunch of text to acconfig.h.
 403 if test "x" = "y"; then
 404   AC_CHECK_FUNCS(asprintf atexit \
 405     basename bcmp bcopy bsearch bzero \
 406     calloc canonicalize_file_name clock \
 407     dup3 \
 408     ffs __fsetlocking \
 409     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 410     index insque \
 411     memchr memcmp memcpy memmem memmove memset mkstemps \
 412     on_exit \
 413     pipe2 psignal pstat_getdynamic pstat_getstatic putenv \
 414     random realpath rename rindex \
 415     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 416      stpcpy stpncpy strcasecmp strchr strdup \
 417      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 418      strtol strtoul strtoll strtoull strverscmp sysconf sysctl sysmp \
 419     table times tmpnam \
 420     vasprintf vfprintf vprintf vsprintf \
 421     wait3 wait4 waitpid)
 422   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf, strtol, strtoul, strtoll, strtoull, strnlen])
 423   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 424   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 425   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 426 fi
 427
 428 # For each of these functions, if the host does not provide the
 429 # function we want to put FN.o in LIBOBJS, and if the host does
 430 # provide the function, we want to define HAVE_FN in config.h.
 431
 432 setobjs=
 433 CHECK=
 434 if test -n "${with_target_subdir}"; then
 435
 436   # We are being configured as a target library.  AC_REPLACE_FUNCS
 437   # may not work correctly, because the compiler may not be able to
 438   # link executables.  Note that we may still be being configured
 439   # native.
 440
 441   # If we are being configured for newlib, we know which functions
 442   # newlib provide and which ones we will be expected to provide.
 443
 444   if test "x${with_newlib}" = "xyes"; then
 445     AC_LIBOBJ([asprintf])
 446     AC_LIBOBJ([basename])
 447     AC_LIBOBJ([insque])
 448     AC_LIBOBJ([random])
 449     AC_LIBOBJ([strdup])
 450     AC_LIBOBJ([vasprintf])
 451
 452     for f in $funcs; do
 453       case "$f" in
 454         asprintf | basename | insque | random | strdup | vasprintf)
 455           ;;
 456         *)
 457           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 458           AC_DEFINE_UNQUOTED($n)
 459           ;;
 460       esac
 461     done
 462
 463     # newlib doesnt provide any of the variables in $vars, so we
 464     # dont have to check them here.
 465
 466     # Of the functions in $checkfuncs, newlib only has strerror.
 467     AC_DEFINE(HAVE_STRERROR)
 468
 469     setobjs=yes
 470
 471   fi
 472
 473   # If we are being configured for Mingw, we know which functions
 474   # Mingw provides and which ones we will be expected to provide.
 475
 476   case "${host}" in
 477   *-*-mingw*)
 478     AC_LIBOBJ([asprintf])
 479     AC_LIBOBJ([basename])
 480     AC_LIBOBJ([bcmp])
 481     AC_LIBOBJ([bcopy])
 482     AC_LIBOBJ([bzero])
 483     AC_LIBOBJ([clock])
 484     AC_LIBOBJ([ffs])
 485     AC_LIBOBJ([getpagesize])
 486     AC_LIBOBJ([index])
 487     AC_LIBOBJ([insque])
 488     AC_LIBOBJ([mempcpy])
 489     AC_LIBOBJ([mkstemps])
 490     AC_LIBOBJ([random])
 491     AC_LIBOBJ([rindex])
 492     AC_LIBOBJ([sigsetmask])
 493     AC_LIBOBJ([stpcpy])
 494     AC_LIBOBJ([stpncpy])
 495     AC_LIBOBJ([strndup])
 496     AC_LIBOBJ([strnlen])
 497     AC_LIBOBJ([strverscmp])
 498     AC_LIBOBJ([vasprintf])
 499     AC_LIBOBJ([waitpid])
 500
 501     for f in $funcs; do
 502       case "$f" in
 503         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 504           ;;
 505         *)
 506           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 507           AC_DEFINE_UNQUOTED($n)
 508           ;;
 509       esac
 510     done
 511
 512     # Mingw doesnt provide any of the variables in $vars, so we
 513     # dont have to check them here.
 514
 515     # Of the functions in $checkfuncs, Mingw only has strerror.
 516     AC_DEFINE(HAVE_STRERROR)
 517
 518     setobjs=yes
 519     ;;
 520
 521   *-*-msdosdjgpp)
 522     AC_LIBOBJ([vasprintf])
 523     AC_LIBOBJ([vsnprintf])
 524     AC_LIBOBJ([snprintf])
 525     AC_LIBOBJ([asprintf])
 526
 527     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 528              getcwd getpagesize getrusage gettimeofday \
 529              index insque memchr memcmp memcpy memmove memset psignal \
 530              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 531              strchr strdup strerror strncasecmp strrchr strstr strtod \
 532              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 533              vsprintf waitpid
 534     do
 535       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 536       AC_DEFINE_UNQUOTED($n)
 537     done
 538
 539
 540     setobjs=yes
 541     ;;
 542
 543   esac
 544
 545 else
 546
 547    # Not a target library, so we set things up to run the test suite.
 548    CHECK=really-check
 549
 550 fi
 551
 552 AC_SUBST(CHECK)
 553 AC_SUBST(target_header_dir)
 554
 555 case "${host}" in
 556   *-*-cygwin* | *-*-mingw*)
 557     AC_DEFINE(HAVE_SYS_ERRLIST)
 558     AC_DEFINE(HAVE_SYS_NERR)
 559     ;;
 560 esac
 561
 562 if test -z "${setobjs}"; then
 563   case "${host}" in
 564
 565   *-*-vxworks*)
 566     # Handle VxWorks configuration specially, since on VxWorks the
 567     # libraries are actually on the target board, not in the file
 568     # system.
 569     AC_LIBOBJ([basename])
 570     AC_LIBOBJ([getpagesize])
 571     AC_LIBOBJ([insque])
 572     AC_LIBOBJ([random])
 573     AC_LIBOBJ([strcasecmp])
 574     AC_LIBOBJ([strncasecmp])
 575     AC_LIBOBJ([strdup])
 576     AC_LIBOBJ([vfork])
 577     AC_LIBOBJ([waitpid])
 578     AC_LIBOBJ([vasprintf])
 579     for f in $funcs; do
 580       case "$f" in
 581         basename | getpagesize | insque | random | strcasecmp)
 582           ;;
 583         strncasecmp | strdup | vfork | waitpid | vasprintf)
 584           ;;
 585         *)
 586           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 587           AC_DEFINE_UNQUOTED($n)
 588           ;;
 589       esac
 590     done
 591
 592     # VxWorks doesn't provide any of the variables in $vars, so we
 593     # don't have to check them here.
 594
 595     # Of the functions in $checkfuncs, VxWorks only has strerror.
 596     AC_DEFINE(HAVE_STRERROR)
 597
 598     setobjs=yes
 599     ;;
 600
 601   esac
 602 fi
 603
 604 if test -z "${setobjs}"; then
 605
 606   case "${host}" in
 607
 608   *-*-android*)
 609     # On android, getpagesize is defined in unistd.h as a static inline
 610     # function, which AC_CHECK_FUNCS does not handle properly.
 611     ac_cv_func_getpagesize=yes
 612     ;;
 613
 614   *-*-mingw32*)
 615     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 616     # macros, so the test below won't find them.
 617     libiberty_cv_var_sys_nerr=yes
 618     libiberty_cv_var_sys_errlist=yes
 619     ;;
 620
 621   *-*-msdosdjgpp*)
 622     # vfork and fork are stubs.
 623     ac_cv_func_vfork_works=no
 624     ;;
 625
 626   *-*-uwin*)
 627     # Under some versions of uwin, vfork is notoriously buggy and the test
 628     # can hang configure; on other versions, vfork exists just as a stub.
 629     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 630     ac_cv_func_vfork_works=no
 631     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 632     # macros (actually, these are imported from a DLL, but the end effect
 633     # is the same), so the test below won't find them.
 634     libiberty_cv_var_sys_nerr=yes
 635     libiberty_cv_var_sys_errlist=yes
 636     ;;
 637
 638   *-*-*vms*)
 639     # Under VMS, vfork works very different than on Unix. The standard test
 640     # won't work, and it isn't easily adaptable. It makes more sense to
 641     # just force it.
 642     ac_cv_func_vfork_works=yes
 643     ;;
 644
 645   esac
 646
 647   # We haven't set the list of objects yet.  Use the standard autoconf
 648   # tests.  This will only work if the compiler works.
 649   AC_ISC_POSIX
 650   AC_REPLACE_FUNCS($funcs)
 651   libiberty_AC_FUNC_C_ALLOCA
 652   AC_FUNC_FORK
 653   if test $ac_cv_func_vfork_works = no; then
 654     AC_LIBOBJ([vfork])
 655   fi
 656   # We only need _doprnt if we might use it to implement v*printf.
 657   if test $ac_cv_func_vprintf != yes \
 658      || test $ac_cv_func_vfprintf != yes \
 659      || test $ac_cv_func_vsprintf != yes; then
 660     AC_REPLACE_FUNCS(_doprnt)
 661   else
 662     AC_CHECK_FUNCS(_doprnt)
 663   fi
 664
 665   for v in $vars; do
 666     AC_MSG_CHECKING([for $v])
 667     AC_CACHE_VAL(libiberty_cv_var_$v,
 668       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern int $v [];]],[[if ($v [0]) return 1;]])],
 669                       [eval "libiberty_cv_var_$v=yes"],
 670                       [eval "libiberty_cv_var_$v=no"])])
 671     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 672       AC_MSG_RESULT(yes)
 673       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 674       AC_DEFINE_UNQUOTED($n)
 675     else
 676       AC_MSG_RESULT(no)
 677     fi
 678   done
 679
 680   # special check for _system_configuration because AIX <4.3.2 do not
 681   # contain the `physmem' member.
 682   AC_MSG_CHECKING([for external symbol _system_configuration])
 683   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 684                         [[double x = _system_configuration.physmem;]])],
 685     [AC_MSG_RESULT([yes])
 686     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 687               [Define if you have the _system_configuration variable.])],
 688     [AC_MSG_RESULT([no])])
 689
 690   AC_CHECK_FUNCS($checkfuncs)
 691   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 692   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 693   AC_CHECK_DECLS([strtol, strtoul, strtoll, strtoull])
 694   AC_CHECK_DECLS([strverscmp])
 695   AC_CHECK_DECLS([strnlen])
 696   libiberty_NEED_DECLARATION(canonicalize_file_name)
 697 fi
 698
 699 # Figure out which version of pexecute to use.
 700 case "${host}" in
 701      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 702      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 703      *-*-msdos*)                pexecute=pex-msdos  ;;
 704      *)                         pexecute=pex-unix   ;;
 705 esac
 706 AC_SUBST(pexecute)
 707
 708 libiberty_AC_FUNC_STRNCMP
 709
 710 # Install a library built with a cross compiler in $(tooldir) rather
 711 # than $(libdir).
 712 if test -z "${with_cross_host}"; then
 713   INSTALL_DEST=libdir
 714 else
 715   INSTALL_DEST=tooldir
 716 fi
 717 AC_SUBST(INSTALL_DEST)
 718
 719 m4_pattern_allow(LIBOBJS)
 720 L=""
 721 for l in x $LIBOBJS; do
 722   case $l in
 723     x) ;;
 724     *) L="$L ./$l" ;;
 725   esac
 726 done
 727 LIBOBJS="$L"
 728
 729 dnl Required by html and install-html
 730 AC_SUBST(datarootdir)
 731 AC_SUBST(docdir)
 732 AC_SUBST(htmldir)
 733
 734 # We need multilib support, but only if configuring for the target.
 735 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 736 AC_CONFIG_COMMANDS([default],
 737   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 738 if test -n "$CONFIG_FILES"; then
 739   if test -n "${with_target_subdir}"; then
 740     # FIXME: We shouldn't need to set ac_file
 741     ac_file=Makefile
 742     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 743     . ${libiberty_topdir}/config-ml.in
 744   fi
 745 fi]],
 746 [[srcdir=${srcdir}
 747 host=${host}
 748 target=${target}
 749 with_target_subdir=${with_target_subdir}
 750 with_multisubdir=${with_multisubdir}
 751 ac_configure_args="--enable-multilib ${ac_configure_args}"
 752 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 753 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 754 libiberty_topdir=${libiberty_topdir}
 755 ]])
 756 AC_OUTPUT