gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997-2017 Free Software Foundation, Inc.
   5
   6 #This file is part of GCC.
   7
   8 #GCC is free software; you can redistribute it and/or modify it under
   9 #the terms of the GNU General Public License as published by the Free
  10 #Software Foundation; either version 3, or (at your option) any later
  11 #version.
  12
  13 #GCC is distributed in the hope that it will be useful, but WITHOUT
  14 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 #for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING3.  If not see
  20 #<http://www.gnu.org/licenses/>.
  21
  22 # --------------------------------
  23 # Initialization and sanity checks
  24 # --------------------------------
  25
  26 AC_PREREQ(2.64)
  27 AC_INIT
  28 AC_CONFIG_SRCDIR(tree.c)
  29 AC_CONFIG_HEADER(auto-host.h:config.in)
  30
  31 gcc_version=`cat $srcdir/BASE-VER`
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical host name, for Ada.
  39 ACX_NONCANONICAL_HOST
  40
  41 # Determine the noncanonical target name, for directory use.
  42 ACX_NONCANONICAL_TARGET
  43
  44 # Used for constructing correct paths for offload compilers.
  45 real_target_noncanonical=${target_noncanonical}
  46 accel_dir_suffix=
  47
  48 # Determine the target- and build-specific subdirectories
  49 GCC_TOPLEV_SUBDIRS
  50
  51 # Set program_transform_name
  52 AC_ARG_PROGRAM
  53
  54 # Check for bogus environment variables.
  55 # Test if LIBRARY_PATH contains the notation for the current directory
  56 # since this would lead to problems installing/building glibc.
  57 # LIBRARY_PATH contains the current directory if one of the following
  58 # is true:
  59 # - one of the terminals (":" and ";") is the first or last sign
  60 # - two terminals occur directly after each other
  61 # - the path contains an element with a dot in it
  62 AC_MSG_CHECKING(LIBRARY_PATH variable)
  63 changequote(,)dnl
  64 case ${LIBRARY_PATH} in
  65   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  66     library_path_setting="contains current directory"
  67     ;;
  68   *)
  69     library_path_setting="ok"
  70     ;;
  71 esac
  72 changequote([,])dnl
  73 AC_MSG_RESULT($library_path_setting)
  74 if test "$library_path_setting" != "ok"; then
  75 AC_MSG_ERROR([
  76 *** LIBRARY_PATH shouldn't contain the current directory when
  77 *** building gcc. Please change the environment variable
  78 *** and run configure again.])
  79 fi
  80
  81 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  82 # since this would lead to problems installing/building glibc.
  83 # GCC_EXEC_PREFIX contains the current directory if one of the following
  84 # is true:
  85 # - one of the terminals (":" and ";") is the first or last sign
  86 # - two terminals occur directly after each other
  87 # - the path contains an element with a dot in it
  88 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  89 changequote(,)dnl
  90 case ${GCC_EXEC_PREFIX} in
  91   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  92     gcc_exec_prefix_setting="contains current directory"
  93     ;;
  94   *)
  95     gcc_exec_prefix_setting="ok"
  96     ;;
  97 esac
  98 changequote([,])dnl
  99 AC_MSG_RESULT($gcc_exec_prefix_setting)
 100 if test "$gcc_exec_prefix_setting" != "ok"; then
 101 AC_MSG_ERROR([
 102 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
 103 *** building gcc. Please change the environment variable
 104 *** and run configure again.])
 105 fi
 106
 107 # -----------
 108 # Directories
 109 # -----------
 110
 111 # Specify the local prefix
 112 local_prefix=
 113 AC_ARG_WITH(local-prefix,
 114 [AS_HELP_STRING([--with-local-prefix=DIR],
 115                 [specifies directory to put local include])],
 116 [case "${withval}" in
 117 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 118 no)     ;;
 119 *)      local_prefix=$with_local_prefix ;;
 120 esac])
 121
 122 # Default local prefix if it is empty
 123 if test x$local_prefix = x; then
 124         local_prefix=/usr/local
 125 fi
 126
 127 AC_ARG_WITH([native-system-header-dir],
 128   [  --with-native-system-header-dir=dir
 129                           use dir as the directory to look for standard
 130                           system header files in.  Defaults to /usr/include.],
 131 [
 132  case ${with_native_system_header_dir} in
 133  yes|no) AC_MSG_ERROR([bad value ${withval} given for --with-native-system-header-dir]) ;;
 134  /* | [[A-Za-z]]:[[\\/]]*) ;;
 135  *) AC_MSG_ERROR([--with-native-system-header-dir argument ${withval} must be an absolute directory]) ;;
 136  esac
 137  configured_native_system_header_dir="${withval}"
 138 ], [configured_native_system_header_dir=])
 139
 140 AC_ARG_WITH(build-sysroot,
 141   [AS_HELP_STRING([--with-build-sysroot=sysroot],
 142                   [use sysroot as the system root during the build])],
 143   [if test x"$withval" != x ; then
 144      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
 145    fi],
 146   [SYSROOT_CFLAGS_FOR_TARGET=])
 147 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
 148
 149 if test "x$prefix" = xNONE; then
 150  test_prefix=/usr/local
 151 else
 152  test_prefix=$prefix
 153 fi
 154 if test "x$exec_prefix" = xNONE; then
 155  test_exec_prefix=$test_prefix
 156 else
 157  test_exec_prefix=$exec_prefix
 158 fi
 159
 160 AC_ARG_WITH(sysroot,
 161 [AS_HELP_STRING([[--with-sysroot[=DIR]]],
 162                 [search for usr/lib, usr/include, et al, within DIR])],
 163 [
 164  case ${with_sysroot} in
 165  /) ;;
 166  */) with_sysroot=`echo $with_sysroot | sed 's,/$,,'` ;;
 167  esac
 168  case ${with_sysroot} in
 169  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 170  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 171  esac
 172
 173  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 174  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 175
 176  case ${TARGET_SYSTEM_ROOT} in
 177  "${test_prefix}"|"${test_prefix}/"*|\
 178  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 179  '${prefix}'|'${prefix}/'*|\
 180  '${exec_prefix}'|'${exec_prefix}/'*)
 181    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 182    TARGET_SYSTEM_ROOT_DEFINE="$t"
 183    ;;
 184  esac
 185 ], [
 186  TARGET_SYSTEM_ROOT=
 187  TARGET_SYSTEM_ROOT_DEFINE=
 188  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 189 ])
 190 AC_SUBST(TARGET_SYSTEM_ROOT)
 191 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 192 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 193
 194 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 195 # passed in by the toplevel make and thus we'd get different behavior
 196 # depending on where we built the sources.
 197 gcc_gxx_include_dir=
 198 # Specify the g++ header file directory
 199 AC_ARG_WITH(gxx-include-dir,
 200 [AS_HELP_STRING([--with-gxx-include-dir=DIR],
 201                 [specifies directory to put g++ header files])],
 202 [case "${withval}" in
 203 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 204 no)     ;;
 205 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 206 esac])
 207
 208 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 209 if test x${gcc_gxx_include_dir} = x; then
 210   if test x${enable_version_specific_runtime_libs} = xyes; then
 211     gcc_gxx_include_dir='${libsubdir}/include/c++'
 212   else
 213     libstdcxx_incdir='include/c++/$(version)'
 214     if test x$host != x$target; then
 215        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 216     fi
 217     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 218   fi
 219 fi
 220
 221 gcc_gxx_include_dir_add_sysroot=0
 222 if test "${with_sysroot+set}" = set; then
 223   gcc_gxx_without_sysroot=`expr "${gcc_gxx_include_dir}" : "${with_sysroot}"'\(.*\)'`
 224   if test "${gcc_gxx_without_sysroot}"; then
 225     if test x${with_sysroot} != x/; then
 226       gcc_gxx_include_dir="${gcc_gxx_without_sysroot}"
 227     fi
 228     gcc_gxx_include_dir_add_sysroot=1
 229   fi
 230 fi
 231
 232 AC_ARG_WITH(cpp_install_dir,
 233 [AC_HELP_STRING([--with-cpp-install-dir=DIR],
 234                 [install the user visible C preprocessor in DIR
 235                  (relative to PREFIX) as well as PREFIX/bin])],
 236 [if test x$withval = xyes; then
 237   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 238 elif test x$withval != xno; then
 239   cpp_install_dir=$withval
 240 fi])
 241
 242 # We would like to our source tree to be readonly.  However when releases or
 243 # pre-releases are generated, the flex/bison generated files as well as the
 244 # various formats of manuals need to be included along with the rest of the
 245 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 246 # just that.
 247
 248 AC_MSG_CHECKING([whether to place generated files in the source directory])
 249   dnl generated-files-in-srcdir is disabled by default
 250   AC_ARG_ENABLE(generated-files-in-srcdir,
 251     [AS_HELP_STRING([--enable-generated-files-in-srcdir],
 252                     [put copies of generated files in source dir
 253                      intended for creating source tarballs for users
 254                      without texinfo bison or flex])],
 255       generated_files_in_srcdir=$enableval,
 256       generated_files_in_srcdir=no)
 257
 258 AC_MSG_RESULT($generated_files_in_srcdir)
 259
 260 if test "$generated_files_in_srcdir" = "yes"; then
 261   GENINSRC=''
 262 else
 263   GENINSRC='#'
 264 fi
 265 AC_SUBST(GENINSRC)
 266
 267 # -------------------
 268 # Find default linker
 269 # -------------------
 270
 271 # With GNU ld
 272 AC_ARG_WITH(gnu-ld,
 273 [AS_HELP_STRING([--with-gnu-ld], [arrange to work with GNU ld])],
 274 gnu_ld_flag="$with_gnu_ld",
 275 gnu_ld_flag=no)
 276
 277 case $target in
 278     *darwin*) ld64_flag=yes;; # Darwin can only use a ld64-compatible linker.
 279     *) ld64_flag=no;;
 280 esac
 281
 282 # With pre-defined ld
 283 AC_ARG_WITH(ld,
 284 [AS_HELP_STRING([--with-ld], [arrange to use the specified ld (full pathname)])],
 285 DEFAULT_LINKER="$with_ld")
 286 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 287   if test ! -x "$DEFAULT_LINKER"; then
 288     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 289   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 290     gnu_ld_flag=yes
 291   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep ld64- > /dev/null; then
 292     ld64_flag=yes
 293   fi
 294   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 295         [Define to enable the use of a default linker.])
 296 fi
 297
 298 AC_MSG_CHECKING([whether a default linker was specified])
 299 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 300   if test x"$gnu_ld_flag" = x"no"; then
 301     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 302   else
 303     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 304   fi
 305 else
 306   AC_MSG_RESULT(no)
 307 fi
 308
 309 # With demangler in GNU ld
 310 AC_ARG_WITH(demangler-in-ld,
 311 [AS_HELP_STRING([--with-demangler-in-ld], [try to use demangler in GNU ld])],
 312 demangler_in_ld="$with_demangler_in_ld",
 313 demangler_in_ld=yes)
 314
 315 # ----------------------
 316 # Find default assembler
 317 # ----------------------
 318
 319 # With GNU as
 320 AC_ARG_WITH(gnu-as,
 321 [AS_HELP_STRING([--with-gnu-as], [arrange to work with GNU as])],
 322 gas_flag="$with_gnu_as",
 323 gas_flag=no)
 324
 325 AC_ARG_WITH(as,
 326 [AS_HELP_STRING([--with-as], [arrange to use the specified as (full pathname)])],
 327 DEFAULT_ASSEMBLER="$with_as")
 328 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 329   if test ! -x "$DEFAULT_ASSEMBLER"; then
 330     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 331   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 332     gas_flag=yes
 333   fi
 334   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 335         [Define to enable the use of a default assembler.])
 336 fi
 337
 338 AC_MSG_CHECKING([whether a default assembler was specified])
 339 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 340   if test x"$gas_flag" = x"no"; then
 341     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 342   else
 343     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 344   fi
 345 else
 346   AC_MSG_RESULT(no)
 347 fi
 348
 349 # ---------------
 350 # Find C compiler
 351 # ---------------
 352
 353 # If a non-executable a.out is present (e.g. created by GNU as above even if
 354 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 355 # file, even when creating an executable, so an execution test fails.
 356 # Remove possible default executable files to avoid this.
 357 #
 358 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 359 # Autoconf includes it.
 360 rm -f a.out a.exe b.out
 361
 362 # Find the native compiler
 363 AC_PROG_CC
 364 AC_PROG_CXX
 365 ACX_PROG_GNAT([-I"$srcdir"/ada])
 366
 367 # Do configure tests with the C++ compiler, since that's what we build with.
 368 AC_LANG(C++)
 369
 370 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 371 # optimizations to be activated explicitly by the toplevel.
 372 case "$CC" in
 373   */prev-gcc/xgcc*) ;;
 374   *) CFLAGS=`echo "$CFLAGS " | sed -e "s/-Ofast[[       ]]//" -e "s/-O[[gs]][[  ]]//" -e "s/-O[[0-9]]*[[        ]]//" `
 375      CXXFLAGS=`echo "$CXXFLAGS " | sed -e "s/-Ofast[[   ]]//" -e "s/-O[[gs]][[  ]]//" -e "s/-O[[0-9]]*[[        ]]//" ` ;;
 376 esac
 377 AC_SUBST(CFLAGS)
 378 AC_SUBST(CXXFLAGS)
 379
 380 # Determine PICFLAG for target gnatlib.
 381 GCC_PICFLAG_FOR_TARGET
 382 AC_SUBST(PICFLAG_FOR_TARGET)
 383
 384 # -------------------------
 385 # Check C compiler features
 386 # -------------------------
 387
 388 AC_USE_SYSTEM_EXTENSIONS
 389 AC_PROG_CPP
 390 AC_C_INLINE
 391
 392 AC_SYS_LARGEFILE
 393
 394 # sizeof(char) is 1 by definition.
 395 AC_CHECK_SIZEOF(void *)
 396 AC_CHECK_SIZEOF(short)
 397 AC_CHECK_SIZEOF(int)
 398 AC_CHECK_SIZEOF(long)
 399 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 400 GCC_STDINT_TYPES
 401 if test x"$ac_cv_c_uint64_t" = x"no" -o x"$ac_cv_c_int64_t" = x"no"; then
 402   AC_MSG_ERROR([uint64_t or int64_t not found])
 403 fi
 404
 405 # check what underlying integer type int64_t uses
 406 AC_CACHE_CHECK(for int64_t underlying type, ac_cv_int64_t_type, [
 407 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 408 #ifdef HAVE_STDINT_H
 409 #include <stdint.h>
 410 #endif
 411 template <typename T> struct X { };
 412 template <>
 413 struct X<long> { typedef long t; };
 414 ]], [[X<int64_t>::t x;]])],[ac_cv_int64_t_type=long],[ac_cv_int64_t_type="long long"])])
 415 if test "$ac_cv_int64_t_type" = "long"; then
 416   AC_DEFINE(INT64_T_IS_LONG, 1,
 417   [Define if int64_t uses long as underlying type.])
 418 else
 419 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 420 #ifdef HAVE_STDINT_H
 421 #include <stdint.h>
 422 #endif
 423 template <typename T> struct X { };
 424 template <>
 425 struct X<long long> { typedef long long t; };
 426 ]], [[X<int64_t>::t x;]])],[],[AC_MSG_ERROR([error verifying int64_t uses long long])])
 427 fi
 428
 429 AC_CACHE_CHECK(for std::swap in <utility>, ac_cv_std_swap_in_utility, [
 430 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 431 #include <utility>
 432 ]], [[int a, b; std::swap(a,b);]])],[ac_cv_std_swap_in_utility=yes],[ac_cv_std_swap_in_utility=no])])
 433 if test $ac_cv_std_swap_in_utility = yes; then
 434   AC_DEFINE(HAVE_SWAP_IN_UTILITY, 1,
 435   [Define if <utility> defines std::swap.])
 436 fi
 437
 438 # Check whether compiler is affected by placement new aliasing bug (PR 29286).
 439 # If the host compiler is affected by the bug, and we build with optimization
 440 # enabled (which happens e.g. when cross-compiling), the pool allocator may
 441 # get miscompiled.  Use -fno-strict-aliasing to work around this problem.
 442 # Since there is no reliable feature check for the presence of this bug,
 443 # we simply use a GCC version number check.  (This should never trigger for
 444 # stages 2 or 3 of a native bootstrap.)
 445 aliasing_flags=
 446 if test "$GCC" = yes; then
 447   saved_CXXFLAGS="$CXXFLAGS"
 448
 449   # The following test compilation will succeed if and only if $CXX accepts
 450   # -fno-strict-aliasing *and* is older than GCC 4.3.
 451   CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 452   AC_MSG_CHECKING([whether $CXX is affected by placement new aliasing bug])
 453   AC_COMPILE_IFELSE([
 454 #if (__GNUC__ > 4) || (__GNUC__ == 4 && __GNUC_MINOR__ >= 3)
 455 #error compiler not affected by placement new aliasing bug
 456 #endif
 457 ],
 458     [AC_MSG_RESULT([yes]); aliasing_flags='-fno-strict-aliasing'],
 459     [AC_MSG_RESULT([no])])
 460
 461   CXXFLAGS="$saved_CXXFLAGS"
 462 fi
 463 AC_SUBST(aliasing_flags)
 464
 465
 466
 467 # ---------------------
 468 # Warnings and checking
 469 # ---------------------
 470
 471 # Check $CC warning features (if it's GCC).
 472 # We want to use -pedantic, but we don't want warnings about
 473 # * 'long long'
 474 # * variadic macros
 475 # * overlong strings
 476 # * C++11 narrowing conversions in { }
 477 # So, we only use -pedantic if we can disable those warnings.
 478
 479 # In stage 1, disable -Wformat warnings from old GCCs about new % codes
 480 AC_ARG_ENABLE(build-format-warnings,
 481   AS_HELP_STRING([--disable-build-format-warnings],[don't use -Wformat while building GCC]),
 482   [],[enable_build_format_warnings=yes])
 483 AS_IF([test $enable_build_format_warnings = no],
 484       [wf_opt=-Wno-format],[wf_opt=])
 485 ACX_PROG_CXX_WARNING_OPTS(
 486         m4_quote(m4_do([-W -Wall -Wno-narrowing -Wwrite-strings ],
 487                        [-Wcast-qual $wf_opt])), [loose_warn])
 488 ACX_PROG_CC_WARNING_OPTS(
 489         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
 490         [c_loose_warn])
 491 ACX_PROG_CXX_WARNING_OPTS(
 492         m4_quote(m4_do([-Wmissing-format-attribute ],
 493                        [-Woverloaded-virtual])), [strict_warn])
 494 ACX_PROG_CC_WARNING_OPTS(
 495         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 496 ACX_PROG_CXX_WARNING_ALMOST_PEDANTIC(
 497         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 498                        [-Wno-overlength-strings])), [strict_warn])
 499 ACX_PROG_CXX_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 500
 501 # The above macros do nothing if the compiler is not GCC.  However, the
 502 # Makefile has more goo to add other flags, so these variables are used
 503 # to enable warnings only for GCC.
 504 warn_cflags=
 505 warn_cxxflags=
 506 if test "x$GCC" = "xyes"; then
 507   warn_cflags='$(GCC_WARN_CFLAGS)'
 508   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 509 fi
 510 AC_SUBST(warn_cflags)
 511 AC_SUBST(warn_cxxflags)
 512
 513 # Disable exceptions and RTTI if building with g++
 514 ACX_PROG_CC_WARNING_OPTS(
 515         m4_quote(m4_do([-fno-exceptions -fno-rtti -fasynchronous-unwind-tables])),
 516                        [noexception_flags])
 517
 518 # Enable expensive internal checks
 519 is_release=
 520 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 521   is_release=yes
 522 fi
 523
 524 AC_ARG_ENABLE(checking,
 525 [AS_HELP_STRING([[--enable-checking[=LIST]]],
 526                 [enable expensive run-time checks.  With LIST,
 527                  enable only specific categories of checks.
 528                  Categories are: yes,no,all,none,release.
 529                  Flags are: assert,df,extra,fold,gc,gcac,gimple,misc,
 530                  rtlflag,rtl,runtime,tree,valgrind,types])],
 531 [ac_checking_flags="${enableval}"],[
 532 # Determine the default checks.
 533 if test x$is_release = x ; then
 534   ac_checking_flags=yes,extra
 535 else
 536   ac_checking_flags=release
 537 fi])
 538 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 539 for check in release $ac_checking_flags
 540 do
 541         case $check in
 542         # these set all the flags to specific states
 543         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 544                         ac_fold_checking= ; ac_gc_checking=1 ; ac_extra_checking= ;
 545                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 546                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 547                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 548                         ac_types_checking=1 ;;
 549         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 550                         ac_fold_checking= ; ac_gc_checking= ; ac_extra_checking= ;
 551                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 552                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 553                         ac_tree_checking= ; ac_valgrind_checking= ;
 554                         ac_types_checking= ;;
 555         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 556                         ac_fold_checking=1 ; ac_gc_checking=1 ; ac_extra_checking=1 ;
 557                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 558                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 559                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 560                         ac_types_checking=1 ;;
 561         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 562                         ac_fold_checking= ; ac_gc_checking= ; ac_extra_checking= ;
 563                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 564                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 565                         ac_tree_checking= ; ac_valgrind_checking= ;
 566                         ac_types_checking= ;;
 567         # these enable particular checks
 568         assert)         ac_assert_checking=1 ;;
 569         df)             ac_df_checking=1 ;;
 570         extra)          ac_extra_checking=1 ;;
 571         fold)           ac_fold_checking=1 ;;
 572         gc)             ac_gc_checking=1 ;;
 573         gcac)           ac_gc_always_collect=1 ;;
 574         gimple)         ac_gimple_checking=1 ;;
 575         misc)           ac_checking=1 ;;
 576         rtl)            ac_rtl_checking=1 ;;
 577         rtlflag)        ac_rtlflag_checking=1 ;;
 578         runtime)        ac_runtime_checking=1 ;;
 579         tree)           ac_tree_checking=1 ;;
 580         types)          ac_types_checking=1 ;;
 581         valgrind)       ac_valgrind_checking=1 ;;
 582         *)      AC_MSG_ERROR(unknown check category $check) ;;
 583         esac
 584 done
 585 IFS="$ac_save_IFS"
 586
 587 nocommon_flag=""
 588 if test x$ac_checking != x ; then
 589   AC_DEFINE(CHECKING_P, 1,
 590 [Define to 0/1 if you want more run-time sanity checks.  This one gets a grab
 591 bag of miscellaneous but relatively cheap checks.])
 592   nocommon_flag=-fno-common
 593 else
 594   AC_DEFINE(CHECKING_P, 0)
 595 fi
 596 AC_SUBST(nocommon_flag)
 597 if test x$ac_extra_checking != x ; then
 598   AC_DEFINE(ENABLE_EXTRA_CHECKING, 1,
 599 [Define to 0/1 if you want extra run-time checking that might affect code
 600 generation.])
 601 else
 602   AC_DEFINE(ENABLE_EXTRA_CHECKING, 0)
 603 fi
 604 if test x$ac_df_checking != x ; then
 605   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 606 [Define if you want more run-time sanity checks for dataflow.])
 607 fi
 608 if test x$ac_assert_checking != x ; then
 609   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 610 [Define if you want assertions enabled.  This is a cheap check.])
 611 fi
 612 if test x$ac_gimple_checking != x ; then
 613   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 614 [Define if you want operations on GIMPLE (the basic data structure of
 615 the high-level optimizers) to be checked for dynamic type safety at
 616 runtime.  This is moderately expensive.])
 617 fi
 618 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 619 if test x$ac_runtime_checking != x ; then
 620   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 621 [Define if you want runtime assertions enabled.  This is a cheap check.])
 622 fi
 623 if test x$ac_tree_checking != x ; then
 624   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 625 [Define if you want all operations on trees (the basic data
 626    structure of the front ends) to be checked for dynamic type safety
 627    at runtime.  This is moderately expensive.
 628    ])
 629   TREECHECKING=yes
 630 fi
 631 if test x$ac_types_checking != x ; then
 632   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 633 [Define if you want all gimple types to be verified after gimplifiation.
 634    This is cheap.
 635    ])
 636 fi
 637 AC_SUBST(TREECHECKING)
 638 if test x$ac_rtl_checking != x ; then
 639   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 640 [Define if you want all operations on RTL (the basic data structure
 641    of the optimizer and back end) to be checked for dynamic type safety
 642    at runtime.  This is quite expensive.])
 643 fi
 644 if test x$ac_rtlflag_checking != x ; then
 645   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 646 [Define if you want RTL flag accesses to be checked against the RTL
 647    codes that are supported for each access macro.  This is relatively
 648    cheap.])
 649 fi
 650 if test x$ac_gc_checking != x ; then
 651   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 652 [Define if you want the garbage collector to do object poisoning and
 653    other memory allocation checks.  This is quite expensive.])
 654 fi
 655 if test x$ac_gc_always_collect != x ; then
 656   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 657 [Define if you want the garbage collector to operate in maximally
 658    paranoid mode, validating the entire heap and collecting garbage at
 659    every opportunity.  This is extremely expensive.])
 660 fi
 661 if test x$ac_fold_checking != x ; then
 662   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 663 [Define if you want fold checked that it never destructs its argument.
 664    This is quite expensive.])
 665 fi
 666 valgrind_path_defines=
 667 valgrind_command=
 668
 669 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 670 dnl # an if statement.  This was the source of very frustrating bugs
 671 dnl # in converting to autoconf 2.5x!
 672 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 673
 674 # It is certainly possible that there's valgrind but no valgrind.h.
 675 # GCC relies on making annotations so we must have both.
 676 AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 677 AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 678   [[#include <valgrind/memcheck.h>
 679 #ifndef VALGRIND_DISCARD
 680 #error VALGRIND_DISCARD not defined
 681 #endif]])],
 682   [gcc_cv_header_valgrind_memcheck_h=yes],
 683   [gcc_cv_header_valgrind_memcheck_h=no])
 684 AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 685 AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 686 AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 687   [[#include <memcheck.h>
 688 #ifndef VALGRIND_DISCARD
 689 #error VALGRIND_DISCARD not defined
 690 #endif]])],
 691   [gcc_cv_header_memcheck_h=yes],
 692   [gcc_cv_header_memcheck_h=no])
 693 AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 694 if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 695   AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 696         [Define if valgrind's valgrind/memcheck.h header is installed.])
 697 fi
 698 if test $gcc_cv_header_memcheck_h = yes; then
 699   AC_DEFINE(HAVE_MEMCHECK_H, 1,
 700         [Define if valgrind's memcheck.h header is installed.])
 701 fi
 702
 703 if test x$ac_valgrind_checking != x ; then
 704   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 705         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 706   if test "x$valgrind_path" = "x" \
 707     || (test $have_valgrind_h = no \
 708         && test $gcc_cv_header_memcheck_h = no \
 709         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 710         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 711   fi
 712   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 713   valgrind_command="$valgrind_path -q"
 714   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 715 [Define if you want to run subprograms and generated programs
 716    through valgrind (a memory checker).  This is extremely expensive.])
 717 fi
 718 AC_SUBST(valgrind_path_defines)
 719 AC_SUBST(valgrind_command)
 720
 721 # Enable code coverage collection
 722 AC_ARG_ENABLE(coverage,
 723 [AS_HELP_STRING([[--enable-coverage[=LEVEL]]],
 724                 [enable compiler's code coverage collection.
 725                  Use to measure compiler performance and locate
 726                  unused parts of the compiler. With LEVEL, specify
 727                  optimization. Values are opt, noopt,
 728                  default is noopt])],
 729 [case "${enableval}" in
 730   yes|noopt)
 731     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 732     ;;
 733   opt)
 734     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 735     ;;
 736   no)
 737     # a.k.a. --disable-coverage
 738     coverage_flags=""
 739     ;;
 740   *)
 741     AC_MSG_ERROR(unknown coverage setting $enableval)
 742     ;;
 743 esac],
 744 [coverage_flags=""])
 745 AC_SUBST(coverage_flags)
 746
 747 AC_ARG_ENABLE(gather-detailed-mem-stats,
 748 [AS_HELP_STRING([--enable-gather-detailed-mem-stats],
 749                 [enable detailed memory allocation stats gathering])], [],
 750 [enable_gather_detailed_mem_stats=no])
 751 gather_stats=`if test $enable_gather_detailed_mem_stats != no; then echo 1; else echo 0; fi`
 752 AC_DEFINE_UNQUOTED(GATHER_STATISTICS, $gather_stats,
 753 [Define to enable detailed memory allocation stats gathering.])
 754
 755 AC_ARG_ENABLE(valgrind-annotations,
 756 [AS_HELP_STRING([--enable-valgrind-annotations],
 757                 [enable valgrind runtime interaction])], [],
 758 [enable_valgrind_annotations=no])
 759 if test x$enable_valgrind_annotations != xno \
 760     || test x$ac_valgrind_checking != x; then
 761   if (test $have_valgrind_h = no \
 762       && test $gcc_cv_header_memcheck_h = no \
 763       && test $gcc_cv_header_valgrind_memcheck_h = no); then
 764     AC_MSG_ERROR([*** Can't find valgrind/memcheck.h, memcheck.h or valgrind.h])
 765   fi
 766   AC_DEFINE(ENABLE_VALGRIND_ANNOTATIONS, 1,
 767 [Define to get calls to the valgrind runtime enabled.])
 768 fi
 769
 770 # -------------------------------
 771 # Miscenalleous configure options
 772 # -------------------------------
 773
 774 # With stabs
 775 AC_ARG_WITH(stabs,
 776 [AS_HELP_STRING([--with-stabs],
 777                 [arrange to use stabs instead of host debug format])],
 778 stabs="$with_stabs",
 779 stabs=no)
 780
 781 # Determine whether or not multilibs are enabled.
 782 AC_ARG_ENABLE(multilib,
 783 [AS_HELP_STRING([--enable-multilib],
 784                 [enable library support for multiple ABIs])],
 785 [], [enable_multilib=yes])
 786 AC_SUBST(enable_multilib)
 787
 788 # Determine whether or not multiarch is enabled.
 789 AC_ARG_ENABLE(multiarch,
 790 [AS_HELP_STRING([--enable-multiarch],
 791                 [enable support for multiarch paths])],
 792 [case "${enableval}" in
 793 yes|no|auto) enable_multiarch=$enableval;;
 794 *) AC_MSG_ERROR(bad value ${enableval} given for --enable-multiarch option) ;;
 795 esac], [enable_multiarch=auto])
 796 if test x${enable_multiarch} = xauto; then
 797   if test x${with_native_system_header_dir} != x; then
 798     ma_msg_suffix=", disabled auto check (configured with --native-system-header-dir)"
 799     enable_multiarch=no
 800   fi
 801   if test x$host != x$target && test "x$with_sysroot" = x; then
 802     ma_msg_suffix=", disabled auto check (cross build configured without --with-sysroot)"
 803     enable_multiarch=no
 804   fi
 805 fi
 806 AC_MSG_CHECKING(for multiarch configuration)
 807 AC_SUBST(enable_multiarch)
 808 AC_MSG_RESULT($enable_multiarch$ma_msg_suffix)
 809
 810 # needed for setting the multiarch name for soft-float/hard-float ABIs
 811 AC_SUBST(with_cpu)
 812 AC_SUBST(with_float)
 813
 814 # Enable __cxa_atexit for C++.
 815 AC_ARG_ENABLE(__cxa_atexit,
 816 [AS_HELP_STRING([--enable-__cxa_atexit], [enable __cxa_atexit for C++])],
 817 [], [])
 818
 819 # Enable C extension for decimal float if target supports it.
 820 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
 821
 822 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 823 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 824 [Define to 1 to enable decimal float extension to C.])
 825
 826 # Use default_decimal_float for dependency.
 827 enable_decimal_float=$default_decimal_float
 828
 829 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 830 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 831 [Define to 1 to specify that we are using the BID decimal floating
 832 point format instead of DPD])
 833
 834 # Enable C extension for fixed-point arithmetic.
 835 AC_ARG_ENABLE(fixed-point,
 836 [AS_HELP_STRING([--enable-fixed-point],
 837                 [enable fixed-point arithmetic extension to C])],
 838 [],
 839 [
 840   case $target in
 841     arm*)
 842       enable_fixed_point=yes
 843       ;;
 844
 845     mips*-*-*)
 846       enable_fixed_point=yes
 847       ;;
 848     *)
 849       AC_MSG_WARN([fixed-point is not supported for this target, ignored])
 850       enable_fixed_point=no
 851       ;;
 852   esac
 853 ])
 854 AC_SUBST(enable_fixed_point)
 855
 856 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 857 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 858 [Define to 1 to enable fixed-point arithmetic extension to C.])
 859
 860 # Enable threads
 861 # Pass with no value to take the default
 862 # Pass with a value to specify a thread package
 863 AC_ARG_ENABLE(threads,
 864 [AS_HELP_STRING([[--enable-threads[=LIB]]],
 865                 [enable thread usage for target GCC,
 866                  using LIB thread package])],,
 867 [enable_threads=''])
 868
 869 AC_ARG_ENABLE(tls,
 870 [AS_HELP_STRING([--enable-tls],
 871                 [enable or disable generation of tls code
 872                  overriding the assembler check for tls support])],
 873 [
 874   case $enable_tls in
 875     yes | no) ;;
 876     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 877 Valid choices are 'yes' and 'no'.]) ;;
 878   esac
 879 ], [enable_tls=''])
 880
 881 AC_ARG_ENABLE(vtable-verify,
 882 [AS_HELP_STRING([--enable-vtable-verify],
 883                 [enable vtable verification feature])],,
 884 [enable_vtable_verify=no])
 885 vtable_verify=`if test x$enable_vtable_verify = xyes; then echo 1; else echo 0; fi`
 886 AC_DEFINE_UNQUOTED(ENABLE_VTABLE_VERIFY, $vtable_verify,
 887 [Define 0/1 if vtable verification feature is enabled.])
 888
 889 AC_ARG_ENABLE(objc-gc,
 890 [AS_HELP_STRING([--enable-objc-gc],
 891                 [enable the use of Boehm's garbage collector with
 892                  the GNU Objective-C runtime])],
 893 if test x$enable_objc_gc = xno; then
 894         objc_boehm_gc=''
 895 else
 896         objc_boehm_gc=1
 897 fi,
 898 objc_boehm_gc='')
 899
 900 AC_ARG_WITH(dwarf2,
 901 [AS_HELP_STRING([--with-dwarf2], [force the default debug format to be DWARF 2])],
 902 dwarf2="$with_dwarf2",
 903 dwarf2=no)
 904
 905 AC_ARG_ENABLE(shared,
 906 [AS_HELP_STRING([--disable-shared], [don't provide a shared libgcc])],
 907 [
 908   case $enable_shared in
 909   yes | no) ;;
 910   *)
 911     enable_shared=no
 912     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 913     for pkg in $enableval; do
 914       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 915         enable_shared=yes
 916       fi
 917     done
 918     IFS="$ac_save_ifs"
 919     ;;
 920   esac
 921 ], [enable_shared=yes])
 922 AC_SUBST(enable_shared)
 923
 924 AC_ARG_WITH(specs,
 925   [AS_HELP_STRING([--with-specs=SPECS],
 926                   [add SPECS to driver command-line processing])],
 927   [CONFIGURE_SPECS=$withval],
 928   [CONFIGURE_SPECS=]
 929 )
 930 AC_SUBST(CONFIGURE_SPECS)
 931
 932 ACX_PKGVERSION([GCC])
 933 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 934
 935 # Sanity check enable_languages in case someone does not run the toplevel
 936 # configure # script.
 937 AC_ARG_ENABLE(languages,
 938 [AS_HELP_STRING([--enable-languages=LIST], [specify which front-ends to build])],
 939 [case ,${enable_languages}, in
 940        ,,|,yes,)
 941                 # go safe -- we cannot be much sure without the toplevel
 942                 # configure's
 943                 # analysis of which target libs are present and usable
 944                 enable_languages=c
 945                 ;;
 946          *,all,*)
 947                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 948                 ;;
 949         *,c,*)
 950                 ;;
 951         *)
 952                 enable_languages=c,${enable_languages}
 953                 ;;
 954 esac],
 955 [enable_languages=c])
 956
 957 if test x"$enable_as_accelerator_for" != x; then
 958   AC_DEFINE(ACCEL_COMPILER, 1,
 959     [Define if this compiler should be built as the offload target compiler.])
 960   enable_as_accelerator=yes
 961   case "${target}" in
 962     *-intelmicemul-*)
 963       # In this case we expect offload compiler to be built as native, so we
 964       # need to rename the driver to avoid clashes with host's drivers.
 965       program_transform_name="s&^&${target}-&" ;;
 966   esac
 967   sedscript="s#${target_noncanonical}#${enable_as_accelerator_for}-accel-${target_noncanonical}#"
 968   program_transform_name=`echo $program_transform_name | sed $sedscript`
 969   accel_dir_suffix=/accel/${target_noncanonical}
 970   real_target_noncanonical=${enable_as_accelerator_for}
 971 fi
 972 AC_SUBST(enable_as_accelerator)
 973 AC_SUBST(real_target_noncanonical)
 974 AC_SUBST(accel_dir_suffix)
 975
 976 for tgt in `echo $enable_offload_targets | sed 's/,/ /g'`; do
 977   tgt=`echo $tgt | sed 's/=.*//'`
 978
 979   if echo "$tgt" | grep "^hsa" > /dev/null ; then
 980     enable_hsa=1
 981   else
 982     enable_offloading=1
 983   fi
 984
 985   if test x"$offload_targets" = x; then
 986     offload_targets=$tgt
 987   else
 988     offload_targets="$offload_targets,$tgt"
 989   fi
 990 done
 991 AC_DEFINE_UNQUOTED(OFFLOAD_TARGETS, "$offload_targets",
 992   [Define to offload targets, separated by commas.])
 993 if test x"$enable_offloading" != x; then
 994   AC_DEFINE(ENABLE_OFFLOADING, 1,
 995     [Define this to enable support for offloading.])
 996 else
 997   AC_DEFINE(ENABLE_OFFLOADING, 0,
 998     [Define this to enable support for offloading.])
 999 fi
