gcc/ada/a-dynpri.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS              --
   4 --                                                                          --
   5 --                 A D A . D Y N A M I C _ P R I O R I T I E S              --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2004, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Task_Identification;
  35 --  used for Task_Id
  36 --           Current_Task
  37 --           Null_Task_Id
  38 --           Is_Terminated
  39
  40 with System.Task_Primitives.Operations;
  41 --  used for Write_Lock
  42 --           Unlock
  43 --           Set_Priority
  44 --           Wakeup
  45 --           Self
  46
  47 with System.Tasking;
  48 --  used for Task_Id
  49
  50 with Ada.Exceptions;
  51 --  used for Raise_Exception
  52
  53 with System.Tasking.Initialization;
  54 --  used for Defer/Undefer_Abort
  55
  56 with System.Parameters;
  57 --  used for Single_Lock
  58
  59 with Unchecked_Conversion;
  60
  61 package body Ada.Dynamic_Priorities is
  62
  63    package STPO renames System.Task_Primitives.Operations;
  64
  65    use System.Parameters;
  66    use System.Tasking;
  67    use Ada.Exceptions;
  68
  69    function Convert_Ids is new
  70      Unchecked_Conversion
  71        (Task_Identification.Task_Id, System.Tasking.Task_Id);
  72
  73    ------------------
  74    -- Get_Priority --
  75    ------------------
  76
  77    --  Inquire base priority of a task
  78
  79    function Get_Priority
  80      (T : Ada.Task_Identification.Task_Id :=
  81         Ada.Task_Identification.Current_Task) return System.Any_Priority
  82    is
  83       Target : constant Task_Id := Convert_Ids (T);
  84       Error_Message : constant String := "Trying to get the priority of a ";
  85
  86    begin
  87       if Target = Convert_Ids (Ada.Task_Identification.Null_Task_Id) then
  88          Raise_Exception (Program_Error'Identity,
  89            Error_Message & "null task");
  90       end if;
  91
  92       if Task_Identification.Is_Terminated (T) then
  93          Raise_Exception (Tasking_Error'Identity,
  94            Error_Message & "null task");
  95       end if;
  96
  97       return Target.Common.Base_Priority;
  98    end Get_Priority;
  99
 100    ------------------
 101    -- Set_Priority --
 102    ------------------
 103
 104    --  Change base priority of a task dynamically
 105
 106    procedure Set_Priority
 107      (Priority : System.Any_Priority;
 108       T        : Ada.Task_Identification.Task_Id :=
 109                    Ada.Task_Identification.Current_Task)
 110    is
 111       Target  : constant Task_Id := Convert_Ids (T);
 112       Self_ID : constant Task_Id := STPO.Self;
 113       Error_Message : constant String := "Trying to set the priority of a ";
 114
 115    begin
 116       if Target = Convert_Ids (Ada.Task_Identification.Null_Task_Id) then
 117          Raise_Exception (Program_Error'Identity,
 118            Error_Message & "null task");
 119       end if;
 120
 121       if Task_Identification.Is_Terminated (T) then
 122          Raise_Exception (Tasking_Error'Identity,
 123            Error_Message & "terminated task");
 124       end if;
 125
 126       Initialization.Defer_Abort (Self_ID);
 127
 128       if Single_Lock then
 129          STPO.Lock_RTS;
 130       end if;
 131
 132       STPO.Write_Lock (Target);
 133
 134       if Self_ID = Target then
 135          Target.Common.Base_Priority := Priority;
 136          STPO.Set_Priority (Target, Priority);
 137
 138          STPO.Unlock (Target);
 139
 140          if Single_Lock then
 141             STPO.Unlock_RTS;
 142          end if;
 143
 144          --  Yield is needed to enforce FIFO task dispatching.
 145
 146          --  LL Set_Priority is made while holding the RTS lock so that it
 147          --  is inheriting high priority until it release all the RTS locks.
 148
 149          --  If this is used in a system where Ceiling Locking is
 150          --  not enforced we may end up getting two Yield effects.
 151
 152          STPO.Yield;
 153
 154       else
 155          Target.New_Base_Priority := Priority;
 156          Target.Pending_Priority_Change := True;
 157          Target.Pending_Action := True;
 158
 159          STPO.Wakeup (Target, Target.Common.State);
 160
 161          --  If the task is suspended, wake it up to perform the change.
 162          --  check for ceiling violations ???
 163
 164          STPO.Unlock (Target);
 165
 166          if Single_Lock then
 167             STPO.Unlock_RTS;
 168          end if;
 169       end if;
 170
 171       Initialization.Undefer_Abort (Self_ID);
 172    end Set_Priority;
 173
 174 end Ada.Dynamic_Priorities;