?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
PR rtl-optimization/79386
[official-gcc.git] / gcc / ada / par-prag.adb
blob0046badb39fb338dd4aa1f0cd0f178b37cda767d
1 ------------------------------------------------------------------------------
2 -- --
3 -- GNAT COMPILER COMPONENTS --
4 -- --
5 -- P A R . P R A G --
6 -- --
7 -- B o d y --
8 -- --
9 -- Copyright (C) 1992-2016, Free Software Foundation, Inc. --
10 -- --
11 -- GNAT is free software; you can redistribute it and/or modify it under --
12 -- terms of the GNU General Public License as published by the Free Soft- --
13 -- ware Foundation; either version 3, or (at your option) any later ver- --
14 -- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
15 -- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
16 -- or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License --
17 -- for more details. You should have received a copy of the GNU General --
18 -- Public License distributed with GNAT; see file COPYING3. If not, go to --
19 -- http://www.gnu.org/licenses for a complete copy of the license. --
20 -- --
21 -- GNAT was originally developed by the GNAT team at New York University. --
22 -- Extensive contributions were provided by Ada Core Technologies Inc. --
23 -- --
24 ------------------------------------------------------------------------------
25
26 -- Generally the parser checks the basic syntax of pragmas, but does not
27 -- do specialized syntax checks for individual pragmas, these are deferred
28 -- to semantic analysis time (see unit Sem_Prag). There are some pragmas
29 -- which require recognition and either partial or complete processing
30 -- during parsing, and this unit performs this required processing.
31
32 with Fname.UF; use Fname.UF;
33 with Osint; use Osint;
34 with Rident; use Rident;
35 with Restrict; use Restrict;
36 with Stringt; use Stringt;
37 with Stylesw; use Stylesw;
38 with Uintp; use Uintp;
39 with Uname; use Uname;
40
41 with System.WCh_Con; use System.WCh_Con;
42
43 separate (Par)
44
45 function Prag (Pragma_Node : Node_Id; Semi : Source_Ptr) return Node_Id is
46 Prag_Name : constant Name_Id := Pragma_Name_Unmapped (Pragma_Node);
47 Prag_Id : constant Pragma_Id := Get_Pragma_Id (Prag_Name);
48 Pragma_Sloc : constant Source_Ptr := Sloc (Pragma_Node);
49 Arg_Count : Nat;
50 Arg_Node : Node_Id;
51
52 -----------------------
53 -- Local Subprograms --
54 -----------------------
55
56 procedure Add_List_Pragma_Entry (PT : List_Pragma_Type; Loc : Source_Ptr);
57 -- Make a new entry in the List_Pragmas table if this entry is not already
58 -- in the table (it will always be the last one if there is a duplication
59 -- resulting from the use of Save/Restore_Scan_State).
60
61 function Arg1 return Node_Id;
62 function Arg2 return Node_Id;
63 function Arg3 return Node_Id;
64 -- Obtain specified Pragma_Argument_Association. It is allowable to call
65 -- the routine for the argument one past the last present argument, but
66 -- that is the only case in which a non-present argument can be referenced.
67
68 procedure Check_Arg_Count (Required : Int);
69 -- Check argument count for pragma = Required. If not give error and raise
70 -- Error_Resync.
71
72 procedure Check_Arg_Is_String_Literal (Arg : Node_Id);
73 -- Check the expression of the specified argument to make sure that it
74 -- is a string literal. If not give error and raise Error_Resync.
75
76 procedure Check_Arg_Is_On_Or_Off (Arg : Node_Id);
77 -- Check the expression of the specified argument to make sure that it
78 -- is an identifier which is either ON or OFF, and if not, then issue
79 -- an error message and raise Error_Resync.
80
81 procedure Check_No_Identifier (Arg : Node_Id);
82 -- Checks that the given argument does not have an identifier. If
83 -- an identifier is present, then an error message is issued, and
84 -- Error_Resync is raised.
85
86 procedure Check_Optional_Identifier (Arg : Node_Id; Id : Name_Id);
87 -- Checks if the given argument has an identifier, and if so, requires
88 -- it to match the given identifier name. If there is a non-matching
89 -- identifier, then an error message is given and Error_Resync raised.
90
91 procedure Check_Required_Identifier (Arg : Node_Id; Id : Name_Id);
92 -- Same as Check_Optional_Identifier, except that the name is required
93 -- to be present and to match the given Id value.
94
95 procedure Process_Restrictions_Or_Restriction_Warnings;
96 -- Common processing for Restrictions and Restriction_Warnings pragmas.
97 -- For the most part, restrictions need not be processed at parse time,
98 -- since they only affect semantic processing. This routine handles the
99 -- exceptions as follows
100 --
101 -- No_Obsolescent_Features must be processed at parse time, since there
102 -- are some obsolescent features (e.g. character replacements) which are
103 -- handled at parse time.
104 --
105 -- SPARK must be processed at parse time, since this restriction controls
106 -- whether the scanner recognizes a spark HIDE directive formatted as an
107 -- Ada comment (and generates a Tok_SPARK_Hide token for the directive).
108 --
109 -- No_Dependence must be processed at parse time, since otherwise it gets
110 -- handled too late.
111 --
112 -- Note that we don't need to do full error checking for badly formed cases
113 -- of restrictions, since these will be caught during semantic analysis.
114
115 ---------------------------
116 -- Add_List_Pragma_Entry --
117 ---------------------------
118
119 procedure Add_List_Pragma_Entry (PT : List_Pragma_Type; Loc : Source_Ptr) is
120 begin
121 if List_Pragmas.Last < List_Pragmas.First
122 or else (List_Pragmas.Table (List_Pragmas.Last)) /= ((PT, Loc))
123 then
124 List_Pragmas.Append ((PT, Loc));
125 end if;
126 end Add_List_Pragma_Entry;
127
128 ----------
129 -- Arg1 --
130 ----------
131
132 function Arg1 return Node_Id is
133 begin
134 return First (Pragma_Argument_Associations (Pragma_Node));
135 end Arg1;
136
137 ----------
138 -- Arg2 --
139 ----------
140
141 function Arg2 return Node_Id is
142 begin
143 return Next (Arg1);
144 end Arg2;
145
146 ----------
147 -- Arg3 --
148 ----------
149
150 function Arg3 return Node_Id is
151 begin
152 return Next (Arg2);
153 end Arg3;
154
155 ---------------------
156 -- Check_Arg_Count --
157 ---------------------
158
159 procedure Check_Arg_Count (Required : Int) is
160 begin
161 if Arg_Count /= Required then
162 Error_Msg ("wrong number of arguments for pragma%", Pragma_Sloc);
163 raise Error_Resync;
164 end if;
165 end Check_Arg_Count;
166
167 ----------------------------
168 -- Check_Arg_Is_On_Or_Off --
169 ----------------------------
170
171 procedure Check_Arg_Is_On_Or_Off (Arg : Node_Id) is
172 Argx : constant Node_Id := Expression (Arg);
173
174 begin
175 if Nkind (Expression (Arg)) /= N_Identifier
176 or else not Nam_In (Chars (Argx), Name_On, Name_Off)
177 then
178 Error_Msg_Name_2 := Name_On;
179 Error_Msg_Name_3 := Name_Off;
180
181 Error_Msg ("argument for pragma% must be% or%", Sloc (Argx));
182 raise Error_Resync;
183 end if;
184 end Check_Arg_Is_On_Or_Off;
185
186 ---------------------------------
187 -- Check_Arg_Is_String_Literal --
188 ---------------------------------
189
190 procedure Check_Arg_Is_String_Literal (Arg : Node_Id) is
191 begin
192 if Nkind (Expression (Arg)) /= N_String_Literal then
193 Error_Msg
194 ("argument for pragma% must be string literal",
195 Sloc (Expression (Arg)));
196 raise Error_Resync;
197 end if;
198 end Check_Arg_Is_String_Literal;
199
200 -------------------------
201 -- Check_No_Identifier --
202 -------------------------
203
204 procedure Check_No_Identifier (Arg : Node_Id) is
205 begin
206 if Chars (Arg) /= No_Name then
207 Error_Msg_N ("pragma% does not permit named arguments", Arg);
208 raise Error_Resync;
209 end if;
210 end Check_No_Identifier;
211
212 -------------------------------
213 -- Check_Optional_Identifier --
214 -------------------------------
215
216 procedure Check_Optional_Identifier (Arg : Node_Id; Id : Name_Id) is
217 begin
218 if Present (Arg) and then Chars (Arg) /= No_Name then
219 if Chars (Arg) /= Id then
220 Error_Msg_Name_2 := Id;
221 Error_Msg_N ("pragma% argument expects identifier%", Arg);
222 end if;
223 end if;
224 end Check_Optional_Identifier;
225
226 -------------------------------
227 -- Check_Required_Identifier --
228 -------------------------------
229
230 procedure Check_Required_Identifier (Arg : Node_Id; Id : Name_Id) is
231 begin
232 if Chars (Arg) /= Id then
233 Error_Msg_Name_2 := Id;
234 Error_Msg_N ("pragma% argument must have identifier%", Arg);
235 end if;
236 end Check_Required_Identifier;
237
238 --------------------------------------------------
239 -- Process_Restrictions_Or_Restriction_Warnings --
240 --------------------------------------------------
241
242 procedure Process_Restrictions_Or_Restriction_Warnings is
243 Arg : Node_Id;
244 Id : Name_Id;
245 Expr : Node_Id;
246
247 begin
248 Arg := Arg1;
249 while Present (Arg) loop
250 Id := Chars (Arg);
251 Expr := Expression (Arg);
252
253 if Id = No_Name and then Nkind (Expr) = N_Identifier then
254 case Chars (Expr) is
255 when Name_No_Obsolescent_Features =>
256 Set_Restriction (No_Obsolescent_Features, Pragma_Node);
257 Restriction_Warnings (No_Obsolescent_Features) :=
258 Prag_Id = Pragma_Restriction_Warnings;
259
260 when Name_SPARK
261 | Name_SPARK_05
262 =>
263 Set_Restriction (SPARK_05, Pragma_Node);
264 Restriction_Warnings (SPARK_05) :=
265 Prag_Id = Pragma_Restriction_Warnings;
266
267 when others =>
268 null;
269 end case;
270
271 elsif Id = Name_No_Dependence then
272 Set_Restriction_No_Dependence
273 (Unit => Expr,
274 Warn => Prag_Id = Pragma_Restriction_Warnings
275 or else Treat_Restrictions_As_Warnings);
276 end if;
277
278 Next (Arg);
279 end loop;
280 end Process_Restrictions_Or_Restriction_Warnings;
281
282 -- Start of processing for Prag
283
284 begin
285 Error_Msg_Name_1 := Prag_Name;
286
287 -- Ignore unrecognized pragma. We let Sem post the warning for this, since
288 -- it is a semantic error, not a syntactic one (we have already checked
289 -- the syntax for the unrecognized pragma as required by (RM 2.8(11)).
290
291 if Prag_Id = Unknown_Pragma then
292 return Pragma_Node;
293 end if;
294
295 -- Ignore pragma previously flagged by Ignore_Pragma
296
297 if Get_Name_Table_Boolean3 (Prag_Name) then
298 return Pragma_Node;
299 end if;
300
301 -- Count number of arguments. This loop also checks if any of the arguments
302 -- are Error, indicating a syntax error as they were parsed. If so, we
303 -- simply return, because we get into trouble with cascaded errors if we
304 -- try to perform our error checks on junk arguments.
305
306 Arg_Count := 0;
307
308 if Present (Pragma_Argument_Associations (Pragma_Node)) then
309 Arg_Node := Arg1;
310 while Arg_Node /= Empty loop
311 Arg_Count := Arg_Count + 1;
312
313 if Expression (Arg_Node) = Error then
314 return Error;
315 end if;
316
317 Next (Arg_Node);
318 end loop;
319 end if;
320
321 -- Remaining processing is pragma dependent
322
323 case Prag_Id is
324
325 ------------
326 -- Ada_83 --
327 ------------
328
329 -- This pragma must be processed at parse time, since we want to set
330 -- the Ada version properly at parse time to recognize the appropriate
331 -- Ada version syntax.
332
333 when Pragma_Ada_83 =>
334 if not Latest_Ada_Only then
335 Ada_Version := Ada_83;
336 Ada_Version_Explicit := Ada_83;
337 Ada_Version_Pragma := Pragma_Node;
338 end if;
339
340 ------------
341 -- Ada_95 --
342 ------------
343
344 -- This pragma must be processed at parse time, since we want to set
345 -- the Ada version properly at parse time to recognize the appropriate
346 -- Ada version syntax.
347
348 when Pragma_Ada_95 =>
349 if not Latest_Ada_Only then
350 Ada_Version := Ada_95;
351 Ada_Version_Explicit := Ada_95;
352 Ada_Version_Pragma := Pragma_Node;
353 end if;
354
355 ---------------------
356 -- Ada_05/Ada_2005 --
357 ---------------------
358
359 -- These pragmas must be processed at parse time, since we want to set
360 -- the Ada version properly at parse time to recognize the appropriate
361 -- Ada version syntax. However, it is only the zero argument form that
362 -- must be processed at parse time.
363
364 when Pragma_Ada_05
365 | Pragma_Ada_2005
366 =>
367 if Arg_Count = 0 and not Latest_Ada_Only then
368 Ada_Version := Ada_2005;
369 Ada_Version_Explicit := Ada_2005;
370 Ada_Version_Pragma := Pragma_Node;
371 end if;
372
373 ---------------------
374 -- Ada_12/Ada_2012 --
375 ---------------------
376
377 -- These pragmas must be processed at parse time, since we want to set
378 -- the Ada version properly at parse time to recognize the appropriate
379 -- Ada version syntax. However, it is only the zero argument form that
380 -- must be processed at parse time.
381
382 when Pragma_Ada_12
383 | Pragma_Ada_2012
384 =>
385 if Arg_Count = 0 then
386 Ada_Version := Ada_2012;
387 Ada_Version_Explicit := Ada_2012;
388 Ada_Version_Pragma := Pragma_Node;
389 end if;
390
391 ---------------------------
392 -- Compiler_Unit_Warning --
393 ---------------------------
394
395 -- This pragma must be processed at parse time, since the resulting
396 -- status may be tested during the parsing of the program.
397
398 when Pragma_Compiler_Unit
399 | Pragma_Compiler_Unit_Warning
400 =>
401 Check_Arg_Count (0);
402
403 -- Only recognized in main unit
404
405 if Current_Source_Unit = Main_Unit then
406 Compiler_Unit := True;
407 end if;
408
409 -----------
410 -- Debug --
411 -----------
412
413 -- pragma Debug ([boolean_EXPRESSION,] PROCEDURE_CALL_STATEMENT);
414
415 when Pragma_Debug =>
416 Check_No_Identifier (Arg1);
417
418 if Arg_Count = 2 then
419 Check_No_Identifier (Arg2);
420 else
421 Check_Arg_Count (1);
422 end if;
423
424 -------------------------------
425 -- Extensions_Allowed (GNAT) --
426 -------------------------------
427
428 -- pragma Extensions_Allowed (Off | On)
429
430 -- The processing for pragma Extensions_Allowed must be done at
431 -- parse time, since extensions mode may affect what is accepted.
432
433 when Pragma_Extensions_Allowed =>
434 Check_Arg_Count (1);
435 Check_No_Identifier (Arg1);
436 Check_Arg_Is_On_Or_Off (Arg1);
437
438 if Chars (Expression (Arg1)) = Name_On then
439 Extensions_Allowed := True;
440 Ada_Version := Ada_2012;
441 else
442 Extensions_Allowed := False;
443 Ada_Version := Ada_Version_Explicit;
444 end if;
445
446 -------------------
447 -- Ignore_Pragma --
448 -------------------
449
450 -- Processing for this pragma must be done at parse time, since we want
451 -- be able to ignore pragmas that are otherwise processed at parse time.
452
453 when Pragma_Ignore_Pragma => Ignore_Pragma : declare
454 A : Node_Id;
455
456 begin
457 Check_Arg_Count (1);
458 Check_No_Identifier (Arg1);
459 A := Expression (Arg1);
460
461 if Nkind (A) /= N_Identifier then
462 Error_Msg ("incorrect argument for pragma %", Sloc (A));
463 else
464 Set_Name_Table_Boolean3 (Chars (A), True);
465 end if;
466 end Ignore_Pragma;
467
468 ----------------
469 -- List (2.8) --
470 ----------------
471
472 -- pragma List (Off | On)
473
474 -- The processing for pragma List must be done at parse time, since a
475 -- listing can be generated in parse only mode.
476
477 when Pragma_List =>
478 Check_Arg_Count (1);
479 Check_No_Identifier (Arg1);
480 Check_Arg_Is_On_Or_Off (Arg1);
481
482 -- We unconditionally make a List_On entry for the pragma, so that
483 -- in the List (Off) case, the pragma will print even in a region
484 -- of code with listing turned off (this is required).
485
486 Add_List_Pragma_Entry (List_On, Sloc (Pragma_Node));
487
488 -- Now generate the list off entry for pragma List (Off)
489
490 if Chars (Expression (Arg1)) = Name_Off then
491 Add_List_Pragma_Entry (List_Off, Semi);
492 end if;
493
494 ----------------
495 -- Page (2.8) --
496 ----------------
497
498 -- pragma Page;
499
500 -- Processing for this pragma must be done at parse time, since a
501 -- listing can be generated in parse only mode with semantics off.
502
503 when Pragma_Page =>
504 Check_Arg_Count (0);
505 Add_List_Pragma_Entry (Page, Semi);
506
507 ------------------
508 -- Restrictions --
509 ------------------
510
511 -- pragma Restrictions (RESTRICTION {, RESTRICTION});
512
513 -- RESTRICTION ::=
514 -- restriction_IDENTIFIER
515 -- | restriction_parameter_IDENTIFIER => EXPRESSION
516
517 -- We process the case of No_Obsolescent_Features, since this has
518 -- a syntactic effect that we need to detect at parse time (the use
519 -- of replacement characters such as colon for pound sign).
520
521 when Pragma_Restrictions =>
522 Process_Restrictions_Or_Restriction_Warnings;
523
524 --------------------------
525 -- Restriction_Warnings --
526 --------------------------
527
528 -- pragma Restriction_Warnings (RESTRICTION {, RESTRICTION});
529
530 -- RESTRICTION ::=
531 -- restriction_IDENTIFIER
532 -- | restriction_parameter_IDENTIFIER => EXPRESSION
533
534 -- See above comment for pragma Restrictions
535
536 when Pragma_Restriction_Warnings =>
537 Process_Restrictions_Or_Restriction_Warnings;
538
539 ----------------------------------------------------------
540 -- Source_File_Name and Source_File_Name_Project (GNAT) --
541 ----------------------------------------------------------
542
543 -- These two pragmas have the same syntax and semantics.
544 -- There are five forms of these pragmas:
545
546 -- pragma Source_File_Name[_Project] (
547 -- [UNIT_NAME =>] unit_NAME,
548 -- BODY_FILE_NAME => STRING_LITERAL
549 -- [, [INDEX =>] INTEGER_LITERAL]);
550
551 -- pragma Source_File_Name[_Project] (
552 -- [UNIT_NAME =>] unit_NAME,
553 -- SPEC_FILE_NAME => STRING_LITERAL
554 -- [, [INDEX =>] INTEGER_LITERAL]);
555
556 -- pragma Source_File_Name[_Project] (
557 -- BODY_FILE_NAME => STRING_LITERAL
558 -- [, DOT_REPLACEMENT => STRING_LITERAL]
559 -- [, CASING => CASING_SPEC]);
560
561 -- pragma Source_File_Name[_Project] (
562 -- SPEC_FILE_NAME => STRING_LITERAL
563 -- [, DOT_REPLACEMENT => STRING_LITERAL]
564 -- [, CASING => CASING_SPEC]);
565
566 -- pragma Source_File_Name[_Project] (
567 -- SUBUNIT_FILE_NAME => STRING_LITERAL
568 -- [, DOT_REPLACEMENT => STRING_LITERAL]
569 -- [, CASING => CASING_SPEC]);
570
571 -- CASING_SPEC ::= Uppercase | Lowercase | Mixedcase
572
573 -- Pragma Source_File_Name_Project (SFNP) is equivalent to pragma
574 -- Source_File_Name (SFN), however their usage is exclusive:
575 -- SFN can only be used when no project file is used, while
576 -- SFNP can only be used when a project file is used.
577
578 -- The Project Manager produces a configuration pragmas file that
579 -- is communicated to the compiler with -gnatec switch. This file
580 -- contains only SFNP pragmas (at least two for the default naming
581 -- scheme. As this configuration pragmas file is always the first
582 -- processed by the compiler, it prevents the use of pragmas SFN in
583 -- other config files when a project file is in use.
584
585 -- Note: we process this during parsing, since we need to have the
586 -- source file names set well before the semantic analysis starts,
587 -- since we load the spec and with'ed packages before analysis.
588
589 when Pragma_Source_File_Name
590 | Pragma_Source_File_Name_Project
591 =>
592 Source_File_Name : declare
593 Unam : Unit_Name_Type;
594 Expr1 : Node_Id;
595 Pat : String_Ptr;
596 Typ : Character;
597 Dot : String_Ptr;
598 Cas : Casing_Type;
599 Nast : Nat;
600 Expr : Node_Id;
601 Index : Nat;
602
603 function Get_Fname (Arg : Node_Id) return File_Name_Type;
604 -- Process file name from unit name form of pragma
605
606 function Get_String_Argument (Arg : Node_Id) return String_Ptr;
607 -- Process string literal value from argument
608
609 procedure Process_Casing (Arg : Node_Id);
610 -- Process Casing argument of pattern form of pragma
611
612 procedure Process_Dot_Replacement (Arg : Node_Id);
613 -- Process Dot_Replacement argument of pattern form of pragma
614
615 ---------------
616 -- Get_Fname --
617 ---------------
618
619 function Get_Fname (Arg : Node_Id) return File_Name_Type is
620 begin
621 String_To_Name_Buffer (Strval (Expression (Arg)));
622
623 for J in 1 .. Name_Len loop
624 if Is_Directory_Separator (Name_Buffer (J)) then
625 Error_Msg
626 ("directory separator character not allowed",
627 Sloc (Expression (Arg)) + Source_Ptr (J));
628 end if;
629 end loop;
630
631 return Name_Find;
632 end Get_Fname;
633
634 -------------------------
635 -- Get_String_Argument --
636 -------------------------
637
638 function Get_String_Argument (Arg : Node_Id) return String_Ptr is
639 Str : String_Id;
640
641 begin
642 if Nkind (Expression (Arg)) /= N_String_Literal
643 and then
644 Nkind (Expression (Arg)) /= N_Operator_Symbol
645 then
646 Error_Msg_N
647 ("argument for pragma% must be string literal", Arg);
648 raise Error_Resync;
649 end if;
650
651 Str := Strval (Expression (Arg));
652
653 -- Check string has no wide chars
654
655 for J in 1 .. String_Length (Str) loop
656 if Get_String_Char (Str, J) > 255 then
657 Error_Msg
658 ("wide character not allowed in pattern for pragma%",
659 Sloc (Expression (Arg2)) + Text_Ptr (J) - 1);
660 end if;
661 end loop;
662
663 -- Acquire string
664
665 String_To_Name_Buffer (Str);
666 return new String'(Name_Buffer (1 .. Name_Len));
667 end Get_String_Argument;
668
669 --------------------
670 -- Process_Casing --
671 --------------------
672
673 procedure Process_Casing (Arg : Node_Id) is
674 Expr : constant Node_Id := Expression (Arg);
675
676 begin
677 Check_Required_Identifier (Arg, Name_Casing);
678
679 if Nkind (Expr) = N_Identifier then
680 if Chars (Expr) = Name_Lowercase then
681 Cas := All_Lower_Case;
682 return;
683 elsif Chars (Expr) = Name_Uppercase then
684 Cas := All_Upper_Case;
685 return;
686 elsif Chars (Expr) = Name_Mixedcase then
687 Cas := Mixed_Case;
688 return;
689 end if;
690 end if;
691
692 Error_Msg_N
693 ("Casing argument for pragma% must be " &
694 "one of Mixedcase, Lowercase, Uppercase",
695 Arg);
696 end Process_Casing;
697
698 -----------------------------
699 -- Process_Dot_Replacement --
700 -----------------------------
701
702 procedure Process_Dot_Replacement (Arg : Node_Id) is
703 begin
704 Check_Required_Identifier (Arg, Name_Dot_Replacement);
705 Dot := Get_String_Argument (Arg);
706 end Process_Dot_Replacement;
707
708 -- Start of processing for Source_File_Name and
709 -- Source_File_Name_Project pragmas.
710
711 begin
712 if Prag_Id = Pragma_Source_File_Name then
713 if Project_File_In_Use = In_Use then
714 Error_Msg
715 ("pragma Source_File_Name cannot be used " &
716 "with a project file", Pragma_Sloc);
717
718 else
719 Project_File_In_Use := Not_In_Use;
720 end if;
721
722 else
723 if Project_File_In_Use = Not_In_Use then
724 Error_Msg
725 ("pragma Source_File_Name_Project should only be used " &
726 "with a project file", Pragma_Sloc);
727 else
728 Project_File_In_Use := In_Use;
729 end if;
730 end if;
731
732 -- We permit from 1 to 3 arguments
733
734 if Arg_Count not in 1 .. 3 then
735 Check_Arg_Count (1);
736 end if;
737
738 Expr1 := Expression (Arg1);
739
740 -- If first argument is identifier or selected component, then
741 -- we have the specific file case of the Source_File_Name pragma,
742 -- and the first argument is a unit name.
743
744 if Nkind (Expr1) = N_Identifier
745 or else
746 (Nkind (Expr1) = N_Selected_Component
747 and then
748 Nkind (Selector_Name (Expr1)) = N_Identifier)
749 then
750 if Nkind (Expr1) = N_Identifier
751 and then Chars (Expr1) = Name_System
752 then
753 Error_Msg_N
754 ("pragma Source_File_Name may not be used for System",
755 Arg1);
756 return Error;
757 end if;
758
759 -- Process index argument if present
760
761 if Arg_Count = 3 then
762 Expr := Expression (Arg3);
763
764 if Nkind (Expr) /= N_Integer_Literal
765 or else not UI_Is_In_Int_Range (Intval (Expr))
766 or else Intval (Expr) > 999
767 or else Intval (Expr) <= 0
768 then
769 Error_Msg
770 ("pragma% index must be integer literal" &
771 " in range 1 .. 999", Sloc (Expr));
772 raise Error_Resync;
773 else
774 Index := UI_To_Int (Intval (Expr));
775 end if;
776
777 -- No index argument present
778
779 else
780 Check_Arg_Count (2);
781 Index := 0;
782 end if;
783
784 Check_Optional_Identifier (Arg1, Name_Unit_Name);
785 Unam := Get_Unit_Name (Expr1);
786
787 Check_Arg_Is_String_Literal (Arg2);
788
789 if Chars (Arg2) = Name_Spec_File_Name then
790 Set_File_Name
791 (Get_Spec_Name (Unam), Get_Fname (Arg2), Index);
792
793 elsif Chars (Arg2) = Name_Body_File_Name then
794 Set_File_Name
795 (Unam, Get_Fname (Arg2), Index);
796
797 else
798 Error_Msg_N
799 ("pragma% argument has incorrect identifier", Arg2);
800 return Pragma_Node;
801 end if;
802
803 -- If the first argument is not an identifier, then we must have
804 -- the pattern form of the pragma, and the first argument must be
805 -- the pattern string with an appropriate name.
806
807 else
808 if Chars (Arg1) = Name_Spec_File_Name then
809 Typ := 's';
810
811 elsif Chars (Arg1) = Name_Body_File_Name then
812 Typ := 'b';
813
814 elsif Chars (Arg1) = Name_Subunit_File_Name then
815 Typ := 'u';
816
817 elsif Chars (Arg1) = Name_Unit_Name then
818 Error_Msg_N
819 ("Unit_Name parameter for pragma% must be an identifier",
820 Arg1);
821 raise Error_Resync;
822
823 else
824 Error_Msg_N
825 ("pragma% argument has incorrect identifier", Arg1);
826 raise Error_Resync;
827 end if;
828
829 Pat := Get_String_Argument (Arg1);
830
831 -- Check pattern has exactly one asterisk
832
833 Nast := 0;
834 for J in Pat'Range loop
835 if Pat (J) = '*' then
836 Nast := Nast + 1;
837 end if;
838 end loop;
839
840 if Nast /= 1 then
841 Error_Msg_N
842 ("file name pattern must have exactly one * character",
843 Arg1);
844 return Pragma_Node;
845 end if;
846
847 -- Set defaults for Casing and Dot_Separator parameters
848
849 Cas := All_Lower_Case;
850 Dot := new String'(".");
851
852 -- Process second and third arguments if present
853
854 if Arg_Count > 1 then
855 if Chars (Arg2) = Name_Casing then
856 Process_Casing (Arg2);
857
858 if Arg_Count = 3 then
859 Process_Dot_Replacement (Arg3);
860 end if;
861
862 else
863 Process_Dot_Replacement (Arg2);
864
865 if Arg_Count = 3 then
866 Process_Casing (Arg3);
867 end if;
868 end if;
869 end if;
870
871 Set_File_Name_Pattern (Pat, Typ, Dot, Cas);
872 end if;
873 end Source_File_Name;
874
875 -----------------------------
876 -- Source_Reference (GNAT) --
877 -----------------------------
878
879 -- pragma Source_Reference
880 -- (INTEGER_LITERAL [, STRING_LITERAL] );
881
882 -- Processing for this pragma must be done at parse time, since error
883 -- messages needing the proper line numbers can be generated in parse
884 -- only mode with semantic checking turned off, and indeed we usually
885 -- turn off semantic checking anyway if any parse errors are found.
886
887 when Pragma_Source_Reference => Source_Reference : declare
888 Fname : File_Name_Type;
889
890 begin
891 if Arg_Count /= 1 then
892 Check_Arg_Count (2);
893 Check_No_Identifier (Arg2);
894 end if;
895
896 -- Check that this is first line of file. We skip this test if
897 -- we are in syntax check only mode, since we may be dealing with
898 -- multiple compilation units.
899
900 if Get_Physical_Line_Number (Pragma_Sloc) /= 1
901 and then Num_SRef_Pragmas (Current_Source_File) = 0
902 and then Operating_Mode /= Check_Syntax
903 then
904 Error_Msg -- CODEFIX
905 ("first % pragma must be first line of file", Pragma_Sloc);
906 raise Error_Resync;
907 end if;
908
909 Check_No_Identifier (Arg1);
910
911 if Arg_Count = 1 then
912 if Num_SRef_Pragmas (Current_Source_File) = 0 then
913 Error_Msg
914 ("file name required for first % pragma in file",
915 Pragma_Sloc);
916 raise Error_Resync;
917 else
918 Fname := No_File;
919 end if;
920
921 -- File name present
922
923 else
924 Check_Arg_Is_String_Literal (Arg2);
925 String_To_Name_Buffer (Strval (Expression (Arg2)));
926 Fname := Name_Find;
927
928 if Num_SRef_Pragmas (Current_Source_File) > 0 then
929 if Fname /= Full_Ref_Name (Current_Source_File) then
930 Error_Msg
931 ("file name must be same in all % pragmas", Pragma_Sloc);
932 raise Error_Resync;
933 end if;
934 end if;
935 end if;
936
937 if Nkind (Expression (Arg1)) /= N_Integer_Literal then
938 Error_Msg
939 ("argument for pragma% must be integer literal",
940 Sloc (Expression (Arg1)));
941 raise Error_Resync;
942
943 -- OK, this source reference pragma is effective, however, we
944 -- ignore it if it is not in the first unit in the multiple unit
945 -- case. This is because the only purpose in this case is to
946 -- provide source pragmas for subsequent use by gnatchop.
947
948 else
949 if Num_Library_Units = 1 then
950 Register_Source_Ref_Pragma
951 (Fname,
952 Strip_Directory (Fname),
953 UI_To_Int (Intval (Expression (Arg1))),
954 Get_Physical_Line_Number (Pragma_Sloc) + 1);
955 end if;
956 end if;
957 end Source_Reference;
958
959 -------------------------
960 -- Style_Checks (GNAT) --
961 -------------------------
962
963 -- pragma Style_Checks (On | Off | ALL_CHECKS | STRING_LITERAL);
964
965 -- This is processed by the parser since some of the style
966 -- checks take place during source scanning and parsing.
967
968 when Pragma_Style_Checks => Style_Checks : declare
969 A : Node_Id;
970 S : String_Id;
971 C : Char_Code;
972 OK : Boolean := True;
973
974 begin
975 -- Two argument case is only for semantics
976
977 if Arg_Count = 2 then
978 null;
979
980 else
981 Check_Arg_Count (1);
982 Check_No_Identifier (Arg1);
983 A := Expression (Arg1);
984
985 if Nkind (A) = N_String_Literal then
986 S := Strval (A);
987
988 declare
989 Slen : constant Natural := Natural (String_Length (S));
990 Options : String (1 .. Slen);
991 J : Positive;
992 Ptr : Positive;
993
994 begin
995 J := 1;
996 loop
997 C := Get_String_Char (S, Pos (J));
998
999 if not In_Character_Range (C) then
1000 OK := False;
1001 Ptr := J;
1002 exit;
1003
1004 else
1005 Options (J) := Get_Character (C);
1006 end if;
1007
1008 if J = Slen then
1009 if not Ignore_Style_Checks_Pragmas then
1010 Set_Style_Check_Options (Options, OK, Ptr);
1011 end if;
1012
1013 exit;
1014
1015 else
1016 J := J + 1;
1017 end if;
1018 end loop;
1019
1020 if not OK then
1021 Error_Msg
1022 (Style_Msg_Buf (1 .. Style_Msg_Len),
1023 Sloc (Expression (Arg1)) + Source_Ptr (Ptr));
1024 raise Error_Resync;
1025 end if;
1026 end;
1027
1028 elsif Nkind (A) /= N_Identifier then
1029 OK := False;
1030
1031 elsif Chars (A) = Name_All_Checks then
1032 if not Ignore_Style_Checks_Pragmas then
1033 if GNAT_Mode then
1034 Stylesw.Set_GNAT_Style_Check_Options;
1035 else
1036 Stylesw.Set_Default_Style_Check_Options;
1037 end if;
1038 end if;
1039
1040 elsif Chars (A) = Name_On then
1041 if not Ignore_Style_Checks_Pragmas then
1042 Style_Check := True;
1043 end if;
1044
1045 elsif Chars (A) = Name_Off then
1046 if not Ignore_Style_Checks_Pragmas then
1047 Style_Check := False;
1048 end if;
1049
1050 else
1051 OK := False;
1052 end if;
1053
1054 if not OK then
1055 Error_Msg ("incorrect argument for pragma%", Sloc (A));
1056 raise Error_Resync;
1057 end if;
1058 end if;
1059 end Style_Checks;
1060
1061 -------------------------
1062 -- Suppress_All (GNAT) --
1063 -------------------------
1064
1065 -- pragma Suppress_All
1066
1067 -- This is a rather odd pragma, because other compilers allow it in
1068 -- strange places. DEC allows it at the end of units, and Rational
1069 -- allows it as a program unit pragma, when it would be more natural
1070 -- if it were a configuration pragma.
1071
1072 -- Since the reason we provide this pragma is for compatibility with
1073 -- these other compilers, we want to accommodate these strange placement
1074 -- rules, and the easiest thing is simply to allow it anywhere in a
1075 -- unit. If this pragma appears anywhere within a unit, then the effect
1076 -- is as though a pragma Suppress (All_Checks) had appeared as the first
1077 -- line of the current file, i.e. as the first configuration pragma in
1078 -- the current unit.
1079
1080 -- To get this effect, we set the flag Has_Pragma_Suppress_All in the
1081 -- compilation unit node for the current source file then in the last
1082 -- stage of parsing a file, if this flag is set, we materialize the
1083 -- Suppress (All_Checks) pragma, marked as not coming from Source.
1084
1085 when Pragma_Suppress_All =>
1086 Set_Has_Pragma_Suppress_All (Cunit (Current_Source_Unit));
1087
1088 ---------------------
1089 -- Warnings (GNAT) --
1090 ---------------------
1091
1092 -- pragma Warnings ([TOOL_NAME,] DETAILS [, REASON]);
1093
1094 -- DETAILS ::= On | Off
1095 -- DETAILS ::= On | Off, local_NAME
1096 -- DETAILS ::= static_string_EXPRESSION
1097 -- DETAILS ::= On | Off, static_string_EXPRESSION
1098
1099 -- TOOL_NAME ::= GNAT | GNATProve
1100
1101 -- REASON ::= Reason => STRING_LITERAL {& STRING_LITERAL}
1102
1103 -- Note: If the first argument matches an allowed tool name, it is
1104 -- always considered to be a tool name, even if there is a string
1105 -- variable of that name.
1106
1107 -- The one argument ON/OFF case is processed by the parser, since it may
1108 -- control parser warnings as well as semantic warnings, and in any case
1109 -- we want to be absolutely sure that the range in the warnings table is
1110 -- set well before any semantic analysis is performed. Note that we
1111 -- ignore this pragma if debug flag -gnatd.i is set.
1112
1113 -- Also note that the "one argument" case may have two or three
1114 -- arguments if the first one is a tool name, and/or the last one is a
1115 -- reason argument.
1116
1117 when Pragma_Warnings => Warnings : declare
1118 function First_Arg_Is_Matching_Tool_Name return Boolean;
1119 -- Returns True if the first argument is a tool name matching the
1120 -- current tool being run.
1121
1122 function Last_Arg return Node_Id;
1123 -- Returns the last argument
1124
1125 function Last_Arg_Is_Reason return Boolean;
1126 -- Returns True if the last argument is a reason argument
1127
1128 function Get_Reason return String_Id;
1129 -- Analyzes Reason argument and returns corresponding String_Id
1130 -- value, or null if there is no Reason argument, or if the
1131 -- argument is not of the required form.
1132
1133 -------------------------------------
1134 -- First_Arg_Is_Matching_Tool_Name --
1135 -------------------------------------
1136
1137 function First_Arg_Is_Matching_Tool_Name return Boolean is
1138 begin
1139 return Nkind (Arg1) = N_Identifier
1140
1141 -- Return True if the tool name is GNAT, and we're not in
1142 -- GNATprove or CodePeer or ASIS mode...
1143
1144 and then ((Chars (Arg1) = Name_Gnat
1145 and then not
1146 (CodePeer_Mode or GNATprove_Mode or ASIS_Mode))
1147
1148 -- or if the tool name is GNATprove, and we're in GNATprove
1149 -- mode.
1150
1151 or else
1152 (Chars (Arg1) = Name_Gnatprove
1153 and then GNATprove_Mode));
1154 end First_Arg_Is_Matching_Tool_Name;
1155
1156 ----------------
1157 -- Get_Reason --
1158 ----------------
1159
1160 function Get_Reason return String_Id is
1161 Arg : constant Node_Id := Last_Arg;
1162 begin
1163 if Last_Arg_Is_Reason then
1164 Start_String;
1165 Get_Reason_String (Expression (Arg));
1166 return End_String;
1167 else
1168 return Null_String_Id;
1169 end if;
1170 end Get_Reason;
1171
1172 --------------
1173 -- Last_Arg --
1174 --------------
1175
1176 function Last_Arg return Node_Id is
1177 Last_Arg : Node_Id;
1178
1179 begin
1180 if Arg_Count = 1 then
1181 Last_Arg := Arg1;
1182 elsif Arg_Count = 2 then
1183 Last_Arg := Arg2;
1184 elsif Arg_Count = 3 then
1185 Last_Arg := Arg3;
1186 elsif Arg_Count = 4 then
1187 Last_Arg := Next (Arg3);
1188
1189 -- Illegal case, error issued in semantic analysis
1190
1191 else
1192 Last_Arg := Empty;
1193 end if;
1194
1195 return Last_Arg;
1196 end Last_Arg;
1197
1198 ------------------------
1199 -- Last_Arg_Is_Reason --
1200 ------------------------
1201
1202 function Last_Arg_Is_Reason return Boolean is
1203 Arg : constant Node_Id := Last_Arg;
1204 begin
1205 return Nkind (Arg) in N_Has_Chars
1206 and then Chars (Arg) = Name_Reason;
1207 end Last_Arg_Is_Reason;
1208
1209 The_Arg : Node_Id; -- On/Off argument
1210 Argx : Node_Id;
1211
1212 -- Start of processing for Warnings
1213
1214 begin
1215 if not Debug_Flag_Dot_I
1216 and then (Arg_Count = 1
1217 or else (Arg_Count = 2
1218 and then (First_Arg_Is_Matching_Tool_Name
1219 or else
1220 Last_Arg_Is_Reason))
1221 or else (Arg_Count = 3
1222 and then First_Arg_Is_Matching_Tool_Name
1223 and then Last_Arg_Is_Reason))
1224 then
1225 if First_Arg_Is_Matching_Tool_Name then
1226 The_Arg := Arg2;
1227 else
1228 The_Arg := Arg1;
1229 end if;
1230
1231 Check_No_Identifier (The_Arg);
1232 Argx := Expression (The_Arg);
1233
1234 if Nkind (Argx) = N_Identifier then
1235 if Chars (Argx) = Name_On then
1236 Set_Warnings_Mode_On (Pragma_Sloc);
1237 elsif Chars (Argx) = Name_Off then
1238 Set_Warnings_Mode_Off (Pragma_Sloc, Get_Reason);
1239 end if;
1240 end if;
1241 end if;
1242 end Warnings;
1243
1244 -----------------------------
1245 -- Wide_Character_Encoding --
1246 -----------------------------
1247
1248 -- pragma Wide_Character_Encoding (IDENTIFIER | CHARACTER_LITERAL);
1249
1250 -- This is processed by the parser, since the scanner is affected
1251
1252 when Pragma_Wide_Character_Encoding => Wide_Character_Encoding : declare
1253 A : Node_Id;
1254
1255 begin
1256 Check_Arg_Count (1);
1257 Check_No_Identifier (Arg1);
1258 A := Expression (Arg1);
1259
1260 if Nkind (A) = N_Identifier then
1261 Get_Name_String (Chars (A));
1262 Wide_Character_Encoding_Method :=
1263 Get_WC_Encoding_Method (Name_Buffer (1 .. Name_Len));
1264
1265 elsif Nkind (A) = N_Character_Literal then
1266 declare
1267 R : constant Char_Code :=
1268 Char_Code (UI_To_Int (Char_Literal_Value (A)));
1269 begin
1270 if In_Character_Range (R) then
1271 Wide_Character_Encoding_Method :=
1272 Get_WC_Encoding_Method (Get_Character (R));
1273 else
1274 raise Constraint_Error;
1275 end if;
1276 end;
1277
1278 else
1279 raise Constraint_Error;
1280 end if;
1281
1282 Upper_Half_Encoding :=
1283 Wide_Character_Encoding_Method in
1284 WC_Upper_Half_Encoding_Method;
1285
1286 exception
1287 when Constraint_Error =>
1288 Error_Msg_N ("invalid argument for pragma%", Arg1);
1289 end Wide_Character_Encoding;
1290
1291 -----------------------
1292 -- All Other Pragmas --
1293 -----------------------
1294
1295 -- For all other pragmas, checking and processing is handled
1296 -- entirely in Sem_Prag, and no further checking is done by Par.
1297
1298 when Pragma_Abort_Defer
1299 | Pragma_Abstract_State
1300 | Pragma_Async_Readers
1301 | Pragma_Async_Writers
1302 | Pragma_Assertion_Policy
1303 | Pragma_Assume
1304 | Pragma_Assume_No_Invalid_Values
1305 | Pragma_All_Calls_Remote
1306 | Pragma_Allow_Integer_Address
1307 | Pragma_Annotate
1308 | Pragma_Assert
1309 | Pragma_Assert_And_Cut
1310 | Pragma_Asynchronous
1311 | Pragma_Atomic
1312 | Pragma_Atomic_Components
1313 | Pragma_Attach_Handler
1314 | Pragma_Attribute_Definition
1315 | Pragma_Check
1316 | Pragma_Check_Float_Overflow
1317 | Pragma_Check_Name
1318 | Pragma_Check_Policy
1319 | Pragma_Compile_Time_Error
1320 | Pragma_Compile_Time_Warning
1321 | Pragma_Constant_After_Elaboration
1322 | Pragma_Contract_Cases
1323 | Pragma_Convention_Identifier
1324 | Pragma_CPP_Class
1325 | Pragma_CPP_Constructor
1326 | Pragma_CPP_Virtual
1327 | Pragma_CPP_Vtable
1328 | Pragma_CPU
1329 | Pragma_C_Pass_By_Copy
1330 | Pragma_Comment
1331 | Pragma_Common_Object
1332 | Pragma_Complete_Representation
1333 | Pragma_Complex_Representation
1334 | Pragma_Component_Alignment
1335 | Pragma_Controlled
1336 | Pragma_Convention
1337 | Pragma_Debug_Policy
1338 | Pragma_Depends
1339 | Pragma_Detect_Blocking
1340 | Pragma_Default_Initial_Condition
1341 | Pragma_Default_Scalar_Storage_Order
1342 | Pragma_Default_Storage_Pool
1343 | Pragma_Disable_Atomic_Synchronization
1344 | Pragma_Discard_Names
1345 | Pragma_Dispatching_Domain
1346 | Pragma_Effective_Reads
1347 | Pragma_Effective_Writes
1348 | Pragma_Eliminate
1349 | Pragma_Elaborate
1350 | Pragma_Elaborate_All
1351 | Pragma_Elaborate_Body
1352 | Pragma_Elaboration_Checks
1353 | Pragma_Enable_Atomic_Synchronization
1354 | Pragma_Export
1355 | Pragma_Export_Function
1356 | Pragma_Export_Object
1357 | Pragma_Export_Procedure
1358 | Pragma_Export_Value
1359 | Pragma_Export_Valued_Procedure
1360 | Pragma_Extend_System
1361 | Pragma_Extensions_Visible
1362 | Pragma_External
1363 | Pragma_External_Name_Casing
1364 | Pragma_Favor_Top_Level
1365 | Pragma_Fast_Math
1366 | Pragma_Finalize_Storage_Only
1367 | Pragma_Ghost
1368 | Pragma_Global
1369 | Pragma_Ident
1370 | Pragma_Implementation_Defined
1371 | Pragma_Implemented
1372 | Pragma_Implicit_Packing
1373 | Pragma_Import
1374 | Pragma_Import_Function
1375 | Pragma_Import_Object
1376 | Pragma_Import_Procedure
1377 | Pragma_Import_Valued_Procedure
1378 | Pragma_Independent
1379 | Pragma_Independent_Components
1380 | Pragma_Initial_Condition
1381 | Pragma_Initialize_Scalars
1382 | Pragma_Initializes
1383 | Pragma_Inline
1384 | Pragma_Inline_Always
1385 | Pragma_Inline_Generic
1386 | Pragma_Inspection_Point
1387 | Pragma_Interface
1388 | Pragma_Interface_Name
1389 | Pragma_Interrupt_Handler
1390 | Pragma_Interrupt_State
1391 | Pragma_Interrupt_Priority
1392 | Pragma_Invariant
1393 | Pragma_Keep_Names
1394 | Pragma_License
1395 | Pragma_Link_With
1396 | Pragma_Linker_Alias
1397 | Pragma_Linker_Constructor
1398 | Pragma_Linker_Destructor
1399 | Pragma_Linker_Options
1400 | Pragma_Linker_Section
1401 | Pragma_Lock_Free
1402 | Pragma_Locking_Policy
1403 | Pragma_Loop_Invariant
1404 | Pragma_Loop_Optimize
1405 | Pragma_Loop_Variant
1406 | Pragma_Machine_Attribute
1407 | Pragma_Main
1408 | Pragma_Main_Storage
1409 | Pragma_Max_Queue_Length
1410 | Pragma_Memory_Size
1411 | Pragma_No_Body
1412 | Pragma_No_Elaboration_Code_All
1413 | Pragma_No_Inline
1414 | Pragma_No_Return
1415 | Pragma_No_Run_Time
1416 | Pragma_No_Strict_Aliasing
1417 | Pragma_No_Tagged_Streams
1418 | Pragma_Normalize_Scalars
1419 | Pragma_Obsolescent
1420 | Pragma_Ordered
1421 | Pragma_Optimize
1422 | Pragma_Optimize_Alignment
1423 | Pragma_Overflow_Mode
1424 | Pragma_Overriding_Renamings
1425 | Pragma_Pack
1426 | Pragma_Part_Of
1427 | Pragma_Partition_Elaboration_Policy
1428 | Pragma_Passive
1429 | Pragma_Preelaborable_Initialization
1430 | Pragma_Polling
1431 | Pragma_Prefix_Exception_Messages
1432 | Pragma_Persistent_BSS
1433 | Pragma_Post
1434 | Pragma_Postcondition
1435 | Pragma_Post_Class
1436 | Pragma_Pre
1437 | Pragma_Precondition
1438 | Pragma_Predicate
1439 | Pragma_Predicate_Failure
1440 | Pragma_Preelaborate
1441 | Pragma_Pre_Class
1442 | Pragma_Priority
1443 | Pragma_Priority_Specific_Dispatching
1444 | Pragma_Profile
1445 | Pragma_Profile_Warnings
1446 | Pragma_Propagate_Exceptions
1447 | Pragma_Provide_Shift_Operators
1448 | Pragma_Psect_Object
1449 | Pragma_Pure
1450 | Pragma_Pure_Function
1451 | Pragma_Queuing_Policy
1452 | Pragma_Refined_Depends
1453 | Pragma_Refined_Global
1454 | Pragma_Refined_Post
1455 | Pragma_Refined_State
1456 | Pragma_Relative_Deadline
1457 | Pragma_Remote_Access_Type
1458 | Pragma_Remote_Call_Interface
1459 | Pragma_Remote_Types
1460 | Pragma_Restricted_Run_Time
1461 | Pragma_Rational
1462 | Pragma_Ravenscar
1463 | Pragma_Rename_Pragma
1464 | Pragma_Reviewable
1465 | Pragma_Secondary_Stack_Size
1466 | Pragma_Share_Generic
1467 | Pragma_Shared
1468 | Pragma_Shared_Passive
1469 | Pragma_Short_Circuit_And_Or
1470 | Pragma_Short_Descriptors
1471 | Pragma_Simple_Storage_Pool_Type
1472 | Pragma_SPARK_Mode
1473 | Pragma_Storage_Size
1474 | Pragma_Storage_Unit
1475 | Pragma_Static_Elaboration_Desired
1476 | Pragma_Stream_Convert
1477 | Pragma_Subtitle
1478 | Pragma_Suppress
1479 | Pragma_Suppress_Debug_Info
1480 | Pragma_Suppress_Exception_Locations
1481 | Pragma_Suppress_Initialization
1482 | Pragma_System_Name
1483 | Pragma_Task_Dispatching_Policy
1484 | Pragma_Task_Info
1485 | Pragma_Task_Name
1486 | Pragma_Task_Storage
1487 | Pragma_Test_Case
1488 | Pragma_Thread_Local_Storage
1489 | Pragma_Time_Slice
1490 | Pragma_Title
1491 | Pragma_Type_Invariant
1492 | Pragma_Type_Invariant_Class
1493 | Pragma_Unchecked_Union
1494 | Pragma_Unevaluated_Use_Of_Old
1495 | Pragma_Unimplemented_Unit
1496 | Pragma_Universal_Aliasing
1497 | Pragma_Universal_Data
1498 | Pragma_Unmodified
1499 | Pragma_Unreferenced
1500 | Pragma_Unreferenced_Objects
1501 | Pragma_Unreserve_All_Interrupts
1502 | Pragma_Unsuppress
1503 | Pragma_Unused
1504 | Pragma_Use_VADS_Size
1505 | Pragma_Volatile
1506 | Pragma_Volatile_Components
1507 | Pragma_Volatile_Full_Access
1508 | Pragma_Volatile_Function
1509 | Pragma_Warning_As_Error
1510 | Pragma_Weak_External
1511 | Pragma_Validity_Checks
1512 =>
1513 null;
1514
1515 --------------------
1516 -- Unknown_Pragma --
1517 --------------------
1518
1519 -- Should be impossible, since we excluded this case earlier on
1520
1521 when Unknown_Pragma =>
1522 raise Program_Error;
1523
1524 end case;
1525
1526 return Pragma_Node;
1527
1528 --------------------
1529 -- Error Handling --
1530 --------------------
1531
1532 exception
1533 when Error_Resync =>
1534 return Error;
1535
1536 end Prag;
Mirror of the offical gcc git repository hosted at gcc.gnu.org