gcc/ada/a-dirval-vms.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --             A D A . D I R E C T O R I E S . V A L I D I T Y              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                              (VMS Version)                               --
   9 --                                                                          --
  10 --          Copyright (C) 2004 Free Software Foundation, Inc.               --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This is the OpenVMS version of this package
  36
  37 package body Ada.Directories.Validity is
  38
  39    Max_Number_Of_Characters : constant := 39;
  40    Max_Path_Length          : constant := 1_024;
  41
  42    Invalid_Character : constant array (Character) of Boolean :=
  43                          ('a' .. 'z' => False,
  44                           'A' .. 'Z' => False,
  45                           '_' | '$' | '-' | '.' => False,
  46                           others => True);
  47
  48    ---------------------------------
  49    -- Is_Path_Name_Case_Sensitive --
  50    ---------------------------------
  51
  52    function Is_Path_Name_Case_Sensitive return Boolean is
  53    begin
  54       return False;
  55    end Is_Path_Name_Case_Sensitive;
  56
  57    ------------------------
  58    -- Is_Valid_Path_Name --
  59    ------------------------
  60
  61    function Is_Valid_Path_Name (Name : String) return Boolean is
  62       First     : Positive := Name'First;
  63       Last      : Positive;
  64       Dot_Found : Boolean := False;
  65
  66    begin
  67       --  A valid path (directory) name cannot be empty, and cannot contain
  68       --  more than 1024 characters. Directories can be ".", ".." or be simple
  69       --  name without extensions.
  70
  71       if Name'Length = 0 or else Name'Length > Max_Path_Length then
  72          return False;
  73
  74       else
  75          loop
  76             --  Look for the start of the next directory or file name
  77
  78             while First <= Name'Last and then Name (First) = '/' loop
  79                First := First + 1;
  80             end loop;
  81
  82             --  If all directories/file names are OK, return True
  83
  84             exit when First > Name'Last;
  85
  86             Last := First;
  87             Dot_Found := False;
  88
  89             --  Look for the end of the directory/file name
  90
  91             while Last < Name'Last loop
  92                exit when Name (Last + 1) = '/';
  93                Last := Last + 1;
  94
  95                if Name (Last) = '.' then
  96                   Dot_Found := True;
  97                end if;
  98             end loop;
  99
 100             --  If name include a dot, it can only be ".", ".." or a the last
 101             --  file name.
 102
 103             if Dot_Found then
 104                if Name (First .. Last) /= "." and then
 105                   Name (First .. Last) /= ".."
 106                then
 107                   return Last = Name'Last
 108                     and then Is_Valid_Simple_Name (Name (First .. Last));
 109
 110                end if;
 111
 112             --  Check if the directory/file name is valid
 113
 114             elsif not Is_Valid_Simple_Name (Name (First .. Last)) then
 115                   return False;
 116             end if;
 117
 118             --  Move to the next name
 119
 120             First := Last + 1;
 121          end loop;
 122       end if;
 123
 124       --  If Name follows the rules, then it is valid
 125
 126       return True;
 127    end Is_Valid_Path_Name;
 128
 129    --------------------------
 130    -- Is_Valid_Simple_Name --
 131    --------------------------
 132
 133    function Is_Valid_Simple_Name (Name : String) return Boolean is
 134       In_Extension         : Boolean := False;
 135       Number_Of_Characters : Natural := 0;
 136
 137    begin
 138       --  A file name cannot be empty, and cannot have more than 39 characters
 139       --  before or after a single '.'.
 140
 141       if Name'Length = 0 then
 142          return False;
 143
 144       else
 145          --  Check each character for validity
 146
 147          for J in Name'Range loop
 148             if Invalid_Character (Name (J)) then
 149                return False;
 150
 151             elsif Name (J) = '.' then
 152
 153                --  Name cannot contain several dots
 154
 155                if In_Extension then
 156                   return False;
 157
 158                else
 159                   --  Reset the number of characters to count the characters
 160                   --  of the extension.
 161
 162                   In_Extension := True;
 163                   Number_Of_Characters := 0;
 164                end if;
 165
 166             else
 167                --  Check that the number of character is not too large
 168
 169                Number_Of_Characters := Number_Of_Characters + 1;
 170
 171                if Number_Of_Characters > Max_Number_Of_Characters then
 172                   return False;
 173                end if;
 174             end if;
 175          end loop;
 176       end if;
 177
 178       --  If the rules are followed, then it is valid
 179
 180       return True;
 181    end Is_Valid_Simple_Name;
 182
 183 end Ada.Directories.Validity;