gcc/ada/exp_tss.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              E X P _ T S S                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  Type Support Subprogram (TSS) handling
  28
  29 with Types; use Types;
  30
  31 package Exp_Tss is
  32
  33    --  A type support subprogram (TSS) is an internally generated function or
  34    --  procedure that is associated with a particular type. Examples are the
  35    --  implicit initialization procedure, and subprograms for the Input and
  36    --  Output attributes.
  37
  38    --  A given TSS is either generated once at the point of the declaration of
  39    --  the type, or it is generated as needed in clients, but only one copy is
  40    --  required in any one generated object file. The choice between these two
  41    --  possibilities is made on a TSS-by-TSS basis depending on the estimation
  42    --  of how likely the TSS is to be used. Initialization procedures fall in
  43    --  the first category, for example, since it is likely that any declared
  44    --  type will be used in a context requiring initialization, but the stream
  45    --  attributes use the second approach, since it is more likely that they
  46    --  will not be used at all, or will only be used in one client in any case.
  47
  48    -------------------------
  49    -- Current Limitations --
  50    -------------------------
  51
  52    --  In the current version of this package, only the case of generating a
  53    --  TSS at the point of declaration of the type is accomodated. A clear
  54    --  improvement would be to follow through with the full implementation
  55    --  as described above, and also accomodate the requirement of generating
  56    --  only one copy in a given object file.
  57
  58    --  For now, we deal with the local case by generating duplicate versions
  59    --  of the TSS routine, which is clearly rather inefficient in space usage.
  60    --  This is done by using Make_TSS_Name_Local to generate unique names
  61    --  for the different instances of TSS routines in a given scope.
  62
  63    ----------------
  64    -- TSS Naming --
  65    ----------------
  66
  67    --  A TSS is identified by its Chars name. The name has the form typXY,
  68    --  where typ is the type name, and XY are two characters that identify
  69    --  the particular TSS routine, using the following codes:
  70
  71    --  Note: When making additions to this list, update the list in snames.adb
  72
  73    type TSS_Name_Type is new String (1 .. 2);
  74    subtype TNT is TSS_Name_Type;
  75
  76    TSS_Deep_Adjust        : constant TNT := "DA";  -- Deep Adjust
  77    TSS_Deep_Finalize      : constant TNT := "DF";  -- Deep Finalize
  78    TSS_Deep_Initialize    : constant TNT := "DI";  -- Deep Initialize
  79    TSS_Composite_Equality : constant TNT := "EQ";  -- Composite Equality
  80    TSS_From_Any           : constant TNT := "FA";  -- PolyORB/DSA From_Any
  81    TSS_Init_Proc          : constant TNT := "IP";  -- Initialization Procedure
  82    TSS_RAS_Access         : constant TNT := "RA";  -- RAS type access
  83    TSS_RAS_Dereference    : constant TNT := "RD";  -- RAS type deference
  84    TSS_Rep_To_Pos         : constant TNT := "RP";  -- Rep to Pos conversion
  85    TSS_Slice_Assign       : constant TNT := "SA";  -- Slice assignment
  86    TSS_Stream_Input       : constant TNT := "SI";  -- Stream Input attribute
  87    TSS_Stream_Output      : constant TNT := "SO";  -- Stream Output attribute
  88    TSS_Stream_Read        : constant TNT := "SR";  -- Stream Read attribute
  89    TSS_Stream_Write       : constant TNT := "SW";  -- Stream Write attribute
  90    TSS_To_Any             : constant TNT := "TA";  -- PolyORB/DSA To_Any
  91    TSS_TypeCode           : constant TNT := "TC";  -- PolyORB/DSA TypeCode
  92
  93    --  The array below contains all valid TSS names
  94
  95    TSS_Names : constant array (Natural range <>) of TSS_Name_Type :=
  96      (TSS_Deep_Adjust,
  97       TSS_Deep_Finalize,
  98       TSS_Deep_Initialize,
  99       TSS_Composite_Equality,
 100       TSS_From_Any,
 101       TSS_Init_Proc,
 102       TSS_RAS_Access,
 103       TSS_RAS_Dereference,
 104       TSS_Rep_To_Pos,
 105       TSS_Slice_Assign,
 106       TSS_Stream_Input,
 107       TSS_Stream_Output,
 108       TSS_Stream_Read,
 109       TSS_Stream_Write,
 110       TSS_To_Any,
 111       TSS_TypeCode);
 112
 113    TSS_Null : constant TNT := "  ";
 114    --  Dummy entry used to indicated that this is not really a TSS
 115
 116    function Get_TSS_Name (E : Entity_Id) return TSS_Name_Type;
 117    --  Given an entity, if it is a TSS, then return the corresponding TSS
 118    --  name type, otherwise return TSS_Null.
 119
 120    function Make_TSS_Name
 121      (Typ : Entity_Id;
 122       Nam : TSS_Name_Type) return Name_Id;
 123    --  Construct the name as described above for the given TSS routine
 124    --  identified by Nam for the type identified by Typ.
 125
 126    function Make_TSS_Name_Local
 127      (Typ : Entity_Id;
 128       Nam : TSS_Name_Type) return Name_Id;
 129    --  Similar to the above call, but a string of the form _nnn is appended
 130    --  to the name, where nnn is a unique serial number. This is used when
 131    --  multiple instances of the same TSS routine may be generated in the
 132    --  same scope (see also discussion above of current limitations).
 133
 134    function Make_Init_Proc_Name (Typ : Entity_Id) return Name_Id;
 135    --  Version for init procs, same as Make_TSS_Name (Typ, TSS_Init_Proc)
 136
 137    function Is_TSS (E : Entity_Id; Nam : TSS_Name_Type) return Boolean;
 138    --  Determines if given entity (E) is the name of a TSS identified by Nam
 139
 140    function Is_TSS (N : Name_Id; Nam : TSS_Name_Type) return Boolean;
 141    --  Same test applied directly to a Name_Id value
 142
 143    function Is_Init_Proc (E : Entity_Id) return Boolean;
 144    --  Version for init procs, same as Is_TSS (E, TSS_Init_Proc);
 145
 146    -----------------------------------------
 147    -- TSS Data structures and Subprograms --
 148    -----------------------------------------
 149
 150    --  The TSS's for a given type are stored in an element list associated with
 151    --  the type, and referenced from the TSS_Elist field of the N_Freeze_Entity
 152    --  node associated with the type (all types that need TSS's always need to
 153    --  be explicitly frozen, so the N_Freeze_Entity node always exists).
 154
 155    function TSS (Typ : Entity_Id; Nam : TSS_Name_Type) return Entity_Id;
 156    --  Finds the TSS with the given name associated with the given type
 157    --  If no such TSS exists, then Empty is returned;
 158
 159    function TSS (Typ : Entity_Id; Nam : Name_Id) return Entity_Id;
 160    --  Finds the TSS with the given name associated with the given type. If
 161    --  no such TSS exists, then Empty is returned.
 162
 163    function Same_TSS (E1, E2 : Entity_Id) return Boolean;
 164    --  Returns True if E1 and E2 are the same kind of TSS, even if the names
 165    --  are different (i.e. if the names of E1 and E2 end with two upper case
 166    --  letters that are the same).
 167
 168    procedure Set_TSS (Typ : Entity_Id; TSS : Entity_Id);
 169    --  This procedure is used to install a newly created TSS. The second
 170    --  argument is the entity for such a new TSS. This entity is placed in
 171    --  the TSS list for the type given as the first argument, replacing an
 172    --  old entry of the same name if one was present. The tree for the body
 173    --  of this TSS, which is not analyzed yet, is placed in the actions field
 174    --  of the freeze node for the type. All such bodies are inserted into the
 175    --  main tree and analyzed at the point at which the freeze node itself is
 176    --  is expanded.
 177
 178    procedure Copy_TSS (TSS : Entity_Id; Typ : Entity_Id);
 179    --  Given an existing TSS for another type (which is already installed,
 180    --  analyzed and expanded), install it as the corresponding TSS for Typ.
 181    --  Note that this just copies a reference, not the tree. This can also
 182    --  be used to initially install a TSS in the case where the subprogram
 183    --  for the TSS has already been created and its declaration processed.
 184
 185    function Init_Proc (Typ : Entity_Id) return Entity_Id;
 186    pragma Inline (Init_Proc);
 187    --  Obtains the _init TSS entry for the given type. This function call is
 188    --  equivalent to TSS (Typ, Name_uInit). The _init TSS is the procedure
 189    --  used to initialize otherwise uninitialized instances of a type. If
 190    --  there is no _init TSS, then the type requires no initialization. Note
 191    --  that subtypes and implicit types never have an _init TSS since subtype
 192    --  objects are always initialized using the initialization procedure for
 193    --  the corresponding base type (see Base_Init_Proc function). A special
 194    --  case arises for concurrent types. Such types do not themselves have an
 195    --  init proc TSS, but initialization is required. The init proc used is
 196    --  the one fot the corresponding record type (see Base_Init_Proc).
 197
 198    function Base_Init_Proc (Typ : Entity_Id) return Entity_Id;
 199    --  Obtains the _Init TSS entry from the base type of the entity, and also
 200    --  deals with going indirect through the Corresponding_Record_Type field
 201    --  for concurrent objects (which are initialized with the initialization
 202    --  routine for the corresponding record type). Returns Empty if there is
 203    --  no _Init TSS entry for the base type.
 204
 205    procedure Set_Init_Proc (Typ : Entity_Id; Init : Entity_Id);
 206    pragma Inline (Set_Init_Proc);
 207    --  The second argument is the _init TSS to be established for the type
 208    --  given as the first argument. Equivalent to Set_TSS (Typ, Init).
 209
 210    function Has_Non_Null_Base_Init_Proc (Typ : Entity_Id) return Boolean;
 211    --  Returns true if the given type has a defined Base_Init_Proc and
 212    --  this init proc is not a null init proc (null init procs occur as
 213    --  a result of the processing for Initialize_Scalars. This function
 214    --  is used to test for the presence of an init proc in cases where
 215    --  a null init proc is considered equivalent to no init proc.
 216
 217    function Find_Inherited_TSS
 218      (Typ : Entity_Id;
 219       Nam : TSS_Name_Type) return Entity_Id;
 220    --  Returns the TSS of name Nam of Typ, or of its closest ancestor defining
 221    --  such a TSS. Empty is returned is neither Typ nor any of its ancestors
 222    --  have such a TSS.
 223
 224 end Exp_Tss;