libcpp/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT(cpplib, [ ], gcc-bugs@gcc.gnu.org, cpplib)
   6 AC_CONFIG_SRCDIR(ucnid.h)
   7 AC_CONFIG_MACRO_DIR(../config)
   8 AC_CANONICAL_SYSTEM
   9
  10 # Checks for programs.
  11 AC_PROG_MAKE_SET
  12 AC_PROG_INSTALL
  13 AC_PROG_CC
  14 AC_PROG_CXX
  15 AC_PROG_RANLIB
  16
  17 AC_USE_SYSTEM_EXTENSIONS
  18 AC_SYS_LARGEFILE
  19
  20 # See if we are building gcc with C++.
  21 # Do this early so setting lang to C++ affects following tests
  22 AC_ARG_ENABLE(build-with-cxx,
  23 [  --enable-build-with-cxx build with C++ compiler instead of C compiler],
  24 ENABLE_BUILD_WITH_CXX=$enableval,
  25 ENABLE_BUILD_WITH_CXX=no)
  26 AC_SUBST(ENABLE_BUILD_WITH_CXX)
  27
  28 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  29 AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
  30 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  31 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  32
  33 # Figure out what compiler warnings we can enable.
  34 # See config/warnings.m4 for details.
  35
  36 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings \
  37                           -Wmissing-format-attribute], [warn])
  38 ACX_PROG_CC_WARNING_OPTS([-Wstrict-prototypes -Wmissing-prototypes \
  39                           -Wold-style-definition -Wc++-compat], [c_warn])
  40 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
  41
  42 # Only enable with --enable-werror-always until existing warnings are
  43 # corrected.
  44 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  45
  46 # Dependency checking.
  47 ZW_CREATE_DEPDIR
  48 if test "$ENABLE_BUILD_WITH_CXX" = "no"; then
  49 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  50 else
  51 AC_LANG_PUSH([C++])
  52 AC_COMPILE_IFELSE([[int i;]], [],
  53                   [AC_MSG_ERROR([C++ compiler missing or inoperational])])
  54 AC_LANG_POP([C++])
  55 ZW_PROG_COMPILER_DEPENDENCIES([CXX])
  56 fi
  57
  58 # Checks for header files.
  59 AC_HEADER_TIME
  60 ACX_HEADER_STRING
  61
  62 AC_CHECK_HEADERS(locale.h fcntl.h limits.h stddef.h \
  63         stdlib.h strings.h string.h sys/file.h unistd.h)
  64
  65 # Checks for typedefs, structures, and compiler characteristics.
  66 AC_C_BIGENDIAN
  67 AC_C_CONST
  68 AC_C_INLINE
  69 AC_FUNC_OBSTACK
  70 AC_TYPE_OFF_T
  71 AC_TYPE_SIZE_T
  72 AC_TYPE_SSIZE_T
  73 AC_TYPE_UINTPTR_T
  74 AC_CHECK_TYPE(ptrdiff_t, int)
  75 AC_STRUCT_TM
  76 AC_CHECK_SIZEOF(int)
  77 AC_CHECK_SIZEOF(long)
  78 define(libcpp_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
  79   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
  80   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
  81   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
  82   putchar_unlocked putc_unlocked)
  83 AC_CHECK_FUNCS(libcpp_UNLOCKED_FUNCS)
  84 AC_CHECK_DECLS([abort, asprintf, basename(char *), errno, getopt, vasprintf])
  85 AC_CHECK_DECLS(m4_split(m4_normalize(libcpp_UNLOCKED_FUNCS)))
  86
  87 # Checks for library functions.
  88 AC_FUNC_ALLOCA
  89 AC_HEADER_STDC
  90 AM_LANGINFO_CODESET
  91 ZW_GNU_GETTEXT_SISTER_DIR
  92
  93 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
  94 [AC_TRY_COMPILE([
  95 #include <sys/types.h>
  96 ],
  97 [if ((uchar *)0) return 0;
  98  if (sizeof(uchar)) return 0;],
  99 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
 100 if test $ac_cv_type_uchar = yes; then
 101   AC_DEFINE(HAVE_UCHAR, 1,
 102   [Define if <sys/types.h> defines \`uchar'.])
 103 fi
 104
 105 AM_ICONV
 106
 107 # More defines and substitutions.
 108 PACKAGE="$PACKAGE_TARNAME"
 109 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Define to the name of this package.])
 110 AC_SUBST(PACKAGE)
 111
 112 if test "x$enable_nls" != xno; then
 113   USED_CATALOGS='$(CATALOGS)'
 114 else
 115   USED_CATALOGS=
 116 fi
 117 AC_SUBST(USED_CATALOGS)
 118
 119 AC_ARG_ENABLE(maintainer-mode,
 120 [  --enable-maintainer-mode enable rules only needed by maintainers],,
 121 enable_maintainer_mode=no)
 122
 123 if test "x$enable_maintainer_mode" = xno; then
 124   MAINT='#'
 125 else
 126   MAINT=
 127 fi
 128 AC_SUBST(MAINT)
 129
 130 AC_ARG_ENABLE(checking,
 131 [  --enable-checking      enable expensive run-time checks],,
 132 enable_checking=no)
 133
 134 if test $enable_checking != no ; then
 135   AC_DEFINE(ENABLE_CHECKING, 1,
 136 [Define if you want more run-time sanity checks.])
 137 fi
 138
 139 m4_changequote(,)
 140 case $target in
 141         alpha*-*-* | \
 142         arm*-*-*eabi* | \
 143         arm*-*-symbianelf* | \
 144         x86_64-*-* | \
 145         ia64-*-* | \
 146         hppa*64*-*-* | \
 147         i[34567]86-*-darwin* | \
 148         i[34567]86-*-solaris2.1[0-9]* | \
 149         i[34567]86-w64-mingw* | \
 150         mips*-*-* | \
 151         mmix-*-* | \
 152         powerpc*-*-* | \
 153         rs6000*-*-* | \
 154         s390*-*-* | \
 155         sparc*-*-* | \
 156         spu-*-* | \
 157         sh[123456789lbe]*-*-* | sh-*-*)
 158                 need_64bit_hwint=yes ;;
 159         i[34567]86-*-linux*)
 160                 if test "x$enable_targets" = xall; then
 161                         need_64bit_hwint=yes
 162                 else
 163                         need_64bit_hwint=no
 164                 fi
 165                 ;;
 166         *)
 167                 need_64bit_hwint=no ;;
 168 esac
 169
 170 case $need_64bit_hwint:$ac_cv_sizeof_long in
 171         *:8 | no:*) host_wide_int=long ;;
 172         *) host_wide_int='long long' ;;
 173 esac
 174 m4_changequote([,])
 175
 176 AC_DEFINE_UNQUOTED(HOST_WIDE_INT, $host_wide_int,
 177 [Define to the widest efficient host integer type at least
 178    as wide as the target's size_t type.])
 179
 180 case $target in
 181   i?86-* | x86_64-*)
 182     AC_TRY_COMPILE([], [asm ("pcmpestri %0, %%xmm0, %%xmm1" : : "i"(0))],
 183       [AC_DEFINE([HAVE_SSE4], [1],
 184                  [Define to 1 if you can assemble SSE4 insns.])])
 185 esac
 186
 187 # Output.
 188
 189 AC_CONFIG_HEADERS(config.h:config.in, [echo timestamp > stamp-h1])
 190 AC_CONFIG_FILES(Makefile)
 191 AC_OUTPUT