configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 144
 145 # libgcj represents the runtime libraries only used by gcj.
 146 libgcj="target-libffi \
 147         target-zlib \
 148         target-libjava"
 149
 150 # these libraries are built for the target environment, and are built after
 151 # the host libraries and the host tools (which may be a cross compiler)
 152 # Note that libiberty is not a target library.
 153 target_libraries="target-libgcc \
 154                 target-libgloss \
 155                 target-newlib \
 156                 target-libgomp \
 157                 target-libitm \
 158                 target-libstdc++-v3 \
 159                 target-libmudflap \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-boehm-gc \
 164                 ${libgcj} \
 165                 target-libobjc \
 166                 target-libada \
 167                 target-libgo"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 # Make sure we don't let ZLIB be added if we didn't want it.
 243 if test x$with_system_zlib = xyes ; then
 244   use_included_zlib=no
 245   noconfigdirs="$noconfigdirs zlib"
 246 fi
 247
 248 # some tools are so dependent upon X11 that if we're not building with X,
 249 # it's not even worth trying to configure, much less build, that tool.
 250
 251 case ${with_x} in
 252   yes | "") ;; # the default value for this tree is that X11 is available
 253   no)
 254     skipdirs="${skipdirs} tk itcl libgui"
 255     # We won't be able to build gdbtk without X.
 256     enable_gdbtk=no
 257     ;;
 258   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 259 esac
 260
 261 # Some are only suitable for cross toolchains.
 262 # Remove these if host=target.
 263 cross_only="target-libgloss target-newlib target-opcodes"
 264
 265 case $is_cross_compiler in
 266   no) skipdirs="${skipdirs} ${cross_only}" ;;
 267 esac
 268
 269 # If both --with-headers and --with-libs are specified, default to
 270 # --without-newlib.
 271 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 272    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 273   if test x"${with_newlib}" = x ; then
 274     with_newlib=no
 275   fi
 276 fi
 277
 278 # Recognize --with-newlib/--without-newlib.
 279 case ${with_newlib} in
 280   no) skipdirs="${skipdirs} target-newlib" ;;
 281   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 282 esac
 283
 284 # Handle --enable-gold, --enable-ld.
 285 # --disable-gold [--enable-ld]
 286 #     Build only ld.  Default option.
 287 # --enable-gold [--enable-ld]
 288 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 289 #     as "ld.bfd" and "ld".
 290 # --enable-gold=default [--enable-ld]
 291 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 292 #     install ld as "ld.bfd".
 293 # --enable-gold[=default] --disable-ld
 294 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 295 # --enable-gold --enable-ld=default
 296 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 297 #     and ld.bfd).
 298 #     In other words, ld is default
 299 # --enable-gold=default --enable-ld=default
 300 #     Error.
 301
 302 default_ld=
 303 AC_ARG_ENABLE(gold,
 304 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 305                 [build gold @<:@ARG={default,yes,no}@:>@])],
 306 ENABLE_GOLD=$enableval,
 307 ENABLE_GOLD=no)
 308 case "${ENABLE_GOLD}" in
 309   yes|default)
 310     # Check for ELF target.
 311     is_elf=no
 312     case "${target}" in
 313       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 314       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 315       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 316       | *-*-solaris2* | *-*-nto*)
 317         case "${target}" in
 318           *-*-linux*aout* | *-*-linux*oldld*)
 319             ;;
 320           *)
 321             is_elf=yes
 322             ;;
 323         esac
 324     esac
 325
 326     if test "$is_elf" = "yes"; then
 327       # Check for target supported by gold.
 328       case "${target}" in
 329         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 330           configdirs="$configdirs gold"
 331           if test x${ENABLE_GOLD} = xdefault; then
 332             default_ld=gold
 333           fi
 334           ENABLE_GOLD=yes
 335           ;;
 336       esac
 337     fi
 338     ;;
 339   no)
 340     ;;
 341   *)
 342     AC_MSG_ERROR([invalid --enable-gold argument])
 343     ;;
 344 esac
 345
 346 AC_ARG_ENABLE(ld,
 347 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 348                 [build ld @<:@ARG={default,yes,no}@:>@])],
 349 ENABLE_LD=$enableval,
 350 ENABLE_LD=yes)
 351
 352 case "${ENABLE_LD}" in
 353   default)
 354     if test x${default_ld} != x; then
 355       AC_MSG_ERROR([either gold or ld can be the default ld])
 356     fi
 357     ;;
 358   yes)
 359     ;;
 360   no)
 361     if test x${ENABLE_GOLD} != xyes; then
 362       AC_MSG_WARN([neither ld nor gold are enabled])
 363     fi
 364     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 365     ;;
 366   *)
 367     AC_MSG_ERROR([invalid --enable-ld argument])
 368     ;;
 369 esac
 370
 371 # Configure extra directories which are host specific
 372
 373 case "${host}" in
 374   *-cygwin*)
 375     configdirs="$configdirs libtermcap" ;;
 376 esac
 377
 378 # A target can indicate whether a language isn't supported for some reason.
 379 # Only spaces may be used in this macro; not newlines or tabs.
 380 unsupported_languages=
 381
 382 # Remove more programs from consideration, based on the host or
 383 # target this usually means that a port of the program doesn't
 384 # exist yet.
 385
 386 case "${host}" in
 387   i[[3456789]]86-*-msdosdjgpp*)
 388     noconfigdirs="$noconfigdirs tcl tk itcl"
 389     ;;
 390 esac
 391
 392
 393 AC_ARG_ENABLE(libquadmath,
 394 AS_HELP_STRING([--disable-libquadmath],
 395   [do not build libquadmath directory]),
 396 ENABLE_LIBQUADMATH=$enableval,
 397 ENABLE_LIBQUADMATH=yes)
 398 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 399   noconfigdirs="$noconfigdirs target-libquadmath"
 400 fi
 401
 402
 403 AC_ARG_ENABLE(libquadmath-support,
 404 AS_HELP_STRING([--disable-libquadmath-support],
 405   [disable libquadmath support for Fortran]),
 406 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 407 ENABLE_LIBQUADMATH_SUPPORT=yes)
 408 enable_libquadmath_support=
 409 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 410   enable_libquadmath_support=no
 411 fi
 412
 413
 414 AC_ARG_ENABLE(libada,
 415 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 416 ENABLE_LIBADA=$enableval,
 417 ENABLE_LIBADA=yes)
 418 if test "${ENABLE_LIBADA}" != "yes" ; then
 419   noconfigdirs="$noconfigdirs gnattools"
 420 fi
 421
 422 AC_ARG_ENABLE(libssp,
 423 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 424 ENABLE_LIBSSP=$enableval,
 425 ENABLE_LIBSSP=yes)
 426
 427 # Save it here so that, even in case of --enable-libgcj, if the Java
 428 # front-end isn't enabled, we still get libgcj disabled.
 429 libgcj_saved=$libgcj
 430 case $enable_libgcj in
 431 yes)
 432   # If we reset it here, it won't get added to noconfigdirs in the
 433   # target-specific build rules, so it will be forcibly enabled
 434   # (unless the Java language itself isn't enabled).
 435   libgcj=
 436   ;;
 437 no)
 438   # Make sure we get it printed in the list of not supported target libs.
 439   # Don't disable libffi, though, other languages use it.
 440   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 441   # Clear libgcj_saved so that even if java is enabled libffi won't be
 442   # built.
 443   libgcj_saved=
 444   ;;
 445 esac
 446
 447 AC_ARG_ENABLE(static-libjava,
 448 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 449                 [build static libjava @<:@default=no@:>@])],
 450 ENABLE_STATIC_LIBJAVA=$enableval,
 451 ENABLE_STATIC_LIBJAVA=no)
 452 enable_static_libjava=
 453 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 454   enable_static_libjava=yes
 455 fi
 456
 457 if test x$enable_static_libjava != xyes ; then
 458   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 459 fi
 460 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 461
 462 # Disable libmudflap on some systems.
 463 if test x$enable_libmudflap = x ; then
 464     case "${target}" in
 465     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 466         # Enable libmudflap by default in GNU and friends.
 467         ;;
 468     *-*-freebsd*)
 469         # Enable libmudflap by default in FreeBSD.
 470         ;;
 471     *)
 472         # Disable it by default everywhere else.
 473         noconfigdirs="$noconfigdirs target-libmudflap"
 474         ;;
 475     esac
 476 fi
 477
 478 # Disable libgomp on non POSIX hosted systems.
 479 if test x$enable_libgomp = x ; then
 480     # Enable libgomp by default on hosted POSIX systems.
 481     case "${target}" in
 482     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 483         ;;
 484     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 485         ;;
 486     *-*-solaris2* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 487         ;;
 488     *-*-darwin* | *-*-aix*)
 489         ;;
 490     *)
 491         noconfigdirs="$noconfigdirs target-libgomp"
 492         ;;
 493     esac
 494 fi
 495
 496 # Disable libitm on unsupported systems.
 497 if test -d ${srcdir}/libitm; then
 498     if test x$enable_libitm = x; then
 499         AC_MSG_CHECKING([for libitm support])
 500         if (srcdir=${srcdir}/libitm; \
 501                 . ${srcdir}/configure.tgt; \
 502                 test -n "$UNSUPPORTED")
 503         then
 504             AC_MSG_RESULT([no])
 505             noconfigdirs="$noconfigdirs target-libitm"
 506         else
 507             AC_MSG_RESULT([yes])
 508         fi
 509     fi
 510 fi
 511
 512 # Disable libssp for some systems.
 513 case "${target}" in
 514   avr-*-*)
 515     # No hosted I/O support.
 516     noconfigdirs="$noconfigdirs target-libssp"
 517     ;;
 518   powerpc-*-aix* | rs6000-*-aix*)
 519     noconfigdirs="$noconfigdirs target-libssp"
 520     ;;
 521   rl78-*-*)
 522     # libssp uses a misaligned load to trigger a fault, but the RL78
 523     # doesn't fault for those - instead, it gives a build-time error
 524     # for explicit misaligned loads.
 525     noconfigdirs="$noconfigdirs target-libssp"
 526     ;;
 527 esac
 528
 529 # Disable libstdc++-v3 for some systems.
 530 case "${target}" in
 531   *-*-vxworks*)
 532     # VxWorks uses the Dinkumware C++ library.
 533     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 534     ;;
 535   arm*-wince-pe*)
 536     # the C++ libraries don't build on top of CE's C libraries
 537     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 538     ;;
 539   avr-*-*)
 540     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 541     ;;
 542 esac
 543
 544 # Disable Fortran for some systems.
 545 case "${target}" in
 546   mmix-*-*)
 547     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 548     unsupported_languages="$unsupported_languages fortran"
 549     ;;
 550 esac
 551
 552 # Disable Java if libffi is not supported.
 553 case "${target}" in
 554   alpha*-*-*)
 555     ;;
 556   arm*-*-*)
 557     ;;
 558   cris-*-*)
 559     ;;
 560   frv-*-*)
 561     ;;
 562   hppa*-*-linux*)
 563     ;;
 564   hppa*-*-hpux*)
 565     ;;
 566   i?86-*-*)
 567     ;;
 568   ia64*-*-*)
 569     ;;
 570   m32r*-*-*)
 571     ;;
 572   m68k-*-*)
 573     ;;
 574   mips-sgi-irix6.* | mips*-*-rtems*)
 575     ;;
 576   mips*-*-linux*)
 577     ;;
 578   powerpc*-*-linux*)
 579     ;;
 580   powerpc-*-darwin*)
 581     ;;
 582   powerpc-*-aix* | rs6000-*-aix*)
 583     ;;
 584   powerpc-*-freebsd*)
 585     ;;
 586   powerpc64-*-freebsd*)
 587     ;;
 588   powerpc*-*-rtems*)
 589     ;;
 590   s390-*-* | s390x-*-*)
 591     ;;
 592   sh-*-* | sh[[34]]*-*-*)
 593     ;;
 594   sh64-*-* | sh5*-*-*)
 595     ;;
 596   sparc*-*-*)
 597     ;;
 598   x86_64-*-*)
 599     ;;
 600   *-*-*)
 601     unsupported_languages="$unsupported_languages java"
 602     ;;
 603 esac
 604
 605 # Disable Java, libgcj or related libraries for some systems.
 606 case "${target}" in
 607   powerpc-*-darwin*)
 608     ;;
 609   i[[3456789]]86-*-darwin*)
 610     ;;
 611   x86_64-*-darwin[[912]]*)
 612     ;;
 613   *-*-darwin*)
 614     noconfigdirs="$noconfigdirs ${libgcj}"
 615     ;;
 616   *-*-netware*)
 617     noconfigdirs="$noconfigdirs ${libgcj}"
 618     ;;
 619   *-*-rtems*)
 620     noconfigdirs="$noconfigdirs ${libgcj}"
 621     ;;
 622   *-*-tpf*)
 623     noconfigdirs="$noconfigdirs ${libgcj}"
 624     ;;
 625   *-*-uclinux*)
 626     noconfigdirs="$noconfigdirs ${libgcj}"
 627     ;;
 628   *-*-vxworks*)
 629     noconfigdirs="$noconfigdirs ${libgcj}"
 630     ;;
 631   alpha*-*-*vms*)
 632     noconfigdirs="$noconfigdirs ${libgcj}"
 633     ;;
 634   arm-wince-pe)
 635     noconfigdirs="$noconfigdirs ${libgcj}"
 636     ;;
 637   arm*-*-symbianelf*)
 638     noconfigdirs="$noconfigdirs ${libgcj}"
 639     ;;
 640   bfin-*-*)
 641     noconfigdirs="$noconfigdirs target-boehm-gc"
 642     ;;
 643   cris-*-* | crisv32-*-*)
 644     unsupported_languages="$unsupported_languages java"
 645     case "${target}" in
 646       *-*-linux*)
 647         ;;
 648       *) # See PR46792 regarding target-libffi.
 649         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 650     esac
 651     ;;
 652   hppa*64*-*-linux*)
 653     # In this case, it's because the hppa64-linux target is for
 654     # the kernel only at this point and has no libc, and thus no
 655     # headers, crt*.o, etc., all of which are needed by these.
 656     unsupported_languages="$unsupported_languages java"
 657     ;;
 658   hppa*64*-*-hpux*)
 659     noconfigdirs="$noconfigdirs ${libgcj}"
 660     ;;
 661   hppa*-hp-hpux11*)
 662     ;;
 663   hppa*-*-hpux*)
 664     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 665     # build on HP-UX 10.20.
 666     noconfigdirs="$noconfigdirs ${libgcj}"
 667     ;;
 668   ia64*-*-*vms*)
 669     noconfigdirs="$noconfigdirs ${libgcj}"
 670     ;;
 671   i[[3456789]]86-w64-mingw*)
 672     noconfigdirs="$noconfigdirs ${libgcj}"
 673     ;;
 674   i[[3456789]]86-*-mingw*)
 675     noconfigdirs="$noconfigdirs ${libgcj}"
 676     ;;
 677   x86_64-*-mingw*)
 678     noconfigdirs="$noconfigdirs ${libgcj}"
 679     ;;
 680   mmix-*-*)
 681     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 682     ;;
 683   powerpc-*-aix*)
 684     # copied from rs6000-*-* entry
 685     noconfigdirs="$noconfigdirs ${libgcj}"
 686     ;;
 687   rs6000-*-aix*)
 688     noconfigdirs="$noconfigdirs ${libgcj}"
 689     ;;
 690   mips*-*-irix6*)
 691     # Linking libjava exceeds command-line length limits on at least
 692     # IRIX 6.2, but not on IRIX 6.5.
 693     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 694     # <oldham@codesourcery.com>
 695     noconfigdirs="$noconfigdirs ${libgcj}"
 696     ;;
 697   *-*-lynxos*)
 698     noconfigdirs="$noconfigdirs ${libgcj}"
 699     ;;
 700 esac
 701
 702 # Default libgloss CPU subdirectory.
 703 libgloss_dir="$target_cpu"
 704
 705 case "${target}" in
 706   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 707     libgloss_dir=wince
 708     ;;
 709   arm*-*-*)
 710     libgloss_dir=arm
 711     ;;
 712   cris-*-* | crisv32-*-*)
 713     libgloss_dir=cris
 714     ;;
 715   hppa*-*-*)
 716     libgloss_dir=pa
 717     ;;
 718   i[[3456789]]86-*-*)
 719     libgloss_dir=i386
 720     ;;
 721   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 722     libgloss_dir=m68hc11
 723     ;;
 724   m68*-*-* | fido-*-*)
 725     libgloss_dir=m68k
 726     ;;
 727   mips*-*-*)
 728     libgloss_dir=mips
 729     ;;
 730   powerpc*-*-*)
 731     libgloss_dir=rs6000
 732     ;;
 733   sparc*-*-*)
 734     libgloss_dir=sparc
 735     ;;
 736 esac
 737
 738 # Disable newlib and libgloss for various target OSes.
 739 case "${target}" in
 740   alpha*-dec-osf*)
 741     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 742     ;;
 743   i[[3456789]]86-*-linux*)
 744     # This section makes it possible to build newlib natively on linux.
 745     # If we are using a cross compiler then don't configure newlib.
 746     if test x${is_cross_compiler} != xno ; then
 747       noconfigdirs="$noconfigdirs target-newlib"
 748     fi
 749     noconfigdirs="$noconfigdirs target-libgloss"
 750     # If we are not using a cross compiler, do configure newlib.
 751     # Note however, that newlib will only be configured in this situation
 752     # if the --with-newlib option has been given, because otherwise
 753     # 'target-newlib' will appear in skipdirs.
 754     ;;
 755   i[[3456789]]86-*-rdos*)
 756     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 757     ;;
 758   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 759     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 760     ;;
 761   sparc-*-sunos4*)
 762     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 763     ;;
 764   *-*-aix*)
 765     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 766     ;;
 767   *-*-beos*)
 768     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 769     ;;
 770   *-*-chorusos)
 771     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 772     ;;
 773   *-*-dragonfly*)
 774     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 775     ;;
 776   *-*-freebsd*)
 777     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 778     ;;
 779   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 780     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 781     ;;
 782   *-*-lynxos*)
 783     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 784     ;;
 785   *-*-mingw*)
 786     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 787     ;;
 788   *-*-netbsd*)
 789     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 790     ;;
 791   *-*-netware*)
 792     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 793     ;;
 794   *-*-tpf*)
 795     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 796     ;;
 797   *-*-uclinux*)
 798     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 799     ;;
 800   *-*-vxworks*)
 801     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 802     ;;
 803 esac
 804
 805 case "${target}" in
 806   *-*-chorusos)
 807     ;;
 808   powerpc-*-darwin*)
 809     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 810     noconfigdirs="$noconfigdirs sim target-rda"
 811     ;;
 812   i[[3456789]]86-*-darwin*)
 813     noconfigdirs="$noconfigdirs ld gprof"
 814     noconfigdirs="$noconfigdirs sim target-rda"
 815     ;;
 816   x86_64-*-darwin[[912]]*)
 817     noconfigdirs="$noconfigdirs ld gas gprof"
 818     noconfigdirs="$noconfigdirs sim target-rda"
 819     ;;
 820   *-*-darwin*)
 821     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 822     noconfigdirs="$noconfigdirs sim target-rda"
 823     ;;
 824   *-*-dragonfly*)
 825     ;;
 826   *-*-freebsd*)
 827     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 828         && test -f /usr/local/include/gmp.h; then
 829       with_gmp=/usr/local
 830     fi
 831     ;;
 832   *-*-kaos*)
 833     # Remove unsupported stuff on all kaOS configurations.
 834     noconfigdirs="$noconfigdirs target-libgloss"
 835     ;;
 836   *-*-netbsd*)
 837     ;;
 838   *-*-netware*)
 839     ;;
 840   *-*-rtems*)
 841     noconfigdirs="$noconfigdirs target-libgloss"
 842     ;;
 843     # The tpf target doesn't support gdb yet.
 844   *-*-tpf*)
 845     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 846     ;;
 847   *-*-uclinux*)
 848     noconfigdirs="$noconfigdirs target-rda"
 849     ;;
 850   *-*-vxworks*)
 851     ;;
 852   alpha*-dec-osf*)
 853     # ld works, but does not support shared libraries.
 854     # gas doesn't generate exception information.
 855     noconfigdirs="$noconfigdirs gas ld"
 856     ;;
 857   alpha*-*-*vms*)
 858     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 859     ;;
 860   alpha*-*-*)
 861     # newlib is not 64 bit ready
 862     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 863     ;;
 864   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 865     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 866     ;;
 867   arc-*-*)
 868     noconfigdirs="$noconfigdirs target-libgloss"
 869     ;;
 870   arm-*-pe*)
 871     noconfigdirs="$noconfigdirs target-libgloss"
 872     ;;
 873   arm-*-riscix*)
 874     noconfigdirs="$noconfigdirs ld target-libgloss"
 875     ;;
 876   c4x-*-* | tic4x-*-*)
 877     noconfigdirs="$noconfigdirs target-libgloss"
 878     ;;
 879   tic54x-*-*)
 880     noconfigdirs="$noconfigdirs target-libgloss gdb"
 881     ;;
 882   cr16-*-*)
 883     noconfigdirs="$noconfigdirs gdb"
 884     ;;
 885   d10v-*-*)
 886     noconfigdirs="$noconfigdirs target-libgloss"
 887     ;;
 888   d30v-*-*)
 889     noconfigdirs="$noconfigdirs gdb"
 890     ;;
 891   fr30-*-elf*)
 892     noconfigdirs="$noconfigdirs gdb"
 893     ;;
 894   moxie-*-*)
 895     noconfigdirs="$noconfigdirs gprof"
 896     ;;
 897   h8300*-*-*)
 898     noconfigdirs="$noconfigdirs target-libgloss"
 899     ;;
 900   h8500-*-*)
 901     noconfigdirs="$noconfigdirs target-libgloss"
 902     ;;
 903   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 904     ;;
 905   hppa*64*-*-linux*)
 906     ;;
 907   hppa*-*-linux*)
 908     ;;
 909   hppa*-*-*elf* | \
 910   hppa*-*-lites* | \
 911   hppa*-*-openbsd* | \
 912   hppa*64*-*-*)
 913     ;;
 914   hppa*-hp-hpux11*)
 915     noconfigdirs="$noconfigdirs ld"
 916     ;;
 917   hppa*-*-pro*)
 918     ;;
 919   hppa*-*-*)
 920     noconfigdirs="$noconfigdirs ld"
 921     ;;
 922   i960-*-*)
 923     noconfigdirs="$noconfigdirs gdb"
 924     ;;
 925   ia64*-*-elf*)
 926     # No gdb support yet.
 927     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 928     ;;
 929   ia64*-**-hpux*)
 930     # No ld support yet.
 931     noconfigdirs="$noconfigdirs libgui itcl ld"
 932     ;;
 933   ia64*-*-*vms*)
 934     # No gdb or ld support yet.
 935     noconfigdirs="$noconfigdirs readline libgui itcl gdb ld"
 936     ;;
 937   i[[3456789]]86-w64-mingw*)
 938     ;;
 939   i[[3456789]]86-*-mingw*)
 940     target_configdirs="$target_configdirs target-winsup"
 941     ;;
 942   *-*-cygwin*)
 943     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 944     noconfigdirs="$noconfigdirs target-libgloss"
 945     # always build newlib if winsup directory is present.
 946     if test -d "$srcdir/winsup/cygwin"; then
 947       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 948     elif test -d "$srcdir/newlib"; then
 949       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 950     fi
 951     ;;
 952   i[[3456789]]86-*-pe)
 953     noconfigdirs="$noconfigdirs target-libgloss"
 954     ;;
 955   i[[3456789]]86-*-sco3.2v5*)
 956     # The linker does not yet know about weak symbols in COFF,
 957     # and is not configured to handle mixed ELF and COFF.
 958     noconfigdirs="$noconfigdirs ld target-libgloss"
 959     ;;
 960   i[[3456789]]86-*-sco*)
 961     noconfigdirs="$noconfigdirs gprof target-libgloss"
 962     ;;
 963   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 964     noconfigdirs="$noconfigdirs target-libgloss"
 965     ;;
 966   i[[3456789]]86-*-sysv4*)
 967     noconfigdirs="$noconfigdirs target-libgloss"
 968     ;;
 969   i[[3456789]]86-*-beos*)
 970     noconfigdirs="$noconfigdirs gdb"
 971     ;;
 972   i[[3456789]]86-*-rdos*)
 973     noconfigdirs="$noconfigdirs gdb"
 974     ;;
 975   mmix-*-*)
 976     noconfigdirs="$noconfigdirs gdb"
 977     ;;
 978   mt-*-*)
 979     noconfigdirs="$noconfigdirs sim"
 980     ;;
 981   powerpc-*-aix*)
 982     # copied from rs6000-*-* entry
 983     noconfigdirs="$noconfigdirs gprof"
 984     ;;
 985   powerpc*-*-winnt* | powerpc*-*-pe*)
 986     target_configdirs="$target_configdirs target-winsup"
 987     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
 988     # always build newlib.
 989     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 990     ;;
 991     # This is temporary until we can link against shared libraries
 992   powerpcle-*-solaris*)
 993     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
 994     ;;
 995   powerpc-*-beos*)
 996     noconfigdirs="$noconfigdirs gdb"
 997     ;;
 998   rs6000-*-lynxos*)
 999     noconfigdirs="$noconfigdirs gprof"
