gcc/ada/s-memory.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         S Y S T E M . M E M O R Y                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is the default implementation of this package
  35
  36 --  This implementation assumes that the underlying malloc/free/realloc
  37 --  implementation is thread safe, and thus, no additional lock is required.
  38 --  Note that we still need to defer abort because on most systems, an
  39 --  asynchronous signal (as used for implementing asynchronous abort of
  40 --  task) cannot safely be handled while malloc is executing.
  41
  42 --  If you are not using Ada constructs containing the "abort" keyword, then
  43 --  you can remove the calls to Abort_Defer.all and Abort_Undefer.all from
  44 --  this unit.
  45
  46 pragma Warnings (Off);
  47 pragma Compiler_Unit;
  48 pragma Warnings (On);
  49
  50 with Ada.Exceptions;
  51 with System.Soft_Links;
  52 with System.Parameters;
  53 with System.CRTL;
  54
  55 package body System.Memory is
  56
  57    use Ada.Exceptions;
  58    use System.Soft_Links;
  59
  60    function c_malloc (Size : System.CRTL.size_t) return System.Address
  61     renames System.CRTL.malloc;
  62
  63    procedure c_free (Ptr : System.Address)
  64      renames System.CRTL.free;
  65
  66    function c_realloc
  67      (Ptr : System.Address; Size : System.CRTL.size_t) return System.Address
  68      renames System.CRTL.realloc;
  69
  70    -----------
  71    -- Alloc --
  72    -----------
  73
  74    function Alloc (Size : size_t) return System.Address is
  75       Result      : System.Address;
  76       Actual_Size : size_t := Size;
  77
  78    begin
  79       if Size = size_t'Last then
  80          Raise_Exception (Storage_Error'Identity, "object too large");
  81       end if;
  82
  83       --  Change size from zero to non-zero. We still want a proper pointer
  84       --  for the zero case because pointers to zero length objects have to
  85       --  be distinct, but we can't just go ahead and allocate zero bytes,
  86       --  since some malloc's return zero for a zero argument.
  87
  88       if Size = 0 then
  89          Actual_Size := 1;
  90       end if;
  91
  92       if Parameters.No_Abort then
  93          Result := c_malloc (System.CRTL.size_t (Actual_Size));
  94       else
  95          Abort_Defer.all;
  96          Result := c_malloc (System.CRTL.size_t (Actual_Size));
  97          Abort_Undefer.all;
  98       end if;
  99
 100       if Result = System.Null_Address then
 101          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 102       end if;
 103
 104       return Result;
 105    end Alloc;
 106
 107    ----------
 108    -- Free --
 109    ----------
 110
 111    procedure Free (Ptr : System.Address) is
 112    begin
 113       if Parameters.No_Abort then
 114          c_free (Ptr);
 115       else
 116          Abort_Defer.all;
 117          c_free (Ptr);
 118          Abort_Undefer.all;
 119       end if;
 120    end Free;
 121
 122    -------------
 123    -- Realloc --
 124    -------------
 125
 126    function Realloc
 127      (Ptr  : System.Address;
 128       Size : size_t)
 129       return System.Address
 130    is
 131       Result      : System.Address;
 132       Actual_Size : constant size_t := Size;
 133
 134    begin
 135       if Size = size_t'Last then
 136          Raise_Exception (Storage_Error'Identity, "object too large");
 137       end if;
 138
 139       if Parameters.No_Abort then
 140          Result := c_realloc (Ptr, System.CRTL.size_t (Actual_Size));
 141       else
 142          Abort_Defer.all;
 143          Result := c_realloc (Ptr, System.CRTL.size_t (Actual_Size));
 144          Abort_Undefer.all;
 145       end if;
 146
 147       if Result = System.Null_Address then
 148          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 149       end if;
 150
 151       return Result;
 152    end Realloc;
 153
 154 end System.Memory;