gcc/ada/sem_prag.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ P R A G                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2016, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  Pragma handling is isolated in a separate package
  27 --  (logically this processing belongs in chapter 4)
  28
  29 with Namet;  use Namet;
  30 with Opt;    use Opt;
  31 with Snames; use Snames;
  32 with Types;  use Types;
  33
  34 package Sem_Prag is
  35
  36    --  The following table lists all pragmas that emulate an Ada 2012 aspect
  37
  38    Aspect_Specifying_Pragma : constant array (Pragma_Id) of Boolean :=
  39      (Pragma_Abstract_State               => True,
  40       Pragma_All_Calls_Remote             => True,
  41       Pragma_Annotate                     => True,
  42       Pragma_Async_Readers                => True,
  43       Pragma_Async_Writers                => True,
  44       Pragma_Asynchronous                 => True,
  45       Pragma_Atomic                       => True,
  46       Pragma_Atomic_Components            => True,
  47       Pragma_Attach_Handler               => True,
  48       Pragma_Constant_After_Elaboration   => True,
  49       Pragma_Contract_Cases               => True,
  50       Pragma_Convention                   => True,
  51       Pragma_CPU                          => True,
  52       Pragma_Default_Initial_Condition    => True,
  53       Pragma_Default_Storage_Pool         => True,
  54       Pragma_Depends                      => True,
  55       Pragma_Discard_Names                => True,
  56       Pragma_Dispatching_Domain           => True,
  57       Pragma_Effective_Reads              => True,
  58       Pragma_Effective_Writes             => True,
  59       Pragma_Elaborate_Body               => True,
  60       Pragma_Export                       => True,
  61       Pragma_Extensions_Visible           => True,
  62       Pragma_Favor_Top_Level              => True,
  63       Pragma_Ghost                        => True,
  64       Pragma_Global                       => True,
  65       Pragma_Import                       => True,
  66       Pragma_Independent                  => True,
  67       Pragma_Independent_Components       => True,
  68       Pragma_Initial_Condition            => True,
  69       Pragma_Initializes                  => True,
  70       Pragma_Inline                       => True,
  71       Pragma_Inline_Always                => True,
  72       Pragma_Interrupt_Handler            => True,
  73       Pragma_Interrupt_Priority           => True,
  74       Pragma_Invariant                    => True,
  75       Pragma_Linker_Section               => True,
  76       Pragma_Lock_Free                    => True,
  77       Pragma_No_Elaboration_Code_All      => True,
  78       Pragma_No_Return                    => True,
  79       Pragma_Obsolescent                  => True,
  80       Pragma_Pack                         => True,
  81       Pragma_Part_Of                      => True,
  82       Pragma_Persistent_BSS               => True,
  83       Pragma_Post                         => True,
  84       Pragma_Post_Class                   => True,
  85       Pragma_Postcondition                => True,
  86       Pragma_Pre                          => True,
  87       Pragma_Pre_Class                    => True,
  88       Pragma_Precondition                 => True,
  89       Pragma_Predicate                    => True,
  90       Pragma_Preelaborable_Initialization => True,
  91       Pragma_Preelaborate                 => True,
  92       Pragma_Priority                     => True,
  93       Pragma_Pure                         => True,
  94       Pragma_Pure_Function                => True,
  95       Pragma_Refined_Depends              => True,
  96       Pragma_Refined_Global               => True,
  97       Pragma_Refined_Post                 => True,
  98       Pragma_Refined_State                => True,
  99       Pragma_Relative_Deadline            => True,
 100       Pragma_Remote_Access_Type           => True,
 101       Pragma_Remote_Call_Interface        => True,
 102       Pragma_Remote_Types                 => True,
 103       Pragma_Secondary_Stack_Size         => True,
 104       Pragma_Shared                       => True,
 105       Pragma_Shared_Passive               => True,
 106       Pragma_Simple_Storage_Pool_Type     => True,
 107       Pragma_SPARK_Mode                   => True,
 108       Pragma_Storage_Size                 => True,
 109       Pragma_Suppress                     => True,
 110       Pragma_Suppress_Debug_Info          => True,
 111       Pragma_Suppress_Initialization      => True,
 112       Pragma_Test_Case                    => True,
 113       Pragma_Thread_Local_Storage         => True,
 114       Pragma_Type_Invariant               => True,
 115       Pragma_Unchecked_Union              => True,
 116       Pragma_Universal_Aliasing           => True,
 117       Pragma_Universal_Data               => True,
 118       Pragma_Unmodified                   => True,
 119       Pragma_Unreferenced                 => True,
 120       Pragma_Unreferenced_Objects         => True,
 121       Pragma_Unsuppress                   => True,
 122       Pragma_Volatile                     => True,
 123       Pragma_Volatile_Components          => True,
 124       Pragma_Volatile_Full_Access         => True,
 125       Pragma_Warnings                     => True,
 126       others                              => False);
 127
 128    --  The following table lists all pragmas that act as an assertion
 129    --  expression.
 130
 131    Assertion_Expression_Pragma : constant array (Pragma_Id) of Boolean :=
 132      (Pragma_Assert                    => True,
 133       Pragma_Assert_And_Cut            => True,
 134       Pragma_Assume                    => True,
 135       Pragma_Check                     => True,
 136       Pragma_Contract_Cases            => True,
 137       Pragma_Default_Initial_Condition => True,
 138       Pragma_Initial_Condition         => True,
 139       Pragma_Invariant                 => True,
 140       Pragma_Loop_Invariant            => True,
 141       Pragma_Loop_Variant              => True,
 142       Pragma_Post                      => True,
 143       Pragma_Post_Class                => True,
 144       Pragma_Postcondition             => True,
 145       Pragma_Pre                       => True,
 146       Pragma_Pre_Class                 => True,
 147       Pragma_Precondition              => True,
 148       Pragma_Predicate                 => True,
 149       Pragma_Refined_Post              => True,
 150       Pragma_Test_Case                 => True,
 151       Pragma_Type_Invariant            => True,
 152       Pragma_Type_Invariant_Class      => True,
 153       others                           => False);
 154
 155    --  The following table lists all the implementation-defined pragmas that
 156    --  should apply to the anonymous object produced by the analysis of a
 157    --  single protected or task type. The table should be synchronized with
 158    --  Aspect_On_Anonymous_Object_OK in unit Aspects.
 159
 160    Pragma_On_Anonymous_Object_OK : constant array (Pragma_Id) of Boolean :=
 161      (Pragma_Depends => True,
 162       Pragma_Global  => True,
 163       Pragma_Part_Of => True,
 164       others         => False);
 165
 166    --  The following table lists all the implementation-defined pragmas that
 167    --  may apply to a body stub (no language defined pragmas apply). The table
 168    --  should be synchronized with Aspect_On_Body_Or_Stub_OK in unit Aspects.
 169
 170    Pragma_On_Body_Or_Stub_OK : constant array (Pragma_Id) of Boolean :=
 171      (Pragma_Refined_Depends => True,
 172       Pragma_Refined_Global  => True,
 173       Pragma_Refined_Post    => True,
 174       Pragma_SPARK_Mode      => True,
 175       Pragma_Warnings        => True,
 176       others                 => False);
 177
 178    -----------------
 179    -- Subprograms --
 180    -----------------
 181
 182    procedure Analyze_Pragma (N : Node_Id);
 183    --  Analyze procedure for pragma reference node N
 184
 185    procedure Analyze_Contract_Cases_In_Decl_Part
 186      (N         : Node_Id;
 187       Freeze_Id : Entity_Id := Empty);
 188    --  Perform full analysis of delayed pragma Contract_Cases. Freeze_Id is the
 189    --  entity of [generic] package body or [generic] subprogram body which
 190    --  caused "freezing" of the related contract where the pragma resides.
 191
 192    procedure Analyze_Depends_In_Decl_Part (N : Node_Id);
 193    --  Perform full analysis of delayed pragma Depends. This routine is also
 194    --  capable of performing basic analysis of pragma Refined_Depends.
 195
 196    procedure Analyze_External_Property_In_Decl_Part
 197      (N        : Node_Id;
 198       Expr_Val : out Boolean);
 199    --  Perform full analysis of delayed pragmas Async_Readers, Async_Writers,
 200    --  Effective_Reads and Effective_Writes. Flag Expr_Val contains the Boolean
 201    --  argument of the pragma or a default True if no argument is present.
 202
 203    procedure Analyze_Global_In_Decl_Part (N : Node_Id);
 204    --  Perform full analysis of delayed pragma Global. This routine is also
 205    --  capable of performing basic analysis of pragma Refind_Global.
 206
 207    procedure Analyze_Initial_Condition_In_Decl_Part (N : Node_Id);
 208    --  Perform full analysis of delayed pragma Initial_Condition
 209
 210    procedure Analyze_Initializes_In_Decl_Part (N : Node_Id);
 211    --  Perform full analysis of delayed pragma Initializes
 212
 213    procedure Analyze_Part_Of_In_Decl_Part
 214      (N         : Node_Id;
 215       Freeze_Id : Entity_Id := Empty);
 216    --  Perform full analysis of delayed pragma Part_Of. Freeze_Id is the entity
 217    --  of [generic] package body or [generic] subprogram body which caused the
 218    --  "freezing" of the related contract where the pragma resides.
 219
 220    procedure Analyze_Pre_Post_Condition_In_Decl_Part
 221      (N         : Node_Id;
 222       Freeze_Id : Entity_Id := Empty);
 223    --  Perform full analysis of pragmas Precondition and Postcondition.
 224    --  Freeze_Id denotes the entity of [generic] package body or [generic]
 225    --  subprogram body which caused "freezing" of the related contract where
 226    --  the pragma resides.
 227
 228    procedure Analyze_Refined_Depends_In_Decl_Part (N : Node_Id);
 229    --  Preform full analysis of delayed pragma Refined_Depends. This routine
 230    --  uses Analyze_Depends_In_Decl_Part as a starting point, then performs
 231    --  various consistency checks between Depends and Refined_Depends.
 232
 233    procedure Analyze_Refined_Global_In_Decl_Part (N : Node_Id);
 234    --  Perform full analysis of delayed pragma Refined_Global. This routine
 235    --  uses Analyze_Global_In_Decl_Part as a starting point, then performs
 236    --  various consistency checks between Global and Refined_Global.
 237
 238    procedure Analyze_Refined_State_In_Decl_Part
 239      (N         : Node_Id;
 240       Freeze_Id : Entity_Id := Empty);
 241    --  Perform full analysis of delayed pragma Refined_State. Freeze_Id denotes
 242    --  the entity of [generic] package body or [generic] subprogram body which
 243    --  caused "freezing" of the related contract where the pragma resides.
 244
 245    procedure Analyze_Test_Case_In_Decl_Part (N : Node_Id);
 246    --  Perform preanalysis of pragma Test_Case
 247
 248    function Build_Pragma_Check_Equivalent
 249      (Prag           : Node_Id;
 250       Subp_Id        : Entity_Id := Empty;
 251       Inher_Id       : Entity_Id := Empty;
 252       Keep_Pragma_Id : Boolean := False) return Node_Id;
 253    --  Transform a pre- or [refined] postcondition denoted by Prag into an
 254    --  equivalent pragma Check. When the pre- or postcondition is inherited,
 255    --  the routine replaces the references of all formals of Inher_Id
 256    --  and primitive operations of its controlling type by references
 257    --  to the corresponding entities of Subp_Id and the descendant type.
 258    --  Keep_Pragma_Id is True when the newly created pragma should be
 259    --  in fact of the same kind as the source pragma Prag. This is used
 260    --  in GNATprove_Mode to generate the inherited pre- and postconditions.
 261
 262    procedure Check_Applicable_Policy (N : Node_Id);
 263    --  N is either an N_Aspect or an N_Pragma node. There are two cases. If
 264    --  the name of the aspect or pragma is not one of those recognized as
 265    --  an assertion kind by an Assertion_Policy pragma, then the call has
 266    --  no effect. Note that in the case of a pragma derived from an aspect,
 267    --  the name we use for the purpose of this procedure is the aspect name,
 268    --  which may be different from the pragma name (e.g. Precondition for
 269    --  Pre aspect). In addition, 'Class aspects are recognized (and the
 270    --  corresponding special names used in the processing).
 271    --
 272    --  If the name is a valid assertion kind name, then the Check_Policy pragma
 273    --  chain is checked for a matching entry (or for an Assertion entry which
 274    --  matches all possibilities). If a matching entry is found then the policy
 275    --  is checked. If it is On or Check, then the Is_Checked flag is set in
 276    --  the aspect or pragma node. If it is Off, Ignore, or Disable, then the
 277    --  Is_Ignored flag is set in the aspect or pragma node. Additionally for
 278    --  policy Disable, the Is_Disabled flag is set.
 279    --
 280    --  If no matching Check_Policy pragma is found then the effect depends on
 281    --  whether -gnata was used, if so, then the call has no effect, otherwise
 282    --  Is_Ignored (but not Is_Disabled) is set True.
 283
 284    procedure Check_External_Properties
 285      (Item : Node_Id;
 286       AR   : Boolean;
 287       AW   : Boolean;
 288       ER   : Boolean;
 289       EW   : Boolean);
 290    --  Flags AR, AW, ER and EW denote the static values of external properties
 291    --  Async_Readers, Async_Writers, Effective_Reads and Effective_Writes. Item
 292    --  is the related variable or state. Ensure legality of the combination and
 293    --  issue an error for an illegal combination.
 294
 295    function Check_Kind (Nam : Name_Id) return Name_Id;
 296    --  This function is used in connection with pragmas Assert, Check,
 297    --  and assertion aspects and pragmas, to determine if Check pragmas
 298    --  (or corresponding assertion aspects or pragmas) are currently active
 299    --  as determined by the presence of -gnata on the command line (which
 300    --  sets the default), and the appearance of pragmas Check_Policy and
 301    --  Assertion_Policy as configuration pragmas either in a configuration
 302    --  pragma file, or at the start of the current unit, or locally given
 303    --  Check_Policy and Assertion_Policy pragmas that are currently active.
 304    --
 305    --  The value returned is one of the names Check, Ignore, Disable (On
 306    --  returns Check, and Off returns Ignore).
 307    --
 308    --  Note: for assertion kinds Pre'Class, Post'Class, Invariant'Class,
 309    --  and Type_Invariant'Class, the name passed is Name_uPre, Name_uPost,
 310    --  Name_uInvariant, or Name_uType_Invariant, which corresponds to _Pre,
 311    --  _Post, _Invariant, or _Type_Invariant, which are special names used
 312    --  in identifiers to represent these attribute references.
 313
 314    procedure Check_Missing_Part_Of (Item_Id : Entity_Id);
 315    --  Determine whether the placement within the state space of an abstract
 316    --  state, variable or package instantiation denoted by Item_Id requires the
 317    --  use of indicator/option Part_Of. If this is the case, emit an error.
 318
 319    procedure Collect_Inherited_Class_Wide_Conditions (Subp : Entity_Id);
 320    --  In GNATprove mode, when analyzing an overriding subprogram, check
 321    --  whether the overridden operations have class-wide pre/postconditions,
 322    --  and generate the corresponding pragmas. The pragmas are inserted after
 323    --  the subprogram declaration, together with those generated for other
 324    --  aspects of the subprogram.
 325
 326    procedure Collect_Subprogram_Inputs_Outputs
 327      (Subp_Id      : Entity_Id;
 328       Synthesize   : Boolean := False;
 329       Subp_Inputs  : in out Elist_Id;
 330       Subp_Outputs : in out Elist_Id;
 331       Global_Seen  : out Boolean);
 332    --  Subsidiary to the analysis of pragmas Depends, Global, Refined_Depends
 333    --  and Refined_Global. The routine is also used by GNATprove. Collect all
 334    --  inputs and outputs of subprogram Subp_Id in lists Subp_Inputs (inputs)
 335    --  and Subp_Outputs (outputs). The inputs and outputs are gathered from:
 336    --    1) The formal parameters of the subprogram
 337    --    2) The generic formal parameters of the generic subprogram
 338    --    3) The current instance of a concurrent type
 339    --    4) The items of pragma [Refined_]Global
 340    --         or
 341    --    5) The items of pragma [Refined_]Depends if there is no pragma
 342    --       [Refined_]Global present and flag Synthesize is set to True.
 343    --  If the subprogram has no inputs and/or outputs, then the returned list
 344    --  is No_Elist. Flag Global_Seen is set when the related subprogram has
 345    --  pragma [Refined_]Global.
 346
 347    function Delay_Config_Pragma_Analyze (N : Node_Id) return Boolean;
 348    --  N is a pragma appearing in a configuration pragma file. Most such
 349    --  pragmas are analyzed when the file is read, before parsing and analyzing
 350    --  the main unit. However, the analysis of certain pragmas results in
 351    --  adding information to the compiled main unit, and this cannot be done
 352    --  till the main unit is processed. Such pragmas return True from this
 353    --  function and in Frontend pragmas where Delay_Config_Pragma_Analyze is
 354    --  True have their analysis delayed until after the main program is parsed
 355    --  and analyzed.
 356
 357    function Find_Related_Package_Or_Body
 358      (Prag      : Node_Id;
 359       Do_Checks : Boolean := False) return Node_Id;
 360    --  Subsidiary to the analysis of pragmas
 361    --    Abstract_State
 362    --    Initial_Condition
 363    --    Initializes
 364    --    Refined_State
 365    --  Find the declaration of the related package [body] subject to pragma
 366    --  Prag. The return value is either N_Package_Declaration, N_Package_Body,
 367    --  or Empty if the placement of the pragma is illegal. If flag Do_Checks is
 368    --  set, the routine reports duplicate pragmas.
 369
 370    function Find_Related_Declaration_Or_Body
 371      (Prag      : Node_Id;
 372       Do_Checks : Boolean := False) return Node_Id;
 373    --  Subsidiary to the analysis of pragmas
 374    --    Contract_Cases
 375    --    Depends
 376    --    Extensions_Visible
 377    --    Global
 378    --    Max_Queue_Length
 379    --    Post
 380    --    Post_Class
 381    --    Postcondition
 382    --    Pre
 383    --    Pre_Class
 384    --    Precondition
 385    --    Refined_Depends
 386    --    Refined_Global
 387    --    Refined_Post
 388    --    Test_Case
 389    --    Volatile_Function
 390    --  as well as attributes 'Old and 'Result. Find the declaration of the
 391    --  related entry, subprogram or task type [body] subject to pragma Prag.
 392    --  If flag Do_Checks is set, the routine reports duplicate pragmas and
 393    --  detects improper use of refinement pragmas in stand alone expression
 394    --  functions.
 395
 396    function Get_Argument
 397      (Prag       : Node_Id;
 398       Context_Id : Node_Id := Empty) return Node_Id;
 399    --  Obtain the argument of pragma Prag depending on context and the nature
 400    --  of the pragma. The argument is extracted in the following manner:
 401    --
 402    --    When the pragma is generated from an aspect, return the corresponding
 403    --    aspect for ASIS or when Context_Id denotes a generic unit.
 404    --
 405    --    Otherwise return the first argument of Prag
 406    --
 407    --  Context denotes the entity of the function, package or procedure where
 408    --  Prag resides.
 409
 410    function Get_SPARK_Mode_From_Annotation
 411      (N : Node_Id) return SPARK_Mode_Type;
 412    --  Given an aspect or pragma SPARK_Mode node, return corresponding mode id
 413
 414    procedure Initialize;
 415    --  Initializes data structures used for pragma processing. Must be called
 416    --  before analyzing each new main source program.
 417
 418    function Is_Config_Static_String (Arg : Node_Id) return Boolean;
 419    --  This is called for a configuration pragma that requires either string
 420    --  literal or a concatenation of string literals. We cannot use normal
 421    --  static string processing because it is too early in the case of the
 422    --  pragma appearing in a configuration pragmas file. If Arg is of an
 423    --  appropriate form, then this call obtains the string (doing any necessary
 424    --  concatenations) and places it in Name_Buffer, setting Name_Len to its
 425    --  length, and then returns True. If it is not of the correct form, then an
 426    --  appropriate error message is posted, and False is returned.
 427
 428    function Is_Elaboration_SPARK_Mode (N : Node_Id) return Boolean;
 429    --  Determine whether pragma SPARK_Mode appears in the statement part of a
 430    --  package body.
 431
 432    function Is_Enabled_Pragma (Prag : Node_Id) return Boolean;
 433    --  Determine whether a Boolean-like SPARK pragma Prag is enabled. To be
 434    --  considered enabled, the pragma must either:
 435    --    * Appear without its Boolean expression
 436    --    * The Boolean expression evaluates to "True"
 437    --
 438    --  Boolean-like SPARK pragmas differ from pure Boolean Ada pragmas in that
 439    --  their optional Boolean expression must be static and cannot benefit from
 440    --  forward references. The following are Boolean-like SPARK pragmas:
 441    --    Async_Readers
 442    --    Async_Writers
 443    --    Constant_After_Elaboration
 444    --    Effective_Reads
 445    --    Effective_Writes
 446    --    Extensions_Visible
 447    --    Volatile_Function
 448
 449    function Is_Non_Significant_Pragma_Reference (N : Node_Id) return Boolean;
 450    --  The node N is a node for an entity and the issue is whether the
 451    --  occurrence is a reference for the purposes of giving warnings about
 452    --  unreferenced variables. This function returns True if the reference is
 453    --  not a reference from this point of view (e.g. the occurrence in a pragma
 454    --  Pack) and False if it is a real reference (e.g. the occurrence in a
 455    --  pragma Export);
 456
 457    function Is_Pragma_String_Literal (Par : Node_Id) return Boolean;
 458    --  Given an N_Pragma_Argument_Association node, Par, which has the form of
 459    --  an operator symbol, determines whether or not it should be treated as an
 460    --  string literal. This is called by Sem_Ch6.Analyze_Operator_Symbol. If
 461    --  True is returned, the argument is converted to a string literal. If
 462    --  False is returned, then the argument is treated as an entity reference
 463    --  to the operator.
 464
 465    function Is_Private_SPARK_Mode (N : Node_Id) return Boolean;
 466    --  Determine whether pragma SPARK_Mode appears in the private part of a
 467    --  package.
 468
 469    function Is_Valid_Assertion_Kind (Nam : Name_Id) return Boolean;
 470    --  Returns True if Nam is one of the names recognized as a valid assertion
 471    --  kind by the Assertion_Policy pragma. Note that the 'Class cases are
 472    --  represented by the corresponding special names Name_uPre, Name_uPost,
 473    --  Name_uInvariant, and Name_uType_Invariant (_Pre, _Post, _Invariant,
 474    --  and _Type_Invariant).
 475
 476    procedure Process_Compile_Time_Warning_Or_Error
 477      (N    : Node_Id;
 478       Eloc : Source_Ptr);
 479    --  Common processing for Compile_Time_Error and Compile_Time_Warning of
 480    --  pragma N. Called when the pragma is processed as part of its regular
 481    --  analysis but also called after calling the back end to validate these
 482    --  pragmas for size and alignment appropriateness.
 483
 484    procedure Process_Compilation_Unit_Pragmas (N : Node_Id);
 485    --  Called at the start of processing compilation unit N to deal with any
 486    --  special issues regarding pragmas. In particular, we have to deal with
 487    --  Suppress_All at this stage, since it can appear after the unit instead
 488    --  of before (actually we allow it to appear anywhere).
 489
 490    procedure Relocate_Pragmas_To_Anonymous_Object
 491      (Typ_Decl : Node_Id;
 492       Obj_Decl : Node_Id);
 493    --  Relocate all pragmas that appear in the visible declarations of task or
 494    --  protected type declaration Typ_Decl after the declaration of anonymous
 495    --  object Obj_Decl. Table Pragmas_On_Anonymous_Object_OK contains the list
 496    --  of candidate pragmas.
 497
 498    procedure Relocate_Pragmas_To_Body
 499      (Subp_Body   : Node_Id;
 500       Target_Body : Node_Id := Empty);
 501    --  Resocate all pragmas that follow and apply to subprogram body Subp_Body
 502    --  to its own declaration list. Candidate pragmas are classified in table
 503    --  Pragma_On_Body_Or_Stub_OK. If Target_Body is set, the pragma are moved
 504    --  to the declarations of Target_Body. This formal should be set when
 505    --  dealing with subprogram body stubs or expression functions.
 506
 507    procedure Set_Encoded_Interface_Name (E : Entity_Id; S : Node_Id);
 508    --  This routine is used to set an encoded interface name. The node S is
 509    --  an N_String_Literal node for the external name to be set, and E is an
 510    --  entity whose Interface_Name field is to be set. In the normal case where
 511    --  S contains a name that is a valid C identifier, then S is simply set as
 512    --  the value of the Interface_Name. Otherwise it is encoded as needed by
 513    --  particular operating systems. See the body for details of the encoding.
 514
 515    function Test_Case_Arg
 516      (Prag        : Node_Id;
 517       Arg_Nam     : Name_Id;
 518       From_Aspect : Boolean := False) return Node_Id;
 519    --  Obtain argument "Name", "Mode", "Ensures" or "Requires" from Test_Case
 520    --  pragma Prag as denoted by Arg_Nam. When From_Aspect is set, an attempt
 521    --  is made to retrieve the argument from the corresponding aspect if there
 522    --  is one. The returned argument has several formats:
 523    --
 524    --    N_Pragma_Argument_Association if retrieved directly from the pragma
 525    --
 526    --    N_Component_Association if retrieved from the corresponding aspect and
 527    --    the argument appears in a named association form.
 528    --
 529    --    An arbitrary expression if retrieved from the corresponding aspect and
 530    --    the argument appears in positional form.
 531    --
 532    --    Empty if there is no such argument
 533
 534 end Sem_Prag;