| blob | 10dac63dcf093c32db52deecebb4ac77d36e7306 |
1 dnl
2 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
3 dnl
4 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
5 dnl end of configure. This lets tested variables be reassigned, and the
6 dnl conditional will depend on the final state of the variable. For a simple
7 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
8 dnl
9 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
10 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
11 m4_divert_text([glibcxx_diversion],dnl
12 AM_CONDITIONAL([$1],[$2])
13 )dnl
14 ])dnl
15 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
18 dnl
19 dnl Check to see what architecture and operating system we are compiling
20 dnl for. Also, if architecture- or OS-specific flags are required for
21 dnl compilation, pick them up here.
22 dnl
23 AC_DEFUN([GLIBCXX_CHECK_HOST], [
24 . $glibcxx_srcdir/configure.host
25 AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
26 AC_MSG_NOTICE([OS config directory is $os_include_dir])
27 ])
29 dnl
30 dnl Initialize the rest of the library configury. At this point we have
31 dnl variables like $host.
32 dnl
33 dnl Sets:
34 dnl SUBDIRS
35 dnl Substs:
36 dnl glibcxx_builddir (absolute path)
37 dnl glibcxx_srcdir (absolute path)
38 dnl toplevel_builddir (absolute path)
39 dnl toplevel_srcdir (absolute path)
40 dnl with_cross_host
41 dnl with_newlib
42 dnl with_target_subdir
43 dnl plus
44 dnl - the variables in GLIBCXX_CHECK_HOST / configure.host
45 dnl - default settings for all AM_CONFITIONAL test variables
46 dnl - lots of tools, like CC and CXX
47 dnl
48 AC_DEFUN([GLIBCXX_CONFIGURE], [
49 # Keep these sync'd with the list in Makefile.am. The first provides an
50 # expandable list at autoconf time; the second provides an expandable list
51 # (i.e., shell variable) at configure time.
52 m4_define([glibcxx_SUBDIRS],[include libsupc++ python src src/c++98 src/c++11 doc po testsuite])
53 SUBDIRS='glibcxx_SUBDIRS'
55 # These need to be absolute paths, yet at the same time need to
56 # canonicalize only relative paths, because then amd will not unmount
57 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
58 glibcxx_builddir=`${PWDCMD-pwd}`
59 case $srcdir in
60 [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
61 *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
62 esac
63 toplevel_builddir=${glibcxx_builddir}/..
64 toplevel_srcdir=${glibcxx_srcdir}/..
65 AC_SUBST(glibcxx_builddir)
66 AC_SUBST(glibcxx_srcdir)
67 AC_SUBST(toplevel_builddir)
68 AC_SUBST(toplevel_srcdir)
70 # We use these options to decide which functions to include. They are
71 # set from the top level.
72 AC_ARG_WITH([target-subdir],
73 AC_HELP_STRING([--with-target-subdir=SUBDIR],
74 [configuring in a subdirectory]))
76 AC_ARG_WITH([cross-host],
77 AC_HELP_STRING([--with-cross-host=HOST],
78 [configuring with a cross compiler]))
80 AC_ARG_WITH([newlib],
81 AC_HELP_STRING([--with-newlib],
82 [assume newlib as a system C library]))
84 # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
85 # available). Uncomment the next line to force a particular method.
86 AC_PROG_LN_S
87 #LN_S='cp -p'
89 AC_CHECK_TOOL(AS, as)
90 AC_CHECK_TOOL(AR, ar)
91 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
93 AM_MAINTAINER_MODE
95 # Set up safe default values for all subsequent AM_CONDITIONAL tests
96 # which are themselves conditionally expanded.
97 ## (Right now, this only matters for enable_wchar_t, but nothing prevents
98 ## other macros from doing the same. This should be automated.) -pme
100 # Check for C library flavor since GNU/Linux platforms use different
101 # configuration directories depending on the C library in use.
102 AC_EGREP_CPP([_using_uclibc], [
103 #include <stdio.h>
104 #if __UCLIBC__
105 _using_uclibc
106 #endif
107 ], uclibc=yes, uclibc=no)
109 AC_EGREP_CPP([_using_bionic], [
110 #include <stdio.h>
111 #if __BIONIC__
112 _using_bionic
113 #endif
114 ], bionic=yes, bionic=no)
116 # Find platform-specific directories containing configuration info.
117 # Also possibly modify flags used elsewhere, as needed by the platform.
118 GLIBCXX_CHECK_HOST
119 ])
122 dnl
123 dnl Tests for newer compiler features, or features that are present in newer
124 dnl compiler versions but not older compiler versions still in use, should
125 dnl be placed here.
126 dnl
127 dnl Defines:
128 dnl WERROR='-Werror' if requested and possible; g++'s that lack the
129 dnl new inlining code or the new system_header pragma will die on -Werror.
130 dnl Leave it out by default and use maint-mode to use it.
131 dnl SECTION_FLAGS='-ffunction-sections -fdata-sections' if
132 dnl compiler supports it and the user has not requested debug mode.
133 dnl
134 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
135 # All these tests are for C++; save the language and the compiler flags.
136 # The CXXFLAGS thing is suspicious, but based on similar bits previously
137 # found in GLIBCXX_CONFIGURE.
138 AC_LANG_SAVE
139 AC_LANG_CPLUSPLUS
140 ac_test_CXXFLAGS="${CXXFLAGS+set}"
141 ac_save_CXXFLAGS="$CXXFLAGS"
143 # Check for maintainer-mode bits.
144 if test x"$USE_MAINTAINER_MODE" = xno; then
145 WERROR=''
146 else
147 WERROR='-Werror'
148 fi
150 # Check for -ffunction-sections -fdata-sections
151 AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
152 CXXFLAGS='-g -Werror -ffunction-sections -fdata-sections'
153 AC_TRY_COMPILE([int foo; void bar() { };],, [ac_fdsections=yes], [ac_fdsections=no])
154 if test "$ac_test_CXXFLAGS" = set; then
155 CXXFLAGS="$ac_save_CXXFLAGS"
156 else
157 # this is the suspicious part
158 CXXFLAGS=''
159 fi
160 if test x"$ac_fdsections" = x"yes"; then
161 SECTION_FLAGS='-ffunction-sections -fdata-sections'
162 fi
163 AC_MSG_RESULT($ac_fdsections)
165 AC_LANG_RESTORE
166 AC_SUBST(WERROR)
167 AC_SUBST(SECTION_FLAGS)
168 ])
171 dnl
172 dnl Check if the assembler used supports disabling generation of hardware
173 dnl capabilities. This is only supported by Sun as at the moment.
174 dnl
175 dnl Defines:
176 dnl HWCAP_FLAGS='-Wa,-nH' if possible.
177 dnl
178 AC_DEFUN([GLIBCXX_CHECK_ASSEMBLER_HWCAP], [
179 test -z "$HWCAP_FLAGS" && HWCAP_FLAGS=''
181 ac_save_CFLAGS="$CFLAGS"
182 CFLAGS="$CFLAGS -Wa,-nH"
184 AC_MSG_CHECKING([for as that supports -Wa,-nH])
185 AC_TRY_COMPILE([], [return 0;], [ac_hwcap_flags=yes],[ac_hwcap_flags=no])
186 if test "$ac_hwcap_flags" = "yes"; then
187 HWCAP_FLAGS="-Wa,-nH $HWCAP_FLAGS"
188 fi
189 AC_MSG_RESULT($ac_hwcap_flags)
191 CFLAGS="$ac_save_CFLAGS"
193 AC_SUBST(HWCAP_FLAGS)
194 ])
197 dnl
198 dnl If GNU ld is in use, check to see if tricky linker opts can be used. If
199 dnl the native linker is in use, all variables will be defined to something
200 dnl safe (like an empty string).
201 dnl
202 dnl Defines:
203 dnl SECTION_LDFLAGS='-Wl,--gc-sections' if possible
204 dnl OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
205 dnl LD (as a side effect of testing)
206 dnl Sets:
207 dnl with_gnu_ld
208 dnl glibcxx_ld_is_gold (set to "no" or "yes")
209 dnl glibcxx_gnu_ld_version (possibly)
210 dnl
211 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
212 dnl set glibcxx_gnu_ld_version to 12345. Zeros cause problems.
213 dnl
214 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
215 # If we're not using GNU ld, then there's no point in even trying these
216 # tests. Check for that first. We should have already tested for gld
217 # by now (in libtool), but require it now just to be safe...
218 test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
219 test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
220 AC_REQUIRE([AC_PROG_LD])
221 AC_REQUIRE([AC_PROG_AWK])
223 # The name set by libtool depends on the version of libtool. Shame on us
224 # for depending on an impl detail, but c'est la vie. Older versions used
225 # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
226 # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
227 # makes sense). We'll test with_gnu_ld everywhere else, so if that isn't
228 # set (hence we're using an older libtool), then set it.
229 if test x${with_gnu_ld+set} != xset; then
230 if test x${ac_cv_prog_gnu_ld+set} != xset; then
231 # We got through "ac_require(ac_prog_ld)" and still not set? Huh?
232 with_gnu_ld=no
233 else
234 with_gnu_ld=$ac_cv_prog_gnu_ld
235 fi
236 fi
238 # Start by getting the version number. I think the libtool test already
239 # does some of this, but throws away the result.
240 glibcxx_ld_is_gold=no
241 if test x"$with_gnu_ld" = x"yes"; then
242 AC_MSG_CHECKING([for ld version])
243 changequote(,)
244 if $LD --version 2>/dev/null | grep 'GNU gold' >/dev/null 2>&1; then
245 glibcxx_ld_is_gold=yes
246 fi
247 ldver=`$LD --version 2>/dev/null |
248 sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
249 changequote([,])
250 glibcxx_gnu_ld_version=`echo $ldver | \
251 $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
252 AC_MSG_RESULT($glibcxx_gnu_ld_version)
253 fi
255 # Set --gc-sections.
256 glibcxx_have_gc_sections=no
257 if test "$glibcxx_ld_is_gold" = "yes"; then
258 if $LD --help 2>/dev/null | grep gc-sections >/dev/null 2>&1; then
259 glibcxx_have_gc_sections=yes
260 fi
261 else
262 glibcxx_gcsections_min_ld=21602
263 if test x"$with_gnu_ld" = x"yes" &&
264 test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
265 glibcxx_have_gc_sections=yes
266 fi
267 fi
268 if test "$glibcxx_have_gc_sections" = "yes"; then
269 # Sufficiently young GNU ld it is! Joy and bunny rabbits!
270 # NB: This flag only works reliably after 2.16.1. Configure tests
271 # for this are difficult, so hard wire a value that should work.
273 ac_test_CFLAGS="${CFLAGS+set}"
274 ac_save_CFLAGS="$CFLAGS"
275 CFLAGS='-Wl,--gc-sections'
277 # Check for -Wl,--gc-sections
278 AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
279 AC_TRY_LINK([ int one(void) { return 1; }
280 int two(void) { return 2; }
281 ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
282 if test "$ac_gcsections" = "yes"; then
283 rm -f conftest.c
284 touch conftest.c
285 if $CC -c conftest.c; then
286 if $LD --gc-sections -o conftest conftest.o 2>&1 | \
287 grep "Warning: gc-sections option ignored" > /dev/null; then
288 ac_gcsections=no
289 fi
290 fi
291 rm -f conftest.c conftest.o conftest
292 fi
293 if test "$ac_gcsections" = "yes"; then
294 SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
295 fi
296 AC_MSG_RESULT($ac_gcsections)
298 if test "$ac_test_CFLAGS" = set; then
299 CFLAGS="$ac_save_CFLAGS"
300 else
301 # this is the suspicious part
302 CFLAGS=''
303 fi
304 fi
306 # Set -z,relro.
307 # Note this is only for shared objects.
308 ac_ld_relro=no
309 if test x"$with_gnu_ld" = x"yes"; then
310 AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
311 cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
312 if test -n "$cxx_z_relo"; then
313 OPT_LDFLAGS="-Wl,-z,relro"
314 ac_ld_relro=yes
315 fi
316 AC_MSG_RESULT($ac_ld_relro)
317 fi
319 # Set linker optimization flags.
320 if test x"$with_gnu_ld" = x"yes"; then
321 OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
322 fi
324 AC_SUBST(SECTION_LDFLAGS)
325 AC_SUBST(OPT_LDFLAGS)
326 ])
329 dnl
330 dnl Check for headers for, and arguments to, the setrlimit() function.
331 dnl Used only in testsuite_hooks.h. Called from GLIBCXX_CONFIGURE_TESTSUITE.
332 dnl
333 dnl Defines:
334 dnl _GLIBCXX_RES_LIMITS if we can set artificial resource limits
335 dnl various HAVE_LIMIT_* for individual limit names
336 dnl
337 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
338 AC_MSG_CHECKING([for RLIMIT_$1])
339 AC_TRY_COMPILE(
340 [#include <unistd.h>
341 #include <sys/time.h>
342 #include <sys/resource.h>
343 ],
344 [ int f = RLIMIT_$1 ; ],
345 [glibcxx_mresult=1], [glibcxx_mresult=0])
346 AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
347 [Only used in build directory testsuite_hooks.h.])
348 if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
349 AC_MSG_RESULT($res)
350 ])
352 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
353 setrlimit_have_headers=yes
354 AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
355 [],
356 [setrlimit_have_headers=no])
357 # If don't have the headers, then we can't run the tests now, and we
358 # won't be seeing any of these during testsuite compilation.
359 if test $setrlimit_have_headers = yes; then
360 # Can't do these in a loop, else the resulting syntax is wrong.
361 GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
362 GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
363 GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
364 GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
365 GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
367 # Check for rlimit, setrlimit.
368 AC_CACHE_VAL(glibcxx_cv_setrlimit, [
369 AC_TRY_COMPILE(
370 [#include <unistd.h>
371 #include <sys/time.h>
372 #include <sys/resource.h>
373 ],
374 [struct rlimit r;
375 setrlimit(0, &r);],
376 [glibcxx_cv_setrlimit=yes], [glibcxx_cv_setrlimit=no])
377 ])
378 fi
380 AC_MSG_CHECKING([for testsuite resource limits support])
381 if test $setrlimit_have_headers = yes && test $glibcxx_cv_setrlimit = yes; then
382 ac_res_limits=yes
383 AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
384 [Define if using setrlimit to set resource limits during
385 "make check"])
386 else
387 ac_res_limits=no
388 fi
389 AC_MSG_RESULT($ac_res_limits)
390 ])
393 dnl
394 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
395 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
396 dnl
397 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
399 AC_LANG_SAVE
400 AC_LANG_CPLUSPLUS
401 ac_save_CXXFLAGS="$CXXFLAGS"
402 CXXFLAGS="$CXXFLAGS -fno-exceptions"
404 AC_MSG_CHECKING([for S_ISREG or S_IFREG])
405 AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
406 GCC_TRY_COMPILE_OR_LINK(
407 [#include <sys/stat.h>],
408 [struct stat buffer;
409 fstat(0, &buffer);
410 S_ISREG(buffer.st_mode);],
411 [glibcxx_cv_S_ISREG=yes],
412 [glibcxx_cv_S_ISREG=no])
413 ])
414 AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
415 GCC_TRY_COMPILE_OR_LINK(
416 [#include <sys/stat.h>],
417 [struct stat buffer;
418 fstat(0, &buffer);
419 S_IFREG & buffer.st_mode;],
420 [glibcxx_cv_S_IFREG=yes],
421 [glibcxx_cv_S_IFREG=no])
422 ])
423 res=no
424 if test $glibcxx_cv_S_ISREG = yes; then
425 AC_DEFINE(HAVE_S_ISREG, 1,
426 [Define if S_IFREG is available in <sys/stat.h>.])
427 res=S_ISREG
428 elif test $glibcxx_cv_S_IFREG = yes; then
429 AC_DEFINE(HAVE_S_IFREG, 1,
430 [Define if S_IFREG is available in <sys/stat.h>.])
431 res=S_IFREG
432 fi
433 AC_MSG_RESULT($res)
435 CXXFLAGS="$ac_save_CXXFLAGS"
436 AC_LANG_RESTORE
437 ])
440 dnl
441 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
442 dnl
443 AC_DEFUN([GLIBCXX_CHECK_POLL], [
445 AC_LANG_SAVE
446 AC_LANG_CPLUSPLUS
447 ac_save_CXXFLAGS="$CXXFLAGS"
448 CXXFLAGS="$CXXFLAGS -fno-exceptions"
450 AC_MSG_CHECKING([for poll])
451 AC_CACHE_VAL(glibcxx_cv_POLL, [
452 GCC_TRY_COMPILE_OR_LINK(
453 [#include <poll.h>],
454 [struct pollfd pfd[1];
455 pfd[0].events = POLLIN;
456 poll(pfd, 1, 0);],
457 [glibcxx_cv_POLL=yes],
458 [glibcxx_cv_POLL=no])
459 ])
460 if test $glibcxx_cv_POLL = yes; then
461 AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
462 fi
463 AC_MSG_RESULT($glibcxx_cv_POLL)
465 CXXFLAGS="$ac_save_CXXFLAGS"
466 AC_LANG_RESTORE
467 ])
470 dnl
471 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
472 dnl
473 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
475 AC_LANG_SAVE
476 AC_LANG_CPLUSPLUS
477 ac_save_CXXFLAGS="$CXXFLAGS"
478 CXXFLAGS="$CXXFLAGS -fno-exceptions"
480 AC_MSG_CHECKING([for writev])
481 AC_CACHE_VAL(glibcxx_cv_WRITEV, [
482 GCC_TRY_COMPILE_OR_LINK(
483 [#include <sys/uio.h>],
484 [struct iovec iov[2];
485 writev(0, iov, 0);],
486 [glibcxx_cv_WRITEV=yes],
487 [glibcxx_cv_WRITEV=no])
488 ])
489 if test $glibcxx_cv_WRITEV = yes; then
490 AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
491 fi
492 AC_MSG_RESULT($glibcxx_cv_WRITEV)
494 CXXFLAGS="$ac_save_CXXFLAGS"
495 AC_LANG_RESTORE
496 ])
499 dnl
500 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
501 dnl Also check whether int64_t is actually a typedef to long or long long.
502 dnl
503 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
505 AC_LANG_SAVE
506 AC_LANG_CPLUSPLUS
508 AC_MSG_CHECKING([for int64_t])
509 AC_CACHE_VAL(glibcxx_cv_INT64_T, [
510 AC_TRY_COMPILE(
511 [#include <stdint.h>],
512 [int64_t var;],
513 [glibcxx_cv_INT64_T=yes],
514 [glibcxx_cv_INT64_T=no])
515 ])
517 if test $glibcxx_cv_INT64_T = yes; then
518 AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
519 AC_MSG_RESULT($glibcxx_cv_INT64_T)
521 AC_MSG_CHECKING([for int64_t as long])
522 AC_CACHE_VAL(glibcxx_cv_int64_t_long, [
523 AC_TRY_COMPILE(
524 [#include <stdint.h>
525 template<typename, typename> struct same { enum { value = -1 }; };
526 template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
527 int array[same<int64_t, long>::value];], [],
528 [glibcxx_cv_int64_t_long=yes], [glibcxx_cv_int64_t_long=no])
529 ])
531 if test $glibcxx_cv_int64_t_long = yes; then
532 AC_DEFINE(HAVE_INT64_T_LONG, 1, [Define if int64_t is a long.])
533 AC_MSG_RESULT($glibcxx_cv_int64_t_long)
534 fi
536 AC_MSG_CHECKING([for int64_t as long long])
537 AC_CACHE_VAL(glibcxx_cv_int64_t_long_long, [
538 AC_TRY_COMPILE(
539 [#include <stdint.h>
540 template<typename, typename> struct same { enum { value = -1 }; };
541 template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
542 int array[same<int64_t, long long>::value];], [],
543 [glibcxx_cv_int64_t_long_long=yes], [glibcxx_cv_int64_t_long_long=no])
544 ])
546 if test $glibcxx_cv_int64_t_long_long = yes; then
547 AC_DEFINE(HAVE_INT64_T_LONG_LONG, 1, [Define if int64_t is a long long.])
548 AC_MSG_RESULT($glibcxx_cv_int64_t_long_long)
549 fi
550 fi
552 AC_LANG_RESTORE
553 ])
556 dnl
557 dnl Check whether LFS support is available.
558 dnl
559 AC_DEFUN([GLIBCXX_CHECK_LFS], [
560 AC_LANG_SAVE
561 AC_LANG_CPLUSPLUS
562 ac_save_CXXFLAGS="$CXXFLAGS"
563 CXXFLAGS="$CXXFLAGS -fno-exceptions"
564 AC_MSG_CHECKING([for LFS support])
565 AC_CACHE_VAL(glibcxx_cv_LFS, [
566 GCC_TRY_COMPILE_OR_LINK(
567 [#include <unistd.h>
568 #include <stdio.h>
569 #include <sys/stat.h>
570 ],
571 [FILE* fp;
572 fopen64("t", "w");
573 fseeko64(fp, 0, SEEK_CUR);
574 ftello64(fp);
575 lseek64(1, 0, SEEK_CUR);
576 struct stat64 buf;
577 fstat64(1, &buf);],
578 [glibcxx_cv_LFS=yes],
579 [glibcxx_cv_LFS=no])
580 ])
581 if test $glibcxx_cv_LFS = yes; then
582 AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
583 fi
584 AC_MSG_RESULT($glibcxx_cv_LFS)
585 CXXFLAGS="$ac_save_CXXFLAGS"
586 AC_LANG_RESTORE
587 ])
590 dnl
591 dnl Check for whether a fully dynamic basic_string implementation should
592 dnl be turned on, that does not put empty objects in per-process static
593 dnl memory (mostly useful together with shared memory allocators, see PR
594 dnl libstdc++/16612 for details).
595 dnl
596 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 1
597 dnl --disable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 0
598 dnl otherwise undefined
599 dnl + Usage: GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
600 dnl Where DEFAULT is either `yes' or `no'.
601 dnl
602 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
603 GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
604 if test $enable_fully_dynamic_string = yes; then
605 enable_fully_dynamic_string_def=1
606 else
607 enable_fully_dynamic_string_def=0
608 fi
609 AC_DEFINE_UNQUOTED([_GLIBCXX_FULLY_DYNAMIC_STRING], [${enable_fully_dynamic_string_def}],
610 [Define to 1 if a fully dynamic basic_string is wanted, 0 to disable, undefined for platform defaults])
611 ])
614 dnl
615 dnl Does any necessary configuration of the testsuite directory. Generates
616 dnl the testsuite_hooks.h header.
617 dnl
618 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
619 dnl
620 dnl Sets:
621 dnl enable_abi_check
622 dnl GLIBCXX_TEST_WCHAR_T
623 dnl GLIBCXX_TEST_THREAD
624 dnl Substs:
625 dnl baseline_dir
626 dnl baseline_subdir_switch
627 dnl
628 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
629 if $GLIBCXX_IS_NATIVE ; then
630 # Do checks for resource limit functions.
631 GLIBCXX_CHECK_SETRLIMIT
633 # Look for setenv, so that extended locale tests can be performed.
634 GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
635 fi
637 if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
638 test $enable_symvers != no; then
639 case "$host" in
640 *-*-cygwin*)
641 enable_abi_check=no ;;
642 *)
643 enable_abi_check=yes ;;
644 esac
645 else
646 # Only build this as native, since automake does not understand
647 # CXX_FOR_BUILD.
648 enable_abi_check=no
649 fi
651 # Export file names for ABI checking.
652 baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}"
653 AC_SUBST(baseline_dir)
654 baseline_subdir_switch="$abi_baseline_subdir_switch"
655 AC_SUBST(baseline_subdir_switch)
656 ])
659 dnl
660 dnl Does any necessary configuration for docbook in the docs directory.
661 dnl
662 dnl XSLTPROC must be set before this
663 dnl
664 dnl Sets:
665 dnl glibcxx_stylesheets
666 dnl Substs:
667 dnl XSL_STYLE_DIR
668 dnl
669 AC_DEFUN([GLIBCXX_CONFIGURE_DOCBOOK], [
671 AC_MSG_CHECKING([for docbook stylesheets for documentation creation])
672 glibcxx_stylesheets=no
673 if test x${XSLTPROC} = xyes && echo '<title/>' | xsltproc --noout --nonet --xinclude http://docbook.sourceforge.net/release/xsl-ns/current/xhtml-1_1/docbook.xsl - 2>/dev/null; then
674 glibcxx_stylesheets=yes
675 fi
676 AC_MSG_RESULT($glibcxx_stylesheets)
678 AC_MSG_CHECKING([for local stylesheet directory])
679 glibcxx_local_stylesheets=no
680 if test x"$glibcxx_stylesheets" = x"yes"; then
681 if test -d /usr/share/sgml/docbook/xsl-ns-stylesheets; then
682 glibcxx_local_stylesheets=yes
683 XSL_STYLE_DIR=/usr/share/sgml/docbook/xsl-ns-stylesheets
684 fi
685 if test -d /usr/share/xml/docbook/stylesheet/docbook-xsl-ns; then
686 glibcxx_local_stylesheets=yes
687 XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/docbook-xsl-ns
688 fi
689 fi
690 AC_MSG_RESULT($glibcxx_local_stylesheets)
692 if test x"$glibcxx_local_stylesheets" = x"yes"; then
693 AC_SUBST(XSL_STYLE_DIR)
694 AC_MSG_NOTICE($XSL_STYLE_DIR)
695 else
696 glibcxx_stylesheets=no
697 fi
699 # Check for epub3 dependencies.
700 AC_MSG_CHECKING([for epub3 stylesheets for documentation creation])
701 glibcxx_epub_stylesheets=no
702 if test x"$glibcxx_local_stylesheets" = x"yes"; then
703 if test -f "$XSL_STYLE_DIR/epub3/chunk.xsl"; then
704 glibcxx_epub_stylesheets=yes
705 fi
706 fi
707 AC_MSG_RESULT($glibcxx_epub_stylesheets)
708 AM_CONDITIONAL(BUILD_EPUB, test x"$glibcxx_epub_stylesheets" = x"yes")
710 ])
713 dnl
714 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
715 dnl
716 dnl Substs:
717 dnl GLIBCXX_INCLUDES
718 dnl TOPLEVEL_INCLUDES
719 dnl
720 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
721 # Used for every C++ compile we perform.
722 GLIBCXX_INCLUDES="\
723 -I$glibcxx_builddir/include/$host_alias \
724 -I$glibcxx_builddir/include \
725 -I$glibcxx_srcdir/libsupc++"
727 # For Canadian crosses, pick this up too.
728 if test $CANADIAN = yes; then
729 GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
730 fi
732 # Stuff in the actual top level. Currently only used by libsupc++ to
733 # get unwind* headers from the libgcc dir.
734 #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc -I$(toplevel_srcdir)/include'
735 TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc'
737 # Now, export this to all the little Makefiles....
738 AC_SUBST(GLIBCXX_INCLUDES)
739 AC_SUBST(TOPLEVEL_INCLUDES)
740 ])
743 dnl
744 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
745 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
746 dnl
747 dnl Substs:
748 dnl OPTIMIZE_CXXFLAGS
749 dnl WARN_FLAGS
750 dnl
751 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
752 # Optimization flags that are probably a good idea for thrill-seekers. Just
753 # uncomment the lines below and make, everything else is ready to go...
754 # Alternatively OPTIMIZE_CXXFLAGS can be set in configure.host.
755 # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
756 AC_SUBST(OPTIMIZE_CXXFLAGS)
758 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual -Wabi'
759 AC_SUBST(WARN_FLAGS)
760 ])
763 dnl
764 dnl All installation directory information is determined here.
765 dnl
766 dnl Substs:
767 dnl gxx_install_dir
768 dnl glibcxx_prefixdir
769 dnl glibcxx_toolexecdir
770 dnl glibcxx_toolexeclibdir
771 dnl
772 dnl Assumes cross_compiling bits already done, and with_cross_host in
773 dnl particular.
774 dnl
775 dnl This logic must match gcc/configure.ac's setting of gcc_gxx_include_dir.
776 dnl config/gxx-include-dir.m4 must be kept consistant with this as well.
777 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
778 glibcxx_toolexecdir=no
779 glibcxx_toolexeclibdir=no
780 glibcxx_prefixdir=$prefix
782 AC_MSG_CHECKING([for gxx-include-dir])
783 AC_ARG_WITH([gxx-include-dir],
784 AC_HELP_STRING([--with-gxx-include-dir=DIR],
785 [installation directory for include files]),
786 [case "$withval" in
787 yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
788 no) gxx_include_dir=no ;;
789 *) gxx_include_dir=$withval ;;
790 esac],
791 [gxx_include_dir=no])
792 AC_MSG_RESULT($gxx_include_dir)
794 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
795 AC_ARG_ENABLE([version-specific-runtime-libs],
796 AC_HELP_STRING([--enable-version-specific-runtime-libs],
797 [Specify that runtime libraries should be installed in a compiler-specific directory]),
798 [case "$enableval" in
799 yes) version_specific_libs=yes ;;
800 no) version_specific_libs=no ;;
801 *) AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
802 esac],
803 [version_specific_libs=no])
804 AC_MSG_RESULT($version_specific_libs)
806 # Default case for install directory for include files.
807 if test $version_specific_libs = no && test $gxx_include_dir = no; then
808 gxx_include_dir='include/c++/${gcc_version}'
809 if test -n "$with_cross_host" &&
810 test x"$with_cross_host" != x"no"; then
811 gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
812 else
813 gxx_include_dir='${prefix}/'"$gxx_include_dir"
814 fi
815 fi
817 # Version-specific runtime libs processing.
818 if test $version_specific_libs = yes; then
819 # Need the gcc compiler version to know where to install libraries
820 # and header files if --enable-version-specific-runtime-libs option
821 # is selected. FIXME: these variables are misnamed, there are
822 # no executables installed in _toolexecdir or _toolexeclibdir.
823 if test x"$gxx_include_dir" = x"no"; then
824 gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
825 fi
826 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
827 glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
828 fi
830 # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
831 # Install a library built with a cross compiler in tooldir, not libdir.
832 if test x"$glibcxx_toolexecdir" = x"no"; then
833 if test -n "$with_cross_host" &&
834 test x"$with_cross_host" != x"no"; then
835 glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
836 glibcxx_toolexeclibdir='${toolexecdir}/lib'
837 else
838 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
839 glibcxx_toolexeclibdir='${libdir}'
840 fi
841 multi_os_directory=`$CXX -print-multi-os-directory`
842 case $multi_os_directory in
843 .) ;; # Avoid trailing /.
844 *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
845 esac
846 fi
848 AC_MSG_CHECKING([for install location])
849 AC_MSG_RESULT($gxx_include_dir)
851 AC_SUBST(glibcxx_prefixdir)
852 AC_SUBST(gxx_include_dir)
853 AC_SUBST(glibcxx_toolexecdir)
854 AC_SUBST(glibcxx_toolexeclibdir)
855 ])
858 dnl
859 dnl GLIBCXX_ENABLE
860 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
861 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
862 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
863 dnl
864 dnl See docs/html/17_intro/configury.html#enable for documentation.
865 dnl
866 m4_define([GLIBCXX_ENABLE],[dnl
867 m4_define([_g_switch],[--enable-$1])dnl
868 m4_define([_g_help],[AC_HELP_STRING([_g_switch$3],[$4 @<:@default=$2@:>@])])dnl
869 AC_ARG_ENABLE([$1],m4_dquote(_g_help),
870 m4_bmatch([$5],
871 [^permit ],
872 [[
873 case "$enableval" in
874 m4_bpatsubst([$5],[permit ])) ;;
875 *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
876 dnl Idea for future: generate a URL pointing to
877 dnl "onlinedocs/configopts.html#whatever"
878 esac
879 ]],
880 [^$],
881 [[
882 case "$enableval" in
883 yes|no) ;;
884 *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
885 esac
886 ]],
887 [[$5]]),
888 [enable_]m4_bpatsubst([$1],-,_)[=][$2])
889 m4_undefine([_g_switch])dnl
890 m4_undefine([_g_help])dnl
891 ])
894 dnl
895 dnl Check for ISO/IEC 9899:1999 "C99" support.
896 dnl
897 dnl --enable-c99 defines _GLIBCXX_USE_C99
898 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
899 dnl + Usage: GLIBCXX_ENABLE_C99[(DEFAULT)]
900 dnl Where DEFAULT is either `yes' or `no'.
901 dnl + If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
902 dnl
903 AC_DEFUN([GLIBCXX_ENABLE_C99], [
904 GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
906 if test x"$enable_c99" = x"yes"; then
908 AC_LANG_SAVE
909 AC_LANG_CPLUSPLUS
911 # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
912 # undefined and fake C99 facilities - like pre-standard snprintf - may be
913 # spuriously enabled.
914 # Long term, -std=c++0x could be even better, could manage to explicitely
915 # request C99 facilities to the underlying C headers.
916 ac_save_CXXFLAGS="$CXXFLAGS"
917 CXXFLAGS="$CXXFLAGS -std=c++98"
918 ac_save_LIBS="$LIBS"
919 ac_save_gcc_no_link="$gcc_no_link"
921 if test x$gcc_no_link != xyes; then
922 # Use -fno-exceptions to that the C driver can link these tests without
923 # hitting undefined references to personality routines.
924 CXXFLAGS="$CXXFLAGS -fno-exceptions"
925 AC_CHECK_LIB(m, sin, [
926 LIBS="$LIBS -lm"
927 ], [
928 # Use the default compile-only tests in GCC_TRY_COMPILE_OR_LINK
929 gcc_no_link=yes
930 ])
931 fi
933 # Check for the existence of <math.h> functions used if C99 is enabled.
934 AC_MSG_CHECKING([for ISO C99 support in <math.h>])
935 AC_CACHE_VAL(glibcxx_cv_c99_math, [
936 GCC_TRY_COMPILE_OR_LINK(
937 [#include <math.h>
938 volatile double d1, d2;
939 volatile int i;],
940 [i = fpclassify(d1);
941 i = isfinite(d1);
942 i = isinf(d1);
943 i = isnan(d1);
944 i = isnormal(d1);
945 i = signbit(d1);
946 i = isgreater(d1, d2);
947 i = isgreaterequal(d1, d2);
948 i = isless(d1, d2);
949 i = islessequal(d1, d2);
950 i = islessgreater(d1, d2);
951 i = islessgreater(d1, d2);
952 i = isunordered(d1, d2);
953 ],[glibcxx_cv_c99_math=yes], [glibcxx_cv_c99_math=no])
954 ])
955 AC_MSG_RESULT($glibcxx_cv_c99_math)
956 if test x"$glibcxx_cv_c99_math" = x"yes"; then
957 AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
958 [Define if C99 functions or macros in <math.h> should be imported
959 in <cmath> in namespace std.])
960 fi
962 # Check for the existence of <complex.h> complex math functions.
963 # This is necessary even though libstdc++ uses the builtin versions
964 # of these functions, because if the builtin cannot be used, a reference
965 # to the library function is emitted.
966 AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
967 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
968 glibcxx_cv_c99_complex=no;
969 if test x"$ac_has_complex_h" = x"yes"; then
970 AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
971 GCC_TRY_COMPILE_OR_LINK(
972 [#include <complex.h>
973 typedef __complex__ float float_type;
974 typedef __complex__ double double_type;
975 typedef __complex__ long double ld_type;
976 volatile float_type tmpf;
977 volatile double_type tmpd;
978 volatile ld_type tmpld;
979 volatile float f;
980 volatile double d;
981 volatile long double ld;],
982 [f = cabsf(tmpf);
983 f = cargf(tmpf);
984 tmpf = ccosf(tmpf);
985 tmpf = ccoshf(tmpf);
986 tmpf = cexpf(tmpf);
987 tmpf = clogf(tmpf);
988 tmpf = csinf(tmpf);
989 tmpf = csinhf(tmpf);
990 tmpf = csqrtf(tmpf);
991 tmpf = ctanf(tmpf);
992 tmpf = ctanhf(tmpf);
993 tmpf = cpowf(tmpf, tmpf);
994 tmpf = cprojf(tmpf);
995 d = cabs(tmpd);
996 d = carg(tmpd);
997 tmpd = ccos(tmpd);
998 tmpd = ccosh(tmpd);
999 tmpd = cexp(tmpd);
1000 tmpd = clog(tmpd);
1001 tmpd = csin(tmpd);
1002 tmpd = csinh(tmpd);
1003 tmpd = csqrt(tmpd);
1004 tmpd = ctan(tmpd);
1005 tmpd = ctanh(tmpd);
1006 tmpd = cpow(tmpd, tmpd);
1007 tmpd = cproj(tmpd);
1008 ld = cabsl(tmpld);
1009 ld = cargl(tmpld);
1010 tmpld = ccosl(tmpld);
1011 tmpld = ccoshl(tmpld);
1012 tmpld = cexpl(tmpld);
1013 tmpld = clogl(tmpld);
1014 tmpld = csinl(tmpld);
1015 tmpld = csinhl(tmpld);
1016 tmpld = csqrtl(tmpld);
1017 tmpld = ctanl(tmpld);
1018 tmpld = ctanhl(tmpld);
1019 tmpld = cpowl(tmpld, tmpld);
1020 tmpld = cprojl(tmpld);
1021 ],[glibcxx_cv_c99_complex=yes], [glibcxx_cv_c99_complex=no])
1022 fi
1023 AC_MSG_RESULT($glibcxx_cv_c99_complex)
1024 if test x"$glibcxx_cv_c99_complex" = x"yes"; then
1025 AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
1026 [Define if C99 functions in <complex.h> should be used in
1027 <complex>. Using compiler builtins for these functions requires
1028 corresponding C99 library functions to be present.])
1029 fi
1031 # Check for the existence in <stdio.h> of vscanf, et. al.
1032 AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1033 AC_CACHE_VAL(glibcxx_cv_c99_stdio, [
1034 GCC_TRY_COMPILE_OR_LINK(
1035 [#include <stdio.h>
1036 #include <stdarg.h>
1037 void foo(char* fmt, ...)
1038 {
1039 va_list args; va_start(args, fmt);
1040 vfscanf(stderr, "%i", args);
1041 vscanf("%i", args);
1042 vsnprintf(fmt, 0, "%i", args);
1043 vsscanf(fmt, "%i", args);
1044 }],
1045 [snprintf("12", 0, "%i");],
1046 [glibcxx_cv_c99_stdio=yes], [glibcxx_cv_c99_stdio=no])
1047 ])
1048 AC_MSG_RESULT($glibcxx_cv_c99_stdio)
1050 # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1051 AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1052 AC_CACHE_VAL(glibcxx_cv_c99_stdlib, [
1053 GCC_TRY_COMPILE_OR_LINK(
1054 [#include <stdlib.h>
1055 volatile float f;
1056 volatile long double ld;
1057 volatile unsigned long long ll;
1058 lldiv_t mydivt;],
1059 [char* tmp;
1060 f = strtof("gnu", &tmp);
1061 ld = strtold("gnu", &tmp);
1062 ll = strtoll("gnu", &tmp, 10);
1063 ll = strtoull("gnu", &tmp, 10);
1064 ll = llabs(10);
1065 mydivt = lldiv(10,1);
1066 ll = mydivt.quot;
1067 ll = mydivt.rem;
1068 ll = atoll("10");
1069 _Exit(0);
1070 ],[glibcxx_cv_c99_stdlib=yes], [glibcxx_cv_c99_stdlib=no])
1071 ])
1072 AC_MSG_RESULT($glibcxx_cv_c99_stdlib)
1074 # Check for the existence in <wchar.h> of wcstold, etc.
1075 glibcxx_cv_c99_wchar=no;
1076 if test x"$ac_has_wchar_h" = xyes &&
1077 test x"$ac_has_wctype_h" = xyes; then
1078 AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1079 AC_TRY_COMPILE([#include <wchar.h>
1080 namespace test
1081 {
1082 using ::wcstold;
1083 using ::wcstoll;
1084 using ::wcstoull;
1085 }
1086 ],[],[glibcxx_cv_c99_wchar=yes], [glibcxx_cv_c99_wchar=no])
1088 # Checks for wide character functions that may not be present.
1089 # Injection of these is wrapped with guard macros.
1090 # NB: only put functions here, instead of immediately above, if
1091 # absolutely necessary.
1092 AC_TRY_COMPILE([#include <wchar.h>
1093 namespace test { using ::vfwscanf; } ], [],
1094 [AC_DEFINE(HAVE_VFWSCANF,1,
1095 [Defined if vfwscanf exists.])],[])
1097 AC_TRY_COMPILE([#include <wchar.h>
1098 namespace test { using ::vswscanf; } ], [],
1099 [AC_DEFINE(HAVE_VSWSCANF,1,
1100 [Defined if vswscanf exists.])],[])
1102 AC_TRY_COMPILE([#include <wchar.h>
1103 namespace test { using ::vwscanf; } ], [],
1104 [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
1106 AC_TRY_COMPILE([#include <wchar.h>
1107 namespace test { using ::wcstof; } ], [],
1108 [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
1110 AC_TRY_COMPILE([#include <wctype.h>],
1111 [ wint_t t; int i = iswblank(t);],
1112 [AC_DEFINE(HAVE_ISWBLANK,1,
1113 [Defined if iswblank exists.])],[])
1115 AC_MSG_RESULT($glibcxx_cv_c99_wchar)
1116 fi
1118 # Option parsed, now set things appropriately.
1119 if test x"$glibcxx_cv_c99_math" = x"no" ||
1120 test x"$glibcxx_cv_c99_complex" = x"no" ||
1121 test x"$glibcxx_cv_c99_stdio" = x"no" ||
1122 test x"$glibcxx_cv_c99_stdlib" = x"no" ||
1123 test x"$glibcxx_cv_c99_wchar" = x"no"; then
1124 enable_c99=no;
1125 else
1126 AC_DEFINE(_GLIBCXX_USE_C99, 1,
1127 [Define if C99 functions or macros from <wchar.h>, <math.h>,
1128 <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1129 fi
1131 gcc_no_link="$ac_save_gcc_no_link"
1132 LIBS="$ac_save_LIBS"
1133 CXXFLAGS="$ac_save_CXXFLAGS"
1134 AC_LANG_RESTORE
1135 fi
1137 AC_MSG_CHECKING([for fully enabled ISO C99 support])
1138 AC_MSG_RESULT($enable_c99)
1139 ])
1142 dnl
1143 dnl Check for clock_gettime, nanosleep and sched_yield, used in the
1144 dnl implementation of 20.11.7 [time.clock], and 30.3.2 [thread.thread.this]
1145 dnl in the C++11 standard.
1146 dnl
1147 dnl --enable-libstdcxx-time
1148 dnl --enable-libstdcxx-time=yes
1149 dnl checks for the availability of monotonic and realtime clocks,
1150 dnl nanosleep and sched_yield in libc and libposix4 and, if needed,
1151 dnl links in the latter.
1152 dnl --enable-libstdcxx-time=rt
1153 dnl also searches (and, if needed, links) librt. Note that this is
1154 dnl not always desirable because, in glibc, for example, in turn it
1155 dnl triggers the linking of libpthread too, which activates locking,
1156 dnl a large overhead for single-thread programs.
1157 dnl --enable-libstdcxx-time=no
1158 dnl --disable-libstdcxx-time
1159 dnl disables the checks completely
1160 dnl
1161 dnl N.B. Darwin provides nanosleep but doesn't support the whole POSIX
1162 dnl Timers option, so doesn't define _POSIX_TIMERS. Because the test
1163 dnl below fails Darwin unconditionally defines _GLIBCXX_USE_NANOSLEEP in
1164 dnl os_defines.h and also defines _GLIBCXX_USE_SCHED_YIELD.
1165 dnl
1166 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_TIME], [
1168 AC_MSG_CHECKING([for clock_gettime, nanosleep and sched_yield])
1169 GLIBCXX_ENABLE(libstdcxx-time,$1,[[[=KIND]]],
1170 [use KIND for check type],
1171 [permit yes|no|rt])
1173 AC_LANG_SAVE
1174 AC_LANG_CPLUSPLUS
1175 ac_save_CXXFLAGS="$CXXFLAGS"
1176 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1177 ac_save_LIBS="$LIBS"
1179 ac_has_clock_monotonic=no
1180 ac_has_clock_realtime=no
1181 AC_MSG_RESULT($enable_libstdcxx_time)
1183 if test x"$enable_libstdcxx_time" != x"no"; then
1185 if test x"$enable_libstdcxx_time" = x"rt"; then
1186 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1187 AC_SEARCH_LIBS(nanosleep, [rt posix4])
1188 else
1189 AC_SEARCH_LIBS(clock_gettime, [posix4])
1190 AC_SEARCH_LIBS(nanosleep, [posix4])
1191 fi
1193 case "$ac_cv_search_clock_gettime" in
1194 -l*) GLIBCXX_LIBS=$ac_cv_search_clock_gettime
1195 ;;
1196 esac
1197 case "$ac_cv_search_nanosleep" in
1198 -l*) GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_nanosleep"
1199 ;;
1200 esac
1202 AC_SEARCH_LIBS(sched_yield, [rt posix4])
1204 case "$ac_cv_search_sched_yield" in
1205 -lposix4*)
1206 GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1207 AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1208 [ Defined if sched_yield is available. ])
1209 ;;
1210 -lrt*)
1211 if test x"$enable_libstdcxx_time" = x"rt"; then
1212 GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1213 AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1214 [ Defined if sched_yield is available. ])
1215 fi
1216 ;;
1217 *)
1218 AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1219 [ Defined if sched_yield is available. ])
1220 ;;
1221 esac
1223 AC_CHECK_HEADERS(unistd.h, ac_has_unistd_h=yes, ac_has_unistd_h=no)
1225 if test x"$ac_has_unistd_h" = x"yes"; then
1226 AC_MSG_CHECKING([for monotonic clock])
1227 AC_TRY_LINK(
1228 [#include <unistd.h>
1229 #include <time.h>
1230 ],
1231 [#if _POSIX_TIMERS > 0 && defined(_POSIX_MONOTONIC_CLOCK)
1232 timespec tp;
1233 #endif
1234 clock_gettime(CLOCK_MONOTONIC, &tp);
1235 ], [ac_has_clock_monotonic=yes], [ac_has_clock_monotonic=no])
1237 AC_MSG_RESULT($ac_has_clock_monotonic)
1239 AC_MSG_CHECKING([for realtime clock])
1240 AC_TRY_LINK(
1241 [#include <unistd.h>
1242 #include <time.h>
1243 ],
1244 [#if _POSIX_TIMERS > 0
1245 timespec tp;
1246 #endif
1247 clock_gettime(CLOCK_REALTIME, &tp);
1248 ], [ac_has_clock_realtime=yes], [ac_has_clock_realtime=no])
1250 AC_MSG_RESULT($ac_has_clock_realtime)
1252 AC_MSG_CHECKING([for nanosleep])
1253 AC_TRY_LINK(
1254 [#include <unistd.h>
1255 #include <time.h>
1256 ],
1257 [#if _POSIX_TIMERS > 0
1258 timespec tp;
1259 #endif
1260 nanosleep(&tp, 0);
1261 ], [ac_has_nanosleep=yes], [ac_has_nanosleep=no])
1263 AC_MSG_RESULT($ac_has_nanosleep)
1264 fi
1265 fi
1267 if test x"$ac_has_clock_monotonic" = x"yes"; then
1268 AC_DEFINE(_GLIBCXX_USE_CLOCK_MONOTONIC, 1,
1269 [ Defined if clock_gettime has monotonic clock support. ])
1270 fi
1272 if test x"$ac_has_clock_realtime" = x"yes"; then
1273 AC_DEFINE(_GLIBCXX_USE_CLOCK_REALTIME, 1,
1274 [ Defined if clock_gettime has realtime clock support. ])
1275 fi
1277 if test x"$ac_has_nanosleep" = x"yes"; then
1278 AC_DEFINE(_GLIBCXX_USE_NANOSLEEP, 1,
1279 [ Defined if nanosleep is available. ])
1280 fi
1282 AC_SUBST(GLIBCXX_LIBS)
1284 CXXFLAGS="$ac_save_CXXFLAGS"
1285 LIBS="$ac_save_LIBS"
1286 AC_LANG_RESTORE
1287 ])
1289 dnl
1290 dnl Check for gettimeofday, used in the implementation of 20.11.7
1291 dnl [time.clock] in the C++11 standard.
1292 dnl
1293 AC_DEFUN([GLIBCXX_CHECK_GETTIMEOFDAY], [
1295 AC_MSG_CHECKING([for gettimeofday])
1297 AC_LANG_SAVE
1298 AC_LANG_CPLUSPLUS
1299 ac_save_CXXFLAGS="$CXXFLAGS"
1300 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1302 ac_has_gettimeofday=no;
1303 AC_CHECK_HEADERS(sys/time.h, ac_has_sys_time_h=yes, ac_has_sys_time_h=no)
1304 if test x"$ac_has_sys_time_h" = x"yes"; then
1305 AC_MSG_CHECKING([for gettimeofday])
1306 GCC_TRY_COMPILE_OR_LINK([#include <sys/time.h>],
1307 [timeval tv; gettimeofday(&tv, 0);],
1308 [ac_has_gettimeofday=yes], [ac_has_gettimeofday=no])
1310 AC_MSG_RESULT($ac_has_gettimeofday)
1311 fi
1313 if test x"$ac_has_gettimeofday" = x"yes"; then
1314 AC_DEFINE(_GLIBCXX_USE_GETTIMEOFDAY, 1,
1315 [ Defined if gettimeofday is available. ])
1316 fi
1318 CXXFLAGS="$ac_save_CXXFLAGS"
1319 AC_LANG_RESTORE
1320 ])
1322 dnl
1323 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
1324 dnl facilities in Chapter 8, "C compatibility".
1325 dnl
1326 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
1328 AC_LANG_SAVE
1329 AC_LANG_CPLUSPLUS
1331 # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
1332 # undefined and fake C99 facilities may be spuriously enabled.
1333 ac_save_CXXFLAGS="$CXXFLAGS"
1334 CXXFLAGS="$CXXFLAGS -std=c++98"
1336 # Check for the existence of <complex.h> complex math functions used
1337 # by tr1/complex.
1338 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1339 ac_c99_complex_tr1=no;
1340 if test x"$ac_has_complex_h" = x"yes"; then
1341 AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1342 AC_TRY_COMPILE([#include <complex.h>],
1343 [typedef __complex__ float float_type; float_type tmpf;
1344 cacosf(tmpf);
1345 casinf(tmpf);
1346 catanf(tmpf);
1347 cacoshf(tmpf);
1348 casinhf(tmpf);
1349 catanhf(tmpf);
1350 typedef __complex__ double double_type; double_type tmpd;
1351 cacos(tmpd);
1352 casin(tmpd);
1353 catan(tmpd);
1354 cacosh(tmpd);
1355 casinh(tmpd);
1356 catanh(tmpd);
1357 typedef __complex__ long double ld_type; ld_type tmpld;
1358 cacosl(tmpld);
1359 casinl(tmpld);
1360 catanl(tmpld);
1361 cacoshl(tmpld);
1362 casinhl(tmpld);
1363 catanhl(tmpld);
1364 ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1365 fi
1366 AC_MSG_RESULT($ac_c99_complex_tr1)
1367 if test x"$ac_c99_complex_tr1" = x"yes"; then
1368 AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1369 [Define if C99 functions in <complex.h> should be used in
1370 <tr1/complex>. Using compiler builtins for these functions
1371 requires corresponding C99 library functions to be present.])
1372 fi
1374 # Check for the existence of <ctype.h> functions.
1375 AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1376 AC_CACHE_VAL(glibcxx_cv_c99_ctype_tr1, [
1377 AC_TRY_COMPILE([#include <ctype.h>],
1378 [int ch;
1379 int ret;
1380 ret = isblank(ch);
1381 ],[glibcxx_cv_c99_ctype_tr1=yes],
1382 [glibcxx_cv_c99_ctype_tr1=no])
1383 ])
1384 AC_MSG_RESULT($glibcxx_cv_c99_ctype_tr1)
1385 if test x"$glibcxx_cv_c99_ctype_tr1" = x"yes"; then
1386 AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1387 [Define if C99 functions in <ctype.h> should be imported in
1388 <tr1/cctype> in namespace std::tr1.])
1389 fi
1391 # Check for the existence of <fenv.h> functions.
1392 AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1393 ac_c99_fenv_tr1=no;
1394 if test x"$ac_has_fenv_h" = x"yes"; then
1395 AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1396 AC_TRY_COMPILE([#include <fenv.h>],
1397 [int except, mode;
1398 fexcept_t* pflag;
1399 fenv_t* penv;
1400 int ret;
1401 ret = feclearexcept(except);
1402 ret = fegetexceptflag(pflag, except);
1403 ret = feraiseexcept(except);
1404 ret = fesetexceptflag(pflag, except);
1405 ret = fetestexcept(except);
1406 ret = fegetround();
1407 ret = fesetround(mode);
1408 ret = fegetenv(penv);
1409 ret = feholdexcept(penv);
1410 ret = fesetenv(penv);
1411 ret = feupdateenv(penv);
1412 ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1413 fi
1414 AC_MSG_RESULT($ac_c99_fenv_tr1)
1415 if test x"$ac_c99_fenv_tr1" = x"yes"; then
1416 AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1417 [Define if C99 functions in <fenv.h> should be imported in
1418 <tr1/cfenv> in namespace std::tr1.])
1419 fi
1421 # Check for the existence of <stdint.h> types.
1422 AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1423 AC_CACHE_VAL(glibcxx_cv_c99_stdint_tr1, [
1424 AC_TRY_COMPILE([#define __STDC_LIMIT_MACROS
1425 #define __STDC_CONSTANT_MACROS
1426 #include <stdint.h>],
1427 [typedef int8_t my_int8_t;
1428 my_int8_t i8 = INT8_MIN;
1429 i8 = INT8_MAX;
1430 typedef int16_t my_int16_t;
1431 my_int16_t i16 = INT16_MIN;
1432 i16 = INT16_MAX;
1433 typedef int32_t my_int32_t;
1434 my_int32_t i32 = INT32_MIN;
1435 i32 = INT32_MAX;
1436 typedef int64_t my_int64_t;
1437 my_int64_t i64 = INT64_MIN;
1438 i64 = INT64_MAX;
1439 typedef int_fast8_t my_int_fast8_t;
1440 my_int_fast8_t if8 = INT_FAST8_MIN;
1441 if8 = INT_FAST8_MAX;
1442 typedef int_fast16_t my_int_fast16_t;
1443 my_int_fast16_t if16 = INT_FAST16_MIN;
1444 if16 = INT_FAST16_MAX;
1445 typedef int_fast32_t my_int_fast32_t;
1446 my_int_fast32_t if32 = INT_FAST32_MIN;
1447 if32 = INT_FAST32_MAX;
1448 typedef int_fast64_t my_int_fast64_t;
1449 my_int_fast64_t if64 = INT_FAST64_MIN;
1450 if64 = INT_FAST64_MAX;
1451 typedef int_least8_t my_int_least8_t;
1452 my_int_least8_t il8 = INT_LEAST8_MIN;
1453 il8 = INT_LEAST8_MAX;
1454 typedef int_least16_t my_int_least16_t;
1455 my_int_least16_t il16 = INT_LEAST16_MIN;
1456 il16 = INT_LEAST16_MAX;
1457 typedef int_least32_t my_int_least32_t;
1458 my_int_least32_t il32 = INT_LEAST32_MIN;
1459 il32 = INT_LEAST32_MAX;
1460 typedef int_least64_t my_int_least64_t;
1461 my_int_least64_t il64 = INT_LEAST64_MIN;
1462 il64 = INT_LEAST64_MAX;
1463 typedef intmax_t my_intmax_t;
1464 my_intmax_t im = INTMAX_MAX;
1465 im = INTMAX_MIN;
1466 typedef intptr_t my_intptr_t;
1467 my_intptr_t ip = INTPTR_MAX;
1468 ip = INTPTR_MIN;
1469 typedef uint8_t my_uint8_t;
1470 my_uint8_t ui8 = UINT8_MAX;
1471 ui8 = UINT8_MAX;
1472 typedef uint16_t my_uint16_t;
1473 my_uint16_t ui16 = UINT16_MAX;
1474 ui16 = UINT16_MAX;
1475 typedef uint32_t my_uint32_t;
1476 my_uint32_t ui32 = UINT32_MAX;
1477 ui32 = UINT32_MAX;
1478 typedef uint64_t my_uint64_t;
1479 my_uint64_t ui64 = UINT64_MAX;
1480 ui64 = UINT64_MAX;
1481 typedef uint_fast8_t my_uint_fast8_t;
1482 my_uint_fast8_t uif8 = UINT_FAST8_MAX;
1483 uif8 = UINT_FAST8_MAX;
1484 typedef uint_fast16_t my_uint_fast16_t;
1485 my_uint_fast16_t uif16 = UINT_FAST16_MAX;
1486 uif16 = UINT_FAST16_MAX;
1487 typedef uint_fast32_t my_uint_fast32_t;
1488 my_uint_fast32_t uif32 = UINT_FAST32_MAX;
1489 uif32 = UINT_FAST32_MAX;
1490 typedef uint_fast64_t my_uint_fast64_t;
1491 my_uint_fast64_t uif64 = UINT_FAST64_MAX;
1492 uif64 = UINT_FAST64_MAX;
1493 typedef uint_least8_t my_uint_least8_t;
1494 my_uint_least8_t uil8 = UINT_LEAST8_MAX;
1495 uil8 = UINT_LEAST8_MAX;
1496 typedef uint_least16_t my_uint_least16_t;
1497 my_uint_least16_t uil16 = UINT_LEAST16_MAX;
1498 uil16 = UINT_LEAST16_MAX;
1499 typedef uint_least32_t my_uint_least32_t;
1500 my_uint_least32_t uil32 = UINT_LEAST32_MAX;
1501 uil32 = UINT_LEAST32_MAX;
1502 typedef uint_least64_t my_uint_least64_t;
1503 my_uint_least64_t uil64 = UINT_LEAST64_MAX;
1504 uil64 = UINT_LEAST64_MAX;
1505 typedef uintmax_t my_uintmax_t;
1506 my_uintmax_t uim = UINTMAX_MAX;
1507 uim = UINTMAX_MAX;
1508 typedef uintptr_t my_uintptr_t;
1509 my_uintptr_t uip = UINTPTR_MAX;
1510 uip = UINTPTR_MAX;
1511 ],[glibcxx_cv_c99_stdint_tr1=yes],
1512 [glibcxx_cv_c99_stdint_tr1=no])
1513 ])
1514 AC_MSG_RESULT($glibcxx_cv_c99_stdint_tr1)
1515 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1516 AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1517 [Define if C99 types in <stdint.h> should be imported in
1518 <tr1/cstdint> in namespace std::tr1.])
1519 fi
1521 # Check for the existence of <math.h> functions.
1522 AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1523 AC_CACHE_VAL(glibcxx_cv_c99_math_tr1, [
1524 AC_TRY_COMPILE([#include <math.h>],
1525 [typedef double_t my_double_t;
1526 typedef float_t my_float_t;
1527 acosh(0.0);
1528 acoshf(0.0f);
1529 acoshl(0.0l);
1530 asinh(0.0);
1531 asinhf(0.0f);
1532 asinhl(0.0l);
1533 atanh(0.0);
1534 atanhf(0.0f);
1535 atanhl(0.0l);
1536 cbrt(0.0);
1537 cbrtf(0.0f);
1538 cbrtl(0.0l);
1539 copysign(0.0, 0.0);
1540 copysignf(0.0f, 0.0f);
1541 copysignl(0.0l, 0.0l);
1542 erf(0.0);
1543 erff(0.0f);
1544 erfl(0.0l);
1545 erfc(0.0);
1546 erfcf(0.0f);
1547 erfcl(0.0l);
1548 exp2(0.0);
1549 exp2f(0.0f);
1550 exp2l(0.0l);
1551 expm1(0.0);
1552 expm1f(0.0f);
1553 expm1l(0.0l);
1554 fdim(0.0, 0.0);
1555 fdimf(0.0f, 0.0f);
1556 fdiml(0.0l, 0.0l);
1557 fma(0.0, 0.0, 0.0);
1558 fmaf(0.0f, 0.0f, 0.0f);
1559 fmal(0.0l, 0.0l, 0.0l);
1560 fmax(0.0, 0.0);
1561 fmaxf(0.0f, 0.0f);
1562 fmaxl(0.0l, 0.0l);
1563 fmin(0.0, 0.0);
1564 fminf(0.0f, 0.0f);
1565 fminl(0.0l, 0.0l);
1566 hypot(0.0, 0.0);
1567 hypotf(0.0f, 0.0f);
1568 hypotl(0.0l, 0.0l);
1569 ilogb(0.0);
1570 ilogbf(0.0f);
1571 ilogbl(0.0l);
1572 lgamma(0.0);
1573 lgammaf(0.0f);
1574 lgammal(0.0l);
1575 llrint(0.0);
1576 llrintf(0.0f);
1577 llrintl(0.0l);
1578 llround(0.0);
1579 llroundf(0.0f);
1580 llroundl(0.0l);
1581 log1p(0.0);
1582 log1pf(0.0f);
1583 log1pl(0.0l);
1584 log2(0.0);
1585 log2f(0.0f);
1586 log2l(0.0l);
1587 logb(0.0);
1588 logbf(0.0f);
1589 logbl(0.0l);
1590 lrint(0.0);
1591 lrintf(0.0f);
1592 lrintl(0.0l);
1593 lround(0.0);
1594 lroundf(0.0f);
1595 lroundl(0.0l);
1596 nan(0);
1597 nanf(0);
1598 nanl(0);
1599 nearbyint(0.0);
1600 nearbyintf(0.0f);
1601 nearbyintl(0.0l);
1602 nextafter(0.0, 0.0);
1603 nextafterf(0.0f, 0.0f);
1604 nextafterl(0.0l, 0.0l);
1605 nexttoward(0.0, 0.0);
1606 nexttowardf(0.0f, 0.0f);
1607 nexttowardl(0.0l, 0.0l);
1608 remainder(0.0, 0.0);
1609 remainderf(0.0f, 0.0f);
1610 remainderl(0.0l, 0.0l);
1611 remquo(0.0, 0.0, 0);
1612 remquof(0.0f, 0.0f, 0);
1613 remquol(0.0l, 0.0l, 0);
1614 rint(0.0);
1615 rintf(0.0f);
1616 rintl(0.0l);
1617 round(0.0);
1618 roundf(0.0f);
1619 roundl(0.0l);
1620 scalbln(0.0, 0l);
1621 scalblnf(0.0f, 0l);
1622 scalblnl(0.0l, 0l);
1623 scalbn(0.0, 0);
1624 scalbnf(0.0f, 0);
1625 scalbnl(0.0l, 0);
1626 tgamma(0.0);
1627 tgammaf(0.0f);
1628 tgammal(0.0l);
1629 trunc(0.0);
1630 truncf(0.0f);
1631 truncl(0.0l);
1632 ],[glibcxx_cv_c99_math_tr1=yes], [glibcxx_cv_c99_math_tr1=no])
1633 ])
1634 AC_MSG_RESULT($glibcxx_cv_c99_math_tr1)
1635 if test x"$glibcxx_cv_c99_math_tr1" = x"yes"; then
1636 AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1637 [Define if C99 functions or macros in <math.h> should be imported
1638 in <tr1/cmath> in namespace std::tr1.])
1639 fi
1641 # Check for the existence of <inttypes.h> functions (NB: doesn't make
1642 # sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1643 ac_c99_inttypes_tr1=no;
1644 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1645 AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1646 AC_TRY_COMPILE([#include <inttypes.h>],
1647 [intmax_t i, numer, denom, base;
1648 const char* s;
1649 char** endptr;
1650 intmax_t ret = imaxabs(i);
1651 imaxdiv_t dret = imaxdiv(numer, denom);
1652 ret = strtoimax(s, endptr, base);
1653 uintmax_t uret = strtoumax(s, endptr, base);
1654 ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1655 fi
1656 AC_MSG_RESULT($ac_c99_inttypes_tr1)
1657 if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1658 AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1659 [Define if C99 functions in <inttypes.h> should be imported in
1660 <tr1/cinttypes> in namespace std::tr1.])
1661 fi
1663 # Check for the existence of whcar_t <inttypes.h> functions (NB: doesn't
1664 # make sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1665 ac_c99_inttypes_wchar_t_tr1=no;
1666 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1667 AC_MSG_CHECKING([for wchar_t ISO C99 support to TR1 in <inttypes.h>])
1668 AC_TRY_COMPILE([#include <inttypes.h>],
1669 [intmax_t base;
1670 const wchar_t* s;
1671 wchar_t** endptr;
1672 intmax_t ret = wcstoimax(s, endptr, base);
1673 uintmax_t uret = wcstoumax(s, endptr, base);
1674 ],[ac_c99_inttypes_wchar_t_tr1=yes],
1675 [ac_c99_inttypes_wchar_t_tr1=no])
1676 fi
1677 AC_MSG_RESULT($ac_c99_inttypes_wchar_t_tr1)
1678 if test x"$ac_c99_inttypes_wchar_t_tr1" = x"yes"; then
1679 AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_WCHAR_T_TR1, 1,
1680 [Define if wchar_t C99 functions in <inttypes.h> should be
1681 imported in <tr1/cinttypes> in namespace std::tr1.])
1682 fi
1684 # Check for the existence of the <stdbool.h> header.
1685 AC_CHECK_HEADERS(stdbool.h)
1687 # Check for the existence of the <stdalign.h> header.
1688 AC_CHECK_HEADERS(stdalign.h)
1690 CXXFLAGS="$ac_save_CXXFLAGS"
1691 AC_LANG_RESTORE
1692 ])
1694 dnl
1695 dnl Check whether "/dev/random" and "/dev/urandom" are available for the
1696 dnl random_device of "TR1" (Chapter 5.1, "Random number generation").
1697 dnl
1698 AC_DEFUN([GLIBCXX_CHECK_RANDOM_TR1], [
1700 AC_MSG_CHECKING([for "/dev/random" and "/dev/urandom" for TR1 random_device])
1701 AC_CACHE_VAL(glibcxx_cv_random_tr1, [
1702 if test -r /dev/random && test -r /dev/urandom; then
1703 glibcxx_cv_random_tr1=yes;
1704 else
1705 glibcxx_cv_random_tr1=no;
1706 fi
1707 ])
1708 AC_MSG_RESULT($glibcxx_cv_random_tr1)
1710 if test x"$glibcxx_cv_random_tr1" = x"yes"; then
1711 AC_DEFINE(_GLIBCXX_USE_RANDOM_TR1, 1,
1712 [Define if /dev/random and /dev/urandom are available for
1713 the random_device of TR1 (Chapter 5.1).])
1714 fi
1716 ])
1718 dnl
1719 dnl Compute the EOF, SEEK_CUR, and SEEK_END integer constants.
1720 dnl
1721 AC_DEFUN([GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS], [
1723 AC_CACHE_CHECK([for the value of EOF], glibcxx_cv_stdio_eof, [
1724 AC_COMPUTE_INT([glibcxx_cv_stdio_eof], [[EOF]],
1725 [#include <stdio.h>],
1726 [AC_MSG_ERROR([computing EOF failed])])
1727 ])
1728 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_EOF, $glibcxx_cv_stdio_eof,
1729 [Define to the value of the EOF integer constant.])
1731 AC_CACHE_CHECK([for the value of SEEK_CUR], glibcxx_cv_stdio_seek_cur, [
1732 AC_COMPUTE_INT([glibcxx_cv_stdio_seek_cur], [[SEEK_CUR]],
1733 [#include <stdio.h>],
1734 [AC_MSG_ERROR([computing SEEK_CUR failed])])
1735 ])
1736 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_CUR, $glibcxx_cv_stdio_seek_cur,
1737 [Define to the value of the SEEK_CUR integer constant.])
1739 AC_CACHE_CHECK([for the value of SEEK_END], glibcxx_cv_stdio_seek_end, [
1740 AC_COMPUTE_INT([glibcxx_cv_stdio_seek_end], [[SEEK_END]],
1741 [#include <stdio.h>],
1742 [AC_MSG_ERROR([computing SEEK_END failed])])
1743 ])
1744 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_END, $glibcxx_cv_stdio_seek_end,
1745 [Define to the value of the SEEK_END integer constant.])
1746 ])
1748 dnl
1749 dnl Check whether required C++ overloads are present in <stdio.h>.
1750 dnl
1751 AC_DEFUN([GLIBCXX_CHECK_STDIO_PROTO], [
1753 AC_LANG_SAVE
1754 AC_LANG_CPLUSPLUS
1756 AC_MSG_CHECKING([for gets declaration])
1757 AC_CACHE_VAL(glibcxx_cv_gets, [
1758 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1759 [#include <stdio.h>
1760 namespace test
1761 {
1762 using ::gets;
1763 }
1764 ])],
1765 [glibcxx_cv_gets=yes],
1766 [glibcxx_cv_gets=no]
1767 )])
1769 if test $glibcxx_cv_gets = yes; then
1770 AC_DEFINE(HAVE_GETS, 1, [Define if gets is available in <stdio.h>.])
1771 fi
1772 AC_MSG_RESULT($glibcxx_cv_gets)
1774 AC_LANG_RESTORE
1775 ])
1777 dnl
1778 dnl Check whether macros, etc are present for <system_error>
1779 dnl
1780 AC_DEFUN([GLIBCXX_CHECK_SYSTEM_ERROR], [
1782 m4_pushdef([n_syserr], [1])dnl
1783 m4_foreach([syserr], [EOWNERDEAD, ENOTRECOVERABLE, ENOLINK, EPROTO, ENODATA,
1784 ENOSR, ENOSTR, ETIME, EBADMSG, ECANCELED,
1785 EOVERFLOW, ENOTSUP, EIDRM, ETXTBSY,
1786 ECHILD, ENOSPC, EPERM,
1787 ETIMEDOUT, EWOULDBLOCK],
1788 [m4_pushdef([SYSERR], m4_toupper(syserr))dnl
1789 AC_MSG_CHECKING([for syserr])
1790 AC_CACHE_VAL([glibcxx_cv_system_error[]n_syserr], [
1791 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
1792 [int i = syserr;])],
1793 [glibcxx_cv_system_error[]n_syserr=yes],
1794 [glibcxx_cv_system_error[]n_syserr=no])
1795 ])
1796 AC_MSG_RESULT([$glibcxx_cv_system_error[]n_syserr])
1797 if test x"$glibcxx_cv_system_error[]n_syserr" = x"yes"; then
1798 AC_DEFINE([HAVE_]SYSERR, 1, [Define if ]syserr[ exists.])
1799 fi
1800 m4_define([n_syserr], m4_incr(n_syserr))dnl
1801 m4_popdef([SYSERR])dnl
1802 ])
1803 m4_popdef([n_syserr])dnl
1804 ])
1806 dnl
1807 dnl Check for what type of C headers to use.
1808 dnl
1809 dnl --enable-cheaders= [does stuff].
1810 dnl --disable-cheaders [does not do anything, really].
1811 dnl + Usage: GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1812 dnl Where DEFAULT is either 'c' or 'c_std' or 'c_global'.
1813 dnl
1814 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1815 GLIBCXX_ENABLE(cheaders,$1,[[[=KIND]]],
1816 [construct "C" headers for g++], [permit c|c_std|c_global])
1817 AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1819 C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1821 # Allow overrides to configure.host here.
1822 if test $enable_cheaders = c_global; then
1823 c_compatibility=yes
1824 fi
1826 AC_SUBST(C_INCLUDE_DIR)
1827 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1828 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1829 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_GLOBAL, test $enable_cheaders = c_global)
1830 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1831 ])
1834 dnl
1835 dnl Check for which locale library to use. The choice is mapped to
1836 dnl a subdirectory of config/locale.
1837 dnl
1838 dnl Default is generic.
1839 dnl
1840 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1841 GLIBCXX_ENABLE(clocale,auto,[[[=MODEL]]],
1842 [use MODEL for target locale package],
1843 [permit generic|gnu|ieee_1003.1-2001|newlib|yes|no|auto])
1845 # Deal with gettext issues. Default to not using it (=no) until we detect
1846 # support for it later. Let the user turn it off via --e/d, but let that
1847 # default to on for easier handling.
1848 USE_NLS=no
1849 AC_ARG_ENABLE(nls,
1850 AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1851 [],
1852 [enable_nls=yes])
1854 # Either a known package, or "auto"
1855 if test $enable_clocale = no || test $enable_clocale = yes; then
1856 enable_clocale=auto
1857 fi
1858 enable_clocale_flag=$enable_clocale
1860 # Probe for locale model to use if none specified.
1861 # Default to "generic".
1862 if test $enable_clocale_flag = auto; then
1863 case ${target_os} in
1864 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1865 enable_clocale_flag=gnu
1866 ;;
1867 darwin* | freebsd*)
1868 enable_clocale_flag=darwin
1869 ;;
1870 openbsd*)
1871 enable_clocale_flag=newlib
1872 ;;
1873 *)
1874 if test x"$with_newlib" = x"yes"; then
1875 enable_clocale_flag=newlib
1876 else
1877 enable_clocale_flag=generic
1878 fi
1879 ;;
1880 esac
1881 fi
1883 # Sanity check model, and test for special functionality.
1884 if test $enable_clocale_flag = gnu; then
1885 AC_EGREP_CPP([_GLIBCXX_ok], [
1886 #include <features.h>
1887 #if (__GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 3)) && !defined(__UCLIBC__)
1888 _GLIBCXX_ok
1889 #endif
1890 ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1892 # Set it to scream when it hurts.
1893 ac_save_CFLAGS="$CFLAGS"
1894 CFLAGS="-Wimplicit-function-declaration -Werror"
1896 # Use strxfrm_l if available.
1897 AC_TRY_COMPILE([#define _GNU_SOURCE 1
1898 #include <string.h>
1899 #include <locale.h>],
1900 [char s[128]; __locale_t loc; strxfrm_l(s, "C", 5, loc);],
1901 AC_DEFINE(HAVE_STRXFRM_L, 1,
1902 [Define if strxfrm_l is available in <string.h>.]),)
1904 # Use strerror_l if available.
1905 AC_TRY_COMPILE([#define _GNU_SOURCE 1
1906 #include <string.h>
1907 #include <locale.h>],
1908 [__locale_t loc; strerror_l(5, loc);],
1909 AC_DEFINE(HAVE_STRERROR_L, 1,
1910 [Define if strerror_l is available in <string.h>.]),)
1912 CFLAGS="$ac_save_CFLAGS"
1913 fi
1915 # Perhaps use strerror_r if available, and strerror_l isn't.
1916 ac_save_CFLAGS="$CFLAGS"
1917 CFLAGS="-Wimplicit-function-declaration -Werror"
1918 AC_TRY_COMPILE([#define _GNU_SOURCE 1
1919 #include <string.h>
1920 #include <locale.h>],
1921 [char s[128]; strerror_r(5, s, 128);],
1922 AC_DEFINE(HAVE_STRERROR_R, 1,
1923 [Define if strerror_r is available in <string.h>.]),)
1924 CFLAGS="$ac_save_CFLAGS"
1926 # Set configure bits for specified locale package
1927 AC_MSG_CHECKING([for C locale to use])
1928 case ${enable_clocale_flag} in
1929 generic)
1930 AC_MSG_RESULT(generic)
1932 CLOCALE_H=config/locale/generic/c_locale.h
1933 CLOCALE_CC=config/locale/generic/c_locale.cc
1934 CCODECVT_CC=config/locale/generic/codecvt_members.cc
1935 CCOLLATE_CC=config/locale/generic/collate_members.cc
1936 CCTYPE_CC=config/locale/generic/ctype_members.cc
1937 CMESSAGES_H=config/locale/generic/messages_members.h
1938 CMESSAGES_CC=config/locale/generic/messages_members.cc
1939 CMONEY_CC=config/locale/generic/monetary_members.cc
1940 CNUMERIC_CC=config/locale/generic/numeric_members.cc
1941 CTIME_H=config/locale/generic/time_members.h
1942 CTIME_CC=config/locale/generic/time_members.cc
1943 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1944 ;;
1945 darwin)
1946 AC_MSG_RESULT(darwin or freebsd)
1948 CLOCALE_H=config/locale/generic/c_locale.h
1949 CLOCALE_CC=config/locale/generic/c_locale.cc
1950 CCODECVT_CC=config/locale/generic/codecvt_members.cc
1951 CCOLLATE_CC=config/locale/generic/collate_members.cc
1952 CCTYPE_CC=config/locale/darwin/ctype_members.cc
1953 CMESSAGES_H=config/locale/generic/messages_members.h
1954 CMESSAGES_CC=config/locale/generic/messages_members.cc
1955 CMONEY_CC=config/locale/generic/monetary_members.cc
1956 CNUMERIC_CC=config/locale/generic/numeric_members.cc
1957 CTIME_H=config/locale/generic/time_members.h
1958 CTIME_CC=config/locale/generic/time_members.cc
1959 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1960 ;;
1962 gnu)
1963 AC_MSG_RESULT(gnu)
1965 # Declare intention to use gettext, and add support for specific
1966 # languages.
1967 # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1968 ALL_LINGUAS="de fr"
1970 # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1971 AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1972 if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1973 USE_NLS=yes
1974 fi
1975 # Export the build objects.
1976 for ling in $ALL_LINGUAS; do \
1977 glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1978 glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1979 done
1980 AC_SUBST(glibcxx_MOFILES)
1981 AC_SUBST(glibcxx_POFILES)
1983 CLOCALE_H=config/locale/gnu/c_locale.h
1984 CLOCALE_CC=config/locale/gnu/c_locale.cc
1985 CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1986 CCOLLATE_CC=config/locale/gnu/collate_members.cc
1987 CCTYPE_CC=config/locale/gnu/ctype_members.cc
1988 CMESSAGES_H=config/locale/gnu/messages_members.h
1989 CMESSAGES_CC=config/locale/gnu/messages_members.cc
1990 CMONEY_CC=config/locale/gnu/monetary_members.cc
1991 CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1992 CTIME_H=config/locale/gnu/time_members.h
1993 CTIME_CC=config/locale/gnu/time_members.cc
1994 CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1995 ;;
1996 ieee_1003.1-2001)
1997 AC_MSG_RESULT(IEEE 1003.1)
1999 CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
2000 CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
2001 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2002 CCOLLATE_CC=config/locale/generic/collate_members.cc
2003 CCTYPE_CC=config/locale/generic/ctype_members.cc
2004 CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
2005 CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
2006 CMONEY_CC=config/locale/generic/monetary_members.cc
2007 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2008 CTIME_H=config/locale/generic/time_members.h
2009 CTIME_CC=config/locale/generic/time_members.cc
2010 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2011 ;;
2012 newlib)
2013 AC_MSG_RESULT(newlib)
2015 CLOCALE_H=config/locale/generic/c_locale.h
2016 CLOCALE_CC=config/locale/generic/c_locale.cc
2017 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2018 CCOLLATE_CC=config/locale/generic/collate_members.cc
2019 CCTYPE_CC=config/locale/newlib/ctype_members.cc
2020 CMESSAGES_H=config/locale/generic/messages_members.h
2021 CMESSAGES_CC=config/locale/generic/messages_members.cc
2022 CMONEY_CC=config/locale/generic/monetary_members.cc
2023 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2024 CTIME_H=config/locale/generic/time_members.h
2025 CTIME_CC=config/locale/generic/time_members.cc
2026 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2027 ;;
2028 esac
2030 # This is where the testsuite looks for locale catalogs, using the
2031 # -DLOCALEDIR define during testsuite compilation.
2032 glibcxx_localedir=${glibcxx_builddir}/po/share/locale
2033 AC_SUBST(glibcxx_localedir)
2035 # A standalone libintl (e.g., GNU libintl) may be in use.
2036 if test $USE_NLS = yes; then
2037 AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
2038 AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
2039 fi
2040 if test $USE_NLS = yes; then
2041 AC_DEFINE(_GLIBCXX_USE_NLS, 1,
2042 [Define if NLS translations are to be used.])
2043 fi
2045 AC_SUBST(USE_NLS)
2046 AC_SUBST(CLOCALE_H)
2047 AC_SUBST(CMESSAGES_H)
2048 AC_SUBST(CCODECVT_CC)
2049 AC_SUBST(CCOLLATE_CC)
2050 AC_SUBST(CCTYPE_CC)
2051 AC_SUBST(CMESSAGES_CC)
2052 AC_SUBST(CMONEY_CC)
2053 AC_SUBST(CNUMERIC_CC)
2054 AC_SUBST(CTIME_H)
2055 AC_SUBST(CTIME_CC)
2056 AC_SUBST(CLOCALE_CC)
2057 AC_SUBST(CLOCALE_INTERNAL_H)
2058 ])
2061 dnl
2062 dnl Check for which std::allocator base class to use. The choice is
2063 dnl mapped from a subdirectory of include/ext.
2064 dnl
2065 dnl Default is new.
2066 dnl
2067 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
2068 AC_MSG_CHECKING([for std::allocator base class])
2069 GLIBCXX_ENABLE(libstdcxx-allocator,auto,[[[=KIND]]],
2070 [use KIND for target std::allocator base],
2071 [permit new|malloc|mt|bitmap|pool|yes|no|auto])
2073 # If they didn't use this option switch, or if they specified --enable
2074 # with no specific model, we'll have to look for one. If they
2075 # specified --disable (???), do likewise.
2076 if test $enable_libstdcxx_allocator = no ||
2077 test $enable_libstdcxx_allocator = yes;
2078 then
2079 enable_libstdcxx_allocator=auto
2080 fi
2082 # Either a known package, or "auto". Auto implies the default choice
2083 # for a particular platform.
2084 enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
2086 # Probe for host-specific support if no specific model is specified.
2087 # Default to "new".
2088 if test $enable_libstdcxx_allocator_flag = auto; then
2089 case ${target_os} in
2090 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
2091 enable_libstdcxx_allocator_flag=new
2092 ;;
2093 *)
2094 enable_libstdcxx_allocator_flag=new
2095 ;;
2096 esac
2097 fi
2098 AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
2101 # Set configure bits for specified locale package
2102 case ${enable_libstdcxx_allocator_flag} in
2103 bitmap)
2104 ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
2105 ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
2106 ;;
2107 malloc)
2108 ALLOCATOR_H=config/allocator/malloc_allocator_base.h
2109 ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
2110 ;;
2111 mt)
2112 ALLOCATOR_H=config/allocator/mt_allocator_base.h
2113 ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
2114 ;;
2115 new)
2116 ALLOCATOR_H=config/allocator/new_allocator_base.h
2117 ALLOCATOR_NAME=__gnu_cxx::new_allocator
2118 ;;
2119 pool)
2120 ALLOCATOR_H=config/allocator/pool_allocator_base.h
2121 ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
2122 ;;
2123 esac
2125 AC_SUBST(ALLOCATOR_H)
2126 AC_SUBST(ALLOCATOR_NAME)
2127 ])
2130 dnl
2131 dnl Check for whether the Boost-derived checks should be turned on.
2132 dnl
2133 dnl --enable-concept-checks turns them on.
2134 dnl --disable-concept-checks leaves them off.
2135 dnl + Usage: GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2136 dnl Where DEFAULT is either `yes' or `no'.
2137 dnl
2138 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
2139 GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
2140 if test $enable_concept_checks = yes; then
2141 AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
2142 [Define to use concept checking code from the boost libraries.])
2143 fi
2144 ])
2146 dnl
2147 dnl Use extern templates.
2148 dnl
2149 dnl --enable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 1
2150 dnl --disable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 0
2152 dnl + Usage: GLIBCXX_ENABLE_TEMPLATE[(DEFAULT)]
2153 dnl Where DEFAULT is `yes' or `no'.
2154 dnl
2155 AC_DEFUN([GLIBCXX_ENABLE_EXTERN_TEMPLATE], [
2157 GLIBCXX_ENABLE(extern-template,$1,,[enable extern template])
2159 AC_MSG_CHECKING([for extern template support])
2160 AC_MSG_RESULT([$enable_extern_template])
2162 GLIBCXX_CONDITIONAL(ENABLE_EXTERN_TEMPLATE, test $enable_extern_template = yes)
2163 ])
2165 dnl
2166 dnl Check for parallel mode pre-requisites, including OpenMP support.
2167 dnl
2168 dnl + Usage: GLIBCXX_ENABLE_PARALLEL
2169 dnl
2170 AC_DEFUN([GLIBCXX_ENABLE_PARALLEL], [
2172 enable_parallel=no;
2174 # See if configured libgomp/omp.h exists. (libgomp may be in
2175 # noconfigdirs but not explicitly disabled.)
2176 if echo " ${TARGET_CONFIGDIRS} " | grep " libgomp " > /dev/null 2>&1 ; then
2177 enable_parallel=yes;
2178 else
2179 AC_MSG_NOTICE([target-libgomp not built])
2180 fi
2182 AC_MSG_CHECKING([for parallel mode support])
2183 AC_MSG_RESULT([$enable_parallel])
2184 ])
2187 dnl
2188 dnl Check for which I/O library to use: stdio, or something specific.
2189 dnl
2190 dnl Default is stdio.
2191 dnl
2192 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
2193 AC_MSG_CHECKING([for underlying I/O to use])
2194 GLIBCXX_ENABLE(cstdio,stdio,[[[=PACKAGE]]],
2195 [use target-specific I/O package], [permit stdio])
2197 # Now that libio has been removed, you can have any color you want as long
2198 # as it's black. This is one big no-op until other packages are added, but
2199 # showing the framework never hurts.
2200 case ${enable_cstdio} in
2201 stdio)
2202 CSTDIO_H=config/io/c_io_stdio.h
2203 BASIC_FILE_H=config/io/basic_file_stdio.h
2204 BASIC_FILE_CC=config/io/basic_file_stdio.cc
2205 AC_MSG_RESULT(stdio)
2206 ;;
2207 esac
2209 AC_SUBST(CSTDIO_H)
2210 AC_SUBST(BASIC_FILE_H)
2211 AC_SUBST(BASIC_FILE_CC)
2212 ])
2215 dnl
2216 dnl Check for "unusual" flags to pass to the compiler while building.
2217 dnl
2218 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
2219 dnl experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
2220 dnl --disable-cxx-flags passes nothing.
2221 dnl + See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
2222 dnl http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
2223 dnl http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
2224 dnl + Usage: GLIBCXX_ENABLE_CXX_FLAGS(default flags)
2225 dnl If "default flags" is an empty string, the effect is the same
2226 dnl as --disable or --enable=no.
2227 dnl
2228 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
2229 AC_MSG_CHECKING([for extra compiler flags for building])
2230 GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
2231 [pass compiler FLAGS when building library],
2232 [case "x$enable_cxx_flags" in
2233 xno | x) enable_cxx_flags= ;;
2234 x-*) ;;
2235 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2236 esac])
2238 # Run through flags (either default or command-line) and set anything
2239 # extra (e.g., #defines) that must accompany particular g++ options.
2240 if test -n "$enable_cxx_flags"; then
2241 for f in $enable_cxx_flags; do
2242 case "$f" in
2243 -fhonor-std) ;;
2244 -*) ;;
2245 *) # and we're trying to pass /what/ exactly?
2246 AC_MSG_ERROR([compiler flags start with a -]) ;;
2247 esac
2248 done
2249 fi
2251 EXTRA_CXX_FLAGS="$enable_cxx_flags"
2252 AC_MSG_RESULT($EXTRA_CXX_FLAGS)
2253 AC_SUBST(EXTRA_CXX_FLAGS)
2254 ])
2257 dnl
2258 dnl Check to see if debugging libraries are to be built.
2259 dnl
2260 dnl --enable-libstdcxx-debug
2261 dnl builds a separate set of debugging libraries in addition to the
2262 dnl normal (shared, static) libstdc++ binaries.
2263 dnl
2264 dnl --disable-libstdcxx-debug
2265 dnl builds only one (non-debug) version of libstdc++.
2266 dnl
2267 dnl --enable-libstdcxx-debug-flags=FLAGS
2268 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
2269 dnl
2270 dnl + Usage: GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
2271 dnl Where DEFAULT is either `yes' or `no'.
2272 dnl
2273 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
2274 AC_MSG_CHECKING([for additional debug build])
2275 GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
2276 AC_MSG_RESULT($enable_libstdcxx_debug)
2277 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
2278 ])
2281 dnl
2282 dnl Check for explicit debug flags.
2283 dnl
2284 dnl --enable-libstdcxx-debug-flags='-O1'
2285 dnl is a general method for passing flags to be used when
2286 dnl building debug libraries with --enable-debug.
2287 dnl
2288 dnl --disable-libstdcxx-debug-flags does nothing.
2289 dnl + Usage: GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
2290 dnl If "default flags" is an empty string, the effect is the same
2291 dnl as --disable or --enable=no.
2292 dnl
2293 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
2294 GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
2295 [pass compiler FLAGS when building debug library],
2296 [case "x$enable_libstdcxx_debug_flags" in
2297 xno | x) enable_libstdcxx_debug_flags= ;;
2298 x-*) ;;
2299 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2300 esac])
2302 # Option parsed, now set things appropriately
2303 DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
2304 AC_SUBST(DEBUG_FLAGS)
2306 AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
2307 ])
2310 dnl
2311 dnl Check if the user only wants a freestanding library implementation.
2312 dnl
2313 dnl --disable-hosted-libstdcxx will turn off most of the library build,
2314 dnl installing only the headers required by [17.4.1.3] and the language
2315 dnl support library. More than that will be built (to keep the Makefiles
2316 dnl conveniently clean), but not installed.
2317 dnl
2318 dnl Sets:
2319 dnl is_hosted (yes/no)
2320 dnl
2321 dnl Defines:
2322 dnl _GLIBCXX_HOSTED (always defined, either to 1 or 0)
2323 dnl
2324 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
2325 AC_ARG_ENABLE([hosted-libstdcxx],
2326 AC_HELP_STRING([--disable-hosted-libstdcxx],
2327 [only build freestanding C++ runtime support]),,
2328 [case "$host" in
2329 arm*-*-symbianelf*)
2330 enable_hosted_libstdcxx=no
2331 ;;
2332 *)
2333 enable_hosted_libstdcxx=yes
2334 ;;
2335 esac])
2336 if test "$enable_hosted_libstdcxx" = no; then
2337 AC_MSG_NOTICE([Only freestanding libraries will be built])
2338 is_hosted=no
2339 hosted_define=0
2340 enable_abi_check=no
2341 enable_libstdcxx_pch=no
2342 else
2343 is_hosted=yes
2344 hosted_define=1
2345 fi
2346 GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
2347 AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
2348 [Define to 1 if a full hosted library is built, or 0 if freestanding.])
2349 ])
2352 dnl
2353 dnl Check if the user wants a non-verbose library implementation.
2354 dnl
2355 dnl --disable-libstdcxx-verbose will turn off descriptive messages to
2356 dnl standard error on termination.
2357 dnl
2358 dnl Defines:
2359 dnl _GLIBCXX_VERBOSE (always defined, either to 1 or 0)
2360 dnl
2361 AC_DEFUN([GLIBCXX_ENABLE_VERBOSE], [
2362 AC_ARG_ENABLE([libstdcxx-verbose],
2363 AC_HELP_STRING([--disable-libstdcxx-verbose],
2364 [disable termination messages to standard error]),,
2365 [enable_libstdcxx_verbose=yes])
2366 if test x"$enable_libstdcxx_verbose" = xyes; then
2367 verbose_define=1
2368 else
2369 AC_MSG_NOTICE([verbose termination messages are disabled])
2370 verbose_define=0
2371 fi
2372 AC_DEFINE_UNQUOTED(_GLIBCXX_VERBOSE, $verbose_define,
2373 [Define to 1 if a verbose library is built, or 0 otherwise.])
2374 ])
2377 dnl
2378 dnl Check for template specializations for the 'long long' type.
2379 dnl The result determines only whether 'long long' I/O is enabled; things
2380 dnl like numeric_limits<> specializations are always available.
2381 dnl
2382 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
2383 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
2384 dnl + Usage: GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
2385 dnl Where DEFAULT is either `yes' or `no'.
2386 dnl
2387 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
2388 GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
2389 if test $enable_long_long = yes; then
2390 AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
2391 [Define if code specialized for long long should be used.])
2392 fi
2393 AC_MSG_CHECKING([for enabled long long specializations])
2394 AC_MSG_RESULT([$enable_long_long])
2395 ])
2398 dnl
2399 dnl Check for decimal floating point.
2400 dnl See:
2401 dnl http://gcc.gnu.org/onlinedocs/gcc/Decimal-Float.html#Decimal-Float
2402 dnl
2403 dnl This checks to see if the host supports decimal floating point types.
2404 dnl
2405 dnl Defines:
2406 dnl _GLIBCXX_USE_DECIMAL_FLOAT
2407 dnl
2408 AC_DEFUN([GLIBCXX_ENABLE_DECIMAL_FLOAT], [
2410 # Fake what AC_TRY_COMPILE does, without linking as this is
2411 # unnecessary for this test.
2413 cat > conftest.$ac_ext << EOF
2414 [#]line __oline__ "configure"
2415 int main()
2416 {
2417 _Decimal32 d1;
2418 _Decimal64 d2;
2419 _Decimal128 d3;
2420 return 0;
2421 }
2422 EOF
2424 AC_MSG_CHECKING([for ISO/IEC TR 24733 ])
2425 if AC_TRY_EVAL(ac_compile); then
2426 AC_DEFINE(_GLIBCXX_USE_DECIMAL_FLOAT, 1,
2427 [Define if ISO/IEC TR 24733 decimal floating point types are supported on this host.])
2428 enable_dfp=yes
2429 else
2430 enable_dfp=no
2431 fi
2432 AC_MSG_RESULT($enable_dfp)
2433 rm -f conftest*
2434 ])
2436 dnl
2437 dnl Check for GNU 128-bit integer and floating point types.
2438 dnl
2439 dnl Note: also checks that the types aren't standard types.
2440 dnl
2441 dnl Defines:
2442 dnl _GLIBCXX_USE_INT128
2443 dnl _GLIBCXX_USE_FLOAT128
2444 dnl
2445 AC_DEFUN([GLIBCXX_ENABLE_INT128_FLOAT128], [
2447 AC_LANG_SAVE
2448 AC_LANG_CPLUSPLUS
2450 # Fake what AC_TRY_COMPILE does, without linking as this is
2451 # unnecessary for this test.
2453 cat > conftest.$ac_ext << EOF
2454 [#]line __oline__ "configure"
2455 template<typename T1, typename T2>
2456 struct same
2457 { typedef T2 type; };
2459 template<typename T>
2460 struct same<T, T>;
2462 int main()
2463 {
2464 typename same<long, __int128>::type i1;
2465 typename same<long long, __int128>::type i2;
2466 }
2467 EOF
2469 AC_MSG_CHECKING([for __int128])
2470 if AC_TRY_EVAL(ac_compile); then
2471 AC_DEFINE(_GLIBCXX_USE_INT128, 1,
2472 [Define if __int128 is supported on this host.])
2473 enable_int128=yes
2474 else
2475 enable_int128=no
2476 fi
2477 AC_MSG_RESULT($enable_int128)
2478 rm -f conftest*
2480 cat > conftest.$ac_ext << EOF
2481 [#]line __oline__ "configure"
2482 template<typename T1, typename T2>
2483 struct same
2484 { typedef T2 type; };
2486 template<typename T>
2487 struct same<T, T>;
2489 int main()
2490 {
2491 typename same<double, __float128>::type f1;
2492 typename same<long double, __float128>::type f2;
2493 }
2494 EOF
2496 AC_MSG_CHECKING([for __float128])
2497 if AC_TRY_EVAL(ac_compile); then
2498 AC_DEFINE(_GLIBCXX_USE_FLOAT128, 1,
2499 [Define if __float128 is supported on this host.])
2500 enable_float128=yes
2501 else
2502 enable_float128=no
2503 fi
2504 AC_MSG_RESULT($enable_float128)
2505 rm -f conftest*
2507 AC_LANG_RESTORE
2508 ])
2510 dnl
2511 dnl Check for template specializations for the 'wchar_t' type.
2512 dnl
2513 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
2514 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
2515 dnl + Usage: GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
2516 dnl Where DEFAULT is either `yes' or `no'.
2517 dnl
2518 dnl Necessary support must also be present.
2519 dnl
2520 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
2521 GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
2523 # Test wchar.h for mbstate_t, which is needed for char_traits and fpos.
2524 AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
2525 AC_MSG_CHECKING([for mbstate_t])
2526 AC_TRY_COMPILE([#include <wchar.h>],
2527 [mbstate_t teststate;],
2528 have_mbstate_t=yes, have_mbstate_t=no)
2529 AC_MSG_RESULT($have_mbstate_t)
2530 if test x"$have_mbstate_t" = xyes; then
2531 AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
2532 fi
2534 # Test it always, for use in GLIBCXX_ENABLE_C99, together with
2535 # ac_has_wchar_h.
2536 AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
2538 if test x"$enable_wchar_t" = x"yes"; then
2540 AC_LANG_SAVE
2541 AC_LANG_CPLUSPLUS
2543 if test x"$ac_has_wchar_h" = xyes &&
2544 test x"$ac_has_wctype_h" = xyes; then
2545 AC_TRY_COMPILE([#include <wchar.h>
2546 #include <stddef.h>
2547 wint_t i;
2548 long l = WEOF;
2549 long j = WCHAR_MIN;
2550 long k = WCHAR_MAX;
2551 namespace test
2552 {
2553 using ::btowc;
2554 using ::fgetwc;
2555 using ::fgetws;
2556 using ::fputwc;
2557 using ::fputws;
2558 using ::fwide;
2559 using ::fwprintf;
2560 using ::fwscanf;
2561 using ::getwc;
2562 using ::getwchar;
2563 using ::mbrlen;
2564 using ::mbrtowc;
2565 using ::mbsinit;
2566 using ::mbsrtowcs;
2567 using ::putwc;
2568 using ::putwchar;
2569 using ::swprintf;
2570 using ::swscanf;
2571 using ::ungetwc;
2572 using ::vfwprintf;
2573 using ::vswprintf;
2574 using ::vwprintf;
2575 using ::wcrtomb;
2576 using ::wcscat;
2577 using ::wcschr;
2578 using ::wcscmp;
2579 using ::wcscoll;
2580 using ::wcscpy;
2581 using ::wcscspn;
2582 using ::wcsftime;
2583 using ::wcslen;
2584 using ::wcsncat;
2585 using ::wcsncmp;
2586 using ::wcsncpy;
2587 using ::wcspbrk;
2588 using ::wcsrchr;
2589 using ::wcsrtombs;
2590 using ::wcsspn;
2591 using ::wcsstr;
2592 using ::wcstod;
2593 using ::wcstok;
2594 using ::wcstol;
2595 using ::wcstoul;
2596 using ::wcsxfrm;
2597 using ::wctob;
2598 using ::wmemchr;
2599 using ::wmemcmp;
2600 using ::wmemcpy;
2601 using ::wmemmove;
2602 using ::wmemset;
2603 using ::wprintf;
2604 using ::wscanf;
2605 }
2606 ],[],[], [enable_wchar_t=no])
2607 else
2608 enable_wchar_t=no
2609 fi
2611 AC_LANG_RESTORE
2612 fi
2614 if test x"$enable_wchar_t" = x"yes"; then
2615 AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
2616 [Define if code specialized for wchar_t should be used.])
2617 fi
2619 AC_MSG_CHECKING([for enabled wchar_t specializations])
2620 AC_MSG_RESULT([$enable_wchar_t])
2621 ])
2624 dnl
2625 dnl Check to see if building and using a C++ precompiled header can be done.
2626 dnl
2627 dnl --enable-libstdcxx-pch=yes
2628 dnl default, this shows intent to use stdc++.h.gch If it looks like it
2629 dnl may work, after some light-hearted attempts to puzzle out compiler
2630 dnl support, flip bits on in include/Makefile.am
2631 dnl
2632 dnl --disable-libstdcxx-pch
2633 dnl turns off attempts to use or build stdc++.h.gch.
2634 dnl
2635 dnl Substs:
2636 dnl glibcxx_PCHFLAGS
2637 dnl
2638 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
2639 GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
2640 if test $enable_libstdcxx_pch = yes; then
2641 AC_CACHE_CHECK([for compiler with PCH support],
2642 [glibcxx_cv_prog_CXX_pch],
2643 [ac_save_CXXFLAGS="$CXXFLAGS"
2644 CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
2645 AC_LANG_SAVE
2646 AC_LANG_CPLUSPLUS
2647 echo '#include <math.h>' > conftest.h
2648 if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
2649 -o conftest.h.gch 1>&5 2>&1 &&
2650 echo '#error "pch failed"' > conftest.h &&
2651 echo '#include "conftest.h"' > conftest.cc &&
2652 $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
2653 then
2654 glibcxx_cv_prog_CXX_pch=yes
2655 else
2656 glibcxx_cv_prog_CXX_pch=no
2657 fi
2658 rm -f conftest*
2659 CXXFLAGS=$ac_save_CXXFLAGS
2660 AC_LANG_RESTORE
2661 ])
2662 enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
2663 fi
2665 AC_MSG_CHECKING([for enabled PCH])
2666 AC_MSG_RESULT([$enable_libstdcxx_pch])
2668 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
2669 if test $enable_libstdcxx_pch = yes; then
2670 glibcxx_PCHFLAGS="-include bits/stdc++.h"
2671 else
2672 glibcxx_PCHFLAGS=""
2673 fi
2674 AC_SUBST(glibcxx_PCHFLAGS)
2675 ])
2678 dnl
2679 dnl Check for atomic builtins.
2680 dnl See:
2681 dnl http://gcc.gnu.org/onlinedocs/gcc/_005f_005fatomic-Builtins.html
2682 dnl
2683 dnl This checks to see if the host supports the compiler-generated
2684 dnl builtins for atomic operations for various integral sizes. Note, this
2685 dnl is intended to be an all-or-nothing switch, so all the atomic operations
2686 dnl that are used should be checked.
2687 dnl
2688 dnl Note:
2689 dnl libgomp and libgfortran use a link test, see CHECK_SYNC_FETCH_AND_ADD.
2690 dnl
2691 AC_DEFUN([GLIBCXX_ENABLE_ATOMIC_BUILTINS], [
2692 AC_LANG_SAVE
2693 AC_LANG_CPLUSPLUS
2694 old_CXXFLAGS="$CXXFLAGS"
2696 # Do link tests if possible, instead asm tests, limited to some platforms
2697 # see discussion in PR target/40134, PR libstdc++/40133 and the thread
2698 # starting at http://gcc.gnu.org/ml/gcc-patches/2009-07/msg00322.html
2699 atomic_builtins_link_tests=no
2700 if test x$gcc_no_link != xyes; then
2701 # Can do link tests. Limit to some tested platforms
2702 case "$host" in
2703 *-*-linux* | *-*-uclinux* | *-*-kfreebsd*-gnu | *-*-gnu*)
2704 atomic_builtins_link_tests=yes
2705 ;;
2706 esac
2707 fi
2709 if test x$atomic_builtins_link_tests = xyes; then
2711 # Do link tests.
2713 CXXFLAGS="$CXXFLAGS -fno-exceptions"
2715 AC_MSG_CHECKING([for atomic builtins for bool])
2716 AC_CACHE_VAL(glibcxx_cv_atomic_bool, [
2717 AC_TRY_LINK(
2718 [ ],
2719 [typedef bool atomic_type;
2720 atomic_type c1;
2721 atomic_type c2;
2722 atomic_type c3(0);
2723 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2724 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2725 __ATOMIC_RELAXED);
2726 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2727 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2728 ],
2729 [glibcxx_cv_atomic_bool=yes],
2730 [glibcxx_cv_atomic_bool=no])
2731 ])
2732 AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2734 AC_MSG_CHECKING([for atomic builtins for short])
2735 AC_CACHE_VAL(glibcxx_cv_atomic_short, [
2736 AC_TRY_LINK(
2737 [ ],
2738 [typedef short atomic_type;
2739 atomic_type c1;
2740 atomic_type c2;
2741 atomic_type c3(0);
2742 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2743 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2744 __ATOMIC_RELAXED);
2745 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2746 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2747 ],
2748 [glibcxx_cv_atomic_short=yes],
2749 [glibcxx_cv_atomic_short=no])
2750 ])
2751 AC_MSG_RESULT($glibcxx_cv_atomic_short)
2753 AC_MSG_CHECKING([for atomic builtins for int])
2754 AC_CACHE_VAL(glibcxx_cv_atomic_int, [
2755 AC_TRY_LINK(
2756 [ ],
2757 [typedef int atomic_type;
2758 atomic_type c1;
2759 atomic_type c2;
2760 atomic_type c3(0);
2761 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2762 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2763 __ATOMIC_RELAXED);
2764 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2765 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2766 ],
2767 [glibcxx_cv_atomic_int=yes],
2768 [glibcxx_cv_atomic_int=no])
2769 ])
2770 AC_MSG_RESULT($glibcxx_cv_atomic_int)
2772 AC_MSG_CHECKING([for atomic builtins for long long])
2773 AC_CACHE_VAL(glibcxx_cv_atomic_long_long, [
2774 AC_TRY_LINK(
2775 [ ],
2776 [typedef long long atomic_type;
2777 atomic_type c1;
2778 atomic_type c2;
2779 atomic_type c3(0);
2780 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2781 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2782 __ATOMIC_RELAXED);
2783 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2784 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2785 ],
2786 [glibcxx_cv_atomic_long_long=yes],
2787 [glibcxx_cv_atomic_long_long=no])
2788 ])
2789 AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2791 else
2793 # Do asm tests.
2795 # Compile unoptimized.
2796 CXXFLAGS='-O0 -S'
2798 # Fake what AC_TRY_COMPILE does.
2800 cat > conftest.$ac_ext << EOF
2801 [#]line __oline__ "configure"
2802 int main()
2803 {
2804 typedef bool atomic_type;
2805 atomic_type c1;
2806 atomic_type c2;
2807 atomic_type c3(0);
2808 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2809 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2810 __ATOMIC_RELAXED);
2811 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2812 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2814 return 0;
2815 }
2816 EOF
2818 AC_MSG_CHECKING([for atomic builtins for bool])
2819 if AC_TRY_EVAL(ac_compile); then
2820 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2821 glibcxx_cv_atomic_bool=no
2822 else
2823 glibcxx_cv_atomic_bool=yes
2824 fi
2825 fi
2826 AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2827 rm -f conftest*
2829 cat > conftest.$ac_ext << EOF
2830 [#]line __oline__ "configure"
2831 int main()
2832 {
2833 typedef short atomic_type;
2834 atomic_type c1;
2835 atomic_type c2;
2836 atomic_type c3(0);
2837 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2838 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2839 __ATOMIC_RELAXED);
2840 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2841 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2843 return 0;
2844 }
2845 EOF
2847 AC_MSG_CHECKING([for atomic builtins for short])
2848 if AC_TRY_EVAL(ac_compile); then
2849 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2850 glibcxx_cv_atomic_short=no
2851 else
2852 glibcxx_cv_atomic_short=yes
2853 fi
2854 fi
2855 AC_MSG_RESULT($glibcxx_cv_atomic_short)
2856 rm -f conftest*
2858 cat > conftest.$ac_ext << EOF
2859 [#]line __oline__ "configure"
2860 int main()
2861 {
2862 // NB: _Atomic_word not necessarily int.
2863 typedef int atomic_type;
2864 atomic_type c1;
2865 atomic_type c2;
2866 atomic_type c3(0);
2867 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2868 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2869 __ATOMIC_RELAXED);
2870 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2871 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2873 return 0;
2874 }
2875 EOF
2877 AC_MSG_CHECKING([for atomic builtins for int])
2878 if AC_TRY_EVAL(ac_compile); then
2879 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2880 glibcxx_cv_atomic_int=no
2881 else
2882 glibcxx_cv_atomic_int=yes
2883 fi
2884 fi
2885 AC_MSG_RESULT($glibcxx_cv_atomic_int)
2886 rm -f conftest*
2888 cat > conftest.$ac_ext << EOF
2889 [#]line __oline__ "configure"
2890 int main()
2891 {
2892 typedef long long atomic_type;
2893 atomic_type c1;
2894 atomic_type c2;
2895 atomic_type c3(0);
2896 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2897 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2898 __ATOMIC_RELAXED);
2899 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2900 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2902 return 0;
2903 }
2904 EOF
2906 AC_MSG_CHECKING([for atomic builtins for long long])
2907 if AC_TRY_EVAL(ac_compile); then
2908 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2909 glibcxx_cv_atomic_long_long=no
2910 else
2911 glibcxx_cv_atomic_long_long=yes
2912 fi
2913 fi
2914 AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2915 rm -f conftest*
2917 fi
2919 CXXFLAGS="$old_CXXFLAGS"
2920 AC_LANG_RESTORE
2922 # Set atomicity_dir to builtins if all but the long long test above passes.
2923 if test $glibcxx_cv_atomic_bool = yes \
2924 && test $glibcxx_cv_atomic_short = yes \
2925 && test $glibcxx_cv_atomic_int = yes; then
2926 AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS, 1,
2927 [Define if the compiler supports C++11 atomics.])
2928 atomicity_dir=cpu/generic/atomicity_builtins
2929 fi
2931 # If still generic, set to mutex.
2932 if test $atomicity_dir = "cpu/generic" ; then
2933 atomicity_dir=cpu/generic/atomicity_mutex
2934 AC_MSG_WARN([No native atomic operations are provided for this platform.])
2935 if test "x$target_thread_file" = xsingle; then
2936 AC_MSG_WARN([They cannot be faked when thread support is disabled.])
2937 AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
2938 else
2939 AC_MSG_WARN([They will be faked using a mutex.])
2940 AC_MSG_WARN([Performance of certain classes will degrade as a result.])
2941 fi
2942 fi
2944 ])
2947 dnl
2948 dnl Check for exception handling support. If an explicit enable/disable
2949 dnl sjlj exceptions is given, we don't have to detect. Otherwise the
2950 dnl target may or may not support call frame exceptions.
2951 dnl
2952 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
2953 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
2954 dnl Neither one forces an attempt at detection.
2955 dnl
2956 dnl Defines:
2957 dnl _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
2958 dnl
2959 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
2960 AC_MSG_CHECKING([for exception model to use])
2961 AC_LANG_SAVE
2962 AC_LANG_CPLUSPLUS
2963 GLIBCXX_ENABLE(sjlj-exceptions,auto,,
2964 [force use of builtin_setjmp for exceptions],
2965 [permit yes|no|auto])
2967 if test $enable_sjlj_exceptions = auto; then
2968 # Botheration. Now we've got to detect the exception model. Link tests
2969 # against libgcc.a are problematic since we've not been given proper -L
2970 # bits for single-tree newlib and libgloss.
2971 #
2972 # Fake what AC_TRY_COMPILE does. XXX Look at redoing this new-style.
2973 cat > conftest.$ac_ext << EOF
2974 [#]line __oline__ "configure"
2975 struct S { ~S(); };
2976 void bar();
2977 void foo()
2978 {
2979 S s;
2980 bar();
2981 }
2982 EOF
2983 old_CXXFLAGS="$CXXFLAGS"
2984 CXXFLAGS=-S
2985 if AC_TRY_EVAL(ac_compile); then
2986 if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
2987 enable_sjlj_exceptions=yes
2988 elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
2989 enable_sjlj_exceptions=no
2990 elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
2991 enable_sjlj_exceptions=no
2992 fi
2993 fi
2994 CXXFLAGS="$old_CXXFLAGS"
2995 rm -f conftest*
2996 fi
2998 # This is a tad weird, for hysterical raisins. We have to map
2999 # enable/disable to two different models.
3000 case $enable_sjlj_exceptions in
3001 yes)
3002 AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
3003 [Define if the compiler is configured for setjmp/longjmp exceptions.])
3004 ac_exception_model_name=sjlj
3005 ;;
3006 no)
3007 ac_exception_model_name="call frame"
3008 ;;
3009 *)
3010 AC_MSG_ERROR([unable to detect exception model])
3011 ;;
3012 esac
3013 AC_LANG_RESTORE
3014 AC_MSG_RESULT($ac_exception_model_name)
3015 ])
3018 dnl
3019 dnl Allow visibility attributes to be used on namespaces, objects, etc.
3020 dnl
3021 dnl --enable-libstdcxx-visibility enables attempt to use visibility attributes.
3022 dnl --disable-libstdcxx-visibility turns off all use of visibility attributes.
3023 dnl + Usage: GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY[(DEFAULT)]
3024 dnl Where DEFAULT is 'yes'.
3025 dnl
3026 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY], [
3027 GLIBCXX_ENABLE(libstdcxx-visibility,$1,,[enables visibility safe usage])
3029 if test x$enable_libstdcxx_visibility = xyes ; then
3030 dnl all hail libgfortran
3031 dnl Check whether the target supports hidden visibility.
3032 AC_CACHE_CHECK([whether the target supports hidden visibility],
3033 glibcxx_cv_have_attribute_visibility, [
3034 save_CFLAGS="$CFLAGS"
3035 CFLAGS="$CFLAGS -Werror"
3036 AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
3037 [], glibcxx_cv_have_attribute_visibility=yes,
3038 glibcxx_cv_have_attribute_visibility=no)
3039 CFLAGS="$save_CFLAGS"])
3040 if test $glibcxx_cv_have_attribute_visibility = no; then
3041 enable_libstdcxx_visibility=no
3042 fi
3043 fi
3045 GLIBCXX_CONDITIONAL(ENABLE_VISIBILITY, test $enable_libstdcxx_visibility = yes)
3046 AC_MSG_NOTICE([visibility supported: $enable_libstdcxx_visibility])
3047 ])
3050 dnl
3051 dnl Add version tags to symbols in shared library (or not), additionally
3052 dnl marking other symbols as private/local (or not).
3053 dnl
3054 dnl Sets libtool_VERSION, and determines shared library SONAME.
3055 dnl
3056 dnl This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
3057 dnl
3058 dnl --enable-symvers=style adds a version script to the linker call when
3059 dnl creating the shared library. The choice of version script is
3060 dnl controlled by 'style'.
3061 dnl --disable-symvers does not.
3062 dnl
3063 dnl + Usage: GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
3064 dnl Where DEFAULT is either 'yes' or 'no'. Passing `yes' tries to
3065 dnl choose a default style based on linker characteristics. Passing
3066 dnl 'no' disables versioning.
3067 dnl
3068 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
3070 GLIBCXX_ENABLE(symvers,$1,[[[=STYLE]]],
3071 [enables symbol versioning of the shared library],
3072 [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export|sun])
3074 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
3075 # don't know enough about $LD to do tricks...
3076 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
3077 # Sun style symbol versions needs GNU c++filt for make_sunver.pl to work
3078 # with extern "C++" in version scripts.
3079 AC_REQUIRE([GCC_PROG_GNU_CXXFILT])
3081 # Turn a 'yes' into a suitable default.
3082 if test x$enable_symvers = xyes ; then
3083 if test $enable_shared = no || test "x$LD" = x || test x$gcc_no_link = xyes; then
3084 enable_symvers=no
3085 else
3086 if test $with_gnu_ld = yes ; then
3087 case ${target_os} in
3088 hpux*)
3089 enable_symvers=no ;;
3090 *)
3091 enable_symvers=gnu ;;
3092 esac
3093 else
3094 case ${target_os} in
3095 darwin*)
3096 enable_symvers=darwin ;;
3097 # Sun symbol versioning exists since Solaris 2.5.
3098 solaris2.[[5-9]]* | solaris2.1[[0-9]]*)
3099 # make_sunver.pl needs GNU c++filt to support extern "C++" in
3100 # version scripts, so disable symbol versioning if none can be
3101 # found.
3102 if test -z "$ac_cv_path_CXXFILT"; then
3103 AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3104 AC_MSG_WARN([=== no GNU c++filt could be found.])
3105 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3106 enable_symvers=no
3107 else
3108 enable_symvers=sun
3109 fi
3110 ;;
3111 *)
3112 enable_symvers=no ;;
3113 esac
3114 fi
3115 fi
3116 fi
3118 # Check to see if 'darwin' or 'darwin-export' can win.
3119 if test x$enable_symvers = xdarwin-export ; then
3120 enable_symvers=darwin
3121 fi
3123 # Check if 'sun' was requested on non-Solaris 2 platforms.
3124 if test x$enable_symvers = xsun ; then
3125 case ${target_os} in
3126 solaris2*)
3127 # All fine.
3128 ;;
3129 *)
3130 # Unlikely to work.
3131 AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3132 AC_MSG_WARN([=== you are not targetting Solaris 2.])
3133 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3134 enable_symvers=no
3135 ;;
3136 esac
3137 fi
3139 # Check to see if 'gnu' can win.
3140 if test $enable_symvers = gnu ||
3141 test $enable_symvers = gnu-versioned-namespace ||
3142 test $enable_symvers = sun; then
3143 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
3144 AC_MSG_CHECKING([for shared libgcc])
3145 ac_save_CFLAGS="$CFLAGS"
3146 CFLAGS=' -lgcc_s'
3147 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
3148 CFLAGS="$ac_save_CFLAGS"
3149 if test $glibcxx_shared_libgcc = no; then
3150 cat > conftest.c <<EOF
3151 int main (void) { return 0; }
3152 EOF
3153 changequote(,)dnl
3154 glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
3155 -shared -shared-libgcc -o conftest.so \
3156 conftest.c -v 2>&1 >/dev/null \
3157 | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
3158 changequote([,])dnl
3159 rm -f conftest.c conftest.so
3160 if test x${glibcxx_libgcc_s_suffix+set} = xset; then
3161 CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
3162 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
3163 CFLAGS="$ac_save_CFLAGS"
3164 fi
3165 fi
3166 AC_MSG_RESULT($glibcxx_shared_libgcc)
3168 # For GNU ld, we need at least this version. The format is described in
3169 # GLIBCXX_CHECK_LINKER_FEATURES above.
3170 glibcxx_min_gnu_ld_version=21400
3172 # If no shared libgcc, can't win.
3173 if test $glibcxx_shared_libgcc != yes; then
3174 AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3175 AC_MSG_WARN([=== you are not building a shared libgcc_s.])
3176 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3177 enable_symvers=no
3178 elif test $with_gnu_ld != yes && test $enable_symvers = sun; then
3179 : All interesting versions of Sun ld support sun style symbol versioning.
3180 elif test $with_gnu_ld != yes ; then
3181 # just fail for now
3182 AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3183 AC_MSG_WARN([=== you are not using the GNU linker.])
3184 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3185 enable_symvers=no
3186 elif test $glibcxx_ld_is_gold = yes ; then
3187 : All versions of gold support symbol versioning.
3188 elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
3189 # The right tools, the right setup, but too old. Fallbacks?
3190 AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
3191 AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
3192 AC_MSG_WARN(=== You would need to upgrade your binutils to version)
3193 AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
3194 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3195 enable_symvers=no
3196 fi
3197 fi
3199 # For libtool versioning info, format is CURRENT:REVISION:AGE
3200 libtool_VERSION=6:17:0
3202 # Everything parsed; figure out what files and settings to use.
3203 case $enable_symvers in
3204 no)
3205 SYMVER_FILE=config/abi/pre/none.ver
3206 ;;
3207 gnu)
3208 SYMVER_FILE=config/abi/pre/gnu.ver
3209 AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
3210 [Define to use GNU versioning in the shared library.])
3211 ;;
3212 gnu-versioned-namespace)
3213 libtool_VERSION=7:0:0
3214 SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
3215 AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
3216 [Define to use GNU namespace versioning in the shared library.])
3217 ;;
3218 darwin)
3219 SYMVER_FILE=config/abi/pre/gnu.ver
3220 AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
3221 [Define to use darwin versioning in the shared library.])
3222 ;;
3223 sun)
3224 SYMVER_FILE=config/abi/pre/gnu.ver
3225 AC_DEFINE(_GLIBCXX_SYMVER_SUN, 1,
3226 [Define to use Sun versioning in the shared library.])
3227 ;;
3228 esac
3230 if test x$enable_symvers != xno ; then
3231 AC_DEFINE(_GLIBCXX_SYMVER, 1,
3232 [Define to use symbol versioning in the shared library.])
3233 fi
3235 AC_CACHE_CHECK([whether the target supports .symver directive],
3236 glibcxx_cv_have_as_symver_directive, [
3237 AC_TRY_COMPILE([void foo (void); __asm (".symver foo, bar@SYMVER");],
3238 [], glibcxx_cv_have_as_symver_directive=yes,
3239 glibcxx_cv_have_as_symver_directive=no)])
3240 if test $glibcxx_cv_have_as_symver_directive = yes; then
3241 AC_DEFINE(HAVE_AS_SYMVER_DIRECTIVE, 1,
3242 [Define to 1 if the target assembler supports .symver directive.])
3243 fi
3245 AC_SUBST(SYMVER_FILE)
3246 AC_SUBST(port_specific_symbol_files)
3247 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
3248 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
3249 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
3250 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
3251 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_SUN, test $enable_symvers = sun)
3252 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
3254 if test $enable_symvers != no ; then
3255 case ${target_os} in
3256 # The Solaris 2 runtime linker doesn't support the GNU extension of
3257 # binding the same symbol to different versions
3258 solaris2*)
3259 ;;
3260 # Other platforms with GNU symbol versioning (GNU/Linux, more?) do.
3261 *)
3262 AC_DEFINE(HAVE_SYMVER_SYMBOL_RENAMING_RUNTIME_SUPPORT, 1,
3263 [Define to 1 if the target runtime linker supports binding the same symbol to different versions.])
3264 ;;
3265 esac
3266 fi
3268 # Now, set up compatibility support, if any.
3269 # In addition, need this to deal with std::size_t mangling in
3270 # src/compatibility.cc. In a perfect world, could use
3271 # typeid(std::size_t).name()[0] to do direct substitution.
3272 AC_MSG_CHECKING([for size_t as unsigned int])
3273 ac_save_CFLAGS="$CFLAGS"
3274 CFLAGS="-Werror"
3275 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
3276 [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
3277 CFLAGS=$ac_save_CFLAGS
3278 if test "$glibcxx_size_t_is_i" = yes; then
3279 AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
3280 fi
3281 AC_MSG_RESULT([$glibcxx_size_t_is_i])
3283 AC_MSG_CHECKING([for ptrdiff_t as int])
3284 ac_save_CFLAGS="$CFLAGS"
3285 CFLAGS="-Werror"
3286 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
3287 [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
3288 CFLAGS=$ac_save_CFLAGS
3289 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
3290 AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
3291 fi
3292 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
3293 ])
3296 dnl
3297 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
3298 dnl We must stage the required headers so that they will be installed
3299 dnl with the library (unlike libgcc, the STL implementation is provided
3300 dnl solely within headers). Since we must not inject random user-space
3301 dnl macro names into user-provided C++ code, we first stage into <file>-in
3302 dnl and process to <file> with an output command. The reason for a two-
3303 dnl stage process here is to correctly handle $srcdir!=$objdir without
3304 dnl having to write complex code (the sed commands to clean the macro
3305 dnl namespace are complex and fragile enough as it is). We must also
3306 dnl add a relative path so that -I- is supported properly.
3307 dnl
3308 dnl Substs:
3309 dnl thread_header
3310 dnl
3311 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
3312 AC_MSG_CHECKING([for thread model used by GCC])
3313 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3314 AC_MSG_RESULT([$target_thread_file])
3315 GCC_AC_THREAD_HEADER([$target_thread_file])
3316 ])
3319 dnl
3320 dnl Check if gthread implementation defines the types and functions
3321 dnl required by the c++0x thread library. Conforming gthread
3322 dnl implementations can define __GTHREADS_CXX0X to enable use with c++0x.
3323 dnl
3324 dnl GLIBCXX_ENABLE_SYMVERS must be done before this.
3325 dnl
3326 AC_DEFUN([GLIBCXX_CHECK_GTHREADS], [
3327 GLIBCXX_ENABLE(libstdcxx-threads,auto,,[enable C++11 threads support])
3329 if test x$enable_libstdcxx_threads = xauto ||
3330 test x$enable_libstdcxx_threads = xyes; then
3332 AC_LANG_SAVE
3333 AC_LANG_CPLUSPLUS
3335 ac_save_CXXFLAGS="$CXXFLAGS"
3336 CXXFLAGS="$CXXFLAGS -fno-exceptions \
3337 -I${toplevel_srcdir}/libgcc -I${toplevel_builddir}/libgcc"
3339 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3340 case $target_thread_file in
3341 posix)
3342 CXXFLAGS="$CXXFLAGS -DSUPPORTS_WEAK -DGTHREAD_USE_WEAK -D_PTHREADS"
3343 esac
3345 AC_MSG_CHECKING([whether it can be safely assumed that mutex_timedlock is available])
3347 AC_TRY_COMPILE([#include <unistd.h>],
3348 [
3349 // In case of POSIX threads check _POSIX_TIMEOUTS.
3350 #if (defined(_PTHREADS) \
3351 && (!defined(_POSIX_TIMEOUTS) || _POSIX_TIMEOUTS <= 0))
3352 #error
3353 #endif
3354 ], [ac_gthread_use_mutex_timedlock=1], [ac_gthread_use_mutex_timedlock=0])
3356 AC_DEFINE_UNQUOTED(_GTHREAD_USE_MUTEX_TIMEDLOCK, $ac_gthread_use_mutex_timedlock,
3357 [Define to 1 if mutex_timedlock is available.])
3359 if test $ac_gthread_use_mutex_timedlock = 1 ; then res_mutex_timedlock=yes ;
3360 else res_mutex_timedlock=no ; fi
3361 AC_MSG_RESULT([$res_mutex_timedlock])
3363 AC_MSG_CHECKING([for gthreads library])
3365 AC_TRY_COMPILE([#include "gthr.h"],
3366 [
3367 #ifndef __GTHREADS_CXX0X
3368 #error
3369 #endif
3370 ], [case $target_os in
3371 # gthreads support breaks symbol versioning on Solaris 9 (PR
3372 # libstdc++/52189).
3373 solaris2.9*)
3374 if test x$enable_symvers = xno; then
3375 ac_has_gthreads=yes
3376 elif test x$enable_libstdcxx_threads = xyes; then
3377 AC_MSG_WARN([You have requested C++11 threads support, but])
3378 AC_MSG_WARN([this breaks symbol versioning.])
3379 ac_has_gthreads=yes
3380 else
3381 ac_has_gthreads=no
3382 fi
3383 ;;
3384 *)
3385 ac_has_gthreads=yes
3386 ;;
3387 esac],
3388 [ac_has_gthreads=no])
3389 else
3390 ac_has_gthreads=no
3391 fi
3393 AC_MSG_RESULT([$ac_has_gthreads])
3395 if test x"$ac_has_gthreads" = x"yes"; then
3396 AC_DEFINE(_GLIBCXX_HAS_GTHREADS, 1,
3397 [Define if gthreads library is available.])
3398 fi
3400 CXXFLAGS="$ac_save_CXXFLAGS"
3401 AC_LANG_RESTORE
3402 ])
3405 # Check whether LC_MESSAGES is available in <locale.h>.
3406 # Ulrich Drepper <drepper@cygnus.com>, 1995.
3407 #
3408 # This file file be copied and used freely without restrictions. It can
3409 # be used in projects which are not available under the GNU Public License
3410 # but which still want to provide support for the GNU gettext functionality.
3411 # Please note that the actual code is *not* freely available.
3412 AC_DEFUN([AC_LC_MESSAGES], [
3413 AC_CHECK_HEADER(locale.h, [
3414 AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
3415 [AC_TRY_COMPILE([#include <locale.h>], [return LC_MESSAGES],
3416 ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
3417 if test $ac_cv_val_LC_MESSAGES = yes; then
3418 AC_DEFINE(HAVE_LC_MESSAGES, 1,
3419 [Define if LC_MESSAGES is available in <locale.h>.])
3420 fi
3421 ])
3422 ])
3424 dnl
3425 dnl Check whether rdrand is supported in the assembler.
3426 AC_DEFUN([GLIBCXX_CHECK_X86_RDRAND], [
3427 AC_MSG_CHECKING([for rdrand support in assembler])
3428 AC_CACHE_VAL(ac_cv_x86_rdrand, [
3429 ac_cv_x86_rdrand=no
3430 case "$target" in
3431 i?86-*-* | \
3432 x86_64-*-*)
3433 AC_TRY_COMPILE(, [asm("rdrand %eax");],
3434 [ac_cv_x86_rdrand=yes], [ac_cv_x86_rdrand=no])
3435 esac
3436 ])
3437 if test $ac_cv_x86_rdrand = yes; then
3438 AC_DEFINE(_GLIBCXX_X86_RDRAND, 1,
3439 [ Defined if as can handle rdrand. ])
3440 fi
3441 AC_MSG_RESULT($ac_cv_x86_rdrand)
3442 ])
3444 dnl
3445 dnl Check whether get_nprocs is available in <sys/sysinfo.h>, and define _GLIBCXX_USE_GET_NPROCS.
3446 dnl
3447 AC_DEFUN([GLIBCXX_CHECK_GET_NPROCS], [
3449 AC_LANG_SAVE
3450 AC_LANG_CPLUSPLUS
3451 ac_save_CXXFLAGS="$CXXFLAGS"
3452 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3454 AC_MSG_CHECKING([for get_nprocs])
3455 AC_CACHE_VAL(glibcxx_cv_GET_NPROCS, [
3456 GCC_TRY_COMPILE_OR_LINK(
3457 [#include <sys/sysinfo.h>],
3458 [int n = get_nprocs();],
3459 [glibcxx_cv_GET_NPROCS=yes],
3460 [glibcxx_cv_GET_NPROCS=no])
3461 ])
3462 if test $glibcxx_cv_GET_NPROCS = yes; then
3463 AC_DEFINE(_GLIBCXX_USE_GET_NPROCS, 1, [Define if get_nprocs is available in <sys/sysinfo.h>.])
3464 fi
3465 AC_MSG_RESULT($glibcxx_cv_GET_NPROCS)
3467 CXXFLAGS="$ac_save_CXXFLAGS"
3468 AC_LANG_RESTORE
3469 ])
3471 dnl
3472 dnl Check whether sysconf(_SC_NPROCESSORS_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROCESSORS_ONLN.
3473 dnl
3474 AC_DEFUN([GLIBCXX_CHECK_SC_NPROCESSORS_ONLN], [
3476 AC_LANG_SAVE
3477 AC_LANG_CPLUSPLUS
3478 ac_save_CXXFLAGS="$CXXFLAGS"
3479 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3481 AC_MSG_CHECKING([for _SC_NPROCESSORS_ONLN])
3482 AC_CACHE_VAL(glibcxx_cv_SC_NPROCESSORS_ONLN, [
3483 GCC_TRY_COMPILE_OR_LINK(
3484 [#include <unistd.h>],
3485 [int n = sysconf(_SC_NPROCESSORS_ONLN);],
3486 [glibcxx_cv_SC_NPROCESSORS_ONLN=yes],
3487 [glibcxx_cv_SC_NPROCESSORS_ONLN=no])
3488 ])
3489 if test $glibcxx_cv_SC_NPROCESSORS_ONLN = yes; then
3490 AC_DEFINE(_GLIBCXX_USE_SC_NPROCESSORS_ONLN, 1, [Define if _SC_NPROCESSORS_ONLN is available in <unistd.h>.])
3491 fi
3492 AC_MSG_RESULT($glibcxx_cv_SC_NPROCESSORS_ONLN)
3494 CXXFLAGS="$ac_save_CXXFLAGS"
3495 AC_LANG_RESTORE
3496 ])
3498 dnl
3499 dnl Check whether sysconf(_SC_NPROC_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROC_ONLN.
3500 dnl
3501 AC_DEFUN([GLIBCXX_CHECK_SC_NPROC_ONLN], [
3503 AC_LANG_SAVE
3504 AC_LANG_CPLUSPLUS
3505 ac_save_CXXFLAGS="$CXXFLAGS"
3506 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3508 AC_MSG_CHECKING([for _SC_NPROC_ONLN])
3509 AC_CACHE_VAL(glibcxx_cv_SC_NPROC_ONLN, [
3510 GCC_TRY_COMPILE_OR_LINK(
3511 [#include <unistd.h>],
3512 [int n = sysconf(_SC_NPROC_ONLN);],
3513 [glibcxx_cv_SC_NPROC_ONLN=yes],
3514 [glibcxx_cv_SC_NPROC_ONLN=no])
3515 ])
3516 if test $glibcxx_cv_SC_NPROC_ONLN = yes; then
3517 AC_DEFINE(_GLIBCXX_USE_SC_NPROC_ONLN, 1, [Define if _SC_NPROC_ONLN is available in <unistd.h>.])
3518 fi
3519 AC_MSG_RESULT($glibcxx_cv_SC_NPROC_ONLN)
3521 CXXFLAGS="$ac_save_CXXFLAGS"
3522 AC_LANG_RESTORE
3523 ])
3525 dnl
3526 dnl Check whether pthread_num_processors_np is available in <pthread.h>, and define _GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP.
3527 dnl
3528 AC_DEFUN([GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP], [
3530 AC_LANG_SAVE
3531 AC_LANG_CPLUSPLUS
3532 ac_save_CXXFLAGS="$CXXFLAGS"
3533 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3535 AC_MSG_CHECKING([for pthreads_num_processors_np])
3536 AC_CACHE_VAL(glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP, [
3537 GCC_TRY_COMPILE_OR_LINK(
3538 [#include <pthread.h>],
3539 [int n = pthread_num_processors_np();],
3540 [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=yes],
3541 [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=no])
3542 ])
3543 if test $glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP = yes; then
3544 AC_DEFINE(_GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP, 1, [Define if pthreads_num_processors_np is available in <pthread.h>.])
3545 fi
3546 AC_MSG_RESULT($glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP)
3548 CXXFLAGS="$ac_save_CXXFLAGS"
3549 AC_LANG_RESTORE
3550 ])
3552 dnl
3553 dnl Check whether sysctl is available in <pthread.h>, and define _GLIBCXX_USE_SYSCTL_HW_NCPU.
3554 dnl
3555 AC_DEFUN([GLIBCXX_CHECK_SYSCTL_HW_NCPU], [
3557 AC_LANG_SAVE
3558 AC_LANG_CPLUSPLUS
3559 ac_save_CXXFLAGS="$CXXFLAGS"
3560 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3562 AC_MSG_CHECKING([for hw.ncpu sysctl])
3563 AC_CACHE_VAL(glibcxx_cv_SYSCTL_HW_NCPU, [
3564 GCC_TRY_COMPILE_OR_LINK(
3565 [
3566 #include <stddef.h>
3567 #include <sys/sysctl.h>
3568 ],
3569 [
3570 int count;
3571 size_t size = sizeof(count);
3572 int mib[] = { CTL_HW, HW_NCPU };
3573 sysctl(mib, 2, &count, &size, NULL, 0);
3574 ],
3575 [glibcxx_cv_SYSCTL_HW_NCPU=yes],
3576 [glibcxx_cv_SYSCTL_HW_NCPU=no])
3577 ])
3578 if test $glibcxx_cv_SYSCTL_HW_NCPU = yes; then
3579 AC_DEFINE(_GLIBCXX_USE_SYSCTL_HW_NCPU, 1, [Define if sysctl(), CTL_HW and HW_NCPU are available in <sys/sysctl.h>.])
3580 fi
3581 AC_MSG_RESULT($glibcxx_cv_SYSCTL_HW_NCPU)
3583 CXXFLAGS="$ac_save_CXXFLAGS"
3584 AC_LANG_RESTORE
3585 ])
3587 dnl
3588 dnl Check to see if python pretty printing can be activated.
3589 dnl
3590 dnl --with-python-dir=dir
3591 dnl installs directory into $prefix/dir
3592 AC_DEFUN([GLIBCXX_ENABLE_PYTHON], [
3594 AC_MSG_CHECKING([for custom python install directory])
3595 AC_ARG_WITH([python-dir],
3596 AS_HELP_STRING([--with-python-dir],
3597 [the location to install Python modules. This path is relative starting from the prefix.]),
3598 [with_python_dir=$withval], [with_python_dir="no"])
3599 AC_MSG_RESULT(${with_python_dir})
3601 # Needed for installing Python modules during make install.
3602 python_mod_dir="${with_python_dir}"
3603 AC_SUBST(python_mod_dir)
3604 GLIBCXX_CONDITIONAL(ENABLE_PYTHONDIR, test $python_mod_dir != no)
3605 ])
3607 dnl
3608 dnl Check to see if -Werror is disabled.
3609 dnl
3610 dnl --enable-werror/--disable-werror
3611 AC_DEFUN([GLIBCXX_ENABLE_WERROR], [
3612 AC_MSG_CHECKING([for -Werror])
3613 GLIBCXX_ENABLE(werror,$1,,[turns on -Werror])
3614 AC_MSG_RESULT($enable_werror)
3615 GLIBCXX_CONDITIONAL(ENABLE_WERROR, test $enable_werror = yes)
3616 ])
3619 # Macros from the top-level gcc directory.
3620 m4_include([../config/gc++filt.m4])
3621 m4_include([../config/tls.m4])
3622 m4_include([../config/gthr.m4])