1000     ;;
1001   rs6000-*-aix*)
1002     noconfigdirs="$noconfigdirs gprof"
1003     ;;
1004   rs6000-*-*)
1005     noconfigdirs="$noconfigdirs gprof"
1006     ;;
1007   m68k-apollo-*)
1008     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1009     ;;
1010   microblaze*)
1011     noconfigdirs="$noconfigdirs gprof"
1012     ;;
1013   mips*-sde-elf*)
1014     if test x$with_newlib = xyes; then
1015       noconfigdirs="$noconfigdirs gprof"
1016     fi
1017     ;;
1018   mips*-*-irix5*)
1019     noconfigdirs="$noconfigdirs gprof target-libgloss"
1020     ;;
1021   mips*-*-irix6*)
1022     noconfigdirs="$noconfigdirs gprof target-libgloss"
1023     ;;
1024   mips*-*-bsd*)
1025     noconfigdirs="$noconfigdirs gprof target-libgloss"
1026     ;;
1027   mips*-*-linux*)
1028     ;;
1029   mips*-*-*)
1030     noconfigdirs="$noconfigdirs gprof"
1031     ;;
1032   sh-*-* | sh64-*-*)
1033     case "${target}" in
1034       sh*-*-elf)
1035          ;;
1036       *)
1037          noconfigdirs="$noconfigdirs target-libgloss" ;;
1038     esac
1039     ;;
1040   sparc-*-sunos4*)
1041     if test x${is_cross_compiler} = xno ; then
1042            use_gnu_ld=no
1043     fi
1044     ;;
1045   tic6x-*-*)
1046     noconfigdirs="$noconfigdirs sim"
1047     ;;
1048   tilepro-*-* | tilegx-*-*)
1049     noconfigdirs="$noconfigdirs sim"
1050     ;;
1051   v810-*-*)
1052     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1053     ;;
1054   vax-*-*)
1055     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1056     ;;
1057 esac
1058
1059 # If we aren't building newlib, then don't build libgloss, since libgloss
1060 # depends upon some newlib header files.
1061 case "${noconfigdirs}" in
1062   *target-libgloss*) ;;
1063   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1064 esac
1065
1066 # Work in distributions that contain no compiler tools, like Autoconf.
1067 host_makefile_frag=/dev/null
1068 if test -d ${srcdir}/config ; then
1069 case "${host}" in
1070   i[[3456789]]86-*-msdosdjgpp*)
1071     host_makefile_frag="config/mh-djgpp"
1072     ;;
1073   *-cygwin*)
1074     ACX_CHECK_CYGWIN_CAT_WORKS
1075     host_makefile_frag="config/mh-cygwin"
1076     ;;
1077   *-mingw*)
1078     host_makefile_frag="config/mh-mingw"
1079     ;;
1080   *-interix*)
1081     host_makefile_frag="config/mh-interix"
1082     ;;
1083   hppa*-hp-hpux10*)
1084     host_makefile_frag="config/mh-pa-hpux10"
1085     ;;
1086   hppa*-hp-hpux*)
1087     host_makefile_frag="config/mh-pa"
1088     ;;
1089   hppa*-*)
1090     host_makefile_frag="config/mh-pa"
1091     ;;
1092   *-*-darwin*)
1093     host_makefile_frag="config/mh-darwin"
1094     ;;
1095   powerpc-*-aix*)
1096     host_makefile_frag="config/mh-ppc-aix"
1097     ;;
1098   rs6000-*-aix*)
1099     host_makefile_frag="config/mh-ppc-aix"
1100     ;;
1101 esac
1102 fi
1103
1104 if test "${build}" != "${host}" ; then
1105   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1106   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1107   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1108   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1109   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1110   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1111   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1112   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1113   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1114   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1115   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1116   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1117   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1118 else
1119   AR_FOR_BUILD="\$(AR)"
1120   AS_FOR_BUILD="\$(AS)"
1121   CC_FOR_BUILD="\$(CC)"
1122   CXX_FOR_BUILD="\$(CXX)"
1123   GCJ_FOR_BUILD="\$(GCJ)"
1124   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1125   GOC_FOR_BUILD="\$(GOC)"
1126   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1127   LD_FOR_BUILD="\$(LD)"
1128   NM_FOR_BUILD="\$(NM)"
1129   RANLIB_FOR_BUILD="\$(RANLIB)"
1130   WINDRES_FOR_BUILD="\$(WINDRES)"
1131   WINDMC_FOR_BUILD="\$(WINDMC)"
1132 fi
1133
1134 AC_PROG_CC
1135 AC_PROG_CXX
1136
1137 # We must set the default linker to the linker used by gcc for the correct
1138 # operation of libtool.  If LD is not defined and we are using gcc, try to
1139 # set the LD default to the ld used by gcc.
1140 if test -z "$LD"; then
1141   if test "$GCC" = yes; then
1142     case $build in
1143     *-*-mingw*)
1144       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1145     *)
1146       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1147     esac
1148     case $gcc_prog_ld in
1149     # Accept absolute paths.
1150     [[\\/]* | [A-Za-z]:[\\/]*)]
1151       LD="$gcc_prog_ld" ;;
1152     esac
1153   fi
1154 fi
1155
1156 ACX_PROG_GNAT
1157 ACX_PROG_CMP_IGNORE_INITIAL
1158
1159 AC_ARG_ENABLE([bootstrap],
1160 [AS_HELP_STRING([--enable-bootstrap],
1161                 [enable bootstrapping @<:@yes if native build@:>@])],,
1162 enable_bootstrap=default)
1163
1164 # Issue errors and warnings for invalid/strange bootstrap combinations.
1165 if test -r $srcdir/gcc/configure; then
1166   have_compiler=yes
1167 else
1168   have_compiler=no
1169 fi
1170
1171 case "$have_compiler:$host:$target:$enable_bootstrap" in
1172   *:*:*:no) ;;
1173
1174   # Default behavior.  Enable bootstrap if we have a compiler
1175   # and we are in a native configuration.
1176   yes:$build:$build:default)
1177     enable_bootstrap=yes ;;
1178
1179   *:*:*:default)
1180     enable_bootstrap=no ;;
1181
1182   # We have a compiler and we are in a native configuration, bootstrap is ok
1183   yes:$build:$build:yes)
1184     ;;
1185
1186   # Other configurations, but we have a compiler.  Assume the user knows
1187   # what he's doing.
1188   yes:*:*:yes)
1189     AC_MSG_WARN([trying to bootstrap a cross compiler])
1190     ;;
1191
1192   # No compiler: if they passed --enable-bootstrap explicitly, fail
1193   no:*:*:yes)
1194     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1195
1196   # Fail if wrong command line
1197   *)
1198     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1199     ;;
1200 esac
1201
1202 # See if we are building gcc with C++.
1203 AC_ARG_ENABLE(build-with-cxx,
1204 [AS_HELP_STRING([--enable-build-with-cxx],
1205                 [build with C++ compiler instead of C compiler])],
1206 ENABLE_BUILD_WITH_CXX=$enableval,
1207 ENABLE_BUILD_WITH_CXX=no)
1208
1209 # Build stage1 with C and build stages 2 and 3 with C++.
1210 AC_ARG_ENABLE(build-poststage1-with-cxx,
1211 [AS_HELP_STRING([--enable-build-poststage1-with-cxx],
1212                 [build stages 2 and 3 with C++, not C])],
1213 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=$enableval,
1214 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=yes)
1215
1216 # Used for setting $lt_cv_objdir
1217 _LT_CHECK_OBJDIR
1218
1219 # Check for GMP, MPFR and MPC
1220 gmplibs="-lmpc -lmpfr -lgmp"
1221 gmpinc=
1222 have_gmp=no
1223
1224 # Specify a location for mpc
1225 # check for this first so it ends up on the link line before mpfr.
1226 AC_ARG_WITH(mpc,
1227 [AS_HELP_STRING([--with-mpc=PATH],
1228                 [specify prefix directory for installed MPC package.
1229                  Equivalent to --with-mpc-include=PATH/include
1230                  plus --with-mpc-lib=PATH/lib])])
1231 AC_ARG_WITH(mpc-include,
1232 [AS_HELP_STRING([--with-mpc-include=PATH],
1233                 [specify directory for installed MPC include files])])
1234 AC_ARG_WITH(mpc-lib,
1235 [AS_HELP_STRING([--with-mpc-lib=PATH],
1236                 [specify directory for the installed MPC library])])
1237
1238 if test "x$with_mpc" != x; then
1239   gmplibs="-L$with_mpc/lib $gmplibs"
1240   gmpinc="-I$with_mpc/include $gmpinc"
1241 fi
1242 if test "x$with_mpc_include" != x; then
1243   gmpinc="-I$with_mpc_include $gmpinc"
1244 fi
1245 if test "x$with_mpc_lib" != x; then
1246   gmplibs="-L$with_mpc_lib $gmplibs"
1247 fi
1248 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1249   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1250   gmpinc='-I$$s/mpc/src '"$gmpinc"
1251   # Do not test the mpc version.  Assume that it is sufficient, since
1252   # it is in the source tree, and the library has not been built yet
1253   # but it would be included on the link line in the version check below
1254   # hence making the test fail.
1255   have_gmp=yes
1256 fi
1257
1258 # Specify a location for mpfr
1259 # check for this first so it ends up on the link line before gmp.
1260 AC_ARG_WITH(mpfr-dir,
1261 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1262 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1263 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1264
1265 AC_ARG_WITH(mpfr,
1266 [AS_HELP_STRING([--with-mpfr=PATH],
1267                 [specify prefix directory for installed MPFR package.
1268                  Equivalent to --with-mpfr-include=PATH/include
1269                  plus --with-mpfr-lib=PATH/lib])])
1270 AC_ARG_WITH(mpfr-include,
1271 [AS_HELP_STRING([--with-mpfr-include=PATH],
1272                 [specify directory for installed MPFR include files])])
1273 AC_ARG_WITH(mpfr-lib,
1274 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1275                 [specify directory for the installed MPFR library])])
1276
1277 if test "x$with_mpfr" != x; then
1278   gmplibs="-L$with_mpfr/lib $gmplibs"
1279   gmpinc="-I$with_mpfr/include $gmpinc"
1280 fi
1281 if test "x$with_mpfr_include" != x; then
1282   gmpinc="-I$with_mpfr_include $gmpinc"
1283 fi
1284 if test "x$with_mpfr_lib" != x; then
1285   gmplibs="-L$with_mpfr_lib $gmplibs"
1286 fi
1287 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1288   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1289   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1290   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1291   # Do not test the mpfr version.  Assume that it is sufficient, since
1292   # it is in the source tree, and the library has not been built yet
1293   # but it would be included on the link line in the version check below
1294   # hence making the test fail.
1295   have_gmp=yes
1296 fi
1297
1298 # Specify a location for gmp
1299 AC_ARG_WITH(gmp-dir,
1300 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1301 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1302 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1303
1304 AC_ARG_WITH(gmp,
1305 [AS_HELP_STRING([--with-gmp=PATH],
1306                 [specify prefix directory for the installed GMP package.
1307                  Equivalent to --with-gmp-include=PATH/include
1308                  plus --with-gmp-lib=PATH/lib])])
1309 AC_ARG_WITH(gmp-include,
1310 [AS_HELP_STRING([--with-gmp-include=PATH],
1311                 [specify directory for installed GMP include files])])
1312 AC_ARG_WITH(gmp-lib,
1313 [AS_HELP_STRING([--with-gmp-lib=PATH],
1314                 [specify directory for the installed GMP library])])
1315
1316
1317 if test "x$with_gmp" != x; then
1318   gmplibs="-L$with_gmp/lib $gmplibs"
1319   gmpinc="-I$with_gmp/include $gmpinc"
1320 fi
1321 if test "x$with_gmp_include" != x; then
1322   gmpinc="-I$with_gmp_include $gmpinc"
1323 fi
1324 if test "x$with_gmp_lib" != x; then
1325   gmplibs="-L$with_gmp_lib $gmplibs"
1326 fi
1327 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1328   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1329   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1330   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1331   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1332   # Do not test the gmp version.  Assume that it is sufficient, since
1333   # it is in the source tree, and the library has not been built yet
1334   # but it would be included on the link line in the version check below
1335   # hence making the test fail.
1336   have_gmp=yes
1337 fi
1338
1339 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1340   have_gmp=yes
1341   saved_CFLAGS="$CFLAGS"
1342   CFLAGS="$CFLAGS $gmpinc"
1343   # Check for the recommended and required versions of GMP.
1344   AC_MSG_CHECKING([for the correct version of gmp.h])
1345   AC_TRY_COMPILE([#include "gmp.h"],[
1346   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1347   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1348   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1349   choke me
1350   #endif
1351   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1352   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1353   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1354   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1355   choke me
1356   #endif
1357   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1358    [AC_MSG_RESULT([no]); have_gmp=no])
1359
1360   # If we have GMP, check the MPFR version.
1361   if test x"$have_gmp" = xyes; then
1362     # Check for the recommended and required versions of MPFR.
1363     AC_MSG_CHECKING([for the correct version of mpfr.h])
1364     AC_TRY_COMPILE([#include <gmp.h>
1365     #include <mpfr.h>],[
1366     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1367     choke me
1368     #endif
1369     ], [AC_TRY_COMPILE([#include <gmp.h>
1370     #include <mpfr.h>],[
1371     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1372     choke me
1373     #endif
1374     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1375      [AC_MSG_RESULT([no]); have_gmp=no])
1376   fi
1377
1378   # Check for the MPC header version.
1379   if test x"$have_gmp" = xyes ; then
1380     # Check for the recommended and required versions of MPC.
1381     AC_MSG_CHECKING([for the correct version of mpc.h])
1382     AC_TRY_COMPILE([#include <mpc.h>],[
1383     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1384     choke me
1385     #endif
1386     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1387     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1388     choke me
1389     #endif
1390     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1391      [AC_MSG_RESULT([no]); have_gmp=no])
1392   fi
1393
1394   # Now check the MPFR library.
1395   if test x"$have_gmp" = xyes; then
1396     saved_LIBS="$LIBS"
1397     LIBS="$LIBS $gmplibs"
1398     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1399     AC_TRY_LINK([#include <mpc.h>],[
1400     mpfr_t n;
1401     mpfr_t x;
1402     mpc_t c;
1403     int t;
1404     mpfr_init (n);
1405     mpfr_init (x);
1406     mpfr_atan2 (n, n, x, GMP_RNDN);
1407     mpfr_erfc (n, x, GMP_RNDN);
1408     mpfr_subnormalize (x, t, GMP_RNDN);
1409     mpfr_clear(n);
1410     mpfr_clear(x);
1411     mpc_init2 (c, 53);
1412     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1413     mpc_cosh (c, c, MPC_RNDNN);
1414     mpc_pow (c, c, c, MPC_RNDNN);
1415     mpc_acosh (c, c, MPC_RNDNN);
1416     mpc_clear (c);
1417     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1418     LIBS="$saved_LIBS"
1419   fi
1420
1421   CFLAGS="$saved_CFLAGS"
1422
1423 # The library versions listed in the error message below should match
1424 # the HARD-minimums enforced above.
1425   if test x$have_gmp != xyes; then
1426     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1427 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1428 their locations.  Source code for these libraries can be found at
1429 their respective hosting sites as well as at
1430 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1431 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1432 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1433 make sure that you have installed both the libraries and the header
1434 files.  They may be located in separate packages.])
1435   fi
1436 fi
1437
1438 # Flags needed for both GMP, MPFR and/or MPC.
1439 AC_SUBST(gmplibs)
1440 AC_SUBST(gmpinc)
1441 AC_SUBST(extra_mpfr_configure_flags)
1442 AC_SUBST(extra_mpc_gmp_configure_flags)
1443 AC_SUBST(extra_mpc_mpfr_configure_flags)
1444
1445 # Allow host libstdc++ to be specified for static linking with PPL.
1446 AC_ARG_WITH(host-libstdcxx,
1447 [AS_HELP_STRING([--with-host-libstdcxx=L],
1448                 [use linker arguments L to link with libstdc++
1449                  when linking with PPL])])
1450
1451 case $with_host_libstdcxx in
1452   no|yes)
1453     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1454     ;;
1455 esac
1456
1457 # Linker flags to use for stage1 or when not boostrapping.
1458 AC_ARG_WITH(stage1-ldflags,
1459 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1460 [if test "$withval" = "no" -o "$withval" = "yes"; then
1461    stage1_ldflags=
1462  else
1463    stage1_ldflags=$withval
1464  fi],
1465 [stage1_ldflags=])
1466 AC_SUBST(stage1_ldflags)
1467
1468 # Libraries to use for stage1 or when not bootstrapping.
1469 AC_ARG_WITH(stage1-libs,
1470 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1471 [if test "$withval" = "no" -o "$withval" = "yes"; then
1472    stage1_libs=
1473  else
1474    stage1_libs=$withval
1475  fi],
1476 [stage1_libs=$with_host_libstdcxx])
1477 AC_SUBST(stage1_libs)
1478
1479 # Libraries to use for stage2 and later builds.  This defaults to the
1480 # argument passed to --with-host-libstdcxx.
1481 AC_ARG_WITH(boot-libs,
1482 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1483 [if test "$withval" = "no" -o "$withval" = "yes"; then
1484    poststage1_libs=
1485  else
1486    poststage1_libs=$withval
1487  fi],
1488 [poststage1_libs=$with_host_libstdcxx])
1489 AC_SUBST(poststage1_libs)
1490
1491 # Linker flags to use for stage2 and later builds.
1492 AC_ARG_WITH(boot-ldflags,
1493 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1494                 [linker flags for stage2 and later])],
1495 [if test "$withval" = "no" -o "$withval" = "yes"; then
1496    poststage1_ldflags=
1497  else
1498    poststage1_ldflags=$withval
1499  fi],
1500 [poststage1_ldflags=
1501  # In stages 2 and 3, default to linking libstdc++ and libgcc
1502  # statically.  But if the user explicitly specified the libraries to
1503  # use, trust that they are doing what they want.
1504  if test "$poststage1_libs" = ""; then
1505    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1506  fi])
1507 AC_SUBST(poststage1_ldflags)
1508
1509 # Check for PPL
1510 ppllibs=
1511 pplinc=
1512 pwllib=
1513
1514 AC_ARG_WITH(ppl,
1515 [AS_HELP_STRING([--with-ppl=PATH],
1516                 [specify prefix directory for the installed PPL package.
1517                  Equivalent to --with-ppl-include=PATH/include
1518                  plus --with-ppl-lib=PATH/lib])])
1519 AC_ARG_WITH(ppl-include,
1520 [AS_HELP_STRING([--with-ppl-include=PATH],
1521                 [specify directory for installed PPL include files])])
1522 AC_ARG_WITH(ppl-lib,
1523 [AS_HELP_STRING([--with-ppl-lib=PATH],
1524                 [specify directory for the installed PPL library])])
1525
1526 AC_ARG_ENABLE(ppl-version-check,
1527 [AS_HELP_STRING([--disable-ppl-version-check],
1528                 [disable check for PPL version])])
1529
1530 case $with_ppl in
1531   yes | no | "")
1532     ;;
1533   *)
1534     ppllibs="-L$with_ppl/lib"
1535     pplinc="-I$with_ppl/include $pplinc"
1536     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1537       with_ppl=yes
1538     else
1539       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1540     fi
1541     ;;
1542 esac
1543
1544 if test x"$with_ppl_include" != x; then
1545   pplinc="-I$with_ppl_include $pplinc"
1546   with_ppl=yes
1547 fi
1548
1549 if test "x$with_ppl_lib" != x; then
1550   ppllibs="-L$with_ppl_lib"
1551   with_ppl=yes
1552 fi
1553
1554 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1555   if test x"$enable_watchdog" = xyes; then
1556     pwllib="-lpwl"
1557   fi
1558   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1559   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1560   enable_ppl_version_check=no
1561   with_ppl=yes
1562 fi
1563
1564 if test "x$with_ppl" != xno; then
1565   if test "x$pwllib" = x; then
1566     saved_LIBS="$LIBS"
1567     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1568     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1569     LIBS="$saved_LIBS"
1570   fi
1571
1572   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1573
1574   if test "$enable_ppl_version_check" != no; then
1575     saved_CFLAGS="$CFLAGS"
1576     CFLAGS="$CFLAGS $pplinc $gmpinc"
1577     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1578     AC_TRY_COMPILE([#include "ppl_c.h"],[
1579     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1580     choke me
1581     #endif
1582     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1583     CFLAGS="$saved_CFLAGS"
1584   fi
1585 fi
1586
1587 # Flags needed for PPL
1588 AC_SUBST(ppllibs)
1589 AC_SUBST(pplinc)
1590
1591
1592 # Check for CLOOG
1593
1594 dnl Provide configure switches and initialize clooginc & clooglibs
1595 dnl with user input.
1596 CLOOG_INIT_FLAGS
1597 if test "x$with_ppl" = "xno"; then
1598   dnl Only execute fail-action, if CLooG has been requested.
1599   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1600   if test "${graphite_requested}" = yes; then
1601     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1602   fi
1603   with_cloog=no
1604 fi
1605 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1606   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1607   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1608   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1609 fi
1610 if test "x$with_cloog" != "xno"; then
1611   dnl The minimal version of CLooG required for Graphite.
1612   dnl
1613   dnl If we use CLooG-Legacy, the provided version information is
1614   dnl ignored.
1615   CLOOG_CHECK_VERSION(0,16,1)
1616
1617   dnl Only execute fail-action, if CLooG has been requested.
1618   CLOOG_IF_FAILED([
1619     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1620 fi
1621
1622 # Check for LTO support.
1623 AC_ARG_ENABLE(lto,
1624 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1625 enable_lto=$enableval,
1626 enable_lto=yes; default_enable_lto=yes)
1627
1628 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1629   build_lto_plugin=yes
1630 ],[if test x"$default_enable_lto" = x"yes" ; then
1631     case $target in
1632       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1633       # On other non-ELF platforms, LTO has yet to be validated.
1634       *) enable_lto=no ;;
1635     esac
1636   else
1637   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1638   # It would also be nice to check the binutils support, but we don't
1639   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1640   # warn during gcc/ subconfigure; unless you're bootstrapping with
1641   # -flto it won't be needed until after installation anyway.
1642     case $target in
1643       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1644       *) if test x"$enable_lto" = x"yes"; then
1645         AC_MSG_ERROR([LTO support is not enabled for this target.])
1646         fi
1647       ;;
1648     esac
1649   fi
1650   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1651   # Build it unless LTO was explicitly disabled.
1652   case $target in
1653     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1654     *) ;;
1655   esac
1656 ])
1657
1658
1659 # By default, C is the only stage 1 language.
1660 stage1_languages=,c,
1661
1662 # Target libraries that we bootstrap.
1663 bootstrap_target_libs=,target-libgcc,
1664
1665 # Figure out what language subdirectories are present.
1666 # Look if the user specified --enable-languages="..."; if not, use
1667 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1668 # go away some day.
1669 # NB:  embedded tabs in this IF block -- do not untabify
1670 if test -d ${srcdir}/gcc; then
1671   if test x"${enable_languages+set}" != xset; then
1672     if test x"${LANGUAGES+set}" = xset; then
1673       enable_languages="${LANGUAGES}"
1674         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1675     else
1676       enable_languages=all
1677     fi
1678   else
1679     if test x"${enable_languages}" = x ||
1680        test x"${enable_languages}" = xyes;
1681        then
1682       echo configure.in: --enable-languages needs at least one language argument 1>&2
1683       exit 1
1684     fi
1685   fi
1686   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1687
1688   # 'f95' is the old name for the 'fortran' language. We issue a warning
1689   # and make the substitution.
1690   case ,${enable_languages}, in
1691     *,f95,*)
1692       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1693       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1694       ;;
1695   esac
1696
1697   # If bootstrapping, then using --enable-build-with-cxx or
1698   # --enable-build-poststage1-with-cxx requires enabling C++.
1699   case ",$enable_languages,:,$ENABLE_BUILD_WITH_CXX,$ENABLE_BUILD_POSTSTAGE1_WITH_CXX,:$enable_bootstrap" in
1700     *,c++,*:*:*) ;;
1701     *:*,yes,*:yes)
1702       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1703         enable_languages="${enable_languages},c++"
1704       else
1705         AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx or --enable-build-poststage1-with-cxx requires c++ sources])
1706       fi
1707       ;;
1708   esac
1709
1710   # First scan to see if an enabled language requires some other language.
1711   # We assume that a given config-lang.in will list all the language
1712   # front ends it requires, even if some are required indirectly.
1713   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1714     case ${lang_frag} in
1715       ..) ;;
1716       # The odd quoting in the next line works around
1717       # an apparent bug in bash 1.12 on linux.
1718       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1719       *)
1720         # From the config-lang.in, get $language, $lang_requires, and
1721         # $lang_requires_boot_languages.
1722         language=
1723         lang_requires=
1724         lang_requires_boot_languages=
1725         . ${lang_frag}
1726         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1727           case ,${enable_languages}, in
1728             *,$other,*) ;;
1729             *,all,*) ;;
1730             *,$language,*)
1731               echo " \`$other' language required by \`$language'; enabling" 1>&2
1732               enable_languages="${enable_languages},${other}"
1733               ;;
1734           esac
1735         done
1736         for other in ${lang_requires_boot_languages} ; do
1737           if test "$other" != "c"; then
1738             case ,${enable_stage1_languages}, in
1739               *,$other,*) ;;
1740               *,all,*) ;;
1741               *)
1742                 case ,${enable_languages}, in
1743                   *,$language,*)
1744                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1745                     enable_stage1_languages="$enable_stage1_languages,${other}"
1746                     ;;
1747                 esac
1748                 ;;
1749             esac
1750           fi
1751         done
1752         ;;
1753     esac
1754   done
1755
1756   new_enable_languages=,c,
1757
1758   # If LTO is enabled, add the LTO front end.
1759   extra_host_libiberty_configure_flags=
1760   if test "$enable_lto" = "yes" ; then
1761     case ,${enable_languages}, in
1762       *,lto,*) ;;
1763       *) enable_languages="${enable_languages},lto" ;;
1764     esac
1765     if test "${build_lto_plugin}" = "yes" ; then
1766       configdirs="$configdirs lto-plugin"
1767       extra_host_libiberty_configure_flags=--enable-shared
1768     fi
1769   fi
1770   AC_SUBST(extra_host_libiberty_configure_flags)
1771
1772   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1773   potential_languages=,c,
1774
1775   enabled_target_libs=
1776   disabled_target_libs=
1777
1778   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1779     case ${lang_frag} in
1780       ..) ;;
1781       # The odd quoting in the next line works around
1782       # an apparent bug in bash 1.12 on linux.
1783       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1784       *)
1785         # From the config-lang.in, get $language, $target_libs,
1786         # $lang_dirs, $boot_language, and $build_by_default
1787         language=
1788         target_libs=
1789         lang_dirs=
1790         subdir_requires=
1791         boot_language=no
1792         build_by_default=yes
1793         . ${lang_frag}
1794         if test x${language} = x; then
1795           echo "${lang_frag} doesn't set \$language." 1>&2
1796           exit 1
1797         fi
1798
1799         if test "$language" = "c++"; then
1800           if test "$ENABLE_BUILD_WITH_CXX" = "yes" \
1801              || test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
1802             boot_language=yes
1803           fi
1804         fi
1805
1806         case ,${enable_languages}, in
1807           *,${language},*)
1808             # Language was explicitly selected; include it.
1809             add_this_lang=yes
1810             ;;
1811           *,all,*)
1812             # 'all' was selected, select it if it is a default language
1813             add_this_lang=${build_by_default}
1814             ;;
1815           *)
1816             add_this_lang=no
1817             ;;
1818         esac
1819
1820         # Disable languages that need other directories if these aren't available.
1821         for i in $subdir_requires; do
1822           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1823           case ,${enable_languages}, in
1824             *,${language},*)
1825               # Specifically requested language; tell them.
1826               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1827               ;;
1828             *)
1829               # Silently disable.
1830               add_this_lang=unsupported
1831               ;;
1832           esac
1833         done
1834
1835         # Disable Ada if no preexisting GNAT is available.
1836         case ,${enable_languages},:${language}:${have_gnat} in
1837           *,${language},*:ada:no)
1838             # Specifically requested language; tell them.
1839             AC_MSG_ERROR([GNAT is required to build $language])
1840             ;;
1841           *:ada:no)
1842             # Silently disable.
1843             add_this_lang=unsupported
1844             ;;
1845         esac
1846
1847         # Disable a language that is unsupported by the target.
1848         case " $unsupported_languages " in
1849           *" $language "*)
1850             add_this_lang=unsupported
1851             ;;
1852         esac
1853
1854         case $add_this_lang in
1855           unsupported)
1856             # Remove language-dependent dirs.
1857             disabled_target_libs="$disabled_target_libs $target_libs"
1858             noconfigdirs="$noconfigdirs $lang_dirs"
1859             ;;
1860           no)
1861             # Remove language-dependent dirs; still show language as supported.
1862             disabled_target_libs="$disabled_target_libs $target_libs"
1863             noconfigdirs="$noconfigdirs $lang_dirs"
1864             potential_languages="${potential_languages}${language},"
1865             ;;
1866           yes)
1867             new_enable_languages="${new_enable_languages}${language},"
1868             potential_languages="${potential_languages}${language},"
1869             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1870             enabled_target_libs="$enabled_target_libs $target_libs"
1871             case "${boot_language}:,$enable_stage1_languages," in
1872               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1873                 # Add to (comma-separated) list of stage 1 languages.
1874                 case ",$stage1_languages," in
1875                   *,$language,* | ,yes, | ,all,) ;;
1876                   *) stage1_languages="${stage1_languages}${language}," ;;
1877                 esac
1878                 # We need to bootstrap any supporting libraries.
1879                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1880                 ;;
1881             esac
1882             ;;
1883         esac
1884         ;;
1885     esac
1886   done
1887
1888   # Add target libraries which are only needed for disabled languages
1889   # to noconfigdirs.
1890   if test -n "$disabled_target_libs"; then
1891     for dir in $disabled_target_libs; do
1892       case " $enabled_target_libs " in
1893       *" ${dir} "*) ;;
1894       *) noconfigdirs="$noconfigdirs $dir" ;;
1895       esac
1896     done
1897   fi
1898
1899   AC_ARG_ENABLE(stage1-languages,
1900   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1901                   [choose additional languages to build during
1902                   stage1.  Mostly useful for compiler development])],
1903   [case ,${enable_stage1_languages}, in
1904     ,no,|,,)
1905       # Set it to something that will have no effect in the loop below
1906       enable_stage1_languages=c ;;
1907     ,yes,)
1908       enable_stage1_languages=`echo $new_enable_languages | \
1909         sed -e "s/^,//" -e "s/,$//" ` ;;
1910     *,all,*)
1911       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1912         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1913   esac
1914
1915   # Add "good" languages from enable_stage1_languages to stage1_languages,
1916   # while "bad" languages go in missing_languages.  Leave no duplicates.
1917   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1918     case $potential_languages in
1919       *,$i,*)
1920         case $stage1_languages in
1921           *,$i,*) ;;
1922           *) stage1_languages="$stage1_languages$i," ;;
1923         esac ;;
1924       *)
1925         case $missing_languages in
1926           *,$i,*) ;;
1927           *) missing_languages="$missing_languages$i," ;;
1928         esac ;;
1929      esac
1930   done])
1931
1932   # Remove leading/trailing commas that were added for simplicity
1933   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1934   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1935   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1936   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1937
1938   if test "x$missing_languages" != x; then
1939     AC_MSG_ERROR([
1940 The following requested languages could not be built: ${missing_languages}
1941 Supported languages are: ${potential_languages}])
1942   fi
1943   if test "x$new_enable_languages" != "x$enable_languages"; then
1944     echo The following languages will be built: ${new_enable_languages}
1945     enable_languages="$new_enable_languages"
1946   fi
1947
1948   AC_SUBST(stage1_languages)
1949   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1950 fi
1951
1952 # Handle --disable-<component> generically.
1953 for dir in $configdirs $build_configdirs $target_configdirs ; do
1954   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1955   varname=`echo $dirname | sed -e s/+/_/g`
1956   if eval test x\${enable_${varname}} "=" xno ; then
1957     noconfigdirs="$noconfigdirs $dir"
1958   fi
1959 done
1960
1961 # Check for Boehm's garbage collector
1962 AC_ARG_ENABLE(objc-gc,
1963 [AS_HELP_STRING([--enable-objc-gc],
1964                 [enable use of Boehm's garbage collector with the
1965                  GNU Objective-C runtime])],
1966 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1967   *,objc,*:*:yes:*target-boehm-gc*)
1968     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1969     ;;
1970 esac])
1971
1972 # Make sure we only build Boehm's garbage collector if required.
1973 case ,${enable_languages},:${enable_objc_gc} in
1974   *,objc,*:yes)
1975     # Keep target-boehm-gc if requested for Objective-C.
1976     ;;
1977   *)
1978     # Otherwise remove target-boehm-gc depending on target-libjava.
1979     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1980       noconfigdirs="$noconfigdirs target-boehm-gc"
1981     fi
1982     ;;
1983 esac
1984
1985 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1986 # $build_configdirs and $target_configdirs.
1987 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1988
1989 notsupp=""
1990 for dir in . $skipdirs $noconfigdirs ; do
1991   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1992   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1993     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1994     if test -r $srcdir/$dirname/configure ; then
1995       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1996         true
1997       else
1998         notsupp="$notsupp $dir"
1999       fi
2000     fi
2001   fi
2002   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2003     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2004     if test -r $srcdir/$dirname/configure ; then
2005       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2006         true
2007       else
2008         notsupp="$notsupp $dir"
2009       fi
2010     fi
2011   fi
2012   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2013     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2014     if test -r $srcdir/$dirname/configure ; then
2015       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2016         true
2017       else
2018         notsupp="$notsupp $dir"
2019       fi
2020     fi
2021   fi
2022 done
2023
2024 # Quietly strip out all directories which aren't configurable in this tree.
2025 # This relies on all configurable subdirectories being autoconfiscated, which
2026 # is now the case.
2027 build_configdirs_all="$build_configdirs"
2028 build_configdirs=
2029 for i in ${build_configdirs_all} ; do
2030   j=`echo $i | sed -e s/build-//g`
2031   if test -f ${srcdir}/$j/configure ; then
2032     build_configdirs="${build_configdirs} $i"
2033   fi
2034 done
2035
2036 configdirs_all="$configdirs"
2037 configdirs=
2038 for i in ${configdirs_all} ; do
2039   if test -f ${srcdir}/$i/configure ; then
2040     configdirs="${configdirs} $i"
2041   fi
2042 done
2043
2044 target_configdirs_all="$target_configdirs"
2045 target_configdirs=
2046 for i in ${target_configdirs_all} ; do
2047   j=`echo $i | sed -e s/target-//g`
2048   if test -f ${srcdir}/$j/configure ; then
2049     target_configdirs="${target_configdirs} $i"
2050   fi
2051 done
2052
2053 # Produce a warning message for the subdirs we can't configure.
2054 # This isn't especially interesting in the Cygnus tree, but in the individual
2055 # FSF releases, it's important to let people know when their machine isn't
2056 # supported by the one or two programs in a package.
2057
2058 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2059   # If $appdirs is non-empty, at least one of those directories must still
2060   # be configured, or we error out.  (E.g., if the gas release supports a
2061   # specified target in some subdirs but not the gas subdir, we shouldn't
2062   # pretend that all is well.)
2063   if test -n "$appdirs" ; then
2064     for dir in $appdirs ; do
2065       if test -r $dir/Makefile.in ; then
2066         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2067           appdirs=""
2068           break
2069         fi
2070         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2071           appdirs=""
2072           break
2073         fi
2074       fi
2075     done
2076     if test -n "$appdirs" ; then
2077       echo "*** This configuration is not supported by this package." 1>&2
2078       exit 1
2079     fi
2080   fi
2081   # Okay, some application will build, or we don't care to check.  Still
2082   # notify of subdirs not getting built.
2083   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2084   echo "    ${notsupp}" 1>&2
2085   echo "    (Any other directories should still work fine.)" 1>&2
2086 fi
2087
2088 case "$host" in
2089   *msdosdjgpp*)
2090     enable_gdbtk=no ;;
2091 esac
2092
2093 # To find our prefix, in gcc_cv_tool_prefix.
2094 ACX_TOOL_DIRS
2095
2096 copy_dirs=
2097
2098 AC_ARG_WITH([build-sysroot],
2099   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2100                   [use sysroot as the system root during the build])],
2101   [if test x"$withval" != x ; then
2102      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2103    fi],
2104   [SYSROOT_CFLAGS_FOR_TARGET=])
2105 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2106
2107 AC_ARG_WITH([debug-prefix-map],
2108   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2109                   [map A to B, C to D ... in debug information])],
2110   [if test x"$withval" != x; then
2111      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2112      for debug_map in $withval; do
2113        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2114      done
2115    fi],
2116   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2117 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2118
2119 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2120 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2121 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2122 # We want to ensure that TARGET libraries (which we know are built with
2123 # gcc) are built with "-O2 -g", so include those options when setting
2124 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2125 if test "x$CFLAGS_FOR_TARGET" = x; then
2126   CFLAGS_FOR_TARGET=$CFLAGS
2127   case " $CFLAGS " in
2128     *" -O2 "*) ;;
2129     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2130   esac
2131   case " $CFLAGS " in
2132     *" -g "* | *" -g3 "*) ;;
2133     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2134   esac
2135 fi
2136 AC_SUBST(CFLAGS_FOR_TARGET)
2137
2138 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2139   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2140   case " $CXXFLAGS " in
2141     *" -O2 "*) ;;
2142     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2143   esac
2144   case " $CXXFLAGS " in
2145     *" -g "* | *" -g3 "*) ;;
2146     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2147   esac
2148 fi
2149 AC_SUBST(CXXFLAGS_FOR_TARGET)
2150
2151 AC_SUBST(LDFLAGS_FOR_TARGET)
2152
2153 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2154 # the named directory are copied to $(tooldir)/sys-include.
2155 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2156   if test x${is_cross_compiler} = xno ; then
2157     echo 1>&2 '***' --with-headers is only supported when cross compiling
2158     exit 1
2159   fi
2160   if test x"${with_headers}" != xyes ; then
2161     x=${gcc_cv_tool_prefix}
2162     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2163   fi
2164 fi
2165
2166 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2167 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2168 # are permitted.
2169 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2170   if test x${is_cross_compiler} = xno ; then
2171     echo 1>&2 '***' --with-libs is only supported when cross compiling
2172     exit 1
2173   fi
2174   if test x"${with_libs}" != xyes ; then
2175     # Copy the libraries in reverse order, so that files in the first named
2176     # library override files in subsequent libraries.
2177     x=${gcc_cv_tool_prefix}
2178     for l in ${with_libs}; do
2179       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2180     done
2181   fi
2182 fi
2183
2184 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2185 #
2186 # This is done by determining whether or not the appropriate directory
2187 # is available, and by checking whether or not specific configurations
2188 # have requested that this magic not happen.
2189 #
2190 # The command line options always override the explicit settings in
2191 # configure.in, and the settings in configure.in override this magic.
2192 #
2193 # If the default for a toolchain is to use GNU as and ld, and you don't
2194 # want to do that, then you should use the --without-gnu-as and
2195 # --without-gnu-ld options for the configure script.  Similarly, if
2196 # the default is to use the included zlib and you don't want to do that,
2197 # you should use the --with-system-zlib option for the configure script.
2198
2199 if test x${use_gnu_as} = x &&
2200    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2201   with_gnu_as=yes
2202   extra_host_args="$extra_host_args --with-gnu-as"
2203 fi
2204
2205 if test x${use_gnu_ld} = x &&
2206    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2207   with_gnu_ld=yes
2208   extra_host_args="$extra_host_args --with-gnu-ld"
2209 fi
2210
2211 if test x${use_included_zlib} = x &&
2212    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2213   :
2214 else
2215   with_system_zlib=yes
2216   extra_host_args="$extra_host_args --with-system-zlib"
2217 fi
2218
2219 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2220 # can detect this case.
2221
2222 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2223   with_newlib=yes
2224   extra_host_args="$extra_host_args --with-newlib"
2225 fi
2226
2227 # Handle ${copy_dirs}
2228 set fnord ${copy_dirs}
2229 shift
2230 while test $# != 0 ; do
2231   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2232     :
2233   else
2234     echo Copying $1 to $2
2235
2236     # Use the install script to create the directory and all required
2237     # parent directories.
2238     if test -d $2 ; then
2239       :
2240     else
2241       echo >config.temp
2242       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2243     fi
2244
2245     # Copy the directory, assuming we have tar.
2246     # FIXME: Should we use B in the second tar?  Not all systems support it.
2247     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2248
2249     # It is the responsibility of the user to correctly adjust all
2250     # symlinks.  If somebody can figure out how to handle them correctly
2251     # here, feel free to add the code.
2252
2253     echo $1 > $2/COPIED
2254   fi
2255   shift; shift
2256 done
2257
2258 # Determine a target-dependent exec_prefix that the installed
2259 # gcc will search in.  Keep this list sorted by triplet, with
2260 # the *-*-osname triplets last.
2261 md_exec_prefix=
2262 case "${target}" in
2263   i[[34567]]86-pc-msdosdjgpp*)
2264     md_exec_prefix=/dev/env/DJDIR/bin
2265     ;;
2266   *-*-hpux* | \
2267   *-*-nto-qnx* | \
2268   *-*-solaris2*)
2269     md_exec_prefix=/usr/ccs/bin
2270     ;;
2271 esac
2272
2273 extra_arflags_for_target=
2274 extra_nmflags_for_target=
2275 extra_ranlibflags_for_target=
2276 target_makefile_frag=/dev/null
2277 case "${target}" in
2278   spu-*-*)
2279     target_makefile_frag="config/mt-spu"
2280     ;;
2281   mips*-sde-elf*)
2282     target_makefile_frag="config/mt-sde"
2283     ;;
2284   mipsisa*-*-elfoabi*)
2285     target_makefile_frag="config/mt-mips-elfoabi"
2286     ;;
2287   mips*-*-*linux* | mips*-*-gnu*)
2288     target_makefile_frag="config/mt-mips-gnu"
2289     ;;
2290   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2291     target_makefile_frag="config/mt-gnu"
2292     ;;
2293   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2294     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2295     # commands to handle both 32-bit and 64-bit objects.  These flags are
2296     # harmless if we're using GNU nm or ar.
2297     extra_arflags_for_target=" -X32_64"
2298     extra_nmflags_for_target=" -B -X32_64"
2299     ;;
2300 esac
2301
2302 alphaieee_frag=/dev/null
2303 case $target in
2304   alpha*-*-*)
2305     # This just makes sure to use the -mieee option to build target libs.
2306     # This should probably be set individually by each library.
2307     alphaieee_frag="config/mt-alphaieee"
2308     ;;
2309 esac
2310
2311 # If --enable-target-optspace always use -Os instead of -O2 to build
2312 # the target libraries, similarly if it is not specified, use -Os
2313 # on selected platforms.
2314 ospace_frag=/dev/null
2315 case "${enable_target_optspace}:${target}" in
2316   yes:*)
2317     ospace_frag="config/mt-ospace"
2318     ;;
2319   :d30v-*)
2320     ospace_frag="config/mt-d30v"
2321     ;;
2322   :m32r-* | :d10v-* | :fr30-*)
2323     ospace_frag="config/mt-ospace"
2324     ;;
2325   no:* | :*)
2326     ;;
2327   *)
2328     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2329     ;;
2330 esac
2331
2332 # Default to using --with-stabs for certain targets.
2333 if test x${with_stabs} = x ; then
2334   case "${target}" in
2335   mips*-*-irix[[56]]*)
2336     ;;
2337   mips*-*-* | alpha*-*-osf*)
2338     with_stabs=yes;
2339     extra_host_args="${extra_host_args} --with-stabs"
2340     ;;
2341   esac
2342 fi
2343
2344 # Some systems (e.g., one of the i386-aix systems the gas testers are
2345 # using) don't handle "\$" correctly, so don't use it here.
2346 tooldir='${exec_prefix}'/${target_noncanonical}
2347 build_tooldir=${tooldir}
2348
2349 # Create a .gdbinit file which runs the one in srcdir
2350 # and tells GDB to look there for source files.
2351
2352 if test -r ${srcdir}/.gdbinit ; then
2353   case ${srcdir} in
2354     .) ;;
2355     *) cat > ./.gdbinit <<EOF
2356 # ${NO_EDIT}
2357 dir ${srcdir}
2358 dir .
2359 source ${srcdir}/.gdbinit
2360 EOF
2361     ;;
2362   esac
2363 fi
2364
2365 # Make sure that the compiler is able to generate an executable.  If it
2366 # can't, we are probably in trouble.  We don't care whether we can run the
2367 # executable--we might be using a cross compiler--we only care whether it
2368 # can be created.  At this point the main configure script has set CC.
2369 we_are_ok=no
2370 echo "int main () { return 0; }" > conftest.c
2371 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2372 if test $? = 0 ; then
2373   if test -s conftest || test -s conftest.exe ; then
2374     we_are_ok=yes
2375   fi
2376 fi
2377 case $we_are_ok in
2378   no)
2379     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2380     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2381     rm -f conftest*
2382     exit 1
2383     ;;
2384 esac
2385 rm -f conftest*
2386
2387 # Decide which environment variable is used to find dynamic libraries.
2388 case "${host}" in
2389   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2390   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2391   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2392   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2393 esac
2394
2395 # On systems where the dynamic library environment variable is PATH,
2396 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2397 # built executables to PATH.
2398 if test "$RPATH_ENVVAR" = PATH; then
2399   GCC_SHLIB_SUBDIR=/shlib
2400 else
2401   GCC_SHLIB_SUBDIR=
2402 fi
2403
2404 # Record target_configdirs and the configure arguments for target and
2405 # build configuration in Makefile.
2406 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2407 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2408
2409 # If we are building libgomp, bootstrap it.
2410 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2411   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2412 fi
2413
2414 # Determine whether gdb needs tk/tcl or not.
2415 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2416 # and in that case we want gdb to be built without tk.  Ugh!
2417 # In fact I believe gdb is the *only* package directly dependent on tk,
2418 # so we should be able to put the 'maybe's in unconditionally and
2419 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2420 # 100% sure that that's safe though.
2421
2422 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2423 case "$enable_gdbtk" in
2424   no)
2425     GDB_TK="" ;;
2426   yes)
2427     GDB_TK="${gdb_tk}" ;;
2428   *)
2429     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2430     # distro.  Eventually someone will fix this and move Insight, nee
2431     # gdbtk to a separate directory.
2432     if test -d ${srcdir}/gdb/gdbtk ; then
2433       GDB_TK="${gdb_tk}"
2434     else
2435       GDB_TK=""
2436     fi
2437     ;;
2438 esac
2439 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2440 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2441
2442 # Strip out unwanted targets.
2443
2444 # While at that, we remove Makefiles if we were started for recursive
2445 # configuration, so that the top-level Makefile reconfigures them,
2446 # like we used to do when configure itself was recursive.
2447
2448 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2449 # but now we're fixing up the Makefile ourselves with the additional
2450 # commands passed to AC_CONFIG_FILES.  Use separate variables
2451 # extrasub-{build,host,target} not because there is any reason to split
2452 # the substitutions up that way, but only to remain below the limit of
2453 # 99 commands in a script, for HP-UX sed.
2454 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2455
2456 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2457   yes:yes:*\ gold\ *:*,c++,*) ;;
2458   yes:yes:*\ gold\ *:*)
2459     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2460     ;;
2461 esac
2462
2463 # Adjust the toplevel makefile according to whether bootstrap was selected.
2464 case $enable_bootstrap in
2465   yes)
2466     bootstrap_suffix=bootstrap
2467     BUILD_CONFIG=bootstrap-debug
2468     ;;
2469   no)
2470     bootstrap_suffix=no-bootstrap
2471     BUILD_CONFIG=
2472     ;;
2473 esac
2474
2475 AC_MSG_CHECKING(for default BUILD_CONFIG)
2476
2477 AC_ARG_WITH([build-config],
2478   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2479                   [use config/NAME.mk build configuration])],
2480   [case $with_build_config in
2481    yes) with_build_config= ;;
2482    no) with_build_config= BUILD_CONFIG= ;;
2483    esac])
2484
2485 if test "x${with_build_config}" != x; then
2486   BUILD_CONFIG=$with_build_config
2487 else
2488   case $BUILD_CONFIG in
2489   bootstrap-debug)
2490     if echo "int f (void) { return 0; }" > conftest.c &&
2491        ${CC} -c conftest.c &&
2492        mv conftest.o conftest.o.g0 &&
2493        ${CC} -c -g conftest.c &&
2494        mv conftest.o conftest.o.g &&
2495        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2496       :
2497     else
2498       BUILD_CONFIG=
2499     fi
2500     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2501     ;;
2502   esac
2503 fi
2504 AC_MSG_RESULT($BUILD_CONFIG)
2505 AC_SUBST(BUILD_CONFIG)
2506
2507 extrasub_build=
2508 for module in ${build_configdirs} ; do
2509   if test -z "${no_recursion}" \
2510      && test -f ${build_subdir}/${module}/Makefile; then
2511     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2512     rm -f ${build_subdir}/${module}/Makefile
2513   fi
2514   extrasub_build="$extrasub_build
2515 /^@if build-$module\$/d
2516 /^@endif build-$module\$/d
2517 /^@if build-$module-$bootstrap_suffix\$/d
2518 /^@endif build-$module-$bootstrap_suffix\$/d"
2519 done
2520 extrasub_host=
2521 for module in ${configdirs} ; do
2522   if test -z "${no_recursion}"; then
2523     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2524       if test -f ${file}; then
2525         echo 1>&2 "*** removing ${file} to force reconfigure"
2526         rm -f ${file}
2527       fi
2528     done
2529   fi
2530   extrasub_host="$extrasub_host
2531 /^@if $module\$/d
2532 /^@endif $module\$/d
2533 /^@if $module-$bootstrap_suffix\$/d
2534 /^@endif $module-$bootstrap_suffix\$/d"
2535 done
2536 extrasub_target=
2537 for module in ${target_configdirs} ; do
2538   if test -z "${no_recursion}" \
2539      && test -f ${target_subdir}/${module}/Makefile; then
2540     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2541     rm -f ${target_subdir}/${module}/Makefile
2542   fi
2543
2544   # We only bootstrap target libraries listed in bootstrap_target_libs.
2545   case $bootstrap_target_libs in
2546     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2547     *) target_bootstrap_suffix=no-bootstrap ;;
2548   esac
2549
2550   extrasub_target="$extrasub_target
2551 /^@if target-$module\$/d
2552 /^@endif target-$module\$/d
2553 /^@if target-$module-$target_bootstrap_suffix\$/d
2554 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2555 done
2556
2557 # Do the final fixup along with target modules.
2558 extrasub_target="$extrasub_target
2559 /^@if /,/^@endif /d"
2560
2561 # Create the serialization dependencies.  This uses a temporary file.
2562
2563 AC_ARG_ENABLE([serial-configure],
2564 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2565                 [force sequential configuration of
2566                  sub-packages for the host, target or build
2567                  machine, or all sub-packages])])
2568
2569 case ${enable_serial_configure} in
2570   yes)
2571     enable_serial_build_configure=yes
2572     enable_serial_host_configure=yes
2573     enable_serial_target_configure=yes
2574     ;;
2575 esac
2576
2577 # These force 'configure's to be done one at a time, to avoid problems
2578 # with contention over a shared config.cache.
2579 rm -f serdep.tmp
2580 echo '# serdep.tmp' > serdep.tmp
2581 olditem=
2582 test "x${enable_serial_build_configure}" = xyes &&
2583 for item in ${build_configdirs} ; do
2584   case ${olditem} in
2585     "") ;;
2586     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2587   esac
2588   olditem=${item}
2589 done
2590 olditem=
2591 test "x${enable_serial_host_configure}" = xyes &&
2592 for item in ${configdirs} ; do
2593   case ${olditem} in
2594     "") ;;
2595     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2596   esac
2597   olditem=${item}
2598 done
2599 olditem=
2600 test "x${enable_serial_target_configure}" = xyes &&
2601 for item in ${target_configdirs} ; do
2602   case ${olditem} in
2603     "") ;;
2604     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2605   esac
2606   olditem=${item}
2607 done
2608 serialization_dependencies=serdep.tmp
2609 AC_SUBST_FILE(serialization_dependencies)
2610
2611 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2612 # target, nonopt, and variable assignments.  These are the ones we
2613 # might not want to pass down to subconfigures.  The exception being
2614 # --cache-file=/dev/null, which is used to turn off the use of cache
2615 # files altogether, and which should be passed on to subconfigures.
2616 # Also strip program-prefix, program-suffix, and program-transform-name,
2617 # so that we can pass down a consistent program-transform-name.
2618 baseargs=
2619 tbaseargs=
2620 keep_next=no
2621 skip_next=no
2622 eval "set -- $ac_configure_args"
2623 for ac_arg
2624 do
2625   if test X"$skip_next" = X"yes"; then
2626     skip_next=no
2627     continue
2628   fi
2629   if test X"$keep_next" = X"yes"; then
2630     case $ac_arg in
2631       *\'*)
2632         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2633     esac
2634     baseargs="$baseargs '$ac_arg'"
2635     tbaseargs="$tbaseargs '$ac_arg'"
2636     keep_next=no
2637     continue
2638   fi
2639
2640   # Handle separated arguments.  Based on the logic generated by
2641   # autoconf 2.59.
2642   case $ac_arg in
2643     *=* | --config-cache | -C | -disable-* | --disable-* \
2644       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2645       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2646       | -with-* | --with-* | -without-* | --without-* | --x)
2647       separate_arg=no
2648       ;;
2649     -*)
2650       separate_arg=yes
2651       ;;
2652     *)
2653       separate_arg=no
2654       ;;
2655   esac
2656
2657   skip_targ=no
2658   case $ac_arg in
2659 changequote(,)
2660   --with-* | --without-*)
2661     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2662
2663     case $libopt in
2664     *[-_]include)
2665       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2666       ;;
2667     *[-_]lib)
2668       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2669       ;;
2670     *)
2671       lib=$libopt
2672       ;;
2673     esac
2674 changequote([,])
2675
2676     case $lib in
2677     mpc | mpfr | gmp | ppl | cloog)
2678       # If we're processing --with-$lib, --with-$lib-include or
2679       # --with-$lib-lib, for one of the libs above, and target is
2680       # different from host, don't pass the current argument to any
2681       # target library's configure.
2682       if test x$is_cross_compiler = xyes; then
2683         skip_targ=yes
2684       fi
2685       ;;
2686     esac
2687     ;;
2688   esac
2689
2690   case "$ac_arg" in
2691     --cache-file=/dev/null | \
2692     -cache-file=/dev/null )
2693       # Handled here to avoid the test to skip args below.
2694       baseargs="$baseargs '$ac_arg'"
2695       tbaseargs="$tbaseargs '$ac_arg'"
2696       # Assert: $separate_arg should always be no.
2697       keep_next=$separate_arg
2698       ;;
2699     --no*)
2700       continue
2701       ;;
2702     --c* | \
2703     --sr* | \
2704     --ho* | \
2705     --bu* | \
2706     --t* | \
2707     --program-* | \
2708     -cache_file* | \
2709     -srcdir* | \
2710     -host* | \
2711     -build* | \
2712     -target* | \
2713     -program-prefix* | \
2714     -program-suffix* | \
2715     -program-transform-name* )
2716       skip_next=$separate_arg
2717       continue
2718       ;;
2719     -*)
2720       # An option.  Add it.
2721       case $ac_arg in
2722         *\'*)
2723           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2724       esac
2725       baseargs="$baseargs '$ac_arg'"
2726       if test X"$skip_targ" = Xno; then
2727         tbaseargs="$tbaseargs '$ac_arg'"
2728       fi
2729       keep_next=$separate_arg
2730       ;;
2731     *)
2732       # Either a variable assignment, or a nonopt (triplet).  Don't
2733       # pass it down; let the Makefile handle this.
2734       continue
2735       ;;
2736   esac
2737 done
2738 # Remove the initial space we just introduced and, as these will be
2739 # expanded by make, quote '$'.
2740 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2741
2742 # Add in --program-transform-name, after --program-prefix and
2743 # --program-suffix have been applied to it.  Autoconf has already
2744 # doubled dollar signs and backslashes in program_transform_name; we want
2745 # the backslashes un-doubled, and then the entire thing wrapped in single
2746 # quotes, because this will be expanded first by make and then by the shell.
2747 # Also, because we want to override the logic in subdir configure scripts to
2748 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2749 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2750 ${program_transform_name}
2751 EOF_SED
2752 gcc_transform_name=`cat conftestsed.out`
2753 rm -f conftestsed.out
2754 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2755 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2756 if test "$silent" = yes; then
2757   baseargs="$baseargs --silent"
2758   tbaseargs="$tbaseargs --silent"
2759 fi
2760 baseargs="$baseargs --disable-option-checking"
2761 tbaseargs="$tbaseargs --disable-option-checking"
2762
2763 # Record and document user additions to sub configure arguments.
2764 AC_ARG_VAR([build_configargs],
2765            [additional configure arguments for build directories])
2766 AC_ARG_VAR([host_configargs],
2767            [additional configure arguments for host directories])
2768 AC_ARG_VAR([target_configargs],
2769            [additional configure arguments for target directories])
2770
2771 # For the build-side libraries, we just need to pretend we're native,
2772 # and not use the same cache file.  Multilibs are neither needed nor
2773 # desired.
2774 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2775
2776 # For host modules, accept cache file option, or specification as blank.
2777 case "${cache_file}" in
2778 "") # empty
2779   cache_file_option="" ;;
2780 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2781   cache_file_option="--cache-file=${cache_file}" ;;
2782 *) # relative path
2783   cache_file_option="--cache-file=../${cache_file}" ;;
2784 esac
2785
2786 # Host dirs don't like to share a cache file either, horribly enough.
2787 # This seems to be due to autoconf 2.5x stupidity.
2788 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2789
2790 target_configargs="$target_configargs ${tbaseargs}"
2791
2792 # Passing a --with-cross-host argument lets the target libraries know
2793 # whether they are being built with a cross-compiler or being built
2794 # native.  However, it would be better to use other mechanisms to make the
2795 # sorts of decisions they want to make on this basis.  Please consider
2796 # this option to be deprecated.  FIXME.
2797 if test x${is_cross_compiler} = xyes ; then
2798   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2799 fi
2800
2801 # Default to --enable-multilib.
2802 if test x${enable_multilib} = x ; then
2803   target_configargs="--enable-multilib ${target_configargs}"
2804 fi
2805
2806 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2807 # changed from the earlier setting of with_newlib.
2808 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2809   target_configargs="--with-newlib ${target_configargs}"
2810 fi
2811
2812 # Different target subdirs use different values of certain variables
2813 # (notably CXX).  Worse, multilibs use *lots* of different values.
2814 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2815 # it doesn't automatically accept command-line overrides of them.
2816 # This means it's not safe for target subdirs to share a cache file,
2817 # which is disgusting, but there you have it.  Hopefully this can be
2818 # fixed in future.  It's still worthwhile to use a cache file for each
2819 # directory.  I think.
2820
2821 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2822 # We need to pass --target, as newer autoconf's requires consistency
2823 # for target_alias and gcc doesn't manage it consistently.
2824 target_configargs="--cache-file=./config.cache ${target_configargs}"
2825
2826 FLAGS_FOR_TARGET=
2827 case " $target_configdirs " in
2828  *" newlib "*)
2829   case " $target_configargs " in
2830   *" --with-newlib "*)
2831    case "$target" in
2832     *-cygwin*)
2833       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2834       ;;
2835    esac
2836
2837    # If we're not building GCC, don't discard standard headers.
2838    if test -d ${srcdir}/gcc; then
2839      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2840
2841      if test "${build}" != "${host}"; then
2842        # On Canadian crosses, CC_FOR_TARGET will have already been set
2843        # by `configure', so we won't have an opportunity to add -Bgcc/
2844        # to it.  This is right: we don't want to search that directory
2845        # for binaries, but we want the header files in there, so add
2846        # them explicitly.
2847        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2848
2849        # Someone might think of using the pre-installed headers on
2850        # Canadian crosses, in case the installed compiler is not fully
2851        # compatible with the compiler being built.  In this case, it
2852        # would be better to flag an error than risking having
2853        # incompatible object files being constructed.  We can't
2854        # guarantee that an error will be flagged, but let's hope the
2855        # compiler will do it, when presented with incompatible header
2856        # files.
2857      fi
2858    fi
2859
2860    case "${target}-${is_cross_compiler}" in
2861    i[[3456789]]86-*-linux*-no)
2862       # Here host == target, so we don't need to build gcc,
2863       # so we don't want to discard standard headers.
2864       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2865       ;;
2866    *)
2867       # If we're building newlib, use its generic headers last, but search
2868       # for any libc-related directories first (so make it the last -B
2869       # switch).
2870       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2871
2872       # If we're building libgloss, find the startup file, simulator library
2873       # and linker script.
2874       case " $target_configdirs " in
2875         *" libgloss "*)
2876         # Look for startup file, simulator library and maybe linker script.
2877         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2878         # Look for libnosys.a in case the target needs it.
2879         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2880         # Most targets have the linker script in the source directory.
2881         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2882         ;;
2883       esac
2884       ;;
2885    esac
2886    ;;
2887   esac
2888   ;;
2889 esac
2890
2891 case "$target" in
2892   x86_64-*mingw* | *-w64-mingw*)
2893   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2894   # however, use a symlink named 'mingw' in ${prefix} .
2895     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2896     ;;
2897   *-mingw*)
2898   # MinGW can't be handled as Cygwin above since it does not use newlib.
2899     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2900     ;;
2901 esac
2902
2903 # Allow the user to override the flags for
2904 # our build compiler if desired.
2905 if test x"${build}" = x"${host}" ; then
2906   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2907   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2908   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2909 fi
2910
2911 # On Canadian crosses, we'll be searching the right directories for
2912 # the previously-installed cross compiler, so don't bother to add
2913 # flags for directories within the install tree of the compiler
2914 # being built; programs in there won't even run.
2915 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2916   # Search for pre-installed headers if nothing else fits.
2917   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2918 fi
2919
2920 if test "x${use_gnu_ld}" = x &&
2921    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2922   # Arrange for us to find uninstalled linker scripts.
2923   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2924 fi
2925
2926 # Search for other target-specific linker scripts and such.
2927 case "${target}" in
2928   mep*)
2929     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2930     ;;
2931 esac
2932
2933 # Makefile fragments.
2934 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2935 do
2936   eval fragval=\$$frag
2937   if test $fragval != /dev/null; then
2938     eval $frag=${srcdir}/$fragval
2939   fi
2940 done
2941 AC_SUBST_FILE(host_makefile_frag)
2942 AC_SUBST_FILE(target_makefile_frag)
2943 AC_SUBST_FILE(alphaieee_frag)
2944 AC_SUBST_FILE(ospace_frag)
2945
2946 # Miscellanea: directories, flags, etc.
2947 AC_SUBST(RPATH_ENVVAR)
2948 AC_SUBST(GCC_SHLIB_SUBDIR)
2949 AC_SUBST(tooldir)
2950 AC_SUBST(build_tooldir)
2951 AC_SUBST(CONFIGURE_GDB_TK)
2952 AC_SUBST(GDB_TK)
2953 AC_SUBST(INSTALL_GDB_TK)
2954
2955 # Build module lists & subconfigure args.
2956 AC_SUBST(build_configargs)
2957 AC_SUBST(build_configdirs)
2958
2959 # Host module lists & subconfigure args.
2960 AC_SUBST(host_configargs)
2961 AC_SUBST(configdirs)
2962 AC_SUBST(target_configdirs)
2963
2964 # Target module lists & subconfigure args.
2965 AC_SUBST(target_configargs)
2966
2967
2968 # Build tools.
2969 AC_SUBST(AR_FOR_BUILD)
2970 AC_SUBST(AS_FOR_BUILD)
2971 AC_SUBST(CC_FOR_BUILD)
2972 AC_SUBST(CFLAGS_FOR_BUILD)
2973 AC_SUBST(CXXFLAGS_FOR_BUILD)
2974 AC_SUBST(CXX_FOR_BUILD)
2975 AC_SUBST(DLLTOOL_FOR_BUILD)
2976 AC_SUBST(GCJ_FOR_BUILD)
2977 AC_SUBST(GFORTRAN_FOR_BUILD)
2978 AC_SUBST(GOC_FOR_BUILD)
2979 AC_SUBST(LDFLAGS_FOR_BUILD)
2980 AC_SUBST(LD_FOR_BUILD)
2981 AC_SUBST(NM_FOR_BUILD)
2982 AC_SUBST(RANLIB_FOR_BUILD)
2983 AC_SUBST(WINDMC_FOR_BUILD)
2984 AC_SUBST(WINDRES_FOR_BUILD)
2985
2986 # Generate default definitions for YACC, M4, LEX and other programs that run
2987 # on the build machine.  These are used if the Makefile can't locate these
2988 # programs in objdir.
2989 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2990
2991 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2992 case " $build_configdirs " in
2993   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2994 esac
2995
2996 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2997 case " $build_configdirs " in
2998   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2999 esac
3000
3001 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3002 case " $build_configdirs " in
3003   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3004 esac
3005
3006 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3007 case " $build_configdirs " in
3008   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3009   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3010 esac
3011
3012 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3013 case " $build_configdirs " in
3014   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3015 esac
3016
3017 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3018 case " $build_configdirs " in
3019   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3020   *)
3021 changequote(,)
3022     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3023     # higher, else we use the "missing" dummy.
3024     if ${MAKEINFO} --version \
3025        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3026       :
3027     else
3028       MAKEINFO="$MISSING makeinfo"
3029     fi
3030     ;;
3031 changequote([,])
3032 esac
3033
3034 # FIXME: expect and dejagnu may become build tools?
3035
3036 AC_CHECK_PROGS(EXPECT, expect, expect)
3037 case " $configdirs " in
3038   *" expect "*)
3039     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3040     ;;
3041 esac
3042
3043 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3044 case " $configdirs " in
3045   *" dejagnu "*)
3046     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3047     ;;
3048 esac
3049
3050
3051 # Host tools.
3052 NCN_STRICT_CHECK_TOOLS(AR, ar)
3053 NCN_STRICT_CHECK_TOOLS(AS, as)
3054 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3055 NCN_STRICT_CHECK_TOOLS(LD, ld)
3056 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3057 NCN_STRICT_CHECK_TOOLS(NM, nm)
3058 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3059 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3060 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3061 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3062 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3063 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3064 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3065 AC_SUBST(CC)
3066 AC_SUBST(CXX)
3067 AC_SUBST(CFLAGS)
3068 AC_SUBST(CXXFLAGS)
3069
3070 # Target tools.
3071 AC_ARG_WITH([build-time-tools],
3072   [AS_HELP_STRING([--with-build-time-tools=PATH],
3073                   [use given path to find target tools during the build])],
3074   [case x"$withval" in
3075      x/*) ;;
3076      *)
3077        with_build_time_tools=
3078        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3079        ;;
3080    esac],
3081   [with_build_time_tools=])
3082
3083 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3084 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3085 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3086 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3087 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3088 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3089
3090 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3091 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3092 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3093 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3094 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3095 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3096 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3097 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3098 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3099 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3100 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3101 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3102
3103 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3104
3105 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3106 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3107 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3108 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3109 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3110                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3111                 c++)
3112 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3113                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3114                 c++)
3115 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3116 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3117 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3118                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3119 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3120                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3121 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3122                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3123 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3124 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3125 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3126 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3127 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3128 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3129 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3130 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3131 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3132
3133 AC_SUBST(FLAGS_FOR_TARGET)
3134 AC_SUBST(RAW_CXX_FOR_TARGET)
3135
3136 # Certain tools may need extra flags.
3137 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3138 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3139 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3140
3141 # When building target libraries, except in a Canadian cross, we use
3142 # the same toolchain as the compiler we just built.
3143 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3144 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3145 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3146 if test $host = $build; then
3147   case " $configdirs " in
3148     *" gcc "*)
3149       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3150       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3151       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3152       ;;
3153   esac
3154 fi
3155
3156 AC_SUBST(COMPILER_AS_FOR_TARGET)
3157 AC_SUBST(COMPILER_LD_FOR_TARGET)
3158 AC_SUBST(COMPILER_NM_FOR_TARGET)
3159
3160 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3161 AC_ARG_ENABLE(maintainer-mode,
3162 [AS_HELP_STRING([--enable-maintainer-mode],
3163                 [enable make rules and dependencies not useful
3164                  (and sometimes confusing) to the casual installer])],
3165       USE_MAINTAINER_MODE=$enableval,
3166       USE_MAINTAINER_MODE=no)
3167 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3168 AC_SUBST(MAINTAINER_MODE_TRUE)
3169 AC_SUBST(MAINTAINER_MODE_FALSE)
3170 if test "$USE_MAINTAINER_MODE" = yes; then
3171   MAINTAINER_MODE_TRUE=
3172   MAINTAINER_MODE_FALSE='#'
3173 else
3174   MAINTAINER_MODE_TRUE='#'
3175   MAINTAINER_MODE_FALSE=
3176 fi
3177 MAINT=$MAINTAINER_MODE_TRUE
3178 AC_SUBST(MAINT)dnl
3179
3180 # ---------------------
3181 # GCC bootstrap support
3182 # ---------------------
3183
3184 # Stage specific cflags for build.
3185 stage1_cflags="-g"
3186 case $build in
3187   vax-*-*)
3188     case ${GCC} in
3189       yes) stage1_cflags="-g -Wa,-J" ;;
3190       *) stage1_cflags="-g -J" ;;
3191     esac ;;
3192 esac
3193
3194 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3195 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3196   saved_CFLAGS="$CFLAGS"
3197
3198   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3199   CFLAGS="$CFLAGS -fkeep-inline-functions"
3200   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3201   AC_TRY_COMPILE([
3202 #if (__GNUC__ < 3) \
3203     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3204                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3205 #error http://gcc.gnu.org/PR29382
3206 #endif
3207     ],,
3208     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3209     [AC_MSG_RESULT([no])])
3210
3211   CFLAGS="$saved_CFLAGS"
3212 fi
3213
3214 AC_SUBST(stage1_cflags)
3215
3216 # Enable --enable-checking in stage1 of the compiler.
3217 AC_ARG_ENABLE(stage1-checking,
3218 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3219                 [choose additional checking for stage1 of the compiler])],
3220 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3221 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3222   stage1_checking=--enable-checking=yes,types
3223 else
3224   stage1_checking=--enable-checking=$enable_checking,types
3225 fi])
3226 AC_SUBST(stage1_checking)
3227
3228 # Enable -Werror in bootstrap stage2 and later.
3229 AC_ARG_ENABLE(werror,
3230 [AS_HELP_STRING([--enable-werror],
3231                 [enable -Werror in bootstrap stage2 and later])], [],
3232 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3233   enable_werror=yes
3234 else
3235   enable_werror=no
3236 fi])
3237 case ${enable_werror} in
3238   yes) stage2_werror_flag="--enable-werror-always" ;;
3239   *) stage2_werror_flag="" ;;
3240 esac
3241 AC_SUBST(stage2_werror_flag)
3242
3243 # If using ENABLE_BUILD_POSTSTAGE1_WITH_CXX, pass
3244 # --enable-build-with-cxx after stage1.
3245 if test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
3246   POSTSTAGE1_CONFIGURE_FLAGS=--enable-build-with-cxx
3247 else
3248   POSTSTAGE1_CONFIGURE_FLAGS=
3249 fi
3250 AC_SUBST(POSTSTAGE1_CONFIGURE_FLAGS)
3251
3252 # Specify what files to not compare during bootstrap.
3253
3254 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3255 case "$target" in
3256   hppa*64*-*-hpux*) ;;
3257   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3258 esac
3259 case " $configdirs " in
3260 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3261 esac
3262 AC_SUBST(compare_exclusions)
3263
3264 AC_CONFIG_FILES([Makefile],
3265   [sed "$extrasub_build" Makefile |
3266    sed "$extrasub_host" |
3267    sed "$extrasub_target" > mf$$
3268    mv -f mf$$ Makefile],
3269   [extrasub_build="$extrasub_build"
3270    extrasub_host="$extrasub_host"
3271    extrasub_target="$extrasub_target"])
3272 AC_OUTPUT