gcc/ada/lib-xref.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . X R E F                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2016, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Csets;    use Csets;
  28 with Elists;   use Elists;
  29 with Errout;   use Errout;
  30 with Nlists;   use Nlists;
  31 with Opt;      use Opt;
  32 with Restrict; use Restrict;
  33 with Rident;   use Rident;
  34 with Sem;      use Sem;
  35 with Sem_Aux;  use Sem_Aux;
  36 with Sem_Prag; use Sem_Prag;
  37 with Sem_Util; use Sem_Util;
  38 with Sem_Warn; use Sem_Warn;
  39 with Sinfo;    use Sinfo;
  40 with Sinput;   use Sinput;
  41 with Snames;   use Snames;
  42 with Stringt;  use Stringt;
  43 with Stand;    use Stand;
  44 with Table;    use Table;
  45
  46 with GNAT.Heap_Sort_G;
  47 with GNAT.HTable;
  48
  49 package body Lib.Xref is
  50
  51    ------------------
  52    -- Declarations --
  53    ------------------
  54
  55    --  The Xref table is used to record references. The Loc field is set
  56    --  to No_Location for a definition entry.
  57
  58    subtype Xref_Entry_Number is Int;
  59
  60    type Xref_Key is record
  61       --  These are the components of Xref_Entry that participate in hash
  62       --  lookups.
  63
  64       Ent : Entity_Id;
  65       --  Entity referenced (E parameter to Generate_Reference)
  66
  67       Loc : Source_Ptr;
  68       --  Location of reference (Original_Location (Sloc field of N parameter
  69       --  to Generate_Reference)). Set to No_Location for the case of a
  70       --  defining occurrence.
  71
  72       Typ : Character;
  73       --  Reference type (Typ param to Generate_Reference)
  74
  75       Eun : Unit_Number_Type;
  76       --  Unit number corresponding to Ent
  77
  78       Lun : Unit_Number_Type;
  79       --  Unit number corresponding to Loc. Value is undefined and not
  80       --  referenced if Loc is set to No_Location.
  81
  82       --  The following components are only used for SPARK cross-references
  83
  84       Ref_Scope : Entity_Id;
  85       --  Entity of the closest subprogram or package enclosing the reference
  86
  87       Ent_Scope : Entity_Id;
  88       --  Entity of the closest subprogram or package enclosing the definition,
  89       --  which should be located in the same file as the definition itself.
  90    end record;
  91
  92    type Xref_Entry is record
  93       Key : Xref_Key;
  94
  95       Ent_Scope_File : Unit_Number_Type;
  96       --  File for entity Ent_Scope
  97
  98       Def : Source_Ptr;
  99       --  Original source location for entity being referenced. Note that these
 100       --  values are used only during the output process, they are not set when
 101       --  the entries are originally built. This is because private entities
 102       --  can be swapped when the initial call is made.
 103
 104       HTable_Next : Xref_Entry_Number;
 105       --  For use only by Static_HTable
 106    end record;
 107
 108    package Xrefs is new Table.Table (
 109      Table_Component_Type => Xref_Entry,
 110      Table_Index_Type     => Xref_Entry_Number,
 111      Table_Low_Bound      => 1,
 112      Table_Initial        => Alloc.Xrefs_Initial,
 113      Table_Increment      => Alloc.Xrefs_Increment,
 114      Table_Name           => "Xrefs");
 115
 116    --------------
 117    -- Xref_Set --
 118    --------------
 119
 120    --  We keep a set of xref entries, in order to avoid inserting duplicate
 121    --  entries into the above Xrefs table. An entry is in Xref_Set if and only
 122    --  if it is in Xrefs.
 123
 124    Num_Buckets : constant := 2**16;
 125
 126    subtype Header_Num is Integer range 0 .. Num_Buckets - 1;
 127    type Null_Type is null record;
 128    pragma Unreferenced (Null_Type);
 129
 130    function Hash (F : Xref_Entry_Number) return Header_Num;
 131
 132    function Equal (F1, F2 : Xref_Entry_Number) return Boolean;
 133
 134    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number);
 135
 136    function  HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number;
 137
 138    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number;
 139
 140    pragma Inline (Hash, Equal, HT_Set_Next, HT_Next, Get_Key);
 141
 142    package Xref_Set is new GNAT.HTable.Static_HTable (
 143      Header_Num,
 144      Element    => Xref_Entry,
 145      Elmt_Ptr   => Xref_Entry_Number,
 146      Null_Ptr   => 0,
 147      Set_Next   => HT_Set_Next,
 148      Next       => HT_Next,
 149      Key        => Xref_Entry_Number,
 150      Get_Key    => Get_Key,
 151      Hash       => Hash,
 152      Equal      => Equal);
 153
 154    -----------------------------
 155    -- SPARK Xrefs Information --
 156    -----------------------------
 157
 158    package body SPARK_Specific is separate;
 159
 160    ------------------------
 161    --  Local Subprograms --
 162    ------------------------
 163
 164    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type);
 165    --  Add an entry to the tables of Xref_Entries, avoiding duplicates
 166
 167    procedure Generate_Prim_Op_References (Typ : Entity_Id);
 168    --  For a tagged type, generate implicit references to its primitive
 169    --  operations, for source navigation. This is done right before emitting
 170    --  cross-reference information rather than at the freeze point of the type
 171    --  in order to handle late bodies that are primitive operations.
 172
 173    function Lt (T1, T2 : Xref_Entry) return Boolean;
 174    --  Order cross-references
 175
 176    ---------------
 177    -- Add_Entry --
 178    ---------------
 179
 180    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type) is
 181    begin
 182       Xrefs.Increment_Last; -- tentative
 183       Xrefs.Table (Xrefs.Last).Key := Key;
 184
 185       --  Set the entry in Xref_Set, and if newly set, keep the above
 186       --  tentative increment.
 187
 188       if Xref_Set.Set_If_Not_Present (Xrefs.Last) then
 189          Xrefs.Table (Xrefs.Last).Ent_Scope_File := Ent_Scope_File;
 190          --  Leave Def and HTable_Next uninitialized
 191
 192          Set_Has_Xref_Entry (Key.Ent);
 193
 194       --  It was already in Xref_Set, so throw away the tentatively-added
 195       --  entry.
 196
 197       else
 198          Xrefs.Decrement_Last;
 199       end if;
 200    end Add_Entry;
 201
 202    -----------
 203    -- Equal --
 204    -----------
 205
 206    function Equal (F1, F2 : Xref_Entry_Number) return Boolean is
 207       Result : constant Boolean :=
 208                  Xrefs.Table (F1).Key = Xrefs.Table (F2).Key;
 209    begin
 210       return Result;
 211    end Equal;
 212
 213    -------------------------
 214    -- Generate_Definition --
 215    -------------------------
 216
 217    procedure Generate_Definition (E : Entity_Id) is
 218    begin
 219       pragma Assert (Nkind (E) in N_Entity);
 220
 221       --  Note that we do not test Xref_Entity_Letters here. It is too early
 222       --  to do so, since we are often called before the entity is fully
 223       --  constructed, so that the Ekind is still E_Void.
 224
 225       if Opt.Xref_Active
 226
 227          --  Definition must come from source
 228
 229          --  We make an exception for subprogram child units that have no spec.
 230          --  For these we generate a subprogram declaration for library use,
 231          --  and the corresponding entity does not come from source.
 232          --  Nevertheless, all references will be attached to it and we have
 233          --  to treat is as coming from user code.
 234
 235          and then (Comes_From_Source (E) or else Is_Child_Unit (E))
 236
 237          --  And must have a reasonable source location that is not
 238          --  within an instance (all entities in instances are ignored)
 239
 240          and then Sloc (E) > No_Location
 241          and then Instantiation_Location (Sloc (E)) = No_Location
 242
 243          --  And must be a non-internal name from the main source unit
 244
 245          and then In_Extended_Main_Source_Unit (E)
 246          and then not Is_Internal_Name (Chars (E))
 247       then
 248          Add_Entry
 249            ((Ent => E,
 250              Loc => No_Location,
 251              Typ => ' ',
 252              Eun => Get_Source_Unit (Original_Location (Sloc (E))),
 253              Lun => No_Unit,
 254              Ref_Scope => Empty,
 255              Ent_Scope => Empty),
 256             Ent_Scope_File => No_Unit);
 257
 258          if In_Inlined_Body then
 259             Set_Referenced (E);
 260          end if;
 261       end if;
 262    end Generate_Definition;
 263
 264    ---------------------------------
 265    -- Generate_Operator_Reference --
 266    ---------------------------------
 267
 268    procedure Generate_Operator_Reference
 269      (N : Node_Id;
 270       T : Entity_Id)
 271    is
 272    begin
 273       if not In_Extended_Main_Source_Unit (N) then
 274          return;
 275       end if;
 276
 277       --  If the operator is not a Standard operator, then we generate a real
 278       --  reference to the user defined operator.
 279
 280       if Sloc (Entity (N)) /= Standard_Location then
 281          Generate_Reference (Entity (N), N);
 282
 283          --  A reference to an implicit inequality operator is also a reference
 284          --  to the user-defined equality.
 285
 286          if Nkind (N) = N_Op_Ne
 287            and then not Comes_From_Source (Entity (N))
 288            and then Present (Corresponding_Equality (Entity (N)))
 289          then
 290             Generate_Reference (Corresponding_Equality (Entity (N)), N);
 291          end if;
 292
 293       --  For the case of Standard operators, we mark the result type as
 294       --  referenced. This ensures that in the case where we are using a
 295       --  derived operator, we mark an entity of the unit that implicitly
 296       --  defines this operator as used. Otherwise we may think that no entity
 297       --  of the unit is used. The actual entity marked as referenced is the
 298       --  first subtype, which is the relevant user defined entity.
 299
 300       --  Note: we only do this for operators that come from source. The
 301       --  generated code sometimes reaches for entities that do not need to be
 302       --  explicitly visible (for example, when we expand the code for
 303       --  comparing two record objects, the fields of the record may not be
 304       --  visible).
 305
 306       elsif Comes_From_Source (N) then
 307          Set_Referenced (First_Subtype (T));
 308       end if;
 309    end Generate_Operator_Reference;
 310
 311    ---------------------------------
 312    -- Generate_Prim_Op_References --
 313    ---------------------------------
 314
 315    procedure Generate_Prim_Op_References (Typ : Entity_Id) is
 316       Base_T    : Entity_Id;
 317       Prim      : Elmt_Id;
 318       Prim_List : Elist_Id;
 319
 320    begin
 321       --  Handle subtypes of synchronized types
 322
 323       if Ekind (Typ) = E_Protected_Subtype
 324         or else Ekind (Typ) = E_Task_Subtype
 325       then
 326          Base_T := Etype (Typ);
 327       else
 328          Base_T := Typ;
 329       end if;
 330
 331       --  References to primitive operations are only relevant for tagged types
 332
 333       if not Is_Tagged_Type (Base_T)
 334         or else Is_Class_Wide_Type (Base_T)
 335       then
 336          return;
 337       end if;
 338
 339       --  Ada 2005 (AI-345): For synchronized types generate reference to the
 340       --  wrapper that allow us to dispatch calls through their implemented
 341       --  abstract interface types.
 342
 343       --  The check for Present here is to protect against previously reported
 344       --  critical errors.
 345
 346       Prim_List := Primitive_Operations (Base_T);
 347
 348       if No (Prim_List) then
 349          return;
 350       end if;
 351
 352       Prim := First_Elmt (Prim_List);
 353       while Present (Prim) loop
 354
 355          --  If the operation is derived, get the original for cross-reference
 356          --  reference purposes (it is the original for which we want the xref
 357          --  and for which the comes_from_source test must be performed).
 358
 359          Generate_Reference
 360            (Typ, Ultimate_Alias (Node (Prim)), 'p', Set_Ref => False);
 361          Next_Elmt (Prim);
 362       end loop;
 363    end Generate_Prim_Op_References;
 364
 365    ------------------------
 366    -- Generate_Reference --
 367    ------------------------
 368
 369    procedure Generate_Reference
 370      (E       : Entity_Id;
 371       N       : Node_Id;
 372       Typ     : Character := 'r';
 373       Set_Ref : Boolean   := True;
 374       Force   : Boolean   := False)
 375    is
 376       Actual_Typ     : Character := Typ;
 377       Call           : Node_Id;
 378       Def            : Source_Ptr;
 379       Ent            : Entity_Id;
 380       Ent_Scope      : Entity_Id;
 381       Formal         : Entity_Id;
 382       Kind           : Entity_Kind;
 383       Nod            : Node_Id;
 384       Ref            : Source_Ptr;
 385       Ref_Scope      : Entity_Id;
 386
 387       function Get_Through_Renamings (E : Entity_Id) return Entity_Id;
 388       --  Get the enclosing entity through renamings, which may come from
 389       --  source or from the translation of generic instantiations.
 390
 391       function Is_On_LHS (Node : Node_Id) return Boolean;
 392       --  Used to check if a node is on the left hand side of an assignment.
 393       --  The following cases are handled:
 394       --
 395       --   Variable    Node is a direct descendant of left hand side of an
 396       --               assignment statement.
 397       --
 398       --   Prefix      Of an indexed or selected component that is present in
 399       --               a subtree rooted by an assignment statement. There is
 400       --               no restriction of nesting of components, thus cases
 401       --               such as A.B (C).D are handled properly. However a prefix
 402       --               of a dereference (either implicit or explicit) is never
 403       --               considered as on a LHS.
 404       --
 405       --   Out param   Same as above cases, but OUT parameter
 406
 407       function OK_To_Set_Referenced return Boolean;
 408       --  Returns True if the Referenced flag can be set. There are a few
 409       --  exceptions where we do not want to set this flag, see body for
 410       --  details of these exceptional cases.
 411
 412       ---------------------------
 413       -- Get_Through_Renamings --
 414       ---------------------------
 415
 416       function Get_Through_Renamings (E : Entity_Id) return Entity_Id is
 417          Result : Entity_Id := E;
 418
 419       begin
 420          while Present (Result)
 421            and then Is_Object (Result)
 422            and then Present (Renamed_Object (Result))
 423          loop
 424             Result := Get_Enclosing_Object (Renamed_Object (Result));
 425          end loop;
 426
 427          return Result;
 428       end Get_Through_Renamings;
 429
 430       ---------------
 431       -- Is_On_LHS --
 432       ---------------
 433
 434       --  ??? There are several routines here and there that perform a similar
 435       --      (but subtly different) computation, which should be factored:
 436
 437       --      Sem_Util.Is_LHS
 438       --      Sem_Util.May_Be_Lvalue
 439       --      Sem_Util.Known_To_Be_Assigned
 440       --      Exp_Ch2.Expand_Entry_Parameter.In_Assignment_Context
 441       --      Exp_Smem.Is_Out_Actual
 442
 443       function Is_On_LHS (Node : Node_Id) return Boolean is
 444          N : Node_Id;
 445          P : Node_Id;
 446          K : Node_Kind;
 447
 448       begin
 449          --  Only identifiers are considered, is this necessary???
 450
 451          if Nkind (Node) /= N_Identifier then
 452             return False;
 453          end if;
 454
 455          --  Immediate return if appeared as OUT parameter
 456
 457          if Kind = E_Out_Parameter then
 458             return True;
 459          end if;
 460
 461          --  Search for assignment statement subtree root
 462
 463          N := Node;
 464          loop
 465             P := Parent (N);
 466             K := Nkind (P);
 467
 468             if K = N_Assignment_Statement then
 469                return Name (P) = N;
 470
 471             --  Check whether the parent is a component and the current node is
 472             --  its prefix, but return False if the current node has an access
 473             --  type, as in that case the selected or indexed component is an
 474             --  implicit dereference, and the LHS is the designated object, not
 475             --  the access object.
 476
 477             --  ??? case of a slice assignment?
 478
 479             elsif (K = N_Selected_Component or else K = N_Indexed_Component)
 480               and then Prefix (P) = N
 481             then
 482                --  Check for access type. First a special test, In some cases
 483                --  this is called too early (see comments in Find_Direct_Name),
 484                --  at a point where the tree is not fully typed yet. In that
 485                --  case we may lack an Etype for N, and we can't check the
 486                --  Etype. For now, we always return False in such a case,
 487                --  but this is clearly not right in all cases ???
 488
 489                if No (Etype (N)) then
 490                   return False;
 491
 492                elsif Is_Access_Type (Etype (N)) then
 493                   return False;
 494
 495                --  Access type case dealt with, keep going
 496
 497                else
 498                   N := P;
 499                end if;
 500
 501             --  All other cases, definitely not on left side
 502
 503             else
 504                return False;
 505             end if;
 506          end loop;
 507       end Is_On_LHS;
 508
 509       ---------------------------
 510       -- OK_To_Set_Referenced --
 511       ---------------------------
 512
 513       function OK_To_Set_Referenced return Boolean is
 514          P : Node_Id;
 515
 516       begin
 517          --  A reference from a pragma Unreferenced or pragma Unmodified or
 518          --  pragma Warnings does not cause the Referenced flag to be set.
 519          --  This avoids silly warnings about things being referenced and
 520          --  not assigned when the only reference is from the pragma.
 521
 522          if Nkind (N) = N_Identifier then
 523             P := Parent (N);
 524
 525             if Nkind (P) = N_Pragma_Argument_Association then
 526                P := Parent (P);
 527
 528                if Nkind (P) = N_Pragma then
 529                   if Nam_In (Pragma_Name (P), Name_Warnings,
 530                                               Name_Unmodified,
 531                                               Name_Unreferenced)
 532                   then
 533                      return False;
 534                   end if;
 535                end if;
 536
 537             --  A reference to a formal in a named parameter association does
 538             --  not make the formal referenced. Formals that are unused in the
 539             --  subprogram body are properly flagged as such, even if calls
 540             --  elsewhere use named notation.
 541
 542             elsif Nkind (P) = N_Parameter_Association
 543               and then N = Selector_Name (P)
 544             then
 545                return False;
 546             end if;
 547          end if;
 548
 549          return True;
 550       end OK_To_Set_Referenced;
 551
 552    --  Start of processing for Generate_Reference
 553
 554    begin
 555       pragma Assert (Nkind (E) in N_Entity);
 556       Find_Actual (N, Formal, Call);
 557
 558       if Present (Formal) then
 559          Kind := Ekind (Formal);
 560       else
 561          Kind := E_Void;
 562       end if;
 563
 564       --  Check for obsolescent reference to package ASCII. GNAT treats this
 565       --  element of annex J specially since in practice, programs make a lot
 566       --  of use of this feature, so we don't include it in the set of features
 567       --  diagnosed when Warn_On_Obsolescent_Features mode is set. However we
 568       --  are required to note it as a violation of the RM defined restriction.
 569
 570       if E = Standard_ASCII then
 571          Check_Restriction (No_Obsolescent_Features, N);
 572       end if;
 573
 574       --  Check for reference to entity marked with Is_Obsolescent
 575
 576       --  Note that we always allow obsolescent references in the compiler
 577       --  itself and the run time, since we assume that we know what we are
 578       --  doing in such cases. For example the calls in Ada.Characters.Handling
 579       --  to its own obsolescent subprograms are just fine.
 580
 581       --  In any case we only generate warnings if we are in the extended main
 582       --  source unit, and the entity itself is not in the extended main source
 583       --  unit, since we assume the source unit itself knows what is going on
 584       --  (and for sure we do not want silly warnings, e.g. on the end line of
 585       --  an obsolescent procedure body).
 586
 587       if Is_Obsolescent (E)
 588         and then not GNAT_Mode
 589         and then not In_Extended_Main_Source_Unit (E)
 590         and then In_Extended_Main_Source_Unit (N)
 591       then
 592          Check_Restriction (No_Obsolescent_Features, N);
 593
 594          if Warn_On_Obsolescent_Feature then
 595             Output_Obsolescent_Entity_Warnings (N, E);
 596          end if;
 597       end if;
 598
 599       --  Warn if reference to Ada 2005 entity not in Ada 2005 mode. We only
 600       --  detect real explicit references (modifications and references).
 601
 602       if Comes_From_Source (N)
 603         and then Is_Ada_2005_Only (E)
 604         and then Ada_Version < Ada_2005
 605         and then Warn_On_Ada_2005_Compatibility
 606         and then (Typ = 'm' or else Typ = 'r' or else Typ = 's')
 607       then
 608          Error_Msg_NE ("& is only defined in Ada 2005?y?", N, E);
 609       end if;
 610
 611       --  Warn if reference to Ada 2012 entity not in Ada 2012 mode. We only
 612       --  detect real explicit references (modifications and references).
 613
 614       if Comes_From_Source (N)
 615         and then Is_Ada_2012_Only (E)
 616         and then Ada_Version < Ada_2012
 617         and then Warn_On_Ada_2012_Compatibility
 618         and then (Typ = 'm' or else Typ = 'r')
 619       then
 620          Error_Msg_NE ("& is only defined in Ada 2012?y?", N, E);
 621       end if;
 622
 623       --  Do not generate references if we are within a postcondition sub-
 624       --  program, because the reference does not comes from source, and the
 625       --  pre-analysis of the aspect has already created an entry for the ALI
 626       --  file at the proper source location.
 627
 628       if Chars (Current_Scope) = Name_uPostconditions then
 629          return;
 630       end if;
 631
 632       --  Never collect references if not in main source unit. However, we omit
 633       --  this test if Typ is 'e' or 'k', since these entries are structural,
 634       --  and it is useful to have them in units that reference packages as
 635       --  well as units that define packages. We also omit the test for the
 636       --  case of 'p' since we want to include inherited primitive operations
 637       --  from other packages.
 638
 639       --  We also omit this test is this is a body reference for a subprogram
 640       --  instantiation. In this case the reference is to the generic body,
 641       --  which clearly need not be in the main unit containing the instance.
 642       --  For the same reason we accept an implicit reference generated for
 643       --  a default in an instance.
 644
 645       --  We also set the referenced flag in a generic package that is not in
 646       --  then main source unit, when the variable is of a formal private type,
 647       --  to warn in the instance if the corresponding type is not a fully
 648       --  initialized type.
 649
 650       if not In_Extended_Main_Source_Unit (N) then
 651          if Typ = 'e' or else
 652             Typ = 'I' or else
 653             Typ = 'p' or else
 654             Typ = 'i' or else
 655             Typ = 'k'
 656            or else (Typ = 'b' and then Is_Generic_Instance (E))
 657
 658             --  Allow the generation of references to reads, writes and calls
 659             --  in SPARK mode when the related context comes from an instance.
 660
 661            or else
 662              (GNATprove_Mode
 663                and then In_Extended_Main_Code_Unit (N)
 664                and then (Typ = 'm' or else Typ = 'r' or else Typ = 's'))
 665          then
 666             null;
 667
 668          elsif In_Instance_Body
 669            and then In_Extended_Main_Code_Unit (N)
 670            and then Is_Generic_Type (Etype (E))
 671          then
 672             Set_Referenced (E);
 673             return;
 674
 675          elsif Inside_A_Generic
 676            and then Is_Generic_Type (Etype (E))
 677          then
 678             Set_Referenced (E);
 679             return;
 680
 681          else
 682             return;
 683          end if;
 684       end if;
 685
 686       --  For reference type p, the entity must be in main source unit
 687
 688       if Typ = 'p' and then not In_Extended_Main_Source_Unit (E) then
 689          return;
 690       end if;
 691
 692       --  Unless the reference is forced, we ignore references where the
 693       --  reference itself does not come from source.
 694
 695       if not Force and then not Comes_From_Source (N) then
 696          return;
 697       end if;
 698
 699       --  Deal with setting entity as referenced, unless suppressed. Note that
 700       --  we still do Set_Referenced on entities that do not come from source.
 701       --  This situation arises when we have a source reference to a derived
 702       --  operation, where the derived operation itself does not come from
 703       --  source, but we still want to mark it as referenced, since we really
 704       --  are referencing an entity in the corresponding package (this avoids
 705       --  wrong complaints that the package contains no referenced entities).
 706
 707       if Set_Ref then
 708
 709          --  Assignable object appearing on left side of assignment or as
 710          --  an out parameter.
 711
 712          if Is_Assignable (E)
 713            and then Is_On_LHS (N)
 714            and then Ekind (E) /= E_In_Out_Parameter
 715          then
 716             --  For objects that are renamings, just set as simply referenced
 717             --  we do not try to do assignment type tracking in this case.
 718
 719             if Present (Renamed_Object (E)) then
 720                Set_Referenced (E);
 721
 722             --  Out parameter case
 723
 724             elsif Kind = E_Out_Parameter then
 725
 726                --  If warning mode for all out parameters is set, or this is
 727                --  the only warning parameter, then we want to mark this for
 728                --  later warning logic by setting Referenced_As_Out_Parameter
 729
 730                if Warn_On_Modified_As_Out_Parameter (Formal) then
 731                   Set_Referenced_As_Out_Parameter (E, True);
 732                   Set_Referenced_As_LHS (E, False);
 733
 734                --  For OUT parameter not covered by the above cases, we simply
 735                --  regard it as a normal reference (in this case we do not
 736                --  want any of the warning machinery for out parameters).
 737
 738                else
 739                   Set_Referenced (E);
 740                end if;
 741
 742             --  For the left hand of an assignment case, we do nothing here.
 743             --  The processing for Analyze_Assignment_Statement will set the
 744             --  Referenced_As_LHS flag.
 745
 746             else
 747                null;
 748             end if;
 749
 750          --  Check for a reference in a pragma that should not count as a
 751          --  making the variable referenced for warning purposes.
 752
 753          elsif Is_Non_Significant_Pragma_Reference (N) then
 754             null;
 755
 756          --  A reference in an attribute definition clause does not count as a
 757          --  reference except for the case of Address. The reason that 'Address
 758          --  is an exception is that it creates an alias through which the
 759          --  variable may be referenced.
 760
 761          elsif Nkind (Parent (N)) = N_Attribute_Definition_Clause
 762            and then Chars (Parent (N)) /= Name_Address
 763            and then N = Name (Parent (N))
 764          then
 765             null;
 766
 767          --  Constant completion does not count as a reference
 768
 769          elsif Typ = 'c'
 770            and then Ekind (E) = E_Constant
 771          then
 772             null;
 773
 774          --  Record representation clause does not count as a reference
 775
 776          elsif Nkind (N) = N_Identifier
 777            and then Nkind (Parent (N)) = N_Record_Representation_Clause
 778          then
 779             null;
 780
 781          --  Discriminants do not need to produce a reference to record type
 782
 783          elsif Typ = 'd'
 784            and then Nkind (Parent (N)) = N_Discriminant_Specification
 785          then
 786             null;
 787
 788          --  All other cases
 789
 790          else
 791             --  Special processing for IN OUT parameters, where we have an
 792             --  implicit assignment to a simple variable.
 793
 794             if Kind = E_In_Out_Parameter
 795               and then Is_Assignable (E)
 796             then
 797                --  For sure this counts as a normal read reference
 798
 799                Set_Referenced (E);
 800                Set_Last_Assignment (E, Empty);
 801
 802                --  We count it as being referenced as an out parameter if the
 803                --  option is set to warn on all out parameters, except that we
 804                --  have a special exclusion for an intrinsic subprogram, which
 805                --  is most likely an instantiation of Unchecked_Deallocation
 806                --  which we do not want to consider as an assignment since it
 807                --  generates false positives. We also exclude the case of an
 808                --  IN OUT parameter if the name of the procedure is Free,
 809                --  since we suspect similar semantics.
 810
 811                if Warn_On_All_Unread_Out_Parameters
 812                  and then Is_Entity_Name (Name (Call))
 813                  and then not Is_Intrinsic_Subprogram (Entity (Name (Call)))
 814                  and then Chars (Name (Call)) /= Name_Free
 815                then
 816                   Set_Referenced_As_Out_Parameter (E, True);
 817                   Set_Referenced_As_LHS (E, False);
 818                end if;
 819
 820             --  Don't count a recursive reference within a subprogram as a
 821             --  reference (that allows detection of a recursive subprogram
 822             --  whose only references are recursive calls as unreferenced).
 823
 824             elsif Is_Subprogram (E)
 825               and then E = Nearest_Dynamic_Scope (Current_Scope)
 826             then
 827                null;
 828
 829             --  Any other occurrence counts as referencing the entity
 830
 831             elsif OK_To_Set_Referenced then
 832                Set_Referenced (E);
 833
 834                --  If variable, this is an OK reference after an assignment
 835                --  so we can clear the Last_Assignment indication.
 836
 837                if Is_Assignable (E) then
 838                   Set_Last_Assignment (E, Empty);
 839                end if;
 840             end if;
 841          end if;
 842
 843          --  Check for pragma Unreferenced given and reference is within
 844          --  this source unit (occasion for possible warning to be issued).
 845
 846          if Has_Unreferenced (E)
 847            and then In_Same_Extended_Unit (E, N)
 848          then
 849             --  A reference as a named parameter in a call does not count
 850             --  as a violation of pragma Unreferenced for this purpose...
 851
 852             if Nkind (N) = N_Identifier
 853               and then Nkind (Parent (N)) = N_Parameter_Association
 854               and then Selector_Name (Parent (N)) = N
 855             then
 856                null;
 857
 858             --  ... Neither does a reference to a variable on the left side
 859             --  of an assignment.
 860
 861             elsif Is_On_LHS (N) then
 862                null;
 863
 864             --  For entry formals, we want to place the warning message on the
 865             --  corresponding entity in the accept statement. The current scope
 866             --  is the body of the accept, so we find the formal whose name
 867             --  matches that of the entry formal (there is no link between the
 868             --  two entities, and the one in the accept statement is only used
 869             --  for conformance checking).
 870
 871             elsif Ekind (Scope (E)) = E_Entry then
 872                declare
 873                   BE : Entity_Id;
 874
 875                begin
 876                   BE := First_Entity (Current_Scope);
 877                   while Present (BE) loop
 878                      if Chars (BE) = Chars (E) then
 879                         Error_Msg_NE -- CODEFIX
 880                           ("??pragma Unreferenced given for&!", N, BE);
 881                         exit;
 882                      end if;
 883
 884                      Next_Entity (BE);
 885                   end loop;
 886                end;
 887
 888             --  Here we issue the warning, since this is a real reference
 889
 890             else
 891                Error_Msg_NE -- CODEFIX
 892                  ("??pragma Unreferenced given for&!", N, E);
 893             end if;
 894          end if;
 895
 896          --  If this is a subprogram instance, mark as well the internal
 897          --  subprogram in the wrapper package, which may be a visible
 898          --  compilation unit.
 899
 900          if Is_Overloadable (E)
 901            and then Is_Generic_Instance (E)
 902            and then Present (Alias (E))
 903          then
 904             Set_Referenced (Alias (E));
 905          end if;
 906       end if;
 907
 908       --  Generate reference if all conditions are met:
 909
 910       if
 911          --  Cross referencing must be active
 912
 913          Opt.Xref_Active
 914
 915          --  The entity must be one for which we collect references
 916
 917          and then Xref_Entity_Letters (Ekind (E)) /= ' '
 918
 919          --  Both Sloc values must be set to something sensible
 920
 921          and then Sloc (E) > No_Location
 922          and then Sloc (N) > No_Location
 923
 924          --  Ignore references from within an instance. The only exceptions to
 925          --  this are default subprograms, for which we generate an implicit
 926          --  reference and compilations in SPARK mode.
 927
 928          and then
 929            (Instantiation_Location (Sloc (N)) = No_Location
 930              or else Typ = 'i'
 931              or else GNATprove_Mode)
 932
 933         --  Ignore dummy references
 934
 935         and then Typ /= ' '
 936       then
 937          if Nkind_In (N, N_Identifier,
 938                          N_Defining_Identifier,
 939                          N_Defining_Operator_Symbol,
 940                          N_Operator_Symbol,
 941                          N_Defining_Character_Literal)
 942            or else Nkind (N) in N_Op
 943            or else (Nkind (N) = N_Character_Literal
 944                      and then Sloc (Entity (N)) /= Standard_Location)
 945          then
 946             Nod := N;
 947
 948          elsif Nkind_In (N, N_Expanded_Name, N_Selected_Component) then
 949             Nod := Selector_Name (N);
 950
 951          else
 952             return;
 953          end if;
 954
 955          --  Normal case of source entity comes from source
 956
 957          if Comes_From_Source (E) then
 958             Ent := E;
 959
 960          --  Because a declaration may be generated for a subprogram body
 961          --  without declaration in GNATprove mode, for inlining, some
 962          --  parameters may end up being marked as not coming from source
 963          --  although they are. Take these into account specially.
 964
 965          elsif GNATprove_Mode and then Ekind (E) in Formal_Kind then
 966             Ent := E;
 967
 968          --  Entity does not come from source, but is a derived subprogram and
 969          --  the derived subprogram comes from source (after one or more
 970          --  derivations) in which case the reference is to parent subprogram.
 971
 972          elsif Is_Overloadable (E)
 973            and then Present (Alias (E))
 974          then
 975             Ent := Alias (E);
 976             while not Comes_From_Source (Ent) loop
 977                if No (Alias (Ent)) then
 978                   return;
 979                end if;
 980
 981                Ent := Alias (Ent);
 982             end loop;
 983
 984          --  The internally created defining entity for a child subprogram
 985          --  that has no previous spec has valid references.
 986
 987          elsif Is_Overloadable (E)
 988            and then Is_Child_Unit (E)
 989          then
 990             Ent := E;
 991
 992          --  Ditto for the formals of such a subprogram
 993
 994          elsif Is_Overloadable (Scope (E))
 995            and then Is_Child_Unit (Scope (E))
 996          then
 997             Ent := E;
 998
 999          --  Record components of discriminated subtypes or derived types must
