gcc/ada/adabkend.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             A D A B K E N D                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                     Copyright (C) 2001-2016, AdaCore                     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 ------------------------------------------------------------------------------
  22
  23 --  This is the version of the Back_End package for back ends written in Ada
  24
  25 with Debug;
  26 with Lib;
  27 with Opt;      use Opt;
  28 with Output;   use Output;
  29 with Osint;    use Osint;
  30 with Osint.C;  use Osint.C;
  31 with Switch.C; use Switch.C;
  32 with Types;    use Types;
  33
  34 with System.OS_Lib; use System.OS_Lib;
  35
  36 package body Adabkend is
  37
  38    use Switch;
  39
  40    -------------------
  41    -- Call_Back_End --
  42    -------------------
  43
  44    procedure Call_Back_End is
  45    begin
  46       if (Opt.Verbose_Mode or Opt.Full_List)
  47         and then not Debug.Debug_Flag_7
  48       then
  49          Write_Eol;
  50          Write_Str (Product_Name);
  51          Write_Str (", Copyright ");
  52          Write_Str (Copyright_Years);
  53          Write_Str (" Ada Core Technologies, Inc.");
  54          Write_Str (" (http://www.adacore.com)");
  55          Write_Eol;
  56          Write_Eol;
  57       end if;
  58
  59       Driver (Lib.Cunit (Types.Main_Unit));
  60    end Call_Back_End;
  61
  62    ------------------------
  63    -- Scan_Compiler_Args --
  64    ------------------------
  65
  66    procedure Scan_Compiler_Arguments is
  67       Output_File_Name_Seen : Boolean := False;
  68       --  Set to True after having scanned the file_name for switch
  69       --  "-gnatO file_name"
  70
  71       Argument_Count : constant Integer := Arg_Count - 1;
  72       --  Number of arguments (excluding program name)
  73
  74       Args     : Argument_List (1 .. Argument_Count);
  75       Next_Arg : Positive := 1;
  76
  77       procedure Scan_Back_End_Switches (Switch_Chars : String);
  78       --  Procedure to scan out switches stored in Switch_Chars. The first
  79       --  character is known to be a valid switch character, and there are no
  80       --  blanks or other switch terminator characters in the string, so the
  81       --  entire string should consist of valid switch characters, except that
  82       --  an optional terminating NUL character is allowed.
  83       --
  84       --  If the switch is not valid, control will not return. The switches
  85       --  must still be scanned to skip the "-o" arguments, or internal GCC
  86       --  switches, which may be safely ignored by other back-ends.
  87
  88       ----------------------------
  89       -- Scan_Back_End_Switches --
  90       ----------------------------
  91
  92       procedure Scan_Back_End_Switches (Switch_Chars : String) is
  93          First : constant Positive := Switch_Chars'First + 1;
  94          Last  : constant Natural  := Switch_Last (Switch_Chars);
  95
  96       begin
  97          --  Process any back end switches, returning if the switch does not
  98          --  affect code generation or falling through if it does, so the
  99          --  switch will get stored.
 100
 101          --  Skip -o, -G or internal GCC switches together with their argument.
 102
 103          if Switch_Chars (First .. Last) = "o"
 104            or else Switch_Chars (First .. Last) = "G"
 105            or else Is_Internal_GCC_Switch (Switch_Chars)
 106          then
 107             Next_Arg := Next_Arg + 1;
 108             return; -- ignore this switch
 109
 110          --  Set optimization indicators appropriately. In gcc-based GNAT this
 111          --  is picked up from imported variables set by the gcc driver, but
 112          --  for compilers with non-gcc back ends we do it here to allow use
 113          --  of these switches by the front end. Allowed optimization switches
 114          --  are -Os (optimize for size), -O[0123], and -O (same as -O1).
 115
 116          elsif Switch_Chars (First) = 'O' then
 117             if First = Last then
 118                Optimization_Level := 1;
 119
 120             elsif Last - First = 1 then
 121                if Switch_Chars (Last) = 's' then
 122                   Optimize_Size := 1;
 123                   Optimization_Level := 2;  -- Consistent with gcc setting
 124
 125                elsif Switch_Chars (Last) in '0' .. '3' then
 126                   Optimization_Level :=
 127                     Character'Pos (Switch_Chars (Last)) - Character'Pos ('0');
 128
 129                else
 130                   Fail ("invalid switch: " & Switch_Chars);
 131                end if;
 132
 133             else
 134                Fail ("invalid switch: " & Switch_Chars);
 135             end if;
 136
 137          elsif Switch_Chars (First .. Last) = "quiet" then
 138             return; -- ignore this switch
 139
 140          elsif Switch_Chars (First .. Last) = "c" then
 141             return; -- ignore this switch
 142
 143          --  The -x switch and its language name argument will generally be
 144          --  ignored by non-gcc back ends. In any case, we save the switch and
 145          --  argument in the compilation switches.
 146
 147          elsif Switch_Chars (First .. Last) = "x" then
 148             Lib.Store_Compilation_Switch (Switch_Chars);
 149             Next_Arg := Next_Arg + 1;
 150
 151             declare
 152                Argv : constant String := Args (Next_Arg).all;
 153
 154             begin
 155                if Is_Switch (Argv) then
 156                   Fail ("language name missing after -x");
 157                else
 158                   Lib.Store_Compilation_Switch (Argv);
 159                end if;
 160             end;
 161
 162             return;
 163
 164          --  Special check, the back end switch -fno-inline also sets the
 165          --  front end flags to entirely inhibit all inlining. So we store it
 166          --  and set the appropriate flags.
 167
 168          elsif Switch_Chars (First .. Last) = "fno-inline" then
 169             Lib.Store_Compilation_Switch (Switch_Chars);
 170             Opt.Disable_FE_Inline := True;
 171             Opt.Disable_FE_Inline_Always := True;
 172             return;
 173
 174          --  Similar processing for -fpreserve-control-flow
 175
 176          elsif Switch_Chars (First .. Last) = "fpreserve-control-flow" then
 177             Lib.Store_Compilation_Switch (Switch_Chars);
 178             Opt.Suppress_Control_Flow_Optimizations := True;
 179             return;
 180
 181          --  Ignore all other back end switches
 182
 183          elsif Is_Back_End_Switch (Switch_Chars) then
 184             null;
 185
 186          --  Give error for junk switch
 187
 188          else
 189             Fail ("invalid switch: " & Switch_Chars);
 190          end if;
 191
 192          --  Store any other GCC switches
 193
 194          Lib.Store_Compilation_Switch (Switch_Chars);
 195       end Scan_Back_End_Switches;
 196
 197    --  Start of processing for Scan_Compiler_Args
 198
 199    begin
 200       --  Put all the arguments in argument list Args
 201
 202       for Arg in 1 .. Argument_Count loop
 203          declare
 204             Argv : String (1 .. Len_Arg (Arg));
 205          begin
 206             Fill_Arg (Argv'Address, Arg);
 207             Args (Arg) := new String'(Argv);
 208          end;
 209       end loop;
 210
 211       --  Loop through command line arguments, storing them for later access
 212
 213       while Next_Arg <= Argument_Count loop
 214          Look_At_Arg : declare
 215             Argv : constant String := Args (Next_Arg).all;
 216
 217          begin
 218             if Argv'Length = 0 then
 219                Fail ("Empty argument");
 220             end if;
 221
 222             --  If the previous switch has set the Output_File_Name_Present
 223             --  flag (that is we have seen a -gnatO), then the next argument
 224             --  is the name of the output object file.
 225
 226             if Opt.Output_File_Name_Present
 227               and then not Output_File_Name_Seen
 228             then
 229                if Is_Switch (Argv) then
 230                   Fail ("Object file name missing after -gnatO");
 231                else
 232                   Set_Output_Object_File_Name (Argv);
 233                   Output_File_Name_Seen := True;
 234                end if;
 235
 236                --  If the previous switch has set the Search_Directory_Present
 237                --  flag (that is if we have just seen -I), then the next
 238                --  argument is a search directory path.
 239
 240             elsif Search_Directory_Present then
 241                if Is_Switch (Argv) then
 242                   Fail ("search directory missing after -I");
 243                else
 244                   Add_Src_Search_Dir (Argv);
 245
 246                   --  Add directory to lib search so that back-end can take as
 247                   --  input ALI files if needed. Otherwise this won't have any
 248                   --  impact on the compiler.
 249
 250                   Add_Lib_Search_Dir (Argv);
 251
 252                   Search_Directory_Present := False;
 253                end if;
 254
 255             --  If not a switch, must be a file name
 256
 257             elsif not Is_Switch (Argv) then
 258                Add_File (Argv);
 259
 260             --  We must recognize -nostdinc to suppress visibility on the
 261             --  standard GNAT RTL sources.
 262
 263             elsif Argv (Argv'First + 1 .. Argv'Last) = "nostdinc" then
 264                Opt.No_Stdinc := True;
 265
 266             --  Front end switch
 267
 268             elsif Is_Front_End_Switch (Argv) then
 269                Scan_Front_End_Switches (Argv, Args, Next_Arg);
 270
 271             --  All non-front-end switches are back-end switches
 272
 273             else
 274                Scan_Back_End_Switches (Argv);
 275             end if;
 276          end Look_At_Arg;
 277
 278          Next_Arg := Next_Arg + 1;
 279       end loop;
 280    end Scan_Compiler_Arguments;
 281
 282 end Adabkend;