1000
1001 if test x"$enable_hsa" = x1 ; then
1002   AC_DEFINE(ENABLE_HSA, 1,
1003     [Define this to enable support for generating HSAIL.])
1004 fi
1005
1006 AC_ARG_WITH(multilib-list,
1007 [AS_HELP_STRING([--with-multilib-list], [select multilibs (AArch64, SH and x86-64 only)])],
1008 :,
1009 with_multilib_list=default)
1010
1011 # -------------------------
1012 # Checks for other programs
1013 # -------------------------
1014
1015 AC_PROG_MAKE_SET
1016
1017 # Find some useful tools
1018 AC_PROG_AWK
1019 # We need awk to create options.c and options.h.
1020 # Bail out if it's missing.
1021 case ${AWK} in
1022   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
1023 esac
1024
1025 gcc_AC_PROG_LN_S
1026 ACX_PROG_LN($LN_S)
1027 AC_PROG_RANLIB
1028 ranlib_flags=""
1029 AC_SUBST(ranlib_flags)
1030
1031 gcc_AC_PROG_INSTALL
1032
1033 # See if cmp has --ignore-initial.
1034 gcc_AC_PROG_CMP_IGNORE_INITIAL
1035
1036 # See if we have the mktemp command.
1037 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
1038
1039 # See if makeinfo has been installed and is modern enough
1040 # that we can use it.
1041 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1042   [GNU texinfo.* \([0-9][0-9.]*\)],
1043   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
1044 if test $gcc_cv_prog_makeinfo_modern = no; then
1045   AC_MSG_WARN([
1046 *** Makeinfo is missing or too old.
1047 *** Info documentation will not be built.])
1048   BUILD_INFO=
1049 else
1050   BUILD_INFO=info
1051 fi
1052 AC_SUBST(BUILD_INFO)
1053
1054 # Is pod2man recent enough to regenerate manpages?
1055 AC_MSG_CHECKING([for recent Pod::Man])
1056 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
1057   AC_MSG_RESULT(yes)
1058   GENERATED_MANPAGES=generated-manpages
1059 else
1060   AC_MSG_RESULT(no)
1061   GENERATED_MANPAGES=
1062 fi
1063 AC_SUBST(GENERATED_MANPAGES)
1064
1065 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
1066
1067 # How about lex?
1068 dnl Don't use AC_PROG_LEX; we insist on flex.
1069 dnl LEXLIB is not useful in gcc.
1070 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
1071
1072 # Bison?
1073 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
1074
1075 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
1076 # check for build == host before using them.
1077
1078 # NM
1079 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
1080   && test -d ../binutils ; then
1081   NM='${objdir}/../binutils/nm-new'
1082 else
1083   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
1084 fi
1085
1086 # AR
1087 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
1088   && test -d ../binutils ; then
1089   AR='${objdir}/../binutils/ar'
1090 else
1091   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
1092 fi
1093
1094 # The jit documentation looks better if built with sphinx, but can be
1095 # built with texinfo if sphinx is not available.
1096 # Set "doc_build_sys" to "sphinx" or "texinfo" accordingly.
1097 AC_CHECK_PROG(doc_build_sys, sphinx-build, sphinx, texinfo)
1098
1099 # --------------------
1100 # Checks for C headers
1101 # --------------------
1102
1103 # Need to reject headers which give warnings, so that the -Werror bootstrap
1104 # works later. *sigh*  This needs to come before all header checks.
1105 AC_PROG_CPP_WERROR
1106
1107 AC_HEADER_STDC
1108 AC_HEADER_TIME
1109 ACX_HEADER_STRING
1110 AC_HEADER_SYS_WAIT
1111 AC_HEADER_TIOCGWINSZ
1112 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
1113                  fcntl.h ftw.h unistd.h sys/file.h sys/time.h sys/mman.h \
1114                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
1115                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
1116
1117 # Check for thread headers.
1118 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
1119 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
1120
1121 # These tests can't be done till we know if we have limits.h.
1122 gcc_AC_C_CHAR_BIT
1123 AC_C_BIGENDIAN
1124
1125 # ----------------------
1126 # Checks for C++ headers
1127 # ----------------------
1128
1129 dnl Autoconf will give an error in the configure script if there is no
1130 dnl C++ preprocessor.  Hack to prevent that.
1131 m4_pushdef([AC_MSG_ERROR], m4_defn([AC_MSG_WARN]))[]dnl
1132 AC_PROG_CXXCPP
1133 m4_popdef([AC_MSG_ERROR])[]dnl
1134
1135 AC_CHECK_HEADERS(unordered_map)
1136 AC_CHECK_HEADERS(tr1/unordered_map)
1137 AC_CHECK_HEADERS(ext/hash_map)
1138
1139 # --------
1140 # Dependency checking.
1141 # --------
1142
1143 ZW_CREATE_DEPDIR
1144 AC_CONFIG_COMMANDS([gccdepdir],[
1145   ${CONFIG_SHELL-/bin/sh} $ac_aux_dir/mkinstalldirs build/$DEPDIR
1146   for lang in $subdirs c-family common
1147   do
1148       ${CONFIG_SHELL-/bin/sh} $ac_aux_dir/mkinstalldirs $lang/$DEPDIR
1149   done], [subdirs="$subdirs" ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR])
1150
1151 ZW_PROG_COMPILER_DEPENDENCIES([CXX])
1152
1153 # --------
1154 # UNSORTED
1155 # --------
1156
1157
1158 # These libraries may be used by collect2.
1159 # We may need a special search path to get them linked.
1160 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
1161 [save_LIBS="$LIBS"
1162 for libs in '' -lld -lmld \
1163                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
1164                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
1165 do
1166         LIBS="$libs"
1167         AC_TRY_LINK_FUNC(ldopen,
1168                 [gcc_cv_collect2_libs="$libs"; break])
1169 done
1170 LIBS="$save_LIBS"
1171 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
1172 case $gcc_cv_collect2_libs in
1173         "none required")        ;;
1174         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
1175 esac
1176 AC_SUBST(COLLECT2_LIBS)
1177
1178 # When building Ada code on Alpha, we need exc_resume which is usually in
1179 # -lexc.  So test for it.
1180 save_LIBS="$LIBS"
1181 LIBS=
1182 AC_SEARCH_LIBS(exc_resume, exc)
1183 GNAT_LIBEXC="$LIBS"
1184 LIBS="$save_LIBS"
1185 AC_SUBST(GNAT_LIBEXC)
1186
1187 # To support -mcpu=native on Solaris/SPARC, we need libkstat.
1188 save_LIBS="$LIBS"
1189 LIBS=
1190 AC_SEARCH_LIBS(kstat_open, kstat)
1191 EXTRA_GCC_LIBS="$LIBS"
1192 LIBS="$save_LIBS"
1193 AC_SUBST(EXTRA_GCC_LIBS)
1194
1195 # Some systems put ldexp and frexp in libm instead of libc; assume
1196 # they're both in the same place.  jcf-dump needs them.
1197 save_LIBS="$LIBS"
1198 LIBS=
1199 AC_SEARCH_LIBS(ldexp, m)
1200 LDEXP_LIB="$LIBS"
1201 LIBS="$save_LIBS"
1202 AC_SUBST(LDEXP_LIB)
1203
1204 # Use <inttypes.h> only if it exists,
1205 # doesn't clash with <sys/types.h>, declares intmax_t and defines
1206 # PRId64
1207 AC_MSG_CHECKING(for inttypes.h)
1208 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1209 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1210 [[#define __STDC_FORMAT_MACROS
1211 #include <sys/types.h>
1212 #include <inttypes.h>]],
1213   [[intmax_t i = -1;
1214 #ifndef PRId64
1215 choke me
1216 #endif]])],
1217   [gcc_cv_header_inttypes_h=yes],
1218   [gcc_cv_header_inttypes_h=no])])
1219 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1220 if test $gcc_cv_header_inttypes_h = yes; then
1221   AC_DEFINE(HAVE_INTTYPES_H, 1,
1222         [Define if you have a working <inttypes.h> header file.])
1223 fi
1224
1225 dnl Disabled until we have a complete test for buggy enum bitfields.
1226 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1227
1228 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1229   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1230   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1231   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1232   putchar_unlocked putc_unlocked)
1233 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoq \
1234         popen sysconf strsignal getrusage nl_langinfo \
1235         gettimeofday mbstowcs wcswidth mmap setlocale \
1236         gcc_UNLOCKED_FUNCS madvise)
1237
1238 if test x$ac_cv_func_mbstowcs = xyes; then
1239   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1240 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1241 int main()
1242 {
1243   mbstowcs(0, "", 0);
1244   return 0;
1245 }]])],
1246     [gcc_cv_func_mbstowcs_works=yes],
1247     [gcc_cv_func_mbstowcs_works=no],
1248     [gcc_cv_func_mbstowcs_works=yes])])
1249   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1250     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1251   [Define this macro if mbstowcs does not crash when its
1252    first argument is NULL.])
1253   fi
1254 fi
1255
1256 AC_CHECK_TYPE(ssize_t, int)
1257 AC_CHECK_TYPE(caddr_t, char *)
1258
1259 GCC_AC_FUNC_MMAP_BLACKLIST
1260
1261 case "${host}" in
1262 *-*-*vms*)
1263   # Under VMS, vfork works very differently than on Unix. The standard test
1264   # won't work, and it isn't easily adaptable. It makes more sense to
1265   # just force it.
1266   ac_cv_func_vfork_works=yes
1267   ;;
1268 esac
1269 AC_FUNC_FORK
1270
1271 AM_ICONV
1272
1273 # Until we have in-tree GNU iconv:
1274 LIBICONV_DEP=
1275 if test -f "$LTLIBICONV"; then
1276   LIBICONV_DEP=$LTLIBICONV
1277 fi
1278 AC_SUBST(LIBICONV_DEP)
1279
1280 AM_LC_MESSAGES
1281
1282 AM_LANGINFO_CODESET
1283
1284 # We will need to find libiberty.h and ansidecl.h
1285 saved_CFLAGS="$CFLAGS"
1286 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include $GMPINC"
1287 saved_CXXFLAGS="$CXXFLAGS"
1288 CXXFLAGS="$CXXFLAGS -I${srcdir} -I${srcdir}/../include $GMPINC"
1289
1290 # gcc_AC_CHECK_DECLS doesn't support overloaded functions, so use the
1291 # normal autoconf function for these.  But force definition of
1292 # HAVE_DECL_BASENAME like gcc_AC_CHECK_DECLS does, to suppress the bizarre
1293 # basename handling in libiberty.h.
1294 AC_CHECK_DECLS([basename(const char*), strstr(const char*,const char*)], , ,[
1295 #undef HAVE_DECL_BASENAME
1296 #define HAVE_DECL_BASENAME 1
1297 #include "ansidecl.h"
1298 #include "system.h"])
1299
1300 gcc_AC_CHECK_DECLS(getenv atol atoll asprintf sbrk abort atof getcwd getwd \
1301         madvise stpcpy strnlen strsignal strverscmp \
1302         strtol strtoul strtoll strtoull setenv unsetenv \
1303         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1304         free getopt clock getpagesize ffs gcc_UNLOCKED_FUNCS, , ,[
1305 #include "ansidecl.h"
1306 #include "system.h"])
1307
1308 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1309 #include "ansidecl.h"
1310 #include "system.h"
1311 #ifdef HAVE_SYS_RESOURCE_H
1312 #include <sys/resource.h>
1313 #endif
1314 ])
1315
1316 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1317 #include "ansidecl.h"
1318 #include "system.h"
1319 #ifdef HAVE_SYS_RESOURCE_H
1320 #include <sys/resource.h>
1321 #endif
1322 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1323 [Define to `long' if <sys/resource.h> doesn't define.])])
1324
1325 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1326 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1327 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1328 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1329 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1330 #include "ansidecl.h"
1331 #include "system.h"
1332 #ifdef HAVE_LDFCN_H
1333 #undef FREAD
1334 #undef FWRITE
1335 #include <ldfcn.h>
1336 #endif
1337 ])
1338
1339 gcc_AC_CHECK_DECLS(times, , ,[
1340 #include "ansidecl.h"
1341 #include "system.h"
1342 #ifdef HAVE_SYS_TIMES_H
1343 #include <sys/times.h>
1344 #endif
1345 ])
1346
1347 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1348 #include "ansidecl.h"
1349 #include "system.h"
1350 #include <signal.h>
1351 ])
1352
1353 # More time-related stuff.
1354 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1355 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1356 #include "ansidecl.h"
1357 #include "system.h"
1358 #ifdef HAVE_SYS_TIMES_H
1359 #include <sys/times.h>
1360 #endif
1361 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1362 if test $ac_cv_struct_tms = yes; then
1363   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1364   [Define if <sys/times.h> defines struct tms.])
1365 fi
1366
1367 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1368 # revisit after autoconf 2.50.
1369 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1370 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1371 #include "ansidecl.h"
1372 #include "system.h"
1373 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1374 if test $gcc_cv_type_clock_t = yes; then
1375   AC_DEFINE(HAVE_CLOCK_T, 1,
1376   [Define if <time.h> defines clock_t.])
1377 fi
1378
1379 # Check if F_SETLKW is supported by fcntl.
1380 AC_CACHE_CHECK(for F_SETLKW, ac_cv_f_setlkw, [
1381 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1382 #include <fcntl.h>]], [[
1383 struct flock fl;
1384 fl.l_whence = 0;
1385 fl.l_start = 0;
1386 fl.l_len = 0;
1387 fl.l_pid = 0;
1388 return fcntl (1, F_SETLKW, &fl);]])],
1389 [ac_cv_f_setlkw=yes],[ac_cv_f_setlkw=no])])
1390 if test $ac_cv_f_setlkw = yes; then
1391   AC_DEFINE(HOST_HAS_F_SETLKW, 1,
1392   [Define if F_SETLKW supported by fcntl.])
1393 fi
1394
1395 # Restore CFLAGS, CXXFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1396 CFLAGS="$saved_CFLAGS"
1397 CXXFLAGS="$saved_CXXFLAGS"
1398
1399 # mkdir takes a single argument on some systems.
1400 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1401
1402 # File extensions
1403 manext='.1'
1404 objext='.o'
1405 AC_SUBST(manext)
1406 AC_SUBST(objext)
1407
1408 # With Setjmp/Longjmp based exception handling.
1409 AC_ARG_ENABLE(sjlj-exceptions,
1410 [AS_HELP_STRING([--enable-sjlj-exceptions],
1411                 [arrange to use setjmp/longjmp exception handling])],
1412 [case $target in
1413   *-*-hpux10*)
1414     if test $enableval != yes; then
1415       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1416       enableval=yes
1417     fi
1418     ;;
1419 esac
1420 force_sjlj_exceptions=yes],
1421 [case $target in
1422   *-*-hpux10*)
1423     force_sjlj_exceptions=yes
1424     enableval=yes
1425     ;;
1426   lm32*-*-*)
1427      force_sjlj_exceptions=yes
1428      enableval=yes
1429      ;;
1430   *)
1431     force_sjlj_exceptions=no
1432     ;;
1433 esac])
1434 if test $force_sjlj_exceptions = yes; then
1435   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1436   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1437     [Define 0/1 to force the choice for exception handling model.])
1438 fi
1439
1440 # --------------------------------------------------------
1441 # Build, host, and target specific configuration fragments
1442 # --------------------------------------------------------
1443
1444 # Collect build-machine-specific information.
1445 . ${srcdir}/config.build
1446
1447 # Collect host-machine-specific information.
1448 . ${srcdir}/config.host
1449
1450 target_gtfiles=
1451
1452 # Collect target-machine-specific information.
1453 . ${srcdir}/config.gcc
1454
1455 extra_objs="${host_extra_objs} ${extra_objs}"
1456 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1457
1458 # Default the target-machine variables that were not explicitly set.
1459 if test x"$tm_file" = x
1460 then tm_file=$cpu_type/$cpu_type.h; fi
1461
1462 if test x"$extra_headers" = x
1463 then extra_headers=; fi
1464
1465 if test x$md_file = x
1466 then md_file=$cpu_type/$cpu_type.md; fi
1467
1468 if test x$out_file = x
1469 then out_file=$cpu_type/$cpu_type.c; fi
1470
1471 if test x"$tmake_file" = x
1472 then tmake_file=$cpu_type/t-$cpu_type
1473 fi
1474
1475 # Support --enable-initfini-array.
1476 if test x$enable_initfini_array != xno; then
1477   tm_file="${tm_file} initfini-array.h"
1478 fi
1479
1480 if test x"$dwarf2" = xyes
1481 then tm_file="$tm_file tm-dwarf2.h"
1482 fi
1483
1484 # Say what files are being used for the output code and MD file.
1485 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1486 echo "Using \`$srcdir/config/$md_file' as machine description file."
1487
1488 # If any of the xm_file variables contain nonexistent files, warn
1489 # about them and drop them.
1490
1491 bx=
1492 for x in $build_xm_file; do
1493   if    test -f $srcdir/config/$x
1494   then      bx="$bx $x"
1495   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1496   fi
1497 done
1498 build_xm_file="$bx"
1499
1500 hx=
1501 for x in $host_xm_file; do
1502   if    test -f $srcdir/config/$x
1503   then      hx="$hx $x"
1504   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1505   fi
1506 done
1507 host_xm_file="$hx"
1508
1509 tx=
1510 for x in $xm_file; do
1511   if    test -f $srcdir/config/$x
1512   then      tx="$tx $x"
1513   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1514   fi
1515 done
1516 xm_file="$tx"
1517
1518 count=a
1519 for f in $tm_file; do
1520         count=${count}x
1521 done
1522 if test $count = ax; then
1523         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1524 else
1525         echo "Using the following target machine macro files:"
1526         for f in $tm_file; do
1527                 echo "  $srcdir/config/$f"
1528         done
1529 fi
1530
1531 if test x$use_long_long_for_widest_fast_int = xyes; then
1532         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1533 [Define to 1 if the 'long long' type is wider than 'long' but still
1534 efficiently supported by the host hardware.])
1535 fi
1536
1537 gnu_ld_bool=`if test x"$gnu_ld" = x"yes"; then echo 1; else echo 0; fi`
1538 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld_bool, [Define to 1 if using GNU ld.])
1539
1540 gnu_as_bool=`if test x"$gas" = x"yes"; then echo 1; else echo 0; fi`
1541 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as_bool, [Define to 1 if using GNU as.])
1542
1543 count=a
1544 for f in $host_xm_file; do
1545         count=${count}x
1546 done
1547 if test $count = a; then
1548         :
1549 elif test $count = ax; then
1550         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1551 else
1552         echo "Using the following host machine macro files:"
1553         for f in $host_xm_file; do
1554                 echo "  $srcdir/config/$f"
1555         done
1556 fi
1557 echo "Using ${out_host_hook_obj} for host machine hooks."
1558
1559 if test "$host_xm_file" != "$build_xm_file"; then
1560         count=a
1561         for f in $build_xm_file; do
1562                 count=${count}x
1563         done
1564         if test $count = a; then
1565                 :
1566         elif test $count = ax; then
1567                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1568         else
1569                 echo "Using the following build machine macro files:"
1570                 for f in $build_xm_file; do
1571                         echo "  $srcdir/config/$f"
1572                 done
1573         fi
1574 fi
1575
1576 if test -n "$configured_native_system_header_dir"; then
1577   native_system_header_dir=$configured_native_system_header_dir
1578 fi
1579 NATIVE_SYSTEM_HEADER_DIR="$native_system_header_dir"
1580 AC_SUBST(NATIVE_SYSTEM_HEADER_DIR)
1581
1582 case ${host} in
1583   powerpc*-*-darwin*)
1584     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1585       gcc_cv_mcontext_underscores,
1586       AC_COMPILE_IFELSE([
1587 #include <sys/cdefs.h>
1588 #include <sys/signal.h>
1589 #include <ucontext.h>
1590 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1591 ],
1592         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1593       if test $gcc_cv_mcontext_underscores = yes; then
1594         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1595           [mcontext_t fields start with __])
1596       fi
1597     ;;
1598 esac
1599
1600 # ---------
1601 # Threading
1602 # ---------
1603
1604 # Check if a valid thread package
1605 case ${enable_threads} in
1606   "" | no)
1607     # No threads
1608     target_thread_file='single'
1609     ;;
1610   yes)
1611     # default
1612     target_thread_file='single'
1613     ;;
1614   aix | dce | lynx | mipssde | posix | rtems | \
1615   single | tpf | vxworks | win32)
1616     target_thread_file=${enable_threads}
1617     ;;
1618   *)
1619     echo "${enable_threads} is an unknown thread package" 1>&2
1620     exit 1
1621     ;;
1622 esac
1623
1624 if test x${thread_file} = x; then
1625   # No thread file set by target-specific clauses in config.gcc,
1626   # so use file chosen by default logic above
1627   thread_file=${target_thread_file}
1628 fi
1629
1630 # --------
1631 # UNSORTED
1632 # --------
1633
1634 use_cxa_atexit=no
1635 if test x$enable___cxa_atexit = xyes || \
1636    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1637   if test x$host = x$target; then
1638     case $host in
1639       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1640       # keyed to flag_use_cxa_atexit
1641       *-*-mingw32*)
1642         use_cxa_atexit=yes
1643         ;;
1644       powerpc-ibm-aix*)
1645         use_cxa_atexit=yes
1646         ;;
1647       *)
1648         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1649           [echo "__cxa_atexit can't be enabled on this target"])
1650         ;;
1651     esac
1652   else
1653     # We can't check for __cxa_atexit when building a cross, so assume
1654     # it is available
1655     use_cxa_atexit=yes
1656   fi
1657   if test x$use_cxa_atexit = xyes; then
1658     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1659       [Define if you want to use __cxa_atexit, rather than atexit, to
1660       register C++ destructors for local statics and global objects.
1661       This is essential for fully standards-compliant handling of
1662       destructors, but requires __cxa_atexit in libc.])
1663   fi
1664 fi
1665
1666 # Look for a file containing extra machine modes.
1667 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1668   extra_modes_file='$(srcdir)'/config/${extra_modes}
1669   AC_SUBST(extra_modes_file)
1670   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1671   [Define to the name of a file containing a list of extra machine modes
1672    for this architecture.])
1673 fi
1674
1675 # Convert extra_options into a form suitable for Makefile use.
1676 extra_opt_files=
1677 all_opt_files=
1678 for f in $extra_options; do
1679   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1680   all_opt_files="$all_opt_files $srcdir/config/$f"
1681 done
1682 AC_SUBST(extra_opt_files)
1683
1684 # auto-host.h is the file containing items generated by autoconf and is
1685 # the first file included by config.h.
1686 # If host=build, it is correct to have bconfig include auto-host.h
1687 # as well.  If host!=build, we are in error and need to do more
1688 # work to find out the build config parameters.
1689 if test x$host = x$build
1690 then
1691         build_auto=auto-host.h
1692 else
1693         # We create a subdir, then run autoconf in the subdir.
1694         # To prevent recursion we set host and build for the new
1695         # invocation of configure to the build for this invocation
1696         # of configure.
1697         tempdir=build.$$
1698         rm -rf $tempdir
1699         mkdir $tempdir
1700         cd $tempdir
1701         case ${srcdir} in
1702         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1703         *) realsrcdir=../${srcdir};;
1704         esac
1705         # Clearing GMPINC is necessary to prevent host headers being
1706         # used by the build compiler.  Defining GENERATOR_FILE stops
1707         # system.h from including gmp.h.
1708         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1709         CXX="${CXX_FOR_BUILD}" CXXFLAGS="${CXXFLAGS_FOR_BUILD}" \
1710         LD="${LD_FOR_BUILD}" LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1711         GMPINC="" CPPFLAGS="${CPPFLAGS} -DGENERATOR_FILE" \
1712         ${realsrcdir}/configure \
1713                 --enable-languages=${enable_languages-all} \
1714                 --target=$target_alias --host=$build_alias --build=$build_alias
1715
1716         # We just finished tests for the build machine, so rename
1717         # the file auto-build.h in the gcc directory.
1718         mv auto-host.h ../auto-build.h
1719         cd ..
1720         rm -rf $tempdir
1721         build_auto=auto-build.h
1722 fi
1723 AC_SUBST(build_subdir)
1724
1725 tm_file="${tm_file} defaults.h"
1726 tm_p_file="${tm_p_file} tm-preds.h"
1727 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1728 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1729 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1730 # put this back in temporarily.
1731 xm_file="auto-host.h ansidecl.h ${xm_file}"
1732
1733 # --------
1734 # UNSORTED
1735 # --------
1736
1737 changequote(,)dnl
1738 # Compile in configure arguments.
1739 if test -f configargs.h ; then
1740         # Being re-configured.
1741         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1742         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1743 else
1744         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1745 fi
1746
1747 # Double all backslashes and backslash all quotes to turn
1748 # gcc_config_arguments into a C string.
1749 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1750 $gcc_config_arguments
1751 EOF
1752 gcc_config_arguments_str=`cat conftest.out`
1753 rm -f conftest.out
1754
1755 cat > configargs.h <<EOF
1756 /* Generated automatically. */
1757 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1758 static const char thread_model[] = "$thread_file";
1759
1760 static const struct {
1761   const char *name, *value;
1762 } configure_default_options[] = $configure_default_options;
1763 EOF
1764 changequote([,])dnl
1765
1766 changequote(,)dnl
1767 gcc_BASEVER=`cat $srcdir/BASE-VER`
1768 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1769 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1770 if test -f $srcdir/REVISION ; then
1771         gcc_REVISION=`cat $srcdir/REVISION`
1772 else
1773         gcc_REVISION=""
1774 fi
1775 cat > plugin-version.h <<EOF
1776 #include "configargs.h"
1777
1778 #define GCCPLUGIN_VERSION_MAJOR   `echo $gcc_BASEVER | sed -e 's/^\([0-9]*\).*$/\1/'`
1779 #define GCCPLUGIN_VERSION_MINOR   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.\([0-9]*\).*$/\1/'`
1780 #define GCCPLUGIN_VERSION_PATCHLEVEL   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.[0-9]*\.\([0-9]*\)$/\1/'`
1781 #define GCCPLUGIN_VERSION  (GCCPLUGIN_VERSION_MAJOR*1000 + GCCPLUGIN_VERSION_MINOR)
1782
1783 static char basever[] = "$gcc_BASEVER";
1784 static char datestamp[] = "$gcc_DATESTAMP";
1785 static char devphase[] = "$gcc_DEVPHASE";
1786 static char revision[] = "$gcc_REVISION";
1787
1788 /* FIXME plugins: We should make the version information more precise.
1789    One way to do is to add a checksum. */
1790
1791 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1792                                                 devphase, revision,
1793                                                 configuration_arguments};
1794 EOF
1795 changequote([,])dnl
1796
1797 # Determine what GCC version number to use in filesystem paths.
1798 GCC_BASE_VER
1799
1800 # Internationalization
1801 ZW_GNU_GETTEXT_SISTER_DIR
1802
1803 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1804 # -liconv on the link line twice.
1805 case "$LIBINTL" in *$LIBICONV*)
1806         LIBICONV= ;;
1807 esac
1808
1809 AC_ARG_ENABLE(secureplt,
1810 [AS_HELP_STRING([--enable-secureplt],
1811                 [enable -msecure-plt by default for PowerPC])],
1812 [], [])
1813
1814 AC_ARG_ENABLE(leading-mingw64-underscores,
1815   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1816                  [enable leading underscores on 64 bit mingw targets]),
1817   [],[])
1818 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1819   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1820     [Define if we should use leading underscore on 64 bit mingw targets])])
1821
1822 AC_ARG_ENABLE(cld,
1823 [AS_HELP_STRING([--enable-cld], [enable -mcld by default for 32bit x86])], [],
1824 [enable_cld=no])
1825
1826 AC_ARG_ENABLE(frame-pointer,
1827 [AS_HELP_STRING([--enable-frame-pointer],
1828                 [enable -fno-omit-frame-pointer by default for 32bit x86])], [],
1829 [
1830 case $target_os in
1831 linux* | darwin[[8912]]*)
1832   # Enable -fomit-frame-pointer by default for Linux and Darwin with
1833   # DWARF2.
1834   enable_frame_pointer=no
1835   ;;
1836 *)
1837   enable_frame_pointer=yes
1838   ;;
1839 esac
1840 ])
1841
1842 # Windows32 Registry support for specifying GCC installation paths.
1843 AC_ARG_ENABLE(win32-registry,
1844 [AS_HELP_STRING([--disable-win32-registry],
1845                 [disable lookup of installation paths in the
1846                  Registry on Windows hosts])
1847 AS_HELP_STRING([--enable-win32-registry], [enable registry lookup (default)])
1848 AS_HELP_STRING([--enable-win32-registry=KEY],
1849                [use KEY instead of GCC version as the last portion
1850                 of the registry key])],,)
1851
1852 case $host_os in
1853   win32 | pe | cygwin* | mingw32*)
1854     if test "x$enable_win32_registry" != xno; then
1855       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1856     fi
1857
1858     if test "x$enable_win32_registry" != xno; then
1859       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1860   [Define to 1 if installation paths should be looked up in the Windows
1861    Registry. Ignored on non-Windows hosts.])
1862
1863       if test "x$enable_win32_registry" != xyes \
1864          && test "x$enable_win32_registry" != x; then
1865         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1866   [Define to be the last component of the Windows registry key under which
1867    to look for installation paths.  The full key used will be
1868    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1869    The default is the GCC version number.])
1870       fi
1871     fi
1872   ;;
1873 esac
1874
1875 # Get an absolute path to the GCC top-level source directory
1876 holddir=`${PWDCMD-pwd}`
1877 cd $srcdir
1878 topdir=`${PWDCMD-pwd}`
1879 cd $holddir
1880
1881 # Conditionalize the makefile for this host machine.
1882 xmake_file=
1883 for f in ${host_xmake_file}
1884 do
1885         if test -f ${srcdir}/config/$f
1886         then
1887                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1888         fi
1889 done
1890
1891 # Conditionalize the makefile for this target machine.
1892 tmake_file_=
1893 for f in ${tmake_file}
1894 do
1895         if test -f ${srcdir}/config/$f
1896         then
1897                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1898         fi
1899 done
1900 tmake_file="${tmake_file_}"
1901
1902 out_object_file=`basename $out_file .c`.o
1903 common_out_object_file=`basename $common_out_file .c`.o
1904
1905 tm_file_list="options.h"
1906 tm_include_list="options.h insn-constants.h"
1907 for f in $tm_file; do
1908   case $f in
1909     ./* )
1910        f=`echo $f | sed 's/^..//'`
1911        tm_file_list="${tm_file_list} $f"
1912        tm_include_list="${tm_include_list} $f"
1913        ;;
1914     defaults.h )
1915        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1916        tm_include_list="${tm_include_list} $f"
1917        ;;
1918     * )
1919        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1920        tm_include_list="${tm_include_list} config/$f"
1921        ;;
1922   esac
1923 done
1924
1925 tm_p_file_list=
1926 tm_p_include_list=
1927 for f in $tm_p_file; do
1928   case $f in
1929     tm-preds.h )
1930        tm_p_file_list="${tm_p_file_list} $f"
1931        tm_p_include_list="${tm_p_include_list} $f"
1932        ;;
1933     * )
1934        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1935        tm_p_include_list="${tm_p_include_list} config/$f"
1936   esac
1937 done
1938
1939 xm_file_list=
1940 xm_include_list=
1941 for f in $xm_file; do
1942   case $f in
1943     ansidecl.h )
1944        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1945        xm_include_list="${xm_include_list} $f"
1946        ;;
1947     auto-host.h )
1948        xm_file_list="${xm_file_list} $f"
1949        xm_include_list="${xm_include_list} $f"
1950        ;;
1951     * )
1952        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1953        xm_include_list="${xm_include_list} config/$f"
1954        ;;
1955   esac
1956 done
1957
1958 host_xm_file_list=
1959 host_xm_include_list=
1960 for f in $host_xm_file; do
1961   case $f in
1962     ansidecl.h )
1963        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1964        host_xm_include_list="${host_xm_include_list} $f"
1965        ;;
1966     auto-host.h )
1967        host_xm_file_list="${host_xm_file_list} $f"
1968        host_xm_include_list="${host_xm_include_list} $f"
1969        ;;
1970     * )
1971        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1972        host_xm_include_list="${host_xm_include_list} config/$f"
1973        ;;
1974   esac
1975 done
1976
1977 build_xm_file_list=
1978 for f in $build_xm_file; do
1979   case $f in
1980     ansidecl.h )
1981        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1982        build_xm_include_list="${build_xm_include_list} $f"
1983        ;;
1984     auto-build.h | auto-host.h )
1985        build_xm_file_list="${build_xm_file_list} $f"
1986        build_xm_include_list="${build_xm_include_list} $f"
1987        ;;
1988     * )
1989        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1990        build_xm_include_list="${build_xm_include_list} config/$f"
1991        ;;
1992   esac
1993 done
1994
1995 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1996 # cross-compiler which does not use the native headers and libraries.
1997 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1998 CROSS=                                          AC_SUBST(CROSS)
1999 ALL=all.internal                                AC_SUBST(ALL)
2000 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
2001
2002 if test "x$with_build_sysroot" != x; then
2003   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
2004 else
2005   # This value is used, even on a native system, because
2006   # CROSS_SYSTEM_HEADER_DIR is just
2007   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
2008   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
2009 fi
2010
2011 if test x$host != x$target
2012 then
2013         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
2014         ALL=all.cross
2015         SYSTEM_HEADER_DIR=$build_system_header_dir
2016         case $target in
2017                 *-*-mingw*)
2018                         if test "x$with_headers" = x; then
2019                                 with_headers=yes
2020                         fi
2021                         ;;
2022                 *)
2023                         ;;
2024         esac
2025 elif test "x$TARGET_SYSTEM_ROOT" != x; then
2026         SYSTEM_HEADER_DIR=$build_system_header_dir
2027 fi
2028
2029 if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
2030   if test "x$with_headers" != x && test "x$with_headers" != xyes; then
2031     target_header_dir=$with_headers
2032   elif test "x$with_sysroot" = x; then
2033     target_header_dir="${test_exec_prefix}/${target_noncanonical}/sys-include"
2034   elif test "x$with_build_sysroot" != "x"; then
2035     target_header_dir="${with_build_sysroot}${native_system_header_dir}"
2036   elif test "x$with_sysroot" = xyes; then
2037     target_header_dir="${test_exec_prefix}/${target_noncanonical}/sys-root${native_system_header_dir}"
2038   else
2039     target_header_dir="${with_sysroot}${native_system_header_dir}"
2040   fi
2041 else
2042   target_header_dir=${native_system_header_dir}
2043 fi
2044
2045 # If this is a cross-compiler that does not
2046 # have its own set of headers then define
2047 # inhibit_libc
2048
2049 # If this is using newlib, without having the headers available now,
2050 # then define inhibit_libc in LIBGCC2_CFLAGS.
2051 # This prevents libgcc2 from containing any code which requires libc
2052 # support.
2053 : ${inhibit_libc=false}
2054 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
2055        test x$with_newlib = xyes ; } &&
2056      { test "x$with_headers" = xno || test ! -f "$target_header_dir/stdio.h"; } ; then
2057        inhibit_libc=true
2058 fi
2059 AC_SUBST(inhibit_libc)
2060
2061 # When building gcc with a cross-compiler, we need to adjust things so
2062 # that the generator programs are still built with the native compiler.
2063 # Also, we cannot run fixincludes.
2064
2065 # These are the normal (build=host) settings:
2066 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
2067 CXX_FOR_BUILD='$(CXX)'          AC_SUBST(CXX_FOR_BUILD)
2068 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
2069 BUILD_CXXFLAGS='$(ALL_CXXFLAGS)' AC_SUBST(BUILD_CXXFLAGS)
2070 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
2071 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
2072
2073 BUILD_NO_PIE_CFLAGS='$(NO_PIE_CFLAGS)' AC_SUBST(BUILD_NO_PIE_CFLAGS)
2074 BUILD_NO_PIE_FLAG='$(NO_PIE_FLAG)' AC_SUBST(BUILD_NO_PIE_FLAG)
2075
2076 # And these apply if build != host, or we are generating coverage data
2077 if test x$build != x$host || test "x$coverage_flags" != x
2078 then
2079     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
2080     BUILD_CXXFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CXXFLAGS_FOR_BUILD)'
2081     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
2082
2083     NO_PIE_CFLAGS_FOR_BUILD=${NO_PIE_CFLAGS_FOR_BUILD-${NO_PIE_CFLAGS}}
2084     NO_PIE_FLAG_FOR_BUILD=${NO_PIE_FLAG_FOR_BUILD-${NO_PIE_FLAG}}
2085     BUILD_NO_PIE_CFLAGS='$(NO_PIE_CFLAGS_FOR_BUILD)'
2086     BUILD_NO_PIE_FLAG='$(NO_PIE_FLAG_FOR_BUILD)'
2087 fi
2088 AC_SUBST(NO_PIE_CFLAGS_FOR_BUILD)
2089 AC_SUBST(NO_PIE_FLAG_FOR_BUILD)
2090
2091 # Expand extra_headers to include complete path.
2092 # This substitutes for lots of t-* files.
2093 extra_headers_list=
2094 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
2095 for file in ${extra_headers} ; do
2096   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
2097 done
2098
2099 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
2100 if test x"$use_gcc_tgmath" = xyes
2101 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
2102 fi
2103
2104 # Define collect2 in Makefile.
2105 case $host_can_use_collect2 in
2106   no) collect2= ;;
2107   *) collect2='collect2$(exeext)' ;;
2108 esac
2109 AC_SUBST([collect2])
2110
2111 # Add a definition of USE_COLLECT2 if system wants one.
2112 case $use_collect2 in
2113   no) use_collect2= ;;
2114   "") ;;
2115   *)
2116     host_xm_defines="${host_xm_defines} USE_COLLECT2"
2117     xm_defines="${xm_defines} USE_COLLECT2"
2118     case $host_can_use_collect2 in
2119       no)
2120         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
2121         ;;
2122     esac
2123     ;;
2124 esac
2125
2126 AC_DEFINE_UNQUOTED(LTOPLUGINSONAME,"${host_lto_plugin_soname}",
2127 [Define to the name of the LTO plugin DSO that must be
2128   passed to the linker's -plugin=LIB option.])
2129
2130 # ---------------------------
2131 # Assembler & linker features
2132 # ---------------------------
2133
2134 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
2135 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
2136 # However when ld-new is first executed from the build tree, libtool will
2137 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
2138 # to the build tree.  While doing this we need to use the previous-stage
2139 # linker, or we have an infinite loop.  The presence of a shell script as
2140 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
2141 # the gcc/collect-ld script.  So we need to know how libtool works, or
2142 # exec-tool will fail.
2143
2144 m4_defun([_LT_CONFIG_COMMANDS], [])
2145 AC_PROG_LIBTOOL
2146 AC_SUBST(objdir)
2147 AC_SUBST(enable_fast_install)
2148
2149 # Identify the assembler which will work hand-in-glove with the newly
2150 # built GCC, so that we can examine its features.  This is the assembler
2151 # which will be driven by the driver program.
2152 #
2153 # If build != host, and we aren't building gas in-tree, we identify a
2154 # build->target assembler and hope that it will have the same features
2155 # as the host->target assembler we'll be using.
2156 gcc_cv_gas_major_version=
2157 gcc_cv_gas_minor_version=
2158 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
2159
2160 m4_pattern_allow([AS_FOR_TARGET])dnl
2161 AS_VAR_SET_IF(gcc_cv_as,, [
2162 if test -x "$DEFAULT_ASSEMBLER"; then
2163         gcc_cv_as="$DEFAULT_ASSEMBLER"
2164 elif test -f $gcc_cv_as_gas_srcdir/configure.ac \
2165      && test -f ../gas/Makefile \
2166      && test x$build = x$host; then
2167         gcc_cv_as=../gas/as-new$build_exeext
2168 elif test -x as$build_exeext; then
2169         # Build using assembler in the current directory.
2170         gcc_cv_as=./as$build_exeext
2171 elif ( set dummy $AS_FOR_TARGET; test -x $[2] ); then
2172         gcc_cv_as="$AS_FOR_TARGET"
2173 else
2174         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
2175 fi])
2176
2177 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
2178 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
2179 case "$ORIGINAL_AS_FOR_TARGET" in
2180   ./as | ./as$build_exeext) ;;
2181   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
2182 esac
2183
2184 AC_MSG_CHECKING(what assembler to use)
2185 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
2186   # Single tree build which includes gas.  We want to prefer it
2187   # over whatever linker top-level may have detected, since
2188   # we'll use what we're building after installation anyway.
2189   AC_MSG_RESULT(newly built gas)
2190   in_tree_gas=yes
2191   _gcc_COMPUTE_GAS_VERSION
2192   in_tree_gas_is_elf=no
2193   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
2194      || (grep 'obj_format = multi' ../gas/Makefile \
2195          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
2196   then
2197     in_tree_gas_is_elf=yes
2198   fi
2199 else
2200   AC_MSG_RESULT($gcc_cv_as)
2201   in_tree_gas=no
2202 fi
2203
2204 default_ld=
2205 AC_ARG_ENABLE(ld,
2206 [[  --enable-ld[=ARG]       build ld [ARG={default,yes,no}]]],
2207 [case "${enableval}" in
2208  no)
2209    default_ld=ld.gold
2210    ;;
2211  esac])
2212
2213 install_gold_as_default=no
2214 AC_ARG_ENABLE(gold,
2215 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
2216 [case "${enableval}" in
2217  default)
2218    install_gold_as_default=yes
2219    ;;
2220  yes)
2221    if test x${default_ld} != x; then
2222      install_gold_as_default=yes
2223    fi
2224    ;;
2225  no)
2226    ;;
2227  *)
2228    AC_MSG_ERROR([invalid --enable-gold argument])
2229    ;;
2230  esac])
2231
2232 # Identify the linker which will work hand-in-glove with the newly
2233 # built GCC, so that we can examine its features.  This is the linker
2234 # which will be driven by the driver program.
2235 #
2236 # If build != host, and we aren't building gas in-tree, we identify a
2237 # build->target linker and hope that it will have the same features
2238 # as the host->target linker we'll be using.
2239 gcc_cv_gld_major_version=
2240 gcc_cv_gld_minor_version=
2241 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
2242 gcc_cv_ld_gold_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gold
2243 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
2244
2245 AS_VAR_SET_IF(gcc_cv_ld,, [
2246 if test -x "$DEFAULT_LINKER"; then
2247         gcc_cv_ld="$DEFAULT_LINKER"
2248 elif test $install_gold_as_default = yes \
2249      && test -f $gcc_cv_ld_gold_srcdir/configure.ac \
2250      && test -f ../gold/Makefile \
2251      && test x$build = x$host; then
2252         gcc_cv_ld=../gold/ld-new$build_exeext
2253 elif test -f $gcc_cv_ld_gld_srcdir/configure.ac \
2254      && test -f ../ld/Makefile \
2255      && test x$build = x$host; then
2256         gcc_cv_ld=../ld/ld-new$build_exeext
2257 elif test -x collect-ld$build_exeext; then
2258         # Build using linker in the current directory.
2259         gcc_cv_ld=./collect-ld$build_exeext
2260 elif ( set dummy $LD_FOR_TARGET; test -x $[2] ); then
2261         gcc_cv_ld="$LD_FOR_TARGET"
2262 else
2263         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
2264 fi])
2265
2266 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
2267 PLUGIN_LD_SUFFIX=`basename $gcc_cv_ld | sed -e "s,$target_alias-,,"`
2268 # if the PLUGIN_LD is set ld-new, just have it as ld
2269 # as that is the installed named.
2270 if test x$PLUGIN_LD_SUFFIX = xld-new \
2271    || test x$PLUGIN_LD_SUFFIX = xcollect-ld ; then
2272   PLUGIN_LD_SUFFIX=ld
2273 fi
2274 AC_ARG_WITH(plugin-ld,
2275 [AS_HELP_STRING([[--with-plugin-ld=[ARG]]], [specify the plugin linker])],
2276 [if test x"$withval" != x; then
2277    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
2278    PLUGIN_LD_SUFFIX="$withval"
2279  fi])
2280 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
2281 AC_DEFINE_UNQUOTED(PLUGIN_LD_SUFFIX, "$PLUGIN_LD_SUFFIX", [Specify plugin linker])
2282
2283 # Check to see if we are using gold instead of ld
2284 AC_MSG_CHECKING(whether we are using gold)
2285 ld_is_gold=no
2286 if test x$gcc_cv_ld != x; then
2287   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
2288      | grep "GNU gold" > /dev/null; then
2289     ld_is_gold=yes
2290   fi
2291 fi
2292 AC_MSG_RESULT($ld_is_gold)
2293
2294 AC_MSG_CHECKING(gold linker with split stack support as non default)
2295 # Check to see if default ld is not gold, but gold is
2296 # available and has support for split stack.  If gcc was configured
2297 # with gold then no checking is done.
2298 #
2299 if test x$ld_is_gold = xno && which ${gcc_cv_ld}.gold >/dev/null 2>&1; then
2300
2301 # For platforms other than powerpc64*, enable as appropriate.
2302
2303   gold_non_default=no
2304   ld_gold=`which ${gcc_cv_ld}.gold`
2305 # Make sure this gold has minimal split stack support
2306   if $ld_gold --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
2307     ld_vers=`$ld_gold --version | sed 1q`
2308     gold_vers=`echo $ld_vers | sed -n \
2309           -e 's,^[[^)]]*[[  ]]\([[0-9]][[0-9]]*\.[[0-9]][[0-9]]*[[^)]]*\)) .*$,\1,p'`
2310     case $target in
2311 # check that the gold version contains the complete split stack support
2312 # on powerpc64 big and little endian
2313       powerpc64*-*-*)
2314         case "$gold_vers" in
2315           2.25.[[1-9]]*|2.2[[6-9]][[.0-9]]*|2.[[3-9]][[.0-9]]*|[[3-9]].[[.0-9]]*) gold_non_default=yes
2316           ;;
2317           *) gold_non_default=no
2318           ;;
2319         esac
2320         ;;
2321     esac
2322   fi
2323   if test $gold_non_default = yes; then
2324     AC_DEFINE(HAVE_GOLD_NON_DEFAULT_SPLIT_STACK, 1,
2325             [Define if the gold linker supports split stack and is available as a non-default])
2326   fi
2327 fi
2328 AC_MSG_RESULT($gold_non_default)
2329
2330 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
2331 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
2332 case "$ORIGINAL_LD_FOR_TARGET" in
2333   ./collect-ld | ./collect-ld$build_exeext) ;;
2334   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
2335 esac
2336
2337 AC_MSG_CHECKING(what linker to use)
2338 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext \
2339    || test "$gcc_cv_ld" = ../gold/ld-new$build_exeext; then
2340         # Single tree build which includes ld.  We want to prefer it
2341         # over whatever linker top-level may have detected, since
2342         # we'll use what we're building after installation anyway.
2343         AC_MSG_RESULT(newly built ld)
2344         in_tree_ld=yes
2345         in_tree_ld_is_elf=no
2346         if (grep 'EMUL = .*elf' ../ld/Makefile \
2347             || grep 'EMUL = .*linux' ../ld/Makefile \
2348             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
2349           in_tree_ld_is_elf=yes
2350         elif test "$ld_is_gold" = yes; then
2351           in_tree_ld_is_elf=yes
2352         fi
2353         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.ac $gcc_cv_ld_gld_srcdir/Makefile.in
2354         do
2355 changequote(,)dnl
2356                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*VERSION=[^0-9A-Za-z_]*\([0-9]*\.[0-9]*.*\)/VERSION=\1/p' < $f`
2357                 if test x$gcc_cv_gld_version != x; then
2358                         break
2359                 fi
2360         done
2361         case $gcc_cv_gld_version in
2362           VERSION=[0-9]*) ;;
2363 changequote([,])dnl
2364           *) AC_MSG_ERROR([[cannot find version of in-tree linker]]) ;;
2365 changequote(,)dnl
2366         esac
2367         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
2368         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
2369 changequote([,])dnl
2370         ORIGINAL_LD_BFD_FOR_TARGET=../ld/ld-new$build_exeext
2371         ORIGINAL_LD_GOLD_FOR_TARGET=../gold/ld-new$build_exeext
2372 else
2373         AC_MSG_RESULT($gcc_cv_ld)
2374         in_tree_ld=no
2375         gcc_cvs_ld_program=`dirname $gcc_cv_ld`/`basename $gcc_cv_ld $host_exeext`
2376         ORIGINAL_LD_BFD_FOR_TARGET=${gcc_cvs_ld_program}.bfd$host_exeext
2377         ORIGINAL_LD_GOLD_FOR_TARGET=${gcc_cvs_ld_program}.gold$host_exeext
2378 fi
2379
2380 AC_SUBST(ORIGINAL_LD_BFD_FOR_TARGET)
2381 AC_SUBST(ORIGINAL_LD_GOLD_FOR_TARGET)
2382
2383 # Figure out what nm we will be using.
2384 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
2385 AS_VAR_SET_IF(gcc_cv_nm,, [
2386 if test -f $gcc_cv_binutils_srcdir/configure.ac \
2387      && test -f ../binutils/Makefile \
2388      && test x$build = x$host; then
2389         gcc_cv_nm=../binutils/nm-new$build_exeext
2390 elif test -x nm$build_exeext; then
2391         gcc_cv_nm=./nm$build_exeext
2392 elif ( set dummy $NM_FOR_TARGET; test -x $[2] ); then
2393         gcc_cv_nm="$NM_FOR_TARGET"
2394 else
2395         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
2396 fi])
2397
2398 AC_MSG_CHECKING(what nm to use)
2399 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2400         # Single tree build which includes binutils.
2401         AC_MSG_RESULT(newly built nm)
2402         in_tree_nm=yes
2403 else
2404         AC_MSG_RESULT($gcc_cv_nm)
2405         in_tree_nm=no
2406 fi
2407
2408 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2409 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2410 case "$ORIGINAL_NM_FOR_TARGET" in
2411   ./nm | ./nm$build_exeext) ;;
2412   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2413 esac
2414
2415
2416 # Figure out what objdump we will be using.
2417 AS_VAR_SET_IF(gcc_cv_objdump,, [
2418 if test -f $gcc_cv_binutils_srcdir/configure.ac \
2419      && test -f ../binutils/Makefile \
2420      && test x$build = x$host; then
2421         # Single tree build which includes binutils.
2422         gcc_cv_objdump=../binutils/objdump$build_exeext
2423 elif test -x objdump$build_exeext; then
2424         gcc_cv_objdump=./objdump$build_exeext
2425 elif ( set dummy $OBJDUMP_FOR_TARGET; test -x $[2] ); then
2426         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2427 else
2428         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2429 fi])
2430
2431 AC_MSG_CHECKING(what objdump to use)
2432 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2433         # Single tree build which includes binutils.
2434         AC_MSG_RESULT(newly built objdump)
2435 elif test x$gcc_cv_objdump = x; then
2436         AC_MSG_RESULT(not found)
2437 else
2438         AC_MSG_RESULT($gcc_cv_objdump)
2439 fi
2440
2441 # Figure out what readelf we will be using.
2442 AS_VAR_SET_IF(gcc_cv_readelf,, [
2443 if test -f $gcc_cv_binutils_srcdir/configure.ac \
2444      && test -f ../binutils/Makefile \
2445      && test x$build = x$host; then
2446         # Single tree build which includes binutils.
2447         gcc_cv_readelf=../binutils/readelf$build_exeext
2448 elif test -x readelf$build_exeext; then
2449         gcc_cv_readelf=./readelf$build_exeext
2450 elif ( set dummy $READELF_FOR_TARGET; test -x $[2] ); then
2451         gcc_cv_readelf="$READELF_FOR_TARGET"
2452 else
2453         AC_PATH_PROG(gcc_cv_readelf, $READELF_FOR_TARGET)
2454 fi])
2455
2456 AC_MSG_CHECKING(what readelf to use)
2457 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2458         # Single tree build which includes binutils.
2459         AC_MSG_RESULT(newly built readelf)
2460 elif test x$gcc_cv_readelf = x; then
2461         AC_MSG_RESULT(not found)
2462 else
2463         AC_MSG_RESULT($gcc_cv_readelf)
2464 fi
2465
2466 # Figure out what assembler alignment features are present.
2467 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2468  [2,6,0],,
2469 [.balign 4
2470 .p2align 2],,
2471 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2472   [Define if your assembler supports .balign and .p2align.])])
2473
2474 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2475  [2,8,0],,
2476  [.p2align 4,,7],,
2477 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2478   [Define if your assembler supports specifying the maximum number
2479    of bytes to skip when using the GAS .p2align command.])])
2480
2481 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2482  [2,8,0],,
2483  [.literal16],,
2484 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2485   [Define if your assembler supports .literal16.])])
2486
2487 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2488  [elf,2,9,0],,
2489  [conftest_label1: .word 0
2490 .subsection -1
2491 conftest_label2: .word 0
2492 .previous],
2493  [if test x$gcc_cv_nm != x; then
2494     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2495     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2496     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2497     then :
2498     else gcc_cv_as_subsection_m1=yes
2499     fi
2500     rm -f conftest.nm1 conftest.nm2
2501   fi],
2502  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2503   [Define if your assembler supports .subsection and .subsection -1 starts
2504    emitting at the beginning of your section.])])
2505
2506 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2507  [2,2,0],,
2508  [      .weak foobar],,
2509 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2510
2511 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2512  [2,17,0],,
2513  [      .weakref foobar, barfnot],,
2514 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2515
2516 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2517  [2,15,91],,
2518  [      .SPACE $TEXT$
2519         .NSUBSPA $CODE$,COMDAT],,
2520 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2521
2522 # .hidden needs to be supported in both the assembler and the linker,
2523 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2524 # This is irritatingly difficult to feature test for; we have to check the
2525 # date string after the version number.  If we've got an in-tree
2526 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2527 # to be safe.
2528 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2529 case "${target}" in
2530   *-*-aix*)
2531     conftest_s='        .globl foobar,hidden'
2532     ;;
2533   *)
2534     conftest_s='        .hidden foobar
2535 foobar:'
2536     ;;
2537 esac
2538 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2539  [elf,2,13,0],, [$conftest_s])
2540 case "${target}" in
2541   *-*-darwin*)
2542     # Darwin as has some visibility support, though with a different syntax.
2543     gcc_cv_as_hidden=yes
2544     ;;
2545 esac
2546
2547 # gnu_indirect_function type is an extension proposed at
2548 # http://groups.google/com/group/generic-abi/files. It allows dynamic runtime
2549 # selection of function implementation
2550 AC_ARG_ENABLE(gnu-indirect-function,
2551  [AS_HELP_STRING([--enable-gnu-indirect-function],
2552                  [enable the use of the @gnu_indirect_function to glibc systems])],
2553  [case $enable_gnu_indirect_function in
2554     yes | no) ;;
2555     *) AC_MSG_ERROR(['$enable_gnu_indirect_function' is an invalid value for --enable-gnu-indirect-function.
2556 Valid choices are 'yes' and 'no'.]) ;;
2557   esac],
2558  [enable_gnu_indirect_function="$default_gnu_indirect_function"])
2559
2560 gif=`if test x$enable_gnu_indirect_function = xyes; then echo 1; else echo 0; fi`
2561 AC_DEFINE_UNQUOTED(HAVE_GNU_INDIRECT_FUNCTION, $gif,
2562 [Define if your system supports gnu indirect functions.])
2563
2564
2565 changequote(,)dnl
2566 if test $in_tree_ld != yes ; then
2567   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2568   if echo "$ld_ver" | grep GNU > /dev/null; then
2569     if test x"$ld_is_gold" = xyes; then
2570       # GNU gold --version looks like this:
2571       #
2572       # GNU gold (GNU Binutils 2.21.51.20110225) 1.11
2573       #
2574       # We extract the binutils version which is more familiar and specific
2575       # than the gold version.
2576       ld_vers=`echo $ld_ver | sed -n \
2577           -e 's,^[^)]*[  ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
2578     else
2579       # GNU ld --version looks like this:
2580       #
2581       # GNU ld (GNU Binutils) 2.21.51.20110225
2582       ld_vers=`echo $ld_ver | sed -n \
2583           -e 's,^.*[     ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2584     fi
2585     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2586     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2587     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2588     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2589   else
2590     case "${target}" in
2591       *-*-solaris2*)
2592         # See acinclude.m4 (gcc_SUN_LD_VERSION) for the version number
2593         # format.
2594         #
2595         # Don't reuse gcc_gv_sun_ld_vers_* in case a linker other than
2596         # /usr/ccs/bin/ld has been configured.
2597         ld_ver=`$gcc_cv_ld -V 2>&1`
2598         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2599           ld_vers=`echo $ld_ver | sed -n \
2600             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2601           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2602           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2603         fi
2604         ;;
2605     esac
2606   fi
2607 fi
2608 changequote([,])dnl
2609
2610 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2611 [[if test $in_tree_ld = yes ; then
2612   gcc_cv_ld_hidden=no
2613   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2614      && test $in_tree_ld_is_elf = yes; then
2615      gcc_cv_ld_hidden=yes
2616   fi
2617 else
2618   gcc_cv_ld_hidden=yes
2619   if test x"$ld_is_gold" = xyes; then
2620     :
2621   elif echo "$ld_ver" | grep GNU > /dev/null; then
2622     case "${target}" in
2623       mmix-knuth-mmixware)
2624         # The linker emits by default mmo, not ELF, so "no" is appropriate.
2625         gcc_cv_ld_hidden=no
2626         ;;
2627     esac
2628     if test 0"$ld_date" -lt 20020404; then
2629       if test -n "$ld_date"; then
2630         # If there was date string, but was earlier than 2002-04-04, fail
2631         gcc_cv_ld_hidden=no
2632       elif test -z "$ld_vers"; then
2633         # If there was no date string nor ld version number, something is wrong
2634         gcc_cv_ld_hidden=no
2635       else
2636         test -z "$ld_vers_patch" && ld_vers_patch=0
2637         if test "$ld_vers_major" -lt 2; then
2638           gcc_cv_ld_hidden=no
2639         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2640           gcc_cv_ld_hidden="no"
2641         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2642           gcc_cv_ld_hidden=no
2643         fi
2644       fi
2645     fi
2646   else
2647     case "${target}" in
2648       *-*-aix[789]*)
2649         gcc_cv_ld_hidden=yes
2650         ;;
2651       *-*-darwin*)
2652         # Darwin ld has some visibility support.
2653         gcc_cv_ld_hidden=yes
2654         ;;
2655       hppa64*-*-hpux* | ia64*-*-hpux*)
2656         gcc_cv_ld_hidden=yes
2657         ;;
2658       *-*-solaris2.1[0-9]*)
2659         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2660         # .symbolic was only added in Solaris 9 12/02.
2661         gcc_cv_ld_hidden=yes
2662         ;;
2663       *)
2664         gcc_cv_ld_hidden=no
2665         ;;
2666     esac
2667   fi
2668 fi]])
2669 libgcc_visibility=no
2670 AC_SUBST(libgcc_visibility)
2671 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2672 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2673   libgcc_visibility=yes
2674   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2675   [Define if your assembler and linker support .hidden.])
2676 fi
2677
2678 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2679 gcc_cv_ld_ro_rw_mix=unknown
2680 if test $in_tree_ld = yes ; then
2681   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2682      && test $in_tree_ld_is_elf = yes; then
2683     gcc_cv_ld_ro_rw_mix=read-write
2684   fi
2685 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2686   echo '.section myfoosect, "a"' > conftest1.s
2687   echo '.section myfoosect, "aw"' > conftest2.s
2688   echo '.byte 1' >> conftest2.s
2689   echo '.section myfoosect, "a"' > conftest3.s
2690   echo '.byte 0' >> conftest3.s
2691   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2692      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2693      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2694      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2695         conftest2.o conftest3.o > /dev/null 2>&1; then
2696     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2697                          | sed -e '/myfoosect/!d' -e N`
2698     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2699       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2700         gcc_cv_ld_ro_rw_mix=read-only
2701       else
2702         gcc_cv_ld_ro_rw_mix=read-write
2703       fi
2704     fi
2705   fi
2706 changequote(,)dnl
2707   rm -f conftest.* conftest[123].*
2708 changequote([,])dnl
2709 fi
2710 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2711         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2712   [Define if your linker links a mix of read-only
2713    and read-write sections into a read-write section.])
2714 fi
2715 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2716
2717 gcc_AC_INITFINI_ARRAY
2718
2719 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2720 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2721   [elf,2,11,0],,
2722 [       .data
2723         .uleb128 L2 - L1
2724 L1:
2725         .uleb128 1280
2726         .sleb128 -1010
2727 L2:],
2728 [[# GAS versions before 2.11 do not support uleb128,
2729   # despite appearing to.
2730   # ??? There exists an elf-specific test that will crash
2731   # the assembler.  Perhaps it's better to figure out whether
2732   # arbitrary sections are supported and try the test.
2733   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2734   if echo "$as_ver" | grep GNU > /dev/null; then
2735     as_vers=`echo $as_ver | sed -n \
2736         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2737     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2738     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2739     if test $as_major -eq 2 && test $as_minor -lt 11
2740     then :
2741     else gcc_cv_as_leb128=yes
2742     fi
2743   fi]],
2744   [AC_DEFINE(HAVE_AS_LEB128, 1,
2745     [Define if your assembler supports .sleb128 and .uleb128.])],
2746   [AC_DEFINE(HAVE_AS_LEB128, 0,
2747     [Define if your assembler supports .sleb128 and .uleb128.])])
2748
2749 # Check if we have assembler support for unwind directives.
2750 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2751   ,,
2752 [       .text
2753         .cfi_startproc
2754         .cfi_offset 0, 0
2755         .cfi_same_value 1
2756         .cfi_def_cfa 1, 2
2757         .cfi_escape 1, 2, 3, 4, 5
2758         .cfi_endproc],
2759 [case "$target" in
2760   *-*-solaris*)
2761     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2762     # read-only and read-write sections, we need to make sure that the
2763     # assembler used emits read-write .eh_frame sections.
2764     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2765       if test "x$gcc_cv_objdump" != x; then
2766         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2767                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2768           gcc_cv_as_cfi_directive=no
2769         else
2770           case "$target" in
2771             i?86-*-solaris2.1[[0-9]]* | x86_64-*-solaris2.1[[0-9]]*)
2772               # On Solaris/x86, make sure that GCC and assembler agree on using
2773               # read-only .eh_frame sections for 64-bit.
2774               if test x$gas = xyes; then
2775                  as_ix86_64_opt="--64"
2776               else
2777                  as_ix86_64_opt="-xarch=amd64"
2778               fi
2779               if $gcc_cv_as $as_ix86_64_opt -o conftest.o conftest.s > /dev/null 2>&1 && \
2780                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2781                         sed -e /.eh_frame/!d -e N | \
2782                         grep READONLY > /dev/null; then
2783                 gcc_cv_as_cfi_directive=yes
2784               else
2785                 gcc_cv_as_cfi_directive=no
2786               fi
2787               ;;
2788             *)
2789               gcc_cv_as_cfi_directive=yes
2790               ;;
2791           esac
2792         fi
2793       else
2794         # no objdump, err on the side of caution
2795         gcc_cv_as_cfi_directive=no
2796       fi
2797     else
2798       gcc_cv_as_cfi_directive=yes
2799     fi
2800     ;;
2801   *-*-*)
2802     gcc_cv_as_cfi_directive=yes
2803     ;;
2804 esac])
2805 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
2806 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2807   ,,
2808 [       .text
2809         .cfi_startproc
2810         .cfi_adjust_cfa_offset 64
2811         .skip 75040, 0
2812         .cfi_adjust_cfa_offset 128
2813         .cfi_endproc],
2814 [[
2815 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
2816     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2817    gcc_cv_as_cfi_advance_working=yes
2818 fi
2819 ]])
2820 else
2821   # no objdump, err on the side of caution
2822   gcc_cv_as_cfi_advance_working=no
2823 fi
2824 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_DIRECTIVE)
2825 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2826   [`if test $gcc_cv_as_cfi_directive = yes \
2827        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2828   [Define 0/1 if your assembler supports CFI directives.])
2829
2830 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE)
2831 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2832   gcc_cv_as_cfi_personality_directive, ,,
2833 [       .text
2834         .cfi_startproc
2835         .cfi_personality 0, symbol
2836         .cfi_endproc])
2837 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2838   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2839     then echo 1; else echo 0; fi`],
2840   [Define 0/1 if your assembler supports .cfi_personality.])
2841
2842 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2843   gcc_cv_as_cfi_sections_directive, ,,
2844 [       .text
2845         .cfi_sections .debug_frame, .eh_frame
2846         .cfi_startproc
2847         .cfi_endproc],
2848 [case $target_os in
2849   win32 | pe | cygwin* | mingw32*)
2850     # Need to check that we generated the correct relocation for the
2851     # .debug_frame section.  This was fixed for binutils 2.21.
2852     gcc_cv_as_cfi_sections_directive=no
2853     if test "x$gcc_cv_objdump" != x; then
2854      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
2855         grep secrel > /dev/null; then
2856       gcc_cv_as_cfi_sections_directive=yes
2857      fi
2858     fi
2859     ;;
2860   *)
2861     gcc_cv_as_cfi_sections_directive=yes
2862     ;;
2863 esac])
2864 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_SECTIONS_DIRECTIVE)
2865 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2866   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2867     then echo 1; else echo 0; fi`],
2868   [Define 0/1 if your assembler supports .cfi_sections.])
2869
2870 # GAS versions up to and including 2.11.0 may mis-optimize
2871 # .eh_frame data.
2872 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2873   [elf,2,12,0],,
2874 [       .text
2875 .LFB1:
2876         .4byte  0
2877 .L1:
2878         .4byte  0
2879 .LFE1:
2880         .section        .eh_frame,"aw",@progbits
2881 __FRAME_BEGIN__:
2882         .4byte  .LECIE1-.LSCIE1
2883 .LSCIE1:
2884         .4byte  0x0
2885         .byte   0x1
2886         .ascii "z\0"
2887         .byte   0x1
2888         .byte   0x78
2889         .byte   0x1a
2890         .byte   0x0
2891         .byte   0x4
2892         .4byte  1
2893         .p2align 1
2894 .LECIE1:
2895 .LSFDE1:
2896         .4byte  .LEFDE1-.LASFDE1
2897 .LASFDE1:
2898         .4byte  .LASFDE1-__FRAME_BEGIN__
2899         .4byte  .LFB1
2900         .4byte  .LFE1-.LFB1
2901         .byte   0x4
2902         .4byte  .LFE1-.LFB1
2903         .byte   0x4
2904         .4byte  .L1-.LFB1
2905 .LEFDE1:],
2906 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2907 cat > conftest.lit <<EOF
2908  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2909  0010 01000000 12000000 18000000 00000000  ................
2910  0020 08000000 04080000 0044               .........D      @&t@
2911 EOF
2912 cat > conftest.big <<EOF
2913  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2914  0010 00000001 00000012 00000018 00000000  ................
2915  0020 00000008 04000000 0844               .........D      @&t@
2916 EOF
2917   # If the assembler didn't choke, and we can objdump,
2918   # and we got the correct data, then succeed.
2919   # The text in the here-document typically retains its unix-style line
2920   # endings, while the output of objdump will use host line endings.
2921   # Therefore, use diff -b for the comparisons.
2922   if test x$gcc_cv_objdump != x \
2923   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2924      | tail -3 > conftest.got \
2925   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2926     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2927   then
2928     gcc_cv_as_eh_frame=yes
2929   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2930     gcc_cv_as_eh_frame=buggy
2931   else
2932     # Uh oh, what do we do now?
2933     gcc_cv_as_eh_frame=no
2934   fi])
2935
2936 if test $gcc_cv_as_eh_frame = buggy; then
2937   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2938   [Define if your assembler mis-optimizes .eh_frame data.])
2939 fi
2940
2941 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2942  [elf,2,12,0], [--fatal-warnings],
2943  [.section .rodata.str, "aMS", @progbits, 1])
2944 if test $gcc_cv_as_shf_merge = no; then
2945   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2946     [elf,2,12,0], [--fatal-warnings],
2947     [.section .rodata.str, "aMS", %progbits, 1])
2948 fi
2949 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2950   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2951 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2952
2953 gcc_GAS_CHECK_FEATURE([stabs directive], gcc_cv_as_stabs_directive, ,,
2954 [.stabs "gcc2_compiled.",60,0,0,0],,
2955 [AC_DEFINE(HAVE_AS_STABS_DIRECTIVE, 1,
2956   [Define if your assembler supports .stabs.])])
2957
2958 gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as)],
2959  gcc_cv_as_comdat_group,
2960  [elf,2,16,0], [--fatal-warnings],
2961  [.section .text,"axG",@progbits,.foo,comdat])
2962 if test $gcc_cv_as_comdat_group = yes; then
2963   gcc_cv_as_comdat_group_percent=no
2964   gcc_cv_as_comdat_group_group=no
2965 else
2966  gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as, %type)],
2967    gcc_cv_as_comdat_group_percent,
2968    [elf,2,16,0], [--fatal-warnings],
2969    [.section .text,"axG",%progbits,.foo,comdat])
2970  if test $gcc_cv_as_comdat_group_percent = yes; then
2971    gcc_cv_as_comdat_group_group=no
2972  else
2973    case "${target}" in
2974      # Sun as uses a completely different syntax.
2975      *-*-solaris2*)
2976        case "${target}" in
2977          sparc*-*-solaris2*)
2978            conftest_s='
2979                .group foo,".text%foo",#comdat
2980                .section ".text%foo", #alloc,#execinstr,#progbits
2981                .globl foo
2982              foo:
2983              '
2984            ;;
2985          i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
2986            conftest_s='
2987                .group foo,.text%foo,#comdat
2988                .section .text%foo, "ax", @progbits
2989                .globl  foo
2990              foo:
2991              '
2992            ;;
2993        esac
2994        gcc_GAS_CHECK_FEATURE([COMDAT group support (Sun as, .group)],
2995          gcc_cv_as_comdat_group_group,
2996          ,, [$conftest_s])
2997        ;;
2998    esac
2999    if test -z "${gcc_cv_as_comdat_group_group+set}"; then
3000      gcc_cv_as_comdat_group_group=no
3001    fi
3002  fi
3003 fi
3004 if test x"$ld_is_gold" = xyes; then
3005   comdat_group=yes
3006 elif test $in_tree_ld = yes ; then
3007   comdat_group=no
3008   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3009      && test $in_tree_ld_is_elf = yes; then
3010      comdat_group=yes
3011   fi
3012 elif echo "$ld_ver" | grep GNU > /dev/null; then
3013   comdat_group=yes
3014   if test 0"$ld_date" -lt 20050308; then
3015     if test -n "$ld_date"; then
3016       # If there was date string, but was earlier than 2005-03-08, fail
3017       comdat_group=no
3018     elif test "$ld_vers_major" -lt 2; then
3019       comdat_group=no
3020     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
3021       comdat_group=no
3022     fi
3023   fi
3024 else
3025 changequote(,)dnl
3026   case "${target}" in
3027     *-*-solaris2.1[1-9]*)
3028       comdat_group=no
3029       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
3030       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
3031       # version 1.688.
3032       #
3033       # If using Sun as for COMDAT group as emitted by GCC, one needs at
3034       # least ld version 1.2267.
3035       if test "$ld_vers_major" -gt 1; then
3036         comdat_group=yes
3037       elif test "x$gas_flag" = xyes && test "$ld_vers_minor" -ge 1688; then
3038         comdat_group=yes
3039       elif test "$ld_vers_minor" -ge 2267; then
3040         comdat_group=yes
3041       fi
3042       ;;
3043     *)
3044       # Assume linkers other than GNU ld don't support COMDAT group.
3045       comdat_group=no
3046       ;;
3047   esac
3048 changequote([,])dnl
3049 fi
3050 # Allow overriding the automatic COMDAT group tests above.
3051 AC_ARG_ENABLE(comdat,
3052   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
3053   [comdat_group="$enable_comdat"])
3054 if test $comdat_group = no; then
3055   gcc_cv_as_comdat_group=no
3056   gcc_cv_as_comdat_group_percent=no
3057   gcc_cv_as_comdat_group_group=no
3058 fi
3059 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
3060   [`if test $gcc_cv_as_comdat_group = yes \
3061     || test $gcc_cv_as_comdat_group_percent = yes \
3062     || test $gcc_cv_as_comdat_group_group = yes; then echo 1; else echo 0; fi`],
3063 [Define 0/1 if your assembler and linker support COMDAT groups.])
3064
3065 gcc_GAS_CHECK_FEATURE([line table discriminator support],
3066  gcc_cv_as_discriminator,
3067  [2,19,51],,
3068 [       .text
3069         .file 1 "conf.c"
3070         .loc 1 1 0 discriminator 1],,
3071 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
3072   [Define if your assembler supports the .loc discriminator sub-directive.])])
3073
3074 # Thread-local storage - the check is heavily parameterized.
3075 conftest_s=
3076 tls_first_major=
3077 tls_first_minor=
3078 tls_as_opt=
3079 case "$target" in
3080 changequote(,)dnl
3081   alpha*-*-*)
3082     conftest_s='
3083         .section ".tdata","awT",@progbits
3084 foo:    .long   25
3085         .text
3086         ldq     $27,__tls_get_addr($29)         !literal!1
3087         lda     $16,foo($29)                    !tlsgd!1
3088         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
3089         ldq     $27,__tls_get_addr($29)         !literal!2
3090         lda     $16,foo($29)                    !tlsldm!2
3091         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
3092         ldq     $1,foo($29)                     !gotdtprel
3093         ldah    $2,foo($29)                     !dtprelhi
3094         lda     $3,foo($2)                      !dtprello
3095         lda     $4,foo($29)                     !dtprel
3096         ldq     $1,foo($29)                     !gottprel
3097         ldah    $2,foo($29)                     !tprelhi
3098         lda     $3,foo($2)                      !tprello
3099         lda     $4,foo($29)                     !tprel'
3100         tls_first_major=2
3101         tls_first_minor=13
3102         tls_as_opt=--fatal-warnings
3103         ;;
3104   arc*-*-*)
3105     conftest_s='
3106         add_s r0,r0, @foo@tpoff'
3107         tls_first_major=2
3108         tls_first_minor=23
3109         ;;
3110   cris-*-*|crisv32-*-*)
3111     conftest_s='
3112         .section ".tdata","awT",@progbits
3113 x:      .long   25
3114         .text
3115         move.d x:IE,$r10
3116         nop'
3117         tls_first_major=2
3118         tls_first_minor=20
3119         tls_as_opt=--fatal-warnings
3120         ;;
3121   frv*-*-*)
3122     conftest_s='
3123         .section ".tdata","awT",@progbits
3124 x:      .long   25
3125         .text
3126         call    #gettlsoff(x)'
3127         tls_first_major=2
3128         tls_first_minor=14
3129         ;;
3130   hppa*-*-linux*)
3131     conftest_s='
3132 t1:     .reg    %r20
3133 t2:     .reg    %r21
3134 gp:     .reg    %r19
3135         .section ".tdata","awT",@progbits
3136 foo:    .long   25
3137         .text
3138         .align  4
3139         addil LT%foo-$tls_gdidx$,gp
3140         ldo RT%foo-$tls_gdidx$(%r1),%arg0
3141         b __tls_get_addr
3142         nop
3143         addil LT%foo-$tls_ldidx$,gp
3144         b __tls_get_addr
3145         ldo RT%foo-$tls_ldidx$(%r1),%arg0
3146         addil LR%foo-$tls_dtpoff$,%ret0
3147         ldo RR%foo-$tls_dtpoff$(%r1),%t1
3148         mfctl %cr27,%t1
3149         addil LT%foo-$tls_ieoff$,gp
3150         ldw RT%foo-$tls_ieoff$(%r1),%t2
3151         add %t1,%t2,%t3
3152         mfctl %cr27,%t1
3153         addil LR%foo-$tls_leoff$,%t1
3154         ldo RR%foo-$tls_leoff$(%r1),%t2'
3155         tls_first_major=2
3156         tls_first_minor=15
3157         tls_as_opt=--fatal-warnings
3158         ;;
3159   arm*-*-*)
3160     conftest_s='
3161         .section ".tdata","awT",%progbits
3162 foo:    .long   25
3163         .text
3164 .word foo(gottpoff)
3165 .word foo(tpoff)
3166 .word foo(tlsgd)
3167 .word foo(tlsldm)
3168 .word foo(tlsldo)'
3169         tls_first_major=2
3170         tls_first_minor=17
3171         ;;
3172   i[34567]86-*-* | x86_64-*-*)
3173     case "$target" in
3174       i[34567]86-*-solaris2.* | x86_64-*-solaris2.1[0-9]*)
3175         on_solaris=yes
3176         ;;
3177       *)
3178         on_solaris=no
3179         ;;
3180     esac
3181     if test x$on_solaris = xyes && test x$gas_flag = xno; then
3182       conftest_s='
3183         .section .tdata,"awt",@progbits'
3184       tls_first_major=0
3185       tls_first_minor=0
3186       tls_section_flag=t
3187 changequote([,])dnl
3188       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
3189 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
3190 changequote(,)dnl
3191     else
3192       conftest_s='
3193         .section ".tdata","awT",@progbits'
3194       tls_first_major=2
3195       tls_first_minor=14
3196       tls_section_flag=T
3197       tls_as_opt="--fatal-warnings"
3198     fi
3199     case "$target" in
3200       i[34567]86-*-*)
3201         conftest_s="$conftest_s
3202 foo:    .long   25
3203         .text
3204         movl    %gs:0, %eax
3205         leal    foo@tlsgd(,%ebx,1), %eax
3206         leal    foo@tlsldm(%ebx), %eax
3207         leal    foo@dtpoff(%eax), %edx
3208         movl    foo@gottpoff(%ebx), %eax
3209         subl    foo@gottpoff(%ebx), %eax
3210         addl    foo@gotntpoff(%ebx), %eax
3211         movl    foo@indntpoff, %eax
3212         movl    \$foo@tpoff, %eax
3213         subl    \$foo@tpoff, %eax
3214         leal    foo@ntpoff(%ecx), %eax"
3215         ;;
3216       x86_64-*-*)
3217         if test x$on_solaris = xyes; then
3218           case $gas_flag in
3219             yes) tls_as_opt="$tls_as_opt --64" ;;
3220             no)  tls_as_opt="$tls_as_opt -xarch=amd64" ;;
3221           esac
3222         fi
3223         conftest_s="$conftest_s
3224 foo:    .long   25
3225         .text
3226         movq    %fs:0, %rax
3227         leaq    foo@tlsgd(%rip), %rdi
3228         leaq    foo@tlsld(%rip), %rdi
3229         leaq    foo@dtpoff(%rax), %rdx
3230         movq    foo@gottpoff(%rip), %rax
3231         movq    \$foo@tpoff, %rax"
3232         ;;
3233     esac
3234     ;;
3235   ia64-*-*)
3236     conftest_s='
3237         .section ".tdata","awT",@progbits
3238 foo:    data8   25
3239         .text
3240         addl    r16 = @ltoff(@dtpmod(foo#)), gp
3241         addl    r17 = @ltoff(@dtprel(foo#)), gp
3242         addl    r18 = @ltoff(@tprel(foo#)), gp
3243         addl    r19 = @dtprel(foo#), gp
3244         adds    r21 = @dtprel(foo#), r13
3245         movl    r23 = @dtprel(foo#)
3246         addl    r20 = @tprel(foo#), gp
3247         adds    r22 = @tprel(foo#), r13
3248         movl    r24 = @tprel(foo#)'
3249         tls_first_major=2
3250         tls_first_minor=13
3251         tls_as_opt=--fatal-warnings
3252         ;;
3253   microblaze*-*-*)
3254     conftest_s='
3255         .section .tdata,"awT",@progbits
3256 x:
3257         .word 2
3258         .text
3259         addik r5,r20,x@TLSGD
3260         addik r5,r20,x@TLSLDM'
3261         tls_first_major=2
3262         tls_first_minor=20
3263         tls_as_opt='--fatal-warnings'
3264         ;;
3265   mips*-*-*)
3266     conftest_s='
3267         .section .tdata,"awT",@progbits
3268 x:
3269         .word 2
3270         .text
3271         addiu $4, $28, %tlsgd(x)
3272         addiu $4, $28, %tlsldm(x)
3273         lui $4, %dtprel_hi(x)
3274         addiu $4, $4, %dtprel_lo(x)
3275         lw $4, %gottprel(x)($28)
3276         lui $4, %tprel_hi(x)
3277         addiu $4, $4, %tprel_lo(x)'
3278         tls_first_major=2
3279         tls_first_minor=16
3280         tls_as_opt='-32 --fatal-warnings'
3281         ;;
3282   m68k-*-*)
3283     conftest_s='
3284         .section .tdata,"awT",@progbits
3285 x:
3286         .word 2
3287         .text
3288 foo:
3289         move.l x@TLSGD(%a5),%a0
3290         move.l x@TLSLDM(%a5),%a0
3291         move.l x@TLSLDO(%a5),%a0
3292         move.l x@TLSIE(%a5),%a0
3293         move.l x@TLSLE(%a5),%a0'
3294         tls_first_major=2
3295         tls_first_minor=19
3296         tls_as_opt='--fatal-warnings'
3297         ;;
3298   nios2-*-*)
3299       conftest_s='
3300         .section ".tdata","awT",@progbits'
3301         tls_first_major=2
3302         tls_first_minor=23
3303         tls_as_opt="--fatal-warnings"
3304         ;;
3305   aarch64*-*-*)
3306     conftest_s='
3307         .section ".tdata","awT",%progbits
3308 foo:    .long   25
3309         .text
3310         adrp  x0, :tlsgd:x
3311         add   x0, x0, #:tlsgd_lo12:x
3312         bl    __tls_get_addr
3313         nop'
3314         tls_first_major=2
3315         tls_first_minor=20
3316         tls_as_opt='--fatal-warnings'
3317         ;;
3318   powerpc-ibm-aix*)
3319     conftest_s='
3320         .extern __get_tpointer
3321         .toc
3322 LC..1:
3323         .tc a[TC],a[TL]@le
3324         .csect .text[PR]
3325 .tlstest:
3326         lwz 9,LC..1(2)
3327         bla __get_tpointer
3328         lwzx 3,9,3
3329         .globl a
3330         .csect a[TL],4
3331 a:
3332         .space 4'
3333         tls_first_major=0
3334         tls_first_minor=0
3335         ;;
3336   powerpc64*-*-*)
3337     conftest_s='
3338         .section ".tdata","awT",@progbits
3339         .align 3
3340 ld0:    .space 8
3341 ld1:    .space 8
3342 x1:     .space 8
3343 x2:     .space 8
3344 x3:     .space 8
3345         .text
3346         addi 3,2,ld0@got@tlsgd
3347         bl .__tls_get_addr
3348         nop
3349         addi 3,2,ld1@toc
3350         bl .__tls_get_addr
3351         nop
3352         addi 3,2,x1@got@tlsld
3353         bl .__tls_get_addr
3354         nop
3355         addi 9,3,x1@dtprel
3356         bl .__tls_get_addr
3357         nop
3358         addis 9,3,x2@dtprel@ha
3359         addi 9,9,x2@dtprel@l
3360         bl .__tls_get_addr
3361         nop
3362         ld 9,x3@got@dtprel(2)
3363         add 9,9,3
3364         bl .__tls_get_addr
3365         nop'
3366         tls_first_major=2
3367         tls_first_minor=14
3368         tls_as_opt="-a64 --fatal-warnings"
3369         ;;
3370   powerpc*-*-*)
3371     conftest_s='
3372         .section ".tdata","awT",@progbits
3373         .align 2
3374 ld0:    .space 4
3375 ld1:    .space 4
3376 x1:     .space 4
3377 x2:     .space 4
3378 x3:     .space 4
3379         .text
3380         addi 3,31,ld0@got@tlsgd
3381         bl __tls_get_addr
3382         addi 3,31,x1@got@tlsld
3383         bl __tls_get_addr
3384         addi 9,3,x1@dtprel
3385         addis 9,3,x2@dtprel@ha
3386         addi 9,9,x2@dtprel@l
3387         lwz 9,x3@got@tprel(31)
3388         add 9,9,x@tls
3389         addi 9,2,x1@tprel
3390         addis 9,2,x2@tprel@ha
3391         addi 9,9,x2@tprel@l'
3392         tls_first_major=2
3393         tls_first_minor=14
3394         tls_as_opt="-a32 --fatal-warnings"
3395         ;;
3396   riscv*-*-*)
3397     conftest_s='
3398         .section .tdata,"awT",@progbits
3399 x:      .word 2
3400         .text
3401         la.tls.gd a0,x
3402         call __tls_get_addr'
3403         tls_first_major=2
3404         tls_first_minor=21
3405         tls_as_opt='--fatal-warnings'
3406         ;;
3407   s390-*-*)
3408     conftest_s='
3409         .section ".tdata","awT",@progbits
3410 foo:    .long   25
3411         .text
3412         .long   foo@TLSGD
3413         .long   foo@TLSLDM
3414         .long   foo@DTPOFF
3415         .long   foo@NTPOFF
3416         .long   foo@GOTNTPOFF
3417         .long   foo@INDNTPOFF
3418         l       %r1,foo@GOTNTPOFF(%r12)
3419         l       %r1,0(%r1):tls_load:foo
3420         bas     %r14,0(%r1,%r13):tls_gdcall:foo
3421         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
3422         tls_first_major=2
3423         tls_first_minor=14
3424         tls_as_opt="-m31 --fatal-warnings"
3425         ;;
3426   s390x-*-*)
3427     conftest_s='
3428         .section ".tdata","awT",@progbits
3429 foo:    .long   25
3430         .text
3431         .quad   foo@TLSGD
3432         .quad   foo@TLSLDM
3433         .quad   foo@DTPOFF
3434         .quad   foo@NTPOFF
3435         .quad   foo@GOTNTPOFF
3436         lg      %r1,foo@GOTNTPOFF(%r12)
3437         larl    %r1,foo@INDNTPOFF
3438         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
3439         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
3440         tls_first_major=2
3441         tls_first_minor=14
3442         tls_as_opt="-m64 -Aesame --fatal-warnings"
3443         ;;
3444   sh-*-* | sh[123456789lbe]*-*-*)
3445     conftest_s='
3446         .section ".tdata","awT",@progbits
3447 foo:    .long   25
3448         .text
3449         .long   foo@TLSGD
3450         .long   foo@TLSLDM
3451         .long   foo@DTPOFF
3452         .long   foo@GOTTPOFF
3453         .long   foo@TPOFF'
3454         tls_first_major=2
3455         tls_first_minor=13
3456         tls_as_opt=--fatal-warnings
3457         ;;
3458   sparc*-*-*)
3459     case "$target" in
3460       sparc*-sun-solaris2.*)
3461         on_solaris=yes
3462         ;;
3463       *)
3464         on_solaris=no
3465         ;;
3466     esac
3467     if test x$on_solaris = xyes && test x$gas_flag = xno; then
3468       conftest_s='
3469         .section ".tdata",#alloc,#write,#tls'
3470         tls_first_major=0
3471         tls_first_minor=0
3472     else
3473       conftest_s='
3474         .section ".tdata","awT",@progbits'
3475         tls_first_major=2
3476         tls_first_minor=14
3477         tls_as_opt="-32 --fatal-warnings"
3478     fi
3479     conftest_s="$conftest_s
3480 foo:    .long   25
3481         .text
3482         sethi   %tgd_hi22(foo), %o0
3483         add     %o0, %tgd_lo10(foo), %o1
3484         add     %l7, %o1, %o0, %tgd_add(foo)
3485         call    __tls_get_addr, %tgd_call(foo)
3486         sethi   %tldm_hi22(foo), %l1
3487         add     %l1, %tldm_lo10(foo), %l2
3488         add     %l7, %l2, %o0, %tldm_add(foo)
3489         call    __tls_get_addr, %tldm_call(foo)
3490         sethi   %tldo_hix22(foo), %l3
3491         xor     %l3, %tldo_lox10(foo), %l4
3492         add     %o0, %l4, %l5, %tldo_add(foo)
3493         sethi   %tie_hi22(foo), %o3
3494         add     %o3, %tie_lo10(foo), %o3
3495         ld      [%l7 + %o3], %o2, %tie_ld(foo)
3496         add     %g7, %o2, %o4, %tie_add(foo)
3497         sethi   %tle_hix22(foo), %l1
3498         xor     %l1, %tle_lox10(foo), %o5
3499         ld      [%g7 + %o5], %o1"
3500         ;;
3501   tilepro*-*-*)
3502       conftest_s='
3503         .section ".tdata","awT",@progbits
3504 foo:    .long   25
3505         .text
3506         addli   r0, zero, tls_gd(foo)
3507         auli    r0, zero, tls_gd_ha16(foo)
3508         addli   r0, r0, tls_gd_lo16(foo)
3509         jal     __tls_get_addr
3510         addli   r0, zero, tls_ie(foo)
3511         auli    r0, r0, tls_ie_ha16(foo)
3512         addli   r0, r0, tls_ie_lo16(foo)'
3513         tls_first_major=2
3514         tls_first_minor=22
3515         tls_as_opt="--fatal-warnings"
3516         ;;
3517   tilegx*-*-*)
3518       conftest_s='
3519         .section ".tdata","awT",@progbits
3520 foo:    .long   25
3521         .text
3522         shl16insli r0, zero, hw0_last_tls_gd(foo)
3523         shl16insli r0, zero, hw1_last_tls_gd(foo)
3524         shl16insli r0, r0,   hw0_tls_gd(foo)
3525         jal        __tls_get_addr
3526         shl16insli r0, zero, hw1_last_tls_ie(foo)
3527         shl16insli r0, r0,   hw0_tls_ie(foo)'
3528         tls_first_major=2
3529         tls_first_minor=22
3530         tls_as_opt="--fatal-warnings"
3531         ;;
3532   xtensa*-*-*)
3533     conftest_s='
3534         .section ".tdata","awT",@progbits
3535 foo:    .long   25
3536         .text
3537         movi    a8, foo@TLSFUNC
3538         movi    a10, foo@TLSARG
3539         callx8.tls a8, foo@TLSCALL'
3540         tls_first_major=2
3541         tls_first_minor=19
3542         ;;
3543 changequote([,])dnl
3544 esac
3545 set_have_as_tls=no
3546 if test "x$enable_tls" = xno ; then
3547   : # TLS explicitly disabled.
3548 elif test "x$enable_tls" = xyes ; then
3549   set_have_as_tls=yes # TLS explicitly enabled.
3550 elif test -z "$tls_first_major"; then
3551   : # If we don't have a check, assume no support.
3552 else
3553   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
3554   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
3555   [set_have_as_tls=yes])
3556 fi
3557 if test $set_have_as_tls = yes ; then
3558   AC_DEFINE(HAVE_AS_TLS, 1,
3559             [Define if your assembler and linker support thread-local storage.])
3560 fi
3561
3562 # Target-specific assembler checks.
3563
3564 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3565 gcc_cv_ld_static_dynamic=no
3566 gcc_cv_ld_static_option='-Bstatic'
3567 gcc_cv_ld_dynamic_option='-Bdynamic'
3568 if test $in_tree_ld = yes ; then
3569   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3570     gcc_cv_ld_static_dynamic=yes
3571   fi
3572 elif test x$gcc_cv_ld != x; then
3573   # Check if linker supports -Bstatic/-Bdynamic option
3574   if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3575      && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3576       gcc_cv_ld_static_dynamic=yes
3577   else
3578     case "$target" in
3579       # AIX ld uses -b flags
3580       *-*-aix4.[[23]]* | *-*-aix[[5-9]]*)
3581         gcc_cv_ld_static_dynamic=yes
3582         gcc_cv_ld_static_option="-bstatic"
3583         gcc_cv_ld_dynamic_option="-bdynamic"
3584         ;;
3585       # HP-UX ld uses -a flags to select between shared and archive.
3586       *-*-hpux*)
3587         if test x"$gnu_ld" = xno; then
3588           gcc_cv_ld_static_dynamic=yes
3589           gcc_cv_ld_static_option="-aarchive_shared"
3590           gcc_cv_ld_dynamic_option="-adefault"
3591         fi
3592         ;;
3593       # Solaris 2 ld always supports -Bstatic/-Bdynamic.
3594       *-*-solaris2*)
3595         gcc_cv_ld_static_dynamic=yes
3596         ;;
3597     esac
3598   fi
3599 fi
3600 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3601         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3602 [Define if your linker supports -Bstatic/-Bdynamic or equivalent options.])
3603         AC_DEFINE_UNQUOTED(LD_STATIC_OPTION, "$gcc_cv_ld_static_option",
3604 [Define to the linker option to disable use of shared objects.])
3605         AC_DEFINE_UNQUOTED(LD_DYNAMIC_OPTION, "$gcc_cv_ld_dynamic_option",
3606 [Define to the linker option to enable use of shared objects.])
3607 fi
3608 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3609
3610 if test x"$demangler_in_ld" = xyes; then
3611   AC_MSG_CHECKING(linker --demangle support)
3612   gcc_cv_ld_demangle=no
3613   if test $in_tree_ld = yes; then
3614     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3615       gcc_cv_ld_demangle=yes
3616     fi
3617   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3618     # Check if the GNU linker supports --demangle option
3619     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3620       gcc_cv_ld_demangle=yes
3621     fi
3622   fi
3623   if test x"$gcc_cv_ld_demangle" = xyes; then
3624     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3625 [Define if your linker supports --demangle option.])
3626   fi
3627   AC_MSG_RESULT($gcc_cv_ld_demangle)
3628 fi
3629
3630 AC_MSG_CHECKING(linker plugin support)
3631 gcc_cv_lto_plugin=0
3632 if test -f liblto_plugin.la; then
3633   save_ld_ver="$ld_ver"
3634   save_ld_vers_major="$ld_vers_major"
3635   save_ld_vers_minor="$ld_vers_minor"
3636   save_ld_is_gold="$ld_is_gold"
3637
3638   ld_is_gold=no
3639
3640   if test $in_tree_ld = yes -a x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" = x"$gcc_cv_ld"; then
3641     ld_ver="GNU ld"
3642     # FIXME: ld_is_gold?
3643     ld_vers_major="$gcc_cv_gld_major_version"
3644     ld_vers_minor="$gcc_cv_gld_minor_version"
3645   else
3646     # Determine plugin linker version.
3647     # FIXME: Partial duplicate from above, generalize.
3648 changequote(,)dnl
3649     ld_ver=`$ORIGINAL_PLUGIN_LD_FOR_TARGET --version 2>/dev/null | sed 1q`
3650     if echo "$ld_ver" | grep GNU > /dev/null; then
3651       if echo "$ld_ver" | grep "GNU gold" > /dev/null; then
3652         ld_is_gold=yes
3653         ld_vers=`echo $ld_ver | sed -n \
3654             -e 's,^[^)]*[        ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
3655       else
3656         ld_vers=`echo $ld_ver | sed -n \
3657             -e 's,^.*[   ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
3658       fi
3659       ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
3660       ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
3661     fi
3662 changequote([,])dnl
3663   fi
3664
3665   # Determine plugin support.
3666   if echo "$ld_ver" | grep GNU > /dev/null; then
3667     # Require GNU ld or gold 2.21+ for plugin support by default.
3668     if test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -ge 21; then
3669       gcc_cv_lto_plugin=2
3670     # Allow -fuse-linker-plugin to enable plugin support in GNU gold 2.20.
3671     elif test "$ld_is_gold" = yes -a "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 20; then
3672       gcc_cv_lto_plugin=1
3673     fi
3674   fi
3675
3676   ld_ver="$save_ld_ver"
3677   ld_vers_major="$save_ld_vers_major"
3678   ld_vers_minor="$save_ld_vers_minor"
3679   ld_is_gold="$save_ld_is_gold"
3680 fi
3681 AC_DEFINE_UNQUOTED(HAVE_LTO_PLUGIN, $gcc_cv_lto_plugin,
3682   [Define to the level of your linker's plugin support.])
3683 AC_MSG_RESULT($gcc_cv_lto_plugin)
3684
3685 # Target OS-specific assembler checks.
3686
3687 case "$target_os" in
3688   darwin*)
3689     gcc_GAS_CHECK_FEATURE([-mmacosx-version-min option],
3690       gcc_cv_as_mmacosx_version_min,,
3691       [-mmacosx-version-min=10.1], [.text],,
3692       [AC_DEFINE(HAVE_AS_MMACOSX_VERSION_MIN_OPTION, 1,
3693         [Define if your Mac OS X assembler supports the -mmacos-version-min option.])])
3694     ;;
3695 esac
3696
3697 # Target CPU-specific assembler checks.
3698
3699 case "$target" in
3700   aarch64*-*-*)
3701     gcc_GAS_CHECK_FEATURE([-mabi option], gcc_cv_as_aarch64_mabi,,
3702                           [-mabi=lp64], [.text],,,)
3703     if test x$gcc_cv_as_aarch64_mabi = xyes; then
3704       AC_DEFINE(HAVE_AS_MABI_OPTION, 1,
3705                 [Define if your assembler supports the -mabi option.])
3706     else
3707       if test x$with_abi = xilp32; then
3708         AC_MSG_ERROR([Assembler does not support -mabi=ilp32.\
3709                      Upgrade the Assembler.])
3710       fi
3711       if test x"$with_multilib_list" = xdefault; then
3712         TM_MULTILIB_CONFIG=lp64
3713       else
3714         aarch64_multilibs=`echo $with_multilib_list | sed -e 's/,/ /g'`
3715         for aarch64_multilib in ${aarch64_multilibs}; do
3716           case ${aarch64_multilib} in
3717             ilp32)
3718               AC_MSG_ERROR([Assembler does not support -mabi=ilp32.\
3719                             Upgrade the Assembler.])
3720               ;;
3721             *)
3722               ;;
3723           esac
3724         done
3725       fi
3726     fi
3727     # Check if we have binutils support for relocations types needed by -fpic
3728     gcc_GAS_CHECK_FEATURE([-fpic relocs], gcc_cv_as_aarch64_picreloc,,,
3729     [
3730         .text
3731         ldr     x0, [[x2, #:gotpage_lo15:globalsym]]
3732     ],,[AC_DEFINE(HAVE_AS_SMALL_PIC_RELOCS, 1,
3733         [Define if your assembler supports relocs needed by -fpic.])])
3734     # Enable default workaround for AArch64 Cortex-A53 erratum 835769.
3735     AC_ARG_ENABLE(fix-cortex-a53-835769,
3736     [
3737 AS_HELP_STRING([--enable-fix-cortex-a53-835769],
3738         [enable workaround for AArch64 Cortex-A53 erratum 835769 by default])
3739 AS_HELP_STRING([--disable-fix-cortex-a53-835769],
3740         [disable workaround for AArch64 Cortex-A53 erratum 835769 by default])
3741     ],
3742       [
3743         case $enableval in
3744           yes)
3745             tm_defines="${tm_defines} TARGET_FIX_ERR_A53_835769_DEFAULT=1"
3746             ;;
3747           no)
3748             ;;
3749           *)
3750             AC_MSG_ERROR(['$enableval' is an invalid value for --enable-fix-cortex-a53-835769.\
3751   Valid choices are 'yes' and 'no'.])
3752             ;;
3753
3754         esac
3755       ],
3756     [])
3757     # Enable default workaround for AArch64 Cortex-A53 erratum 843419.
3758     AC_ARG_ENABLE(fix-cortex-a53-843419,
3759     [
3760 AS_HELP_STRING([--enable-fix-cortex-a53-843419],
3761         [enable workaround for AArch64 Cortex-A53 erratum 843419 by default])
3762 AS_HELP_STRING([--disable-fix-cortex-a53-843419],
3763         [disable workaround for AArch64 Cortex-A53 erratum 843419 by default])
3764     ],
3765       [
3766         case $enableval in
3767           yes)
3768             tm_defines="${tm_defines} TARGET_FIX_ERR_A53_843419_DEFAULT=1"
3769             ;;
3770           no)
3771             ;;
3772           *)
3773             AC_MSG_ERROR(['$enableval' is an invalid value for --enable-fix-cortex-a53-843419.\
3774   Valid choices are 'yes' and 'no'.])
3775             ;;
3776
3777         esac
3778       ],
3779     [])
3780     ;;
3781
3782   # All TARGET_ABI_OSF targets.
3783   alpha*-*-linux* | alpha*-*-*bsd*)
3784     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3785         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3786 [       .set nomacro
3787         .text
3788         extbl   $3, $2, $3      !lituse_bytoff!1
3789         ldq     $2, a($29)      !literal!1
3790         ldq     $4, b($29)      !literal!2
3791         ldq_u   $3, 0($2)       !lituse_base!1
3792         ldq     $27, f($29)     !literal!5
3793         jsr     $26, ($27), f   !lituse_jsr!5
3794         ldah    $29, 0($26)     !gpdisp!3
3795         lda     $0, c($29)      !gprel
3796         ldah    $1, d($29)      !gprelhigh
3797         lda     $1, d($1)       !gprellow
3798         lda     $29, 0($29)     !gpdisp!3],,
3799     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3800   [Define if your assembler supports explicit relocations.])])
3801     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3802         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3803 [       .set nomacro
3804         .text
3805         ldq     $27, a($29)     !literal!1
3806         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3807     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3808   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3809     ;;
3810
3811   avr-*-*)
3812     gcc_GAS_CHECK_FEATURE([--mlink-relax option], gcc_cv_as_avr_mlink_relax,,
3813       [--mlink-relax], [.text],,
3814       [AC_DEFINE(HAVE_AS_AVR_MLINK_RELAX_OPTION, 1,
3815                 [Define if your avr assembler supports --mlink-relax option.])])
3816
3817     gcc_GAS_CHECK_FEATURE([-mrmw option], gcc_cv_as_avr_mrmw,,
3818       [-mrmw], [.text],,
3819       [AC_DEFINE(HAVE_AS_AVR_MRMW_OPTION, 1,
3820                 [Define if your avr assembler supports -mrmw option.])])
3821     ;;
3822
3823   cris-*-*)
3824     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3825       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3826       [-no-mul-bug-abort], [.text],,
3827       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3828                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3829     ;;
3830
3831   sparc*-*-*)
3832     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3833       [.register %g2, #scratch],,
3834       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3835                 [Define if your assembler supports .register.])])
3836
3837     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3838       [-relax], [.text],,
3839       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3840                 [Define if your assembler supports -relax option.])])
3841
3842     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3843       gcc_cv_as_sparc_gotdata_op,,
3844       [-K PIC],
3845 [.text
3846 .align 4
3847 foo:
3848         nop
3849 bar:
3850         sethi %gdop_hix22(foo), %g1
3851         xor    %g1, %gdop_lox10(foo), %g1
3852         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3853       [if test x$gcc_cv_ld != x \
3854        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3855          if test x$gcc_cv_objdump != x; then
3856            if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3857               | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3858                gcc_cv_as_sparc_gotdata_op=no
3859            else
3860                gcc_cv_as_sparc_gotdata_op=yes
3861            fi
3862          fi
3863        fi
3864        rm -f conftest],
3865       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3866                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3867
3868     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3869       gcc_cv_as_sparc_ua_pcrel,,
3870       [-K PIC],
3871 [.text
3872 foo:
3873         nop
3874 .data
3875 .align 4
3876 .byte 0
3877 .uaword %r_disp32(foo)],
3878       [if test x$gcc_cv_ld != x \
3879        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3880          gcc_cv_as_sparc_ua_pcrel=yes
3881        fi
3882        rm -f conftest],
3883       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3884                 [Define if your assembler and linker support unaligned PC relative relocs.])
3885
3886       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3887         gcc_cv_as_sparc_ua_pcrel_hidden,,
3888         [-K PIC],
3889 [.data
3890 .align 4
3891 .byte 0x31
3892 .uaword %r_disp32(foo)
3893 .byte 0x32, 0x33, 0x34
3894 .global foo
3895 .hidden foo
3896 foo:
3897 .skip 4],
3898         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3899          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3900          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3901             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3902             if $gcc_cv_objdump -R conftest 2> /dev/null \
3903                | grep 'DISP32' > /dev/null 2>&1; then
3904                 :
3905             else
3906                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3907             fi
3908          fi
3909          rm -f conftest],
3910          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3911                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3912     ]) # unaligned pcrel relocs
3913
3914     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3915       gcc_cv_as_sparc_offsetable_lo10,,
3916       [-xarch=v9],
3917 [.text
3918         or %g1, %lo(ab) + 12, %g1
3919         or %g1, %lo(ab + 12), %g1],
3920       [if test x$gcc_cv_objdump != x \
3921        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3922           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3923          gcc_cv_as_sparc_offsetable_lo10=yes
3924        fi],
3925        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3926                  [Define if your assembler supports offsetable %lo().])])
3927
3928     gcc_GAS_CHECK_FEATURE([FMAF, HPC, and VIS 3.0 instructions],
3929       gcc_cv_as_sparc_fmaf,,
3930       [-xarch=v9d],
3931       [.text
3932        .register %g2, #scratch
3933        .register %g3, #scratch
3934        .align 4
3935        fmaddd %f0, %f2, %f4, %f6
3936        addxccc %g1, %g2, %g3
3937        fsrl32 %f2, %f4, %f8
3938        fnaddd %f10, %f12, %f14],,
3939       [AC_DEFINE(HAVE_AS_FMAF_HPC_VIS3, 1,
3940                 [Define if your assembler supports FMAF, HPC, and VIS 3.0 instructions.])])
3941
3942     gcc_GAS_CHECK_FEATURE([SPARC4 instructions],
3943       gcc_cv_as_sparc_sparc4,,
3944       [-xarch=sparc4],
3945       [.text
3946        .register %g2, #scratch
3947        .register %g3, #scratch
3948        .align 4
3949        cxbe %g2, %g3, 1f
3950 1:     cwbneg %g2, %g3, 1f
3951 1:     sha1
3952        md5
3953        aes_kexpand0 %f4, %f6, %f8
3954        des_round %f38, %f40, %f42, %f44
3955        camellia_f %f54, %f56, %f58, %f60
3956        kasumi_fi_xor %f46, %f48, %f50, %f52],,
3957       [AC_DEFINE(HAVE_AS_SPARC4, 1,
3958                 [Define if your assembler supports SPARC4 instructions.])])
3959
3960     gcc_GAS_CHECK_FEATURE([SPARC5 and VIS 4.0 instructions],
3961       gcc_cv_as_sparc_sparc5,,
3962       [-xarch=sparc5],
3963       [.text
3964        .register %g2, #scratch
3965        .register %g3, #scratch
3966        .align 4
3967        subxc %g1, %g2, %g3
3968        fpadd8 %f0, %f2, %f4],,
3969       [AC_DEFINE(HAVE_AS_SPARC5_VIS4, 1,
3970                 [Define if your assembler supports SPARC5 and VIS 4.0 instructions.])])
3971
3972     gcc_GAS_CHECK_FEATURE([LEON instructions],
3973       gcc_cv_as_sparc_leon,,
3974       [-Aleon],
3975       [.text
3976        .register %g2, #scratch
3977        .register %g3, #scratch
3978        .align 4
3979        smac %g2, %g3, %g1
3980        umac %g2, %g3, %g1
3981        casa [[%g2]] 0xb, %g3, %g1],,
3982       [AC_DEFINE(HAVE_AS_LEON, 1,
3983                 [Define if your assembler supports LEON instructions.])])
3984     ;;
3985
3986 changequote(,)dnl
3987   i[34567]86-*-* | x86_64-*-*)
3988 changequote([,])dnl
3989     case $target_os in
3990       cygwin*)
3991         # Full C++ conformance when using a shared libstdc++-v3 requires some
3992         # support from the Cygwin DLL, which in more recent versions exports
3993         # wrappers to aid in interposing and redirecting operators new, delete,
3994         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3995         # are configuring for a version of Cygwin that exports the wrappers.
3996         if test x$host = x$target && test x$host_cpu = xi686; then
3997           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3998         else
3999           # Can't check presence of libc functions during cross-compile, so
4000           # we just have to assume we're building for an up-to-date target.
4001           gcc_ac_cygwin_dll_wrappers=yes
4002         fi
4003         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
4004           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
4005           [Define if you want to generate code by default that assumes that the
4006            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
4007     esac
4008     case $target_os in
4009       cygwin* | pe | mingw32*)
4010         # Recent binutils allows the three-operand form of ".comm" on PE.  This
4011         # definition is used unconditionally to initialise the default state of
4012         # the target option variable that governs usage of the feature.
4013         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
4014          [2,19,52],,[.comm foo,1,32])
4015         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
4016           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
4017           [Define if your assembler supports specifying the alignment
4018            of objects allocated using the GAS .comm command.])
4019         # Used for DWARF 2 in PE
4020         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
4021           gcc_cv_as_ix86_pe_secrel32,
4022           [2,15,91],,
4023 [.text
4024 foo:    nop
4025 .data
4026         .secrel32 foo],
4027           [if test x$gcc_cv_ld != x \
4028            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
4029              gcc_cv_as_ix86_pe_secrel32=yes
4030            fi
4031            rm -f conftest],
4032           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
4033             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
4034         # Test if the assembler supports the extended form of the .section
4035         # directive that specifies section alignment.  LTO support uses this,
4036         # but normally only after installation, so we warn but don't fail the
4037         # configure if LTO is enabled but the assembler does not support it.
4038         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
4039           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
4040         if test x$gcc_cv_as_section_has_align != xyes; then
4041           case ",$enable_languages," in
4042             *,lto,*)
4043               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
4044               ;;
4045           esac
4046         fi
4047         ;;
4048     esac
4049
4050     # Test if the assembler supports the section flag 'e' for specifying
4051     # an excluded section.
4052     gcc_GAS_CHECK_FEATURE([.section with e], gcc_cv_as_section_has_e,
4053       [2,22,51], [--fatal-warnings],
4054 [.section foo1,"e"
4055 .byte 0,0,0,0])
4056     AC_DEFINE_UNQUOTED(HAVE_GAS_SECTION_EXCLUDE,
4057       [`if test $gcc_cv_as_section_has_e = yes; then echo 1; else echo 0; fi`],
4058       [Define if your assembler supports specifying the section flag e.])
4059
4060     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
4061        gcc_cv_as_ix86_filds,,,
4062        [filds (%ebp); fists (%ebp)],,
4063        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
4064          [Define if your assembler uses filds and fists mnemonics.])])
4065
4066     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
4067        gcc_cv_as_ix86_fildq,,,
4068        [fildq (%ebp); fistpq (%ebp)],,
4069        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
4070          [Define if your assembler uses fildq and fistq mnemonics.])])
4071
4072     gcc_GAS_CHECK_FEATURE([cmov syntax],
4073       gcc_cv_as_ix86_cmov_sun_syntax,,,
4074       [cmovl.l %edx, %eax],,
4075       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
4076         [Define if your assembler supports the Sun syntax for cmov.])])
4077
4078     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
4079       gcc_cv_as_ix86_ffreep,,,
4080       [ffreep %st(1)],,
4081       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
4082         [Define if your assembler supports the ffreep mnemonic.])])
4083
4084     gcc_GAS_CHECK_FEATURE([.quad directive],
4085       gcc_cv_as_ix86_quad,,,
4086       [.quad 0],,
4087       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
4088         [Define if your assembler supports the .quad directive.])])
4089
4090     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
4091       gcc_cv_as_ix86_sahf,,,
4092       [.code64
4093        sahf],,
4094       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
4095         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
4096
4097     gcc_GAS_CHECK_FEATURE([interunit movq mnemonic],
4098       gcc_cv_as_ix86_interunit_movq,,,
4099       [.code64
4100        movq %mm0, %rax
4101        movq %rax, %xmm0])
4102     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_INTERUNIT_MOVQ,
4103       [`if test $gcc_cv_as_ix86_interunit_movq = yes; then echo 1; else echo 0; fi`],
4104       [Define if your assembler supports interunit movq mnemonic.])
4105
4106     gcc_GAS_CHECK_FEATURE([hle prefixes],
4107       gcc_cv_as_ix86_hle,,,
4108       [lock xacquire cmpxchg %esi, (%ecx)],,
4109       [AC_DEFINE(HAVE_AS_IX86_HLE, 1,
4110         [Define if your assembler supports HLE prefixes.])])
4111
4112     gcc_GAS_CHECK_FEATURE([swap suffix],
4113       gcc_cv_as_ix86_swap,,,
4114       [movl.s %esp, %ebp],,
4115       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
4116         [Define if your assembler supports the swap suffix.])])
4117
4118     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
4119       gcc_cv_as_ix86_diff_sect_delta,,,
4120       [.section .rodata
4121 .L1:
4122         .long .L2-.L1
4123         .long .L3-.L1
4124         .text
4125 .L3:    nop
4126 .L2:    nop],,
4127       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
4128         [Define if your assembler supports the subtraction of symbols in different sections.])])
4129
4130     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
4131         gcc_cv_as_ix86_rep_lock_prefix,,,
4132         [rep movsl
4133          rep ret
4134          rep nop
4135          rep bsf %ecx, %eax
4136          rep bsr %ecx, %eax
4137          lock addl %edi, (%eax,%esi)
4138          lock orl $0, (%esp)],,
4139         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
4140           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
4141
4142     gcc_GAS_CHECK_FEATURE([ud2 mnemonic],
4143         gcc_cv_as_ix86_ud2,,,
4144         [ud2],,
4145       [AC_DEFINE(HAVE_AS_IX86_UD2, 1,
4146         [Define if your assembler supports the 'ud2' mnemonic.])])
4147
4148     # Enforce 32-bit output with gas and gld.
4149     if test x$gas = xyes; then
4150       as_ix86_gas_32_opt="--32"
4151     fi
4152     if echo "$ld_ver" | grep GNU > /dev/null; then
4153       if $gcc_cv_ld -V 2>/dev/null | grep elf_i386_sol2 > /dev/null; then
4154         ld_ix86_gld_32_opt="-melf_i386_sol2"
4155       else
4156         ld_ix86_gld_32_opt="-melf_i386"
4157       fi
4158     fi
4159
4160     gcc_GAS_CHECK_FEATURE([R_386_TLS_GD_PLT reloc],
4161         gcc_cv_as_ix86_tlsgdplt,,
4162         [$as_ix86_gas_32_opt],
4163         [call    tls_gd@tlsgdplt],
4164         [if test x$gcc_cv_ld != x \
4165          && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o -G > /dev/null 2>&1; then
4166            gcc_cv_as_ix86_tlsgdplt=yes
4167          fi
4168          rm -f conftest],
4169       [AC_DEFINE(HAVE_AS_IX86_TLSGDPLT, 1,
4170         [Define if your assembler and linker support @tlsgdplt.])])
4171
4172     conftest_s='
4173         .section .tdata,"aw'$tls_section_flag'",@progbits
4174 tls_ld:
4175         .section .text,"ax",@progbits
4176          call    tls_ld@tlsldmplt'
4177
4178     gcc_GAS_CHECK_FEATURE([R_386_TLS_LDM_PLT reloc],
4179         gcc_cv_as_ix86_tlsldmplt,,
4180         [$as_ix86_gas_32_opt],
4181         [$conftest_s],
4182         [if test x$gcc_cv_ld != x \
4183          && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o -G > /dev/null 2>&1; then
4184            gcc_cv_as_ix86_tlsldmplt=yes
4185          fi
4186          rm -f conftest])
4187     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_TLSLDMPLT,
4188       [`if test $gcc_cv_as_ix86_tlsldmplt = yes; then echo 1; else echo 0; fi`],
4189       [Define to 1 if your assembler and linker support @tlsldmplt.])
4190
4191     conftest_s='
4192         .section .text,"ax",@progbits
4193         .globl  _start
4194         .type   _start, @function
4195 _start:
4196         leal    value@tlsldm(%ebx), %eax
4197         call    ___tls_get_addr@plt
4198
4199         .section .tdata,"aw'$tls_section_flag'",@progbits
4200         .type   value, @object
4201 value:'
4202     gcc_GAS_CHECK_FEATURE([R_386_TLS_LDM reloc],
4203         gcc_cv_as_ix86_tlsldm,,
4204         [$as_ix86_gas_32_opt],
4205         [$conftest_s],
4206         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
4207             && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o $ld_tls_libs -lc > /dev/null 2>&1; then
4208            if $gcc_cv_objdump -d conftest 2>/dev/null | grep nop > /dev/null \
4209               || dis conftest 2>/dev/null | grep nop > /dev/null; then
4210              gcc_cv_as_ix86_tlsldm=yes
4211            fi
4212          fi
4213          rm -f conftest])
4214     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_TLSLDM,
4215       [`if test $gcc_cv_as_ix86_tlsldm = yes; then echo 1; else echo 0; fi`],
4216       [Define to 1 if your assembler and linker support @tlsldm.])
4217
4218     conftest_s='
4219         .data
4220 bar:
4221         .byte 1
4222         .text
4223         .global _start
4224 _start:
4225          cmpl $0, bar@GOT
4226          jmp *_start@GOT'
4227     gcc_GAS_CHECK_FEATURE([R_386_GOT32X reloc],
4228         gcc_cv_as_ix86_got32x,,
4229         [$as_ix86_gas_32_opt],
4230         [$conftest_s],
4231         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
4232             && test x$gcc_cv_readelf != x \
4233             && $gcc_cv_readelf --relocs --wide conftest.o 2>&1 \
4234                | grep R_386_GOT32X > /dev/null 2>&1 \
4235             && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o > /dev/null 2>&1; then
4236            if $gcc_cv_objdump -dw conftest 2>&1 \
4237               | grep 0xffffff > /dev/null 2>&1; then
4238              gcc_cv_as_ix86_got32x=no
4239            else
4240              gcc_cv_as_ix86_got32x=yes
4241            fi
4242          fi
4243          rm -f conftest])
4244     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_GOT32X,
4245       [`if test x"$gcc_cv_as_ix86_got32x" = xyes; then echo 1; else echo 0; fi`],
4246       [Define 0/1 if your assembler and linker support @GOT.])
4247
4248     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
4249       gcc_cv_as_ix86_gotoff_in_data, [2,11,0],
4250       [$as_ix86_gas_32_opt],
4251 [       .text
4252 .L0:
4253         nop
4254         .data
4255         .long .L0@GOTOFF])
4256     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
4257       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
4258       [Define true if the assembler supports '.long foo@GOTOFF'.])
4259
4260     conftest_s='
4261         .section .text,"ax",@progbits
4262         .globl  _start
4263         .type   _start, @function
4264 _start:
4265         leal    ld@tlsldm(%ecx), %eax
4266         call    *___tls_get_addr@GOT(%ecx)
4267         leal    gd@tlsgd(%ecx), %eax
4268         call    *___tls_get_addr@GOT(%ecx)
4269
4270         .section .tdata,"aw'$tls_section_flag'",@progbits
4271         .type   ld, @object
4272 ld:
4273         .byte 0
4274         .globl  gd
4275         .type   gd, @object
4276 gd:
4277         .byte 0'
4278     gcc_GAS_CHECK_FEATURE([calling ___tls_get_addr via GOT],
4279         gcc_cv_as_ix86_tls_get_addr_via_got,,
4280         [$as_ix86_gas_32_opt],
4281         [$conftest_s],
4282         [if test x$gcc_cv_ld != x \
4283             && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o > /dev/null 2>&1; then
4284            gcc_cv_as_ix86_tls_get_addr_via_got=yes
4285          fi
4286          rm -f conftest])
4287     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_TLS_GET_ADDR_GOT,
4288       [`if test x"$gcc_cv_as_ix86_tls_get_addr_via_got" = xyes; then echo 1; else echo 0; fi`],
4289       [Define 0/1 if your assembler and linker support calling ___tls_get_addr via GOT.])
4290     ;;
4291
4292   ia64*-*-*)
4293     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
4294         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
4295 [       .text
4296         addl r15 = @ltoffx(x#), gp
4297         ;;
4298         ld8.mov r16 = [[r15]], x#],,
4299     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
4300           [Define if your assembler supports ltoffx and ldxmov relocations.])])
4301
4302     ;;
4303
4304   powerpc*-*-*)
4305
4306     case $target in
4307       *-*-darwin*)
4308         gcc_GAS_CHECK_FEATURE([.machine directive support],
4309           gcc_cv_as_machine_directive,,,
4310           [     .machine ppc7400])
4311         if test x$gcc_cv_as_machine_directive != xyes; then
4312           echo "*** This target requires an assembler supporting \".machine\"" >&2
4313           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
4314           test x$build = x$target && exit 1
4315         fi
4316         ;;
4317     esac
4318
4319     case $target in
4320       *-*-aix*) conftest_s='    .machine "pwr5"
4321         .csect .text[[PR]]
4322         mfcr 3,128';;
4323       *-*-darwin*) conftest_s=' .text
4324         mfcr r3,128';;
4325       *) conftest_s='   .machine power4
4326         .text
4327         mfcr 3,128';;
4328     esac
4329
4330     gcc_GAS_CHECK_FEATURE([mfcr field support],
4331       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
4332       [$conftest_s],,
4333       [AC_DEFINE(HAVE_AS_MFCRF, 1,
4334           [Define if your assembler supports mfcr field.])])
4335
4336     case $target in
4337       *-*-aix*) conftest_s='    .machine "pwr5"
4338         .csect .text[[PR]]
4339         popcntb 3,3';;
4340       *) conftest_s='   .machine power5
4341         .text
4342         popcntb 3,3';;
4343     esac
4344
4345     gcc_GAS_CHECK_FEATURE([popcntb support],
4346       gcc_cv_as_powerpc_popcntb, [2,17,0],,
4347       [$conftest_s],,
4348       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
4349           [Define if your assembler supports popcntb field.])])
4350
4351     case $target in
4352       *-*-aix*) conftest_s='    .machine "pwr5x"
4353         .csect .text[[PR]]
4354         frin 1,1';;
4355       *) conftest_s='   .machine power5
4356         .text
4357         frin 1,1';;
4358     esac
4359
4360     gcc_GAS_CHECK_FEATURE([fp round support],
4361       gcc_cv_as_powerpc_fprnd, [2,17,0],,
4362       [$conftest_s],,
4363       [AC_DEFINE(HAVE_AS_FPRND, 1,
4364           [Define if your assembler supports fprnd.])])
4365
4366     case $target in
4367       *-*-aix*) conftest_s='    .machine "pwr6"
4368         .csect .text[[PR]]
4369         mffgpr 1,3';;
4370       *) conftest_s='   .machine power6
4371         .text
4372         mffgpr 1,3';;
4373     esac
4374
4375     gcc_GAS_CHECK_FEATURE([move fp gpr support],
4376       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
4377       [$conftest_s],,
4378       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
4379           [Define if your assembler supports mffgpr and mftgpr.])])
4380
4381     case $target in
4382       *-*-aix*) conftest_s='    .csect .text[[PR]]
4383 LCF..0:
4384         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
4385       *-*-darwin*)
4386         conftest_s='    .text
4387 LCF0:
4388         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
4389       *) conftest_s='   .text
4390 .LCF0:
4391         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
4392     esac
4393
4394     gcc_GAS_CHECK_FEATURE([rel16 relocs],
4395       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
4396       [$conftest_s],,
4397       [AC_DEFINE(HAVE_AS_REL16, 1,
4398           [Define if your assembler supports R_PPC_REL16 relocs.])])
4399
4400     case $target in
4401       *-*-aix*) conftest_s='    .machine "pwr6"
4402         .csect .text[[PR]]
4403         cmpb 3,4,5';;
4404       *) conftest_s='   .machine power6
4405         .text
4406         cmpb 3,4,5';;
4407     esac
4408
4409     gcc_GAS_CHECK_FEATURE([compare bytes support],
4410       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
4411       [$conftest_s],,
4412       [AC_DEFINE(HAVE_AS_CMPB, 1,
4413           [Define if your assembler supports cmpb.])])
4414
4415     case $target in
4416       *-*-aix*) conftest_s='    .machine "pwr6"
4417         .csect .text[[PR]]
4418         dadd 1,2,3';;
4419       *) conftest_s='   .machine power6
4420         .text
4421         dadd 1,2,3';;
4422     esac
4423
4424     gcc_GAS_CHECK_FEATURE([decimal float support],
4425       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
4426       [$conftest_s],,
4427       [AC_DEFINE(HAVE_AS_DFP, 1,
4428           [Define if your assembler supports DFP instructions.])])
4429
4430     case $target in
4431       *-*-aix*) conftest_s='    .machine "pwr7"
4432         .csect .text[[PR]]
4433         lxvd2x 1,2,3';;
4434       *) conftest_s='   .machine power7
4435         .text
4436         lxvd2x 1,2,3';;
4437     esac
4438
4439     gcc_GAS_CHECK_FEATURE([vector-scalar support],
4440       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
4441       [$conftest_s],,
4442       [AC_DEFINE(HAVE_AS_VSX, 1,
4443           [Define if your assembler supports VSX instructions.])])
4444
4445     case $target in
4446       *-*-aix*) conftest_s='    .machine "pwr7"
4447         .csect .text[[PR]]
4448         popcntd 3,3';;
4449       *) conftest_s='   .machine power7
4450         .text
4451         popcntd 3,3';;
4452     esac
4453
4454     gcc_GAS_CHECK_FEATURE([popcntd support],
4455       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
4456       [$conftest_s],,
4457       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
4458           [Define if your assembler supports POPCNTD instructions.])])
4459
4460     case $target in
4461       *-*-aix*) conftest_s='    .machine "pwr8"
4462         .csect .text[[PR]]';;
4463       *) conftest_s='   .machine power8
4464         .text';;
4465     esac
4466
4467     gcc_GAS_CHECK_FEATURE([power8 support],
4468       gcc_cv_as_powerpc_power8, [2,19,2], -a32,
4469       [$conftest_s],,
4470       [AC_DEFINE(HAVE_AS_POWER8, 1,
4471           [Define if your assembler supports POWER8 instructions.])])
4472
4473     case $target in
4474       *-*-aix*) conftest_s='    .machine "pwr9"
4475         .csect .text[[PR]]';;
4476       *) conftest_s='   .machine power9
4477         .text';;
4478     esac
4479
4480     gcc_GAS_CHECK_FEATURE([power9 support],
4481       gcc_cv_as_powerpc_power9, [2,19,2], -a32,
4482       [$conftest_s],,
4483       [AC_DEFINE(HAVE_AS_POWER9, 1,
4484           [Define if your assembler supports POWER9 instructions.])])
4485
4486     case $target in
4487       *-*-aix*) conftest_s='    .csect .text[[PR]]
4488         lwsync';;
4489       *) conftest_s='   .text
4490         lwsync';;
4491     esac
4492
4493     gcc_GAS_CHECK_FEATURE([lwsync support],
4494       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
4495       [$conftest_s],,
4496       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
4497           [Define if your assembler supports LWSYNC instructions.])])
4498
4499     case $target in
4500       *-*-aix*) conftest_s='    .machine "476"
4501         .csect .text[[PR]]
4502         dci 0';;
4503       *) conftest_s='   .machine "476"
4504         .text
4505         dci 0';;
4506     esac
4507
4508     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
4509       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
4510       [$conftest_s],,
4511       [AC_DEFINE(HAVE_AS_DCI, 1,
4512           [Define if your assembler supports the DCI/ICI instructions.])])
4513
4514     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
4515       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
4516       [.gnu_attribute 4,1],,
4517       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
4518           [Define if your assembler supports .gnu_attribute.])])
4519
4520     gcc_GAS_CHECK_FEATURE([tls marker support],
4521       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
4522       [ bl __tls_get_addr(x@tlsgd)],,
4523       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
4524           [Define if your assembler supports arg info for __tls_get_addr.])])
4525
4526     gcc_GAS_CHECK_FEATURE([prologue entry point marker support],
4527       gcc_cv_as_powerpc_entry_markers, [2,26,0],-a64 --fatal-warnings,
4528       [ .reloc .,R_PPC64_ENTRY; nop],,
4529       [AC_DEFINE(HAVE_AS_ENTRY_MARKERS, 1,
4530           [Define if your assembler supports the R_PPC64_ENTRY relocation.])])
4531
4532     case $target in
4533       *-*-aix*)
4534         gcc_GAS_CHECK_FEATURE([AIX .ref support],
4535           gcc_cv_as_aix_ref, [2,21,0],,
4536           [     .csect stuff[[rw]]
4537              stuff:
4538                 .long 1
4539                 .extern sym
4540                 .ref sym
4541           ],,
4542           [AC_DEFINE(HAVE_AS_REF, 1,
4543             [Define if your assembler supports .ref])])
4544
4545         gcc_GAS_CHECK_FEATURE([AIX DWARF location lists section support],
4546           gcc_cv_as_aix_dwloc, [2,21,0],,
4547           [     .dwsect 0xA0000
4548         Lframe..0:
4549                 .vbyte 4,Lframe..0
4550           ],,
4551           [AC_DEFINE(HAVE_XCOFF_DWARF_EXTRAS, 1,
4552             [Define if your assembler supports AIX debug frame section label reference.])])
4553         ;;
4554     esac
4555     ;;
4556
4557   mips*-*-*)
4558     gcc_GAS_CHECK_FEATURE([explicit relocation support],
4559       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
4560 [       lw $4,%gp_rel(foo)($4)],,
4561       [if test x$target_cpu_default = x
4562        then target_cpu_default=MASK_EXPLICIT_RELOCS
4563        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
4564        fi])
4565
4566     gcc_GAS_CHECK_FEATURE([-mno-shared support],
4567       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
4568       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
4569                  [Define if the assembler understands -mno-shared.])])
4570
4571     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
4572       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
4573       [.gnu_attribute 4,1],,
4574       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
4575           [Define if your assembler supports .gnu_attribute.])])
4576
4577     gcc_GAS_CHECK_FEATURE([.module support],
4578       gcc_cv_as_mips_dot_module,,[-32],
4579       [.module mips2
4580        .module fp=xx],,
4581       [AC_DEFINE(HAVE_AS_DOT_MODULE, 1,
4582           [Define if your assembler supports .module.])])
4583     if test x$gcc_cv_as_mips_dot_module = xno \
4584        && test x$with_fp_32 != x; then
4585       AC_MSG_ERROR(
4586         [Requesting --with-fp-32= requires assembler support for .module.])
4587     fi
4588
4589     gcc_GAS_CHECK_FEATURE([.micromips support],
4590       gcc_cv_as_micromips_support,,[--fatal-warnings],
4591       [.set micromips],,
4592       [AC_DEFINE(HAVE_GAS_MICROMIPS, 1,
4593           [Define if your assembler supports the .set micromips directive])])
4594
4595     gcc_GAS_CHECK_FEATURE([.dtprelword support],
4596       gcc_cv_as_mips_dtprelword, [2,18,0],,
4597       [.section .tdata,"awT",@progbits
4598 x:
4599         .word 2
4600         .text
4601         .dtprelword x+0x8000],,
4602       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
4603           [Define if your assembler supports .dtprelword.])])
4604
4605     gcc_GAS_CHECK_FEATURE([DSPR1 mult with four accumulators support],
4606       gcc_cv_as_mips_dspr1_mult,,,
4607 [       .set    mips32r2
4608         .set    nodspr2
4609         .set    dsp
4610         madd    $ac3,$4,$5
4611         maddu   $ac3,$4,$5
4612         msub    $ac3,$4,$5
4613         msubu   $ac3,$4,$5
4614         mult    $ac3,$4,$5
4615         multu   $ac3,$4,$5],,
4616       [AC_DEFINE(HAVE_AS_DSPR1_MULT, 1,
4617           [Define if your assembler supports DSPR1 mult.])])
4618
4619     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
4620     gcc_cv_as_ld_jalr_reloc=no
4621     if test $gcc_cv_as_mips_explicit_relocs = yes; then
4622       if test $in_tree_ld = yes ; then
4623         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
4624            && test $in_tree_ld_is_elf = yes; then
4625           gcc_cv_as_ld_jalr_reloc=yes
4626         fi
4627       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
4628         echo '  .ent x' > conftest.s
4629         echo 'x:        lw $2,%got_disp(y)($3)' >> conftest.s
4630         echo '  lw $25,%call16(y)($28)' >> conftest.s
4631         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
4632         echo '1:        jalr $25' >> conftest.s
4633         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
4634         echo '1:        jalr $25' >> conftest.s
4635         echo '  .end x' >> conftest.s
4636         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
4637            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
4638           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
4639              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
4640             gcc_cv_as_ld_jalr_reloc=yes
4641           fi
4642         fi
4643         rm -f conftest.*
4644       fi
4645     fi
4646     if test $gcc_cv_as_ld_jalr_reloc = yes; then
4647       if test x$target_cpu_default = x; then
4648         target_cpu_default=MASK_RELAX_PIC_CALLS
4649       else
4650         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
4651       fi
4652     fi
4653     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
4654
4655     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
4656       [gcc_cv_ld_mips_personality_relaxation],
4657       [gcc_cv_ld_mips_personality_relaxation=no
4658        if test $in_tree_ld = yes ; then
4659          if test "$gcc_cv_gld_major_version" -eq 2 \
4660                  -a "$gcc_cv_gld_minor_version" -ge 21 \
4661                  -o "$gcc_cv_gld_major_version" -gt 2; then
4662            gcc_cv_ld_mips_personality_relaxation=yes
4663          fi
4664        elif test x$gcc_cv_as != x \
4665                  -a x$gcc_cv_ld != x \
4666                  -a x$gcc_cv_readelf != x ; then
4667          cat > conftest.s <<EOF
4668         .cfi_startproc
4669         .cfi_personality 0x80,indirect_ptr
4670         .ent test
4671 test:
4672         nop
4673         .end test
4674         .cfi_endproc
4675
4676         .section .data,"aw",@progbits
4677 indirect_ptr:
4678         .dc.a personality
4679 EOF
4680          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
4681             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
4682            if $gcc_cv_readelf -d conftest 2>&1 \
4683               | grep TEXTREL > /dev/null 2>&1; then
4684              :
4685            elif $gcc_cv_readelf --relocs conftest 2>&1 \
4686                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
4687              :
4688            else
4689              gcc_cv_ld_mips_personality_relaxation=yes
4690            fi
4691          fi
4692        fi
4693        rm -f conftest.s conftest.o conftest])
4694     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
4695             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
4696       [Define if your linker can relax absolute .eh_frame personality
4697 pointers into PC-relative form.])
4698     fi
4699
4700     gcc_GAS_CHECK_FEATURE([-mnan= support],
4701       gcc_cv_as_mips_nan,,
4702       [-mnan=2008],,,
4703       [AC_DEFINE(HAVE_AS_NAN, 1,
4704                  [Define if the assembler understands -mnan=.])])
4705     if test x$gcc_cv_as_mips_nan = xno \
4706        && test x$with_nan != x; then
4707       AC_MSG_ERROR(
4708         [Requesting --with-nan= requires assembler support for -mnan=])
4709     fi
4710     ;;
4711     s390*-*-*)
4712     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
4713       gcc_cv_as_s390_gnu_attribute, [2,18,0],,
4714       [.gnu_attribute 8,1],,
4715       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
4716           [Define if your assembler supports .gnu_attribute.])])
4717     gcc_GAS_CHECK_FEATURE([.machine and .machinemode support],
4718       gcc_cv_as_s390_machine_machinemode, [2,24,0],,
4719       [ .machinemode push
4720         .machinemode pop
4721         .machine push
4722         .machine pop],,
4723       [AC_DEFINE(HAVE_AS_MACHINE_MACHINEMODE, 1,
4724           [Define if your assembler supports .machine and .machinemode.])])
4725     gcc_GAS_CHECK_FEATURE([architecture modifiers support],
4726       gcc_cv_as_s390_architecture_modifiers, [2,26,0],,
4727       [ .machine z13+vx ],,
4728       [AC_DEFINE(HAVE_AS_ARCHITECTURE_MODIFIERS, 1,
4729           [Define if your assembler supports architecture modifiers.])])
4730     ;;
4731 esac
4732
4733 # Mips and HP-UX need the GNU assembler.
4734 # Linux on IA64 might be able to use the Intel assembler.
4735
4736 case "$target" in
4737   mips*-*-* | *-*-hpux* )
4738     if test x$gas_flag = xyes \
4739        || test x"$host" != x"$build" \
4740        || test ! -x "$gcc_cv_as" \
4741        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
4742       :
4743     else
4744       echo "*** This configuration requires the GNU assembler" >&2
4745       exit 1
4746     fi
4747     ;;
4748 esac
4749
4750 # ??? Not all targets support dwarf2 debug_line, even within a version
4751 # of gas.  Moreover, we need to emit a valid instruction to trigger any
4752 # info to the output file.  So, as supported targets are added to gas 2.11,
4753 # add some instruction here to (also) show we expect this might work.
4754 # ??? Once 2.11 is released, probably need to add first known working
4755 # version to the per-target configury.
4756 case "$cpu_type" in
4757   aarch64 | alpha | arm | avr | bfin | cris | i386 | m32c | m68k | microblaze \
4758   | mips | nios2 | pa | riscv | rs6000 | score | sparc | spu | tilegx \
4759   | tilepro | visium | xstormy16 | xtensa)
4760     insn="nop"
4761     ;;
4762   ia64 | s390)
4763     insn="nop 0"
4764     ;;
4765   mmix)
4766     insn="swym 0"
4767     ;;
4768 esac
4769 if test x"$insn" != x; then
4770  conftest_s="\
4771         .file 1 \"conftest.s\"
4772         .loc 1 3 0
4773         $insn"
4774  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
4775   gcc_cv_as_dwarf2_debug_line,
4776   [elf,2,11,0],, [$conftest_s],
4777   [if test x$gcc_cv_objdump != x \
4778    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
4779       | grep debug_line > /dev/null 2>&1; then
4780      gcc_cv_as_dwarf2_debug_line=yes
4781    fi])
4782
4783 # The .debug_line file table must be in the exact order that
4784 # we specified the files, since these indices are also used
4785 # by DW_AT_decl_file.  Approximate this test by testing if
4786 # the assembler bitches if the same index is assigned twice.
4787  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
4788   gcc_cv_as_dwarf2_file_buggy,,,
4789 [       .file 1 "foo.s"
4790         .file 1 "bar.s"])
4791
4792  if test $gcc_cv_as_dwarf2_debug_line = yes \
4793  && test $gcc_cv_as_dwarf2_file_buggy = no; then
4794         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
4795   [Define if your assembler supports dwarf2 .file/.loc directives,
4796    and preserves file table indices exactly as given.])
4797  fi
4798
4799  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
4800   gcc_cv_as_gdwarf2_flag,
4801   [elf,2,11,0], [--gdwarf2], [$insn],,
4802   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
4803 [Define if your assembler supports the --gdwarf2 option.])])
4804
4805  gcc_GAS_CHECK_FEATURE([--gstabs option],
4806   gcc_cv_as_gstabs_flag,
4807   [elf,2,11,0], [--gstabs], [$insn],,
4808   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
4809 [Define if your assembler supports the --gstabs option.])])
4810
4811  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
4812   gcc_cv_as_debug_prefix_map_flag,
4813   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
4814   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
4815 [Define if your assembler supports the --debug-prefix-map option.])])
4816 fi
4817
4818 gcc_GAS_CHECK_FEATURE([compressed debug sections],
4819   gcc_cv_as_compress_debug,,,,
4820   [# gas compiled without zlib cannot compress debug sections and warns
4821    # about it, but still exits successfully.  So check for this, too.
4822    if $gcc_cv_as --compress-debug-sections -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null
4823    then
4824      gcc_cv_as_compress_debug=0
4825    # Since binutils 2.26, gas supports --compress-debug-sections=type,
4826    # defaulting to the ELF gABI format.
4827    elif $gcc_cv_as --compress-debug-sections=zlib-gnu -o conftest.o conftest.s > /dev/null 2>&1
4828    then
4829      gcc_cv_as_compress_debug=2
4830      gcc_cv_as_compress_debug_option="--compress-debug-sections"
4831      gcc_cv_as_no_compress_debug_option="--nocompress-debug-sections"
4832    # Before binutils 2.26, gas only supported --compress-debug-options and
4833    # emitted the traditional GNU format.
4834    elif $gcc_cv_as --compress-debug-sections -o conftest.o conftest.s > /dev/null 2>&1
4835    then
4836      gcc_cv_as_compress_debug=1
4837      gcc_cv_as_compress_debug_option="--compress-debug-sections"
4838      gcc_cv_as_no_compress_debug_option="--nocompress-debug-sections"
4839    else
4840      gcc_cv_as_compress_debug=0
4841    fi])
4842 AC_DEFINE_UNQUOTED(HAVE_AS_COMPRESS_DEBUG, $gcc_cv_as_compress_debug,
4843 [Define to the level of your assembler's compressed debug section support.])
4844 AC_DEFINE_UNQUOTED(AS_COMPRESS_DEBUG_OPTION, "$gcc_cv_as_compress_debug_option",
4845 [Define to the assembler option to enable compressed debug sections.])
4846 AC_DEFINE_UNQUOTED(AS_NO_COMPRESS_DEBUG_OPTION, "$gcc_cv_as_no_compress_debug_option",
4847 [Define to the assembler option to disable compressed debug sections.])
4848
4849 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
4850  ,,
4851 [.lcomm bar,4,16],,
4852 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
4853   [Define if your assembler supports .lcomm with an alignment field.])])
4854
4855 if test x$with_sysroot = x && test x$host = x$target \
4856    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
4857    && test "$prefix" != "NONE"; then
4858   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
4859 [Define to PREFIX/include if cpp should also search that directory.])
4860 fi
4861
4862 # Determine the version of glibc, if any, used on the target.
4863 AC_MSG_CHECKING([for target glibc version])
4864 AC_ARG_WITH([glibc-version],
4865   [AS_HELP_STRING([--with-glibc-version=M.N],
4866     [assume GCC used with glibc version M.N or later])], [
4867 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
4868   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
4869   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
4870 else
4871   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
4872 fi], [
4873 glibc_version_major=0
4874 glibc_version_minor=0
4875 [if test -f $target_header_dir/features.h \
4876   && glibc_version_major_define=`$EGREP '^[     ]*#[    ]*define[       ]+__GLIBC__[    ]+[0-9]' $target_header_dir/features.h` \
4877   && glibc_version_minor_define=`$EGREP '^[     ]*#[    ]*define[       ]+__GLIBC_MINOR__[      ]+[0-9]' $target_header_dir/features.h`; then
4878   glibc_version_major=`echo "$glibc_version_major_define" | sed -e 's/.*__GLIBC__[      ]*//'`
4879   glibc_version_minor=`echo "$glibc_version_minor_define" | sed -e 's/.*__GLIBC_MINOR__[        ]*//'`
4880 fi]])
4881 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
4882 AC_DEFINE_UNQUOTED([TARGET_GLIBC_MAJOR], [$glibc_version_major],
4883 [GNU C Library major version number used on the target, or 0.])
4884 AC_DEFINE_UNQUOTED([TARGET_GLIBC_MINOR], [$glibc_version_minor],
4885 [GNU C Library minor version number used on the target, or 0.])
4886
4887 AC_ARG_ENABLE(gnu-unique-object,
4888  [AS_HELP_STRING([--enable-gnu-unique-object],
4889    [enable the use of the @gnu_unique_object ELF extension on glibc systems])],
4890  [case $enable_gnu_unique_object in
4891     yes | no) ;;
4892     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
4893 Valid choices are 'yes' and 'no'.]) ;;
4894   esac],
4895  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
4896    [elf,2,19,52],,
4897    [.type foo, '$target_type_format_char'gnu_unique_object],,
4898 # We need to unquote above to to use the definition from config.gcc.
4899 # Also check for ld.so support, i.e. glibc 2.11 or higher.
4900    [GCC_GLIBC_VERSION_GTE_IFELSE([2], [11], [enable_gnu_unique_object=yes], )]
4901    )])
4902 if test x$enable_gnu_unique_object = xyes; then
4903   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
4904    [Define if your assembler supports @gnu_unique_object.])
4905 fi
4906
4907 AC_CACHE_CHECK([assembler for tolerance to line number 0],
4908  [gcc_cv_as_line_zero],
4909  [gcc_cv_as_line_zero=no
4910   if test $in_tree_gas = yes; then
4911     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
4912   elif test "x$gcc_cv_as" != x; then
4913     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
4914     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
4915        test "x`cat conftest.out`" = x
4916     then
4917       gcc_cv_as_line_zero=yes
4918     else
4919       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
4920       cat conftest.s >&AS_MESSAGE_LOG_FD
4921       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
4922       cat conftest.out >&AS_MESSAGE_LOG_FD
4923     fi
4924     rm -f conftest.o conftest.s conftest.out
4925   fi])
4926 if test "x$gcc_cv_as_line_zero" = xyes; then
4927   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
4928 [Define if the assembler won't complain about a line such as # 0 "" 2.])
4929 fi
4930
4931 AC_MSG_CHECKING(support for thin archives)
4932 thin_archive_support=no
4933 echo 'int main (void) { return 0; }' > conftest.c
4934 if ($AR --version | sed 1q | grep "GNU ar" \
4935     && $CC $CFLAGS -c conftest.c \
4936     && $AR rcT conftest.a conftest.o \
4937     && $CC $CFLAGS $LDFLAGS -o conftest conftest.a) >/dev/null 2>&1; then
4938   thin_archive_support=yes
4939 fi
4940 rm -f conftest.c conftest.o conftest.a conftest
4941 AC_MSG_RESULT($thin_archive_support)
4942 AC_SUBST(thin_archive_support)
4943
4944 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
4945 gcc_cv_ld_eh_frame_hdr=no
4946 if test $in_tree_ld = yes ; then
4947   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
4948      && test $in_tree_ld_is_elf = yes; then
4949     gcc_cv_ld_eh_frame_hdr=yes
4950   fi
4951 elif test x$gcc_cv_ld != x; then
4952   if echo "$ld_ver" | grep GNU > /dev/null; then
4953     # Check if linker supports --eh-frame-hdr option
4954     if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
4955       gcc_cv_ld_eh_frame_hdr=yes
4956     fi
4957   else
4958     case "$target" in
4959       *-*-solaris2*)
4960         # Sun ld has various bugs in .eh_frame_hdr support before version 1.2251.
4961         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2251; then
4962           gcc_cv_ld_eh_frame_hdr=yes
4963         fi
4964         ;;
4965     esac
4966   fi
4967 fi
4968 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
4969 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
4970         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
4971 [Define if your linker supports .eh_frame_hdr.])
4972 fi
4973 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
4974
4975 AC_MSG_CHECKING(linker CIEv3 in .eh_frame support)
4976 gcc_cv_ld_eh_frame_ciev3=no
4977 if test $in_tree_ld = yes ; then
4978   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
4979      && test $in_tree_ld_is_elf = yes; then
4980     gcc_cv_ld_eh_frame_ciev3=yes
4981   fi
4982 elif test x$gcc_cv_ld != x; then
4983   if echo "$ld_ver" | grep GNU > /dev/null; then
4984     gcc_cv_ld_eh_frame_ciev3=yes
4985     if test 0"$ld_date" -lt 20040513; then
4986       if test -n "$ld_date"; then
4987         # If there was date string, but was earlier than 2004-05-13, fail
4988         gcc_cv_ld_eh_frame_ciev3=no
4989       elif test "$ld_vers_major" -lt 2; then
4990         gcc_cv_ld_eh_frame_ciev3=no
4991       elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
4992         gcc_cv_ld_eh_frame_ciev3=no
4993       fi
4994     fi
4995   else
4996     case "$target" in
4997       *-*-solaris2*)
4998         # Sun ld added support for CIE v3 in .eh_frame in Solaris 11.1.
4999         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2324; then
5000           gcc_cv_ld_eh_frame_ciev3=yes
5001         fi
5002         ;;
5003     esac
5004   fi
5005 fi
5006 AC_DEFINE_UNQUOTED(HAVE_LD_EH_FRAME_CIEV3,
5007   [`if test x"$gcc_cv_ld_eh_frame_ciev3" = xyes; then echo 1; else echo 0; fi`],
5008   [Define 0/1 if your linker supports CIE v3 in .eh_frame.])
5009 AC_MSG_RESULT($gcc_cv_ld_eh_frame_ciev3)
5010
5011 AC_MSG_CHECKING(linker position independent executable support)
5012 gcc_cv_ld_pie=no
5013 if test $in_tree_ld = yes ; then
5014   case "$target" in
5015     # Full PIE support on Solaris was only introduced in gld 2.26.
5016     *-*-solaris2*)  gcc_gld_pie_min_version=26 ;;
5017     *)              gcc_gld_pie_min_version=15 ;;
5018   esac
5019   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge "$gcc_gld_pie_min_version" -o "$gcc_cv_gld_major_version" -gt 2 \
5020      && test $in_tree_ld_is_elf = yes; then
5021     gcc_cv_ld_pie=yes
5022   fi
5023 elif test x$gcc_cv_ld != x; then
5024   # Check if linker supports -pie option
5025   if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
5026     gcc_cv_ld_pie=yes
5027     case "$target" in
5028       *-*-solaris2*)
5029         if echo "$ld_ver" | grep GNU > /dev/null \
5030           && test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 26; then
5031           gcc_cv_ld_pie=no
5032         fi
5033         ;;
5034     esac
5035   else
5036     case "$target" in
5037       *-*-solaris2.1[[1-9]]*)
5038         # Solaris 11.x and Solaris 12 added PIE support.
5039         if $gcc_cv_ld -z help 2>&1 | grep -- type.*pie > /dev/null; then
5040           gcc_cv_ld_pie=yes
5041         fi
5042         ;;
5043     esac
5044   fi
5045 fi
5046 if test x"$gcc_cv_ld_pie" = xyes; then
5047         AC_DEFINE(HAVE_LD_PIE, 1,
5048 [Define if your linker supports PIE option.])
5049 fi
5050 AC_MSG_RESULT($gcc_cv_ld_pie)
5051
5052 AC_MSG_CHECKING(linker PIE support with copy reloc)
5053 gcc_cv_ld_pie_copyreloc=no
5054 if test $gcc_cv_ld_pie = yes ; then
5055   if test $in_tree_ld = yes ; then
5056     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 25 -o "$gcc_cv_gld_major_version" -gt 2; then
5057       gcc_cv_ld_pie_copyreloc=yes
5058     fi
5059   elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
5060     # Check if linker supports -pie option with copy reloc
5061     case "$target" in
5062     i?86-*-linux* | x86_64-*-linux*)
5063       cat > conftest1.s <<EOF
5064         .globl  a_glob
5065         .data
5066         .type   a_glob, @object
5067         .size   a_glob, 4
5068 a_glob:
5069         .long   2
5070 EOF
5071       cat > conftest2.s <<EOF
5072         .text
5073         .globl  main
5074         .type   main, @function
5075 main:
5076         movl    %eax, a_glob(%rip)
5077         .size   main, .-main
5078         .globl  ptr
5079         .section        .data.rel,"aw",@progbits
5080         .type   ptr, @object
5081 ptr:
5082         .quad   a_glob
5083 EOF
5084       if $gcc_cv_as --64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
5085          && $gcc_cv_ld -shared -melf_x86_64 -o conftest1.so conftest1.o > /dev/null 2>&1 \
5086          && $gcc_cv_as --64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
5087          && $gcc_cv_ld -pie -melf_x86_64 -o conftest conftest2.o conftest1.so > /dev/null 2>&1; then
5088         gcc_cv_ld_pie_copyreloc=yes
5089       fi
5090       rm -f conftest conftest1.so conftest1.o conftest2.o conftest1.s conftest2.s
5091       ;;
5092     esac
5093   fi
5094 fi
5095 AC_DEFINE_UNQUOTED(HAVE_LD_PIE_COPYRELOC,
5096   [`if test x"$gcc_cv_ld_pie_copyreloc" = xyes; then echo 1; else echo 0; fi`],
5097   [Define 0/1 if your linker supports -pie option with copy reloc.])
5098 AC_MSG_RESULT($gcc_cv_ld_pie_copyreloc)
5099
5100 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
5101 gcc_cv_ld_eh_gc_sections=no
5102 if test $in_tree_ld = yes ; then
5103   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
5104      && test $in_tree_ld_is_elf = yes; then
5105     gcc_cv_ld_eh_gc_sections=yes
5106   fi
5107 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
5108   cat > conftest.s <<EOF
5109         .section        .text
5110 .globl _start
5111         .type _start, @function
5112 _start:
5113         .long foo
5114         .size _start, .-_start
5115         .section        .text.foo,"ax",@progbits
5116         .type foo, @function
5117 foo:
5118         .long 0
5119         .size foo, .-foo
5120         .section        .gcc_except_table.foo,"a",@progbits
5121 .L0:
5122         .long 0
5123         .section        .eh_frame,"a",@progbits
5124         .long .L0
5125 EOF
5126   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
5127     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
5128          | grep "gc-sections option ignored" > /dev/null; then
5129       gcc_cv_ld_eh_gc_sections=no
5130     elif $gcc_cv_objdump -h conftest 2> /dev/null \
5131          | grep gcc_except_table > /dev/null; then
5132       gcc_cv_ld_eh_gc_sections=yes
5133       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
5134       if test x$gcc_cv_as_comdat_group != xyes; then
5135         gcc_cv_ld_eh_gc_sections=no
5136         cat > conftest.s <<EOF
5137         .section        .text
5138 .globl _start
5139         .type _start, @function
5140 _start:
5141         .long foo
5142         .size _start, .-_start
5143         .section        .gnu.linkonce.t.foo,"ax",@progbits
5144         .type foo, @function
5145 foo:
5146         .long 0
5147         .size foo, .-foo
5148         .section        .gcc_except_table.foo,"a",@progbits
5149 .L0:
5150         .long 0
5151         .section        .eh_frame,"a",@progbits
5152         .long .L0
5153 EOF
5154         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
5155           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
5156                | grep "gc-sections option ignored" > /dev/null; then
5157             gcc_cv_ld_eh_gc_sections=no
5158           elif $gcc_cv_objdump -h conftest 2> /dev/null \
5159                | grep gcc_except_table > /dev/null; then
5160             gcc_cv_ld_eh_gc_sections=yes
5161           fi
5162         fi
5163       fi
5164     fi
5165   fi
5166   rm -f conftest.s conftest.o conftest
5167 fi
5168 case "$target" in
5169   hppa*-*-linux*)
5170     # ??? This apparently exposes a binutils bug with PC-relative relocations.
5171     gcc_cv_ld_eh_gc_sections=no
5172     ;;
5173 esac
5174 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
5175         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
5176   [Define if your linker supports garbage collection of
5177    sections in presence of EH frames.])
5178 fi
5179 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
5180
5181 AC_MSG_CHECKING(linker EH garbage collection of sections bug)
5182 gcc_cv_ld_eh_gc_sections_bug=no
5183 if test $in_tree_ld = yes ; then
5184   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -lt 19 -o "$gcc_cv_gld_major_version" -lt 2 \
5185      && test $in_tree_ld_is_elf = yes; then
5186     gcc_cv_ld_eh_gc_sections_bug=yes
5187   fi
5188 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x -a x$gcc_cv_as_comdat_group = xyes; then
5189   gcc_cv_ld_eh_gc_sections_bug=yes
5190   cat > conftest.s <<EOF
5191         .section        .text
5192 .globl _start
5193         .type _start, @function
5194 _start:
5195         .long foo
5196         .size _start, .-_start
5197         .section        .text.startup.foo,"ax",@progbits
5198         .type foo, @function
5199 foo:
5200         .long 0
5201         .size foo, .-foo
5202         .section        .gcc_except_table.foo,"a",@progbits
5203 .L0:
5204         .long 0
5205         .section        .eh_frame,"a",@progbits
5206         .long .L0
5207 EOF
5208   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
5209     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
5210          | grep "gc-sections option ignored" > /dev/null; then
5211       :
5212     elif $gcc_cv_objdump -h conftest 2> /dev/null \
5213          | grep gcc_except_table > /dev/null; then
5214       gcc_cv_ld_eh_gc_sections_bug=no
5215     fi
5216   fi
5217   rm -f conftest.s conftest.o conftest
5218 fi
5219 if test x$gcc_cv_ld_eh_gc_sections_bug = xyes; then
5220         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS_BUG, 1,
5221   [Define if your linker has buggy garbage collection of
5222    sections support when .text.startup.foo like sections are used.])
5223 fi
5224 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections_bug)
5225
5226 AC_MSG_CHECKING(linker for compressed debug sections)
5227 # gold/gld support compressed debug sections since binutils 2.19/2.21
5228 # In binutils 2.26, gld gained support for the ELF gABI format.
5229 if test $in_tree_ld = yes ; then
5230   gcc_cv_ld_compress_debug=0
5231   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 19 -o "$gcc_cv_gld_major_version" -gt 2 \
5232      && test $in_tree_ld_is_elf = yes && test $ld_is_gold = yes; then
5233     gcc_cv_ld_compress_debug=2
5234     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
5235   elif test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 26 -o "$gcc_cv_gld_major_version" -gt 2 \
5236      && test $in_tree_ld_is_elf = yes && test $ld_is_gold = no; then
5237     gcc_cv_ld_compress_debug=3
5238     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
5239   elif test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2 \
5240      && test $in_tree_ld_is_elf = yes; then
5241     gcc_cv_ld_compress_debug=1
5242   fi
5243 elif echo "$ld_ver" | grep GNU > /dev/null; then
5244   if test "$ld_vers_major" -lt 2 \
5245      || test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 21; then
5246     gcc_cv_ld_compress_debug=0
5247   elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 26; then
5248     gcc_cv_ld_compress_debug=1
5249   else
5250     gcc_cv_ld_compress_debug=3
5251     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
5252   fi
5253   if test $ld_is_gold = yes; then
5254     gcc_cv_ld_compress_debug=2
5255     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
5256   fi
5257 else
5258 changequote(,)dnl
5259   case "${target}" in
5260     *-*-solaris2*)
5261       # Introduced in Solaris 11.2.
5262       if $gcc_cv_ld --help 2>&1 | grep -- '-z compress-sections' > /dev/null; then
5263         gcc_cv_ld_compress_debug=3
5264         gcc_cv_ld_compress_debug_option="-z compress-sections"
5265       else
5266         gcc_cv_ld_compress_debug=0
5267       fi
5268       ;;
5269     *)
5270       # Assume linkers other than GNU ld don't support compessed debug
5271       # sections.
5272       gcc_cv_ld_compress_debug=0
5273       ;;
5274   esac
5275 changequote([,])dnl
5276 fi
5277 AC_DEFINE_UNQUOTED(HAVE_LD_COMPRESS_DEBUG, $gcc_cv_ld_compress_debug,
5278 [Define to the level of your linker's compressed debug section support.])
5279 AC_DEFINE_UNQUOTED(LD_COMPRESS_DEBUG_OPTION, "$gcc_cv_ld_compress_debug_option",
5280 [Define to the linker option to enable compressed debug sections.])
5281 AC_MSG_RESULT($gcc_cv_ld_compress_debug)
5282
5283 if test x"$ld64_flag" = x"yes"; then
5284
5285   # Set defaults for possibly untestable items.
5286   gcc_cv_ld64_export_dynamic=0
5287
5288   if test "$build" = "$host"; then
5289     darwin_try_test=1
5290   else
5291     darwin_try_test=0
5292   fi
5293
5294   # On Darwin, because of FAT library support, it is often possible to execute
5295   # exes from compatible archs even when the host differs from the build system.
5296   case "$build","$host" in
5297     x86_64-*-darwin*,i?86-*-darwin* | powerpc64*-*-darwin*,powerpc*-*-darwin*)
5298         darwin_try_test=1;;
5299     *) ;;
5300   esac
5301
5302   # If the configurer specified a minimum ld64 version to be supported, then use
5303   # that to determine feature support.
5304   if test x"${gcc_cv_ld64_version}" != x; then
5305     AC_MSG_CHECKING(ld64 specified version)
5306     gcc_cv_ld64_major=`echo "$gcc_cv_ld64_version" | sed -e 's/\..*//'`
5307     AC_MSG_RESULT($gcc_cv_ld64_major)
5308    if test "$gcc_cv_ld64_major" -ge 236; then
5309       gcc_cv_ld64_export_dynamic=1
5310     fi
5311   elif test -x "$gcc_cv_ld" -a "$darwin_try_test" -eq 1; then
5312     # If the version was not specified, try to find it.
5313     AC_MSG_CHECKING(linker version)
5314     if test x"${gcc_cv_ld64_version}" = x; then
5315       gcc_cv_ld64_version=`$gcc_cv_ld -v 2>&1 | grep ld64 | sed s/.*ld64-// | awk '{print $1}'`
5316     fi
5317     AC_MSG_RESULT($gcc_cv_ld64_version)
5318
5319     AC_MSG_CHECKING(linker for -export_dynamic support)
5320     gcc_cv_ld64_export_dynamic=1
5321     if $gcc_cv_ld -export_dynamic < /dev/null 2>&1 | grep 'unknown option' > /dev/null; then
5322       gcc_cv_ld64_export_dynamic=0
5323     fi
5324     AC_MSG_RESULT($gcc_cv_ld64_export_dynamic)
5325   fi
5326
5327   if test x"${gcc_cv_ld64_version}" != x; then
5328     AC_DEFINE_UNQUOTED(LD64_VERSION, "${gcc_cv_ld64_version}",
5329       [Define to ld64 version.])
5330   fi
5331
5332   AC_DEFINE_UNQUOTED(LD64_HAS_EXPORT_DYNAMIC, $gcc_cv_ld64_export_dynamic,
5333   [Define to 1 if ld64 supports '-export_dynamic'.])
5334 fi
5335
5336 # --------
5337 # UNSORTED
5338 # --------
5339
5340 AC_CACHE_CHECK(linker --as-needed support,
5341 gcc_cv_ld_as_needed,
5342 [gcc_cv_ld_as_needed=no
5343 gcc_cv_ld_as_needed_option='--as-needed'
5344 gcc_cv_ld_no_as_needed_option='--no-as-needed'
5345 if test $in_tree_ld = yes ; then
5346   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
5347      && test $in_tree_ld_is_elf = yes; then
5348     gcc_cv_ld_as_needed=yes
5349   fi
5350 elif test x$gcc_cv_ld != x; then
5351         # Check if linker supports --as-needed and --no-as-needed options
5352         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
5353                 gcc_cv_ld_as_needed=yes
5354         else
5355           case "$target" in
5356             # Solaris 2 ld always supports -z ignore/-z record.
5357             *-*-solaris2*)
5358               gcc_cv_ld_as_needed=yes
5359               gcc_cv_ld_as_needed_option="-z ignore"
5360               gcc_cv_ld_no_as_needed_option="-z record"
5361               ;;
5362           esac
5363         fi
5364 fi
5365 # --as-needed/-z ignore can only be used if libgcc_s.so.1 uses
5366 # dl_iterate_phdr, i.e. since Solaris 11.
5367 case "$target" in
5368   *-*-solaris2.1[[1-9]]*)
5369     case "$target" in
5370     i?86-*-* | x86_64-*-*)
5371       if echo "$ld_ver" | grep GNU > /dev/null; then
5372         # Doesn't work with gld on Solaris/x86 due to PR ld/12320.
5373         gcc_cv_ld_as_needed=no
5374       fi
5375       ;;
5376     esac
5377     ;;
5378   *-*-solaris2*)
5379     gcc_cv_ld_as_needed=no
5380     ;;
5381 esac
5382 ])
5383 if test x"$gcc_cv_ld_as_needed" = xyes; then
5384         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
5385 [Define if your linker supports --as-needed/--no-as-needed or equivalent options.])
5386         AC_DEFINE_UNQUOTED(LD_AS_NEEDED_OPTION, "$gcc_cv_ld_as_needed_option",
5387 [Define to the linker option to ignore unused dependencies.])
5388         AC_DEFINE_UNQUOTED(LD_NO_AS_NEEDED_OPTION, "$gcc_cv_ld_no_as_needed_option",
5389 [Define to the linker option to keep unused dependencies.])
5390 fi
5391
5392 AC_MSG_CHECKING(linker mapfile support for clearing hardware capabilities)
5393 saved_LDFLAGS="$LDFLAGS"
5394 for clearcap_map in sol2-clearcapv2.map sol2-clearcap.map; do
5395   LDFLAGS="$saved_LDFLAGS -Wl,-M,${srcdir}/config/$clearcap_map"
5396   AC_LINK_IFELSE([int main(void) {return 0;}],
5397     [gcc_cv_ld_clearcap=yes; break], [gcc_cv_ld_clearcap=no])
5398 done
5399 LDFLAGS="$saved_LDFLAGS"
5400 if test "x$gcc_cv_ld_clearcap" = xyes; then
5401   AC_DEFINE([HAVE_LD_CLEARCAP], 1,
5402 [Define if the linker supports clearing hardware capabilities via mapfile.])
5403   AC_CONFIG_LINKS([clearcap.map:${srcdir}/config/$clearcap_map])
5404 fi
5405 AC_MSG_RESULT($gcc_cv_ld_clearcap)
5406
5407 case "$target" in
5408   powerpc*-*-*)
5409     case "$target" in
5410       *le-*-linux*)
5411         emul_name="-melf32lppc"
5412         ;;
5413       *)
5414         emul_name="-melf32ppc"
5415         ;;
5416     esac
5417     AC_CACHE_CHECK(linker .gnu.attributes long double support,
5418     gcc_cv_ld_ppc_attr,
5419     [gcc_cv_ld_ppc_attr=no
5420     if test x"$ld_is_gold" = xyes; then
5421       gcc_cv_ld_ppc_attr=yes
5422     elif test $in_tree_ld = yes ; then
5423       if test "$gcc_cv_gld_major_version" -eq 2 \
5424                 -a "$gcc_cv_gld_minor_version" -ge 28 \
5425                 -o "$gcc_cv_gld_major_version" -gt 2; then
5426         gcc_cv_ld_ppc_attr=yes
5427       fi
5428     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
5429       # check that merging the long double .gnu_attribute doesn't warn
5430       cat > conftest1.s <<EOF
5431         .gnu_attribute 4,1
5432 EOF
5433       cat > conftest2.s <<EOF
5434         .gnu_attribute 4,9
5435 EOF
5436       if $gcc_cv_as -a32 -o conftest1.o conftest1.s > /dev/null 2>&1 \
5437          && $gcc_cv_as -a32 -o conftest2.o conftest2.s > /dev/null 2>&1 \
5438          && $gcc_cv_ld $emul_name -r -o conftest.o conftest1.o conftest2.o > /dev/null 2> conftest.err \
5439          && test ! -s conftest.err; then
5440         gcc_cv_ld_ppc_attr=yes
5441       fi
5442       rm -f conftest.err conftest.o conftest1.o conftest2.o conftest1.s conftest2.s
5443     fi
5444     ])
5445     if test x$gcc_cv_ld_ppc_attr = xyes; then
5446       AC_DEFINE(HAVE_LD_PPC_GNU_ATTR_LONG_DOUBLE, 1,
5447     [Define if your PowerPC linker has .gnu.attributes long double support.])
5448     fi
5449     ;;
5450 esac
5451
5452 case "$target:$tm_file" in
5453   powerpc64-*-freebsd* | powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
5454   case "$target" in
5455      *le-*-linux*)
5456      emul_name="-melf64lppc"
5457       ;;
5458      *-*-linux*)
5459      emul_name="-melf64ppc"
5460       ;;
5461      *-*-freebsd*)
5462      emul_name="-melf64ppc_fbsd"
5463       ;;
5464   esac
5465     AC_CACHE_CHECK(linker support for omitting dot symbols,
5466     gcc_cv_ld_no_dot_syms,
5467     [gcc_cv_ld_no_dot_syms=no
5468     if test x"$ld_is_gold" = xyes; then
5469       gcc_cv_ld_no_dot_syms=yes
5470     elif test $in_tree_ld = yes ; then
5471       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
5472         gcc_cv_ld_no_dot_syms=yes
5473       fi
5474     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
5475       cat > conftest1.s <<EOF
5476         .text
5477         bl .foo
5478 EOF
5479       cat > conftest2.s <<EOF
5480         .section ".opd","aw"
5481         .align 3
5482         .globl foo
5483         .type foo,@function
5484 foo:
5485         .quad .LEfoo,.TOC.@tocbase,0
5486         .text
5487 .LEfoo:
5488         blr
5489         .size foo,.-.LEfoo
5490 EOF
5491       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
5492          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
5493          && $gcc_cv_ld $emul_name -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
5494         gcc_cv_ld_no_dot_syms=yes
5495       fi
5496       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
5497     fi
5498     ])
5499     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
5500       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
5501     [Define if your PowerPC64 linker only needs function descriptor syms.])
5502     fi
5503
5504     AC_CACHE_CHECK(linker large toc support,
5505     gcc_cv_ld_large_toc,
5506     [gcc_cv_ld_large_toc=no
5507     if test x"$ld_is_gold" = xyes; then
5508       gcc_cv_ld_large_toc=yes
5509     elif test $in_tree_ld = yes ; then
5510       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
5511         gcc_cv_ld_large_toc=yes
5512       fi
5513     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
5514       cat > conftest.s <<EOF
5515         .section ".tbss","awT",@nobits
5516         .align 3
5517 ie0:    .space 8
5518         .global _start
5519         .text
5520 _start:
5521         addis 9,13,ie0@got@tprel@ha
5522         ld 9,ie0@got@tprel@l(9)
5523 EOF
5524       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
5525          && $gcc_cv_ld $emul_name --no-toc-sort -o conftest conftest.o > /dev/null 2>&1; then
5526         gcc_cv_ld_large_toc=yes
5527       fi
5528       rm -f conftest conftest.o conftest.s
5529     fi
5530     ])
5531     if test x"$gcc_cv_ld_large_toc" = xyes; then
5532       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
5533     [Define if your PowerPC64 linker supports a large TOC.])
5534     fi
5535
5536     AC_CACHE_CHECK(linker toc pointer alignment,
5537     gcc_cv_ld_toc_align,
5538     [if test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_nm != x; then
5539       cat > conftest.s <<EOF
5540         .global _start
5541         .text
5542 _start:
5543         addis 9,2,x@got@ha
5544         .section .data.rel.ro,"aw",@progbits
5545         .p2align 16
5546         .space 32768
5547 x:      .quad .TOC.
5548 EOF
5549       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
5550          && $gcc_cv_ld $emul_name -z norelro -o conftest conftest.o > /dev/null 2>&1; then
5551         gcc_cv_ld_toc_align=`$gcc_cv_nm conftest | ${AWK} '/\.TOC\./ { match ($0, "0[[[:xdigit:]]]*", a); print strtonum ("0x" substr(a[[0]], length(a[[0]])-3)) }'`
5552       fi
5553       rm -f conftest conftest.o conftest.s
5554     fi
5555     ])
5556     if test -n "$gcc_cv_ld_toc_align" && test $gcc_cv_ld_toc_align -gt 8; then
5557       AC_DEFINE_UNQUOTED(POWERPC64_TOC_POINTER_ALIGNMENT, $gcc_cv_ld_toc_align,
5558     [Define to .TOC. alignment forced by your linker.])
5559     fi
5560     ;;
5561 esac
5562
5563 case "$target" in
5564   *-*-aix*)
5565     AC_CACHE_CHECK(linker large toc support,
5566     gcc_cv_ld_large_toc,
5567     [gcc_cv_ld_large_toc=no
5568     if test x$gcc_cv_as != x ; then
5569       cat > conftest.s <<EOF
5570         .toc
5571 LC..1:
5572         .tc a[[TC]],a[[RW]]
5573         .extern a[[RW]]
5574         .csect .text[[PR]]
5575 .largetoctest:
5576         addis 9,LC..1@u(2)
5577         ld 3,LC..1@l(9)
5578 EOF
5579       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1; then
5580         gcc_cv_ld_large_toc=yes
5581       fi
5582       rm -f conftest conftest.o conftest.s
5583     fi
5584     ])
5585     if test x"$gcc_cv_ld_large_toc" = xyes; then
5586       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
5587     [Define if your PowerPC64 linker supports a large TOC.])
5588     fi
5589     ;;
5590 esac
5591
5592 AC_CACHE_CHECK(linker --build-id support,
5593   gcc_cv_ld_buildid,
5594   [gcc_cv_ld_buildid=no
5595   if test $in_tree_ld = yes ; then
5596     if test "$gcc_cv_gld_major_version" -eq 2 -a \
5597        "$gcc_cv_gld_minor_version" -ge 18 -o \
5598        "$gcc_cv_gld_major_version" -gt 2 \
5599        && test $in_tree_ld_is_elf = yes; then
5600       gcc_cv_ld_buildid=yes
5601     fi
5602   elif test x$gcc_cv_ld != x; then
5603     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
5604       gcc_cv_ld_buildid=yes
5605     fi
5606   fi])
5607 if test x"$gcc_cv_ld_buildid" = xyes; then
5608   AC_DEFINE(HAVE_LD_BUILDID, 1,
5609   [Define if your linker supports --build-id.])
5610 fi
5611
5612 AC_ARG_ENABLE(linker-build-id,
5613 [AS_HELP_STRING([--enable-linker-build-id],
5614                 [compiler will always pass --build-id to linker])],
5615 [],
5616 enable_linker_build_id=no)
5617
5618 if test x"$enable_linker_build_id" = xyes; then
5619   if test x"$gcc_cv_ld_buildid" = xyes; then
5620     AC_DEFINE(ENABLE_LD_BUILDID, 1,
5621     [Define if gcc should always pass --build-id to linker.])
5622   else
5623     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
5624   fi
5625 fi
5626
5627 # In binutils 2.21, GNU ld gained support for new emulations fully
5628 # supporting the Solaris 2 ABI.  Detect their presence in the linker used.
5629 AC_CACHE_CHECK(linker *_sol2 emulation support,
5630   gcc_cv_ld_sol2_emulation,
5631   [gcc_cv_ld_sol2_emulation=no
5632   if test $in_tree_ld = yes ; then
5633     if test "$gcc_cv_gld_major_version" -eq 2 -a \
5634        "$gcc_cv_gld_minor_version" -ge 21 -o \
5635        "$gcc_cv_gld_major_version" -gt 2 \
5636        && test $in_tree_ld_is_elf = yes; then
5637       gcc_cv_ld_sol2_emulation=yes
5638     fi
5639   elif test x$gcc_cv_ld != x; then
5640     if $gcc_cv_ld -V 2>/dev/null | sed -e '1,/Supported emulations/d;q' | \
5641        grep _sol2 > /dev/null; then
5642       gcc_cv_ld_sol2_emulation=yes
5643     fi
5644   fi])
5645 if test x"$gcc_cv_ld_sol2_emulation" = xyes; then
5646   AC_DEFINE(HAVE_LD_SOL2_EMULATION, 1,
5647   [Define if your linker supports the *_sol2 emulations.])
5648 fi
5649
5650 AC_CACHE_CHECK(linker --sysroot support,
5651   gcc_cv_ld_sysroot,
5652   [gcc_cv_ld_sysroot=no
5653   if test $in_tree_ld = yes ; then
5654       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
5655         gcc_cv_ld_sysroot=yes
5656       fi
5657   elif test x$gcc_cv_ld != x; then
5658     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
5659       gcc_cv_ld_sysroot=yes
5660     fi
5661   fi])
5662 if test x"$gcc_cv_ld_sysroot" = xyes; then
5663   AC_DEFINE(HAVE_LD_SYSROOT, 1,
5664   [Define if your linker supports --sysroot.])
5665 fi
5666
5667 case $target in
5668 *-*-solaris2*)
5669   # Check for system-provided CRTs on Solaris 11.x and Solaris 12.
5670   AC_CACHE_CHECK([system-provided CRTs on Solaris],
5671     gcc_cv_solaris_crts,
5672     [gcc_cv_solaris_crts=no
5673      if test x$host != x$target; then
5674        if test "x$with_sysroot" = xyes; then
5675          target_sysroot="${test_exec_prefix}/${target_noncanonical}/sys-root"
5676        else
5677          target_sysroot="${with_sysroot}"
5678        fi
5679      fi
5680      target_libdir="$target_sysroot/usr/lib"
5681      # At the time they were added, gcrt1.o became a symlink for backwards
5682      # compatibility on x86, while crt1.o was added on sparc, so check for that.
5683      case $target in
5684        i?86-*-solaris2* | x86_64-*-solaris2*)
5685          if test -h "$target_libdir/gcrt1.o"; then gcc_cv_solaris_crts=yes; fi
5686          ;;
5687        sparc*-*-solaris2*)
5688          if test -f "$target_libdir/crt1.o"; then gcc_cv_solaris_crts=yes; fi
5689          ;;
5690      esac])
5691   ;;
5692 esac
5693 if test x$gcc_cv_solaris_crts = xyes; then
5694   AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
5695             [Define if the system-provided CRTs are present on Solaris.])
5696 fi
5697
5698 # Test for stack protector support in target C library.
5699 AC_CACHE_CHECK(__stack_chk_fail in target C library,
5700       gcc_cv_libc_provides_ssp,
5701       [gcc_cv_libc_provides_ssp=no
5702     case "$target" in
5703        *-*-musl*)
5704          # All versions of musl provide stack protector
5705          gcc_cv_libc_provides_ssp=yes;;
5706        *-*-linux* | *-*-kfreebsd*-gnu)
5707       # glibc 2.4 and later provides __stack_chk_fail and
5708       # either __stack_chk_guard, or TLS access to stack guard canary.
5709       GCC_GLIBC_VERSION_GTE_IFELSE([2], [4], [gcc_cv_libc_provides_ssp=yes], [
5710       [if test -f $target_header_dir/features.h \
5711          && $EGREP '^[  ]*#[    ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
5712             $target_header_dir/features.h > /dev/null; then
5713         if $EGREP '^[   ]*#[    ]*define[       ]+__UCLIBC__[   ]+1' \
5714              $target_header_dir/features.h > /dev/null && \
5715              test -f $target_header_dir/bits/uClibc_config.h && \
5716              $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
5717              $target_header_dir/bits/uClibc_config.h > /dev/null; then
5718           gcc_cv_libc_provides_ssp=yes
5719         fi
5720       # all versions of Bionic support stack protector
5721       elif test -f $target_header_dir/sys/cdefs.h \
5722         && $EGREP '^[  ]*#[    ]*define[       ]+__BIONIC__[   ]+1' \
5723            $target_header_dir/sys/cdefs.h > /dev/null; then
5724          gcc_cv_libc_provides_ssp=yes
5725       fi]])
5726         ;;
5727        *-*-gnu*)
5728          # Avoid complicated tests (see
5729          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
5730          # simply assert that glibc does provide this, which is true for all
5731          # realistically usable GNU/Hurd configurations.
5732          # All supported versions of musl provide it as well
5733          gcc_cv_libc_provides_ssp=yes;;
5734        *-*-darwin* | *-*-freebsd* | *-*-netbsd*)
5735          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
5736            [echo "no __stack_chk_fail on this target"])
5737         ;;
5738   *) gcc_cv_libc_provides_ssp=no ;;
5739     esac])
5740
5741 if test x$gcc_cv_libc_provides_ssp = xyes; then
5742   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
5743             [Define if your target C library provides stack protector support])
5744 fi
5745
5746 # Check whether --enable-default-ssp was given.
5747 AC_ARG_ENABLE(default-ssp,
5748 [AS_HELP_STRING([--enable-default-ssp],
5749   [enable Stack Smashing Protection as default])],[
5750 if test x$gcc_cv_libc_provides_ssp = xyes; then
5751   case "$target" in
5752     ia64*-*-*) enable_default_ssp=no ;;
5753     *) enable_default_ssp=$enableval ;;
5754   esac
5755 else
5756   enable_default_ssp=no
5757 fi],
5758 enable_default_ssp=no)
5759 if test x$enable_default_ssp = xyes ; then
5760   AC_DEFINE(ENABLE_DEFAULT_SSP, 1,
5761       [Define if your target supports default stack protector and it is enabled.])
5762 fi
5763 AC_SUBST([enable_default_ssp])
5764
5765 # Test for <sys/sdt.h> on the target.
5766 GCC_TARGET_TEMPLATE([HAVE_SYS_SDT_H])
5767 AC_MSG_CHECKING(sys/sdt.h in the target C library)
5768 have_sys_sdt_h=no
5769 if test -f $target_header_dir/sys/sdt.h; then
5770   have_sys_sdt_h=yes
5771   AC_DEFINE(HAVE_SYS_SDT_H, 1,
5772             [Define if your target C library provides sys/sdt.h])
5773 fi
5774 AC_MSG_RESULT($have_sys_sdt_h)
5775
5776 # Check if TFmode long double should be used by default or not.
5777 # Some glibc targets used DFmode long double, but with glibc 2.4
5778 # and later they can use TFmode.
5779 case "$target" in
5780   powerpc*-*-linux* | \
5781   sparc*-*-linux* | \
5782   s390*-*-linux* | \
5783   alpha*-*-linux*)
5784     AC_ARG_WITH(long-double-128,
5785       [AS_HELP_STRING([--with-long-double-128],
5786                       [use 128-bit long double by default])],
5787       gcc_cv_target_ldbl128="$with_long_double_128",
5788       [GCC_GLIBC_VERSION_GTE_IFELSE([2], [4], [gcc_cv_target_ldbl128=yes], [
5789       [gcc_cv_target_ldbl128=no
5790       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
5791         $target_header_dir/bits/wordsize.h > /dev/null 2>&1 \
5792       && gcc_cv_target_ldbl128=yes
5793       ]])])
5794     ;;
5795 esac
5796 if test x$gcc_cv_target_ldbl128 = xyes; then
5797   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
5798             [Define if TFmode long double should be the default])
5799 fi
5800
5801 # Check if the target LIBC supports exporting the AT_PLATFORM and AT_HWCAP
5802 # values in the TCB.  Currently, only GLIBC 2.23 and later support this.
5803 gcc_cv_libc_provides_hwcap_in_tcb=no
5804 case "$target" in
5805   powerpc*-*-linux*)
5806     GCC_GLIBC_VERSION_GTE_IFELSE([2], [23], [gcc_cv_libc_provides_hwcap_in_tcb=yes], )
5807     ;;
5808 esac
5809 if test x$gcc_cv_libc_provides_hwcap_in_tcb = xyes; then
5810   AC_DEFINE(TARGET_LIBC_PROVIDES_HWCAP_IN_TCB, 1,
5811             [Define if your target C Library provides the AT_HWCAP value in the TCB])
5812 fi
5813
5814 AC_MSG_CHECKING(dl_iterate_phdr in target C library)
5815 gcc_cv_target_dl_iterate_phdr=unknown
5816 case "$target" in
5817   # Restrict to Solaris 11+.  While most of the Solaris 11 linker changes
5818   # were backported to Solaris 10 Update 10, dl_iterate_phdr only lives in
5819   # libdl there, both complicating its use and breaking compatibility
5820   # between Solaris 10 updates.
5821   *-*-solaris2.1[[1-9]]*)
5822     # <link.h> needs both a dl_iterate_phdr declaration and support for
5823     # compilation with largefile support.
5824     if grep dl_iterate_phdr $target_header_dir/link.h > /dev/null 2>&1 \
5825       && grep 'large file capable' $target_header_dir/link.h > /dev/null 2>&1; then
5826       gcc_cv_target_dl_iterate_phdr=yes
5827     else
5828       gcc_cv_target_dl_iterate_phdr=no
5829     fi
5830     ;;
5831   *-*-dragonfly* | *-*-freebsd*)
5832     if grep dl_iterate_phdr $target_header_dir/sys/link_elf.h > /dev/null 2>&1; then
5833       gcc_cv_target_dl_iterate_phdr=yes
5834     else
5835       gcc_cv_target_dl_iterate_phdr=no
5836     fi
5837     ;;
5838   *-linux-musl*)
5839     gcc_cv_target_dl_iterate_phdr=yes
5840     ;;
5841 esac
5842 GCC_TARGET_TEMPLATE([TARGET_DL_ITERATE_PHDR])
5843 if test x$gcc_cv_target_dl_iterate_phdr = xyes; then
5844    AC_DEFINE(TARGET_DL_ITERATE_PHDR, 1,
5845 [Define if your target C library provides the `dl_iterate_phdr' function.])
5846 fi
5847 AC_MSG_RESULT($gcc_cv_target_dl_iterate_phdr)
5848
5849 # We no longer support different GC mechanisms.  Emit an error if
5850 # the user configures with --with-gc.
5851 AC_ARG_WITH(gc,
5852 [AS_HELP_STRING([--with-gc={page,zone}],
5853                 [this option is not supported anymore.  It used to choose
5854                  the garbage collection mechanism to use with the compiler])],
5855 [AC_MSG_ERROR([Configure option --with-gc is only supported up to GCC 4.7.x])],
5856 [])
5857
5858 # Libraries to use on the host.  This will normally be set by the top
5859 # level Makefile.  Here we simply capture the value for our Makefile.
5860 if test -z "${HOST_LIBS+set}"; then
5861   HOST_LIBS=
5862 fi
5863 AC_SUBST(HOST_LIBS)
5864
5865 # Use the system's zlib library.
5866 AM_ZLIB
5867
5868 dnl Very limited version of automake's enable-maintainer-mode
5869
5870 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
5871   dnl maintainer-mode is disabled by default
5872   AC_ARG_ENABLE(maintainer-mode,
5873 [AS_HELP_STRING([--enable-maintainer-mode],
5874                 [enable make rules and dependencies not useful
5875                  (and sometimes confusing) to the casual installer])],
5876       maintainer_mode=$enableval,
5877       maintainer_mode=no)
5878
5879 AC_MSG_RESULT($maintainer_mode)
5880
5881 if test "$maintainer_mode" = "yes"; then
5882   MAINT=''
5883 else
5884   MAINT='#'
5885 fi
5886 AC_SUBST(MAINT)dnl
5887
5888 dnl Whether to prevent multiple front-ends from linking at the same time
5889
5890 AC_MSG_CHECKING([whether to avoid linking multiple front-ends at once])
5891   AC_ARG_ENABLE(link-mutex,
5892 [AS_HELP_STRING([--enable-link-mutex],
5893                 [avoid linking multiple front-ends at once to avoid thrashing
5894                  on the build machine])],
5895       do_link_mutex=$enableval,
5896       do_link_mutex=no)
5897 AC_MSG_RESULT($do_link_mutex)
5898
5899 if test "$do_link_mutex" = "yes"; then
5900    DO_LINK_MUTEX=true
5901 else
5902    DO_LINK_MUTEX=false
5903 fi
5904 AC_SUBST(DO_LINK_MUTEX)
5905
5906 # --------------
5907 # Language hooks
5908 # --------------
5909
5910 # Make empty files to contain the specs and options for each language.
5911 # Then add #include lines to for a compiler that has specs and/or options.
5912
5913 subdirs=
5914 lang_opt_files=
5915 lang_specs_files=
5916 lang_tree_files=
5917 # These (without "all_") are set in each config-lang.in.
5918 # `language' must be a single word so is spelled singularly.
5919 all_languages=
5920 all_compilers=
5921 all_outputs='Makefile'
5922 # List of language makefile fragments.
5923 all_lang_makefrags=
5924 # Additional files for gengtype
5925 all_gtfiles="$target_gtfiles"
5926
5927 # These are the languages that are set in --enable-languages,
5928 # and are available in the GCC tree.
5929 all_selected_languages=
5930
5931 # Add the language fragments.
5932 # Languages are added via two mechanisms.  Some information must be
5933 # recorded in makefile variables, these are defined in config-lang.in.
5934 # We accumulate them and plug them into the main Makefile.
5935 # The other mechanism is a set of hooks for each of the main targets
5936 # like `clean', `install', etc.
5937
5938 language_hooks="Make-hooks"
5939
5940 for lang in ${srcdir}/*/config-lang.in
5941 do
5942 changequote(,)dnl
5943         test "$lang" = "${srcdir}/*/config-lang.in" && continue
5944
5945         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
5946         if test "x$lang_alias" = x
5947         then
5948               echo "$lang doesn't set \$language." 1>&2
5949               exit 1
5950         fi
5951         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
5952         subdirs="$subdirs $subdir"
5953
5954         # $gcc_subdir is where the gcc integration files are to be found
5955         # for a language, both for internal compiler purposes (compiler
5956         # sources implementing front-end to GCC tree converters), and for
5957         # build infrastructure purposes (Make-lang.in, etc.)
5958         #
5959         # This will be <subdir> (relative to $srcdir) if a line like
5960         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
5961         # is found in <langdir>/config-lang.in, and will remain <langdir>
5962         # otherwise.
5963         #
5964         # Except for the language alias (fetched above), the regular
5965         # "config-lang.in" contents are always retrieved from $gcc_subdir,
5966         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
5967         # only this and the language alias.
5968
5969         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
5970         if [ "$gcc_subdir" = "" ]; then
5971            gcc_subdir="$subdir"
5972         fi
5973
5974         case ",$enable_languages," in
5975         *,$lang_alias,*)
5976             all_selected_languages="$all_selected_languages $lang_alias"
5977             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
5978                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
5979             fi
5980             ;;
5981         esac
5982 changequote([,])dnl
5983
5984         language=
5985         boot_language=
5986         compilers=
5987         outputs=
5988         gtfiles=
5989         subdir_requires=
5990         . ${srcdir}/$gcc_subdir/config-lang.in
5991         if test "x$language" = x
5992         then
5993                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
5994                 exit 1
5995         fi
5996
5997         ok=:
5998         case ",$enable_languages," in
5999                 *,$lang_alias,*) ;;
6000                 *)
6001                         for i in $subdir_requires; do
6002                                 test -f "${srcdir}/$i/config-lang.in" && continue
6003                                 ok=false
6004                                 break
6005                         done
6006                 ;;
6007         esac
6008         $ok || continue
6009
6010         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
6011         if test -f $srcdir/$gcc_subdir/lang.opt; then
6012             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
6013             all_opt_files="$all_opt_files $srcdir/$gcc_subdir/lang.opt"
6014         fi
6015         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
6016             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
6017         fi
6018         all_languages="$all_languages $language"
6019         all_compilers="$all_compilers $compilers"
6020         all_outputs="$all_outputs $outputs"
6021         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
6022         case ",$enable_languages," in
6023                 *,lto,*)
6024                     AC_DEFINE(ENABLE_LTO, 1, [Define to enable LTO support.])
6025                     enable_lto=yes
6026                     AC_SUBST(enable_lto)
6027                     ;;
6028                 *) ;;
6029         esac
6030 done
6031
6032 check_languages=
6033 for language in $all_selected_languages
6034 do
6035         check_languages="$check_languages check-$language"
6036 done
6037
6038 # We link each language in with a set of hooks, reached indirectly via
6039 # lang.${target}.  Only do so for selected languages.
6040
6041 rm -f Make-hooks
6042 touch Make-hooks
6043 target_list="all.cross start.encap rest.encap tags \
6044         install-common install-man install-info install-pdf install-html dvi \
6045         pdf html uninstall info man srcextra srcman srcinfo \
6046         mostlyclean clean distclean maintainer-clean install-plugin"
6047
6048 for t in $target_list
6049 do
6050         x=
6051         for lang in $all_selected_languages
6052         do
6053                 x="$x $lang.$t"
6054         done
6055         echo "lang.$t: $x" >> Make-hooks
6056 done
6057
6058 # --------
6059 # Option include files
6060 # --------
6061
6062 ${AWK} -f $srcdir/opt-include.awk $all_opt_files > option-includes.mk
6063 option_includes="option-includes.mk"
6064 AC_SUBST_FILE(option_includes)
6065
6066 # --------
6067 # UNSORTED
6068 # --------
6069
6070 # Create .gdbinit.
6071
6072 echo "dir ." > .gdbinit
6073 echo "dir ${srcdir}" >> .gdbinit
6074 if test x$gdb_needs_out_file_path = xyes
6075 then
6076         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
6077 fi
6078 if test "x$subdirs" != x; then
6079         for s in $subdirs
6080         do
6081                 echo "dir ${srcdir}/$s" >> .gdbinit
6082         done
6083 fi
6084 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
6085 echo "python import sys; sys.path.append('${srcdir}'); import gdbhooks" >> .gdbinit
6086
6087 # Put a breakpoint on __asan_report_error to help with debugging buffer
6088 # overflow.
6089 case "$CFLAGS" in
6090 *-fsanitize=address*)
6091   echo "source ${srcdir}/gdbasan.in" >> .gdbinit
6092   ;;
6093 esac
6094
6095 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
6096 AC_SUBST(gcc_tooldir)
6097 AC_SUBST(dollar)
6098
6099 # Find a directory in which to install a shared libgcc.
6100
6101 AC_ARG_ENABLE(version-specific-runtime-libs,
6102 [AS_HELP_STRING([--enable-version-specific-runtime-libs],
6103                 [specify that runtime libraries should be
6104                  installed in a compiler-specific directory])])
6105
6106 # Substitute configuration variables
6107 AC_SUBST(subdirs)
6108 AC_SUBST(srcdir)
6109 AC_SUBST(all_compilers)
6110 AC_SUBST(all_gtfiles)
6111 AC_SUBST(all_lang_makefrags)
6112 AC_SUBST(all_languages)
6113 AC_SUBST(all_selected_languages)
6114 AC_SUBST(build_exeext)
6115 AC_SUBST(build_install_headers_dir)
6116 AC_SUBST(build_xm_file_list)
6117 AC_SUBST(build_xm_include_list)
6118 AC_SUBST(build_xm_defines)
6119 AC_SUBST(build_file_translate)
6120 AC_SUBST(check_languages)
6121 AC_SUBST(cpp_install_dir)
6122 AC_SUBST(xmake_file)
6123 AC_SUBST(tmake_file)
6124 AC_SUBST(TM_ENDIAN_CONFIG)
6125 AC_SUBST(TM_MULTILIB_CONFIG)
6126 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
6127 AC_SUBST(extra_gcc_objs)
6128 AC_SUBST(user_headers_inc_next_pre)
6129 AC_SUBST(user_headers_inc_next_post)
6130 AC_SUBST(extra_headers_list)
6131 AC_SUBST(extra_objs)
6132 AC_SUBST(extra_programs)
6133 AC_SUBST(float_h_file)
6134 AC_SUBST(gcc_config_arguments)
6135 AC_SUBST(gcc_gxx_include_dir)
6136 AC_SUBST(gcc_gxx_include_dir_add_sysroot)
6137 AC_SUBST(host_exeext)
6138 AC_SUBST(host_xm_file_list)
6139 AC_SUBST(host_xm_include_list)
6140 AC_SUBST(host_xm_defines)
6141 AC_SUBST(out_host_hook_obj)
6142 AC_SUBST(install)
6143 AC_SUBST(lang_opt_files)
6144 AC_SUBST(lang_specs_files)
6145 AC_SUBST(lang_tree_files)
6146 AC_SUBST(local_prefix)
6147 AC_SUBST(md_file)
6148 AC_SUBST(objc_boehm_gc)
6149 AC_SUBST(out_file)
6150 AC_SUBST(out_object_file)
6151 AC_SUBST(common_out_file)
6152 AC_SUBST(common_out_object_file)
6153 AC_SUBST(tm_file_list)
6154 AC_SUBST(tm_include_list)
6155 AC_SUBST(tm_defines)
6156 AC_SUBST(tm_p_file_list)
6157 AC_SUBST(tm_p_include_list)
6158 AC_SUBST(xm_file_list)
6159 AC_SUBST(xm_include_list)
6160 AC_SUBST(xm_defines)
6161 AC_SUBST(use_gcc_stdint)
6162 AC_SUBST(c_target_objs)
6163 AC_SUBST(cxx_target_objs)
6164 AC_SUBST(fortran_target_objs)
6165 AC_SUBST(target_cpu_default)
6166
6167 AC_SUBST_FILE(language_hooks)
6168
6169 # Echo link setup.
6170 if test x${build} = x${host} ; then
6171   if test x${host} = x${target} ; then
6172     echo "Links are now set up to build a native compiler for ${target}." 1>&2
6173   else
6174     echo "Links are now set up to build a cross-compiler" 1>&2
6175     echo " from ${host} to ${target}." 1>&2
6176   fi
6177 else
6178   if test x${host} = x${target} ; then
6179     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
6180     echo " for ${target}." 1>&2
6181   else
6182     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
6183     echo " from ${host} to ${target}." 1>&2
6184   fi
6185 fi
6186
6187 AC_ARG_VAR(GMPLIBS,[How to link GMP])
6188 AC_ARG_VAR(GMPINC,[How to find GMP include files])
6189
6190 AC_ARG_VAR(ISLLIBS,[How to link isl])
6191 AC_ARG_VAR(ISLINC,[How to find isl include files])
6192 if test "x${ISLLIBS}" != "x" ; then
6193    AC_DEFINE(HAVE_isl, 1, [Define if isl is in use.])
6194 fi
6195
6196 # Check whether isl_options_set_schedule_serialize_sccs is available;
6197 # it's new in isl 0.15.
6198 if test "x${ISLLIBS}" != "x" ; then
6199   saved_CXXFLAGS="$CXXFLAGS"
6200   CXXFLAGS="$CXXFLAGS $ISLINC $GMPINC"
6201   saved_LIBS="$LIBS"
6202   LIBS="$LIBS $ISLLIBS $GMPLIBS"
6203
6204   AC_MSG_CHECKING([Checking for isl_options_set_schedule_serialize_sccs])
6205   AC_TRY_LINK([#include <isl/schedule.h>],
6206               [isl_options_set_schedule_serialize_sccs (NULL, 0);],
6207               [ac_has_isl_options_set_schedule_serialize_sccs=yes],
6208               [ac_has_isl_options_set_schedule_serialize_sccs=no])
6209   AC_MSG_RESULT($ac_has_isl_options_set_schedule_serialize_sccs)
6210
6211   LIBS="$saved_LIBS"
6212   CXXFLAGS="$saved_CXXFLAGS"
6213
6214   if test x"$ac_has_isl_options_set_schedule_serialize_sccs" = x"yes"; then
6215      AC_DEFINE(HAVE_ISL_OPTIONS_SET_SCHEDULE_SERIALIZE_SCCS, 1,
6216                [Define if isl_options_set_schedule_serialize_sccs exists.])
6217   fi
6218 fi
6219
6220 GCC_ENABLE_PLUGINS
6221 AC_SUBST(pluginlibs)
6222 AC_SUBST(enable_plugin)
6223 if test x"$enable_plugin" = x"yes"; then
6224   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
6225 fi
6226
6227
6228 # Enable --enable-host-shared
6229 AC_ARG_ENABLE(host-shared,
6230 [AS_HELP_STRING([--enable-host-shared],
6231                 [build host code as shared libraries])],
6232 [PICFLAG=-fPIC], [PICFLAG=])
6233 AC_SUBST(enable_host_shared)
6234 AC_SUBST(PICFLAG)
6235
6236
6237 AC_ARG_ENABLE(libquadmath-support,
6238 [AS_HELP_STRING([--disable-libquadmath-support],
6239   [disable libquadmath support for Fortran])],
6240 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
6241 ENABLE_LIBQUADMATH_SUPPORT=yes)
6242 if test "${ENABLE_LIBQUADMATH_SUPPORT}" != "no" ; then
6243   AC_DEFINE(ENABLE_LIBQUADMATH_SUPPORT, 1,
6244             [Define to 1 to enable libquadmath support])
6245 fi
6246
6247
6248 # Specify what hash style to use by default.
6249 AC_ARG_WITH([linker-hash-style],
6250 [AC_HELP_STRING([--with-linker-hash-style={sysv,gnu,both}],
6251                 [specify the linker hash style])],
6252 [case x"$withval" in
6253    xsysv)
6254      LINKER_HASH_STYLE=sysv
6255      ;;
6256    xgnu)
6257      LINKER_HASH_STYLE=gnu
6258      ;;
6259    xboth)
6260      LINKER_HASH_STYLE=both
6261      ;;
6262    *)
6263      AC_MSG_ERROR([$withval is an invalid option to --with-linker-hash-style])
6264      ;;
6265  esac],
6266 [LINKER_HASH_STYLE=''])
6267 if test x"${LINKER_HASH_STYLE}" != x; then
6268   AC_DEFINE_UNQUOTED(LINKER_HASH_STYLE, "$LINKER_HASH_STYLE",
6269                                          [The linker hash style])
6270 fi
6271
6272 # Specify what should be the default of -fdiagnostics-color option.
6273 AC_ARG_WITH([diagnostics-color],
6274 [AC_HELP_STRING([--with-diagnostics-color={never,auto,auto-if-env,always}],
6275                 [specify the default of -fdiagnostics-color option
6276                  auto-if-env stands for -fdiagnostics-color=auto if
6277                  GCC_COLOR environment variable is present and
6278                  -fdiagnostics-color=never otherwise])],
6279 [case x"$withval" in
6280    xnever)
6281      DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_NO
6282      ;;
6283    xauto)
6284      DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_AUTO
6285      ;;
6286    xauto-if-env)
6287      DIAGNOSTICS_COLOR_DEFAULT=-1
6288      ;;
6289    xalways)
6290      DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_YES
6291      ;;
6292    *)
6293      AC_MSG_ERROR([$withval is an invalid option to --with-diagnostics-color])
6294      ;;
6295  esac],
6296 [DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_AUTO])
6297 AC_DEFINE_UNQUOTED(DIAGNOSTICS_COLOR_DEFAULT, $DIAGNOSTICS_COLOR_DEFAULT,
6298                    [The default for -fdiagnostics-color option])
6299
6300 # Generate gcc-driver-name.h containing GCC_DRIVER_NAME for the benefit
6301 # of jit/jit-playback.c.
6302 cat > gcc-driver-name.h <<EOF
6303 #define GCC_DRIVER_NAME "${target_noncanonical}-gcc-${gcc_BASEVER}${exeext}"
6304 EOF
6305
6306 # Check whether --enable-default-pie was given.
6307 AC_ARG_ENABLE(default-pie,
6308 [AS_HELP_STRING([--enable-default-pie],
6309   [enable Position Independent Executable as default])],
6310 enable_default_pie=$enableval,
6311 enable_default_pie=no)
6312 if test x$enable_default_pie = xyes ; then
6313   AC_DEFINE(ENABLE_DEFAULT_PIE, 1,
6314       [Define if your target supports default PIE and it is enabled.])
6315 fi
6316 AC_SUBST([enable_default_pie])
6317
6318 # Check if -fno-PIE works.
6319 AC_CACHE_CHECK([for -fno-PIE option],
6320   [gcc_cv_c_no_fpie],
6321   [saved_CXXFLAGS="$CXXFLAGS"
6322    CXXFLAGS="$CXXFLAGS -fno-PIE"
6323    AC_COMPILE_IFELSE([int main(void) {return 0;}],
6324      [gcc_cv_c_no_fpie=yes],
6325      [gcc_cv_c_no_fpie=no])
6326    CXXFLAGS="$saved_CXXFLAGS"])
6327 if test "$gcc_cv_c_no_fpie" = "yes"; then
6328   NO_PIE_CFLAGS="-fno-PIE"
6329 fi
6330 AC_SUBST([NO_PIE_CFLAGS])
6331
6332 # Check if -no-pie works.
6333 AC_CACHE_CHECK([for -no-pie option],
6334   [gcc_cv_no_pie],
6335   [saved_LDFLAGS="$LDFLAGS"
6336    LDFLAGS="$LDFLAGS -no-pie"
6337    AC_LINK_IFELSE([int main(void) {return 0;}],
6338      [gcc_cv_no_pie=yes],
6339      [gcc_cv_no_pie=no])
6340    LDFLAGS="$saved_LDFLAGS"])
6341 if test "$gcc_cv_no_pie" = "yes"; then
6342   NO_PIE_FLAG="-no-pie"
6343 fi
6344 AC_SUBST([NO_PIE_FLAG])
6345
6346 # Check linker supports '-z bndplt'
6347 ld_bndplt_support=no
6348 AC_MSG_CHECKING(linker -z bndplt option)
6349 if test x"$ld_is_gold" = xno; then
6350   if test $in_tree_ld = yes ; then
6351     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 25 -o "$gcc_cv_gld_major_version" -gt 2; then
6352       ld_bndplt_support=yes
6353     fi
6354   elif test x$gcc_cv_ld != x; then
6355     # Check if linker supports -a bndplt option
6356     if $gcc_cv_ld --help 2>/dev/null | grep -- '-z bndplt' > /dev/null; then
6357       ld_bndplt_support=yes
6358     fi
6359   fi
6360 fi
6361 if test x"$ld_bndplt_support" = xyes; then
6362   AC_DEFINE(HAVE_LD_BNDPLT_SUPPORT, 1,
6363         [Define if your linker supports -z bndplt])
6364 fi
6365 AC_MSG_RESULT($ld_bndplt_support)
6366
6367 # Check linker supports '--push-state'/'--pop-state'
6368 ld_pushpopstate_support=no
6369 AC_MSG_CHECKING(linker --push-state/--pop-state options)
6370 if test x"$ld_is_gold" = xno; then
6371   if test $in_tree_ld = yes ; then
6372     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 25 -o "$gcc_cv_gld_major_version" -gt 2; then
6373       ld_pushpopstate_support=yes
6374     fi
6375   elif test x$gcc_cv_ld != x; then
6376     # Check if linker supports --push-state/--pop-state options
6377     if $gcc_cv_ld --help 2>/dev/null | grep -- '--push-state' > /dev/null; then
6378       ld_pushpopstate_support=yes
6379     fi
6380   fi
6381 fi
6382 if test x"$ld_pushpopstate_support" = xyes; then
6383   AC_DEFINE(HAVE_LD_PUSHPOPSTATE_SUPPORT, 1,
6384         [Define if your linker supports --push-state/--pop-state])
6385 fi
6386 AC_MSG_RESULT($ld_pushpopstate_support)
6387
6388 # Configure the subdirectories
6389 # AC_CONFIG_SUBDIRS($subdirs)
6390
6391 # Create the Makefile
6392 # and configure language subdirectories
6393 AC_CONFIG_FILES($all_outputs)
6394
6395 AC_CONFIG_COMMANDS([default],
6396 [
6397 case ${CONFIG_HEADERS} in
6398   *auto-host.h:config.in*)
6399   echo > cstamp-h ;;
6400 esac
6401 # Make sure all the subdirs exist.
6402 for d in $subdirs doc build common c-family
6403 do
6404     test -d $d || mkdir $d
6405 done
6406 ],
6407 [subdirs='$subdirs'])
6408 AC_OUTPUT
6409