1000          --  be treated as references to the original component.
1001
1002          elsif Ekind (E) = E_Component
1003            and then Comes_From_Source (Original_Record_Component (E))
1004          then
1005             Ent := Original_Record_Component (E);
1006
1007          --  If this is an expanded reference to a discriminant, recover the
1008          --  original discriminant, which gets the reference.
1009
1010          elsif Ekind (E) = E_In_Parameter
1011            and then  Present (Discriminal_Link (E))
1012          then
1013             Ent := Discriminal_Link (E);
1014             Set_Referenced (Ent);
1015
1016          --  Ignore reference to any other entity that is not from source
1017
1018          else
1019             return;
1020          end if;
1021
1022          --  In SPARK mode, consider the underlying entity renamed instead of
1023          --  the renaming, which is needed to compute a valid set of effects
1024          --  (reads, writes) for the enclosing subprogram.
1025
1026          if GNATprove_Mode then
1027             Ent := Get_Through_Renamings (Ent);
1028
1029             --  If no enclosing object, then it could be a reference to any
1030             --  location not tracked individually, like heap-allocated data.
1031             --  Conservatively approximate this possibility by generating a
1032             --  dereference, and return.
1033
1034             if No (Ent) then
1035                if Actual_Typ = 'w' then
1036                   SPARK_Specific.Generate_Dereference (Nod, 'r');
1037                   SPARK_Specific.Generate_Dereference (Nod, 'w');
1038                else
1039                   SPARK_Specific.Generate_Dereference (Nod, 'r');
1040                end if;
1041
1042                return;
1043             end if;
1044          end if;
1045
1046          --  Record reference to entity
1047
1048          if Actual_Typ = 'p'
1049            and then Is_Subprogram (Nod)
1050            and then Present (Overridden_Operation (Nod))
1051          then
1052             Actual_Typ := 'P';
1053          end if;
1054
1055          --  Comment needed here for special SPARK code ???
1056
1057          if GNATprove_Mode then
1058             Ref := Sloc (Nod);
1059             Def := Sloc (Ent);
1060
1061             Ref_Scope :=
1062               SPARK_Specific.Enclosing_Subprogram_Or_Library_Package (Nod);
1063             Ent_Scope :=
1064               SPARK_Specific.Enclosing_Subprogram_Or_Library_Package (Ent);
1065
1066             --  Since we are reaching through renamings in SPARK mode, we may
1067             --  end up with standard constants. Ignore those.
1068
1069             if Sloc (Ent_Scope) <= Standard_Location
1070               or else Def <= Standard_Location
1071             then
1072                return;
1073             end if;
1074
1075             Add_Entry
1076               ((Ent       => Ent,
1077                 Loc       => Ref,
1078                 Typ       => Actual_Typ,
1079                 Eun       => Get_Code_Unit (Def),
1080                 Lun       => Get_Code_Unit (Ref),
1081                 Ref_Scope => Ref_Scope,
1082                 Ent_Scope => Ent_Scope),
1083                Ent_Scope_File => Get_Code_Unit (Ent));
1084
1085          else
1086             Ref := Original_Location (Sloc (Nod));
1087             Def := Original_Location (Sloc (Ent));
1088
1089             --  If this is an operator symbol, skip the initial quote for
1090             --  navigation purposes. This is not done for the end label,
1091             --  where we want the actual position after the closing quote.
1092
1093             if Typ = 't' then
1094                null;
1095
1096             elsif Nkind (N) = N_Defining_Operator_Symbol
1097               or else Nkind (Nod) = N_Operator_Symbol
1098             then
1099                Ref := Ref + 1;
1100             end if;
1101
1102             Add_Entry
1103               ((Ent       => Ent,
1104                 Loc       => Ref,
1105                 Typ       => Actual_Typ,
1106                 Eun       => Get_Source_Unit (Def),
1107                 Lun       => Get_Source_Unit (Ref),
1108                 Ref_Scope => Empty,
1109                 Ent_Scope => Empty),
1110                Ent_Scope_File => No_Unit);
1111
1112             --  Generate reference to the first private entity
1113
1114             if Typ = 'e'
1115               and then Comes_From_Source (E)
1116               and then Nkind (Ent) = N_Defining_Identifier
1117               and then (Is_Package_Or_Generic_Package (Ent)
1118                          or else Is_Concurrent_Type (Ent))
1119               and then Present (First_Private_Entity (E))
1120               and then In_Extended_Main_Source_Unit (N)
1121             then
1122                --  Handle case in which the full-view and partial-view of the
1123                --  first private entity are swapped.
1124
1125                declare
1126                   First_Private : Entity_Id := First_Private_Entity (E);
1127
1128                begin
1129                   if Is_Private_Type (First_Private)
1130                     and then Present (Full_View (First_Private))
1131                   then
1132                      First_Private := Full_View (First_Private);
1133                   end if;
1134
1135                   Add_Entry
1136                     ((Ent       => Ent,
1137                       Loc       => Sloc (First_Private),
1138                       Typ       => 'E',
1139                       Eun       => Get_Source_Unit (Def),
1140                       Lun       => Get_Source_Unit (Ref),
1141                       Ref_Scope => Empty,
1142                       Ent_Scope => Empty),
1143                      Ent_Scope_File => No_Unit);
1144                end;
1145             end if;
1146          end if;
1147       end if;
1148    end Generate_Reference;
1149
1150    -----------------------------------
1151    -- Generate_Reference_To_Formals --
1152    -----------------------------------
1153
1154    procedure Generate_Reference_To_Formals (E : Entity_Id) is
1155       Formal : Entity_Id;
1156
1157    begin
1158       if Is_Generic_Subprogram (E) then
1159          Formal := First_Entity (E);
1160
1161          while Present (Formal)
1162            and then not Is_Formal (Formal)
1163          loop
1164             Next_Entity (Formal);
1165          end loop;
1166
1167       elsif Ekind (E) in Access_Subprogram_Kind then
1168          Formal := First_Formal (Designated_Type (E));
1169
1170       else
1171          Formal := First_Formal (E);
1172       end if;
1173
1174       while Present (Formal) loop
1175          if Ekind (Formal) = E_In_Parameter then
1176
1177             if Nkind (Parameter_Type (Parent (Formal))) = N_Access_Definition
1178             then
1179                Generate_Reference (E, Formal, '^', False);
1180             else
1181                Generate_Reference (E, Formal, '>', False);
1182             end if;
1183
1184          elsif Ekind (Formal) = E_In_Out_Parameter then
1185             Generate_Reference (E, Formal, '=', False);
1186
1187          else
1188             Generate_Reference (E, Formal, '<', False);
1189          end if;
1190
1191          Next_Formal (Formal);
1192       end loop;
1193    end Generate_Reference_To_Formals;
1194
1195    -------------------------------------------
1196    -- Generate_Reference_To_Generic_Formals --
1197    -------------------------------------------
1198
1199    procedure Generate_Reference_To_Generic_Formals (E : Entity_Id) is
1200       Formal : Entity_Id;
1201
1202    begin
1203       Formal := First_Entity (E);
1204       while Present (Formal) loop
1205          if Comes_From_Source (Formal) then
1206             Generate_Reference (E, Formal, 'z', False);
1207          end if;
1208
1209          Next_Entity (Formal);
1210       end loop;
1211    end Generate_Reference_To_Generic_Formals;
1212
1213    -------------
1214    -- Get_Key --
1215    -------------
1216
1217    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number is
1218    begin
1219       return E;
1220    end Get_Key;
1221
1222    ----------
1223    -- Hash --
1224    ----------
1225
1226    function Hash (F : Xref_Entry_Number) return Header_Num is
1227       --  It is unlikely to have two references to the same entity at the same
1228       --  source location, so the hash function depends only on the Ent and Loc
1229       --  fields.
1230
1231       XE : Xref_Entry renames Xrefs.Table (F);
1232       type M is mod 2**32;
1233
1234       H : constant M := M (XE.Key.Ent) + 2 ** 7 * M (abs XE.Key.Loc);
1235       --  It would be more natural to write:
1236       --
1237       --    H : constant M := M'Mod (XE.Key.Ent) + 2**7 * M'Mod (XE.Key.Loc);
1238       --
1239       --  But we can't use M'Mod, because it prevents bootstrapping with older
1240       --  compilers. Loc can be negative, so we do "abs" before converting.
1241       --  One day this can be cleaned up ???
1242
1243    begin
1244       return Header_Num (H mod Num_Buckets);
1245    end Hash;
1246
1247    -----------------
1248    -- HT_Set_Next --
1249    -----------------
1250
1251    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number) is
1252    begin
1253       Xrefs.Table (E).HTable_Next := Next;
1254    end HT_Set_Next;
1255
1256    -------------
1257    -- HT_Next --
1258    -------------
1259
1260    function HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number is
1261    begin
1262       return Xrefs.Table (E).HTable_Next;
1263    end HT_Next;
1264
1265    ----------------
1266    -- Initialize --
1267    ----------------
1268
1269    procedure Initialize is
1270    begin
1271       Xrefs.Init;
1272    end Initialize;
1273
1274    --------
1275    -- Lt --
1276    --------
1277
1278    function Lt (T1, T2 : Xref_Entry) return Boolean is
1279    begin
1280       --  First test: if entity is in different unit, sort by unit
1281
1282       if T1.Key.Eun /= T2.Key.Eun then
1283          return Dependency_Num (T1.Key.Eun) < Dependency_Num (T2.Key.Eun);
1284
1285       --  Second test: within same unit, sort by entity Sloc
1286
1287       elsif T1.Def /= T2.Def then
1288          return T1.Def < T2.Def;
1289
1290       --  Third test: sort definitions ahead of references
1291
1292       elsif T1.Key.Loc = No_Location then
1293          return True;
1294
1295       elsif T2.Key.Loc = No_Location then
1296          return False;
1297
1298       --  Fourth test: for same entity, sort by reference location unit
1299
1300       elsif T1.Key.Lun /= T2.Key.Lun then
1301          return Dependency_Num (T1.Key.Lun) < Dependency_Num (T2.Key.Lun);
1302
1303       --  Fifth test: order of location within referencing unit
1304
1305       elsif T1.Key.Loc /= T2.Key.Loc then
1306          return T1.Key.Loc < T2.Key.Loc;
1307
1308       --  Finally, for two locations at the same address, we prefer
1309       --  the one that does NOT have the type 'r' so that a modification
1310       --  or extension takes preference, when there are more than one
1311       --  reference at the same location. As a result, in the case of
1312       --  entities that are in-out actuals, the read reference follows
1313       --  the modify reference.
1314
1315       else
1316          return T2.Key.Typ = 'r';
1317       end if;
1318    end Lt;
1319
1320    -----------------------
1321    -- Output_References --
1322    -----------------------
1323
1324    procedure Output_References is
1325
1326       procedure Get_Type_Reference
1327         (Ent   : Entity_Id;
1328          Tref  : out Entity_Id;
1329          Left  : out Character;
1330          Right : out Character);
1331       --  Given an Entity_Id Ent, determines whether a type reference is
1332       --  required. If so, Tref is set to the entity for the type reference
1333       --  and Left and Right are set to the left/right brackets to be output
1334       --  for the reference. If no type reference is required, then Tref is
1335       --  set to Empty, and Left/Right are set to space.
1336
1337       procedure Output_Import_Export_Info (Ent : Entity_Id);
1338       --  Output language and external name information for an interfaced
1339       --  entity, using the format <language, external_name>.
1340
1341       ------------------------
1342       -- Get_Type_Reference --
1343       ------------------------
1344
1345       procedure Get_Type_Reference
1346         (Ent   : Entity_Id;
1347          Tref  : out Entity_Id;
1348          Left  : out Character;
1349          Right : out Character)
1350       is
1351          Sav : Entity_Id;
1352
1353       begin
1354          --  See if we have a type reference
1355
1356          Tref := Ent;
1357          Left := '{';
1358          Right := '}';
1359
1360          loop
1361             Sav := Tref;
1362
1363             --  Processing for types
1364
1365             if Is_Type (Tref) then
1366
1367                --  Case of base type
1368
1369                if Base_Type (Tref) = Tref then
1370
1371                   --  If derived, then get first subtype
1372
1373                   if Tref /= Etype (Tref) then
1374                      Tref := First_Subtype (Etype (Tref));
1375
1376                      --  Set brackets for derived type, but don't override
1377                      --  pointer case since the fact that something is a
1378                      --  pointer is more important.
1379
1380                      if Left /= '(' then
1381                         Left := '<';
1382                         Right := '>';
1383                      end if;
1384
1385                   --  If the completion of a private type is itself a derived
1386                   --  type, we need the parent of the full view.
1387
1388                   elsif Is_Private_Type (Tref)
1389                     and then Present (Full_View (Tref))
1390                     and then Etype (Full_View (Tref)) /= Full_View (Tref)
1391                   then
1392                      Tref := Etype (Full_View (Tref));
1393
1394                      if Left /= '(' then
1395                         Left := '<';
1396                         Right := '>';
1397                      end if;
1398
1399                   --  If non-derived pointer, get directly designated type.
1400                   --  If the type has a full view, all references are on the
1401                   --  partial view that is seen first.
1402
1403                   elsif Is_Access_Type (Tref) then
1404                      Tref := Directly_Designated_Type (Tref);
1405                      Left := '(';
1406                      Right := ')';
1407
1408                   elsif Is_Private_Type (Tref)
1409                     and then Present (Full_View (Tref))
1410                   then
1411                      if Is_Access_Type (Full_View (Tref)) then
1412                         Tref := Directly_Designated_Type (Full_View (Tref));
1413                         Left := '(';
1414                         Right := ')';
1415
1416                      --  If the full view is an array type, we also retrieve
1417                      --  the corresponding component type, because the ali
1418                      --  entry already indicates that this is an array.
1419
1420                      elsif Is_Array_Type (Full_View (Tref)) then
1421                         Tref := Component_Type (Full_View (Tref));
1422                         Left := '(';
1423                         Right := ')';
1424                      end if;
1425
1426                   --  If non-derived array, get component type. Skip component
1427                   --  type for case of String or Wide_String, saves worthwhile
1428                   --  space.
1429
1430                   elsif Is_Array_Type (Tref)
1431                     and then Tref /= Standard_String
1432                     and then Tref /= Standard_Wide_String
1433                   then
1434                      Tref := Component_Type (Tref);
1435                      Left := '(';
1436                      Right := ')';
1437
1438                   --  For other non-derived base types, nothing
1439
1440                   else
1441                      exit;
1442                   end if;
1443
1444                --  For a subtype, go to ancestor subtype
1445
1446                else
1447                   Tref := Ancestor_Subtype (Tref);
1448
1449                   --  If no ancestor subtype, go to base type
1450
1451                   if No (Tref) then
1452                      Tref := Base_Type (Sav);
1453                   end if;
1454                end if;
1455
1456             --  For objects, functions, enum literals, just get type from
1457             --  Etype field.
1458
1459             elsif Is_Object (Tref)
1460               or else Ekind (Tref) = E_Enumeration_Literal
1461               or else Ekind (Tref) = E_Function
1462               or else Ekind (Tref) = E_Operator
1463             then
1464                Tref := Etype (Tref);
1465
1466                --  Another special case: an object of a classwide type
1467                --  initialized with a tag-indeterminate call gets a subtype
1468                --  of the classwide type during expansion. See if the original
1469                --  type in the declaration is named, and return it instead
1470                --  of going to the root type. The expression may be a class-
1471                --  wide function call whose result is on the secondary stack,
1472                --  which forces the declaration to be rewritten as a renaming,
1473                --  so examine the source declaration.
1474
1475                if Ekind (Tref) = E_Class_Wide_Subtype then
1476                   declare
1477                      Decl : constant Node_Id := Original_Node (Parent (Ent));
1478                   begin
1479                      if Nkind (Decl) = N_Object_Declaration
1480                        and then Is_Entity_Name
1481                          (Original_Node ((Object_Definition (Decl))))
1482                      then
1483                         Tref :=
1484                          Entity ((Original_Node ((Object_Definition (Decl)))));
1485                      end if;
1486                   end;
1487                end if;
1488
1489             --  For anything else, exit
1490
1491             else
1492                exit;
1493             end if;
1494
1495             --  Exit if no type reference, or we are stuck in some loop trying
1496             --  to find the type reference, or if the type is standard void
1497             --  type (the latter is an implementation artifact that should not
1498             --  show up in the generated cross-references).
1499
1500             exit when No (Tref)
1501               or else Tref = Sav
1502               or else Tref = Standard_Void_Type;
1503
1504             --  If we have a usable type reference, return, otherwise keep
1505             --  looking for something useful (we are looking for something
1506             --  that either comes from source or standard)
1507
1508             if Sloc (Tref) = Standard_Location
1509               or else Comes_From_Source (Tref)
1510             then
1511                --  If the reference is a subtype created for a generic actual,
1512                --  go actual directly, the inner subtype is not user visible.
1513
1514                if Nkind (Parent (Tref)) = N_Subtype_Declaration
1515                  and then not Comes_From_Source (Parent (Tref))
1516                  and then
1517                   (Is_Wrapper_Package (Scope (Tref))
1518                      or else Is_Generic_Instance (Scope (Tref)))
1519                then
1520                   Tref := First_Subtype (Base_Type (Tref));
1521                end if;
1522
1523                return;
1524             end if;
1525          end loop;
1526
1527          --  If we fall through the loop, no type reference
1528
1529          Tref := Empty;
1530          Left := ' ';
1531          Right := ' ';
1532       end Get_Type_Reference;
1533
1534       -------------------------------
1535       -- Output_Import_Export_Info --
1536       -------------------------------
1537
1538       procedure Output_Import_Export_Info (Ent : Entity_Id) is
1539          Language_Name : Name_Id;
1540          Conv          : constant Convention_Id := Convention (Ent);
1541
1542       begin
1543          --  Generate language name from convention
1544
1545          if Conv  = Convention_C then
1546             Language_Name := Name_C;
1547
1548          elsif Conv = Convention_CPP then
1549             Language_Name := Name_CPP;
1550
1551          elsif Conv = Convention_Ada then
1552             Language_Name := Name_Ada;
1553
1554          else
1555             --  For the moment we ignore all other cases ???
1556
1557             return;
1558          end if;
1559
1560          Write_Info_Char ('<');
1561          Get_Unqualified_Name_String (Language_Name);
1562
1563          for J in 1 .. Name_Len loop
1564             Write_Info_Char (Name_Buffer (J));
1565          end loop;
1566
1567          if Present (Interface_Name (Ent)) then
1568             Write_Info_Char (',');
1569             String_To_Name_Buffer (Strval (Interface_Name (Ent)));
1570
1571             for J in 1 .. Name_Len loop
1572                Write_Info_Char (Name_Buffer (J));
1573             end loop;
1574          end if;
1575
1576          Write_Info_Char ('>');
1577       end Output_Import_Export_Info;
1578
1579    --  Start of processing for Output_References
1580
1581    begin
1582       --  First we add references to the primitive operations of tagged types
1583       --  declared in the main unit.
1584
1585       Handle_Prim_Ops : declare
1586          Ent  : Entity_Id;
1587
1588       begin
1589          for J in 1 .. Xrefs.Last loop
1590             Ent := Xrefs.Table (J).Key.Ent;
1591
1592             if Is_Type (Ent)
1593               and then Is_Tagged_Type (Ent)
1594               and then Is_Base_Type (Ent)
1595               and then In_Extended_Main_Source_Unit (Ent)
1596             then
1597                Generate_Prim_Op_References (Ent);
1598             end if;
1599          end loop;
1600       end Handle_Prim_Ops;
1601
1602       --  Before we go ahead and output the references we have a problem
1603       --  that needs dealing with. So far we have captured things that are
1604       --  definitely referenced by the main unit, or defined in the main
1605       --  unit. That's because we don't want to clutter up the ali file
1606       --  for this unit with definition lines for entities in other units
1607       --  that are not referenced.
1608
1609       --  But there is a glitch. We may reference an entity in another unit,
1610       --  and it may have a type reference to an entity that is not directly
1611       --  referenced in the main unit, which may mean that there is no xref
1612       --  entry for this entity yet in the list of references.
1613
1614       --  If we don't do something about this, we will end with an orphan type
1615       --  reference, i.e. it will point to an entity that does not appear
1616       --  within the generated references in the ali file. That is not good for
1617       --  tools using the xref information.
1618
1619       --  To fix this, we go through the references adding definition entries
1620       --  for any unreferenced entities that can be referenced in a type
1621       --  reference. There is a recursion problem here, and that is dealt with
1622       --  by making sure that this traversal also traverses any entries that
1623       --  get added by the traversal.
1624
1625       Handle_Orphan_Type_References : declare
1626          J    : Nat;
1627          Tref : Entity_Id;
1628          Ent  : Entity_Id;
1629
1630          L, R : Character;
1631          pragma Warnings (Off, L);
1632          pragma Warnings (Off, R);
1633
1634          procedure New_Entry (E : Entity_Id);
1635          --  Make an additional entry into the Xref table for a type entity
1636          --  that is related to the current entity (parent, type ancestor,
1637          --  progenitor, etc.).
1638
1639          ----------------
1640          -- New_Entry --
1641          ----------------
1642
1643          procedure New_Entry (E : Entity_Id) is
1644          begin
1645             pragma Assert (Present (E));
1646
1647             if not Has_Xref_Entry (Implementation_Base_Type (E))
1648               and then Sloc (E) > No_Location
1649             then
1650                Add_Entry
1651                  ((Ent       => E,
1652                    Loc       => No_Location,
1653                    Typ       => Character'First,
1654                    Eun       => Get_Source_Unit (Original_Location (Sloc (E))),
1655                    Lun       => No_Unit,
1656                    Ref_Scope => Empty,
1657                    Ent_Scope => Empty),
1658                   Ent_Scope_File => No_Unit);
1659             end if;
1660          end New_Entry;
1661
1662       --  Start of processing for Handle_Orphan_Type_References
1663
1664       begin
1665          --  Note that this is not a for loop for a very good reason. The
1666          --  processing of items in the table can add new items to the table,
1667          --  and they must be processed as well.
1668
1669          J := 1;
1670          while J <= Xrefs.Last loop
1671             Ent := Xrefs.Table (J).Key.Ent;
1672
1673             --  Do not generate reference information for an ignored Ghost
1674             --  entity because neither the entity nor its references will
1675             --  appear in the final tree.
1676
1677             if Is_Ignored_Ghost_Entity (Ent) then
1678                goto Orphan_Continue;
1679             end if;
1680
1681             Get_Type_Reference (Ent, Tref, L, R);
1682
1683             if Present (Tref)
1684               and then not Has_Xref_Entry (Tref)
1685               and then Sloc (Tref) > No_Location
1686             then
1687                New_Entry (Tref);
1688
1689                if Is_Record_Type (Ent)
1690                  and then Present (Interfaces (Ent))
1691                then
1692                   --  Add an entry for each one of the given interfaces
1693                   --  implemented by type Ent.
1694
1695                   declare
1696                      Elmt : Elmt_Id := First_Elmt (Interfaces (Ent));
1697                   begin
1698                      while Present (Elmt) loop
1699                         New_Entry (Node (Elmt));
1700                         Next_Elmt (Elmt);
1701                      end loop;
1702                   end;
1703                end if;
1704             end if;
1705
1706             --  Collect inherited primitive operations that may be declared in
1707             --  another unit and have no visible reference in the current one.
1708
1709             if Is_Type (Ent)
1710               and then Is_Tagged_Type (Ent)
1711               and then Is_Derived_Type (Ent)
1712               and then Is_Base_Type (Ent)
1713               and then In_Extended_Main_Source_Unit (Ent)
1714             then
1715                declare
1716                   Op_List : constant Elist_Id := Primitive_Operations (Ent);
1717                   Op      : Elmt_Id;
1718                   Prim    : Entity_Id;
1719
1720                   function Parent_Op (E : Entity_Id) return Entity_Id;
1721                   --  Find original operation, which may be inherited through
1722                   --  several derivations.
1723
1724                   function Parent_Op (E : Entity_Id) return Entity_Id is
1725                      Orig_Op : constant Entity_Id := Alias (E);
1726
1727                   begin
1728                      if No (Orig_Op) then
1729                         return Empty;
1730
1731                      elsif not Comes_From_Source (E)
1732                        and then not Has_Xref_Entry (Orig_Op)
1733                        and then Comes_From_Source (Orig_Op)
1734                      then
1735                         return Orig_Op;
1736                      else
1737                         return Parent_Op (Orig_Op);
1738                      end if;
1739                   end Parent_Op;
1740
1741                begin
1742                   Op := First_Elmt (Op_List);
1743                   while Present (Op) loop
1744                      Prim := Parent_Op (Node (Op));
1745
1746                      if Present (Prim) then
1747                         Add_Entry
1748                           ((Ent       => Prim,
1749                             Loc       => No_Location,
1750                             Typ       => Character'First,
1751                             Eun       => Get_Source_Unit (Sloc (Prim)),
1752                             Lun       => No_Unit,
1753                             Ref_Scope => Empty,
1754                             Ent_Scope => Empty),
1755                            Ent_Scope_File => No_Unit);
1756                      end if;
1757
1758                      Next_Elmt (Op);
1759                   end loop;
1760                end;
1761             end if;
1762
1763             <<Orphan_Continue>>
1764             J := J + 1;
1765          end loop;
1766       end Handle_Orphan_Type_References;
1767
1768       --  Now we have all the references, including those for any embedded type
1769       --  references, so we can sort them, and output them.
1770
1771       Output_Refs : declare
1772          Nrefs : constant Nat := Xrefs.Last;
1773          --  Number of references in table
1774
1775          Rnums : array (0 .. Nrefs) of Nat;
1776          --  This array contains numbers of references in the Xrefs table.
1777          --  This list is sorted in output order. The extra 0'th entry is
1778          --  convenient for the call to sort. When we sort the table, we
1779          --  move the entries in Rnums around, but we do not move the
1780          --  original table entries.
1781
1782          Curxu : Unit_Number_Type;
1783          --  Current xref unit
1784
1785          Curru : Unit_Number_Type;
1786          --  Current reference unit for one entity
1787
1788          Curent : Entity_Id;
1789          --  Current entity
1790
1791          Curnam : String (1 .. Name_Buffer'Length);
1792          Curlen : Natural;
1793          --  Simple name and length of current entity
1794
1795          Curdef : Source_Ptr;
1796          --  Original source location for current entity
1797
1798          Crloc : Source_Ptr;
1799          --  Current reference location
1800
1801          Ctyp : Character;
1802          --  Entity type character
1803
1804          Prevt : Character;
1805          --  reference kind of previous reference
1806
1807          Tref : Entity_Id;
1808          --  Type reference
1809
1810          Rref : Node_Id;
1811          --  Renaming reference
1812
1813          Trunit : Unit_Number_Type;
1814          --  Unit number for type reference
1815
1816          function Lt (Op1, Op2 : Natural) return Boolean;
1817          --  Comparison function for Sort call
1818
1819          function Name_Change (X : Entity_Id) return Boolean;
1820          --  Determines if entity X has a different simple name from Curent
1821
1822          procedure Move (From : Natural; To : Natural);
1823          --  Move procedure for Sort call
1824
1825          package Sorting is new GNAT.Heap_Sort_G (Move, Lt);
1826
1827          --------
1828          -- Lt --
1829          --------
1830
1831          function Lt (Op1, Op2 : Natural) return Boolean is
1832             T1 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op1)));
1833             T2 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op2)));
1834
1835          begin
1836             return Lt (T1, T2);
1837          end Lt;
1838
1839          ----------
1840          -- Move --
1841          ----------
1842
1843          procedure Move (From : Natural; To : Natural) is
1844          begin
1845             Rnums (Nat (To)) := Rnums (Nat (From));
1846          end Move;
1847
1848          -----------------
1849          -- Name_Change --
1850          -----------------
1851
1852          --  Why a string comparison here??? Why not compare Name_Id values???
1853
1854          function Name_Change (X : Entity_Id) return Boolean is
1855          begin
1856             Get_Unqualified_Name_String (Chars (X));
1857
1858             if Name_Len /= Curlen then
1859                return True;
1860             else
1861                return Name_Buffer (1 .. Curlen) /= Curnam (1 .. Curlen);
1862             end if;
1863          end Name_Change;
1864
1865       --  Start of processing for Output_Refs
1866
1867       begin
1868          --  Capture the definition Sloc values. We delay doing this till now,
1869          --  since at the time the reference or definition is made, private
1870          --  types may be swapped, and the Sloc value may be incorrect. We
1871          --  also set up the pointer vector for the sort.
1872
1873          --  For user-defined operators we need to skip the initial quote and
1874          --  point to the first character of the name, for navigation purposes.
1875
1876          for J in 1 .. Nrefs loop
1877             declare
1878                E   : constant Entity_Id  := Xrefs.Table (J).Key.Ent;
1879                Loc : constant Source_Ptr := Original_Location (Sloc (E));
1880
1881             begin
1882                Rnums (J) := J;
1883
1884                if Nkind (E) = N_Defining_Operator_Symbol then
1885                   Xrefs.Table (J).Def := Loc + 1;
1886                else
1887                   Xrefs.Table (J).Def := Loc;
1888                end if;
1889             end;
1890          end loop;
1891
1892          --  Sort the references
1893
1894          Sorting.Sort (Integer (Nrefs));
1895
1896          --  Initialize loop through references
1897
1898          Curxu  := No_Unit;
1899          Curent := Empty;
1900          Curdef := No_Location;
1901          Curru  := No_Unit;
1902          Crloc  := No_Location;
1903          Prevt  := 'm';
1904
1905          --  Loop to output references
1906
1907          for Refno in 1 .. Nrefs loop
1908             Output_One_Ref : declare
1909                Ent : Entity_Id;
1910
1911                XE : Xref_Entry renames Xrefs.Table (Rnums (Refno));
1912                --  The current entry to be accessed
1913
1914                Left  : Character;
1915                Right : Character;
1916                --  Used for {} or <> or () for type reference
1917
1918                procedure Check_Type_Reference
1919                  (Ent            : Entity_Id;
1920                   List_Interface : Boolean;
1921                   Is_Component   : Boolean := False);
1922                --  Find whether there is a meaningful type reference for
1923                --  Ent, and display it accordingly. If List_Interface is
1924                --  true, then Ent is a progenitor interface of the current
1925                --  type entity being listed. In that case list it as is,
1926                --  without looking for a type reference for it. Flag is also
1927                --  used for index types of an array type, where the caller
1928                --  supplies the intended type reference. Is_Component serves
1929                --  the same purpose, to display the component type of a
1930                --  derived array type, for which only the parent type has
1931                --  ben displayed so far.
1932
1933                procedure Output_Instantiation_Refs (Loc : Source_Ptr);
1934                --  Recursive procedure to output instantiation references for
1935                --  the given source ptr in [file|line[...]] form. No output
1936                --  if the given location is not a generic template reference.
1937
1938                procedure Output_Overridden_Op (Old_E : Entity_Id);
1939                --  For a subprogram that is overriding, display information
1940                --  about the inherited operation that it overrides.
1941
1942                --------------------------
1943                -- Check_Type_Reference --
1944                --------------------------
1945
1946                procedure Check_Type_Reference
1947                  (Ent            : Entity_Id;
1948                   List_Interface : Boolean;
1949                   Is_Component   : Boolean := False)
1950                is
1951                begin
1952                   if List_Interface then
1953
1954                      --  This is a progenitor interface of the type for which
1955                      --  xref information is being generated.
1956
1957                      Tref  := Ent;
1958                      Left  := '<';
1959                      Right := '>';
1960
1961                   --  The following is not documented in lib-xref.ads ???
1962
1963                   elsif Is_Component then
1964                      Tref  := Ent;
1965                      Left  := '(';
1966                      Right := ')';
1967
1968                   else
1969                      Get_Type_Reference (Ent, Tref, Left, Right);
1970                   end if;
1971
1972                   if Present (Tref) then
1973
1974                      --  Case of standard entity, output name
1975
1976                      if Sloc (Tref) = Standard_Location then
1977                         Write_Info_Char (Left);
1978                         Write_Info_Name (Chars (Tref));
1979                         Write_Info_Char (Right);
1980
1981                      --  Case of source entity, output location
1982
1983                      else
1984                         Write_Info_Char (Left);
1985                         Trunit := Get_Source_Unit (Sloc (Tref));
1986
1987                         if Trunit /= Curxu then
1988                            Write_Info_Nat (Dependency_Num (Trunit));
1989                            Write_Info_Char ('|');
1990                         end if;
1991
1992                         Write_Info_Nat
1993                           (Int (Get_Logical_Line_Number (Sloc (Tref))));
1994
1995                         declare
1996                            Ent  : Entity_Id;
1997                            Ctyp : Character;
1998
1999                         begin
2000                            Ent := Tref;
2001                            Ctyp := Xref_Entity_Letters (Ekind (Ent));
2002
2003                            if Ctyp = '+'
2004                              and then Present (Full_View (Ent))
2005                            then
2006                               Ent := Underlying_Type (Ent);
2007
2008                               if Present (Ent) then
2009                                  Ctyp := Xref_Entity_Letters (Ekind (Ent));
2010                               end if;
2011                            end if;
2012
2013                            Write_Info_Char (Ctyp);
2014                         end;
2015
2016                         Write_Info_Nat
2017                           (Int (Get_Column_Number (Sloc (Tref))));
2018
2019                         --  If the type comes from an instantiation, add the
2020                         --  corresponding info.
2021
2022                         Output_Instantiation_Refs (Sloc (Tref));
2023                         Write_Info_Char (Right);
2024                      end if;
2025                   end if;
2026                end Check_Type_Reference;
2027
2028                -------------------------------
2029                -- Output_Instantiation_Refs --
2030                -------------------------------
2031
2032                procedure Output_Instantiation_Refs (Loc : Source_Ptr) is
2033                   Iloc : constant Source_Ptr := Instantiation_Location (Loc);
2034                   Lun  : Unit_Number_Type;
2035                   Cu   : constant Unit_Number_Type := Curru;
2036
2037                begin
2038                   --  Nothing to do if this is not an instantiation
2039
2040                   if Iloc = No_Location then
2041                      return;
2042                   end if;
2043
2044                   --  Output instantiation reference
2045
2046                   Write_Info_Char ('[');
2047                   Lun := Get_Source_Unit (Iloc);
2048
2049                   if Lun /= Curru then
2050                      Curru := Lun;
2051                      Write_Info_Nat (Dependency_Num (Curru));
2052                      Write_Info_Char ('|');
2053                   end if;
2054
2055                   Write_Info_Nat (Int (Get_Logical_Line_Number (Iloc)));
2056
2057                   --  Recursive call to get nested instantiations
2058
2059                   Output_Instantiation_Refs (Iloc);
2060
2061                   --  Output final ] after call to get proper nesting
2062
2063                   Write_Info_Char (']');
2064                   Curru := Cu;
2065                   return;
2066                end Output_Instantiation_Refs;
2067
2068                --------------------------
2069                -- Output_Overridden_Op --
2070                --------------------------
2071
2072                procedure Output_Overridden_Op (Old_E : Entity_Id) is
2073                   Op : Entity_Id;
2074
2075                begin
2076                   --  The overridden operation has an implicit declaration
2077                   --  at the point of derivation. What we want to display
2078                   --  is the original operation, which has the actual body
2079                   --  (or abstract declaration) that is being overridden.
2080                   --  The overridden operation is not always set, e.g. when
2081                   --  it is a predefined operator.
2082
2083                   if No (Old_E) then
2084                      return;
2085
2086                   --  Follow alias chain if one is present
2087
2088                   elsif Present (Alias (Old_E)) then
2089
2090                      --  The subprogram may have been implicitly inherited
2091                      --  through several levels of derivation, so find the
2092                      --  ultimate (source) ancestor.
2093
2094                      Op := Ultimate_Alias (Old_E);
2095
2096                   --  Normal case of no alias present. We omit generated
2097                   --  primitives like tagged equality, that have no source
2098                   --  representation.
2099
2100                   else
2101                      Op := Old_E;
2102                   end if;
2103
2104                   if Present (Op)
2105                     and then Sloc (Op) /= Standard_Location
2106                     and then Comes_From_Source (Op)
2107                   then
2108                      declare
2109                         Loc      : constant Source_Ptr := Sloc (Op);
2110                         Par_Unit : constant Unit_Number_Type :=
2111                                      Get_Source_Unit (Loc);
2112
2113                      begin
2114                         Write_Info_Char ('<');
2115
2116                         if Par_Unit /= Curxu then
2117                            Write_Info_Nat (Dependency_Num (Par_Unit));
2118                            Write_Info_Char ('|');
2119                         end if;
2120
2121                         Write_Info_Nat (Int (Get_Logical_Line_Number (Loc)));
2122                         Write_Info_Char ('p');
2123                         Write_Info_Nat (Int (Get_Column_Number (Loc)));
2124                         Write_Info_Char ('>');
2125                      end;
2126                   end if;
2127                end Output_Overridden_Op;
2128
2129             --  Start of processing for Output_One_Ref
2130
2131             begin
2132                Ent := XE.Key.Ent;
2133
2134                --  Do not generate reference information for an ignored Ghost
2135                --  entity because neither the entity nor its references will
2136                --  appear in the final tree.
2137
2138                if Is_Ignored_Ghost_Entity (Ent) then
2139                   goto Continue;
2140                end if;
2141
2142                Ctyp := Xref_Entity_Letters (Ekind (Ent));
2143
2144                --  Skip reference if it is the only reference to an entity,
2145                --  and it is an END line reference, and the entity is not in
2146                --  the current extended source. This prevents junk entries
2147                --  consisting only of packages with END lines, where no
2148                --  entity from the package is actually referenced.
2149
2150                if XE.Key.Typ = 'e'
2151                  and then Ent /= Curent
2152                  and then (Refno = Nrefs
2153                             or else
2154                               Ent /= Xrefs.Table (Rnums (Refno + 1)).Key.Ent)
2155                  and then not In_Extended_Main_Source_Unit (Ent)
2156                then
2157                   goto Continue;
2158                end if;
2159
2160                --  For private type, get full view type
2161
2162                if Ctyp = '+'
2163                  and then Present (Full_View (XE.Key.Ent))
2164                then
2165                   Ent := Underlying_Type (Ent);
2166
2167                   if Present (Ent) then
2168                      Ctyp := Xref_Entity_Letters (Ekind (Ent));
2169                   end if;
2170                end if;
2171
2172                --  Special exception for Boolean
2173
2174                if Ctyp = 'E' and then Is_Boolean_Type (Ent) then
2175                   Ctyp := 'B';
2176                end if;
2177
2178                --  For variable reference, get corresponding type
2179
2180                if Ctyp = '*' then
2181                   Ent := Etype (XE.Key.Ent);
2182                   Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
2183
2184                   --  If variable is private type, get full view type
2185
2186                   if Ctyp = '+'
2187                     and then Present (Full_View (Etype (XE.Key.Ent)))
2188                   then
2189                      Ent := Underlying_Type (Etype (XE.Key.Ent));
2190
2191                      if Present (Ent) then
2192                         Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
2193                      end if;
2194
2195                   elsif Is_Generic_Type (Ent) then
2196
2197                      --  If the type of the entity is a generic private type,
2198                      --  there is no usable full view, so retain the indication
2199                      --  that this is an object.
2200
2201                      Ctyp := '*';
2202                   end if;
2203
2204                   --  Special handling for access parameters and objects and
2205                   --  components of an anonymous access type.
2206
2207                   if Ekind_In (Etype (XE.Key.Ent),
2208                                E_Anonymous_Access_Type,
2209                                E_Anonymous_Access_Subprogram_Type,
2210                                E_Anonymous_Access_Protected_Subprogram_Type)
2211                   then
2212                      if Is_Formal (XE.Key.Ent)
2213                        or else
2214                          Ekind_In
2215                            (XE.Key.Ent, E_Variable, E_Constant, E_Component)
2216                      then
2217                         Ctyp := 'p';
2218                      end if;
2219
2220                      --  Special handling for Boolean
2221
2222                   elsif Ctyp = 'e' and then Is_Boolean_Type (Ent) then
2223                      Ctyp := 'b';
2224                   end if;
2225                end if;
2226
2227                --  Special handling for abstract types and operations
2228
2229                if Is_Overloadable (XE.Key.Ent)
2230                  and then Is_Abstract_Subprogram (XE.Key.Ent)
2231                then
2232                   if Ctyp = 'U' then
2233                      Ctyp := 'x';            --  Abstract procedure
2234
2235                   elsif Ctyp = 'V' then
2236                      Ctyp := 'y';            --  Abstract function
2237                   end if;
2238
2239                elsif Is_Type (XE.Key.Ent)
2240                  and then Is_Abstract_Type (XE.Key.Ent)
2241                then
2242                   if Is_Interface (XE.Key.Ent) then
2243                      Ctyp := 'h';
2244
2245                   elsif Ctyp = 'R' then
2246                      Ctyp := 'H';            --  Abstract type
2247                   end if;
2248                end if;
2249
2250                --  Only output reference if interesting type of entity
2251
2252                if Ctyp = ' '
2253
2254                --  Suppress references to object definitions, used for local
2255                --  references.
2256
2257                  or else XE.Key.Typ = 'D'
2258                  or else XE.Key.Typ = 'I'
2259
2260                --  Suppress self references, except for bodies that act as
2261                --  specs.
2262
2263                  or else (XE.Key.Loc = XE.Def
2264                            and then
2265                              (XE.Key.Typ /= 'b'
2266                                or else not Is_Subprogram (XE.Key.Ent)))
2267
2268                --  Also suppress definitions of body formals (we only
2269                --  treat these as references, and the references were
2270                --  separately recorded).
2271
2272                  or else (Is_Formal (XE.Key.Ent)
2273                            and then Present (Spec_Entity (XE.Key.Ent)))
2274                then
2275                   null;
2276
2277                else
2278                   --  Start new Xref section if new xref unit
2279
2280                   if XE.Key.Eun /= Curxu then
2281                      if Write_Info_Col > 1 then
2282                         Write_Info_EOL;
2283                      end if;
2284
2285                      Curxu := XE.Key.Eun;
2286
2287                      Write_Info_Initiate ('X');
2288                      Write_Info_Char (' ');
2289                      Write_Info_Nat (Dependency_Num (XE.Key.Eun));
2290                      Write_Info_Char (' ');
2291                      Write_Info_Name
2292                        (Reference_Name (Source_Index (XE.Key.Eun)));
2293                   end if;
2294
2295                   --  Start new Entity line if new entity. Note that we
2296                   --  consider two entities the same if they have the same
2297                   --  name and source location. This causes entities in
2298                   --  instantiations to be treated as though they referred
2299                   --  to the template.
2300
2301                   if No (Curent)
2302                     or else
2303                       (XE.Key.Ent /= Curent
2304                          and then
2305                            (Name_Change (XE.Key.Ent) or else XE.Def /= Curdef))
2306                   then
2307                      Curent := XE.Key.Ent;
2308                      Curdef := XE.Def;
2309
2310                      Get_Unqualified_Name_String (Chars (XE.Key.Ent));
2311                      Curlen := Name_Len;
2312                      Curnam (1 .. Curlen) := Name_Buffer (1 .. Curlen);
2313
2314                      if Write_Info_Col > 1 then
2315                         Write_Info_EOL;
2316                      end if;
2317
2318                      --  Write column number information
2319
2320                      Write_Info_Nat (Int (Get_Logical_Line_Number (XE.Def)));
2321                      Write_Info_Char (Ctyp);
2322                      Write_Info_Nat (Int (Get_Column_Number (XE.Def)));
2323
2324                      --  Write level information
2325
2326                      Write_Level_Info : declare
2327                         function Is_Visible_Generic_Entity
2328                           (E : Entity_Id) return Boolean;
2329                         --  Check whether E is declared in the visible part
2330                         --  of a generic package. For source navigation
2331                         --  purposes, treat this as a visible entity.
2332
2333                         function Is_Private_Record_Component
2334                           (E : Entity_Id) return Boolean;
2335                         --  Check whether E is a non-inherited component of a
2336                         --  private extension. Even if the enclosing record is
2337                         --  public, we want to treat the component as private
2338                         --  for navigation purposes.
2339
2340                         ---------------------------------
2341                         -- Is_Private_Record_Component --
2342                         ---------------------------------
2343
2344                         function Is_Private_Record_Component
2345                           (E : Entity_Id) return Boolean
2346                         is
2347                            S : constant Entity_Id := Scope (E);
2348                         begin
2349                            return
2350                              Ekind (E) = E_Component
2351                                and then Nkind (Declaration_Node (S)) =
2352                                  N_Private_Extension_Declaration
2353                                and then Original_Record_Component (E) = E;
2354                         end Is_Private_Record_Component;
2355
2356                         -------------------------------
2357                         -- Is_Visible_Generic_Entity --
2358                         -------------------------------
2359
2360                         function Is_Visible_Generic_Entity
2361                           (E : Entity_Id) return Boolean
2362                         is
2363                            Par : Node_Id;
2364
2365                         begin
2366                            --  The Present check here is an error defense
2367
2368                            if Present (Scope (E))
2369                              and then Ekind (Scope (E)) /= E_Generic_Package
2370                            then
2371                               return False;
2372                            end if;
2373
2374                            Par := Parent (E);
2375                            while Present (Par) loop
2376                               if
2377                                 Nkind (Par) = N_Generic_Package_Declaration
2378                               then
2379                                  --  Entity is a generic formal
2380
2381                                  return False;
2382
2383                               elsif
2384                                 Nkind (Parent (Par)) = N_Package_Specification
2385                               then
2386                                  return
2387                                    Is_List_Member (Par)
2388                                      and then List_Containing (Par) =
2389                                        Visible_Declarations (Parent (Par));
2390                               else
2391                                  Par := Parent (Par);
2392                               end if;
2393                            end loop;
2394
2395                            return False;
2396                         end Is_Visible_Generic_Entity;
2397
2398                      --  Start of processing for Write_Level_Info
2399
2400                      begin
2401                         if Is_Hidden (Curent)
2402                           or else Is_Private_Record_Component (Curent)
2403                         then
2404                            Write_Info_Char (' ');
2405
2406                         elsif
2407                            Is_Public (Curent)
2408                              or else Is_Visible_Generic_Entity (Curent)
2409                         then
2410                            Write_Info_Char ('*');
2411
2412                         else
2413                            Write_Info_Char (' ');
2414                         end if;
2415                      end Write_Level_Info;
2416
2417                      --  Output entity name. We use the occurrence from the
2418                      --  actual source program at the definition point.
2419
2420                      declare
2421                         Ent_Name : constant String :=
2422                                      Exact_Source_Name (Sloc (XE.Key.Ent));
2423                      begin
2424                         for C in Ent_Name'Range loop
2425                            Write_Info_Char (Ent_Name (C));
2426                         end loop;
2427                      end;
2428
2429                      --  See if we have a renaming reference
2430
2431                      if Is_Object (XE.Key.Ent)
2432                        and then Present (Renamed_Object (XE.Key.Ent))
2433                      then
2434                         Rref := Renamed_Object (XE.Key.Ent);
2435
2436                      elsif Is_Overloadable (XE.Key.Ent)
2437                        and then Nkind (Parent (Declaration_Node (XE.Key.Ent)))
2438                                            = N_Subprogram_Renaming_Declaration
2439                      then
2440                         Rref := Name (Parent (Declaration_Node (XE.Key.Ent)));
2441
2442                      elsif Ekind (XE.Key.Ent) = E_Package
2443                        and then Nkind (Declaration_Node (XE.Key.Ent)) =
2444                                          N_Package_Renaming_Declaration
2445                      then
2446                         Rref := Name (Declaration_Node (XE.Key.Ent));
2447
2448                      else
2449                         Rref := Empty;
2450                      end if;
2451
2452                      if Present (Rref) then
2453                         if Nkind (Rref) = N_Expanded_Name then
2454                            Rref := Selector_Name (Rref);
2455                         end if;
2456
2457                         if Nkind (Rref) = N_Identifier
2458                           or else Nkind (Rref) = N_Operator_Symbol
2459                         then
2460                            null;
2461
2462                         --  For renamed array components, use the array name
2463                         --  for the renamed entity, which reflect the fact that
2464                         --  in general the whole array is aliased.
2465
2466                         elsif Nkind (Rref) = N_Indexed_Component then
2467                            if Nkind (Prefix (Rref)) = N_Identifier then
2468                               Rref := Prefix (Rref);
2469                            elsif Nkind (Prefix (Rref)) = N_Expanded_Name then
2470                               Rref := Selector_Name (Prefix (Rref));
2471                            else
2472                               Rref := Empty;
2473                            end if;
2474
2475                         else
2476                            Rref := Empty;
2477                         end if;
2478                      end if;
2479
2480                      --  Write out renaming reference if we have one
2481
2482                      if Present (Rref) then
2483                         Write_Info_Char ('=');
2484                         Write_Info_Nat
2485                           (Int (Get_Logical_Line_Number (Sloc (Rref))));
2486                         Write_Info_Char (':');
2487                         Write_Info_Nat
2488                           (Int (Get_Column_Number (Sloc (Rref))));
2489                      end if;
2490
2491                      --  Indicate that the entity is in the unit of the current
2492                      --  xref section.
2493
2494                      Curru := Curxu;
2495
2496                      --  Write out information about generic parent, if entity
2497                      --  is an instance.
2498
2499                      if Is_Generic_Instance (XE.Key.Ent) then
2500                         declare
2501                            Gen_Par : constant Entity_Id :=
2502                                        Generic_Parent
2503                                          (Specification
2504                                             (Unit_Declaration_Node
2505                                                (XE.Key.Ent)));
2506                            Loc     : constant Source_Ptr := Sloc (Gen_Par);
2507                            Gen_U   : constant Unit_Number_Type :=
2508                                        Get_Source_Unit (Loc);
2509
2510                         begin
2511                            Write_Info_Char ('[');
2512
2513                            if Curru /= Gen_U then
2514                               Write_Info_Nat (Dependency_Num (Gen_U));
2515                               Write_Info_Char ('|');
2516                            end if;
2517
2518                            Write_Info_Nat
2519                              (Int (Get_Logical_Line_Number (Loc)));
2520                            Write_Info_Char (']');
2521                         end;
2522                      end if;
2523
2524                      --  See if we have a type reference and if so output
2525
2526                      Check_Type_Reference (XE.Key.Ent, False);
2527
2528                      --  Additional information for types with progenitors,
2529                      --  including synchronized tagged types.
2530
2531                      declare
2532                         Typ  : constant Entity_Id := XE.Key.Ent;
2533                         Elmt : Elmt_Id;
2534
2535                      begin
2536                         if Is_Record_Type (Typ)
2537                           and then Present (Interfaces (Typ))
2538                         then
2539                            Elmt := First_Elmt (Interfaces (Typ));
2540
2541                         elsif Is_Concurrent_Type (Typ)
2542                           and then Present (Corresponding_Record_Type (Typ))
2543                           and then Present (
2544                             Interfaces (Corresponding_Record_Type (Typ)))
2545                         then
2546                            Elmt :=
2547                              First_Elmt (
2548                               Interfaces (Corresponding_Record_Type (Typ)));
2549
2550                         else
2551                            Elmt := No_Elmt;
2552                         end if;
2553
2554                         while Present (Elmt) loop
2555                            Check_Type_Reference (Node (Elmt), True);
2556                            Next_Elmt (Elmt);
2557                         end loop;
2558                      end;
2559
2560                      --  For array types, list index types as well. (This is
2561                      --  not C, indexes have distinct types).
2562
2563                      if Is_Array_Type (XE.Key.Ent) then
2564                         declare
2565                            A_Typ : constant Entity_Id := XE.Key.Ent;
2566                            Indx : Node_Id;
2567
2568                         begin
2569                            --  If this is a derived array type, we have
2570                            --  output the parent type, so add the component
2571                            --  type now.
2572
2573                            if Is_Derived_Type (A_Typ) then
2574                               Check_Type_Reference
2575                                 (Component_Type (A_Typ), False, True);
2576                            end if;
2577
2578                            --  Add references to index types.
2579
2580                            Indx := First_Index (XE.Key.Ent);
2581                            while Present (Indx) loop
2582                               Check_Type_Reference
2583                                 (First_Subtype (Etype (Indx)), True);
2584                               Next_Index (Indx);
2585                            end loop;
2586                         end;
2587                      end if;
2588
2589                      --  If the entity is an overriding operation, write info
2590                      --  on operation that was overridden.
2591
2592                      if Is_Subprogram (XE.Key.Ent)
2593                        and then Present (Overridden_Operation (XE.Key.Ent))
2594                      then
2595                         Output_Overridden_Op
2596                           (Overridden_Operation (XE.Key.Ent));
2597                      end if;
2598
2599                      --  End of processing for entity output
2600
2601                      Crloc := No_Location;
2602                   end if;
2603
2604                   --  Output the reference if it is not as the same location
2605                   --  as the previous one, or it is a read-reference that
2606                   --  indicates that the entity is an in-out actual in a call.
2607
2608                   if XE.Key.Loc /= No_Location
2609                     and then
2610                       (XE.Key.Loc /= Crloc
2611                         or else (Prevt = 'm' and then  XE.Key.Typ = 'r'))
2612                   then
2613                      Crloc := XE.Key.Loc;
2614                      Prevt := XE.Key.Typ;
2615
2616                      --  Start continuation if line full, else blank
2617
2618                      if Write_Info_Col > 72 then
2619                         Write_Info_EOL;
2620                         Write_Info_Initiate ('.');
2621                      end if;
2622
2623                      Write_Info_Char (' ');
2624
2625                      --  Output file number if changed
2626
2627                      if XE.Key.Lun /= Curru then
2628                         Curru := XE.Key.Lun;
2629                         Write_Info_Nat (Dependency_Num (Curru));
2630                         Write_Info_Char ('|');
2631                      end if;
2632
2633                      Write_Info_Nat
2634                        (Int (Get_Logical_Line_Number (XE.Key.Loc)));
2635                      Write_Info_Char (XE.Key.Typ);
2636
2637                      if Is_Overloadable (XE.Key.Ent) then
2638                         if (Is_Imported (XE.Key.Ent) and then XE.Key.Typ = 'b')
2639                              or else
2640                            (Is_Exported (XE.Key.Ent) and then XE.Key.Typ = 'i')
2641                         then
2642                            Output_Import_Export_Info (XE.Key.Ent);
2643                         end if;
2644                      end if;
2645
2646                      Write_Info_Nat (Int (Get_Column_Number (XE.Key.Loc)));
2647
2648                      Output_Instantiation_Refs (Sloc (XE.Key.Ent));
2649                   end if;
2650                end if;
2651             end Output_One_Ref;
2652
2653          <<Continue>>
2654             null;
2655          end loop;
2656
2657          Write_Info_EOL;
2658       end Output_Refs;
2659    end Output_References;
2660
2661    ---------------------------------
2662    -- Process_Deferred_References --
2663    ---------------------------------
2664
2665    procedure Process_Deferred_References is
2666    begin
2667       for J in Deferred_References.First .. Deferred_References.Last loop
2668          declare
2669             D : Deferred_Reference_Entry renames Deferred_References.Table (J);
2670
2671          begin
2672             case Is_LHS (D.N) is
2673                when Yes =>
2674                   Generate_Reference (D.E, D.N, 'm');
2675
2676                when No =>
2677                   Generate_Reference (D.E, D.N, 'r');
2678
2679                --  Not clear if Unknown can occur at this stage, but if it
2680                --  does we will treat it as a normal reference.
2681
2682                when Unknown =>
2683                   Generate_Reference (D.E, D.N, 'r');
2684             end case;
2685          end;
2686       end loop;
2687
2688       --  Clear processed entries from table
2689
2690       Deferred_References.Init;
2691    end Process_Deferred_References;
2692
2693 --  Start of elaboration for Lib.Xref
2694
2695 begin
2696    --  Reset is necessary because Elmt_Ptr does not default to Null_Ptr,
2697    --  because it's not an access type.
2698
2699    Xref_Set.Reset;
2700 end Lib.Xref;