gcc/ada/table.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                T A B L E                                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2016, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This package provides an implementation of dynamically resizable one
  33 --  dimensional arrays. The idea is to mimic the normal Ada semantics for
  34 --  arrays as closely as possible with the one additional capability of
  35 --  dynamically modifying the value of the Last attribute.
  36
  37 --  Note that this interface should remain synchronized with those in
  38 --  GNAT.Table and GNAT.Dynamic_Tables to keep coherency between these
  39 --  three related units.
  40
  41 with Types; use Types;
  42
  43 package Table is
  44    pragma Elaborate_Body;
  45
  46    generic
  47       type Table_Component_Type is private;
  48       type Table_Index_Type     is range <>;
  49
  50       Table_Low_Bound   : Table_Index_Type;
  51       Table_Initial     : Pos;
  52       Table_Increment   : Nat;
  53       Table_Name        : String;
  54       Release_Threshold : Nat := 0;
  55
  56    package Table is
  57
  58       --  Table_Component_Type and Table_Index_Type specify the type of the
  59       --  array, Table_Low_Bound is the lower bound. Table_Index_Type must be
  60       --  an integer type. The effect is roughly to declare:
  61
  62       --    Table : array (Table_Index_Type range Table_Low_Bound .. <>)
  63       --                       of Table_Component_Type;
  64
  65       --    Note: since the upper bound can be one less than the lower
  66       --    bound for an empty array, the table index type must be able
  67       --    to cover this range, e.g. if the lower bound is 1, then the
  68       --    Table_Index_Type should be Natural rather than Positive.
  69
  70       --  Table_Component_Type may be any Ada type, except that controlled
  71       --  types are not supported. Note however that default initialization
  72       --  will NOT occur for array components.
  73
  74       --  The Table_Initial values controls the allocation of the table when
  75       --  it is first allocated, either by default, or by an explicit Init
  76       --  call. The value used is Opt.Table_Factor * Table_Initial.
  77
  78       --  The Table_Increment value controls the amount of increase, if the
  79       --  table has to be increased in size. The value given is a percentage
  80       --  value (e.g. 100 = increase table size by 100%, i.e. double it).
  81
  82       --  The Table_Name parameter is simply use in debug output messages it
  83       --  has no other usage, and is not referenced in non-debugging mode.
  84
  85       --  The Last and Set_Last subprograms provide control over the current
  86       --  logical allocation. They are quite efficient, so they can be used
  87       --  freely (expensive reallocation occurs only at major granularity
  88       --  chunks controlled by the allocation parameters).
  89
  90       --  Note: We do not make the table components aliased, since this would
  91       --  restrict the use of table for discriminated types. If it is necessary
  92       --  to take the access of a table element, use Unrestricted_Access.
  93
  94       --  WARNING: On HPPA, the virtual addressing approach used in this unit
  95       --  is incompatible with the indexing instructions on the HPPA. So when
  96       --  using this unit, compile your application with -mdisable-indexing.
  97
  98       --  WARNING: If the table is reallocated, then the address of all its
  99       --  components will change. So do not capture the address of an element
 100       --  and then use the address later after the table may be reallocated.
 101       --  One tricky case of this is passing an element of the table to a
 102       --  subprogram by reference where the table gets reallocated during
 103       --  the execution of the subprogram. The best rule to follow is never
 104       --  to pass a table element as a parameter except for the case of IN
 105       --  mode parameters with scalar values.
 106
 107       type Table_Type is
 108         array (Table_Index_Type range <>) of Table_Component_Type;
 109
 110       subtype Big_Table_Type is
 111         Table_Type (Table_Low_Bound .. Table_Index_Type'Last);
 112       --  We work with pointers to a bogus array type that is constrained
 113       --  with the maximum possible range bound. This means that the pointer
 114       --  is a thin pointer, which is more efficient. Since subscript checks
 115       --  in any case must be on the logical, rather than physical bounds,
 116       --  safety is not compromised by this approach.
 117
 118       type Table_Ptr is access all Big_Table_Type;
 119       for Table_Ptr'Storage_Size use 0;
 120       --  The table is actually represented as a pointer to allow reallocation
 121
 122       Table : aliased Table_Ptr := null;
 123       --  The table itself. The lower bound is the value of Low_Bound.
 124       --  Logically the upper bound is the current value of Last (although
 125       --  the actual size of the allocated table may be larger than this).
 126       --  The program may only access and modify Table entries in the range
 127       --  First .. Last.
 128
 129       Locked : Boolean := False;
 130       --  Table expansion is permitted only if this switch is set to False. A
 131       --  client may set Locked to True, in which case any attempt to expand
 132       --  the table will cause an assertion failure. Note that while a table
 133       --  is locked, its address in memory remains fixed and unchanging. This
 134       --  feature is used to control table expansion during Gigi processing.
 135       --  Gigi assumes that tables other than the Uint and Ureal tables do
 136       --  not move during processing, which means that they cannot be expanded.
 137       --  The Locked flag is used to enforce this restriction.
 138
 139       procedure Init;
 140       --  This procedure allocates a new table of size Initial (freeing any
 141       --  previously allocated larger table). It is not necessary to call
 142       --  Init when a table is first instantiated (since the instantiation does
 143       --  the same initialization steps). However, it is harmless to do so, and
 144       --  Init is convenient in reestablishing a table for new use.
 145
 146       function Last return Table_Index_Type;
 147       pragma Inline (Last);
 148       --  Returns the current value of the last used entry in the table, which
 149       --  can then be used as a subscript for Table. Note that the only way to
 150       --  modify Last is to call the Set_Last procedure. Last must always be
 151       --  used to determine the logically last entry.
 152
 153       procedure Release;
 154       --  Storage is allocated in chunks according to the values given in the
 155       --  Initial and Increment parameters. If Release_Threshold is 0 or the
 156       --  length of the table does not exceed this threshold then a call to
 157       --  Release releases all storage that is allocated, but is not logically
 158       --  part of the current array value; otherwise the call to Release leaves
 159       --  the current array value plus 0.1% of the current table length free
 160       --  elements located at the end of the table (this parameter facilitates
 161       --  reopening large tables and adding a few elements without allocating a
 162       --  chunk of memory). In both cases current array values are not affected
 163       --  by this call.
 164
 165       procedure Free;
 166       --  Free all allocated memory for the table. A call to init is required
 167       --  before any use of this table after calling Free.
 168
 169       First : constant Table_Index_Type := Table_Low_Bound;
 170       --  Export First as synonym for Low_Bound (parallel with use of Last)
 171
 172       procedure Set_Last (New_Val : Table_Index_Type);
 173       pragma Inline (Set_Last);
 174       --  This procedure sets Last to the indicated value. If necessary the
 175       --  table is reallocated to accommodate the new value (i.e. on return
 176       --  the allocated table has an upper bound of at least Last). If Set_Last
 177       --  reduces the size of the table, then logically entries are removed
 178       --  from the table. If Set_Last increases the size of the table, then
 179       --  new entries are logically added to the table.
 180
 181       procedure Increment_Last;
 182       pragma Inline (Increment_Last);
 183       --  Adds 1 to Last (same as Set_Last (Last + 1)
 184
 185       procedure Decrement_Last;
 186       pragma Inline (Decrement_Last);
 187       --  Subtracts 1 from Last (same as Set_Last (Last - 1)
 188
 189       procedure Append (New_Val : Table_Component_Type);
 190       pragma Inline (Append);
 191       --  Equivalent to:
 192       --    x.Increment_Last;
 193       --    x.Table (x.Last) := New_Val;
 194       --  i.e. the table size is increased by one, and the given new item
 195       --  stored in the newly created table element.
 196
 197       procedure Append_All (New_Vals : Table_Type);
 198       --  Appends all components of New_Vals
 199
 200       procedure Set_Item
 201         (Index : Table_Index_Type;
 202          Item  : Table_Component_Type);
 203       pragma Inline (Set_Item);
 204       --  Put Item in the table at position Index. The table is expanded if
 205       --  current table length is less than Index and in that case Last is set
 206       --  to Index. Item will replace any value already present in the table
 207       --  at this position.
 208
 209       type Saved_Table is private;
 210       --  Type used for Save/Restore subprograms
 211
 212       function Save return Saved_Table;
 213       --  Resets table to empty, but saves old contents of table in returned
 214       --  value, for possible later restoration by a call to Restore.
 215
 216       procedure Restore (T : Saved_Table);
 217       --  Given a Saved_Table value returned by a prior call to Save, restores
 218       --  the table to the state it was in at the time of the Save call.
 219
 220       procedure Tree_Write;
 221       --  Writes out contents of table using Tree_IO
 222
 223       procedure Tree_Read;
 224       --  Initializes table by reading contents previously written with the
 225       --  Tree_Write call (also using Tree_IO).
 226
 227    private
 228
 229       Last_Val : Int;
 230       --  Current value of Last. Note that we declare this in the private part
 231       --  because we don't want the client to modify Last except through one of
 232       --  the official interfaces (since a modification to Last may require a
 233       --  reallocation of the table).
 234
 235       Max : Int;
 236       --  Subscript of the maximum entry in the currently allocated table
 237
 238       type Saved_Table is record
 239          Last_Val : Int;
 240          Max      : Int;
 241          Table    : Table_Ptr;
 242       end record;
 243
 244    end Table;
 245 end Table;